configure.ac

   1 dnl -*- mode: m4 -*-
   2 AC_PREREQ([2.63])
   3
   4 m4_define([dbus_major_version], [1])
   5 m4_define([dbus_minor_version], [6])
   6 m4_define([dbus_micro_version], [9])
   7 m4_define([dbus_version],
   8           [dbus_major_version.dbus_minor_version.dbus_micro_version])
   9 AC_INIT([dbus],[dbus_version],[https://bugs.freedesktop.org/enter_bug.cgi?product=dbus],[dbus])
  10
  11 AC_CANONICAL_HOST
  12
  13 AC_CONFIG_HEADERS([config.h])
  14 AC_CONFIG_MACRO_DIR([m4])
  15
  16 AM_INIT_AUTOMAKE([1.10 tar-ustar -Wno-portability])
  17
  18 GETTEXT_PACKAGE=dbus-1
  19 AC_SUBST(GETTEXT_PACKAGE)
  20 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[The name of the gettext domain])
  21
  22 # By default, rebuild autotools files on demand; only use ./missing if the
  23 # user says --disable-maintainer-mode (some distributions like to do this)
  24 AM_MAINTAINER_MODE([enable])
  25
  26 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  27
  28 AC_DEFINE_UNQUOTED(DBUS_DAEMON_NAME,"dbus-daemon",[Name of executable])
  29
  30 # libtool versioning - this applies to libdbus
  31 #
  32 # See http://sources.redhat.com/autobook/autobook/autobook_91.html#SEC91 for details
  33 #
  34
  35 ## increment if the interface has additions, changes, removals.
  36 LT_CURRENT=10
  37
  38 ## increment any time the source changes; set to
  39 ##  0 if you increment CURRENT
  40 LT_REVISION=2
  41
  42 ## increment if any interfaces have been added; set to 0
  43 ## if any interfaces have been changed or removed. removal has
  44 ## precedence over adding, so set to 0 if both happened.
  45 LT_AGE=7
  46
  47 AC_SUBST(LT_CURRENT)
  48 AC_SUBST(LT_REVISION)
  49 AC_SUBST(LT_AGE)
  50
  51 DBUS_MAJOR_VERSION=dbus_major_version
  52 DBUS_MINOR_VERSION=dbus_minor_version
  53 DBUS_MICRO_VERSION=dbus_micro_version
  54 DBUS_VERSION=dbus_major_version.dbus_minor_version.dbus_micro_version
  55
  56 AC_SUBST(DBUS_MAJOR_VERSION)
  57 AC_SUBST(DBUS_MINOR_VERSION)
  58 AC_SUBST(DBUS_MICRO_VERSION)
  59 AC_SUBST(DBUS_VERSION)
  60
  61 AC_PROG_CC
  62 AM_PROG_CC_C_O
  63 AC_PROG_CXX
  64 AC_USE_SYSTEM_EXTENSIONS
  65 AC_ISC_POSIX
  66 AC_HEADER_STDC
  67 AC_C_INLINE
  68 AM_PROG_LIBTOOL
  69 AC_PROG_MKDIR_P
  70 COMPILER_COVERAGE
  71 COMPILER_OPTIMISATIONS
  72 PKG_PROG_PKG_CONFIG
  73
  74 # Initialize libtool
  75 LT_INIT([win32-dll])
  76 LT_LANG([Windows Resource])
  77
  78 # Set some internal variables depending on the platform for later use.
  79 dbus_win=no
  80 dbus_cygwin=no
  81 dbus_unix=no
  82 case "${host}" in
  83     *-mingw32ce*)
  84         dbus_win=yes
  85         dbus_wince=yes
  86         ;;
  87     *-mingw32*)
  88         dbus_win=yes
  89         ;;
  90     *-cygwin*)
  91         dbus_cygwin=yes
  92         dbus_unix=yes
  93         ;;
  94     *)
  95         dbus_unix=yes
  96        ;;
  97 esac
  98
  99 # Special defines for certain platforms
 100 if test "$dbus_win" = yes; then
 101     AC_DEFINE(DBUS_WIN,1,[Defined if we run on a W32 API based system])
 102     BUILD_TIMESTAMP=`date --iso-8601=minutes`
 103     AC_SUBST(BUILD_TIMESTAMP)
 104     # Assume DBUS_VERSION is always three numbers
 105     BUILD_FILEVERSION=`echo "$DBUS_VERSION" | sed -e 's/\./,/g'`,0
 106     AC_SUBST(BUILD_FILEVERSION)
 107     AC_CHECK_TOOL(WINDRES, windres, no)
 108     if test "$WINDRES" = no; then
 109       AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 110     fi
 111     if test "$dbus_wince" = yes; then
 112       AC_DEFINE(DBUS_WINCE,1,[Defined if we run on a W32 CE API based system])
 113       AC_DEFINE(_WIN32_WCE, 0x0502, [Defined to get newer W32 CE APIs])
 114     fi
 115 else
 116     AC_DEFINE(DBUS_UNIX,1,[Defined if we run on a Unix-based system])
 117 fi
 118 if test "$dbus_cygwin" = yes; then
 119     AC_DEFINE(DBUS_CYGWIN,1,[Defined if we run on a cygwin API based system])
 120 fi
 121
 122 AM_CONDITIONAL(DBUS_WIN, test "$dbus_win" = yes)
 123 AM_CONDITIONAL(DBUS_WINCE, test "$dbus_wince" = yes)
 124 AM_CONDITIONAL(DBUS_UNIX, test "$dbus_unix" = yes)
 125 AM_CONDITIONAL(DBUS_CYGWIN, test "$dbus_cygwin" = yes)
 126
 127 # this must come first: other options use this to set their defaults
 128 AC_ARG_ENABLE([developer],
 129   [AS_HELP_STRING([--enable-developer],
 130     [set defaults to be appropriate for a D-Bus developer instead of a distribution/end-user])],
 131   [],
 132   [enable_developer=no])
 133
 134 DBUS_STATIC_BUILD_CPPFLAGS=
 135 if test "x$enable_shared" = xno; then
 136     # On Windows, linking against the static library requires special effort
 137     # to turn off DLL import/export processing. We normally link some things
 138     # against the dynamic library, but if we're not building that, we'll
 139     # have to link everything statically.
 140     DBUS_STATIC_BUILD_CPPFLAGS=-DDBUS_STATIC_BUILD
 141 fi
 142 AC_SUBST([DBUS_STATIC_BUILD_CPPFLAGS])
 143
 144 AC_ARG_ENABLE(ansi, AS_HELP_STRING([--enable-ansi],[enable -ansi -pedantic gcc flags]),enable_ansi=$enableval,enable_ansi=no)
 145 AC_ARG_ENABLE(verbose-mode, AS_HELP_STRING([--enable-verbose-mode],[support verbose debug mode]),enable_verbose_mode=$enableval,enable_verbose_mode=$enable_developer)
 146 AC_ARG_ENABLE(asserts, AS_HELP_STRING([--enable-asserts],[include assertion checks]),enable_asserts=$enableval,enable_asserts=$enable_developer)
 147 AC_ARG_ENABLE(checks, AS_HELP_STRING([--enable-checks],[include sanity checks on public API]),enable_checks=$enableval,enable_checks=yes)
 148 AC_ARG_ENABLE(xml-docs, AS_HELP_STRING([--enable-xml-docs],[build XML documentation (requires xmlto)]),enable_xml_docs=$enableval,enable_xml_docs=auto)
 149 AC_ARG_ENABLE(doxygen-docs, AS_HELP_STRING([--enable-doxygen-docs],[build DOXYGEN documentation (requires Doxygen)]),enable_doxygen_docs=$enableval,enable_doxygen_docs=auto)
 150 AC_ARG_ENABLE(abstract-sockets, AS_HELP_STRING([--enable-abstract-sockets],[use abstract socket namespace (linux only)]),enable_abstract_sockets=$enableval,enable_abstract_sockets=auto)
 151 AC_ARG_ENABLE(selinux, AS_HELP_STRING([--enable-selinux],[build with SELinux support]),enable_selinux=$enableval,enable_selinux=auto)
 152 AC_ARG_ENABLE(libaudit,AS_HELP_STRING([--enable-libaudit],[build audit daemon support for SELinux]),enable_libaudit=$enableval,enable_libaudit=auto)
 153 AC_ARG_ENABLE(dnotify, AS_HELP_STRING([--enable-dnotify],[build with dnotify support (linux only)]),enable_dnotify=$enableval,enable_dnotify=auto)
 154 AC_ARG_ENABLE(inotify, AS_HELP_STRING([--enable-inotify],[build with inotify support (linux only)]),enable_inotify=$enableval,enable_inotify=auto)
 155 AC_ARG_ENABLE(kqueue, AS_HELP_STRING([--enable-kqueue],[build with kqueue support]),enable_kqueue=$enableval,enable_kqueue=auto)
 156 AC_ARG_ENABLE(console-owner-file, AS_HELP_STRING([--enable-console-owner-file],[enable console owner file]),enable_console_owner_file=$enableval,enable_console_owner_file=auto)
 157 AC_ARG_ENABLE(userdb-cache, AS_HELP_STRING([--enable-userdb-cache],[build with userdb-cache support]),enable_userdb_cache=$enableval,enable_userdb_cache=yes)
 158 AC_ARG_ENABLE(launchd, AS_HELP_STRING([--enable-launchd],[build with launchd auto-launch support]),enable_launchd=$enableval,enable_launchd=auto)
 159 AC_ARG_ENABLE(systemd, AS_HELP_STRING([--enable-systemd],[build with systemd at_console support]),enable_systemd=$enableval,enable_systemd=auto)
 160
 161 AC_ARG_WITH(xml, AS_HELP_STRING([--with-xml=[libxml/expat]],[XML library to use (libxml may be named libxml2 on some systems)]))
 162 AC_ARG_WITH(init-scripts, AS_HELP_STRING([--with-init-scripts=[redhat]],[Style of init scripts to install]))
 163 AC_ARG_WITH(session-socket-dir, AS_HELP_STRING([--with-session-socket-dir=[dirname]],[Where to put sockets for the per-login-session message bus]))
 164 AC_ARG_WITH(test-socket-dir, AS_HELP_STRING([--with-test-socket-dir=[dirname]],[Where to put sockets for make check]))
 165 AC_ARG_WITH(system-pid-file, AS_HELP_STRING([--with-system-pid-file=[pidfile]],[PID file for systemwide daemon]))
 166 AC_ARG_WITH(system-socket, AS_HELP_STRING([--with-system-socket=[filename]],[UNIX domain socket for systemwide daemon]))
 167 AC_ARG_WITH(console-auth-dir, AS_HELP_STRING([--with-console-auth-dir=[dirname]],[directory to check for console ownerhip]))
 168 AC_ARG_WITH(console-owner-file, AS_HELP_STRING([--with-console-owner-file=[filename]],[file whose owner determines current console owner]))
 169 AC_ARG_WITH(launchd-agent-dir, AS_HELP_STRING([--with-launchd-agent-dir=[dirname]],[directory to put the launchd agent (default: /Library/LaunchAgents)]))
 170 AC_ARG_WITH(dbus_user, AS_HELP_STRING([--with-dbus-user=<user>],[User for running the DBUS daemon (messagebus)]))
 171 AC_ARG_WITH(dbus_daemondir, AS_HELP_STRING([--with-dbus-daemondir=[dirname]],[Directory for installing the DBUS daemon]))
 172 AC_ARG_WITH(dbus_session_bus_default_address, AS_HELP_STRING([--with-dbus-session-bus-default-address=[nonce-tcp:/autolaunch:/tcp:host:port]],[Transport Type to be used (default: nonce-tcp:)]),with_dbus_session_bus_default_address=$withval,with_dbus_session_bus_default_address=nonce-tcp:)
 173
 174 AC_ARG_ENABLE([embedded-tests],
 175   AS_HELP_STRING([--enable-embedded-tests],
 176     [enable unit test code in the library and binaries]),
 177   [], [enable_embedded_tests=$enable_developer])
 178 AC_ARG_ENABLE([modular-tests],
 179   AS_HELP_STRING([--enable-modular-tests],
 180     [enable modular regression tests (requires GLib)]),
 181   [], [enable_modular_tests=auto])
 182 # --enable-tests overrides both --enable-embedded-tests and
 183 # --enable-modular-tests
 184 AC_ARG_ENABLE([tests],
 185   AS_HELP_STRING([--enable-tests],
 186     [enable/disable all tests, overriding embedded-tests/modular-tests]),
 187   [
 188   if test "x$enableval" = xyes; then
 189     AC_MSG_NOTICE([Full test coverage was requested with --enable-tests=yes])
 190     AC_MSG_NOTICE([This has many dependencies (GLib, dbus-glib, Python)])
 191   fi
 192   enable_embedded_tests=$enableval
 193   enable_modular_tests=$enableval
 194   ],
 195   [])
 196
 197 # DBUS_ENABLE_EMBEDDED_TESTS controls unit tests built in to .c files
 198 # and also some stuff in the test/ subdir. DBUS_BUILD_TESTS was an older
 199 # name for this.
 200 AM_CONDITIONAL([DBUS_BUILD_TESTS], [test "x$enable_embedded_tests" = xyes])
 201 AM_CONDITIONAL([DBUS_ENABLE_EMBEDDED_TESTS],
 202   [test "x$enable_embedded_tests" = xyes])
 203 if test "x$enable_embedded_tests" = xyes; then
 204     AC_DEFINE([DBUS_ENABLE_EMBEDDED_TESTS], [1],
 205       [Define to build test code into the library and binaries])
 206     AC_DEFINE([DBUS_BUILD_TESTS], [1],
 207       [Define to build test code into the library and binaries])
 208 fi
 209
 210 # DBUS_ENABLE_MODULAR_TESTS controls tests that work based on public API.
 211 # These use GTest, from GLib, because life's too short. They're enabled by
 212 # default (unless you don't have GLib), because they don't bloat the library
 213 # or binaries.
 214
 215 with_glib=yes
 216
 217 if test "x$enable_modular_tests" != xno; then
 218   PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.24, gio-2.0 >= 2.24],
 219     [],
 220     [if test "x$enable_modular_tests" = xyes; then
 221       AC_MSG_NOTICE([Full test coverage (--enable-modular-tests=yes or --enable-tests=yes) requires GLib])
 222       AC_MSG_ERROR([$GLIB_ERRORS])
 223     else # assumed to be "auto"
 224       with_glib=no
 225     fi])
 226   # If dbus-gmain.[ch] returned to libdbus then we wouldn't need this
 227   PKG_CHECK_MODULES([DBUS_GLIB], [dbus-glib-1],
 228     [],
 229     [if test "x$enable_modular_tests" = xyes; then
 230       AC_MSG_NOTICE([Full test coverage (--enable-modular-tests=yes or --enable-tests=yes) requires dbus-glib])
 231       AC_MSG_ERROR([$DBUS_GLIB_ERRORS])
 232     else # assumed to be "auto"
 233       with_glib=no
 234     fi])
 235 fi
 236 if test "x$enable_modular_tests" != xno; then
 237   AC_DEFINE([DBUS_ENABLE_MODULAR_TESTS], [1],
 238     [Define to build independent test binaries])
 239 fi
 240 AM_CONDITIONAL([DBUS_ENABLE_MODULAR_TESTS],
 241   [test "x$enable_modular_tests" != xno])
 242
 243 if test "x$with_glib" != xno; then
 244   AC_DEFINE([DBUS_WITH_GLIB], [1],
 245     [Define if GLib, GObject, GIO are available])
 246 fi
 247 AM_CONDITIONAL([DBUS_WITH_GLIB], [test "x$with_glib" != xno])
 248
 249 AC_ARG_ENABLE([installed-tests],
 250   AS_HELP_STRING([--enable-installed-tests],
 251     [enable unit test code in the library and binaries]),
 252   [], [enable_installed_tests=no])
 253 AM_CONDITIONAL([DBUS_ENABLE_INSTALLED_TESTS],
 254   [test "x$enable_installed_tests" = xyes])
 255
 256 if test "x$enable_tests" = xyes; then
 257   # full test coverage is required, Python is a hard dependency
 258   AC_MSG_NOTICE([Full test coverage (--enable-tests=yes) requires Python, dbus-python, pygobject])
 259   AM_PATH_PYTHON([2.6])
 260   AC_MSG_CHECKING([for Python modules for full test coverage])
 261   if "$PYTHON" -c "import dbus, gobject, dbus.mainloop.glib"; then
 262     AC_MSG_RESULT([yes])
 263   else
 264     AC_MSG_RESULT([no])
 265     AC_MSG_ERROR([cannot import dbus, gobject, dbus.mainloop.glib Python modules])
 266   fi
 267 else
 268   # --enable-tests not given: do not abort if Python is missing
 269   AM_PATH_PYTHON([2.6], [], [:])
 270 fi
 271
 272 if test x$enable_verbose_mode = xyes; then
 273     AC_DEFINE(DBUS_ENABLE_VERBOSE_MODE,1,[Support a verbose mode])
 274 fi
 275
 276 if test x$enable_asserts = xno; then
 277     AC_DEFINE(DBUS_DISABLE_ASSERT,1,[Disable assertion checking])
 278     DISABLE_UNUSED_WARNINGS="unused-label"
 279     R_DYNAMIC_LDFLAG=""
 280 else
 281     # -rdynamic is needed for glibc's backtrace_symbols to work.
 282     # No clue how much overhead this adds, but it's useful
 283     # to do this on any assertion failure,
 284     # so for now it's enabled anytime asserts are (currently not
 285     # in production builds).
 286
 287     # To get -rdynamic you pass -export-dynamic to libtool.
 288     AC_DEFINE(DBUS_BUILT_R_DYNAMIC,1,[whether -export-dynamic was passed to libtool])
 289     R_DYNAMIC_LDFLAG=-export-dynamic
 290 fi
 291 AC_SUBST(R_DYNAMIC_LDFLAG)
 292
 293 if test x$enable_checks = xno; then
 294     AC_DEFINE(DBUS_DISABLE_CHECKS,1,[Disable public API sanity checking])
 295     AC_DEFINE(G_DISABLE_CHECKS,1,[Disable GLib public API sanity checking])
 296     DISABLE_UNUSED_WARNINGS="unused-label"
 297 fi
 298
 299 if test x$enable_userdb_cache = xyes; then
 300     AC_DEFINE(DBUS_ENABLE_USERDB_CACHE,1,[Build with caching of user data])
 301 fi
 302
 303 if test x$enable_compiler_coverage = xyes; then
 304      ## so that config.h changes when you toggle gcov support
 305      AC_DEFINE_UNQUOTED(DBUS_GCOV_ENABLED, 1, [Defined if gcov is enabled to force a rebuild due to config.h changing])
 306 fi
 307
 308 # glibc21.m4 serial 3
 309 dnl Copyright (C) 2000-2002, 2004 Free Software Foundation, Inc.
 310 dnl This file is free software; the Free Software Foundation
 311 dnl gives unlimited permission to copy and/or distribute it,
 312 dnl with or without modifications, as long as this notice is preserved.
 313
 314 # Test for the GNU C Library, version 2.1 or newer.
 315 # From Bruno Haible.
 316
 317 AC_CACHE_CHECK(whether we are using the GNU C Library 2.1 or newer,
 318   ac_cv_gnu_library_2_1,
 319   [AC_EGREP_CPP([Lucky GNU user],
 320     [
 321 #include <features.h>
 322 #ifdef __GNU_LIBRARY__
 323  #if (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 1) || (__GLIBC__ > 2)
 324   Lucky GNU user
 325  #endif
 326 #endif
 327     ],
 328     ac_cv_gnu_library_2_1=yes,
 329     ac_cv_gnu_library_2_1=no)
 330   ]
 331 )
 332
 333 #### Integer sizes
 334
 335 AC_CHECK_SIZEOF(char)
 336 AC_CHECK_SIZEOF(short)
 337 AC_CHECK_SIZEOF(long)
 338 AC_CHECK_SIZEOF(int)
 339 AC_CHECK_SIZEOF(void *)
 340 AC_CHECK_SIZEOF(long long)
 341 AC_CHECK_SIZEOF(__int64)
 342
 343 AC_ARG_WITH([64-bit],
 344   [AS_HELP_STRING([--without-64-bit],
 345     [If you have to use this option, please report it as a bug])],
 346   [],
 347   [with_64_bit=yes])
 348
 349 ### See what our 64 bit type is called
 350 AC_MSG_CHECKING([64-bit integer type])
 351
 352 case 8 in
 353 $ac_cv_sizeof_int)
 354   dbusint64=int
 355   dbusint64_constant='(val)'
 356   dbusuint64_constant='(val)'
 357   dbusint64_printf_modifier='""'
 358   ;;
 359 $ac_cv_sizeof_long)
 360   dbusint64=long
 361   dbusint64_constant='(val##L)'
 362   dbusuint64_constant='(val##UL)'
 363   dbusint64_printf_modifier='"l"'
 364   ;;
 365 $ac_cv_sizeof_long_long)
 366   dbusint64='long long'
 367   dbusint64_constant='(val##LL)'
 368   dbusuint64_constant='(val##ULL)'
 369   # Ideally we discover what the format is, but this is
 370   # only used in verbose mode, so eh...
 371   if test x"$ac_cv_gnu_library_2_1" = xyes; then
 372     dbusint64_printf_modifier='"ll"'
 373   fi
 374   ;;
 375 $ac_cv_sizeof___int64)
 376   dbusint64=__int64
 377   dbusint64_constant='(val##i64)'
 378   dbusuint64_constant='(val##ui64)'
 379   # See above case
 380   if test x"$ac_cv_gnu_library_2_1" = xyes; then
 381     dbusint64_printf_modifier='"ll"'
 382   fi
 383   ;;
 384 esac
 385
 386 AS_IF(
 387   [test "x$with_64_bit" = xno],
 388   [
 389         DBUS_INT64_TYPE="no_int64_type_detected"
 390         DBUS_HAVE_INT64=0
 391         DBUS_INT64_CONSTANT=
 392         DBUS_UINT64_CONSTANT=
 393         AC_MSG_RESULT([disabled via --without-64-bit])
 394   ],
 395   dnl else if
 396   [test -z "$dbusint64"],
 397   [AC_MSG_RESULT([not found])
 398   AC_MSG_ERROR([Could not find a 64-bit integer type.
 399
 400 Please report a bug here with details of your platform and compiler:
 401
 402     http://bugs.freedesktop.org/enter_bug.cgi?product=DBus&component=core
 403
 404 To compile D-Bus with all 64-bit integer types removed (not recommended), use
 405 the option "--without-64-bit".
 406
 407 This option is likely to be removed in future, unless you report that your
 408 platform needs it.])
 409   ],
 410   dnl else
 411   [
 412         DBUS_INT64_TYPE="$dbusint64"
 413         DBUS_HAVE_INT64=1
 414         DBUS_INT64_CONSTANT="$dbusint64_constant"
 415         DBUS_UINT64_CONSTANT="$dbusuint64_constant"
 416         if test x"$dbusint64_printf_modifier" != x; then
 417                 AC_DEFINE_UNQUOTED(DBUS_INT64_PRINTF_MODIFIER, [$dbusint64_printf_modifier], [Define to printf modifier for 64 bit integer type])
 418         fi
 419         AC_MSG_RESULT($DBUS_INT64_TYPE)
 420   ])
 421
 422 AC_SUBST(DBUS_INT64_TYPE)
 423 AC_SUBST(DBUS_INT64_CONSTANT)
 424 AC_SUBST(DBUS_UINT64_CONSTANT)
 425 AC_SUBST(DBUS_HAVE_INT64)
 426
 427 ### see what 32-bit int is called
 428 AC_MSG_CHECKING([32-bit integer type])
 429
 430 case 4 in
 431 $ac_cv_sizeof_short)
 432   dbusint32=short
 433   ;;
 434 $ac_cv_sizeof_int)
 435   dbusint32=int
 436   ;;
 437 $ac_cv_sizeof_long)
 438   dbusint32=long
 439   ;;
 440 esac
 441
 442 if test -z "$dbusint32" ; then
 443         DBUS_INT32_TYPE="no_int32_type_detected"
 444         AC_MSG_ERROR([No 32-bit integer type found])
 445 else
 446         DBUS_INT32_TYPE="$dbusint32"
 447         AC_MSG_RESULT($DBUS_INT32_TYPE)
 448 fi
 449
 450 AC_SUBST(DBUS_INT32_TYPE)
 451
 452 ### see what 16-bit int is called
 453 AC_MSG_CHECKING([16-bit integer type])
 454
 455 case 2 in
 456 $ac_cv_sizeof_short)
 457   dbusint16=short
 458   ;;
 459 $ac_cv_sizeof_int)
 460   dbusint16=int
 461   ;;
 462 esac
 463
 464 if test -z "$dbusint16" ; then
 465         DBUS_INT16_TYPE="no_int16_type_detected"
 466         AC_MSG_ERROR([No 16-bit integer type found])
 467 else
 468         DBUS_INT16_TYPE="$dbusint16"
 469         AC_MSG_RESULT($DBUS_INT16_TYPE)
 470 fi
 471
 472 AC_SUBST(DBUS_INT16_TYPE)
 473
 474 ## byte order
 475 case $host_os in
 476         darwin*)
 477                 # check at compile-time, so that it is possible to build universal
 478                 # (with multiple architectures at once on the compile line)
 479                 AH_VERBATIM([WORDS_BIGENDIAN_DARWIN], [
 480                         /* Use the compiler-provided endianness defines to allow universal compiling. */
 481                         #if defined(__BIG_ENDIAN__)
 482                         #define WORDS_BIGENDIAN 1
 483                         #endif
 484                 ])
 485                 ;;
 486         *)
 487                 AC_C_BIGENDIAN
 488                 ;;
 489 esac
 490
 491 dnl **********************************
 492 dnl *** va_copy checks (from GLib) ***
 493 dnl **********************************
 494 dnl we currently check for all three va_copy possibilities, so we get
 495 dnl all results in config.log for bug reports.
 496 AC_CACHE_CHECK([for an implementation of va_copy()],dbus_cv_va_copy,[
 497         AC_LINK_IFELSE([AC_LANG_SOURCE([#include <stdarg.h>
 498 #include <stdlib.h>
 499         static void f (int i, ...) {
 500         va_list args1, args2;
 501         va_start (args1, i);
 502         va_copy (args2, args1);
 503         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 504           exit (1);
 505         va_end (args1); va_end (args2);
 506         }
 507         int main() {
 508           f (0, 42);
 509           return 0;
 510         }])],
 511         [dbus_cv_va_copy=yes],
 512         [dbus_cv_va_copy=no])
 513 ])
 514 AC_CACHE_CHECK([for an implementation of __va_copy()],dbus_cv___va_copy,[
 515         AC_LINK_IFELSE([AC_LANG_SOURCE([#include <stdarg.h>
 516 #include <stdlib.h>
 517         static void f (int i, ...) {
 518         va_list args1, args2;
 519         va_start (args1, i);
 520         __va_copy (args2, args1);
 521         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 522           exit (1);
 523         va_end (args1); va_end (args2);
 524         }
 525         int main() {
 526           f (0, 42);
 527           return 0;
 528         }])],
 529         [dbus_cv___va_copy=yes],
 530         [dbus_cv___va_copy=no])
 531 ])
 532
 533 if test "x$dbus_cv_va_copy" = "xyes"; then
 534   dbus_va_copy_func=va_copy
 535 else if test "x$dbus_cv___va_copy" = "xyes"; then
 536   dbus_va_copy_func=__va_copy
 537 fi
 538 fi
 539
 540 if test -n "$dbus_va_copy_func"; then
 541   AC_DEFINE_UNQUOTED(DBUS_VA_COPY,$dbus_va_copy_func,[A 'va_copy' style function])
 542 fi
 543
 544 AC_LANG_PUSH(C)
 545 AC_CACHE_CHECK([whether va_lists can be copied by value],
 546         dbus_cv_va_val_copy,
 547         [AC_RUN_IFELSE([AC_LANG_PROGRAM(
 548 [[
 549         #include <stdarg.h>
 550         #include <stdlib.h>
 551 ]],
 552 [[
 553         static void f (int i, ...) {
 554         va_list args1, args2;
 555         va_start (args1, i);
 556         args2 = args1;
 557         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 558           exit (1);
 559         va_end (args1); va_end (args2);
 560         }
 561         int main() {
 562           f (0, 42);
 563           return 0;
 564         }
 565 ]])],
 566         [dbus_cv_va_val_copy=yes],
 567         [dbus_cv_va_val_copy=no],
 568         [dbus_cv_va_val_copy=yes])
 569 ])
 570 AC_LANG_POP(C)
 571
 572 if test "x$dbus_cv_va_val_copy" = "xno"; then
 573   AC_DEFINE(DBUS_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
 574 fi
 575
 576
 577 #### Atomic integers
 578
 579 AC_CACHE_CHECK([whether $CC knows __sync_sub_and_fetch()],
 580   dbus_cv_sync_sub_and_fetch,
 581   [AC_LINK_IFELSE([
 582      AC_LANG_PROGRAM([[]], [[int a = 4; int b = __sync_sub_and_fetch(&a, 4); exit(b); ]])],
 583      [dbus_cv_sync_sub_and_fetch=yes],
 584      [dbus_cv_sync_sub_and_fetch=no])
 585   ])
 586
 587 if test "x$dbus_cv_sync_sub_and_fetch" = "xyes" ; then
 588    have_sync=1
 589 else
 590    have_sync=0
 591 fi
 592
 593 AC_DEFINE_UNQUOTED([DBUS_USE_SYNC], [$have_sync], [Use the gcc __sync extension])
 594
 595 #### Various functions
 596 AC_SEARCH_LIBS(socket,[socket network])
 597 AC_CHECK_FUNC(gethostbyname,,[AC_CHECK_LIB(nsl,gethostbyname)])
 598
 599 AC_CHECK_FUNCS(vsnprintf vasprintf nanosleep usleep setenv clearenv unsetenv socketpair getgrouplist fpathconf setrlimit poll setlocale localeconv strtoll strtoull issetugid getresuid)
 600
 601 AC_CHECK_HEADERS([syslog.h])
 602 if test "x$ac_cv_header_syslog_h" = "xyes"; then
 603   AC_CHECK_DECLS([LOG_PERROR], [], [], [[#include <syslog.h>]])
 604 fi
 605
 606 #### Check for broken poll; taken from Glib's configure
 607
 608 AC_MSG_CHECKING([for broken poll])
 609 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 610     #include <stdlib.h>
 611     #include <fcntl.h>
 612     #include <poll.h>
 613     #ifdef HAVE_SYS_POLL_H
 614     #include <sys/poll.h>
 615     #endif
 616     int main(void) {
 617       struct pollfd fds[1];
 618       int fd;
 619       fd = open("/dev/null", 1);
 620       fds[0].fd = fd;
 621       fds[0].events = POLLIN;
 622       fds[0].revents = 0;
 623       if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
 624             exit(1);  /* Does not work for devices -- fail */
 625       }
 626       exit(0);
 627     }]])],
 628   [broken_poll=no],
 629   [broken_poll=yes
 630    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
 631   [broken_poll="no (cross compiling)"])
 632 AC_MSG_RESULT($broken_poll)
 633
 634 AC_MSG_CHECKING(for dirfd)
 635 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 636 #include <sys/types.h>
 637 #include <dirent.h>
 638 ]], [[
 639 DIR *dirp;
 640 dirp = opendir(".");
 641 dirfd(dirp);
 642 closedir(dirp);
 643 ]])],
 644 [dbus_have_dirfd=yes],
 645 [dbus_have_dirfd=no])
 646 AC_MSG_RESULT($dbus_have_dirfd)
 647 if test "$dbus_have_dirfd" = yes; then
 648         AC_DEFINE(HAVE_DIRFD,1,[Have dirfd function])
 649 else
 650         AC_MSG_CHECKING(for DIR *dirp->dd_fd)
 651         AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 652 #include <sys/types.h>
 653 #include <dirent.h>
 654         ]], [[
 655 DIR *dirp;
 656 int fd;
 657 dirp = opendir(".");
 658 fd = dirp->dd_fd;
 659 closedir(dirp);
 660         ]])],
 661         [dbus_have_ddfd=yes],
 662         [dbus_have_ddfd=no])
 663         AC_MSG_RESULT($dbus_have_ddfd)
 664         if test "$dbus_have_ddfd" = yes; then
 665                 AC_DEFINE(HAVE_DDFD,1,[Have the ddfd member of DIR])
 666         fi
 667 fi
 668
 669 AC_CHECK_HEADERS(sys/resource.h)
 670
 671 AC_CHECK_HEADERS(dirent.h)
 672
 673 AC_CHECK_HEADERS(execinfo.h, [AC_CHECK_FUNCS(backtrace)])
 674
 675 AC_CHECK_HEADERS(errno.h)
 676
 677 AC_CHECK_HEADERS(signal.h)
 678
 679 AC_CHECK_HEADERS(locale.h)
 680
 681 AC_CHECK_HEADERS(byteswap.h)
 682
 683 AC_CHECK_HEADERS(unistd.h)
 684
 685 AC_CHECK_HEADERS(ws2tcpip.h)
 686
 687 AC_CHECK_HEADERS(wspiapi.h)
 688
 689 AC_CHECK_HEADERS(alloca.h)
 690
 691 # Add -D_POSIX_PTHREAD_SEMANTICS if on Solaris
 692 #
 693 case $host_os in
 694     solaris*)
 695        CFLAGS="$CFLAGS -D_POSIX_PTHREAD_SEMANTICS" ;;
 696 esac
 697
 698 # checking for a posix version of getpwnam_r
 699 # if we are cross compiling and can not run the test
 700 # assume getpwnam_r is the posix version
 701 # it is up to the person cross compiling to change
 702 # this behavior if desired
 703 AC_LANG_PUSH(C)
 704 AC_CACHE_CHECK([for posix getpwnam_r],
 705                 ac_cv_func_posix_getpwnam_r,
 706                 [AC_RUN_IFELSE([AC_LANG_PROGRAM(
 707 [[
 708 #include <errno.h>
 709 #include <pwd.h>
 710 ]],
 711 [[
 712     char buffer[10000];
 713     struct passwd pwd, *pwptr = &pwd;
 714     int error;
 715     errno = 0;
 716     error = getpwnam_r ("", &pwd, buffer,
 717                         sizeof (buffer), &pwptr);
 718    return (error < 0 && errno == ENOSYS)
 719            || error == ENOSYS;
 720 ]])],
 721         [ac_cv_func_posix_getpwnam_r=yes],
 722         [ac_cv_func_posix_getpwnam_r=no],
 723         [ac_cv_func_posix_getpwnam_r=yes]
 724 )])
 725 AC_LANG_POP(C)
 726
 727 if test "$ac_cv_func_posix_getpwnam_r" = yes; then
 728         AC_DEFINE(HAVE_POSIX_GETPWNAM_R,1,
 729                 [Have POSIX function getpwnam_r])
 730 else
 731         AC_CACHE_CHECK([for nonposix getpwnam_r],
 732                 ac_cv_func_nonposix_getpwnam_r,
 733                 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <pwd.h>]], [[char buffer[10000];
 734                         struct passwd pwd;
 735                         getpwnam_r ("", &pwd, buffer,
 736                                         sizeof (buffer));]])],
 737                         [ac_cv_func_nonposix_getpwnam_r=yes],
 738                         [ac_cv_func_nonposix_getpwnam_r=no])])
 739                 if test "$ac_cv_func_nonposix_getpwnam_r" = yes; then
 740                 AC_DEFINE(HAVE_NONPOSIX_GETPWNAM_R,1,
 741                         [Have non-POSIX function getpwnam_r])
 742         fi
 743 fi
 744
 745 dnl check for socklen_t
 746 AC_MSG_CHECKING(whether socklen_t is defined)
 747 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 748 #include <sys/types.h>
 749 #include <sys/socket.h>
 750 #include <netdb.h>
 751 ]], [[
 752 socklen_t foo;
 753 foo = 1;
 754 ]])],
 755 [dbus_have_socklen_t=yes],
 756 [dbus_have_socklen_t=no])
 757 AC_MSG_RESULT($dbus_have_socklen_t)
 758
 759 if test "x$dbus_have_socklen_t" = "xyes"; then
 760     AC_DEFINE(HAVE_SOCKLEN_T,1,[Have socklen_t type])
 761 fi
 762
 763 dnl check for writev header and writev function so we're
 764 dnl good to go if HAVE_WRITEV gets defined.
 765 AC_CHECK_HEADERS(sys/uio.h, [AC_CHECK_FUNCS(writev)])
 766
 767 dnl needed on darwin for NAME_MAX
 768 AC_CHECK_HEADERS(sys/syslimits.h)
 769
 770 dnl Make it easy to check if we have MSG_NOSIGNAL without actually having to include sys/socket.h
 771 AC_CHECK_DECLS([MSG_NOSIGNAL], [], [], [[ #include <sys/types.h>
 772 #include <sys/socket.h> ]])
 773
 774 dnl check for flavours of varargs macros (test from GLib)
 775 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 776 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[
 777 int a(int p1, int p2, int p3);
 778 #define call_a(...) a(1,__VA_ARGS__)
 779 call_a(2,3);
 780 ]])],
 781 [dbus_have_iso_c_varargs=yes],
 782 [dbus_have_iso_c_varargs=no])
 783 AC_MSG_RESULT($dbus_have_iso_c_varargs)
 784
 785 AC_MSG_CHECKING(for GNUC varargs macros)
 786 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[
 787 int a(int p1, int p2, int p3);
 788 #define call_a(params...) a(1,params)
 789 call_a(2,3);
 790 ]])],
 791 [dbus_have_gnuc_varargs=yes],
 792 [dbus_have_gnuc_varargs=no])
 793 AC_MSG_RESULT($dbus_have_gnuc_varargs)
 794
 795 dnl Output varargs tests
 796 if test x$dbus_have_iso_c_varargs = xyes; then
 797     AC_DEFINE(HAVE_ISO_VARARGS,1,[Have ISO C99 varargs macros])
 798 fi
 799 if test x$dbus_have_gnuc_varargs = xyes; then
 800     AC_DEFINE(HAVE_GNUC_VARARGS,1,[Have GNU-style varargs macros])
 801 fi
 802
 803 dnl Check for various credentials.
 804 AC_MSG_CHECKING(for struct cmsgcred)
 805 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 806 #include <sys/types.h>
 807 #include <sys/socket.h>
 808 ]], [[
 809 struct cmsgcred cred;
 810
 811 cred.cmcred_pid = 0;
 812 ]])],
 813 [dbus_have_struct_cmsgcred=yes],
 814 [dbus_have_struct_cmsgcred=no])
 815 AC_MSG_RESULT($dbus_have_struct_cmsgcred)
 816
 817 if test x$dbus_have_struct_cmsgcred = xyes; then
 818     AC_DEFINE(HAVE_CMSGCRED,1,[Have cmsgcred structure])
 819 fi
 820
 821 AC_CHECK_FUNCS(getpeerucred getpeereid)
 822
 823 AC_CHECK_FUNCS(pipe2 accept4)
 824
 825 #### Abstract sockets
 826
 827 if test x$enable_abstract_sockets = xauto; then
 828 AC_LANG_PUSH(C)
 829 warn_on_xcompile=no
 830 AC_CACHE_CHECK([abstract socket namespace],
 831                 ac_cv_have_abstract_sockets,
 832                 [AC_RUN_IFELSE([AC_LANG_PROGRAM(
 833 [[
 834 #include <sys/types.h>
 835 #include <stdlib.h>
 836 #include <string.h>
 837 #include <stdio.h>
 838 #include <sys/socket.h>
 839 #include <sys/un.h>
 840 #include <errno.h>
 841 ]],
 842 [[
 843   size_t slen;
 844   int listen_fd;
 845   struct sockaddr_un addr;
 846
 847   listen_fd = socket (PF_UNIX, SOCK_STREAM, 0);
 848
 849   if (listen_fd < 0)
 850     {
 851       fprintf (stderr, "socket() failed: %s\n", strerror (errno));
 852       exit (1);
 853     }
 854
 855   memset (&addr, '\0', sizeof (addr));
 856   addr.sun_family = AF_UNIX;
 857   strcpy (addr.sun_path, "X/tmp/dbus-fake-socket-path-used-in-configure-test");
 858   /* SUN_LEN uses strlen() so need to calculate it before adding \0 at the
 859    * beginning.
 860    */
 861   slen = SUN_LEN(&addr);
 862   addr.sun_path[0] = '\0'; /* this is what makes it abstract */
 863
 864   if (bind (listen_fd, (struct sockaddr*) &addr, slen) < 0)
 865     {
 866        fprintf (stderr, "Abstract socket namespace bind() failed: %s\n",
 867                 strerror (errno));
 868        exit (1);
 869     }
 870   else
 871     exit (0);
 872 ]])],
 873               [ac_cv_have_abstract_sockets=yes],
 874               [ac_cv_have_abstract_sockets=no],
 875               [
 876                 ac_cv_have_abstract_sockets=no
 877                 warn_on_xcompile=yes
 878               ]
 879 )])
 880 if test x$warn_on_xcompile = xyes ; then
 881   AC_MSG_WARN([Cannot check for abstract sockets when cross-compiling, please use --enable-abstract-sockets])
 882 fi
 883 AC_LANG_POP(C)
 884 fi
 885
 886 if test x$enable_abstract_sockets = xyes; then
 887     if test x$ac_cv_have_abstract_sockets = xno; then
 888         AC_MSG_ERROR([Abstract sockets explicitly required, and support not detected.])
 889     fi
 890 fi
 891
 892 if test x$enable_abstract_sockets = xno; then
 893    ac_cv_have_abstract_sockets=no;
 894 fi
 895
 896 if test x$ac_cv_have_abstract_sockets = xyes ; then
 897    DBUS_PATH_OR_ABSTRACT=abstract
 898    AC_DEFINE(HAVE_ABSTRACT_SOCKETS,1,[Have abstract socket namespace])
 899 else
 900    DBUS_PATH_OR_ABSTRACT=path
 901 fi
 902
 903 # this is used in addresses to prefer abstract, e.g.
 904 # unix:path=/foo or unix:abstract=/foo
 905 AC_SUBST(DBUS_PATH_OR_ABSTRACT)
 906
 907 PKG_PROG_PKG_CONFIG
 908
 909 #### Sort out XML library
 910
 911 # see what we have
 912 AC_CHECK_LIB(expat, XML_ParserCreate_MM,
 913              [ AC_CHECK_HEADERS(expat.h, have_expat=true, have_expat=false) ],
 914              have_expat=false)
 915
 916 # see what we want to use
 917 dbus_use_libxml=false
 918 dbus_use_expat=false
 919 if test x$with_xml = xexpat; then
 920         if ! $have_expat ; then
 921            AC_MSG_ERROR([Explicitly requested expat but expat not found])
 922         fi
 923         dbus_use_expat=true
 924 elif test x$with_xml = xlibxml; then
 925         PKG_CHECK_MODULES(LIBXML, libxml-2.0 >= 2.6.0, have_libxml=true, have_libxml=false)
 926         if ! $have_libxml ; then
 927            AC_MSG_ERROR([Explicitly requested libxml but libxml not found])
 928         fi
 929         dbus_use_libxml=true
 930 else
 931         ### expat is the default because libxml can't currently survive
 932         ### our brutal OOM-handling unit test setup.
 933         ### http://bugzilla.gnome.org/show_bug.cgi?id=109368
 934         if test x$have_expat = xfalse; then
 935                 AC_MSG_ERROR([Could not find expat.h, check config.log for failed attempts])
 936         fi
 937         ### By default, only use Expat since it's tested and known to work.  If you're a
 938         ### general-purpose OS vendor, please don't enable libxml.  For embedded use
 939         ### if your OS is built around libxml, that's another case.
 940         dbus_use_expat=true
 941 fi
 942
 943 AM_CONDITIONAL(DBUS_USE_EXPAT, $dbus_use_expat)
 944 AM_CONDITIONAL(DBUS_USE_LIBXML, $dbus_use_libxml)
 945
 946 if $dbus_use_expat; then
 947    XML_LIBS=-lexpat
 948    XML_CFLAGS=
 949 fi
 950 if $dbus_use_libxml; then
 951    XML_LIBS=$LIBXML_LIBS
 952    XML_CFLAGS=$LIBXML_CFLAGS
 953 fi
 954 AC_SUBST([XML_CFLAGS])
 955 AC_SUBST([XML_LIBS])
 956
 957 # Thread lib detection
 958 AC_CHECK_FUNC(pthread_cond_timedwait,[AC_CHECK_LIB(pthread,pthread_cond_timedwait,
 959                                                     [THREAD_LIBS="-lpthread"])])
 960 save_libs="$LIBS"
 961 LIBS="$LIBS $THREAD_LIBS"
 962 AC_CHECK_FUNC(pthread_condattr_setclock,have_pthread_condattr_setclock=true,have_pthread_condattr_setclock=false)
 963 if test x$have_pthread_condattr_setclock = xtrue; then
 964     AC_SEARCH_LIBS([clock_getres],[rt],[THREAD_LIBS="$THREAD_LIBS -lrt"])
 965     AC_MSG_CHECKING([for CLOCK_MONOTONIC])
 966     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>
 967 #include <pthread.h>
 968 ]], [[
 969 struct timespec monotonic_timer;
 970 pthread_condattr_t attr;
 971 pthread_condattr_init (&attr);
 972 pthread_condattr_setclock (&attr, CLOCK_MONOTONIC);
 973 clock_getres (CLOCK_MONOTONIC,&monotonic_timer);
 974 ]])],
 975 [have_clock_monotonic=true],
 976 [have_clock_monotonic=false])
 977 if test x$have_clock_monotonic = xtrue; then
 978     AC_MSG_RESULT([found])
 979     AC_DEFINE(HAVE_MONOTONIC_CLOCK, 1, [Define if we have CLOCK_MONOTONIC])
 980 else
 981     AC_MSG_RESULT([not found])
 982 fi
 983 fi
 984 LIBS="$save_libs"
 985
 986 AC_SUBST([THREAD_LIBS])
 987
 988 # SELinux detection
 989 if test x$enable_selinux = xno ; then
 990     have_selinux=no;
 991 else
 992     # See if we have SELinux library
 993     AC_CHECK_LIB(selinux, is_selinux_enabled,
 994                  have_selinux=yes, have_selinux=no)
 995
 996     # see if we have the SELinux header with the new D-Bus stuff in it
 997     if test x$have_selinux = xyes ; then
 998         AC_MSG_CHECKING([for DBUS Flask permissions in selinux/av_permissions.h])
 999         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <selinux/av_permissions.h>]],
