configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 m4_pattern_forbid([^MAN_])
   3
   4 # Initialise and check we're in the correct directory.
   5 AC_INIT([man-db], [2.6.5], [cjwatson@debian.org])
   6 AC_CONFIG_AUX_DIR([tools])
   7 AM_INIT_AUTOMAKE([1.11 -Wall -Wno-override -Werror foreign dist-xz no-dist-gzip parallel-tests])
   8 AM_MAINTAINER_MODE
   9 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  10 AC_PREREQ([2.59])
  11 AC_CONFIG_SRCDIR([src/man.c])
  12 AC_GNU_SOURCE
  13 AM_PROG_AR
  14 LT_INIT([disable-static])
  15
  16 if test ! -f "$srcdir/gnulib/po/Makefile.in.in"; then
  17         AC_MSG_ERROR([you must run ./autogen.sh before ./configure when building from revision control])
  18 fi
  19
  20 AC_CONFIG_HEADER([config.h])
  21 AC_CANONICAL_HOST
  22
  23 # Define below date and version information to be put into man pages etc.
  24 date=2013-06-27
  25 AC_SUBST([date])dnl
  26 roff_version=`echo AC_PACKAGE_VERSION | sed 's/-/\\-/g'`
  27 AC_SUBST([roff_version])dnl
  28
  29 # We have to be a bit naughty here and supply options.
  30 # The autoconf literature states that only features that can be separately
  31 # 'built' should use --enable and friends. Oh well...
  32 AC_ARG_ENABLE([setuid],
  33 [AS_HELP_STRING([--enable-setuid[=ARG]], [install man setuid to user ARG [ARG=man]])
  34 AS_HELP_STRING([--disable-setuid], [don't install man setuid])],
  35           [if test "$enableval" = "yes"
  36            then
  37                 enableval=man
  38            fi
  39            if test "$enableval" = "no"
  40            then
  41                 man_owner=
  42                 man_mode="755"
  43                 AC_MSG_NOTICE([Man will not be installed setuid])
  44            else
  45                 man_owner=$enableval
  46                 man_mode="4755"
  47                 AC_MSG_NOTICE([Man will be installed setuid $enableval])
  48                 AC_DEFINE_UNQUOTED([SECURE_MAN_UID], ["$man_owner"],
  49                                    [Define as the setuid owner of man or undefine if not installing setuid.])
  50            fi],
  51           [man_owner=man
  52            man_mode="4755"
  53            AC_DEFINE_UNQUOTED([SECURE_MAN_UID], ["$man_owner"])])
  54 AC_ARG_ENABLE([undoc],
  55 [AS_HELP_STRING([--enable-undoc=COMMAND], [suggest COMMAND for missing manual pages])],
  56         [if test "$enableval" = "yes" || test "$enableval" = "no"
  57          then
  58                 AC_MSG_ERROR([--enable-undoc requires an argument])
  59          else
  60                 AC_MSG_NOTICE([Suggesting '$enableval' for missing manual pages])
  61                 AC_DEFINE_UNQUOTED([UNDOC_COMMAND], ["$enableval"],
  62                                    [Define as the name of a command you want to suggest when a non-existent page is requested.])
  63          fi])
  64 AC_ARG_WITH([device],
  65 [AS_HELP_STRING([--with-device=DEVICE], [use nroff with the output device DEVICE])],
  66         [if test "$withval" = "yes" || test "$withval" = "no"
  67          then
  68                 AC_MSG_ERROR([--with-device requires an argument])
  69          else
  70                 nroff_device=" -T$withval"
  71          fi])
  72 AC_ARG_WITH([db],
  73 [AS_HELP_STRING([--with-db=LIBRARY], [use database library LIBRARY (db5, db4, db3, db2, db1, db, gdbm, ndbm)])],
  74         [if test "$withval" = "yes" || test "$withval" = "no"
  75          then
  76                 AC_MSG_ERROR([--with-db requires an argument])
  77          else
  78                 db=$withval
  79          fi],
  80         [: ${db=no}])
  81 AC_ARG_WITH([config-file],
  82 [AS_HELP_STRING([--with-config-file=CF], [use config file CF [CF=SYSCONFDIR/man_db.conf]])],
  83         [if test "$withval" = "yes" || test "$withval" = "no"
  84          then
  85                 AC_MSG_ERROR([--with-config-file requires an argument])
  86          else
  87                 config_file=$withval
  88          fi],
  89         [: ${config_file=\$\{sysconfdir\}/man_db.conf}])
  90 config_file_basename=${withval##*/}
  91 config_file_dirname=`AS_DIRNAME(["$config_file"])`
  92 AC_ARG_WITH([sections],
  93 [AS_HELP_STRING([--with-sections=SECTIONS], [use manual page sections SECTIONS @<:@1 n l 8 3 0 2 5 4 9 6 7@:>@])],
  94         [if test "$withval" = "yes" || test "$withval" = "no"
  95          then
  96                 AC_MSG_ERROR([--with-sections requires an argument])
  97          else
  98                 sections="$withval"
  99          fi],
 100         [: ${sections=1 n l 8 3 2 5 4 9 6 7}])
 101 AC_ARG_ENABLE([automatic-create],
 102 [AS_HELP_STRING([--enable-automatic-create], [allow man to create user databases on the fly])],
 103         [if test "$enableval" = "yes"
 104          then
 105                 AC_DEFINE([MAN_DB_CREATES], [1], [Allow man to create user databases on the fly.])
 106          fi])
 107 AC_ARG_ENABLE([automatic-update],
 108 [AS_HELP_STRING([--disable-automatic-update], [don't allow man to update databases on the fly])],
 109         [if test "$enableval" = "yes"
 110          then
 111                 AC_DEFINE([MAN_DB_UPDATES], [1], [Allow man to update databases on the fly.])
 112          fi],
 113         [AC_DEFINE([MAN_DB_UPDATES], [1], [Allow man to update databases on the fly.])])
 114 AC_ARG_ENABLE([cats],
 115 [AS_HELP_STRING([--disable-cats], [don't allow man to create/update cat files])],
 116         [if test "$enableval" = "yes"
 117          then
 118                 AC_DEFINE([MAN_CATS], [1], [Allow man to create/update cat files.])
 119          fi],
 120         [AC_DEFINE([MAN_CATS], [1], [Allow man to create/update cat files.])])
 121
 122 # Finish the argument parsing.
 123 AC_SUBST([man_owner])dnl
 124 AC_SUBST([man_mode])dnl
 125 AC_SUBST([config_file])dnl
 126 AC_SUBST([config_file_basename])dnl
 127 AC_SUBST([config_file_dirname])dnl
 128 AC_SUBST([sections])dnl
 129
 130 # Check $PATH for the following programs and append suitable options.
 131 AC_PROG_CC
 132 gl_EARLY
 133 AC_PROG_CPP
 134 CFLAGS="$CFLAGS -Wall"
 135 case $host_os in
 136         ultrix4.3*)
 137                 dnl When compiled for BSD environment, each running `man'
 138                 dnl increases the system load as reported by uptime(1) by
 139                 dnl one.  The reason for this behaviour is currently
 140                 dnl unknown, but the load increase does *not* reflect actual
 141                 dnl resource usage.  To avoid it, compile for POSIX
 142                 dnl environment:
 143                 CFLAGS="$CFLAGS -YPOSIX"
 144                 ;;
 145 esac
 146 if test "$GCC" = yes
 147 then
 148         gl_WARN_ADD([-W])
 149         gl_WARN_ADD([-Wpointer-arith])
 150         gl_WARN_ADD([-Wwrite-strings])
 151         gl_WARN_ADD([-Wstrict-prototypes])
 152         gl_WARN_ADD([-Wshadow])
 153         gl_WARN_ADD([-Wformat-security])
 154         gl_WARN_ADD([-Wredundant-decls])
 155         gl_WARN_ADD([-Wno-missing-field-initializers])
 156 fi
 157 AC_PROG_INSTALL
 158 AC_PROG_LN_S
 159 AC_CHECK_PROGS([cat], [cat])
 160 MAN_CHECK_PROGS([browser], [BROWSER], [use BROWSER as default web browser], [www-browser lynx elinks w3m])
 161 test -n "$browser" && browser="exec $browser"
 162 AC_CHECK_PROGS([tr], [tr])
 163 AC_CHECK_PROGS([grep], [grep])
 164 MAN_CHECK_PROGS([pager], [PAGER], [use PAGER as default pager], [pager less more])
 165 test -n "$pager" && pager="$pager -s"
 166
 167 # Define below (in list of preference) *roff macros to check for.
 168 macros="andoc an doc"
 169
 170 # We have problems here, as different systems have different *roff
 171 # formatters and they accept different options and do different things :(
 172 MAN_CHECK_PROGS([nroff], [NROFF], [use NROFF as roff formatter for character devices], [nroff gnroff groff])
 173 if test -n "$nroff"
 174 then
 175         MAN_PROG_GNU_NROFF([$nroff])
 176         if test "$man_cv_prog_gnu_nroff" != "yes"
 177         then
 178                 MAN_PROG_HEIRLOOM_NROFF([$nroff])
 179         fi
 180         if test -n "$nroff_device"
 181         then
 182                 AC_MSG_CHECKING([that nroff works with argument$nroff_device])
 183                 # We cannot cache this result as it can change between runs
 184                 # of configure.
 185                 if $nroff $nroff_device </dev/null >/dev/null 2>&1 3>&1
 186                 then
 187                         AC_MSG_RESULT([yes])
 188                 else
 189                         AC_MSG_RESULT([no])
 190                         AC_MSG_ERROR([nroff does not work with argument$nroff_device])
 191                 fi
 192         fi
 193         AC_MSG_CHECKING([for appropriate nroff macro])
 194         AC_CACHE_VAL([man_cv_prog_nroff_macro], [
 195
 196         for macro in $macros
 197         do
 198                 if $nroff -m$macro $nroff_device </dev/null >/dev/null 2>&1 3>&1
 199                 then
 200                         man_cv_prog_nroff_macro=-m$macro
 201                         break
 202                 fi
 203         done])
 204
 205         if test -n "$man_cv_prog_nroff_macro"
 206         then
 207                 if test "$man_cv_prog_heirloom_nroff" = "yes"
 208                 then
 209                         # Heirloom works best with some extra options:
 210                         #   -mg: groff compatibility
 211                         #   -msafe: disable privileged operations
 212                         #   -mpadj: clean up line breaking
 213                         man_cv_prog_nroff_macro="-mg -msafe -mpadj ${man_cv_prog_nroff_macro}"
 214                 fi
 215                 nroff="$nroff ${man_cv_prog_nroff_macro}"
 216 dnl             nroff="$nroff ${man_cv_prog_nroff_macro}${nroff_device}"
 217                 AC_MSG_RESULT([$man_cv_prog_nroff_macro])
 218         else
 219                 AC_MSG_RESULT([ambiguous])
 220                 AC_MSG_WARN([please edit include/manconfig.h and add nroff definition])
 221         fi
 222 else
 223         AC_MSG_WARN([Cannot find an nroff-like program, formatting of manual page source will not be supported.])
 224         nroff="(nroff not installed)"
 225         AC_DEFINE([NROFF_MISSING], [1], [Define if you don't have nroff.])
 226 fi
 227
 228 dnl It would be nice to use MAN_CHECK_PROGS here, but how do we determine
 229 dnl TROFF_IS_GROFF?
 230 AC_CHECK_PROGS([troff], [groff])
 231 if test -n "$troff"
 232 then
 233         troff_is_groff=yes
 234         AC_DEFINE([TROFF_IS_GROFF], [1], [Define if you are using groff as troff.])
 235         TROFF=groff
 236 else
 237         troff_is_groff=no
 238         AC_CHECK_PROGS([troff], [troff gtroff])
 239         TROFF=troff
 240 fi
 241 AC_SUBST([TROFF])
 242 if test -n "$troff"
 243 then
 244         AC_DEFINE([HAS_TROFF], [1], [Define if you have troff.])
 245         AC_MSG_CHECKING([for appropriate $TROFF options])
 246         AC_CACHE_VAL([man_cv_prog_troff_options], [
 247         # Do a quick test to see if -t works [AIX needs this], groff doesn't
 248         # as it indicates pre-process with tbl.
 249         test "$TROFF" = "troff" && $troff -t </dev/null >/dev/null 2>&1 3>&1 \
 250                                 && troff_filter="-t "
 251         for macro in $macros
 252         do
 253                 if $troff $troff_filter -m$macro </dev/null >/dev/null 2>&1 3>&1
 254                 then
 255                         man_cv_prog_troff_options="${troff_filter}-m${macro}"
 256                         break
 257                 fi
 258         done])
 259         if test -n "$man_cv_prog_troff_options"
 260         then
 261                 if test "$man_cv_prog_heirloom_nroff" = "yes"
 262                 then
 263                         # Heirloom works best with some extra options:
 264                         #   -mg: groff compatibility
 265                         #   -msafe: disable privileged operations
 266                         #   -mpadj: clean up line breaking
 267                         man_cv_prog_troff_options="-mg -msafe -mpadj ${man_cv_prog_troff_options}"
 268                 fi
 269                 troff="$troff $man_cv_prog_troff_options"
 270                 AC_MSG_RESULT([$man_cv_prog_troff_options])
 271         else
 272                 AC_MSG_RESULT([ambiguous])
 273                 AC_MSG_WARN([please edit include/manconfig.h and add troff definition])
 274         fi
 275 else
 276         troff="(troff not installed)"
 277 fi
 278
 279 if test -n "$nroff"
 280 then
 281         AC_CACHE_CHECK([whether nroff supports warning control],
 282                        [man_cv_prog_nroff_warnings], [
 283                 if test "x$troff_is_groff" = xyes && \
 284                    nroff -wmac </dev/null >/dev/null 2>&1
 285                 then
 286                         man_cv_prog_nroff_warnings=yes
 287                 else
 288                         man_cv_prog_nroff_warnings=no
 289                 fi])
 290         if test "x$man_cv_prog_nroff_warnings" = xyes; then
 291                 AC_DEFINE([NROFF_WARNINGS], [1],
 292                           [Define if nroff supports warning control.])
 293         fi
 294 fi
 295
 296 AC_CHECK_PROGS([preconv], [gpreconv preconv])
 297
 298 AC_MSG_CHECKING([for groff with Debian multibyte patch or real Unicode support])
 299 man_mb_groff=no
 300 AC_ARG_ENABLE([mb-groff],
 301 [AS_HELP_STRING([--enable-mb-groff], [expect groff with Debian multibyte patch or real Unicode support])],
 302         [if test "$enableval" = "yes"
 303          then
 304                 man_mb_groff=yes
 305          fi],
 306         [if test -n "$preconv"
 307          then
 308                 man_mb_groff=yes
 309          elif test -n "$troff" && test "$troff_is_groff" = "yes"
 310          then
 311                 if $troff -Tnippon </dev/null >/dev/null 2>&1
 312                 then
 313                         man_mb_groff=yes
 314                 fi
 315          fi])
 316 AC_MSG_RESULT([$man_mb_groff])
 317 if test "$man_mb_groff" = "yes"
 318 then
 319         AC_DEFINE([MULTIBYTE_GROFF], 1,
 320                   [Define if your groff installation has the Debian multibyte patch.])
 321 fi
 322
 323 MAN_CHECK_PROGS([eqn], [EQN], [use EQN to preprocess equations], [eqn geqn])
 324 MAN_CHECK_PROGS([neqn], [NEQN], [use NEQN to preprocess equations for character devices], [neqn gneqn])
 325 # If we fail to find an neqn, use eqn and try to force it to output for an
 326 # ascii device. As this is only relevant for equations (?), not using latin1
 327 # should be acceptable. -Tlatin1 is ignored by some eqn implementations.
 328 if test -z "$neqn"
 329 then
 330         test -n "$eqn" &&
 331         (test -n "$nroff_device" && neqn="$eqn -T$nroff_device" || neqn="$eqn -Tascii")
 332 fi
 333 MAN_CHECK_PROGS([tbl], [TBL], [use TBL to preprocess tables], [tbl gtbl])
 334 TBL_X_FORMAT=
 335 if test -n "$tbl"
 336 then
 337         AC_CACHE_CHECK([whether tbl supports the 'x' format character],
 338                        [man_cv_tbl_x_format], [
 339                 if (echo .TS; echo ';'; echo lx.; echo SENTINEL; echo .TE) | \
 340                    $tbl 2>/dev/null | grep SENTINEL >/dev/null 2>&1
 341                 then
 342                         man_cv_tbl_x_format=yes
 343                 else
 344                         man_cv_tbl_x_format=no
 345                 fi])
 346         if test "x$man_cv_tbl_x_format" = xyes
 347         then
 348                 TBL_X_FORMAT=x
 349         fi
 350 fi
 351 AC_SUBST([TBL_X_FORMAT])
 352 MAN_CHECK_PROGS([col], [COL], [use COL to filter formatting characters from output], [col gcol])
 353 MAN_CHECK_PROGS([vgrind], [VGRIND], [use VGRIND to preprocess program sources], [vgrind gvgrind])
 354 MAN_CHECK_PROGS([refer], [REFER], [use REFER to preprocess bibliographic references], [refer grefer])
 355 MAN_CHECK_PROGS([grap], [GRAP], [use GRAP to preprocess graphs], [grap])
 356 MAN_CHECK_PROGS([pic], [PIC], [use PIC to preprocess pictures], [pic gpic])
 357 test -n "$pic" && pic="$pic -S"
 358
 359 MAN_CHECK_PROGS([gzip], [GZIP], [use GZIP as GNU compression utility], [gzip])
 360 if test -n "$gzip"
 361 then
 362         gunzip="$gzip -dc"
 363         compressor="$gzip -c7"
 364         compress_ext="gz"
 365 fi
 366 MAN_CHECK_PROGS([compress], [COMPRESS], [use COMPRESS as UNIX compression utility], [compress])
 367 if test -n "$compress"
 368 then
 369         uncompress="$compress -dc"
 370         if test -z "$gzip"
 371         then
 372                 compressor="$compress -c"
 373                 compress_ext="Z"
 374         fi
 375 fi
 376 MAN_CHECK_PROGS([bzip2], [BZIP2], [use BZIP2 as block-sorting compression utility], [bzip2])
 377 if test -n "$bzip2"
 378 then
 379         bunzip2="$bzip2 -dc"
 380 fi
 381 MAN_CHECK_PROGS([xz], [XZ], [use XZ as Lempel-Ziv-Markov chain-Algorithm compression utility], [xz])
 382 if test -n "$xz"
 383 then
 384         unxz="$xz -dc"
 385         unlzma=
 386 else
 387         dnl lzma not used/needed if we have xz
 388         MAN_CHECK_PROGS([lzma], [LZMA], [use LZMA as Lempel-Ziv-Markov chain-Algorithm compression utility], [lzma])
 389         if test -n "$lzma"
 390         then
 391                 unlzma="$lzma -dc"
 392         fi
 393 fi
 394 MAN_CHECK_PROGS([lzip], [LZIP], [use LZIP as Lempel-Ziv-Markov chain-Algorithm compression utility], [lzip])
 395 if test -n "$lzip"
 396 then
 397         unlzip="$lzip -dc"
 398 fi
 399 if test -n "$gzip" || test -n "$compress" || test -n "$bzip2" || test -n "$xz" || test -n "$lzip" || test -n "$lzma"
 400 then
 401         AC_DEFINE([COMP_CAT], [1], [Define if you have compressors and want to support compressed cat files.])
 402         AC_DEFINE([COMP_SRC], [1], [Define if you have compressors and want to support compressed manual source.])
 403 fi
 404 AC_SUBST([compressor])
 405 AC_SUBST([compress_ext])
 406 AC_SUBST([gunzip])
 407 AC_SUBST([uncompress])
 408 AC_SUBST([bunzip2])
 409 AC_SUBST([unlzma])
 410 AC_SUBST([unxz])
 411 AC_SUBST([unlzip])
 412 MAN_COMPRESS_LIB([z], [gzopen])
 413 dnl To add more decompressors just follow the scheme above.
 414
 415 # Work out which manual page hierarchy scheme might be in use.
 416 AC_ARG_ENABLE([mandirs],
 417 [AS_HELP_STRING([--enable-mandirs=OS], [select manual page hierarchy organization (GNU, HPUX, IRIX, Solaris, BSD)])],
 418         [AC_MSG_NOTICE([Using $enableval hierarchy organization(s)])
 419          AC_DEFINE_UNQUOTED([MANDIR_LAYOUT], ["$enableval"],
 420                             [Define to the manual page hierarchy organization(s) in use.])
 421          MANDIR_LAYOUT="$enableval"],
 422         [case $host in
 423                 *-gnu)          mandirs=GNU;;
 424                 *-hpux*)        mandirs=HPUX;;
 425                 *-irix*)        mandirs=IRIX;;
 426                 *-solaris*)     mandirs=Solaris;;
 427                 *-*bsd*)        mandirs=BSD;;
 428                 *)              mandirs=;;
 429          esac
 430          if test -n "$mandirs"; then
 431                 AC_MSG_NOTICE([Using $mandirs hierarchy organization])
 432                 AC_DEFINE_UNQUOTED([MANDIR_LAYOUT], ["$mandirs"])
 433                 MANDIR_LAYOUT="$mandirs"
 434          else
 435                 AC_MSG_NOTICE([Allowing any hierarchy organization])
 436                 AC_DEFINE([MANDIR_LAYOUT], [""])
 437                 MANDIR_LAYOUT=
 438          fi])
 439 AC_SUBST([MANDIR_LAYOUT])
 440
 441 # Check for various header files and associated libraries.
 442 AC_ISC_POSIX
 443 dnl AC_PROG_LEX calls AC_TRY_LINK: must come after above 3
 444 AC_PROG_LEX
 445 gl_INIT
 446 AC_HEADER_DIRENT
 447 AC_CHECK_HEADERS([fcntl.h sys/file.h])
 448
 449 # Internationalization support.
 450 AM_GNU_GETTEXT([external])
 451 AM_GNU_GETTEXT_VERSION([0.18.1])
 452 AC_SUBST([LINGUAS])
 453 AM_ICONV
 454 MAN_PO4A
 455 MAN_LINGUAS
 456
 457 # Checks for structures and compiler characteristics.
 458 AC_C_CONST
 459 AC_C_INLINE
 460 AC_TYPE_PID_T
 461 AC_TYPE_UID_T
 462 AC_TYPE_SIZE_T
 463
 464 # Check for pipeline library.
 465 PKG_CHECK_MODULES([libpipeline], [libpipeline >= 1.1.0])
 466
 467 # Find a suitable database interface header and library.
 468 #
 469 # Check for GNU dbm routines.
 470 if test "$db" = "no" || test "$db" = "gdbm"
 471 then
 472   AC_CHECK_HEADER([gdbm.h], [
 473     for lib in gdbm c dbm
 474     do
 475       AC_CHECK_LIB([$lib], [gdbm_fetch],
 476                    test "$lib" = "c" || DBLIBS="-l$lib"
 477                    [AC_DEFINE([GDBM], [1], [Define if you have, and want to use, gdbm interface routines.])
 478                     AC_SUBST([DBTYPE], [gdbm])]
 479                    db=yes, db=no)
 480       if test "$db" = "yes"
 481       then
 482         man_save_LIBS="$LIBS"
 483         LIBS="$LIBS $DBLIBS"
 484         AC_CHECK_FUNCS([gdbm_exists])
 485         LIBS="$man_save_LIBS"
 486         break
 487       fi
 488     done], db=no)
 489 fi
 490
 491 # Check for Berkeley db routines (first version API).
 492 MAN_CHECK_BDB([db5 db], [db5/db_185.h db_185.h], [db5 db-5])
 493 MAN_CHECK_BDB([db4 db], [db4/db_185.h db_185.h], [db4 db-4])
 494 MAN_CHECK_BDB([db3 db], [db3/db_185.h db_185.h], [db3])
 495 MAN_CHECK_BDB([db2 db], [db_185.h db2/db_185.h db2_185.h], [db2 db])
 496 MAN_CHECK_BDB([db1 db], [db/db.h db.h db1/db.h], [db db1 c])
 497
 498 dnl MAN_CHECK_BDB([db2], [db2_185.h], [db2 db c], [AC_DEFINE(DB_ON_LIBC)])
 499 dnl MAN_CHECK_BDB([db2], [db2/db_185.h], [db2 db c])
 500
 501 # Check for UNIX ndbm routines.
 502 if test "$db" = "no" || test "$db" = "ndbm"
 503 then
 504   AC_CHECK_HEADER([ndbm.h], [
 505     for lib in ndbm c dbm
 506     do
 507       AC_CHECK_LIB([$lib], [dbm_fetch],
 508                    test "$lib" = "c" || DBLIBS="-l$lib"
 509                    [AC_DEFINE([NDBM], [1], [Define if you have, and want to use, ndbm interface routines.])
 510                     AC_SUBST([DBTYPE], [ndbm])]
 511                    db=yes, db=no)
 512       test "$db" = "yes" && break
 513       done], db=no)
 514 fi
 515
 516 if test "$db" != "yes"
 517 then
 518     if test "$db" = "no"
 519     then
 520       AC_MSG_ERROR([Fatal: no supported database library/header found])
 521     else
 522       AC_MSG_ERROR([Fatal: $db: unsupported database library])
 523     fi
 524 fi
 525 AC_SUBST([DBLIBS])
 526
 527 dnl MAN_ECHO_VAR(ENV-VARIABLE)
 528 define([MAN_ECHO_VAR], [AC_MSG_NOTICE([default $1 = "$$1"])])dnl
 529 dnl
 530 MAN_ECHO_VAR([CC])
 531 MAN_ECHO_VAR([CPP])
 532 MAN_ECHO_VAR([CPPFLAGS])
 533 MAN_ECHO_VAR([CFLAGS])
 534 MAN_ECHO_VAR([LDFLAGS])
 535 MAN_ECHO_VAR([LIBS])
 536 MAN_ECHO_VAR([DBLIBS])
 537
 538 # Transformed versions of program names for use in Automake variables.
 539 MAN_TRANS_SUBST([apropos])
 540 MAN_TRANS_SUBST([catman])
 541 MAN_TRANS_SUBST([lexgrog])
 542 MAN_TRANS_SUBST([man])
 543 MAN_TRANS_SUBST([manconv])
 544 MAN_TRANS_SUBST([mandb])
 545 MAN_TRANS_SUBST([manpath])
 546 MAN_TRANS_SUBST([whatis])
 547 MAN_TRANS_SUBST([zsoelim])
 548
 549 # If we're cross-compiling, tests won't work.
 550 AM_CONDITIONAL([CROSS_COMPILING], [test "x$cross_compiling" = xyes])
 551
 552 AC_CONFIG_FILES([Makefile
 553         gnulib/lib/Makefile
 554         gnulib/po/Makefile.in
 555         lib/Makefile
 556         src/Makefile
 557         src/man_db.conf
 558         src/tests/Makefile
 559         man/Makefile
 560         man/replace.sin
 561         man/po4a/Makefile
 562         man/da/Makefile
 563         man/de/Makefile
 564         man/es/Makefile
 565         man/fr/Makefile
 566         man/id/Makefile
 567         man/it/Makefile
 568         man/ja/Makefile
 569         man/nl/Makefile
 570         man/pl/Makefile
 571         man/ru/Makefile
 572         man/zh_CN/Makefile
 573         manual/Makefile
 574         libdb/Makefile
 575         docs/Makefile
 576         tools/Makefile
 577         include/comp_src.h
 578         include/manconfig.h
 579         po/Makefile.in])
 580 AC_OUTPUT