configure.ac

   1 AC_PREREQ([2.64])
   2 AC_INIT([wayland-demos],
   3         [0.1],
   4         [https://bugs.freedesktop.org/enter_bug.cgi?product=wayland],
   5         [wayland-demos],
   6         [http://wayland.freedesktop.org/])
   7
   8 AC_CONFIG_HEADERS([config.h])
   9
  10 AM_INIT_AUTOMAKE([1.11 foreign dist-bzip2])
  11
  12 AM_SILENT_RULES([yes])
  13
  14 # Check for programs
  15 AC_PROG_CC
  16 AC_PROG_RANLIB
  17
  18 # Initialize libtool
  19 LT_PREREQ([2.2])
  20 LT_INIT
  21
  22 PKG_PROG_PKG_CONFIG()
  23
  24 PKG_CHECK_MODULES([XCB], xcb)
  25 xcb_save_LIBS=$LIBS
  26 xcb_save_CFLAGS=$CFLAGS
  27 CFLAGS=$XCB_CFLAGS
  28 LIBS=$XCB_LIBS
  29 AC_CHECK_FUNCS([xcb_poll_for_queued_event])
  30 LIBS=$xcb_save_LIBS
  31 CFLAGS=$xcb_save_CFLAGS
  32
  33 AC_CHECK_FUNC([dlopen], [],
  34               AC_CHECK_LIB([dl], [dlopen], DLOPEN_LIBS="-ldl"))
  35 AC_SUBST(DLOPEN_LIBS)
  36
  37 PKG_CHECK_MODULES(COMPOSITOR,
  38                   [wayland-server egl >= 7.10 glesv2 gdk-pixbuf-2.0 pixman-1])
  39
  40 AC_CHECK_PROG(RSVG_CONVERT, rsvg-convert, rsvg-convert)
  41 AM_CONDITIONAL(HAVE_RSVG_CONVERT, test -n "$RSVG_CONVERT")
  42
  43 AC_ARG_ENABLE(x11-compositor, [  --enable-x11-compositor],,
  44               enable_x11_compositor=yes)
  45 AM_CONDITIONAL(ENABLE_X11_COMPOSITOR, test x$enable_x11_compositor == xyes)
  46 if test x$enable_x11_compositor == xyes; then
  47   AC_DEFINE([BUILD_X11_COMPOSITOR], [1], [Build the X11 compositor])
  48   PKG_CHECK_MODULES(X11_COMPOSITOR, [x11 x11-xcb])
  49 fi
  50
  51
  52 AC_ARG_ENABLE(drm-compositor, [  --enable-drm-compositor],,
  53               enable_drm_compositor=yes)
  54 AM_CONDITIONAL(ENABLE_DRM_COMPOSITOR, test x$enable_drm_compositor == xyes)
  55 if test x$enable_drm_compositor == xyes; then
  56   AC_DEFINE([BUILD_DRM_COMPOSITOR], [1], [Build the DRM compositor])
  57   PKG_CHECK_MODULES(DRM_COMPOSITOR, [libudev >= 136 libdrm >= 2.4.23])
  58 fi
  59
  60
  61 AC_ARG_ENABLE(openwfd-compositor, [  --enable-openwfd-compositor],,
  62               enable_openwfd_compositor=no)
  63 AM_CONDITIONAL(ENABLE_OPENWFD_COMPOSITOR, test x$enable_openwfd_compositor == xyes)
  64 if test x$enable_openwfd_compositor == xyes; then
  65   AC_DEFINE([BUILD_OPENWFD_COMPOSITOR], [1], [Build the OpenWF compositor])
  66   PKG_CHECK_MODULES(OPENWFD_COMPOSITOR, [openwfd])
  67 fi
  68
  69
  70 AC_ARG_ENABLE(wayland-compositor, [  --enable-wayland-compositor],,
  71               enable_wayland_compositor=yes)
  72 AM_CONDITIONAL(ENABLE_WAYLAND_COMPOSITOR,
  73                test x$enable_wayland_compositor == xyes)
  74 if test x$enable_wayland_compositor == xyes; then
  75   AC_DEFINE([BUILD_WAYLAND_COMPOSITOR], [1],
  76             [Build the Wayland (nested) compositor])
  77   PKG_CHECK_MODULES(WAYLAND_COMPOSITOR, [wayland-client wayland-egl])
  78 fi
  79
  80
  81 AC_ARG_ENABLE(clients, [  --enable-clients],, enable_clients=yes)
  82 AM_CONDITIONAL(BUILD_CLIENTS, test x$enable_clients == xyes)
  83 if test x$enable_clients == xyes; then
  84   AC_DEFINE([BUILD_CLIENTS], [1], [Build the Wayland clients])
  85
  86   PKG_CHECK_MODULES(SIMPLE_CLIENT,
  87                     [egl >= 7.10 glesv2 wayland-client wayland-egl])
  88   PKG_CHECK_MODULES(CLIENT, [wayland-client wayland-egl egl >= 7.10 gl cairo >= 1.10.0 gdk-pixbuf-2.0 glib-2.0 gobject-2.0 xkbcommon])
  89
  90   PKG_CHECK_MODULES(POPPLER, [poppler-glib gdk-2.0 gio-2.0],
  91                              [have_poppler=yes], [have_poppler=no])
  92   PKG_CHECK_MODULES(CAIRO_EGL, [cairo-egl >= 1.11.3],
  93                     [have_cairo_egl=yes], [have_cairo_egl=no])
  94   AS_IF([test "x$have_cairo_egl" = "xyes"],
  95         [AC_DEFINE([HAVE_CAIRO_EGL], [1], [Have cairo-egl])])
  96 fi
  97
  98 AM_CONDITIONAL(HAVE_POPPLER, test "x$have_poppler" = "xyes")
  99
 100 if test "x$GCC" = "xyes"; then
 101         GCC_CFLAGS="-Wall -g -Wstrict-prototypes -Wmissing-prototypes -fvisibility=hidden"
 102 fi
 103 AC_SUBST(GCC_CFLAGS)
 104
 105 # workaround a bug in xcb-dri2 generated by xcb-proto 1.6
 106 AC_CHECK_LIB(xcb-dri2, xcb_dri2_connect_alignment_pad, [],
 107              [AC_DEFINE([XCB_DRI2_CONNECT_DEVICE_NAME_BROKEN], [1],
 108                         [Define to 1 if xcb_dri2_connect_device_name is broken])])
 109
 110 WAYLAND_SCANNER_RULES(['$(top_srcdir)/protocol'])
 111
 112 AC_CONFIG_FILES([Makefile
 113                  compositor/Makefile
 114                  clients/Makefile
 115                  data/Makefile])
 116 AC_OUTPUT