1000                           [[#ifdef DBUS__ACQUIRE_SVC return 0;
1001                             #else
1002                             #error DBUS__ACQUIRE_SVC not defined
1003                             #endif]])],
1004                           [have_selinux=yes],
1005                           [have_selinux=no])
1006         AC_MSG_RESULT($have_selinux)
1007     fi
1008
1009     if test x$enable_selinux = xauto ; then
1010         if test x$have_selinux = xno ; then
1011                 AC_MSG_WARN([Sufficiently new SELinux library not found])
1012         fi
1013     else
1014         if test x$have_selinux = xno ; then
1015                 AC_MSG_ERROR([SElinux explicitly required, and SELinux library not found])
1016         fi
1017     fi
1018 fi
1019
1020 AM_CONDITIONAL(HAVE_SELINUX, test x$have_selinux = xyes)
1021
1022 if test x$have_selinux = xyes ; then
1023     # the selinux code creates threads
1024     # which requires libpthread even on linux
1025     AC_CHECK_FUNC(pthread_create,,[AC_CHECK_LIB(pthread,pthread_create,
1026                                                 [SELINUX_THREAD_LIBS="-lpthread"])])
1027
1028     SELINUX_LIBS="-lselinux $SELINUX_THREAD_LIBS"
1029     AC_DEFINE(HAVE_SELINUX,1,[SELinux support])
1030 else
1031     SELINUX_LIBS=
1032 fi
1033
1034 # inotify checks
1035 if test x$enable_inotify = xno ; then
1036     have_inotify=no;
1037 else
1038     AC_CHECK_HEADERS(sys/inotify.h, have_inotify=yes, have_inotify=no)
1039 fi
1040
1041 dnl check if inotify backend is enabled
1042 if test x$have_inotify = xyes; then
1043    AC_DEFINE(DBUS_BUS_ENABLE_INOTIFY,1,[Use inotify])
1044    AC_CHECK_FUNCS(inotify_init1)
1045 fi
1046
1047 AM_CONDITIONAL(DBUS_BUS_ENABLE_INOTIFY, test x$have_inotify = xyes)
1048
1049 # dnotify checks
1050 if test x$enable_dnotify = xno ; then
1051     have_dnotify=no;
1052 else
1053     if test x$have_inotify = xno -a x$host_os = xlinux-gnu -o x$host_os = xlinux; then
1054         have_dnotify=yes;
1055     else
1056         have_dnotify=no;
1057     fi
1058 fi
1059
1060 dnl check if dnotify backend is enabled
1061 if test x$have_dnotify = xyes; then
1062    AC_DEFINE(DBUS_BUS_ENABLE_DNOTIFY_ON_LINUX,1,[Use dnotify on Linux])
1063 fi
1064
1065 AM_CONDITIONAL(DBUS_BUS_ENABLE_DNOTIFY_ON_LINUX, test x$have_dnotify = xyes)
1066
1067 # For simplicity, we require the userland API for epoll_create1 at
1068 # compile-time (glibc 2.9), but we'll run on kernels that turn out
1069 # not to have it at runtime.
1070 AC_ARG_ENABLE([epoll],
1071               [AS_HELP_STRING([--enable-epoll],[use epoll(4) on Linux])],
1072               [enable_epoll=$enableval], [enable_epoll=auto])
1073 if test x$enable_epoll = xno; then
1074     have_linux_epoll=no
1075 else
1076     AC_MSG_CHECKING([for Linux epoll(4)])
1077     AC_LINK_IFELSE([AC_LANG_PROGRAM(
1078         [
1079         #ifndef __linux__
1080         #error This is not Linux
1081         #endif
1082         #include <sys/epoll.h>
1083         ],
1084         [epoll_create1 (EPOLL_CLOEXEC);])],
1085         [have_linux_epoll=yes],
1086         [have_linux_epoll=no])
1087     AC_MSG_RESULT([$have_linux_epoll])
1088 fi
1089 if test x$enable_epoll,$have_linux_epoll = xyes,no; then
1090     AC_MSG_ERROR([epoll support explicitly enabled but not available])
1091 fi
1092 if test x$have_linux_epoll = xyes; then
1093   AC_DEFINE([DBUS_HAVE_LINUX_EPOLL], 1, [Define to use epoll(4) on Linux])
1094 fi
1095 AM_CONDITIONAL([HAVE_LINUX_EPOLL], [test x$have_linux_epoll = xyes])
1096
1097 # kqueue checks
1098 if test x$enable_kqueue = xno ; then
1099     have_kqueue=no
1100 else
1101     have_kqueue=yes
1102     AC_CHECK_HEADER(sys/event.h, , have_kqueue=no)
1103     AC_CHECK_FUNC(kqueue, , have_kqueue=no)
1104
1105     if test x$enable_kqueue = xyes -a x$have_kqueue = xno; then
1106         AC_MSG_ERROR(kqueue support explicitly enabled but not available)
1107     fi
1108 fi
1109
1110 dnl check if kqueue backend is enabled
1111 if test x$have_kqueue = xyes; then
1112    AC_DEFINE(DBUS_BUS_ENABLE_KQUEUE,1,[Use kqueue])
1113 fi
1114
1115 AM_CONDITIONAL(DBUS_BUS_ENABLE_KQUEUE, test x$have_kqueue = xyes)
1116
1117 # launchd checks
1118 if test x$enable_launchd = xno ; then
1119     have_launchd=no
1120 else
1121     have_launchd=yes
1122     AC_CHECK_HEADER([launch.h], , have_launchd=no)
1123     AC_PATH_PROG([LAUNCHCTL], [launchctl])
1124     if test "x$LAUNCHCTL" = "x"; then
1125         have_launchd=no
1126     fi
1127
1128     if test x$enable_launchd = xyes && test x$have_launchd = xno ; then
1129         AC_MSG_ERROR([launchd support explicitly enabled but not available])
1130     fi
1131 fi
1132
1133 dnl check if launchd is enabled
1134 if test x$have_launchd = xyes; then
1135     AC_DEFINE(DBUS_ENABLE_LAUNCHD,1,[Use launchd autolaunch])
1136 fi
1137
1138 AM_CONDITIONAL(DBUS_ENABLE_LAUNCHD, test x$have_launchd = xyes)
1139
1140 #### Directory to place launchd agent file
1141 if test "x$with_launchd_agent_dir" = "x"; then
1142    LAUNCHD_AGENT_DIR="/Library/LaunchAgents"
1143 else
1144    LAUNCHD_AGENT_DIR="$with_launchd_agent_dir"
1145 fi
1146
1147 AC_SUBST(LAUNCHD_AGENT_DIR)
1148
1149 dnl console owner file
1150 if test x$enable_console_owner_file = xno ; then
1151     have_console_owner_file=no;
1152 else
1153     case $host_os in
1154     solaris*)
1155         have_console_owner_file=yes;
1156         AC_DEFINE(HAVE_CONSOLE_OWNER_FILE,1,[Have console owner file])
1157         ;;
1158     *)
1159         have_console_owner_file=no;;
1160     esac
1161 fi
1162
1163 AM_CONDITIONAL(HAVE_CONSOLE_OWNER_FILE, test x$have_console_owner_file = xyes)
1164
1165 dnl systemd detection
1166 if test x$enable_systemd = xno ; then
1167     have_systemd=no;
1168 else
1169     PKG_CHECK_MODULES(SYSTEMD,
1170         [libsystemd-login >= 32, libsystemd-daemon >= 32],
1171         have_systemd=yes,
1172         have_systemd=no)
1173 fi
1174
1175 if test x$have_systemd = xyes; then
1176     AC_DEFINE(HAVE_SYSTEMD,1,[Have systemd])
1177 fi
1178
1179 if test x$enable_systemd = xyes -a x$have_systemd != xyes ; then
1180     AC_MSG_ERROR([Explicitly requested systemd support, but systemd not found])
1181 fi
1182
1183 # libaudit detection
1184 if test x$enable_libaudit = xno ; then
1185     have_libaudit=no;
1186 else
1187     # See if we have audit daemon & capabilities library
1188     AC_CHECK_LIB(audit, audit_log_user_avc_message,
1189                  have_libaudit=yes, have_libaudit=no)
1190     if test x$have_libaudit = xyes ; then
1191         AC_CHECK_LIB(cap-ng, capng_clear,
1192                  have_libaudit=yes, have_libaudit=no)
1193     fi
1194 fi
1195
1196 AM_CONDITIONAL(HAVE_LIBAUDIT, test x$have_libaudit = xyes)
1197
1198 if test x$have_libaudit = xyes ; then
1199     SELINUX_LIBS="$SELINUX_LIBS -laudit -lcap-ng"
1200     AC_DEFINE(HAVE_LIBAUDIT,1,[audit daemon SELinux support])
1201 fi
1202
1203 AC_SUBST([SELINUX_LIBS])
1204
1205 # Check for ADT API (Solaris Basic Security Mode auditing)
1206 AC_MSG_CHECKING(for ADT API)
1207 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1208 #include <bsm/adt.h>
1209 adt_user_context = ADT_USER;
1210 ]], [[]])], [ check_adt_audit=yes ], [ check_adt_audit=no ])
1211
1212 if test ${check_adt_audit} = yes
1213 then
1214    AC_DEFINE([HAVE_ADT], [], [Adt audit API])
1215    ADT_LIBS="-lbsm"
1216    LIBS="-lbsm $LIBS"
1217    AC_MSG_RESULT(yes)
1218 else
1219    AC_MSG_RESULT(no)
1220 fi
1221 AC_SUBST([ADT_LIBS])
1222
1223 # Check for SCM_RIGHTS
1224 AC_MSG_CHECKING([for SCM_RIGHTS])
1225 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1226 #include <sys/types.h>
1227 #include <sys/socket.h>
1228 #include <sys/un.h>
1229 static int x = SCM_RIGHTS;
1230 ]], [[]])],
1231 [ AC_MSG_RESULT([supported])
1232   AC_DEFINE([HAVE_UNIX_FD_PASSING], [1], [Supports sending UNIX file descriptors]) ],
1233 [ AC_MSG_RESULT([not supported]) ])
1234
1235 NETWORK_libs=
1236 if test x$dbus_win = xyes ; then
1237   if test x$dbus_wince = xyes ; then
1238     NETWORK_libs="-lws2"
1239   else
1240     NETWORK_libs="-lws2_32"
1241   fi
1242 fi
1243
1244 AC_SUBST([NETWORK_libs])
1245
1246 AC_ARG_WITH([valgrind],
1247   [AS_HELP_STRING([--with-valgrind],
1248      [Add instrumentation to help valgrind to understand our allocator])],
1249   [],
1250   [with_valgrind=no])
1251
1252 if test x$with_valgrind != xno; then
1253   PKG_CHECK_MODULES([VALGRIND], [valgrind >= 3.6])
1254   AC_DEFINE([WITH_VALGRIND], [1], [Define to add Valgrind instrumentation])
1255 fi
1256
1257 #### Set up final flags
1258 LIBDBUS_LIBS="$THREAD_LIBS $NETWORK_libs"
1259 AC_SUBST([LIBDBUS_LIBS])
1260
1261 ### X11 detection
1262 DBUS_X_LIBS=
1263 DBUS_X_CFLAGS=
1264
1265 AC_ARG_ENABLE([x11-autolaunch],
1266   AS_HELP_STRING([--enable-x11-autolaunch], [build with X11 auto-launch support]),
1267   [], [enable_x11_autolaunch=auto])
1268
1269 if test "x$dbus_win" = xyes; then
1270     if test "x$enable_x11_autolaunch" = xyes; then
1271         AC_MSG_ERROR([X11 auto-launch is not supported on Windows])
1272     fi
1273
1274     enable_x11_autolaunch=no
1275     have_x11=no
1276 else
1277     AC_PATH_XTRA
1278
1279     if test "x$no_x" = xyes; then
1280         have_x11=no
1281     else
1282         have_x11=yes
1283         DBUS_X_LIBS="$X_LIBS $X_PRE_LIBS -lX11 $X_EXTRA_LIBS"
1284         DBUS_X_CFLAGS="$X_CFLAGS"
1285     fi
1286 fi
1287
1288 if test "x$enable_x11_autolaunch,$have_x11" = xyes,no; then
1289     AC_MSG_ERROR([X11 auto-launch requires X headers/libraries])
1290 else
1291     # move from "auto" to "yes" or "no" if necessary
1292     if test "x$enable_x11_autolaunch" != xno; then
1293         enable_x11_autolaunch="$have_x11"
1294     fi
1295 fi
1296
1297 if test "x$have_x11" = xyes ; then
1298    AC_DEFINE([DBUS_BUILD_X11], [1], [Define to build X11 functionality])
1299 fi
1300
1301 if test "x$enable_x11_autolaunch" = xyes ; then
1302    AC_DEFINE([DBUS_ENABLE_X11_AUTOLAUNCH], [1], [Define to enable X11 auto-launch])
1303 fi
1304
1305 AC_SUBST([DBUS_X_CFLAGS])
1306 AC_SUBST([DBUS_X_LIBS])
1307
1308 #### gcc warning flags
1309
1310 cc_supports_flag() {
1311   AC_MSG_CHECKING(whether $CC supports "$*")
1312   save_CFLAGS="$CFLAGS"
1313   CFLAGS="$*"
1314   AC_TRY_COMPILE([], [], [rc=yes], [rc=no])
1315   CFLAGS="$save_CFLAGS"
1316   AC_MSG_RESULT([$rc])
1317   test "x$rc" = xyes
1318 }
1319
1320 TP_COMPILER_WARNINGS([WARNING_CFLAGS],
1321   dnl Use -Werror by default if:
1322   dnl - we're not on Windows (too many warnings), and
1323   dnl - we're in developer mode (a D-Bus developer, not a distro or end-user)
1324   dnl Override with --enable-Werror or --disable-Werror
1325   [test x$dbus_win != xyes -a x$dbus_cygwin != xyes -a x$enable_developer = xyes],
1326
1327   dnl Enable these warnings if possible:
1328   [all \
1329    extra \
1330    char-subscripts \
1331    missing-declarations \
1332    missing-prototypes \
1333    nested-externs \
1334    pointer-arith \
1335    cast-align \
1336    no-address \
1337    float-equal \
1338    declaration-after-statement \
1339   ],
1340
1341   dnl Disable these warnings if possible, make them non-fatal if possible,
1342   dnl and don't enable -Werror unless we succeeded.
1343   dnl
1344   dnl Intentional:
1345   dnl - $DISABLE_UNUSED_WARNINGS disables unused-label warnings if not
1346   dnl   checking or not asserting
1347   dnl - missing field initializers being 0 is a C feature, not a bug
1348   dnl - unused-parameter is to make writing callbacks less annoying
1349   dnl
1350   dnl To be fixed one day:
1351   dnl - sign-compare and pointer-sign are workarounds for fd.o #17433
1352   dnl - type-limits is probably a bug too, but having the rest of -Wextra
1353   dnl   is better than nothing
1354   [$DISABLE_UNUSED_WARNINGS \
1355    missing-field-initializers \
1356    unused-parameter \
1357    sign-compare \
1358    pointer-sign \
1359    type-limits \
1360   ])
1361
1362 if test "x$GCC" = "xyes"; then
1363   # We're treating -fno-common like a warning: it makes the linker more
1364   # strict, because on some systems the linker is *always* this strict
1365   TP_ADD_COMPILER_FLAG([WARNING_CFLAGS], [-fno-common])
1366
1367   # http://bugs.freedesktop.org/show_bug.cgi?id=10599
1368   TP_ADD_COMPILER_FLAG([WARNING_CFLAGS], [-fno-strict-aliasing])
1369
1370   if test "x$enable_ansi" = "xyes"; then
1371     TP_ADD_COMPILER_FLAG([WARNING_CFLAGS],
1372       [-ansi -D_POSIX_C_SOURCE=199309L -D_BSD_SOURCE -pedantic])
1373   fi
1374 fi
1375
1376 dnl In principle we should put WARNING_CFLAGS in each Makefile.am like
1377 dnl telepathy-glib does, since CFLAGS is meant to be reserved for the user...
1378 dnl but prepending to CFLAGS (so the user can override it with later CFLAGS)
1379 dnl is the next best thing
1380 CFLAGS="$WARNING_CFLAGS $CFLAGS"
1381
1382 case $host_os in
1383     solaris*)
1384         # Solaris' C library apparently needs these runes to be threadsafe...
1385         CFLAGS="$CFLAGS -D_POSIX_PTHREAD_SEMANTICS -D_REENTRANT"
1386         # ... this opt-in to get sockaddr_in6 and sockaddr_storage...
1387         CFLAGS="$CFLAGS -D__EXTENSIONS__"
1388         # ... and this opt-in to get file descriptor passing support
1389         CFLAGS="$CFLAGS -D_XOPEN_SOURCE=500"
1390         ;;
1391 esac
1392
1393 ### Doxygen Documentation
1394
1395 AC_PATH_PROG(DOXYGEN, doxygen, no)
1396
1397 AC_MSG_CHECKING([whether to build Doxygen documentation])
1398
1399 if test x$DOXYGEN = xno ; then
1400     have_doxygen=no
1401 else
1402     have_doxygen=yes
1403 fi
1404
1405 if test x$enable_doxygen_docs = xauto ; then
1406     if test x$have_doxygen = xno ; then
1407         enable_doxygen_docs=no
1408     else
1409         enable_doxygen_docs=yes
1410     fi
1411 fi
1412
1413 if test x$enable_doxygen_docs = xyes; then
1414     if test x$have_doxygen = xno; then
1415         AC_MSG_ERROR([Building Doxygen docs explicitly required, but Doxygen not found])
1416     fi
1417 fi
1418
1419 AM_CONDITIONAL(DBUS_DOXYGEN_DOCS_ENABLED, test x$enable_doxygen_docs = xyes)
1420 AC_MSG_RESULT($enable_doxygen_docs)
1421
1422 AC_CHECK_PROGS([XSLTPROC], [xsltproc])
1423 AM_CONDITIONAL([DBUS_HAVE_XSLTPROC], [test "x$XSLTPROC" != "x"])
1424
1425 ### XML Documentation
1426
1427 AC_PATH_PROG(XMLTO, xmlto, no)
1428
1429 AC_MSG_CHECKING([whether to build XML documentation])
1430
1431 if test x$XMLTO = xno ; then
1432     have_xmlto=no
1433 else
1434     have_xmlto=yes
1435 fi
1436
1437 if test x$enable_xml_docs = xauto ; then
1438     if test x$have_xmlto = xno ; then
1439         enable_xml_docs=no
1440     else
1441         enable_xml_docs=yes
1442     fi
1443 fi
1444
1445 if test x$enable_xml_docs = xyes; then
1446     if test x$have_xmlto = xno; then
1447         AC_MSG_ERROR([Building XML docs explicitly required, but xmlto not found])
1448     fi
1449 fi
1450
1451 AM_CONDITIONAL(DBUS_XML_DOCS_ENABLED, test x$enable_xml_docs = xyes)
1452 AC_MSG_RESULT($enable_xml_docs)
1453
1454 AC_PATH_PROG([MAN2HTML], [man2html])
1455 AC_ARG_VAR([MAN2HTML], [Path to man2html (optional)])
1456 AM_CONDITIONAL(DBUS_HAVE_MAN2HTML, test x$MAN2HTML != x)
1457
1458 AM_CONDITIONAL(DBUS_CAN_UPLOAD_DOCS,
1459     test x$enable_doxygen_docs = xyes -a x$enable_xml_docs = xyes -a \
1460          x$MAN2HTML != x)
1461
1462 #### Have to go $localstatedir->$prefix/var->/usr/local/var
1463
1464 #### find the actual value for $prefix that we'll end up with
1465 ##   (I know this is broken and should be done in the Makefile, but
1466 ##    that's a major pain and almost nobody actually seems to care)
1467 AS_AC_EXPAND(EXPANDED_PREFIX, "$prefix")
1468 AS_AC_EXPAND(EXPANDED_LOCALSTATEDIR, "$localstatedir")
1469 AS_AC_EXPAND(EXPANDED_SYSCONFDIR, "$sysconfdir")
1470 AS_AC_EXPAND(EXPANDED_BINDIR, "$bindir")
1471 AS_AC_EXPAND(EXPANDED_LIBDIR, "$libdir")
1472 AS_AC_EXPAND(EXPANDED_LIBEXECDIR, "$libexecdir")
1473 AS_AC_EXPAND(EXPANDED_DATADIR, "$datadir")
1474
1475 #### Check our operating system
1476 operating_system=unknown
1477 if test -f /etc/redhat-release || test -f $EXPANDED_SYSCONFDIR/redhat-release ; then
1478    operating_system=redhat
1479 fi
1480
1481 if test -f /etc/slackware-version || test -f $EXPANDED_SYSCONFDIR/slackware-version ; then
1482    operating_system=slackware
1483 fi
1484
1485 if test -f /usr/bin/cygwin1.dll || test -f $EXPANDED_BINDIR/cygwin1.dll ; then
1486    operating_system=cygwin
1487 fi
1488
1489 #### Sort out init scripts
1490
1491 if test x$with_init_scripts = x; then
1492     case x$operating_system in
1493         xredhat)        with_init_scripts=redhat ;;
1494         xslackware)     with_init_scripts=slackware ;;
1495         xcygwin)        with_init_scripts=cygwin ;;
1496         *)                      with_init_scripts=none ;;
1497     esac
1498 fi
1499
1500 AM_CONDITIONAL(DBUS_INIT_SCRIPTS_RED_HAT, test x$with_init_scripts = xredhat)
1501 AM_CONDITIONAL(DBUS_INIT_SCRIPTS_SLACKWARE, test x$with_init_scripts = xslackware)
1502 AM_CONDITIONAL(DBUS_INIT_SCRIPTS_CYGWIN, test x$with_init_scripts = xcygwin)
1503
1504 ##### systemd unit files
1505 AC_ARG_WITH([systemdsystemunitdir],
1506 AS_HELP_STRING([--with-systemdsystemunitdir=DIR], [Directory for systemd service files]),
1507     [],
1508     [
1509     PKG_CHECK_EXISTS([systemd],
1510       [with_systemdsystemunitdir=$($PKG_CONFIG --variable=systemdsystemunitdir systemd)],
1511       [with_systemdsystemunitdir=no])
1512     ])
1513 if test "x$with_systemdsystemunitdir" != xno; then
1514    AC_SUBST([systemdsystemunitdir], [$with_systemdsystemunitdir])
1515 fi
1516 AM_CONDITIONAL(HAVE_SYSTEMD, [test -n "$with_systemdsystemunitdir" -a "x$with_systemdsystemunitdir" != xno ])
1517
1518 ##### Set up location for system bus socket
1519 if ! test -z "$with_system_socket"; then
1520    DBUS_SYSTEM_SOCKET=$with_system_socket
1521 else
1522    DBUS_SYSTEM_SOCKET=${EXPANDED_LOCALSTATEDIR}/run/dbus/system_bus_socket
1523 fi
1524
1525 AC_SUBST(DBUS_SYSTEM_SOCKET)
1526 AC_DEFINE_UNQUOTED(DBUS_SYSTEM_SOCKET,"$DBUS_SYSTEM_SOCKET",[The name of the socket the system bus listens on by default])
1527
1528 ## system bus only listens on local domain sockets, and never
1529 ## on an abstract socket (so only root can create the socket)
1530 DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="unix:path=$DBUS_SYSTEM_SOCKET"
1531 AC_SUBST(DBUS_SYSTEM_BUS_DEFAULT_ADDRESS)
1532 AC_DEFINE_UNQUOTED(DBUS_SYSTEM_BUS_DEFAULT_ADDRESS, "$DBUS_SYSTEM_BUS_DEFAULT_ADDRESS",[The default D-Bus address of the system bus])
1533
1534 #### Set up the pid file
1535 if ! test -z "$with_system_pid_file"; then
1536    DBUS_SYSTEM_PID_FILE=$with_system_pid_file
1537 elif test x$with_init_scripts = xredhat ; then
1538    DBUS_SYSTEM_PID_FILE=${EXPANDED_LOCALSTATEDIR}/run/messagebus.pid
1539 else
1540    DBUS_SYSTEM_PID_FILE=${EXPANDED_LOCALSTATEDIR}/run/dbus/pid
1541 fi
1542
1543 AC_SUBST(DBUS_SYSTEM_PID_FILE)
1544
1545 #### Directory to check for console ownership
1546 if ! test -z "$with_console_auth_dir"; then
1547    DBUS_CONSOLE_AUTH_DIR=$with_console_auth_dir
1548 else
1549    DBUS_CONSOLE_AUTH_DIR=/var/run/console/
1550 fi
1551
1552 AC_SUBST(DBUS_CONSOLE_AUTH_DIR)
1553 AC_DEFINE_UNQUOTED(DBUS_CONSOLE_AUTH_DIR, "$DBUS_CONSOLE_AUTH_DIR", [Directory to check for console ownerhip])
1554
1555 #### File to check for console ownership
1556 if test x$have_console_owner_file = xyes; then
1557    if ! test -z "$with_console_owner_file"; then
1558       DBUS_CONSOLE_OWNER_FILE=$with_console_owner_file
1559    else
1560       DBUS_CONSOLE_OWNER_FILE=/dev/console
1561    fi
1562 else
1563   DBUS_CONSOLE_OWNER_FILE=
1564 fi
1565
1566 AC_SUBST(DBUS_CONSOLE_OWNER_FILE)
1567 AC_DEFINE_UNQUOTED(DBUS_CONSOLE_OWNER_FILE, "$DBUS_CONSOLE_OWNER_FILE", [File to check for console ownerhip])
1568
1569 #### User to start the system bus as
1570 if test -z "$with_dbus_user" ; then
1571     DBUS_USER=messagebus
1572 else
1573     DBUS_USER=$with_dbus_user
1574 fi
1575 AC_SUBST(DBUS_USER)
1576 AC_DEFINE_UNQUOTED(DBUS_USER,"$DBUS_USER", [User for running the system BUS daemon])
1577
1578 #### Prefix to install into
1579 DBUS_PREFIX=$EXPANDED_PREFIX
1580 AC_SUBST(DBUS_PREFIX)
1581 AC_DEFINE_UNQUOTED(DBUS_PREFIX,"$DBUS_PREFIX", [Prefix for installing DBUS])
1582
1583 #### Direcotry to install data files into
1584 DBUS_DATADIR=$EXPANDED_DATADIR
1585 AC_SUBST(DBUS_DATADIR)
1586 AC_DEFINE_UNQUOTED(DBUS_DATADIR,"$DBUS_DATADIR", [Directory for installing DBUS data files])
1587
1588 #### Directory to install dbus-daemon
1589 if test -z "$with_dbus_daemondir" ; then
1590     DBUS_DAEMONDIR=$EXPANDED_BINDIR
1591 else
1592     DBUS_DAEMONDIR=$with_dbus_daemondir
1593 fi
1594 AC_SUBST(DBUS_DAEMONDIR)
1595 AC_DEFINE_UNQUOTED(DBUS_DAEMONDIR,"$DBUS_DAEMONDIR", [Directory for installing the DBUS daemon])
1596
1597 #### Directory to install the other binaries
1598 DBUS_BINDIR="$EXPANDED_BINDIR"
1599 AC_SUBST(DBUS_BINDIR)
1600 AC_DEFINE_UNQUOTED(DBUS_BINDIR,"$DBUS_BINDIR", [Directory for installing the binaries])
1601
1602 #### Directory to install the libexec binaries
1603 DBUS_LIBEXECDIR="$EXPANDED_LIBEXECDIR"
1604 AC_SUBST(DBUS_LIBEXECDIR)
1605 AC_DEFINE_UNQUOTED(DBUS_LIBEXECDIR,"$DBUS_LIBEXECDIR", [Directory for installing the libexec binaries])
1606
1607 #### Tell tests where to find certain stuff in builddir
1608
1609 DBUS_PWD=`pwd`
1610 # Useful in a cross-compilation environment, where the tests are run on the host system.
1611 AC_ARG_WITH(dbus-test-dir, AS_HELP_STRING([--with-dbus-test-dir=[dirname]],[path where the tests tools are available]),
1612                            DBUS_PWD=$withval)
1613
1614 DBUS_TEST_EXEC="$DBUS_PWD/test"
1615 DBUS_TEST_DATA="$DBUS_PWD/test/data"
1616
1617 AC_SUBST([DBUS_TEST_DATA])
1618 AC_SUBST([DBUS_TEST_EXEC])
1619
1620 AC_DEFINE_UNQUOTED([DBUS_TEST_EXEC], ["$DBUS_TEST_EXEC"],
1621                    [Full path to the daemon in the builddir])
1622 AC_DEFINE_UNQUOTED([DBUS_EXEEXT], ["$EXEEXT"],
1623                    [Extension for executables, typically empty or .exe])
1624
1625 AC_DEFINE_UNQUOTED(TEST_BUS_BINARY, ["$DBUS_PWD/bus/dbus-daemon$EXEEXT"],
1626                    [Full path to the daemon in the builddir])
1627 AC_SUBST(TEST_BUS_BINARY)
1628
1629 ## Export the non-setuid external helper
1630 TEST_LAUNCH_HELPER_BINARY="$DBUS_PWD/bus/dbus-daemon-launch-helper-test$EXEEXT"
1631 AC_SUBST(TEST_LAUNCH_HELPER_BINARY)
1632 AC_DEFINE_UNQUOTED(DBUS_TEST_LAUNCH_HELPER_BINARY, "$TEST_LAUNCH_HELPER_BINARY",
1633                    [Full path to the launch helper test program in the builddir])
1634
1635 #### Find socket directories
1636 if ! test -z "$TMPDIR" ; then
1637    DEFAULT_SOCKET_DIR=$TMPDIR
1638 elif ! test -z "$TEMP" ; then
1639    DEFAULT_SOCKET_DIR=$TEMP
1640 elif ! test -z "$TMP" ; then
1641    DEFAULT_SOCKET_DIR=$TMP
1642 else
1643    DEFAULT_SOCKET_DIR=/tmp
1644 fi
1645
1646 DEFAULT_SOCKET_DIR=`echo $DEFAULT_SOCKET_DIR | sed 's/+/%2B/g'`
1647
1648 if ! test -z "$with_test_socket_dir" ; then
1649    TEST_SOCKET_DIR="$with_test_socket_dir"
1650 else
1651    TEST_SOCKET_DIR=$DEFAULT_SOCKET_DIR
1652 fi
1653 AC_SUBST(TEST_SOCKET_DIR)
1654 AC_DEFINE_UNQUOTED(DBUS_TEST_SOCKET_DIR, "$TEST_SOCKET_DIR", [Where to put test sockets])
1655
1656 if test "x$dbus_unix" = xyes; then
1657   TEST_LISTEN="unix:tmpdir=$TEST_SOCKET_DIR"
1658 else
1659   TEST_LISTEN="tcp:host=localhost"
1660 fi
1661 AC_SUBST([TEST_LISTEN])
1662 AC_DEFINE_UNQUOTED([TEST_LISTEN], ["$TEST_LISTEN"],
1663   [Listening address for regression tests])
1664
1665 if ! test -z "$with_session_socket_dir" ; then
1666    DBUS_SESSION_SOCKET_DIR="$with_session_socket_dir"
1667 else
1668    DBUS_SESSION_SOCKET_DIR=$DEFAULT_SOCKET_DIR
1669 fi
1670 AC_DEFINE_UNQUOTED(DBUS_SESSION_SOCKET_DIR, "$DBUS_SESSION_SOCKET_DIR", [Where per-session bus puts its sockets])
1671 AC_SUBST(DBUS_SESSION_SOCKET_DIR)
1672
1673 if test x$dbus_win = xyes; then
1674         DBUS_SESSION_BUS_DEFAULT_ADDRESS="$with_dbus_session_bus_default_address"
1675 elif test x$have_launchd = xyes; then
1676         DBUS_SESSION_BUS_DEFAULT_ADDRESS="launchd:env=DBUS_LAUNCHD_SESSION_BUS_SOCKET"
1677 else
1678         DBUS_SESSION_BUS_DEFAULT_ADDRESS="unix:tmpdir=$DBUS_SESSION_SOCKET_DIR"
1679 fi
1680 AC_SUBST(DBUS_SESSION_BUS_DEFAULT_ADDRESS)
1681
1682 # darwin needs this to initialize the environment
1683 AC_CHECK_HEADERS(crt_externs.h)
1684 AC_CHECK_FUNC(_NSGetEnviron, [AC_DEFINE(HAVE_NSGETENVIRON, 1, [Define if your system needs _NSGetEnviron to set up the environment])])
1685 AH_VERBATIM(_DARWIN_ENVIRON,
1686 [
1687 #if defined(HAVE_NSGETENVIRON) && defined(HAVE_CRT_EXTERNS_H)
1688 # include <sys/time.h>
1689 # include <crt_externs.h>
1690 # define environ (*_NSGetEnviron())
1691 #endif
1692 ])
1693
1694 AC_ARG_ENABLE([stats],
1695   [AS_HELP_STRING([--enable-stats],
1696     [enable bus daemon usage statistics])],
1697   [], [enable_stats=no])
1698 if test "x$enable_stats" = xyes; then
1699   AC_DEFINE([DBUS_ENABLE_STATS], [1],
1700     [Define to enable bus daemon usage statistics])
1701 fi
1702
1703 AC_CONFIG_FILES([
1704 Doxyfile
1705 dbus/versioninfo.rc
1706 dbus/dbus-arch-deps.h
1707 bus/system.conf
1708 bus/session.conf
1709 bus/messagebus
1710 bus/messagebus-config
1711 bus/org.freedesktop.dbus-session.plist
1712 bus/rc.messagebus
1713 bus/dbus.service
1714 bus/dbus.socket
1715 Makefile
1716 dbus/Makefile
1717 bus/Makefile
1718 tools/Makefile
1719 test/Makefile
1720 test/name-test/Makefile
1721 doc/Makefile
1722 doc/dbus-daemon.1
1723 dbus-1.pc
1724 dbus-1-uninstalled.pc
1725 test/data/valid-config-files/debug-allow-all.conf
1726 test/data/valid-config-files/debug-allow-all-sha1.conf
1727 test/data/valid-config-files-system/debug-allow-all-pass.conf
1728 test/data/valid-config-files-system/debug-allow-all-fail.conf
1729 test/data/valid-service-files/org.freedesktop.DBus.TestSuite.PrivServer.service
1730 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteEchoService.service
1731 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteForkingEchoService.service
1732 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteSegfaultService.service
1733 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteShellEchoServiceSuccess.service
1734 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteShellEchoServiceFail.service
1735 test/data/valid-service-files-system/org.freedesktop.DBus.TestSuiteEchoService.service
1736 test/data/valid-service-files-system/org.freedesktop.DBus.TestSuiteSegfaultService.service
1737 test/data/valid-service-files-system/org.freedesktop.DBus.TestSuiteShellEchoServiceSuccess.service
1738 test/data/valid-service-files-system/org.freedesktop.DBus.TestSuiteShellEchoServiceFail.service
1739 test/data/invalid-service-files-system/org.freedesktop.DBus.TestSuiteNoExec.service
1740 test/data/invalid-service-files-system/org.freedesktop.DBus.TestSuiteNoUser.service
1741 test/data/invalid-service-files-system/org.freedesktop.DBus.TestSuiteNoService.service
1742 ])
1743 AC_OUTPUT
1744
1745 dnl ==========================================================================
1746 echo "
1747                     D-Bus $VERSION
1748                   ==============
1749
1750         prefix:                   ${EXPANDED_PREFIX}
1751         exec_prefix:              ${exec_prefix}
1752         libdir:                   ${EXPANDED_LIBDIR}
1753         libexecdir:               ${EXPANDED_LIBEXECDIR}
1754         bindir:                   ${EXPANDED_BINDIR}
1755         sysconfdir:               ${EXPANDED_SYSCONFDIR}
1756         localstatedir:            ${EXPANDED_LOCALSTATEDIR}
1757         datadir:                  ${EXPANDED_DATADIR}
1758         source code location:     ${srcdir}
1759         compiler:                 ${CC}
1760         cflags:                   ${CFLAGS}
1761         cppflags:                 ${CPPFLAGS}
1762         cxxflags:                 ${CXXFLAGS}
1763         64-bit int:               ${DBUS_INT64_TYPE}
1764         32-bit int:               ${DBUS_INT32_TYPE}
1765         16-bit int:               ${DBUS_INT16_TYPE}
1766         Doxygen:                  ${DOXYGEN:-not found}
1767         xmlto:                    ${XMLTO:-not found}
1768         man2html:                 ${MAN2HTML:-not found}"
1769
1770 echo "
1771         Rebuilding generated files: ${USE_MAINTAINER_MODE}
1772         gcc coverage profiling:   ${enable_compiler_coverage}
1773         Building embedded tests:  ${enable_embedded_tests}
1774         Building modular tests:   ${enable_modular_tests}
1775             - with GLib:          ${with_glib}
1776         Building verbose mode:    ${enable_verbose_mode}
1777         Building assertions:      ${enable_asserts}
1778         Building checks:          ${enable_checks}
1779         Building bus stats API:   ${enable_stats}
1780         Building SELinux support: ${have_selinux}
1781         Building inotify support: ${have_inotify}
1782         Building dnotify support: ${have_dnotify}
1783         Building kqueue support:  ${have_kqueue}
1784         Building systemd support: ${have_systemd}
1785         Building X11 code:        ${enable_x11}
1786         Building Doxygen docs:    ${enable_doxygen_docs}
1787         Building XML docs:        ${enable_xml_docs}
1788         Building cache support:   ${enable_userdb_cache}
1789         Building launchd support: ${have_launchd}
1790         Using XML parser:         ${with_xml}
1791         Init scripts style:       ${with_init_scripts}
1792         Abstract socket names:    ${ac_cv_have_abstract_sockets}
1793         System bus socket:        ${DBUS_SYSTEM_SOCKET}
1794         System bus address:       ${DBUS_SYSTEM_BUS_DEFAULT_ADDRESS}
1795         System bus PID file:      ${DBUS_SYSTEM_PID_FILE}
1796         Session bus address:      ${DBUS_SESSION_BUS_DEFAULT_ADDRESS}
1797         Console auth dir:         ${DBUS_CONSOLE_AUTH_DIR}
1798         Console owner file:       ${have_console_owner_file}
1799         Console owner file path:  ${DBUS_CONSOLE_OWNER_FILE}
1800         System bus user:          ${DBUS_USER}
1801         Session bus services dir: ${EXPANDED_DATADIR}/dbus-1/services
1802         'make check' socket dir:  ${TEST_SOCKET_DIR}
1803 "
1804 if test x$have_launchd = xyes; then
1805         echo "        launchd agent dir:        ${LAUNCHD_AGENT_DIR}"
1806 fi
1807 echo
1808
1809 if test x$enable_embedded_tests = xyes; then
1810         echo "NOTE: building with unit tests increases the size of the installed library and renders it insecure."
1811 fi
1812 if test x$enable_embedded_tests = xyes -a x$enable_asserts = xno; then
1813         echo "NOTE: building with embedded tests but without assertions means tests may not properly report failures (this configuration is only useful when doing something like profiling the tests)"
1814 fi
1815 if test x$enable_compiler_coverage = xyes; then
1816         echo "NOTE: building with coverage profiling is definitely for developers only."
1817 fi
1818 if test x$enable_verbose_mode = xyes; then
1819         echo "NOTE: building with verbose mode increases library size, may slightly increase security risk, and decreases performance."
1820 fi
1821 if test x$enable_asserts = xyes; then
1822         echo "NOTE: building with assertions increases library size and decreases performance."
1823 fi
1824 if test x$enable_checks = xno; then
1825         echo "NOTE: building without checks for arguments passed to public API makes it harder to debug apps using D-Bus, but will slightly decrease D-Bus library size and _very_ slightly improve performance."
1826 fi
1827 if test x$dbus_use_libxml = xtrue; then
1828         echo
1829         echo "WARNING: You have chosen to use libxml as your xml parser however this code path is not maintained by the D-Bus developers and if it breaks you get to keep the pieces.  If you have selected this option in err please reconfigure with expat (e.g. --with-xml=expat)."
1830 fi
1831
1832 if test "x$DBUS_HAVE_INT64" = x0; then
1833   AC_MSG_WARN([You have disabled 64-bit integers via --without-64-bit.
1834
1835   This removes parts of the standard D-Bus API and ABI (the 't' and 'x'
1836   typecodes, the dbus_int64_t and dbus_uint64_t types, etc.) and should only be
1837   used if your compiler lacks support for 64-bit integers. Please report a bug
1838   with details of your platform and compiler.
1839
1840   This option is likely to be removed in future, unless the D-Bus developers
1841   receive reports that it is still needed.
1842   ])
1843 fi