configure.ac

   1 # If not 1, append datestamp to the version number
   2 m4_define([folks_released], [0])
   3
   4 m4_define([folks_major_version], [0])
   5 m4_define([folks_minor_version], [5])
   6 m4_define([folks_micro_version], [2])
   7 m4_define([folks_nano_version], [1])
   8
   9 # If library source has changed since last release, increment revision
  10 # If interfaces have been added, removed or changed since last release,
  11 #  increment current and set revision to 0
  12 # If interfaces have been added since last release, increment age
  13 # If interfaces have been removed since last release, set age to 0
  14 m4_define([folks_lt_current], [24])
  15 m4_define([folks_lt_revision], [1])
  16 m4_define([folks_lt_age], [0])
  17
  18 # Display the nano_version only if it's not '0'
  19 m4_define([folks_base_version],
  20           folks_major_version.folks_minor_version.folks_micro_version)
  21 m4_define([folks_full_version],
  22           [m4_if(folks_nano_version, [0],
  23                  folks_base_version, folks_base_version.folks_nano_version)])
  24
  25 m4_define([folks_maybe_datestamp],
  26           m4_if(folks_released, [1],
  27                 [], [m4_esyscmd([date +.%Y%m%d | tr -d '\n\r'])]))
  28
  29 m4_define([folks_version], folks_full_version[]folks_maybe_datestamp)
  30 m4_define([folks_major_minor_version], folks_major_version.folks_minor_version)
  31 m4_define([folks_module_version], folks_lt_current)
  32
  33 AC_INIT([folks], folks_version,
  34         [https://bugzilla.gnome.org/browse.cgi?product=folks], [folks],
  35         [http://telepathy.freedesktop.org/wiki/Folks])
  36 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  37
  38 AC_PREREQ([2.65])
  39 AC_COPYRIGHT([Copyright (C) 2010 Collabora Ltd.])
  40
  41 AC_CONFIG_MACRO_DIR([m4])
  42 AC_CONFIG_SRCDIR([Makefile.am])
  43 AC_CONFIG_HEADERS(config.h)
  44 AC_CONFIG_SRCDIR([configure.ac])
  45 AM_INIT_AUTOMAKE([1.11 dist-bzip2 no-define
  46                   no-dist-gzip tar-ustar -Wno-portability])
  47 AM_MAINTAINER_MODE
  48
  49 AC_PROG_CC
  50 AM_PROG_CC_C_O
  51 AC_DISABLE_STATIC
  52 LT_INIT
  53 PKG_PROG_PKG_CONFIG([0.21])
  54
  55 AC_SUBST([CFLAGS])
  56 AC_SUBST([CPPFLAGS])
  57 AC_SUBST([LDFLAGS])
  58
  59 LT_CURRENT=folks_lt_current
  60 LT_REVISION=folks_lt_revision
  61 LT_AGE=folks_lt_age
  62 AC_SUBST([LT_CURRENT])
  63 AC_SUBST([LT_REVISION])
  64 AC_SUBST([LT_AGE])
  65
  66 FOLKS_MAJOR_MINOR_VERSION=folks_major_minor_version
  67 AC_SUBST([FOLKS_MAJOR_MINOR_VERSION])
  68
  69 API_VERSION=0.6
  70 AC_SUBST([API_VERSION])
  71
  72 AC_ARG_ENABLE(tracker-backend,
  73         AC_HELP_STRING([--enable-tracker-backend],
  74                        [ build the Tracker backend]),
  75         enable_tracker_backend=$enableval,
  76         enable_tracker_backend=no )
  77
  78 AM_CONDITIONAL([ENABLE_TRACKER], [test "x$enable_tracker_backend" = "xyes"])
  79
  80 # Automatically check the dependencies for the libsocialweb backend
  81 SW_CLIENT_REQUIRED=0.25.15
  82 AC_ARG_ENABLE(libsocialweb-backend,
  83         AC_HELP_STRING([--enable-libsocialweb-backend=@<:@no/yes/auto@:>@],
  84                        [build the Libsocialweb backend (default: auto)]),
  85         enable_libsocialweb_backend=$enableval,
  86         enable_libsocialweb_backend=auto )
  87
  88 if test "x$enable_libsocialweb_backend" != "xno"; then
  89   PKG_CHECK_MODULES([SW_CLIENT], [libsocialweb-client >= $SW_CLIENT_REQUIRED],
  90       have_libsocialweb_backend="yes", have_libsocialweb_backend="no")
  91   if test "x$have_libsocialweb_backend" = "xyes" -a \
  92           "x$enable_vala" = "xyes"; then
  93     VALA_CHECK_PACKAGES([telepathy-glib
  94                          gio-2.0
  95                          gee-1.0
  96                          libsocialweb-client],
  97         ,
  98         have_libsocialweb_backend="no")
  99   fi
 100
 101   if test "x$have_libsocialweb_backend" = "xyes"; then
 102     AC_DEFINE(HAVE_LIBSOCIALWEB, [],
 103               [Define if you have the libsocialweb backend])
 104   fi
 105 else
 106    have_libsocialweb_backend=no
 107 fi
 108
 109 if test "x$enable_libsocialweb_backend" = "xyes" -a \
 110   "x$have_libsocialweb_backend" != "xyes"; then
 111     AC_MSG_ERROR([Cannot find libsocialweb dependencies.])
 112 fi
 113
 114 AM_CONDITIONAL([ENABLE_LIBSOCIALWEB],
 115         [test "x$have_libsocialweb_backend" = "xyes"])
 116
 117 # -----------------------------------------------------------
 118 # Dependencies
 119 # -----------------------------------------------------------
 120
 121 GLIB_REQUIRED=2.24.0
 122 TP_GLIB_REQUIRED=0.13.1
 123 VALA_REQUIRED=0.12.0
 124 VALADOC_REQUIRED=0.2.1
 125 TRACKER_SPARQL_REQUIRED=0.10
 126 GCONF2_REQUIRED=2.31
 127
 128 PKG_CHECK_MODULES([GLIB],
 129                   [glib-2.0 >= $GLIB_REQUIRED
 130                    gobject-2.0 >= $GLIB_REQUIRED])
 131 PKG_CHECK_MODULES([GMODULE], [gmodule-no-export-2.0])
 132 PKG_CHECK_MODULES([GIO], [gio-2.0 >= $GLIB_REQUIRED])
 133 PKG_CHECK_MODULES([GCONF2], [gconf-2.0 >= $GCONF2_REQUIRED])
 134
 135 # FIXME: We depend on libgee < 0.7 because 0.7 breaks API. bgo#627746
 136 PKG_CHECK_MODULES([GEE], [gee-1.0 < 0.7])
 137 PKG_CHECK_MODULES([TP_GLIB], [telepathy-glib >= $TP_GLIB_REQUIRED])
 138
 139 if test x$enable_tracker_backend = xyes; then
 140         PKG_CHECK_MODULES([TRACKER_SPARQL],
 141                           [tracker-sparql-0.10 >= $TRACKER_SPARQL_REQUIRED])
 142 fi
 143
 144 #
 145 # Vala building options -- allows tarball builds without installing Vala
 146 #
 147 AC_ARG_ENABLE([vala],
 148               AS_HELP_STRING([--enable-vala],
 149                              [Enable building from the Vala sources]),
 150               [enable_vala=$enableval],
 151               [enable_vala=no])
 152
 153 # will be re-set as necessary below
 154 AM_CONDITIONAL([HAVE_INTROSPECTION], [test "x$enable_vala" = "xyes"])
 155 sd=${srcdir}/
 156
 157 # Force Vala for non-release builds
 158 m4_if(folks_released, [1], [],
 159     [
 160         enable_vala=yes
 161         echo "Vala compiler required for non-release builds; requiring Vala..."
 162     ])
 163
 164 # Force Vala if generated source is missing or outdated
 165 if test \
 166         ! -e ${sd}tools/folks_import_vala.stamp -o \
 167         ! -e ${sd}tests/folks/aggregation_vala.stamp -o \
 168         ! -e ${sd}tests/folks/backend_loading_vala.stamp -o \
 169         ! -e ${sd}tests/folks/field_details_vala.stamp -o \
 170         ! -e ${sd}tests/key-file/individual_retrieval_vala.stamp -o \
 171         ! -e ${sd}tests/lib/folks-test.vapi -o \
 172         ! -e ${sd}tests/lib/key-file/kf-test.vapi -o \
 173         ! -e ${sd}tests/lib/key-file/libkf_test_la_vala.stamp -o \
 174         ! -e ${sd}tests/lib/telepathy/contactlist/tp-test-contactlist.gir -o \
 175         ! -e ${sd}tests/lib/telepathy/contactlist/tp-test-contactlist.vapi -o \
 176         ! -e ${sd}tests/lib/libfolks_test_la_vala.stamp -o \
 177         ! -e ${sd}tests/telepathy/persona_store_capabilities_vala.stamp -o \
 178         ! -e ${sd}tests/telepathy/individual_retrieval_vala.stamp -o \
 179         ! -e ${sd}tests/telepathy/individual_properties_vala.stamp -o \
 180         ! -e ${sd}tests/folks/backend_loading_vala.stamp -o \
 181         ! -e ${sd}backends/key-file/libfolks_backend_key_file_la_vala.stamp -o \
 182         ! -e ${sd}backends/telepathy/libfolks_backend_telepathy_la_vala.stamp \
 183                 -o \
 184         ! -e ${sd}backends/telepathy/lib/folks-telepathy.vapi -o \
 185         ! -e ${sd}backends/telepathy/lib/tp-lowlevel.gir -o \
 186         ! -e ${sd}backends/telepathy/lib/tp-lowlevel.vapi -o \
 187         ! -e ${sd}backends/telepathy/lib/libfolks_telepathy_la_vala.stamp -o \
 188         ! -e ${sd}folks/folks.vapi -o \
 189         ! -e ${sd}folks/libfolks_la_vala.stamp ; then
 190         enable_vala=yes
 191         echo "Vala source needs to be re-compiled; requiring Vala..."
 192 fi
 193
 194 if test "x$enable_vala" = "xyes" ; then
 195         AM_PROG_VALAC([$VALA_REQUIRED])
 196         if test "x$VALAC" = "x"; then
 197               AC_MSG_ERROR([Vala requested but valac is not installed])
 198         fi
 199
 200         AC_PATH_PROG([VAPIGEN], [vapigen], [])
 201         if test "x$VAPIGEN" = "x"; then
 202               AC_MSG_ERROR([Vala must be built with --enable-vapigen])
 203         fi
 204
 205         # require GLib >= 2.24 so GLib.Array, etc. reffing is handled
 206         # automatically
 207         VALAFLAGS="$VALAFLAGS --target-glib=2.24"
 208         AC_SUBST([VALAFLAGS])
 209         AC_SUBST([VAPIGENFLAGS])
 210         AC_SUBST([VAPIDIR])
 211
 212         VALA_CHECK_PACKAGES([telepathy-glib
 213                              gio-2.0
 214                              gee-1.0])
 215
 216         if test x$enable_tracker_backend = xyes; then
 217           VALA_CHECK_PACKAGES([tracker-sparql-0.10])
 218         fi
 219
 220 fi
 221
 222 # this will set HAVE_INTROSPECTION
 223 GOBJECT_INTROSPECTION_REQUIRE([0.9.12])
 224
 225 AM_CONDITIONAL([HAVE_VALA], [test "x$enable_vala" = "xyes"])
 226
 227 # Various functions that we need (used in C code generated from Vala)
 228 AC_CHECK_FUNCS([memset])
 229 AC_CHECK_FUNCS([strstr])
 230
 231 # -----------------------------------------------------------
 232 # Backends
 233 # -----------------------------------------------------------
 234
 235 FOLKS_MODULE_VERSION=folks_module_version
 236 AC_SUBST([FOLKS_MODULE_VERSION])
 237 AC_DEFINE([MODULE_VERSION], "folks_module_version", [Module interface version])
 238
 239 BACKEND_DIR='$(libdir)/folks/$(FOLKS_MODULE_VERSION)/backends'
 240 AC_SUBST([BACKEND_DIR])
 241
 242 BACKEND_KF='$(top_builddir)/backends/key-file/.libs/libfolks-backend-key-file.so'
 243 AC_SUBST([BACKEND_KF])
 244 BACKEND_TP='$(top_builddir)/backends/telepathy/.libs/libfolks-backend-telepathy.so'
 245 AC_SUBST([BACKEND_TP])
 246
 247 if test x$have_libsocialweb_backend = xyes; then
 248   BACKEND_LIBSOCIALWEB='$(top_builddir)/backends/libsocialweb/.libs/libfolks-backend-libsocialweb.so'
 249   AC_SUBST([BACKEND_LIBSOCIALWEB])
 250 fi
 251
 252 if test x$enable_tracker_backend = xyes; then
 253   BACKEND_TRACKER='$(top_builddir)/backends/tracker/.libs/libfolks-backend-tracker.so'
 254   AC_SUBST([BACKEND_TRACKER])
 255 fi
 256
 257 # All of the backend libraries in our tree; to be used by the tests
 258 BACKEND_UNINST_PATH='$(BACKEND_KF):$(BACKEND_TP)'
 259 if test x$have_libsocialweb_backend = xyes; then
 260   LIBSOCIALWEB_BACKEND_UNINST_PATH='$(BACKEND_LIBSOCIALWEB)'
 261   BACKEND_UNINST_PATH="$BACKEND_UNINST_PATH:$LIBSOCIALWEB_BACKEND_UNINST_PATH"
 262 fi
 263 if test x$enable_tracker_backend = xyes; then
 264   TRACKER_BACKEND_UNINST_PATH='$(BACKEND_TRACKER)'
 265   BACKEND_UNINST_PATH="$BACKEND_UNINST_PATH:$TRACKER_BACKEND_UNINST_PATH"
 266 fi
 267 AC_SUBST([BACKEND_UNINST_PATH])
 268
 269 # -----------------------------------------------------------
 270 # Tools
 271 # -----------------------------------------------------------
 272
 273 AC_ARG_ENABLE([import-tool],
 274               AS_HELP_STRING([--enable-import-tool],
 275                              [Enable building the meta-contact import tool]),
 276               [enable_import_tool=$enableval with_import_tool=$enableval],
 277               [enable_import_tool=maybe with_import_tool=no])
 278 AS_IF([test "$enable_import_tool" != "no"],
 279       [PKG_CHECK_MODULES([LIBXML], [libxml-2.0],
 280                          [with_import_tool=yes], [with_import_tool=no])])
 281 AS_IF([test "$enable_import_tool" = "yes" -a "$with_import_tool" = "no"],
 282       [AC_MSG_ERROR([Import tool explicitly enabled, but libxml2 not found])])
 283 AM_CONDITIONAL([ENABLE_IMPORT_TOOL], [test "$with_import_tool" = "yes"])
 284
 285 # Readline's required for the folks-inspect program
 286 AC_ARG_ENABLE([inspect-tool],
 287               AS_HELP_STRING([--enable-inspect-tool],
 288                              [Enable building the data inspection tool]),
 289               [enable_inspect_tool=$enableval with_inspect_tool=$enableval],
 290               [enable_inspect_tool=maybe with_inspect_tool=no])
 291 AS_IF([test "$enable_inspect_tool" = "yes" -a "$enable_vala" != "yes"],
 292       [AC_MSG_ERROR([Inspect tool explicitly enabled, but Vala wasn't enabled \
 293                      using --enable-vala])])
 294 AS_IF([test "$enable_inspect_tool" = "maybe" -a "$enable_vala" != "yes"],
 295       [AC_MSG_NOTICE([Inspect tool disabled, as Vala wasn't enabled using \
 296                       --enable-vala])])
 297 AS_IF([test "$enable_inspect_tool" != "no" -a "x$enable_vala" = "xyes"],
 298       [AC_CHECK_LIB([readline], [main],
 299                     [with_inspect_tool=yes], [with_inspect_tool=no],
 300                     [-lncurses])])
 301 AS_IF([test "$enable_inspect_tool" != "no" -a "$with_inspect_tool" = "yes" -a \
 302        "x$enable_vala" = "xyes"],
 303       [VALA_CHECK_PACKAGES([readline])
 304        LIBREADLINE="-lreadline -lncurses"
 305        AC_DEFINE([HAVE_LIBREADLINE], [1], [Define if you have libreadline])
 306        AC_SUBST([LIBREADLINE])])
 307 AS_IF([test "$enable_inspect_tool" = "yes" -a "$with_inspect_tool" = "no"],
 308       [AC_MSG_ERROR([Inspect tool explicitly enabled, but readline not found])])
 309 AM_CONDITIONAL([ENABLE_INSPECT_TOOL], [test "$with_inspect_tool" = "yes"])
 310
 311 # -----------------------------------------------------------
 312 # Documentation
 313 # -----------------------------------------------------------
 314
 315 AC_ARG_ENABLE([docs],
 316               AS_HELP_STRING([--enable-docs],[Enable documentation generation]),
 317               [enable_docs=$enableval], [enable_docs=no])
 318 AM_CONDITIONAL([ENABLE_DOCS], [test x$enable_docs = xyes])
 319
 320 AS_IF([test "x$enable_docs" != xno],
 321       [AC_PATH_PROG([VALADOC], [valadoc], [:])
 322        AS_IF([test "$VALADOC" != :], have_valadoc=yes)])
 323 AM_CONDITIONAL([HAVE_VALADOC], [test x$have_valadoc = xyes])
 324
 325 # -----------------------------------------------------------
 326 # Gettext
 327 # -----------------------------------------------------------
 328
 329 GETTEXT_PACKAGE=AC_PACKAGE_NAME
 330 AC_SUBST(GETTEXT_PACKAGE)
 331 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"], [Define the gettext package to be used])
 332 IT_PROG_INTLTOOL([0.35.0])
 333
 334 # -----------------------------------------------------------
 335 # Error flags
 336 # -----------------------------------------------------------
 337
 338 AS_COMPILER_FLAG([-Wall], [ERROR_CFLAGS="-Wall"], [ERROR_CFLAGS=""])
 339 AS_COMPILER_FLAG([-Werror], [werror=yes], [werror=no])
 340
 341 AC_ARG_ENABLE([debug],
 342               AS_HELP_STRING([--disable-debug],[compile without debug code]),
 343               [enable_debug=$enableval], [enable_debug=yes])
 344
 345 AC_ARG_ENABLE([Werror],
 346               AS_HELP_STRING([--disable-Werror],
 347                              [compile without -Werror (normally enabled in
 348                               development builds)]),
 349               [werror=$enableval], [werror=yes])
 350
 351 AS_COMPILER_FLAG([-Wextra], [wextra=yes], [wextra=no])
 352 AS_COMPILER_FLAG([-Wno-missing-field-initializers],
 353                  [wno_missing_field_initializers=yes],
 354                  [wno_missing_field_initializers=no])
 355 AS_COMPILER_FLAG([-Wno-unused-parameter],
 356                  [wno_unused_parameter=yes], [wno_unused_parameter=no])
 357
 358 m4_if(folks_released, [1], [],
 359     [
 360         if test x$werror = xyes; then
 361             ERROR_CFLAGS="$ERROR_CFLAGS -Werror"
 362         fi
 363         if test x$wextra = xyes -a \
 364             x$wno_missing_field_initializers = xyes -a \
 365             x$wno_unused_parameter = xyes; then
 366             ERROR_CFLAGS="$ERROR_CFLAGS -Wextra \
 367                 -Wno-missing-field-initializers -Wno-unused-parameter"
 368         fi
 369     ])
 370
 371 AS_COMPILER_FLAG([-D_POSIX_SOURCE], [ERROR_CFLAGS="$ERROR_CFLAGS -D_POSIX_SOURCE"])
 372 AS_COMPILER_FLAG([-std=c99], [ERROR_CFLAGS="$ERROR_CFLAGS -std=c99"])
 373 AS_COMPILER_FLAG([-Wshadow], [ERROR_CFLAGS="$ERROR_CFLAGS -Wshadow"])
 374 AS_COMPILER_FLAG([-Wmissing-prototypes], [ERROR_CFLAGS="$ERROR_CFLAGS \
 375                                           -Wmissing-prototypes"])
 376 AS_COMPILER_FLAG([-Wmissing-declarations], [ERROR_CFLAGS="$ERROR_CFLAGS \
 377                                             -Wmissing-declarations"])
 378 AS_COMPILER_FLAG([-Wstrict-prototypes], [ERROR_CFLAGS="$ERROR_CFLAGS \
 379                                          -Wstrict-prototypes"])
 380
 381 AC_SUBST([ERROR_CFLAGS])
 382
 383 # Vala-related flags
 384 AS_IF([test "x$enable_vala" = "xyes"],
 385       [ERROR_INTROSPECTION_SCANNER_ARGS="\
 386                         $ERROR_INTROSPECTION_SCANNER_ARGS --warn-error"
 387        ERROR_VALAFLAGS="$ERROR_VALAFLAGS --fatal-warnings"])
 388
 389 AC_SUBST([ERROR_INTROSPECTION_SCANNER_ARGS])
 390 AC_SUBST([ERROR_VALAFLAGS])
 391
 392 # -----------------------------------------------------------
 393 # Final output
 394 # -----------------------------------------------------------
 395
 396 AC_CONFIG_FILES([
 397     backends/telepathy/lib/folks-telepathy.pc
 398     backends/telepathy/lib/folks-telepathy-uninstalled.pc
 399     backends/tracker/lib/folks-tracker.pc
 400     backends/tracker/lib/folks-tracker-uninstalled.pc
 401     folks/folks.pc
 402     folks/folks-uninstalled.pc
 403     Makefile
 404     backends/Makefile
 405     backends/key-file/Makefile
 406     backends/libsocialweb/Makefile
 407     backends/libsocialweb/lib/Makefile
 408     backends/libsocialweb/lib/folks-libsocialweb.pc
 409     backends/libsocialweb/lib/folks-libsocialweb-uninstalled.pc
 410     backends/telepathy/Makefile
 411     backends/telepathy/lib/Makefile
 412     backends/tracker/Makefile
 413     backends/tracker/lib/Makefile
 414     folks/Makefile
 415     docs/Makefile
 416     po/Makefile.in
 417     tests/Makefile
 418     tests/data/Makefile
 419     tests/data/gconf.path
 420     tests/folks/Makefile
 421     tests/key-file/Makefile
 422     tests/libsocialweb/Makefile
 423     tests/telepathy/Makefile
 424     tests/tracker/Makefile
 425     tests/lib/Makefile
 426     tests/lib/folks-test-uninstalled.pc
 427     tests/lib/key-file/Makefile
 428     tests/lib/libsocialweb/Makefile
 429     tests/lib/libsocialweb/session.conf
 430     tests/lib/telepathy/Makefile
 431     tests/lib/tracker/Makefile
 432     tests/lib/telepathy/contactlist/Makefile
 433     tests/lib/telepathy/contactlist/session.conf
 434     tests/tools/Makefile
 435     tools/Makefile
 436     tools/inspect/Makefile
 437 ])
 438
 439 AC_OUTPUT
 440
 441 echo "
 442 Configure summary:
 443
 444         Vala........................:  ${enable_vala}
 445         Vala Compiler...............:  ${VALAC}
 446         C Compiler Flags............:  ${CFLAGS} ${ERROR_CFLAGS}
 447         Prefix......................:  ${prefix}
 448         Bugreporting URL............:  ${PACKAGE_BUGREPORT}
 449         Documentation...............:  ${HAVE_VALADOC}
 450         Tests.......................:  ${have_tp_glib_for_tests}
 451         Import tool.................:  ${with_import_tool}
 452         Inspector tool..............:  ${with_inspect_tool}
 453         Tracker backend.............:  ${enable_tracker_backend}
 454         Libsocialweb backend........:  ${have_libsocialweb_backend}
 455
 456
 457 "