configure.ac

   1 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
   2 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
   3 m4_define([v_maj], [0])
   4 m4_define([v_min], [9])
   5 m4_define([v_mic], [9])
   6 m4_define([v_rev], m4_esyscmd([(svnversion "${SVN_REPO_PATH:-.}" | grep -v export || echo 0) | awk -F : '{printf("%s\n", $1);}' | tr -d ' :MSP\n']))
   7 m4_if(v_rev, [0], [m4_define([v_rev], m4_esyscmd([git log 2> /dev/null | (grep -m1 git-svn-id || echo 0) | sed -e 's/.*@\([0-9]*\).*/\1/' | tr -d '\n']))])
   8 ##--   When released, remove the dnl on the below line
   9 dnl m4_undefine([v_rev])
  10 ##--   When doing snapshots - change soname. remove dnl on below line
  11 m4_define([relname], [ver-pre-svn-07])
  12 m4_define([v_rel], [-release relname])
  13 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  14 m4_ifdef([v_rev], [m4_define([v_ver], [v_maj.v_min.v_mic.v_rev])],
  15 [m4_define([v_ver], [v_maj.v_min.v_mic])])
  16 m4_define([lt_rev], m4_eval(v_maj + v_min))
  17 m4_define([lt_cur], v_mic)
  18 m4_define([lt_age], v_min)
  19 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  20 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  21
  22 AC_INIT([eina], [v_ver], [enlightenment-devel@lists.sourceforge.net])
  23 AC_PREREQ([2.59])
  24 AC_CONFIG_SRCDIR([configure.ac])
  25 AC_CONFIG_MACRO_DIR([m4])
  26 AC_CANONICAL_BUILD
  27 AC_CANONICAL_HOST
  28 AC_ISC_POSIX
  29
  30 AM_INIT_AUTOMAKE([1.6 dist-bzip2])
  31 AM_CONFIG_HEADER([config.h])
  32 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  33
  34 AC_LIBTOOL_WIN32_DLL
  35 define([AC_LIBTOOL_LANG_CXX_CONFIG], [:])dnl
  36 define([AC_LIBTOOL_LANG_F77_CONFIG], [:])dnl
  37 AC_PROG_LIBTOOL
  38
  39 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  40 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  41 m4_ifdef([v_rev], , [m4_define([v_rev], [0])])
  42 m4_ifdef([v_rel], , [m4_define([v_rel], [])])
  43 AC_DEFINE_UNQUOTED(VMAJ, [v_maj], [Major version])
  44 AC_DEFINE_UNQUOTED(VMIN, [v_min], [Minor version])
  45 AC_DEFINE_UNQUOTED(VMIC, [v_mic], [Micro version])
  46 AC_DEFINE_UNQUOTED(VREV, [v_rev], [Revison])
  47 version_info="lt_rev:lt_cur:lt_age"
  48 release_info="v_rel"
  49 AC_SUBST(version_info)
  50 AC_SUBST(release_info)
  51 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  52 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  53 VMAJ=v_maj
  54 AC_SUBST(VMAJ)
  55
  56 ### Needed information
  57
  58 requirement_eina=""
  59
  60 case "$host_os" in
  61    mingw32ce*)
  62       MODULE_ARCH="$host_os-$host_cpu"
  63       ;;
  64    *)
  65       MODULE_ARCH="$host_os-$host_cpu-$relname"
  66       ;;
  67 esac
  68 AC_SUBST(MODULE_ARCH)
  69 AC_DEFINE_UNQUOTED(MODULE_ARCH, "${MODULE_ARCH}", "Module architecture")
  70
  71 case "$host_os" in
  72    mingw*)
  73       MODULE_EXT=".dll"
  74       ;;
  75    *)
  76       MODULE_EXT=".so"
  77       ;;
  78 esac
  79
  80 AC_DEFINE_UNQUOTED(SHARED_LIB_SUFFIX, "${MODULE_EXT}", [Suffix for shared objects])
  81
  82 EFL_CHECK_CPU_MMX([have_mmx="yes"], [have_mmx="no"])
  83 EFL_CHECK_CPU_SSE([have_sse="yes"], [have_sse="no"])
  84 EFL_CHECK_CPU_SSE2([have_sse2="yes"], [have_sse2="no"])
  85 EFL_CHECK_CPU_ALTIVEC([have_altivec="yes"], [have_altivec="no"])
  86
  87 EFL_CHECK_THREADS(
  88    [
  89     if test "x${_efl_have_posix_threads}" = "xyes" ; then
  90        have_threads="POSIX"
  91     else
  92        if test "x${_efl_have_win32_threads}" = "xyes" ; then
  93           have_threads="Win32"
  94        else
  95           have_threads="no"
  96        fi
  97     fi
  98    ],
  99    [have_threads="no"])
 100 EFL_CHECK_SPINLOCK([have_posix_threads_spinlock="yes"], [have_posix_threads_spinlock="no"])
 101 EFL_CHECK_RWLOCK([have_posix_threads_rwlock="yes"], [have_posix_threads_rwlock="no"])
 102
 103 ### Additional options to configure
 104
 105 # Magic debug
 106 AC_ARG_ENABLE([magic-debug],
 107    [AC_HELP_STRING([--disable-magic-debug], [disable magic debug of eina structure @<:@default=enabled@:>@])],
 108    [
 109     if test "x${enableval}" = "xyes" ; then
 110        have_magic_debug="yes"
 111     else
 112        have_magic_debug="no"
 113     fi
 114    ],
 115    [have_magic_debug="yes"])
 116
 117 AC_MSG_CHECKING([whether magic debug is enable])
 118 AC_MSG_RESULT([${have_magic_debug}])
 119
 120 if test "x${have_magic_debug}" = "xyes" ; then
 121    EINA_CONFIGURE_MAGIC_DEBUG="#define EINA_MAGIC_DEBUG"
 122 fi
 123 AC_SUBST(EINA_CONFIGURE_MAGIC_DEBUG)
 124
 125 # Safety checks (avoid crashes on wrong api usage)
 126 AC_ARG_ENABLE(safety-checks,
 127    [AC_HELP_STRING([--disable-safety-checks], [disable safety checks for NULL pointers and like. @<:@default=enabled@:>@])],
 128    [
 129     if test "x${enableval}" = "xyes" ; then
 130        have_safety_checks="yes"
 131     else
 132        have_safety_checks="no"
 133     fi
 134    ],
 135    [have_safety_checks="yes"])
 136
 137 AC_MSG_CHECKING(whether to do safety checking on api parameters)
 138 AC_MSG_RESULT($have_safety_checks)
 139
 140 AM_CONDITIONAL(SAFETY_CHECKS, test "x$have_safety_checks" = "xyes")
 141 if test "x$have_safety_checks" = "xyes"; then
 142   AC_DEFINE(EINA_SAFETY_CHECKS, 1, [disable safety checks for NULL pointers and like.])
 143   EINA_CONFIGURE_SAFETY_CHECKS="#define EINA_SAFETY_CHECKS"
 144 fi
 145 AC_SUBST(EINA_CONFIGURE_SAFETY_CHECKS)
 146
 147 with_max_log_level="<unset>"
 148 AC_ARG_WITH(internal-maximum-log-level,
 149    [AC_HELP_STRING([--with-internal-maximum-log-level=NUMBER],
 150                    [limit eina internal log level to the given number, any call to EINA_LOG() with values greater than this will be compiled out, ignoring runtime settings, but saving function calls.])],
 151    [
 152     if test "x${withval}" != "xno"; then
 153        if echo "${withval}" | grep '^[[0-9]]\+$' >/dev/null 2>/dev/null; then
 154           AC_MSG_NOTICE([ignoring any EINA_LOG() with level greater than ${withval}])
 155           AC_DEFINE_UNQUOTED(EINA_LOG_LEVEL_MAXIMUM, ${withval}, [if set, logging is limited to this amount.])
 156           with_max_log_level="${withval}"
 157        else
 158           AC_MSG_ERROR([--with-internal-maximum-log-level takes a decimal number, got "${withval}" instead.])
 159        fi
 160     fi
 161     ], [:])
 162
 163 AC_ARG_ENABLE([amalgamation],
 164    [AC_HELP_STRING([--enable-amalgamation], [enable generation of one single file with all source code in it, helps compiler optimizations.])],
 165    [if test "x${enableval}" = "xyes"; then
 166        do_amalgamation="yes"
 167     else
 168        do_amalgamation="no"
 169     fi
 170    ],
 171    [do_amalgamation="no"]
 172 )
 173 AM_CONDITIONAL(EINA_AMALGAMATION, test "x${do_amalgamation}" = "xyes")
 174
 175 # Choose best memory pool
 176 AC_ARG_ENABLE([default-mempool],
 177    [AC_HELP_STRING([--enable-default-mempool], [Default memory allocator could be faster for some computer. @<:@default=disabled@:>@])],
 178    [
 179     if test "x${enableval}" = "xyes"; then
 180        have_default_mempool="yes"
 181     else
 182        have_default_mempool="no"
 183     fi
 184    ],
 185    [have_default_mempool="no"]
 186 )
 187 AC_MSG_CHECKING([whether to use default mempool allocator])
 188 AC_MSG_RESULT([${have_default_mempool}])
 189
 190 if test "x${have_default_mempool}" = "xyes" ; then
 191    EINA_CONFIGURE_DEFAULT_MEMPOOL="#define EINA_DEFAULT_MEMPOOL"
 192 fi
 193 AC_SUBST(EINA_CONFIGURE_DEFAULT_MEMPOOL)
 194
 195 # Report stringshare usage
 196 AC_ARG_ENABLE([stringshare-usage],
 197    [AC_HELP_STRING([--enable-stringshare-usage], [Report stringshare usage on stringshare shutdown. @<:@default=disabled@:>@])],
 198    [
 199     if test "x${enableval}" = "xyes"; then
 200        have_stringshare_usage="yes"
 201     else
 202        have_stringshare_usage="no"
 203     fi
 204    ],
 205    [have_stringshare_usage="no"]
 206 )
 207 AC_MSG_CHECKING([whether to report stringshare usage])
 208 AC_MSG_RESULT([${have_stringshare_usage}])
 209
 210 if test "x${have_stringshare_usage}" = "xyes"; then
 211    AC_DEFINE(EINA_STRINGSHARE_USAGE, 1, [Report Eina stringshare usage pattern])
 212 fi
 213
 214 # Check if we want to benchmark on real data
 215 enable_benchmark_e17="no"
 216 AC_ARG_ENABLE([e17],
 217    [AC_HELP_STRING([--enable-e17], [enable heavy benchmark @<:@default=no@:>@])],
 218    [
 219     if test "x${enableval}" = "xyes" ; then
 220        enable_benchmark_e17="yes"
 221     else
 222        enable_benchmark_e17="no"
 223     fi
 224    ],
 225    [enable_benchmark_e17="no"])
 226
 227 AC_MSG_CHECKING([whether e17 real data benchmark are built])
 228 AC_MSG_RESULT([${enable_benchmark_e17}])
 229
 230 AM_CONDITIONAL(EINA_ENABLE_BENCHMARK_E17, test "x${enable_benchmark_e17}" = "xyes")
 231
 232
 233 ### Checks for programs
 234 AC_PROG_CC
 235
 236 # pkg-config
 237 PKG_PROG_PKG_CONFIG
 238
 239 # Check whether pkg-config supports Requires.private
 240 if $PKG_CONFIG --atleast-pkgconfig-version 0.22; then
 241    pkgconfig_requires_private="Requires.private"
 242 else
 243    pkgconfig_requires_private="Requires"
 244 fi
 245 AC_SUBST(pkgconfig_requires_private)
 246
 247 # doxygen program for documentation building
 248
 249 EFL_CHECK_DOXYGEN([build_doc="yes"], [build_doc="no"])
 250
 251
 252 ### Checks for libraries
 253
 254 # Evil library for compilation on Windows CE
 255
 256 EFL_EINA_BUILD=""
 257 case "$host_os" in
 258    mingw*)
 259       PKG_CHECK_MODULES([EVIL], [evil])
 260       AC_DEFINE(HAVE_EVIL, 1, [Set to 1 if evil package is installed])
 261       requirement_eina="evil"
 262       EFL_EINA_BUILD="-DEFL_EINA_BUILD"
 263    ;;
 264 esac
 265 AC_SUBST(EFL_EINA_BUILD)
 266
 267 # Check ememoa memory pool library
 268
 269 AC_ARG_ENABLE([ememoa],
 270    [AC_HELP_STRING([--enable-ememoa], [build ememoa memory pool module @<:@default=yes@:>@])],
 271    [
 272     if test "x${enableval}" = "xyes" ; then
 273        enable_ememoa="yes"
 274     else
 275        enable_ememoa="no"
 276     fi
 277    ],
 278    [enable_ememoa="yes"]
 279 )
 280 AC_MSG_CHECKING([whether to use ememoa for memory pool])
 281 AC_MSG_RESULT([$enable_ememoa])
 282
 283 if test "x${enable_ememoa}" = "xyes" ; then
 284    PKG_CHECK_MODULES([EMEMOA],
 285       [ememoa >= 0.0.26 ],
 286       [enable_ememoa="yes"],
 287       [enable_ememoa="no"]
 288    )
 289 fi
 290
 291
 292 ### Checks for header files
 293 AC_HEADER_ASSERT
 294 AC_HEADER_DIRENT
 295 AC_HEADER_TIME
 296
 297
 298 ### Checks for types
 299 AC_CHECK_HEADER([inttypes.h],
 300                 [EINA_CONFIGURE_HAVE_INTTYPES_H="#define EINA_HAVE_INTTYPES_H"])
 301 AC_SUBST(EINA_CONFIGURE_HAVE_INTTYPES_H)
 302
 303 AC_CHECK_HEADER([stdint.h],
 304                 [EINA_CONFIGURE_HAVE_STDINT_H="#define EINA_HAVE_STDINT_H"])
 305 AC_SUBST(EINA_CONFIGURE_HAVE_STDINT_H)
 306
 307 AC_CHECK_SIZEOF(wchar_t)
 308 EINA_SIZEOF_WCHAR_T=$ac_cv_sizeof_wchar_t
 309 AC_SUBST(EINA_SIZEOF_WCHAR_T)
 310
 311 ### Checks for structures
 312
 313
 314 ### Checks for compiler characteristics
 315 AC_C_CONST
 316 AC_C_BIGENDIAN
 317 AC_C_INLINE
 318 AC_C___ATTRIBUTE__
 319 AC_PROG_CC_STDC
 320
 321 EINA_CPPFLAGS=""
 322 EINA_CFLAGS=""
 323 case "$host_os" in
 324    mingw32ce*)
 325       EINA_CPPFLAGS="-D_WIN32_WCE=0x0420"
 326       EINA_CFLAGS="${EVIL_CFLAGS}"
 327       ;;
 328    mingw*)
 329       EINA_CPPFLAGS="-D_WIN32_WINNT=0x0501"
 330       EINA_CFLAGS="${EVIL_CFLAGS}"
 331       ;;
 332 esac
 333
 334 m4_ifdef([v_mic],
 335    [
 336     EFL_COMPILER_FLAG([-Wall])
 337     EFL_COMPILER_FLAG([-W])
 338    ])
 339
 340 EFL_COMPILER_FLAG([-Wshadow])
 341
 342 AC_SUBST(EINA_CPPFLAGS)
 343 AC_SUBST(EINA_CFLAGS)
 344
 345
 346 ### Checks for linker characteristics
 347 EINA_LIBS=
 348 lt_enable_auto_import=""
 349 case "${host_os}" in
 350    mingw*)
 351       EINA_LIBS="-ldl ${EVIL_LIBS} -lm"
 352       lt_enable_auto_import="-Wl,--enable-auto-import"
 353    ;;
 354    dragonfly*|openbsd*)
 355       EINA_LIBS="-lm"
 356    ;;
 357    freebsd*|netbsd*)
 358       EINA_LIBS="-lrt -lm"
 359    ;;
 360    darwin*)
 361       EINA_LIBS="-lm"
 362    ;;
 363    cygwin*)
 364       EINA_LIBS="-ldl -lm"
 365    ;;
 366    *)
 367       EINA_LIBS="-ldl -lrt -lm"
 368    ;;
 369 esac
 370 AC_SUBST(EINA_LIBS)
 371 AC_SUBST(lt_enable_auto_import)
 372
 373 EFL_LINKER_FLAG([-fno-strict-aliasing])
 374
 375
 376 ### Checks for library functions
 377 AC_FUNC_ALLOCA
 378 AC_CHECK_FUNCS(strlcpy)
 379
 380 #dlopen and dladdr
 381 dlopen_libs=""
 382 case "$host_os" in
 383    mingw*)
 384 # managed by evil
 385       AC_DEFINE(HAVE_DLADDR)
 386       ;;
 387    *)
 388       AC_CHECK_FUNCS([dlopen], [res="yes"], [res="no"])
 389       if test "x${res}" = "xyes" ; then
 390          AC_CHECK_FUNCS([dladdr], [AC_DEFINE(HAVE_DLADDR)])
 391       else
 392          AC_CHECK_LIB([dl], [dlopen], [res="yes"], [res="no"])
 393          if test "x${res}" = "xyes" ; then
 394             AC_CHECK_LIB([dl], [dladdr], [AC_DEFINE(HAVE_DLADDR)])
 395             dlopen_libs="-ldl"
 396          else
 397             AC_MSG_ERROR([Cannot find dlopen])
 398          fi
 399       fi
 400       ;;
 401 esac
 402 AC_SUBST(dlopen_libs)
 403
 404 EFL_CHECK_FNMATCH([], [AC_MSG_ERROR([Cannot find fnmatch()])])
 405
 406 # iconv library
 407 have_iconv="no"
 408 AC_ARG_WITH([iconv-link],
 409    AC_HELP_STRING([--with-iconv-link=ICONV_LINK], [explicitly specify an iconv link option]),
 410    [
 411     LIBS="$withval $LIBS"
 412     have_iconv="yes"
 413    ])
 414
 415 AC_MSG_CHECKING(for explicit iconv link options)
 416 if test "x${iconv_libs}" = "x" ; then
 417    AC_MSG_RESULT([no explicit iconv link option])
 418 else
 419    AC_MSG_RESULT([$iconv_libs])
 420 fi
 421
 422 if test "x${have_iconv}" = "xno" ; then
 423    AC_CHECK_HEADERS([iconv.h], [have_iconv="yes"])
 424
 425    if test "x${have_iconv}" = "xyes" ; then
 426       AC_MSG_CHECKING([whether iconv() is in libc])
 427
 428       AC_LINK_IFELSE(
 429          [AC_LANG_PROGRAM(
 430              [[
 431 #include <stdlib.h>
 432 #include <iconv.h>
 433              ]],
 434              [[
 435 iconv_t ic;
 436 size_t count = iconv(ic, NULL, NULL, NULL, NULL);
 437              ]])],
 438          [have_iconv="yes"],
 439          [have_iconv="no"])
 440
 441       AC_MSG_RESULT([${have_iconv}])
 442    fi
 443
 444    if test "x${have_iconv}" = "xno" ; then
 445       AC_MSG_CHECKING([whether iconv() is in libiconv.a])
 446
 447       LIBS_save="${LIBS}"
 448       LIBS="-liconv $LIBS"
 449       AC_LINK_IFELSE(
 450          [AC_LANG_PROGRAM(
 451              [[
 452 #include <stdlib.h>
 453 #include <iconv.h>
 454              ]],
 455              [[
 456 iconv_t ic;
 457 size_t count;
 458 count = iconv(ic, NULL, NULL, NULL, NULL);
 459              ]])],
 460          [have_iconv="yes"],
 461          [
 462           have_iconv="no"
 463           LIBS=${LIBS_save}
 464          ])
 465
 466       AC_MSG_RESULT([${have_iconv}])
 467    fi
 468
 469    if test "x${have_iconv}" = "xno" ; then
 470       AC_MSG_CHECKING([whether iconv() is in libiconv_plug.a])
 471
 472       LIBS_save="${LIBS}"
 473       LIBS="-liconv_plug $LIBS"
 474       AC_LINK_IFELSE(
 475          [AC_LANG_PROGRAM(
 476              [[
 477 #include <stdlib.h>
 478 #include <iconv.h>
 479              ]],
 480              [[
 481 iconv_t ic;
 482 size_t count = iconv(ic, NULL, NULL, NULL, NULL);
 483              ]])],
 484          [have_iconv="yes"],
 485          [
 486           have_iconv="no"
 487           LIBS=${LIBS_save}
 488          ])
 489
 490       AC_MSG_RESULT([${have_iconv}])
 491    fi
 492 fi
 493
 494 if test "x${have_iconv}" = "xyes" ; then
 495    AC_DEFINE([HAVE_ICONV], [1], [Set to 1 if iconv library is installed])
 496 fi
 497
 498
 499 ### Modules
 500
 501 if test "x${have_default_mempool}" = "xyes" ; then
 502    enable_chained_pool="no"
 503    enable_pass_through="static"
 504 else
 505    enable_chained_pool="static"
 506    enable_pass_through="no"
 507 fi
 508
 509 enable_one_big="static"
 510
 511 EINA_CHECK_MODULE([chained-pool],   [${enable_chained_pool}], [chained pool])
 512 EINA_CHECK_MODULE([ememoa-fixed],   [${enable_ememoa}],       [ememoa fixed])
 513 EINA_CHECK_MODULE([ememoa-unknown], [${enable_ememoa}],       [ememoa unknown])
 514 EINA_CHECK_MODULE([fixed-bitmap],   [no],                     [fixed bitmap])
 515 EINA_CHECK_MODULE([pass-through],   [${enable_pass_through}], [pass through])
 516 EINA_CHECK_MODULE([buddy],          [no],                     [buddy])
 517 EINA_CHECK_MODULE([one-big],        [${enable_one_big}],      [one big])
 518
 519 ### Make the debug preprocessor configurable
 520
 521 ### Unit tests, coverage and benchmarking
 522
 523 EFL_CHECK_TESTS([enable_tests="yes"], [enable_tests="no"])
 524
 525 EFL_CHECK_COVERAGE([${enable_tests}], [enable_coverage="yes"], [enable_coverage="no"])
 526 EINA_CFLAGS="${EINA_CFLAGS} ${EFL_COVERAGE_CFLAGS}"
 527 EINA_LIBS="${EINA_LIBS} ${EFL_COVERAGE_LIBS}"
 528 if test "x$enable_coverage" = "xyes" ; then
 529    EINA_CFLAGS="${EINA_CFLAGS} ${EFL_DEBUG_CFLAGS}"
 530 fi
 531
 532 EFL_CHECK_BENCHMARK([enable_benchmark="yes"], [enable_benchmark="no"])
 533 EINA_BENCH_MODULE([glib], [${enable_benchmark}], [glib-2.0], [enable_benchmark_glib="yes"], [enable_benchmark_glib="no"])
 534
 535 AC_SUBST(requirement_eina)
 536
 537 ### Create the .pc.in file according to the major version
 538 #cat > ${srcdir}/eina-${VMAJ}.pc.in << EOF
 539 #prefix=@prefix@
 540 #exec_prefix=@exec_prefix@
 541 #libdir=@libdir@
 542 #includedir=@includedir@
 543 #
 544 #Name: Eina
 545 #Description: A Library that implements fast data types and miscellaneous tools
 546 #Requires:
 547 #Version: @VERSION@
 548 #Libs: -L${libdir} -leina
 549 #Libs.private: -ldl
 550 #Cflags: -I${includedir}/eina-@VMAJ@ -I${includedir}/eina-@VMAJ@/eina
 551 #EOF
 552
 553 AC_CONFIG_FILES([
 554 Makefile
 555 eina-0.pc
 556 eina.spec
 557 doc/Makefile
 558 src/Makefile
 559 src/include/Makefile
 560 src/include/eina_config.h
 561 src/lib/Makefile
 562 src/modules/Makefile
 563 src/modules/mp/Makefile
 564 src/modules/mp/chained_pool/Makefile
 565 src/modules/mp/ememoa_fixed/Makefile
 566 src/modules/mp/ememoa_unknown/Makefile
 567 src/modules/mp/pass_through/Makefile
 568 src/modules/mp/fixed_bitmap/Makefile
 569 src/modules/mp/buddy/Makefile
 570 src/modules/mp/one_big/Makefile
 571 src/tests/Makefile
 572 ])
 573
 574 AC_OUTPUT
 575
 576 #####################################################################
 577 ## Info
 578
 579 echo
 580 echo
 581 echo
 582 echo "------------------------------------------------------------------------"
 583 echo "$PACKAGE $VERSION"
 584 echo "------------------------------------------------------------------------"
 585 echo
 586 echo
 587 echo "Configuration Options Summary:"
 588 echo
 589 echo "  Magic debug..........: ${have_magic_debug}"
 590 echo "  Safety checks........: ${have_safety_checks}"
 591 echo "  Maximum log level....: ${with_max_log_level}"
 592 echo "  Report string usage..: ${have_stringshare_usage}"
 593 echo "  Default mempool......: ${have_default_mempool}"
 594 echo "  Thread Support.......: ${have_threads}"
 595 if test "${have_threads}" = "POSIX" ; then
 596 echo "    spinlock...........: ${have_posix_threads_spinlock}"
 597 echo "    rwlock.............: ${have_posix_threads_rwlock}"
 598 fi
 599 echo "  Amalgamation.........: ${do_amalgamation}"
 600 echo "  Iconv support........: ${have_iconv}"
 601 echo
 602 echo "  Documentation........: ${build_doc}"
 603 echo "  Tests................: ${enable_tests}"
 604 echo "  Coverage.............: ${enable_coverage}"
 605 echo "  Benchmark............: ${enable_benchmark}"
 606 if test "x${enable_benchmark}" = "xyes" ; then
 607 echo "    Glib...............: ${enable_benchmark_glib}"
 608 echo "    E17 real data......: ${enable_benchmark_e17}"
 609 fi
 610 echo
 611 echo "  CPU Specific Extensions:"
 612 echo "    MMX................: ${have_mmx}"
 613 echo "    SSE................: ${have_sse}"
 614 echo "    SSE2...............: ${have_sse2}"
 615 echo "    ALTIVEC............: ${have_altivec}"
 616 echo
 617 echo "  Memory pools:"
 618 echo "    Chained pool.......: ${enable_chained_pool}"
 619 echo "    Ememoa fixed.......: ${enable_ememoa_fixed}"
 620 echo "    Ememoa unknown.....: ${enable_ememoa_unknown}"
 621 echo "    Fixed bitmap.......: ${enable_fixed_bitmap}"
 622 echo "    Pass through.......: ${enable_pass_through}"
 623 echo "    Buddy..............: ${enable_buddy}"
 624 echo "    One big............: ${enable_one_big}"
 625 echo
 626 echo "Compilation............: make (or gmake)"
 627 echo "  CPPFLAGS.............: $CPPFLAGS"
 628 echo "  CFLAGS...............: $CFLAGS"
 629 echo "  LDFLAGS..............: $LDFLAGS"
 630 echo
 631 echo "Installation...........: make install (as root if needed, with 'su' or 'sudo')"
 632 echo "  prefix...............: $prefix"
 633 echo
 634 EFL_FORM_VOLTRON