configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2
   3 # Copyright (C) 1995-2012 Free Software Foundation, Inc.
   4 #
   5 # This program is free software; you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 2, or (at your option)
   8 # any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  17
  18 AC_PREREQ([2.68])
  19 AC_INIT([GNU Automake], [1.11a], [bug-automake@gnu.org])
  20
  21 AC_CONFIG_SRCDIR([automake.in])
  22 AC_CONFIG_AUX_DIR([lib])
  23
  24 AM_SILENT_RULES([yes])
  25
  26 AC_CANONICAL_HOST
  27 AC_CANONICAL_BUILD
  28
  29 # Save the AUTOCONF setting before AM_INIT_AUTOMAKE overrides it; this
  30 # way we can run Autoconf tests from configure (or from the test
  31 # suite) without being bothered by `missing'.  Likewise for autom4te,
  32 # autoreconf, autoheader, and autoupdate.
  33 AC_SUBST([am_AUTOCONF], ["${AUTOCONF-autoconf}"])
  34 AC_SUBST([am_AUTOM4TE], ["${AUTOM4TE-autom4te}"])
  35 AC_SUBST([am_AUTORECONF], ["${AUTORECONF-autoreconf}"])
  36 AC_SUBST([am_AUTOHEADER], ["${AUTOHEADER-autoheader}"])
  37 AC_SUBST([am_AUTOUPDATE], ["${AUTOUPDATE-autoupdate}"])
  38
  39 dnl We call AC_PROG_CC in an unusual way, and only for use in our
  40 dnl testsuite, so also use `no-dependencies' and `no-define' among
  41 dnl the automake options to avoid bloating and potential problems.
  42 AM_INIT_AUTOMAKE([1.10a dist-xz filename-length-max=99 color-tests
  43                   parallel-tests silent-rules no-define no-dependencies])
  44
  45 # The API version is the base version.  We must guarantee
  46 # compatibility for all releases with the same API version.
  47 # Our current rule is that:
  48 # * All releases, including the prereleases, in an X.Y series
  49 #   are compatible.  So 1.5.1c is compatible with 1.5.
  50 # * Prereleases on the trunk are all incompatible -- 1.5b and 1.5c
  51 #   aren't the same.
  52 APIVERSION=`echo "$VERSION" | sed -e 's/^\([[0-9]]*\.[[0-9]]*[[a-z]]*\).*$/\1/'`
  53 AC_SUBST([APIVERSION])
  54
  55 AC_SUBST([pkgvdatadir], ["\${datadir}/$PACKAGE-$APIVERSION"])
  56 AC_SUBST([scriptdir], ["\${pkgvdatadir}"])
  57 AC_SUBST([amdir], ["\${pkgvdatadir}/am"])
  58 AC_SUBST([automake_acdir], ["\${datadir}/aclocal-$APIVERSION"])
  59 AC_SUBST([system_acdir], ["\${datadir}/aclocal"])
  60
  61 # $AUTOMAKE and $ACLOCAL are always run after a `cd $top_srcdir',
  62 # hence `.' is really what we want for perllibdir, libdir, and acdir.
  63 ACLOCAL="perllibdir=\"`pwd`/lib$PATH_SEPARATOR./lib\" \"`pwd`/aclocal\" --acdir=m4 -I m4"
  64 AUTOMAKE="perllibdir=\"`pwd`/lib$PATH_SEPARATOR./lib\" \"`pwd`/automake\" --libdir=lib"
  65
  66 AC_PATH_PROG([PERL], [perl])
  67 if test -z "$PERL"; then
  68    AC_MSG_ERROR([perl not found])
  69 fi
  70 # Save details about the selected perl interpreter in config.log.
  71 AM_RUN_LOG([$PERL --version])
  72 $PERL -e 'require 5.006;' || {
  73    AC_MSG_ERROR(
  74 [perl 5.6 or better is required; perl 5.8.2 or better
  75 is recommended.  If you have several perl versions
  76 installed, select the one Automake should use using
  77   ./configure PERL=/path/to/perl])
  78 }
  79
  80 # We require ithreads support, and version 5.7.2 for CLONE.
  81 AC_CACHE_CHECK([whether $PERL supports ithreads], [am_cv_prog_PERL_ithreads],
  82 [if $PERL -e '
  83     require 5.007_002;
  84     use Config;
  85     if ($Config{useithreads})
  86       {
  87         require threads;
  88         import threads;
  89         require Thread::Queue;
  90         import Thread::Queue;
  91         exit 0;
  92       }
  93     exit 1;' >&AS_MESSAGE_LOG_FD 2>&1
  94 then
  95   am_cv_prog_PERL_ithreads=yes
  96 else
  97   am_cv_prog_PERL_ithreads=no
  98 fi])
  99 if test $am_cv_prog_PERL_ithreads = yes; then
 100   PERL_THREADS=1;
 101 else
 102   PERL_THREADS=0;
 103 fi
 104 AC_SUBST([PERL_THREADS])
 105
 106 # The test suite will skip some tests if tex is absent.
 107 AC_CHECK_PROG([TEX], [tex], [tex])
 108 # Save details about the selected TeX program in config.log.
 109 # Redirect input from /dev/null, as TeX might otherwise hang waiting
 110 # for input from the terminal.
 111 AM_RUN_LOG([$TEX --version </dev/null])
 112
 113 # The test suite will skip some tests if no lex or yacc program is
 114 # available.
 115 # We don't use AC_PROG_LEX nor AC_PROG_YACC here because:
 116 #  1. we don't want flex (resp. bison) to be preferred to system lex
 117 #     (resp. system yacc);
 118 #  2. we don't want $LEX (resp. $YACC) to be defined to ':' (resp. 'yacc')
 119 #     by default;
 120 #  3. we prefer not to have the variables YFLAGS, LEX_OUTPUT_ROOT and
 121 #     LEXLIB to be calculated and/or AC_SUBST'd;
 122 #  4. we prefer that the YACC and LEX variables are not reported in the
 123 #     configure help screen.
 124 AC_CHECK_PROGS([YACC], [yacc byacc 'bison -y'], [false])
 125 AC_CHECK_PROGS([LEX], [lex flex], [false])
 126
 127 # Generate man pages.
 128 AM_MISSING_PROG([HELP2MAN], [help2man])
 129
 130 # Test for Autoconf.  We run Autoconf in a subdirectory to ease
 131 # deletion of any files created (such as those added to
 132 # autom4te.cache).  We used to perform only the last of the three
 133 # following tests, but some users were unable to figure out that their
 134 # installation was broken since --version appeared to work.
 135
 136 required_autoconf_version=2.62
 137 AC_CACHE_CHECK([whether autoconf is installed], [am_cv_autoconf_installed],
 138 [if AM_RUN_LOG([$am_AUTOCONF --version]);
 139 then
 140   am_cv_autoconf_installed=yes
 141 else
 142   am_cv_autoconf_installed=no
 143 fi])
 144 if test "$am_cv_autoconf_installed" = no; then
 145   AC_MSG_ERROR([Autoconf $required_autoconf_version or better is required.
 146     Please make sure it is installed and in your PATH.])
 147 fi
 148
 149 AC_CACHE_CHECK([whether autoconf works], [am_cv_autoconf_works],
 150 [mkdir conftest
 151 echo 'AC''_INIT' > conftest/conftest.ac
 152 if AM_RUN_LOG([cd conftest && $am_AUTOCONF -o /dev/null conftest.ac]);
 153 then
 154   am_cv_autoconf_works=yes
 155 else
 156   am_cv_autoconf_works=no
 157 fi
 158 rm -rf conftest])
 159 if test "$am_cv_autoconf_works" = no; then
 160   AC_MSG_ERROR([The installed version of autoconf does not work.
 161     Please check config.log for error messages before this one.])
 162 fi
 163
 164 AC_CACHE_CHECK([whether autoconf is recent enough], [am_cv_autoconf_version],
 165 [mkdir conftest
 166 dnl Creative quoting required to avoid spurious expansion of AC_PREREQ macro
 167 echo 'AC'"_PREREQ([[$required_autoconf_version]])" > conftest/conftest.ac
 168 if AM_RUN_LOG([cd conftest && $am_AUTOCONF -o /dev/null conftest.ac]);
 169 then
 170   am_cv_autoconf_version=yes
 171 else
 172   am_cv_autoconf_version=no
 173 fi
 174 rm -rf conftest])
 175 if test "$am_cv_autoconf_version" = no; then
 176   AC_MSG_ERROR([Autoconf $required_autoconf_version or better is required.])
 177 fi
 178
 179 # Test for ln.  We need use it to install the versioned binaries.
 180 AC_MSG_CHECKING([whether ln works])
 181 AC_CACHE_VAL([am_cv_prog_ln], [
 182 rm -f conftest conftest.file
 183 : >conftest.file
 184 if ln conftest.file conftest 2>/dev/null; then
 185   am_cv_prog_ln=ln
 186 else
 187   am_cv_prog_ln='cp -p'
 188 fi
 189 rm -f conftest conftest.file])
 190 AC_SUBST([LN], [$am_cv_prog_ln])
 191 result=no
 192 test "x$am_cv_prog_ln" = xln && result=yes
 193 AC_MSG_RESULT([$result])
 194
 195 # The amount we should wait after modifying files depends on the platform.
 196 # On Windows '95, '98 and ME, files modifications have 2-seconds
 197 # granularity and can be up to 3 seconds in the future w.r.t. the
 198 # system clock.  When it is important to ensure one file is older
 199 # than another we wait at least 5 seconds between creations.
 200 case $build in
 201   *-pc-msdosdjgpp) MODIFICATION_DELAY=5;;
 202   *)               MODIFICATION_DELAY=2;;
 203 esac
 204 AC_SUBST([MODIFICATION_DELAY])
 205
 206 # Test for things needed by the test suite.
 207 AC_PROG_EGREP
 208 AC_PROG_FGREP
 209
 210 AC_CACHE_CHECK([whether $SHELL has working 'set -e' with exit trap],
 211 [am_cv_sh_errexit_works],
 212 [if $SHELL -ec "trap 'exit \$?' 0; (exit 77); exit 77"; test $? = 77
 213 then
 214   am_cv_sh_errexit_works=yes
 215 else
 216   am_cv_sh_errexit_works=no
 217 fi
 218 ])
 219 if test $am_cv_sh_errexit_works = no; then
 220   AC_MSG_WARN([`${MAKE-make} check' will leave leftover directories tests/*.dir])
 221   AC_MSG_WARN([you can clean them up manually using `${MAKE-make} clean' or])
 222   AC_MSG_WARN([`cd tests && ${MAKE-make} clean-local-check'])
 223   dnl restore font-lock: `
 224 fi
 225 AC_SUBST([sh_errexit_works], [$am_cv_sh_errexit_works])
 226
 227
 228 ###########################################################################
 229
 230 # Look for C, C++ and fortran compilers to be used in the testsuite.
 231
 232 dnl We don't want to abort our configuration script if no C compiler is
 233 dnl available, as such a compiler is only required to run part of the
 234 dnl testsuite, not to build or install Automake.  Ditto for C++, Fortran
 235 dnl and Fortran 77 compilers.  Unfortunately, autoconf does not offer an
 236 dnl easy way to obtain this behaviour, so we'll need a few hacks.
 237
 238 dnl We want the body of this macro to expand as a single shell statement,
 239 dnl thus we wrap it into { ... } brackets.
 240 AC_DEFUN([_AM_WRAP_MSG_ERROR], [ {
 241   AC_MSG_WARN([$1])
 242   am__failed=yes
 243   break
 244 } ])
 245
 246 AC_DEFUN([_AM_COMPILER_CAN_FAIL], [
 247   m4_pushdef([AC_MSG_FAILURE], m4_defn([_AM_WRAP_MSG_ERROR]))
 248   m4_pushdef([AC_MSG_ERROR],   m4_defn([_AM_WRAP_MSG_ERROR]))
 249   am__failed=no
 250   while :; do
 251      $1
 252      break
 253   done
 254   AS_IF([test $am__failed = yes], [$2])
 255   # We have to clear these cache variables, so that future checks on
 256   # compilers for different languages won't be confused.
 257   unset ac_cv_objext ac_cv_exeext
 258   # We also need to meddle with the autoconf internals to ensure that
 259   # checks to find object and executable extensions will be run anew.
 260   # FIXME: In the long run, the better thing to do would be to fix
 261   # FIXME: autoconf instead ...
 262   m4_undefine([m4_provide(_AC_COMPILER_OBJEXT)])
 263   m4_undefine([m4_provide(_AC_COMPILER_EXEEXT)])
 264   m4_popdef([AC_MSG_FAILURE])
 265   m4_popdef([AC_MSG_ERROR])
 266 ])
 267
 268 # Prefer generic compilers to GNU ones when possible.  This will ensure
 269 # more testsuite coverage "in the wild".
 270 # Note that we don't look for the MSVC C/C++ compiler here.  This is
 271 # deliberate; for more discussion an rationale, see:
 272 # <http://lists.gnu.org/archive/html/automake-patches/2012-01/msg00130.html>
 273
 274 # C compiler.
 275 _AM_COMPILER_CAN_FAIL([AC_PROG_CC([cc gcc])], [CC=false])
 276 AS_IF([test x"$GCC" = x"yes"], [am_CC_is_GNU=yes], [am_CC_is_GNU=no])
 277
 278 # The list of C++ compilers here has been copied, pasted and edited
 279 # from `lib/autoconf/c.m4:AC_PROG_CXX' in the Autoconf distribution.
 280 # Keep it in sync, or better again, find out a way to avoid this code
 281 # duplication.
 282 _AM_COMPILER_CAN_FAIL([AC_PROG_CXX(dnl
 283   [aCC CC FCC KCC RCC xlC_r xlC c++ cxx cc++ gpp g++])],
 284   [CXX=false])
 285 AS_IF([test x"$GXX" = x"yes"], [am_CXX_is_GNU=yes], [am_CXX_is_GNU=no])
 286
 287 # The lists of Fortran compilers here has been copied, pasted and edited
 288 # from file `lib/autoconf/fortran.m4' in the Autoconf distribution.
 289 # Keep it in sync, or better again, find out a way to avoid this code
 290 # duplication.
 291
 292 _AM_COMPILER_CAN_FAIL([AC_PROG_FC(dnl
 293   [xlf95 f95 fort ifort ifc efc pgfortran pgf95 lf95 ftn nagfor] dnl
 294   [xlf90 f90 pgf90 pghpf epcf90 g95 gfortran])],
 295   [FC=false])
 296 # FIXME this won't work as expected until we can assume autoconf 2.69 :-(
 297 AS_IF([test x"$GFC" = x"yes"], [am_FC_is_GNU=yes], [am_FC_is_GNU=no])
 298
 299 _AM_COMPILER_CAN_FAIL([AC_PROG_F77(dnl
 300   [xlf f77 frt pgf77 cf77 fort77 fl32 af77 g77 gfortran])],
 301   [F77=false])
 302 AS_IF([test x"$G77" = x"yes"], [am_F77_is_GNU=yes], [am_F77_is_GNU=no])
 303
 304 # Some tests will need the GNU compilers.  Searching for them here would
 305 # be overkill, since our testsuite already handles their search and setup
 306 # pretty well.  However, in case the compilers detected above at configure
 307 # time are not the GNU ones, we cannot use the values of CFLAGS, CXXFLAGS,
 308 # FCFLAGS and FFLAGS detected for them with the GNU compilers too, since
 309 # it's likely they won't be compatible.  So we allow the user to define
 310 # variants of this variables for the GNU compilers separately.
 311
 312 test $am_CC_is_GNU = yes && GNU_CFLAGS=${GNU_CFLAGS-$CFLAGS}
 313 AC_ARG_VAR([GNU_CFLAGS], [GNU C compiler flags])
 314
 315 test $am_CXX_is_GNU = yes && GNU_CXXFLAGS=${GNU_CXXFLAGS-$CXXFLAGS}
 316 AC_ARG_VAR([GNU_CXXFLAGS], [GNU C++ compiler flags])
 317
 318 test $am_F77_is_GNU = yes && GNU_FCFLAGS=${GNU_FCFLAGS-$FCFLAGS}
 319 AC_ARG_VAR([GNU_FCFLAGS], [GNU Fortran compiler flags])
 320
 321 test $am_FC_is_GNU = yes && GNU_FFLAGS=${GNU_FFLAGS-$FFLAGS}
 322 AC_ARG_VAR([GNU_FFLAGS], [GNU Fortran 77 compiler flags])
 323
 324 # If we have been able to find at least a working compiler above, we
 325 # know what the object and executable extensions for this platform are.
 326 OBJEXT=${ac_cv_objext-UNKNOWN}
 327 EXEEXT=${ac_cv_exeext-UNKNOWN}
 328 AC_SUBST([OBJEXT])
 329 AC_SUBST([EXEEXT])
 330
 331 ###########################################################################
 332
 333 AC_CONFIG_FILES([
 334   Makefile
 335   contrib/Makefile
 336   doc/Makefile
 337   lib/Automake/Makefile
 338   lib/Makefile
 339   lib/am/Makefile
 340   m4/Makefile
 341   tests/Makefile
 342 ])
 343 AC_CONFIG_LINKS([GNUmakefile:GNUmakefile])
 344 AC_CONFIG_LINKS([tests/defs:tests/defs])
 345 AC_CONFIG_FILES([tests/aclocal-${APIVERSION}:tests/aclocal.in],
 346                 [chmod +x tests/aclocal-${APIVERSION}],
 347                 [APIVERSION=$APIVERSION])
 348 AC_CONFIG_FILES([tests/automake-${APIVERSION}:tests/automake.in],
 349                 [chmod +x tests/automake-${APIVERSION}])
 350
 351 AC_OUTPUT
 352
 353 # Inform the user if this version of automake is a beta release or
 354 # a development snapshot.
 355 # According to HACKING, the version of a development snapshot should
 356 # end with an "odd" letter (a, c, ...), the version of a test release
 357 # should end wit an "even" letter (b, d, ...).
 358
 359 am_stable_version_rx='[[1-9]\.[0-9]+(\.[0-9]+)?]'
 360 am_beta_version_rx="[$am_stable_version_rx[bdfhjlnprtvxz]]"
 361
 362 am_release_type=`AS_ECHO(["$PACKAGE_VERSION"]) | LC_ALL=C awk ["
 363   /^$am_stable_version_rx$/ { print \"stable\"; exit(0); }
 364   /^$am_beta_version_rx$/ { print \"beta version\"; exit(0); }
 365   { print \"development snapshot\"; }"]`
 366
 367 test "$am_release_type" = stable || cat <<EOF
 368
 369 WARNING: You are about to use a $am_release_type of automake.
 370 WARNING: It might easily suffer from new bugs or regressions.
 371 WARNING: You are strongly advised not to use it in production code.
 372
 373 Please report bugs, problems and feedback to <bug-automake@gnu.org>.
 374 EOF
 375
 376 AS_EXIT([0])