configure.ac

   1 dnl  Copyright © 2008 Dan Nicholson
   2 dnl
   3 dnl  Permission to use, copy, modify, distribute, and sell this software and its
   4 dnl  documentation for any purpose is hereby granted without fee, provided that
   5 dnl  the above copyright notice appear in all copies and that both that
   6 dnl  copyright notice and this permission notice appear in supporting
   7 dnl  documentation, and that the name of Keith Packard not be used in
   8 dnl  advertising or publicity pertaining to distribution of the software without
   9 dnl  specific, written prior permission.  Keith Packard makes no
  10 dnl  representations about the suitability of this software for any purpose.  It
  11 dnl  is provided "as is" without express or implied warranty.
  12 dnl
  13 dnl  DAN NICHOLSON DISCLAIMS ALL WARRANTIES WITH REGARD TO THIS SOFTWARE,
  14 dnl  INCLUDING ALL IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS, IN NO
  15 dnl  EVENT SHALL KEITH PACKARD BE LIABLE FOR ANY SPECIAL, INDIRECT OR
  16 dnl  CONSEQUENTIAL DAMAGES OR ANY DAMAGES WHATSOEVER RESULTING FROM LOSS OF USE,
  17 dnl  DATA OR PROFITS, WHETHER IN AN ACTION OF CONTRACT, NEGLIGENCE OR OTHER
  18 dnl  TORTIOUS ACTION, ARISING OUT OF OR IN CONNECTION WITH THE USE OR
  19 dnl  PERFORMANCE OF THIS SOFTWARE.
  20 dnl
  21 dnl Process this file with autoconf to create configure.
  22
  23 # Initialize Autoconf
  24 AC_PREREQ([2.62])
  25 AC_INIT([libxkbcommon], [0.1.0],
  26     [https://bugs.freedesktop.org/enter_bug.cgi?product=libxkbcommon])
  27 AC_CONFIG_SRCDIR([Makefile.am])
  28 AC_CONFIG_HEADERS([src/config.h])
  29 AC_CONFIG_MACRO_DIR([m4])
  30
  31 # Initialize Automake
  32 AM_INIT_AUTOMAKE([foreign dist-bzip2 subdir-objects color-tests parallel-tests])
  33 AM_MAINTAINER_MODE([enable])
  34
  35 # Get _GNU_SOURCE and friends
  36 AC_USE_SYSTEM_EXTENSIONS
  37
  38 # Initialize libtool
  39 LT_INIT
  40
  41 # Require xorg-macros minimum of 1.8 for AM_SILENT_RULES
  42 m4_ifndef([XORG_MACROS_VERSION],
  43           [m4_fatal([must install xorg-macros 1.8 or later before running autoconf/autogen])])
  44 XORG_MACROS_VERSION(1.8)
  45 XORG_DEFAULT_OPTIONS
  46 XORG_MEMORY_CHECK_FLAGS
  47 XORG_ENABLE_DOCS
  48 XORG_WITH_DOXYGEN
  49
  50 # Check for compiler features
  51 AC_C_INLINE
  52 AC_C_TYPEOF
  53
  54 # Check for programs
  55 AC_PROG_MKDIR_P
  56 AC_PROG_LEX
  57 AC_PROG_YACC
  58 AC_PATH_PROG([YACC_INST], $YACC)
  59 if test ! -f "src/xkbcomp/parser.c"; then
  60    if test -z "$YACC_INST"; then
  61       AC_MSG_ERROR([yacc not found - unable to compile src/xkbcomp/parser.y])
  62    fi
  63 fi
  64 AM_PATH_PYTHON([2.6], [], [
  65     AC_MSG_ERROR([python not found - unable to run makekeys])
  66 ])
  67
  68 # Checks for library functions.
  69 AC_CHECK_FUNCS([strcasecmp strncasecmp])
  70 if test "x$ac_cv_func_strcasecmp" = xno || \
  71    test "x$ac_cv_func_strncasecmp" = xno; then
  72     AC_MSG_ERROR([C library does not support strcasecmp/strncasecmp])
  73 fi
  74
  75 AC_CHECK_FUNCS([eaccess euidaccess])
  76
  77 XORG_TESTSET_CFLAG([CFLAGS], [-fvisibility=hidden])
  78
  79 # Define a configuration option for the XKB config root
  80 xkb_base=`$PKG_CONFIG --variable=xkb_base xkeyboard-config`
  81 if test "x$xkb_base" = x; then
  82     xkb_base=$datadir/X11/xkb
  83 fi
  84 AC_ARG_WITH([xkb_config_root],
  85     [AS_HELP_STRING([--with-xkb-config-root=<path>],
  86         [Set default XKB config root (default: xkeyboard-config install path)])],
  87     [XKBCONFIGROOT="$withval"],
  88     [XKBCONFIGROOT="$xkb_base"])
  89 AC_SUBST([XKBCONFIGROOT])
  90
  91 AC_ARG_WITH([default_rules],
  92     [AS_HELP_STRING([--with-default-rules=<path>],
  93         [Default XKB ruleset (default: evdev)])],
  94     [DEFAULT_XKB_RULES="$withval"],
  95     [DEFAULT_XKB_RULES="evdev"])
  96 AC_DEFINE_UNQUOTED([DEFAULT_XKB_RULES], ["$DEFAULT_XKB_RULES"],
  97                    [Default XKB ruleset])
  98
  99 AC_ARG_WITH([default_model],
 100     [AS_HELP_STRING([--with-default-model=<path>],
 101         [Default XKB model (default: pc105)])],
 102     [DEFAULT_XKB_MODEL="$withval"],
 103     [DEFAULT_XKB_MODEL="pc105"])
 104 AC_DEFINE_UNQUOTED([DEFAULT_XKB_MODEL], ["$DEFAULT_XKB_MODEL"],
 105                    [Default XKB model])
 106
 107 AC_ARG_WITH([default_layout],
 108     [AS_HELP_STRING([--with-default-layout=<path>],
 109         [Default XKB layout (default: us)])],
 110     [DEFAULT_XKB_LAYOUT="$withval"],
 111     [DEFAULT_XKB_LAYOUT="us"])
 112 AC_DEFINE_UNQUOTED([DEFAULT_XKB_LAYOUT], ["$DEFAULT_XKB_LAYOUT"],
 113                    [Default XKB layout])
 114
 115 AC_CONFIG_FILES([
 116     Makefile
 117     xkbcommon-uninstalled.pc
 118     xkbcommon.pc
 119     doc/Doxyfile
 120 ])
 121 AC_OUTPUT