configure.ac

   1 # -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # This file is part of PulseAudio.
   5 #
   6 # Copyright 2004-2008 Lennart Poettering
   7 # Copyright 2006-2007 Pierre Ossman <ossman@cendio.se> for Cendio AB
   8 #
   9 # PulseAudio is free software; you can redistribute it and/or modify it
  10 # under the terms of the GNU Lesser General Public License as published by
  11 # the Free Software Foundation; either version 2 of the License, or
  12 # (at your option) any later version.
  13 #
  14 # PulseAudio is distributed in the hope that it will be useful, but
  15 # WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  17 # General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public License
  20 # along with PulseAudio; if not, see <http://www.gnu.org/licenses/>.
  21
  22 AC_PREREQ(2.63)
  23
  24 AC_INIT([pulseaudio],[m4_esyscmd(./git-version-gen .tarball-version)],[pulseaudio-discuss (at) lists (dot) freedesktop (dot) org],[pulseaudio],[http://pulseaudio.org/])
  25 AC_CONFIG_SRCDIR([src/daemon/main.c])
  26 AC_CONFIG_MACRO_DIR([m4])
  27 AC_CONFIG_HEADERS([config.h])
  28 AC_CONFIG_AUX_DIR([build-aux])
  29 AM_INIT_AUTOMAKE([foreign 1.11 -Wall -Wno-portability subdir-objects silent-rules color-tests dist-xz tar-ustar])
  30
  31 AS_IF([! test -n "$VERSION"], [
  32    AC_MSG_ERROR([git-version-gen failed])
  33 ])
  34
  35 m4_define(pa_major, `echo $VERSION | cut -d. -f1 | cut -d- -f1`)
  36 m4_define(pa_minor, `echo $VERSION | cut -d. -f2 | cut -d- -f1`)
  37
  38 AC_SUBST(PA_MAJOR, pa_major)
  39 AC_SUBST(PA_MINOR, pa_minor)
  40 AC_SUBST(PA_MAJORMINOR, pa_major.pa_minor)
  41
  42 AC_SUBST(PA_API_VERSION, 12)
  43 AC_SUBST(PA_PROTOCOL_VERSION, 30)
  44
  45 # The stable ABI for client applications, for the version info x:y:z
  46 # always will hold y=z
  47 AC_SUBST(LIBPULSE_VERSION_INFO, [18:0:18])
  48
  49 # A simplified, synchronous, ABI-stable interface for client
  50 # applications, for the version info x:y:z always will hold y=z
  51 AC_SUBST(LIBPULSE_SIMPLE_VERSION_INFO, [1:0:1])
  52
  53 # The ABI-stable GLib adapter for client applications, for the version
  54 # info x:y:z always will hold y=z
  55 AC_SUBST(LIBPULSE_MAINLOOP_GLIB_VERSION_INFO, [0:5:0])
  56
  57 AC_CANONICAL_HOST
  58 AC_DEFINE_UNQUOTED([CANONICAL_HOST], "$host", [Canonical host string.])
  59
  60 AC_CHECK_PROG([STOW], [stow], [yes], [no])
  61
  62 AS_IF([test "x$STOW" = "xyes" && test -d /usr/local/stow], [
  63     AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
  64     ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
  65 ])
  66
  67 AM_SILENT_RULES([yes])
  68
  69
  70 #### Checks for programs. ####
  71
  72 # mkdir -p
  73
  74 AC_PROG_MKDIR_P
  75
  76 # ln -s
  77
  78 AC_PROG_LN_S
  79
  80 # CC
  81
  82 AC_PROG_CC
  83 AC_PROG_CC_C99
  84 AM_PROG_CC_C_O
  85 # Only required if you want the WebRTC canceller -- no runtime dep on
  86 # libstdc++ otherwise
  87 AC_PROG_CXX
  88 AC_PROG_GCC_TRADITIONAL
  89 AC_USE_SYSTEM_EXTENSIONS
  90
  91 # M4
  92
  93 AC_CHECK_PROGS([M4], gm4 m4, no)
  94 AS_IF([test "x$M4" = "xno"], AC_MSG_ERROR([m4 missing]))
  95
  96 # pkg-config
  97
  98 PKG_PROG_PKG_CONFIG
  99
 100 # gettext
 101
 102 if test "x$enable_nls" != "xno"; then
 103 IT_PROG_INTLTOOL([0.35.0])
 104
 105 AM_GNU_GETTEXT_VERSION([0.18.1])
 106 AM_GNU_GETTEXT([external])
 107
 108 GETTEXT_PACKAGE=pulseaudio
 109 AC_SUBST([GETTEXT_PACKAGE])
 110 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["$GETTEXT_PACKAGE"],[Gettext package])
 111
 112 pulselocaledir='${prefix}/${DATADIRNAME}/locale'
 113 AX_DEFINE_DIR(PULSE_LOCALEDIR, pulselocaledir, [Gettext locale dir])
 114 else
 115 # workaround till an intltool m4 bug is fixed upstream
 116 # (https://bugs.launchpad.net/intltool/+bug/904647)
 117 USE_NLS=no
 118 AC_SUBST(USE_NLS)
 119 fi
 120
 121
 122 #### Determine host OS ####
 123
 124 # if the host has the possibility of sys/capability.h for dropping privileges
 125 # used to determine if we should error out if it is not found
 126 host_has_caps=0
 127
 128 os_is_linux=0
 129 os_is_win32=0
 130 os_is_darwin=0
 131
 132 AC_MSG_CHECKING([host operating system])
 133 case "$host_os" in
 134     linux*)
 135         AC_MSG_RESULT([linux])
 136         host_has_caps=1
 137         os_is_linux=1
 138     ;;
 139     freebsd*)
 140         AC_MSG_RESULT([freebsd])
 141         host_has_caps=1
 142     ;;
 143     darwin*)
 144         AC_MSG_RESULT([darwin])
 145         os_is_darwin=1
 146         AC_DEFINE([OS_IS_DARWIN], 1, [Build target is Darwin.])
 147     ;;
 148     mingw*)
 149         AC_MSG_RESULT([win32])
 150         os_is_win32=1
 151         AC_DEFINE([OS_IS_WIN32], 1, [Build target is Windows.])
 152     ;;
 153     *)
 154         AC_MSG_RESULT([unknown])
 155     ;;
 156 esac
 157
 158 AM_CONDITIONAL(OS_IS_DARWIN, test "x$os_is_darwin" = "x1")
 159 AM_CONDITIONAL(OS_IS_WIN32, test "x$os_is_win32" = "x1")
 160 AC_SUBST([OS_IS_WIN32], [$os_is_win32])
 161
 162 # Platform specific hacks
 163 case "$host_os" in
 164     darwin* )
 165         AC_DEFINE([_DARWIN_C_SOURCE], [200112L], [Needed to get NSIG on Mac OS X])
 166     ;;
 167     mingw* )
 168         AC_DEFINE([WIN32_LEAN_AND_MEAN], 1, [Needed to avoid including unnecessary headers on Windows])
 169     ;;
 170     solaris* )
 171         AC_DEFINE(_XOPEN_SOURCE,       600, [Needed to get declarations for msg_control and msg_controllen on Solaris])
 172         AC_DEFINE(__EXTENSIONS__,        1, [Needed to get declarations for msg_control and msg_controllen on Solaris])
 173     ;;
 174 esac
 175
 176
 177 #### Compiler flags ####
 178
 179 AX_APPEND_COMPILE_FLAGS(
 180     [-Wall -W -Wextra -pipe -Wno-long-long -Wno-overlength-strings -Wunsafe-loop-optimizations -Wundef -Wformat=2 -Wlogical-op -Wsign-compare -Wformat-security -Wmissing-include-dirs -Wformat-nonliteral -Wold-style-definition -Wpointer-arith -Winit-self -Wdeclaration-after-statement -Wfloat-equal -Wmissing-prototypes -Wstrict-prototypes -Wredundant-decls -Wmissing-declarations -Wmissing-noreturn -Wshadow -Wendif-labels -Wcast-align -Wstrict-aliasing -Wwrite-strings -Wno-unused-parameter -ffast-math -fno-common -fdiagnostics-show-option -fdiagnostics-color=auto],
 181     [], [-pedantic -Werror])
 182
 183 AS_CASE([" $CFLAGS "], [*" -O0 "*], [], [
 184     # Don't append the flag if it already exists.
 185     # Only enable fastpath asserts when doing a debug build, e.g. from bootstrap.sh.
 186     AX_APPEND_FLAG([-DFASTPATH], [CPPFLAGS])
 187
 188     # Cannot use AX_APPEND_FLAG here, as it assumes no space inside the added flags.
 189     # Cannot append flags with AX_APPEND_FLAG one by one, as this would destroy all fortifications
 190     # if CPPFLAGS already contain -D_FORTIFY_SOURCE=2.
 191
 192     # Warnings to be aware of that appear with -D_FORTIFY_SOURCE=2 but without -U_FORTIFY_SOURCE:
 193     # On Fedora 20 with -O0: #warning _FORTIFY_SOURCE requires compiling with optimization (-O) [-Wcpp]
 194     # On Gentoo with -O2:    "_FORTIFY_SOURCE" redefined [enabled by default]
 195     AS_VAR_APPEND([CPPFLAGS],[" -U_FORTIFY_SOURCE -D_FORTIFY_SOURCE=2"])
 196 ])
 197
 198 #### Linker flags ####
 199
 200 # Check whether the linker supports the -version-script option.
 201 # The Make variable $(srcdir) needs to be in the LDFLAGS in that form,
 202 # so that it is expanded the right way in every subdir.
 203 AX_CHECK_LINK_FLAG(["-Wl,-version-script=${srcdir}/src/map-file"],
 204     [VERSIONING_LDFLAGS='-Wl,-version-script=$(abs_top_srcdir)/src/map-file'])
 205 AC_SUBST([VERSIONING_LDFLAGS])
 206
 207 # Use immediate (now) bindings; avoids the funky re-call in itself.
 208 # The -z now syntax is lifted from Sun's linker and works with GNU's too, other linkers might be added later.
 209 AX_APPEND_LINK_FLAGS([-Wl,-z,now], [IMMEDIATE_LDFLAGS])
 210 AC_SUBST([IMMEDIATE_LDFLAGS])
 211
 212 # On ELF systems we don't want the libraries to be unloaded since we don't clean them up properly,
 213 # so we request the nodelete flag to be enabled.
 214 # On other systems, we don't really know how to do that, but it's welcome if somebody can tell.
 215 AX_APPEND_LINK_FLAGS([-Wl,-z,nodelete], [NODELETE_LDFLAGS])
 216 AC_SUBST([NODELETE_LDFLAGS])
 217
 218 # Check for the proper way to build libraries that have no undefined symbols
 219 case $host in
 220     # FreeBSD (et al.) does not complete linking for shared objects when pthreads
 221     # are requested, as different implementations are present.
 222     *-freebsd* | *-openbsd*) ;;
 223     *)
 224         for possible_flag in "-Wl,--no-undefined" "-Wl,-z,defs"; do
 225             AX_CHECK_LINK_FLAG([$possible_flag], [NOUNDEFINED_LDFLAGS="$possible_flag"; break])
 226         done
 227     ;;
 228 esac
 229 AC_SUBST([NOUNDEFINED_LDFLAGS])
 230
 231
 232 #### Atomic operations ####
 233
 234 # Native atomic operation support
 235 AC_ARG_ENABLE([atomic-arm-linux-helpers],
 236     AS_HELP_STRING([--disable-atomic-arm-linux-helpers],[use inline asm or libatomic_ops instead]))
 237
 238 AC_ARG_ENABLE([atomic-arm-memory-barrier],
 239     AS_HELP_STRING([--enable-atomic-arm-memory-barrier],[only really needed in SMP arm systems]))
 240
 241 if test "x$enable_atomic_arm_memory_barrier" = "xyes"; then
 242     AC_DEFINE_UNQUOTED(ATOMIC_ARM_MEMORY_BARRIER_ENABLED, 1, [Enable memory barriers])
 243 fi
 244
 245 # If everything else fails use libatomic_ops
 246 need_libatomic_ops=yes
 247
 248 AC_CACHE_CHECK([whether $CC knows __sync_bool_compare_and_swap()],
 249     pulseaudio_cv_sync_bool_compare_and_swap, [
 250     AC_LINK_IFELSE(
 251         [AC_LANG_PROGRAM([], [[int a = 4; __sync_bool_compare_and_swap(&a, 4, 5);]])],
 252         [pulseaudio_cv_sync_bool_compare_and_swap=yes],
 253         [pulseaudio_cv_sync_bool_compare_and_swap=no])
 254     ])
 255
 256 if test "$pulseaudio_cv_sync_bool_compare_and_swap" = "yes" ; then
 257     AC_DEFINE([HAVE_ATOMIC_BUILTINS], 1, [Have __sync_bool_compare_and_swap() and friends.])
 258     need_libatomic_ops=no
 259 else
 260     # HW specific atomic ops stuff
 261     AC_MSG_CHECKING([architecture for native atomic operations])
 262     case $host in
 263         arm*)
 264             AC_MSG_RESULT([arm])
 265             AC_MSG_CHECKING([whether we can use Linux kernel helpers])
 266             # The Linux kernel helper functions have been there since 2.6.16. However
 267             # compile time checking for kernel version in cross compile environment
 268             # (which is usually the case for arm cpu) is tricky (or impossible).
 269             if test "x$os_is_linux" = "x1" && test "x$enable_atomic_arm_linux_helpers" != "xno"; then
 270                 AC_MSG_RESULT([yes])
 271                 AC_DEFINE_UNQUOTED(ATOMIC_ARM_LINUX_HELPERS, 1, [special arm linux implementation])
 272                 need_libatomic_ops=no
 273             else
 274                 AC_MSG_RESULT([no])
 275                 AC_CACHE_CHECK([compiler support for arm inline asm atomic operations],
 276                     pulseaudio_cv_support_arm_atomic_ops, [
 277                     AC_COMPILE_IFELSE(
 278                         [AC_LANG_PROGRAM([], [[
 279                             volatile int a=0;
 280                             int o=0, n=1, r;
 281                             asm volatile ("ldrex    %0, [%1]\n"
 282                                           "subs  %0, %0, %2\n"
 283                                           "strexeq %0, %3, [%1]\n"
 284                                           : "=&r" (r)
 285                                           : "r" (&a), "Ir" (o), "r" (n)
 286                                           : "cc");
 287                             return (a==1 ? 0 : -1);
 288                         ]])],
 289                         [pulseaudio_cv_support_arm_atomic_ops=yes],
 290                         [pulseaudio_cv_support_arm_atomic_ops=no])
 291                 ])
 292                 AS_IF([test "$pulseaudio_cv_support_arm_atomic_ops" = "yes"], [
 293                     AC_DEFINE([ATOMIC_ARM_INLINE_ASM], 1, [Have ARM atomic instructions.])
 294                     need_libatomic_ops=no
 295                 ])
 296             fi
 297         ;;
 298         *-netbsdelf5*)
 299             AC_MSG_RESULT([yes])
 300             need_libatomic_ops=no
 301         ;;
 302         *-freebsd*)
 303             AC_MSG_RESULT([yes])
 304             need_libatomic_ops=no
 305         ;;
 306         *)
 307             AC_MSG_RESULT([unknown])
 308         ;;
 309     esac
 310 fi
 311
 312 # If we're on ARM, check for the ARMV6 instructions we need */
 313 case $host in
 314   arm*)
 315     AC_CACHE_CHECK([support for required armv6 instructions],
 316       pulseaudio_cv_support_armv6,
 317       [AC_COMPILE_IFELSE(
 318          [AC_LANG_PROGRAM([],
 319            [[volatile int a = -60000, b = 0xaaaabbbb, c = 0xccccdddd;
 320              asm volatile ("ldr r0, %2 \n"
 321                            "ldr r2, %3 \n"
 322                            "ldr r3, %4 \n"
 323                            "ssat r1, #8, r0 \n"
 324                            "str r1, %0 \n"
 325                            "pkhbt r1, r3, r2, LSL #8 \n"
 326                            "str r1, %1 \n"
 327                            : "=m" (a), "=m" (b)
 328                            : "m" (a), "m" (b), "m" (c)
 329                            : "r0", "r1", "r2", "r3", "cc");
 330              return (a == -128 && b == 0xaabbdddd) ? 0 : -1;
 331            ]])],
 332          [pulseaudio_cv_support_armv6=yes],
 333          [pulseaudio_cv_support_armv6=no])
 334       ])
 335     AS_IF([test "$pulseaudio_cv_support_armv6" = "yes"], [
 336         AC_DEFINE([HAVE_ARMV6], 1, [Have ARMv6 instructions.])
 337       ])
 338   ;;
 339   *)
 340   ;;
 341 esac
 342
 343 #### NEON optimisations ####
 344 AC_ARG_ENABLE([neon-opt],
 345     AS_HELP_STRING([--enable-neon-opt], [Enable NEON optimisations on ARM CPUs that support it]))
 346
 347 AS_IF([test "x$enable_neon_opt" != "xno"],
 348     [save_CFLAGS="$CFLAGS"; CFLAGS="-mfpu=neon $CFLAGS"
 349      AC_COMPILE_IFELSE(
 350         [AC_LANG_PROGRAM([[#include <arm_neon.h>]], [])],
 351         [
 352          HAVE_NEON=1
 353          NEON_CFLAGS="-mfpu=neon"
 354         ],
 355         [
 356          HAVE_NEON=0
 357          NEON_CFLAGS=
 358         ])
 359      CFLAGS="$save_CFLAGS"
 360     ],
 361     [HAVE_NEON=0])
 362
 363 AS_IF([test "x$enable_neon_opt" = "xyes" && test "x$HAVE_NEON" = "x0"],
 364       [AC_MSG_ERROR([*** Compiler does not support -mfpu=neon or CFLAGS override -mfpu])])
 365
 366 AC_SUBST(HAVE_NEON)
 367 AC_SUBST(NEON_CFLAGS)
 368 AM_CONDITIONAL([HAVE_NEON], [test "x$HAVE_NEON" = x1])
 369 AS_IF([test "x$HAVE_NEON" = "x1"], AC_DEFINE([HAVE_NEON], 1, [Have NEON support?]))
 370
 371
 372 #### libtool stuff ####
 373
 374 LT_PREREQ(2.4)
 375 LT_INIT([dlopen win32-dll disable-static])
 376
 377 dnl As an extra safety device, check for lt_dladvise_init() which is
 378 dnl only implemented in libtool 2.x, and refine as we go if we have
 379 dnl refined requirements.
 380 dnl
 381 dnl Check the header files first since the system may have a
 382 dnl libltdl.so for runtime, but no headers, and we want to bail out as
 383 dnl soon as possible.
 384 dnl
 385 dnl We don't need any special variable for this though, since the user
 386 dnl can give the proper place to find libltdl through the standard
 387 dnl variables like LDFLAGS and CPPFLAGS.
 388
 389 AC_CHECK_HEADER([ltdl.h],
 390     [AC_CHECK_LIB([ltdl], [lt_dladvise_init], [LIBLTDL=-lltdl], [LIBLTDL=])],
 391     [LIBLTDL=])
 392
 393 AS_IF([test "x$LIBLTDL" = "x"],
 394     [AC_MSG_ERROR([Unable to find libltdl version 2. Makes sure you have libtool 2.4 or later installed.])])
 395 AC_SUBST([LIBLTDL])
 396
 397
 398 ###################################
 399 #   Basic environment checks      #
 400 ###################################
 401
 402 #### Checks for header files. ####
 403
 404 # ISO
 405 AC_HEADER_STDC
 406
 407 # POSIX
 408 AC_CHECK_HEADERS_ONCE([arpa/inet.h glob.h grp.h netdb.h netinet/in.h \
 409     netinet/in_systm.h netinet/tcp.h poll.h pwd.h sched.h \
 410     sys/mman.h sys/select.h sys/socket.h sys/wait.h \
 411     sys/uio.h syslog.h sys/dl.h dlfcn.h linux/sockios.h])
 412 AC_CHECK_HEADERS([netinet/ip.h], [], [],
 413                  [#include <sys/types.h>
 414                   #if HAVE_NETINET_IN_H
 415                   # include <netinet/in.h>
 416                   #endif
 417                   #if HAVE_NETINET_IN_SYSTM_H
 418                   # include <netinet/in_systm.h>
 419                   #endif
 420                  ])
 421 AC_CHECK_HEADERS([sys/resource.h], [HAVE_SYS_RESOURCE_H=1], [HAVE_SYS_RESOURCE_H=0])
 422 AC_SUBST(HAVE_SYS_RESOURCE_H)
 423 AC_CHECK_HEADERS([sys/un.h], [HAVE_AF_UNIX=1], [HAVE_AF_UNIX=0])
 424 AM_CONDITIONAL(HAVE_AF_UNIX, test "x$HAVE_AF_UNIX" = "x1")
 425 AC_SUBST(HAVE_AF_UNIX)
 426
 427 # Linux
 428 AC_CHECK_HEADERS([linux/input.h], [HAVE_EVDEV=1], [HAVE_EVDEV=0])
 429 AM_CONDITIONAL([HAVE_EVDEV], [test "x$HAVE_EVDEV" = "x1"])
 430
 431 AC_CHECK_HEADERS_ONCE([sys/prctl.h])
 432
 433 # Solaris
 434 AC_CHECK_HEADERS_ONCE([sys/filio.h])
 435
 436 # Windows
 437 AC_CHECK_HEADERS_ONCE([windows.h winsock2.h ws2tcpip.h])
 438
 439 # NetBSD
 440 AC_CHECK_HEADERS_ONCE([sys/atomic.h])
 441
 442 # Other
 443 AC_CHECK_HEADERS_ONCE([sys/ioctl.h])
 444 AC_CHECK_HEADERS_ONCE([byteswap.h])
 445 AC_CHECK_HEADERS_ONCE([sys/syscall.h])
 446 AC_CHECK_HEADERS_ONCE([sys/eventfd.h])
 447 AC_CHECK_HEADERS_ONCE([execinfo.h])
 448 AC_CHECK_HEADERS_ONCE([langinfo.h])
 449 AC_CHECK_HEADERS_ONCE([regex.h pcreposix.h])
 450
 451 AM_CONDITIONAL(HAVE_SYS_EVENTFD_H, test "x$ac_cv_header_sys_eventfd_h" = "xyes")
 452
 453 #### Typdefs, structures, etc. ####
 454
 455 AC_C_CONST
 456 AC_C_BIGENDIAN
 457 AC_TYPE_PID_T
 458 AC_TYPE_SIZE_T
 459 AC_CHECK_TYPES(ssize_t, , AC_DEFINE([ssize_t], [signed long], [Define ssize_t if it is not done by the standard libs.]))
 460 AC_TYPE_OFF_T
 461
 462 AC_TYPE_UID_T
 463 AC_CHECK_DECLS(environ)
 464
 465 # SIGXCPU
 466 AX_CHECK_DEFINE([signal.h], [SIGXCPU], [HAVE_SIGXCPU=1], [HAVE_SIGXCPU=0])
 467 AS_IF([test "x$HAVE_SIGXCPU" = "x1"], AC_DEFINE([HAVE_SIGXCPU], 1, [Have SIGXCPU?]))
 468 AM_CONDITIONAL(HAVE_SIGXCPU, test "x$HAVE_SIGXCPU" = "x1")
 469
 470 # INADDR_NONE, Solaris lacks this
 471 AX_CHECK_DEFINE([netinet/in.h], [INADDR_NONE], [],
 472     [AX_CHECK_DEFINE([winsock2.h], [INADDR_NONE], [],
 473         [AC_DEFINE([INADDR_NONE],  [0xffffffff], [Define INADDR_NONE if not found in <netinet/in.h>])])])
 474
 475
 476 # _Bool
 477 AC_CACHE_CHECK([whether $CC knows _Bool],
 478     pulseaudio_cv__Bool,
 479     [AC_COMPILE_IFELSE(
 480         [AC_LANG_PROGRAM([], [[_Bool b;]])],
 481         [pulseaudio_cv__Bool=yes],
 482         [pulseaudio_cv__Bool=no])
 483     ])
 484
 485 AS_IF([test "$pulseaudio_cv__Bool" = "yes"], AC_DEFINE([HAVE_STD_BOOL], 1, [Have _Bool.]))
 486
 487
 488 #### Thread support ####
 489
 490 AX_TLS
 491 AS_IF([test "$ac_cv_tls" == "__thread"],
 492     AC_DEFINE([SUPPORT_TLS___THREAD], 1, [Define this if the compiler supports __thread for Thread-Local Storage]))
 493
 494 # Win32 build breaks with win32 pthread installed
 495 AS_IF([test "x$os_is_win32" != "x1"],
 496   [AX_PTHREAD])
 497
 498 AS_IF([test "x$ax_pthread_ok" == "xyes"],
 499     AC_DEFINE([_POSIX_PTHREAD_SEMANTICS], 1, [Needed on Solaris]))
 500
 501
 502 #### Check for libs ####
 503
 504 # ISO
 505 AC_SEARCH_LIBS([pow], [m])
 506
 507 # POSIX
 508 AC_SEARCH_LIBS([sched_setscheduler], [rt])
 509 AC_SEARCH_LIBS([dlopen], [dl])
 510 AC_SEARCH_LIBS([shm_open], [rt])
 511 AC_SEARCH_LIBS([inet_ntop], [nsl])
 512 AC_SEARCH_LIBS([timer_create], [rt])
 513 AC_SEARCH_LIBS([pthread_setaffinity_np], [pthread])
 514 AC_SEARCH_LIBS([pthread_getname_np], [pthread])
 515 AC_SEARCH_LIBS([pthread_setname_np], [pthread])
 516
 517 # BSD
 518 AC_SEARCH_LIBS([connect], [socket])
 519 AC_SEARCH_LIBS([backtrace], [execinfo ubacktrace])
 520
 521 # Darwin/OS X
 522 if test "x$os_is_darwin" = "x1" ; then
 523     AC_MSG_CHECKING([looking for Apple CoreService Framework])
 524     # How do I check a framework "library" - AC_CHECK_LIB prob. won't work??, just assign LIBS & hope
 525     AC_CHECK_HEADER([/Developer/Headers/FlatCarbon/CoreServices.h],
 526         [LIBS="$LIBS -framework CoreServices"],
 527         [AC_CHECK_HEADERS([/System/Library/Frameworks/CoreServices.framework/Headers/CoreServices.h],
 528             [LIBS="$LIBS -framework CoreServices"],
 529             [AC_MSG_ERROR([CoreServices.h header file not found])]
 530         )]
 531     )
 532
 533     AC_MSG_RESULT([ok])
 534     AC_DEFINE([HAVE_CLOCK_GETTIME], 1, [Using clock_gettime() replacement])
 535     HAVE_BONJOUR=1
 536 fi
 537
 538 AM_CONDITIONAL([HAVE_BONJOUR], [test "x$HAVE_BONJOUR" = x1])
 539
 540 # Windows
 541 AC_SEARCH_LIBS([regexec], [pcreposix])
 542 # This magic is needed so we do not needlessly add static libs to the win32  build, disabling its ability to make dlls.
 543 AC_CHECK_FUNCS([getopt_long], [], [AC_CHECK_LIB([iberty], [getopt_long])])
 544
 545
 546 #### Check for functions ####
 547
 548 # ISO
 549 AC_CHECK_FUNCS_ONCE([lrintf strtof])
 550
 551 # POSIX
 552 AC_FUNC_FORK
 553 AC_FUNC_GETGROUPS
 554 AC_CHECK_FUNCS_ONCE([chmod chown fstat fchown fchmod clock_gettime getaddrinfo getgrgid_r getgrnam_r \
 555     getpwnam_r getpwuid_r gettimeofday getuid mlock nanosleep \
 556     pipe posix_fadvise posix_madvise posix_memalign setpgid setsid shm_open \
 557     sigaction sleep symlink sysconf uname pthread_setaffinity_np pthread_getname_np pthread_setname_np])
 558 AC_CHECK_FUNCS([mkfifo], [HAVE_MKFIFO=1], [HAVE_MKFIFO=0])
 559 AC_SUBST(HAVE_MKFIFO)
 560 AM_CONDITIONAL(HAVE_MKFIFO, test "x$HAVE_MKFIFO" = "x1")
 561
 562 # X/OPEN
 563 AC_CHECK_FUNCS_ONCE([readlink])
 564
 565 # SUSv2
 566 AC_CHECK_FUNCS_ONCE([ctime_r usleep])
 567
 568 # SUSv3
 569 AC_CHECK_FUNCS_ONCE([strerror_r])
 570
 571 # BSD
 572 AC_CHECK_FUNCS_ONCE([lstat])
 573
 574 # Non-standard
 575 AC_CHECK_FUNCS_ONCE([setresuid setresgid setreuid setregid seteuid setegid ppoll strsignal sig2str strtof_l pipe2 accept4])
 576
 577 AC_FUNC_ALLOCA
 578
 579 AC_CHECK_FUNCS([regexec], [HAVE_REGEX=1], [HAVE_REGEX=0])
 580 AM_CONDITIONAL(HAVE_REGEX, [test "x$HAVE_REGEX" = "x1"])
 581
 582 # Large File-Support (LFS)
 583 AC_SYS_LARGEFILE
 584 # Check for open64 to know if the current system does have open64() and similar functions
 585 AC_CHECK_FUNCS_ONCE([open64])
 586
 587 AC_SEARCH_LIBS([dladdr], [dl], [HAVE_DLADDR=1], [HAVE_DLADDR=0])
 588 AC_DEFINE(HAVE_DLADDR, [1], [Have dladdr?])
 589
 590 ###################################
 591 #      External libraries         #
 592 ###################################
 593
 594 #### [lib]iconv ####
 595
 596 AM_ICONV
 597
 598 #### X11 (optional) ####
 599
 600 AC_ARG_ENABLE([x11],
 601     AS_HELP_STRING([--disable-x11],[Disable optional X11 support]))
 602
 603 AS_IF([test "x$enable_x11" != "xno"],
 604     [PKG_CHECK_MODULES(X11, [ x11-xcb xcb >= 1.6 ice sm xtst ], HAVE_X11=1, HAVE_X11=0)],
 605     HAVE_X11=0)
 606
 607 AS_IF([test "x$enable_x11" = "xyes" && test "x$HAVE_X11" = "x0"],
 608     [AC_MSG_ERROR([*** X11 not found])])
 609
 610 AC_SUBST(HAVE_X11)
 611 AM_CONDITIONAL([HAVE_X11], [test "x$HAVE_X11" = x1])
 612 AS_IF([test "x$HAVE_X11" = "x1"], AC_DEFINE([HAVE_X11], 1, [Have X11?]))
 613
 614 #### Capabilities (optional) ####
 615
 616 CAP_LIBS=''
 617
 618 AC_ARG_WITH([caps],
 619     AS_HELP_STRING([--without-caps],[Omit support for dropping capabilities.]))
 620
 621 if test "x${with_caps}" != "xno"; then
 622     AC_SEARCH_LIBS([cap_init], [cap], [], [])
 623
 624     # Only give an error on hosts that we know could support capabilities
 625     AC_CHECK_HEADERS([sys/capability.h], [], [
 626       if test "${host_has_caps}" = "1"; then
 627         AC_MSG_ERROR([*** sys/capability.h not found.  Use --without-caps to disable capabilities support.])
 628       fi])
 629 fi
 630
 631 #### Valgrind (optional) ####
 632
 633 AC_CHECK_HEADERS_ONCE([valgrind/memcheck.h])
 634
 635 #### check unit tests ####
 636
 637 AC_ARG_ENABLE([tests],
 638     AS_HELP_STRING([--disable-tests],[Disable unit tests]))
 639
 640 AS_IF([test "x$enable_tests" != "xno"],
 641     [PKG_CHECK_MODULES(LIBCHECK, [ check ], HAVE_LIBCHECK=1, HAVE_LIBCHECK=0)],
 642     HAVE_LIBCHECK=0)
 643
 644 AS_IF([test "x$enable_tests" = "xyes" && test "x$HAVE_LIBCHECK" = "x0"],
 645     [AC_MSG_ERROR([*** check library not found])])
 646
 647 AM_CONDITIONAL([HAVE_TESTS], [test "x$HAVE_LIBCHECK" = x1])
 648
 649 #### json parsing ####
 650
 651 PKG_CHECK_MODULES(LIBJSON, [ json-c >= 0.11 ])
 652
 653 #### Sound file ####
 654
 655 PKG_CHECK_MODULES(LIBSNDFILE, [ sndfile >= 1.0.20 ])
 656
 657 #### atomic-ops ####
 658
 659 AC_MSG_CHECKING([whether we need libatomic_ops])
 660 if test "x$need_libatomic_ops" = "xyes"; then
 661     AC_MSG_RESULT([yes])
 662     AC_CHECK_HEADERS([atomic_ops.h],
 663         [CFLAGS="$CFLAGS -DAO_REQUIRE_CAS"],
 664         [AC_MSG_ERROR([*** libatomic-ops headers not found])])
 665
 666     # Win32 does not need the lib and breaks horribly if we try to include it
 667     AS_IF([test "x$os_is_win32" != "x1"], [LIBS="$LIBS -latomic_ops"])
 668 else
 669     AC_MSG_RESULT([no])
 670 fi
 671
 672 #### Libsamplerate support (optional) ####
 673
 674 AC_ARG_ENABLE([samplerate],
 675     AS_HELP_STRING([--enable-samplerate],[Enable optional libsamplerate support (DEPRECATED)]))
 676
 677 AS_IF([test "x$enable_samplerate" = "xyes"],
 678     [PKG_CHECK_MODULES(LIBSAMPLERATE, [ samplerate >= 0.1.0 ], HAVE_LIBSAMPLERATE=1, HAVE_LIBSAMPLERATE=0)],
 679     HAVE_LIBSAMPLERATE=0)
 680
 681 AS_IF([test "x$enable_samplerate" = "xyes" && test "x$HAVE_LIBSAMPLERATE" = "x0"],
 682     [AC_MSG_ERROR([*** Libsamplerate not found])])
 683
 684 AM_CONDITIONAL([HAVE_LIBSAMPLERATE], [test "x$HAVE_LIBSAMPLERATE" = x1])
 685 AS_IF([test "x$HAVE_LIBSAMPLERATE" = "x1"], AC_DEFINE([HAVE_LIBSAMPLERATE], 1, [Have libsamplerate?]))
 686
 687 AS_IF([test "x$HAVE_LIBSAMPLERATE" = "x1"], AC_MSG_WARN([Support for libsamplerate is DEPRECATED]))
 688
 689 #### Database support ####
 690
 691 AC_ARG_WITH([database],
 692     AS_HELP_STRING([--with-database=auto|tdb|gdbm|simple],[Choose database backend.]),[],[with_database=auto])
 693
 694
 695 AS_IF([test "x$with_database" = "xauto" -o "x$with_database" = "xtdb"],
 696     [PKG_CHECK_MODULES(TDB, [ tdb ], HAVE_TDB=1, HAVE_TDB=0)],
 697     HAVE_TDB=0)
 698 AS_IF([test "x$HAVE_TDB" = "x1"], with_database=tdb)
 699
 700 AS_IF([test "x$with_database" = "xtdb" && test "x$HAVE_TDB" = "x0"],
 701     [AC_MSG_ERROR([*** tdb not found])])
 702
 703
 704 AS_IF([test "x$with_database" = "xauto" -o "x$with_database" = "xgdbm"],
 705     [
 706         HAVE_GDBM=1
 707         AC_CHECK_LIB(gdbm, gdbm_open, [], HAVE_GDBM=0)
 708         AC_CHECK_HEADERS(gdbm.h, [], HAVE_GDBM=0)
 709     ],
 710     HAVE_GDBM=0)
 711 AS_IF([test "x$HAVE_GDBM" = "x1"],
 712     [
 713         with_database=gdbm
 714         GDBM_CFLAGS=
 715         GDBM_LIBS=-lgdbm
 716     ])
 717
 718 AS_IF([test "x$with_database" = "xgdbm" && test "x$HAVE_GDBM" = "x0"],
 719     [AC_MSG_ERROR([*** gdbm not found])])
 720
 721
 722 AS_IF([test "x$with_database" = "xauto" -o "x$with_database" = "xsimple"],
 723     HAVE_SIMPLEDB=1,
 724     HAVE_SIMPLEDB=0)
 725 AS_IF([test "x$HAVE_SIMPLEDB" = "x1"], with_database=simple)
 726
 727 AS_IF([test "x$HAVE_TDB" != x1 -a "x$HAVE_GDBM" != x1 -a "x$HAVE_SIMPLEDB" != x1],
 728     AC_MSG_ERROR([*** missing database backend]))
 729
 730
 731 AM_CONDITIONAL([HAVE_TDB], [test "x$HAVE_TDB" = x1])
 732 AS_IF([test "x$HAVE_TDB" = "x1"], AC_DEFINE([HAVE_TDB], 1, [Have tdb?]))
 733
 734 AC_SUBST(GDBM_CFLAGS)
 735 AC_SUBST(GDBM_LIBS)
 736 AM_CONDITIONAL([HAVE_GDBM], [test "x$HAVE_GDBM" = x1])
 737 AS_IF([test "x$HAVE_GDBM" = "x1"], AC_DEFINE([HAVE_GDBM], 1, [Have gdbm?]))
 738
 739 AM_CONDITIONAL([HAVE_SIMPLEDB], [test "x$HAVE_SIMPLEDB" = x1])
 740 AS_IF([test "x$HAVE_SIMPLEDB" = "x1"], AC_DEFINE([HAVE_SIMPLEDB], 1, [Have simple?]))
 741
 742 #### OSS support (optional) ####
 743
 744 AC_ARG_ENABLE([oss-output],
 745     AS_HELP_STRING([--disable-oss-output],[Disable optional OSS output support]))
 746
 747 AC_ARG_ENABLE([oss-wrapper],
 748     AS_HELP_STRING([--disable-oss-wrapper],[Disable optional OSS wrapper support]))
 749
 750 AS_IF([test "x$enable_oss_output" != "xno" -o "x$enable_oss_wrapper" != "xno"],
 751     [AC_CHECK_HEADERS([sys/soundcard.h], HAVE_OSS=1, HAVE_OSS=0)],
 752     HAVE_OSS=0)
 753
 754 AS_IF([test "x$enable_oss_output" = "xyes" -o "x$enable_oss_wrapper" = "xyes" && test "x$HAVE_OSS" = "x0"],
 755     [AC_MSG_ERROR([*** OSS support not found])])
 756
 757 AS_IF([test "x$enable_oss_output" != "xno"],
 758     [AS_IF([test "x$HAVE_OSS" = "x1"], HAVE_OSS_OUTPUT=1, HAVE_OSS_OUTPUT=0)],
 759     HAVE_OSS_OUTPUT=0)
 760
 761 AS_IF([test "x$enable_oss_wrapper" != "xno"],
 762     [AS_IF([test "x$HAVE_OSS" = "x1"], HAVE_OSS_WRAPPER=1, HAVE_OSS_WRAPPER=0)],
 763     HAVE_OSS_WRAPPER=0)
 764
 765 AC_SUBST(HAVE_OSS_OUTPUT)
 766 AM_CONDITIONAL([HAVE_OSS_OUTPUT], [test "x$HAVE_OSS_OUTPUT" = "x1"])
 767 AM_CONDITIONAL([HAVE_OSS_WRAPPER], [test "x$HAVE_OSS_WRAPPER" = "x1"])
 768 AS_IF([test "x$HAVE_OSS_OUTPUT" = "x1"], AC_DEFINE([HAVE_OSS_OUTPUT], 1, [Have OSS output?]))
 769 AS_IF([test "x$HAVE_OSS_WRAPPER" = "x1"], AC_DEFINE([HAVE_OSS_WRAPPER], 1, [Have OSS wrapper (padsp)?]))
 770
 771 #### CoreAudio support (optional) ####
 772
 773 AC_ARG_ENABLE([coreaudio-output],
 774     AS_HELP_STRING([--disable-coreaudio-output],[Disable optional CoreAudio output support]))
 775
 776 AS_IF([test "x$enable_coreaudio_output" != "xno"],
 777     [AC_CHECK_HEADERS([CoreAudio/CoreAudio.h], HAVE_COREAUDIO=1, HAVE_COREAUDIO=0)],
 778     HAVE_COREAUDIO=0)
 779
 780 AS_IF([test "x$enable_coreaudio_output" = "xyes" && test "x$HAVE_COREAUDIO" = "x0"],
 781     [AC_MSG_ERROR([*** CoreAudio output support not found])])
 782
 783 AM_CONDITIONAL([HAVE_COREAUDIO], [test "x$HAVE_COREAUDIO" = "x1" && test "x$enable_coreaudio_output" != "xno"])
 784
 785 #### ALSA support (optional) ####
 786
 787 AC_ARG_ENABLE([alsa],
 788     AS_HELP_STRING([--disable-alsa],[Disable optional ALSA support]))
 789
 790 AS_IF([test "x$enable_alsa" != "xno"],
 791     [PKG_CHECK_MODULES(ASOUNDLIB, [ alsa >= 1.0.19 ], HAVE_ALSA=1, HAVE_ALSA=0)],
 792     HAVE_ALSA=0)
 793
 794 AS_IF([test "x$enable_alsa" = "xyes" && test "x$HAVE_ALSA" = "x0"],
 795     [AC_MSG_ERROR([*** Needed alsa >= 1.0.19 support not found])])
 796
 797 AS_IF([test "x$HAVE_ALSA" = "x1"],
 798     [
 799         save_CPPFLAGS="$CPPFLAGS"; CPPFLAGS="$CPPFLAGS $ASOUNDLIB_CFLAGS"
 800         AC_CHECK_HEADERS([use-case.h], HAVE_ALSA_UCM=1, HAVE_ALSA_UCM=0)
 801         CPPFLAGS="$save_CPPFLAGS"
 802     ],
 803     HAVE_ALSA_UCM=0)
 804
 805 AC_SUBST(HAVE_ALSA)
 806 AM_CONDITIONAL([HAVE_ALSA], [test "x$HAVE_ALSA" = x1])
 807 AS_IF([test "x$HAVE_ALSA" = "x1"], AC_DEFINE([HAVE_ALSA], 1, [Have ALSA?]))
 808 AS_IF([test "x$HAVE_ALSA_UCM" = "x1"], AC_DEFINE([HAVE_ALSA_UCM], 1, [Have ALSA UCM?]))
 809
 810 #### EsounD support (optional) ####
 811
 812 AC_ARG_ENABLE([esound],
 813     AS_HELP_STRING([--disable-esound],[Disable optional EsounD support]))
 814 AM_CONDITIONAL([HAVE_ESOUND], [test "x$enable_esound" != "xno"])
 815 AS_IF([test "x$enable_esound" != "xno"], [HAVE_ESOUND=1])
 816
 817 #### Solaris audio support (optional) ####
 818
 819 AC_ARG_ENABLE([solaris],
 820     AS_HELP_STRING([--disable-solaris],[Disable optional Solaris audio support]))
 821
 822 AS_IF([test "x$enable_solaris" != "xno"],
 823     [AC_CHECK_HEADERS([sys/audio.h], HAVE_SOLARIS=1, HAVE_SOLARIS=0)],
 824     HAVE_SOLARIS=0)
 825
 826 AS_IF([test "x$enable_solaris" = "xyes" && test "x$HAVE_SOLARIS" = "x0"],
 827     [AC_MSG_ERROR([*** Solaris audio support not found])])
 828
 829 AM_CONDITIONAL([HAVE_SOLARIS], [test "x$HAVE_SOLARIS" = x1])
 830 AS_IF([test "x$HAVE_SOLARIS" = "x1"], AC_DEFINE([HAVE_SOLARIS], 1, [Have Solaris audio?]))
 831
 832 #### WaveOut audio support (optional) ####
 833
 834 AC_ARG_ENABLE([waveout],
 835     AS_HELP_STRING([--disable-waveout],[Disable optional WaveOut audio support]))
 836
 837 AS_IF([test "x$enable_waveout" != "xno"],
 838     [AC_CHECK_HEADERS([mmsystem.h], HAVE_WAVEOUT=1, HAVE_WAVEOUT=0, [#include <windows.h>])],
 839     HAVE_WAVEOUT=0)
 840
 841 AS_IF([test "x$enable_waveout" = "xyes" && test "x$HAVE_WAVEOUT" = "x0"],
 842     [AC_MSG_ERROR([*** WaveOut audio support not found])])
 843
 844 AC_SUBST(HAVE_WAVEOUT)
 845 AM_CONDITIONAL([HAVE_WAVEOUT], [test "x$HAVE_WAVEOUT" = x1])
 846 AS_IF([test "x$HAVE_WAVEOUT" = "x1"], AC_DEFINE([HAVE_WAVEOUT], 1, [Have WaveOut audio?]))
 847
 848 #### GLib 2 support (optional) ####
 849
 850 AC_ARG_ENABLE([glib2],
 851     AS_HELP_STRING([--disable-glib2],[Disable optional GLib 2 support]))
 852
 853 AS_IF([test "x$enable_glib2" != "xno"],
 854     [PKG_CHECK_MODULES(GLIB20, [ glib-2.0 >= 2.4.0 ], HAVE_GLIB20=1, HAVE_GLIB20=0)],
 855     HAVE_GLIB20=0)
 856
 857 AS_IF([test "x$enable_glib2" = "xyes" && test "x$HAVE_GLIB20" = "x0"],
 858     [AC_MSG_ERROR([*** GLib 2 support not found])])
 859
 860 AC_SUBST(HAVE_GLIB20)
 861 AM_CONDITIONAL([HAVE_GLIB20], [test "x$HAVE_GLIB20" = x1])
 862 AS_IF([test "x$HAVE_GLIB20" = "x1"], AC_DEFINE([HAVE_GLIB], 1, [Have GLIB?]))
 863
 864 #### GTK3 support (optional) ####
 865
 866 AC_ARG_ENABLE([gtk3],
 867     AS_HELP_STRING([--disable-gtk3],[Disable optional Gtk+ 3 support]))
 868
 869 AS_IF([test "x$enable_gtk3" != "xno"],
 870     [PKG_CHECK_MODULES(GTK30, [ gtk+-3.0 ], HAVE_GTK30=1, HAVE_GTK30=0)],
 871     HAVE_GTK30=0)
 872
 873 AS_IF([test "x$enable_gtk3" = "xyes" && test "x$HAVE_GTK30" = "x0"],
 874     [AC_MSG_ERROR([*** Gtk+ 3 support not found])])
 875
 876 AM_CONDITIONAL([HAVE_GTK30], [test "x$HAVE_GTK30" = x1])
 877 AS_IF([test "x$HAVE_GTK30" = "x1"], AC_DEFINE([HAVE_GTK], 1, [Have GTK?]))
 878
 879 #### GConf support (optional) ####
 880
 881 AC_ARG_ENABLE([gconf],
 882     AS_HELP_STRING([--disable-gconf],[Disable optional GConf support]))
 883
 884 AS_IF([test "x$enable_gconf" != "xno"],
 885     [PKG_CHECK_MODULES(GCONF, [ gconf-2.0 >= 2.4.0 gobject-2.0 ], HAVE_GCONF=1, HAVE_GCONF=0)],
 886     HAVE_GCONF=0)
 887
 888 AS_IF([test "x$enable_gconf" = "xyes" && test "x$HAVE_GCONF" = "x0"],
 889     [AC_MSG_ERROR([*** GConf support not found])])
 890
 891 AM_CONDITIONAL([HAVE_GCONF], [test "x$HAVE_GCONF" = x1])
 892
 893 #### Avahi support (optional) ####
 894
 895 AC_ARG_ENABLE([avahi],
 896     AS_HELP_STRING([--disable-avahi],[Disable optional Avahi support]))
 897
 898 AS_IF([test "x$enable_avahi" != "xno"],
 899     [PKG_CHECK_MODULES(AVAHI, [ avahi-client >= 0.6.0 ], HAVE_AVAHI=1, HAVE_AVAHI=0)],
 900     HAVE_AVAHI=0)
 901
 902 AS_IF([test "x$enable_avahi" = "xyes" && test "x$HAVE_AVAHI" = "x0"],
 903     [AC_MSG_ERROR([*** Avahi support not found])])
 904
 905 AC_SUBST(HAVE_AVAHI)
 906 AM_CONDITIONAL([HAVE_AVAHI], [test "x$HAVE_AVAHI" = x1])
 907
 908 #### JACK (optional) ####
 909
 910 AC_ARG_ENABLE([jack],
 911     AS_HELP_STRING([--disable-jack],[Disable optional JACK support]))
 912
 913 AS_IF([test "x$enable_jack" != "xno"],
 914     [PKG_CHECK_MODULES(JACK, [ jack >= 0.117.0 ], HAVE_JACK=1, HAVE_JACK=0)],
 915     HAVE_JACK=0)
 916
 917 AS_IF([test "x$enable_jack" = "xyes" && test "x$HAVE_JACK" = "x0"],
 918     [AC_MSG_ERROR([*** JACK support not found])])
 919
 920 AM_CONDITIONAL([HAVE_JACK], [test "x$HAVE_JACK" = x1])
 921
 922 #### Async DNS support (optional) ####
 923
 924 AC_ARG_ENABLE([asyncns],
 925     AS_HELP_STRING([--disable-asyncns],[Disable optional Async DNS support]))
 926
 927 AS_IF([test "x$enable_asyncns" != "xno"],
 928     [PKG_CHECK_MODULES(LIBASYNCNS, [ libasyncns >= 0.1 ], HAVE_LIBASYNCNS=1, HAVE_LIBASYNCNS=0)],
 929     HAVE_LIBASYNCNS=0)
 930
 931 AS_IF([test "x$enable_asyncns" = "xyes" && test "x$HAVE_LIBASYNCNS" = "x0"],
 932     [AC_MSG_ERROR([*** Async DNS support not found])])
 933
 934 AM_CONDITIONAL([HAVE_LIBASYNCNS], [test "x$HAVE_LIBASYNCNS" = x1])
 935 AS_IF([test "x$HAVE_LIBASYNCNS" = "x1"], AC_DEFINE([HAVE_LIBASYNCNS], 1, [Have libasyncns?]))
 936
 937 #### TCP wrappers (optional) ####
 938
 939 AC_ARG_ENABLE([tcpwrap],
 940     AS_HELP_STRING([--disable-tcpwrap],[Disable optional TCP wrappers support]))
 941
 942 AS_IF([test "x$enable_tcpwrap" != "xno"],
 943     [
 944         ACX_LIBWRAP
 945         AS_IF([test "x$LIBWRAP_LIBS" != "x"], HAVE_TCPWRAP=1, HAVE_TCPWRAP=0)
 946     ],
 947     HAVE_TCPWRAP=0)
 948
 949 AS_IF([test "x$enable_tcpwrap" = "xyes" && test "x$HAVE_TCPWRAP" = "x0"],
 950     [AC_MSG_ERROR([*** TCP wrappers support not found])])
 951
 952 AC_SUBST(LIBWRAP_LIBS)
 953
 954 #### LIRC support (optional) ####
 955
 956 AC_ARG_ENABLE([lirc],
 957     AS_HELP_STRING([--disable-lirc],[Disable optional LIRC support]))
 958
 959 LIRC_CFLAGS=
 960 LIRC_LIBS=
 961
 962 AS_IF([test "x$enable_lirc" != "xno"],
 963     [
 964         HAVE_LIRC=1
 965         AC_CHECK_HEADER(lirc/lirc_client.h, [], [HAVE_LIRC=0])
 966         AC_CHECK_LIB(lirc_client, lirc_init, [LIRC_LIBS=-llirc_client], [HAVE_LIRC=0])
 967     ],
 968     HAVE_LIRC=0)
 969
 970 AS_IF([test "x$enable_lirc" = "xyes" && test "x$HAVE_LIRC" = "x0"],
 971     [AC_MSG_ERROR([*** LIRC support not found])])
 972
 973 AC_SUBST(LIRC_CFLAGS)
 974 AC_SUBST(LIRC_LIBS)
 975 AM_CONDITIONAL([HAVE_LIRC], [test "x$HAVE_LIRC" = x1])
 976
 977 #### D-Bus support (optional) ####
 978
 979 AC_ARG_ENABLE([dbus],
 980     AS_HELP_STRING([--disable-dbus],[Disable optional D-Bus support]))
 981
 982 AS_IF([test "x$enable_dbus" != "xno"],
 983     [PKG_CHECK_MODULES(DBUS, [ dbus-1 >= 1.4.12 ], HAVE_DBUS=1, HAVE_DBUS=0)],
 984     HAVE_DBUS=0)
 985
 986 AS_IF([test "x$enable_dbus" = "xyes" && test "x$HAVE_DBUS" = "x0"],
 987     [AC_MSG_ERROR([*** D-Bus not available or too old version])])
 988
 989 AS_IF([test "x$HAVE_DBUS" = "x1"],
 990     [
 991         save_CFLAGS="$CFLAGS"; CFLAGS="$CFLAGS $DBUS_CFLAGS"
 992         save_LIBS="$LIBS"; LIBS="$LIBS $DBUS_LIBS"
 993         AC_CHECK_FUNCS(dbus_watch_get_unix_fd)
 994         CFLAGS="$save_CFLAGS"
 995         LIBS="$save_LIBS"
 996     ])
 997
 998 AC_SUBST(HAVE_DBUS)
 999 AM_CONDITIONAL([HAVE_DBUS], [test "x$HAVE_DBUS" = x1])
1000 AS_IF([test "x$HAVE_DBUS" = "x1"], AC_DEFINE([HAVE_DBUS], 1, [Have D-Bus.]))
1001
1002 PA_MACHINE_ID="${sysconfdir}/machine-id"
1003 AX_DEFINE_DIR(PA_MACHINE_ID, PA_MACHINE_ID, [D-Bus machine-id file])
1004 PA_MACHINE_ID_FALLBACK="${localstatedir}/lib/dbus/machine-id"
1005 AX_DEFINE_DIR(PA_MACHINE_ID_FALLBACK, PA_MACHINE_ID_FALLBACK,
1006               [Fallback machine-id file])
1007
1008 #### BlueZ support (optional, dependent on D-Bus and SBC) ####
1009
1010 AC_ARG_ENABLE([bluez4],
1011     AS_HELP_STRING([--disable-bluez4],[Disable optional BlueZ 4 support]))
1012 AC_ARG_ENABLE([bluez5],
1013     AS_HELP_STRING([--disable-bluez5],[Disable optional BlueZ 5 support]))
1014
1015 ## SBC ##
1016 AS_IF([test "x$enable_bluez4" != "xno" || test "x$enable_bluez5" != "xno"],
1017     [PKG_CHECK_MODULES(SBC, [ sbc >= 1.0 ], HAVE_SBC=1, HAVE_SBC=0)],
1018     HAVE_SBC=0)
1019
1020 ## BlueZ 4 ##
1021 AS_IF([test "x$enable_bluez4" != "xno" && test "x$HAVE_DBUS" = "x1" && test "x$HAVE_SBC" = "x1"], HAVE_BLUEZ_4=1,
1022       HAVE_BLUEZ_4=0)
1023 AS_IF([test "x$enable_bluez4" = "xyes" && test "x$HAVE_BLUEZ_4" != "x1"],
1024     [AC_MSG_ERROR([*** BLUEZ 4 support not found (requires sbc and D-Bus)])])
1025 AC_SUBST(HAVE_BLUEZ_4)
1026 AM_CONDITIONAL([HAVE_BLUEZ_4], [test "x$HAVE_BLUEZ_4" = x1])
1027
1028 ## BlueZ 5 ##
1029 AS_IF([test "x$enable_bluez5" != "xno" && test "x$HAVE_DBUS" = "x1" && test "x$HAVE_SBC" = "x1"], HAVE_BLUEZ_5=1,
1030       HAVE_BLUEZ_5=0)
1031 AS_IF([test "x$enable_bluez5" = "xyes" && test "x$HAVE_BLUEZ_5" != "x1"],
1032     [AC_MSG_ERROR([*** BLUEZ 5 support not found (requires sbc and D-Bus)])])
1033 AC_SUBST(HAVE_BLUEZ_5)
1034 AM_CONDITIONAL([HAVE_BLUEZ_5], [test "x$HAVE_BLUEZ_5" = x1])
1035
1036 AS_IF([test "x$HAVE_BLUEZ_4" = "x1" || test "x$HAVE_BLUEZ_5" = "x1"], HAVE_BLUEZ=1, HAVE_BLUEZ=0)
1037 AC_SUBST(HAVE_BLUEZ)
1038 AM_CONDITIONAL([HAVE_BLUEZ], [test "x$HAVE_BLUEZ" = x1])
1039
1040 ## Bluetooth Headset profiles backend ##
1041
1042 AC_ARG_ENABLE([bluez5-ofono-headset],
1043     AS_HELP_STRING([--disable-bluez5-ofono-headset],[Disable optional ofono headset backend support (Bluez 5)]))
1044 AS_IF([test "x$HAVE_BLUEZ_5" = "x1" && test "x$enable_bluez5_ofono_headset" != "xno"], HAVE_BLUEZ_5_OFONO_HEADSET=1,
1045       HAVE_BLUEZ_5_OFONO_HEADSET=0)
1046 AC_SUBST(HAVE_BLUEZ_5_OFONO_HEADSET)
1047 AM_CONDITIONAL([HAVE_BLUEZ_5_OFONO_HEADSET], [test "x$HAVE_BLUEZ_5_OFONO_HEADSET" = x1])
1048 AS_IF([test "x$HAVE_BLUEZ_5_OFONO_HEADSET" = "x1"], AC_DEFINE([HAVE_BLUEZ_5_OFONO_HEADSET], 1, [Bluez 5 ofono headset backend enabled]))
1049
1050 AC_ARG_ENABLE([bluez5-native-headset],
1051     AS_HELP_STRING([--disable-bluez5-native-headset],[Disable optional native headset backend support (Bluez 5)]))
1052 AS_IF([test "x$HAVE_BLUEZ_5" = "x1" && test "x$enable_bluez5_native_headset" != "xno"],
1053       [PKG_CHECK_MODULES(BLUEZ, [ bluez >= 4.101 ], HAVE_BLUEZ_5_NATIVE_HEADSET=1, HAVE_BLUEZ_5_NATIVE_HEADSET=0)],
1054       HAVE_BLUEZ_5_NATIVE_HEADSET=0)
1055 AS_IF([test "x$enable_bluez5_native_headset" = "xyes" && test "x$HAVE_BLUEZ_5_NATIVE_HEADSET" = "x0"],
1056       [AC_MSG_ERROR([*** BlueZ 5 native headset backend support not available (requires the libbluetooth headers)])])
1057 AC_SUBST(HAVE_BLUEZ_5_NATIVE_HEADSET)
1058 AM_CONDITIONAL([HAVE_BLUEZ_5_NATIVE_HEADSET], [test "x$HAVE_BLUEZ_5_NATIVE_HEADSET" = x1])
1059 AS_IF([test "x$HAVE_BLUEZ_5_NATIVE_HEADSET" = "x1"], AC_DEFINE([HAVE_BLUEZ_5_NATIVE_HEADSET], 1, [Bluez 5 native headset backend enabled]))
1060
1061 #### UDEV support (optional) ####
1062
1063 AC_ARG_ENABLE([udev],
1064     AS_HELP_STRING([--disable-udev],[Disable optional UDEV support]))
1065
1066 AS_IF([test "x$enable_udev" != "xno" -a \( "x$HAVE_OSS" = "x1" -o "x$HAVE_ALSA" = "x1" \)],
1067     [PKG_CHECK_MODULES(UDEV, [ libudev >= 143 ], HAVE_UDEV=1, HAVE_UDEV=0)],
1068     HAVE_UDEV=0)
1069
1070 AS_IF([test "x$enable_udev" = "xyes" && test "x$HAVE_UDEV" = "x0"],
1071     [AC_MSG_ERROR([*** UDEV support not found])])
1072
1073 AC_SUBST(HAVE_UDEV)
1074 AM_CONDITIONAL([HAVE_UDEV], [test "x$HAVE_UDEV" = x1])
1075 AS_IF([test "x$HAVE_UDEV" = "x1"], AC_DEFINE([HAVE_UDEV], 1, [Have UDEV.]))
1076
1077 #### HAL compat support (optional, dependent on UDEV) ####
1078
1079 AC_ARG_ENABLE([hal-compat],
1080     AS_HELP_STRING([--disable-hal-compat],[Disable optional HAL->udev transition compatibility support]))
1081
1082 AS_IF([test "x$enable_hal_compat" != "xno"],
1083     [AS_IF([test "x$HAVE_UDEV" = "x1"], HAVE_HAL_COMPAT=1, HAVE_HAL_COMPAT=0)],
1084     HAVE_HAL_COMPAT=0)
1085
1086 AM_CONDITIONAL([HAVE_HAL_COMPAT], [test "x$HAVE_HAL_COMPAT" = x1])
1087 AS_IF([test "x$HAVE_HAL_COMPAT" = "x1"], AC_DEFINE([HAVE_HAL_COMPAT], 1, [Have HAL compatibility.]))
1088
1089 #### IPv6 connection support (optional) ####
1090
1091 AC_ARG_ENABLE([ipv6],
1092     AS_HELP_STRING([--disable-ipv6],[Disable optional IPv6 support]))
1093
1094 AS_IF([test "x$enable_ipv6" != "xno"], [HAVE_IPV6=1], [HAVE_IPV6=0])
1095
1096 AS_IF([test "x$HAVE_IPV6" = "x1"], AC_DEFINE([HAVE_IPV6], 1, [Define this to enable IPv6 connection support]))
1097
1098 #### OpenSSL support (optional) ####
1099
1100 AC_ARG_ENABLE([openssl],
1101     AS_HELP_STRING([--disable-openssl],[Disable OpenSSL support (used for Airtunes/RAOP)]))
1102
1103 AS_IF([test "x$enable_openssl" != "xno"],
1104     [PKG_CHECK_MODULES(OPENSSL, [ openssl > 0.9 ], HAVE_OPENSSL=1, HAVE_OPENSSL=0)],
1105     HAVE_OPENSSL=0)
1106
1107 AS_IF([test "x$enable_openssl" = "xyes" && test "x$HAVE_OPENSSL" = "x0"],
1108     [AC_MSG_ERROR([*** OpenSSL support not found])])
1109
1110 AM_CONDITIONAL([HAVE_OPENSSL], [test "x$HAVE_OPENSSL" = x1])
1111 AS_IF([test "x$HAVE_OPENSSL" = "x1"], AC_DEFINE([HAVE_OPENSSL], 1, [Have OpenSSL]))
1112
1113 #### FFTW (optional) ####
1114
1115 AC_ARG_WITH([fftw],
1116     AS_HELP_STRING([--without-fftw],[Omit FFTW-using modules (equalizer)]))
1117
1118 AS_IF([test "x$with_fftw" != "xno"],
1119     [PKG_CHECK_MODULES(FFTW, [ fftw3f ], HAVE_FFTW=1, HAVE_FFTW=0)],
1120     HAVE_FFTW=0)
1121
1122 AS_IF([test "x$with_fftw" = "xyes" && test "x$HAVE_FFTW" = "x0"],
1123     [AC_MSG_ERROR([*** FFTW support not found])])
1124
1125 AM_CONDITIONAL([HAVE_FFTW], [test "x$HAVE_FFTW" = "x1"])
1126
1127 #### speex (optional) ####
1128
1129 AC_ARG_WITH([speex],
1130     AS_HELP_STRING([--without-speex],[Omit speex (resampling, AEC)]))
1131
1132 AS_IF([test "x$with_speex" != "xno"],
1133     [PKG_CHECK_MODULES(LIBSPEEX, [ speexdsp >= 1.2 ], HAVE_SPEEX=1, HAVE_SPEEX=0)],
1134     HAVE_SPEEX=0)
1135
1136 AS_IF([test "x$with_speex" = "xyes" && test "x$HAVE_SPEEX" = "x0"],
1137     [AC_MSG_ERROR([*** speex support not found])])
1138
1139 AM_CONDITIONAL([HAVE_SPEEX], [test "x$HAVE_SPEEX" = "x1"])
1140 AS_IF([test "x$HAVE_SPEEX" = "x1"], AC_DEFINE([HAVE_SPEEX], 1, [Have speex]))
1141
1142 #### Xen support (optional) ####
1143
1144 AC_ARG_ENABLE([xen],
1145     AS_HELP_STRING([--disable-xen],[Disable optional Xen paravirtualized driver]))
1146
1147 XEN_CFLAGS=
1148 XEN_LIBS=
1149
1150 AS_IF([test "x$enable_xen" != "xno"],
1151     [
1152         HAVE_XEN=1
1153         AC_CHECK_HEADER(xenctrl.h, [], [HAVE_XEN=0])
1154         AC_CHECK_HEADER(xs.h, [], [HAVE_XEN=0])
1155         AC_CHECK_LIB(xenctrl, xc_interface_open, [XEN_LIBS="$XEN_LIBS -lxenctrl"], [HAVE_XEN=0])
1156         AC_CHECK_LIB(xenstore, xs_domain_open, [XEN_LIBS="$XEN_LIBS -lxenstore"], [HAVE_XEN=0])
1157     ],
1158     HAVE_XEN=0)
1159
1160 AS_IF([test "x$enable_xen" = "xyes" && test "x$HAVE_XEN" = "x0"],
1161     [AC_MSG_ERROR([*** Xen development headers or libraries not found])])
1162
1163 AC_SUBST(XEN_CFLAGS)
1164 AC_SUBST(XEN_LIBS)
1165 AM_CONDITIONAL([HAVE_XEN], [test "x$HAVE_XEN" = x1])
1166
1167 #### gcov support (optional) #####
1168
1169 AC_ARG_ENABLE([gcov],
1170     AS_HELP_STRING([--enable-gcov],[Enable optional gcov coverage analysis]))
1171
1172 GCOV_CFLAGS=
1173 GCOV_LIBS=" -lgcov"
1174
1175 AS_IF([test "x$enable_gcov" = "xyes"],
1176     [
1177         HAVE_GCOV=1
1178         GCOV_CFLAGS="$GCOV_CFLAGS -fprofile-arcs -ftest-coverage"
1179         GCOV_LIBS="$GCOV_LIBS -fprofile-arcs"
1180     ],
1181     HAVE_GCOV=0)
1182
1183 AC_SUBST(GCOV_CFLAGS)
1184 AC_SUBST(GCOV_LIBS)
1185 AM_CONDITIONAL([HAVE_GCOV], [test "x$HAVE_GCOV" = x1])
1186
1187 #### ORC (optional) ####
1188
1189 ORC_CHECK([0.4.11])
1190
1191 #### systemd support (optional) ####
1192
1193 AC_ARG_ENABLE([systemd-daemon],
1194     AS_HELP_STRING([--disable-systemd-daemon],[Disable optional systemd daemon (socket activation) support]))
1195
1196 AC_ARG_ENABLE([systemd-login],
1197     AS_HELP_STRING([--disable-systemd-login],[Disable optional systemd login support]))
1198
1199 AC_ARG_ENABLE([systemd-journal],
1200     AS_HELP_STRING([--disable-systemd-journal],[Disable optional systemd journal support]))
1201
1202 # Newer systemd's combine their subcomponent libraries into one
1203 # If it exists, we should use it for the further checks
1204
1205 AS_IF([test "x$enable_systemd_daemon" != "xno" || test "x$enable_systemd_login" != "xno" || test "x$enable_systemd_journal" != "xno"],
1206     [PKG_CHECK_MODULES(SYSTEMD, [ libsystemd ], HAVE_SYSTEMD=1, HAVE_SYSTEMD=0)],
1207     HAVE_SYSTEMD=0)
1208
1209 AS_IF([test "x$HAVE_SYSTEMD" = "x1"],
1210     [
1211         HAVE_SYSTEMD_DAEMON=1
1212         HAVE_SYSTEMD_LOGIN=1
1213         HAVE_SYSTEMD_JOURNAL=1
1214     ])
1215
1216 AC_ARG_WITH([systemduserunitdir],
1217         AS_HELP_STRING([--with-systemduserunitdir=DIR], [Directory for systemd user service files]),
1218         [], [with_systemduserunitdir=$($PKG_CONFIG --variable=systemduserunitdir systemd)])
1219 if test "x$with_systemduserunitdir" != xno; then
1220         AC_SUBST([systemduserunitdir], [$with_systemduserunitdir])
1221 fi
1222
1223 #### systemd daemon support (optional) ####
1224
1225 AS_IF([test "x$enable_systemd_daemon" != "xno"],
1226     [AS_IF([test "x$HAVE_SYSTEMD_DAEMON" != "x1"], [PKG_CHECK_MODULES(SYSTEMDDAEMON, [ libsystemd-daemon ], HAVE_SYSTEMD_DAEMON=1, HAVE_SYSTEMD_DAEMON=0)])],
1227     HAVE_SYSTEMD_DAEMON=0)
1228
1229 AS_IF([test "x$enable_systemd_daemon" = "xyes" && test "x$HAVE_SYSTEMD_DAEMON" = "x0"],
1230     [AC_MSG_ERROR([*** Needed systemd daemon support not found])])
1231
1232 AC_SUBST(HAVE_SYSTEMD_DAEMON)
1233 AM_CONDITIONAL([HAVE_SYSTEMD_DAEMON], [test "x$HAVE_SYSTEMD_DAEMON" = x1])
1234 AS_IF([test "x$HAVE_SYSTEMD_DAEMON" = "x1"], AC_DEFINE([HAVE_SYSTEMD_DAEMON], 1, [Have SYSTEMDDAEMON?]))
1235
1236 #### systemd login support (optional) ####
1237
1238 AS_IF([test "x$enable_systemd_login" != "xno"],
1239     [AS_IF([test "x$HAVE_SYSTEMD_LOGIN" != "x1"], [PKG_CHECK_MODULES(SYSTEMDLOGIN, [ libsystemd-login ], HAVE_SYSTEMD_LOGIN=1, HAVE_SYSTEMD_LOGIN=0)])],
1240     HAVE_SYSTEMD_LOGIN=0)
1241
1242 AS_IF([test "x$enable_systemd_login" = "xyes" && test "x$HAVE_SYSTEMD_LOGIN" = "x0"],
1243     [AC_MSG_ERROR([*** Needed systemd login support not found])])
1244
1245 AC_SUBST(HAVE_SYSTEMD_LOGIN)
1246 AM_CONDITIONAL([HAVE_SYSTEMD_LOGIN], [test "x$HAVE_SYSTEMD_LOGIN" = x1])
1247 AS_IF([test "x$HAVE_SYSTEMD_LOGIN" = "x1"], AC_DEFINE([HAVE_SYSTEMD_LOGIN], 1, [Have SYSTEMDLOGIN?]))
1248
1249 #### systemd journal support (optional) ####
1250
1251 AS_IF([test "x$enable_systemd_journal" != "xno"],
1252     [AS_IF([test "x$HAVE_SYSTEMD_JOURNAL" != "x1"], [PKG_CHECK_MODULES(SYSTEMDJOURNAL, [ libsystemd-journal ], HAVE_SYSTEMD_JOURNAL=1, HAVE_SYSTEMD_JOURNAL=0)])],
1253     HAVE_SYSTEMD_JOURNAL=0)
1254
1255 AS_IF([test "x$enable_systemd_journal" = "xyes" && test "x$HAVE_SYSTEMD_JOURNAL" = "x0"],
1256     [AC_MSG_ERROR([*** Needed systemd journal support not found])])
1257
1258 AC_SUBST(HAVE_SYSTEMD_JOURNAL)
1259 AM_CONDITIONAL([HAVE_SYSTEMD_JOURNAL], [test "x$HAVE_SYSTEMD_JOURNAL" = x1])
1260 AS_IF([test "x$HAVE_SYSTEMD_JOURNAL" = "x1"], AC_DEFINE([HAVE_SYSTEMD_JOURNAL], 1, [Have SYSTEMDJOURNAL?]))
1261
1262 #### Build and Install man pages ####
1263
1264 AC_ARG_ENABLE([manpages],
1265     AS_HELP_STRING([--disable-manpages],[Disable building and installation of man pages]))
1266
1267 AM_CONDITIONAL([BUILD_MANPAGES], [test "x$enable_manpages" != "xno"])
1268
1269 #### PulseAudio system group & user  #####
1270
1271 AC_ARG_WITH(system_user, AS_HELP_STRING([--with-system-user=<user>],[User for running the PulseAudio daemon as a system-wide instance (pulse)]))
1272 if test -z "$with_system_user" ; then
1273     PA_SYSTEM_USER=pulse
1274 else
1275     PA_SYSTEM_USER=$with_system_user
1276 fi
1277 AC_SUBST(PA_SYSTEM_USER)
1278 AC_DEFINE_UNQUOTED(PA_SYSTEM_USER,"$PA_SYSTEM_USER", [User for running the PulseAudio system daemon])
1279
1280 AC_ARG_WITH(system_group,AS_HELP_STRING([--with-system-group=<group>],[Group for running the PulseAudio daemon as a system-wide instance (pulse)]))
1281 if test -z "$with_system_group" ; then
1282     PA_SYSTEM_GROUP=pulse
1283 else
1284     PA_SYSTEM_GROUP=$with_system_group
1285 fi
1286 AC_SUBST(PA_SYSTEM_GROUP)
1287 AC_DEFINE_UNQUOTED(PA_SYSTEM_GROUP,"$PA_SYSTEM_GROUP", [Group for the PulseAudio system daemon])
1288
1289 AC_ARG_WITH(access_group,AS_HELP_STRING([--with-access-group=<group>],[Group which is allowed access to a system-wide PulseAudio daemon (pulse-access)]))
1290 if test -z "$with_access_group" ; then
1291     PA_ACCESS_GROUP=pulse-access
1292 else
1293     PA_ACCESS_GROUP=$with_access_group
1294 fi
1295 AC_SUBST(PA_ACCESS_GROUP)
1296 AC_DEFINE_UNQUOTED(PA_ACCESS_GROUP,"$PA_ACCESS_GROUP", [Access group])
1297
1298 AC_ARG_ENABLE([per-user-esound-socket],
1299     AS_HELP_STRING([--disable-per-user-esound-socket],[Use global esound socket directory /tmp/.esd/socket.]))
1300
1301 if test "x$enable_per_user_esound_socket" != "xno"; then
1302     USE_PER_USER_ESOUND_SOCKET=1
1303     AC_DEFINE([USE_PER_USER_ESOUND_SOCKET], [1], [Define this if you want per-user esound socket directories])
1304 else
1305     USE_PER_USER_ESOUND_SOCKET=0
1306 fi
1307
1308 #### PulseAudio system runtime dir ####
1309
1310 PA_SYSTEM_RUNTIME_PATH="${localstatedir}/run/pulse"
1311 AX_DEFINE_DIR(PA_SYSTEM_RUNTIME_PATH, PA_SYSTEM_RUNTIME_PATH, [System runtime dir])
1312 PA_SYSTEM_CONFIG_PATH="${localstatedir}/lib/pulse"
1313 AX_DEFINE_DIR(PA_SYSTEM_CONFIG_PATH, PA_SYSTEM_CONFIG_PATH, [System config dir])
1314 PA_SYSTEM_STATE_PATH="${localstatedir}/lib/pulse"
1315 AX_DEFINE_DIR(PA_SYSTEM_STATE_PATH, PA_SYSTEM_STATE_PATH, [System state dir])
1316
1317 PA_BINARY=${bindir}/pulseaudio${EXEEXT}
1318 AX_DEFINE_DIR(PA_BINARY, PA_BINARY, [Location of pulseaudio binary])
1319
1320 PACTL_BINARY=${bindir}/pactl${EXEEXT}
1321 AX_DEFINE_DIR(PACTL_BINARY, PACTL_BINARY, [Location of pactl binary])
1322
1323 AC_SUBST(PA_SOEXT, [.so])
1324 AC_DEFINE(PA_SOEXT, [".so"], [Shared object extension])
1325
1326 AC_SUBST(pulseconfdir, ["${sysconfdir}/pulse"])
1327 AX_DEFINE_DIR(PA_DEFAULT_CONFIG_DIR, pulseconfdir, [Location of configuration files])
1328
1329 #### Mac OSX specific stuff #####
1330
1331 AC_ARG_ENABLE(mac-universal,
1332     AS_HELP_STRING([--enable-mac-universal], [Build Mac universal binaries]),
1333     enable_mac_universal=$enableval, enable_mac_universal="no")
1334
1335 AC_ARG_WITH(mac-version-min,
1336     AS_HELP_STRING([--with-mac-version-min=<version>], [Defines the earliest version of MacOS X that the executables will run on.]),
1337     mac_version_min=$withval, mac_version_min="10.5")
1338
1339 AC_ARG_WITH(mac-sysroot,
1340     AS_HELP_STRING([--with-mac-sysroot=<path>], [SDK basedir to use as the logical root directory for headers and libraries.]),
1341     mac_sysroot=$withval, mac_sysroot="/Developer/SDKs/MacOSX10.5.sdk")
1342
1343 if test "x$os_is_darwin" = "x1" ; then
1344     LDFLAGS="$LDFLAGS -isysroot $mac_sysroot -mmacosx-version-min=$mac_version_min"
1345     CFLAGS="$CFLAGS -isysroot $mac_sysroot -mmacosx-version-min=$mac_version_min"
1346
1347     if test "x$enable_mac_universal" = "xyes" ; then
1348         mac_arches="-arch i386 -arch x86_64"
1349         LDFLAGS="$LDFLAGS $mac_arches"
1350         CFLAGS="$CFLAGS $mac_arches"
1351     fi
1352 fi
1353
1354 AC_ARG_ENABLE([webrtc-aec],
1355     AS_HELP_STRING([--enable-webrtc-aec], [Enable the optional WebRTC-based echo canceller]))
1356
1357 AS_IF([test "x$enable_webrtc_aec" != "xno"],
1358     [PKG_CHECK_MODULES(WEBRTC, [ webrtc-audio-processing ], [HAVE_WEBRTC=1], [HAVE_WEBRTC=0])],
1359     [HAVE_WEBRTC=0])
1360
1361 AS_IF([test "x$enable_webrtc_aec" = "xyes" && test "x$HAVE_WEBRTC" = "x0"],
1362     [AC_MSG_ERROR([*** webrtc-audio-processing library not found])])
1363
1364 AM_CONDITIONAL([HAVE_WEBRTC], [test "x$HAVE_WEBRTC" = "x1"])
1365
1366 AC_ARG_ENABLE([adrian-aec],
1367     AS_HELP_STRING([--enable-adrian-aec], [Enable Adrian's optional echo canceller]))
1368 AS_IF([test "x$enable_adrian_aec" != "xno"],
1369     [HAVE_ADRIAN_EC=1])
1370 AM_CONDITIONAL([HAVE_ADRIAN_EC], [test "x$HAVE_ADRIAN_EC" = "x1"])
1371
1372
1373
1374 ###################################
1375 #            Output               #
1376 ###################################
1377
1378 AC_DEFINE_UNQUOTED(PA_CFLAGS, "$CFLAGS", [The CFLAGS used during compilation])
1379
1380 # Check whether to build tests by default (as compile-test) or not
1381 AC_ARG_ENABLE([default-build-tests],
1382     AS_HELP_STRING([--disable-default-build-tests], [Build test programs only during make check]))
1383 AM_CONDITIONAL([BUILD_TESTS_DEFAULT], [test "x$enable_default_build_tests" != "xno"])
1384
1385 AC_ARG_ENABLE([legacy-database-entry-format],
1386         AS_HELP_STRING([--disable-legacy-database-entry-format], [Try to load legacy (< 1.0) database files (card, device and volume restore).]))
1387 if test "x$enable_legacy_database_entry_format" != "xno" ; then
1388         AC_DEFINE(ENABLE_LEGACY_DATABASE_ENTRY_FORMAT, [1], [Legacy database entry format])
1389 fi
1390
1391 AC_ARG_ENABLE([static-bins],
1392     AS_HELP_STRING([--enable-static-bins],[Statically link executables.]))
1393 AM_CONDITIONAL([STATIC_BINS], [test "x$enable_static_bins" = "xyes"])
1394
1395 AC_ARG_WITH(
1396         [preopen-mods],
1397         AS_HELP_STRING([--with-preopen-mods],[Modules to preopen in daemon (default: all).]),
1398         [PREOPEN_MODS=$withval], [PREOPEN_MODS="all"])
1399 AM_CONDITIONAL([PREOPEN_MODS], [test "x$PREOPEN_MODS" != "xall"])
1400 if test "x$PREOPEN_MODS" != "xall" ; then
1401     tmpLIBS=""
1402     for mod in $PREOPEN_MODS; do
1403         tmpLIBS="$tmpLIBS module-$mod.la"
1404     done
1405     PREOPEN_MODS="$tmpLIBS"
1406     AC_SUBST(PREOPEN_MODS)
1407 fi
1408
1409 AC_ARG_WITH(
1410         [module-dir],
1411         AS_HELP_STRING([--with-module-dir],[Directory where to install the modules to (defaults to ${libdir}/pulse-${PA_MAJORMINOR}/modules]),
1412         [modlibexecdir=$withval], [modlibexecdir="${libdir}/pulse-${PA_MAJORMINOR}/modules"])
1413
1414 AC_SUBST(modlibexecdir)
1415 AX_DEFINE_DIR(PA_DLSEARCHPATH, modlibexecdir, [Modules dir])
1416
1417 AC_ARG_WITH(
1418         [udev-rules-dir],
1419         AS_HELP_STRING([--with-udev-rules-dir],[Directory where to install udev rules to (defaults to /lib/udev/rules.d)]),
1420         [udevrulesdir=$withval], [udevrulesdir="/lib/udev/rules.d"])
1421
1422 AC_SUBST(udevrulesdir)
1423
1424 AC_ARG_WITH(
1425         [zsh-completion-dir],
1426         AS_HELP_STRING([--with-zsh-completion-dir], [Zsh completions directory (defaults to ${datadir}/zsh/site-functions)]),
1427         [zshcompletiondir=$withval], [zshcompletiondir="${datadir}/zsh/site-functions"])
1428
1429 AC_SUBST(zshcompletiondir)
1430
1431 AC_ARG_ENABLE([force-preopen],
1432     AS_HELP_STRING([--enable-force-preopen],[Preopen modules, even when dlopen() is supported.]))
1433
1434 if test "x$enable_force_preopen" = "xyes"; then
1435     FORCE_PREOPEN=yes
1436 else
1437     FORCE_PREOPEN=no
1438 fi
1439
1440 AM_CONDITIONAL([FORCE_PREOPEN], [test "x$FORCE_PREOPEN" = "xyes"])
1441
1442 AC_CONFIG_FILES([
1443 Makefile
1444 src/Makefile
1445 man/Makefile
1446 libpulse.pc
1447 libpulse-simple.pc
1448 libpulse-mainloop-glib.pc
1449 doxygen/Makefile
1450 doxygen/doxygen.conf
1451 src/pulse/version.h
1452 po/Makefile.in
1453 man/pulseaudio.1.xml
1454 man/esdcompat.1.xml
1455 man/pax11publish.1.xml
1456 man/paplay.1.xml
1457 man/pacat.1.xml
1458 man/pacmd.1.xml
1459 man/pactl.1.xml
1460 man/pasuspender.1.xml
1461 man/padsp.1.xml
1462 man/pulse-daemon.conf.5.xml
1463 man/pulse-client.conf.5.xml
1464 man/default.pa.5.xml
1465 man/pulse-cli-syntax.5.xml
1466 man/start-pulseaudio-x11.1.xml
1467 ])
1468
1469 AC_CONFIG_FILES([src/esdcompat:src/daemon/esdcompat.in], [chmod +x src/esdcompat])
1470 AC_CONFIG_FILES([src/start-pulseaudio-x11:src/daemon/start-pulseaudio-x11.in], [chmod +x src/start-pulseaudio-x11])
1471 AC_CONFIG_FILES([src/client.conf:src/pulse/client.conf.in])
1472 AC_CONFIG_FILES([src/daemon.conf:src/daemon/daemon.conf.in],
1473     [m4 src/daemon.conf > src/daemon.conf.gen && mv src/daemon.conf.gen src/daemon.conf])
1474 AC_CONFIG_FILES([src/default.pa:src/daemon/default.pa.in],
1475     [m4 src/default.pa > src/default.pa.gen && mv src/default.pa.gen src/default.pa])
1476 AC_CONFIG_FILES([src/system.pa:src/daemon/system.pa.in],
1477     [m4 src/system.pa > src/system.pa.gen && mv src/system.pa.gen src/system.pa])
1478 AS_IF([test "x$HAVE_SYSTEMD_DAEMON" = "x1"],
1479     [
1480         AC_CONFIG_FILES([src/pulseaudio.service:src/daemon/systemd/user/pulseaudio.service.in])
1481     ])
1482
1483 # CMake related ProjectConfig files
1484 PA_LIBDIR="$libdir"
1485 AX_DEFINE_DIR(PA_LIBDIR, PA_LIBDIR, [PulseAudio library dir])
1486 PA_INCDIR="$includedir"
1487 AX_DEFINE_DIR(PA_INCDIR, PA_INCDIR, [PulseAudio include dir])
1488
1489 AC_CONFIG_FILES([PulseAudioConfig.cmake:PulseAudioConfig.cmake.in],
1490     [m4 PulseAudioConfig.cmake > PulseAudioConfig.cmake.gen && mv PulseAudioConfig.cmake.gen PulseAudioConfig.cmake])
1491 AC_CONFIG_FILES([PulseAudioConfigVersion.cmake])
1492
1493 AC_OUTPUT
1494
1495 # ==========================================================================
1496
1497 AS_IF([test "x$HAVE_X11" = "x1"], ENABLE_X11=yes, ENABLE_X11=no)
1498 AS_IF([test "x$HAVE_OSS_OUTPUT" = "x1"], ENABLE_OSS_OUTPUT=yes, ENABLE_OSS_OUTPUT=no)
1499 AS_IF([test "x$HAVE_OSS_WRAPPER" = "x1"], ENABLE_OSS_WRAPPER=yes, ENABLE_OSS_WRAPPER=no)
1500 AS_IF([test "x$HAVE_ALSA" = "x1"], ENABLE_ALSA=yes, ENABLE_ALSA=no)
1501 AS_IF([test "x$HAVE_COREAUDIO" = "x1"], ENABLE_COREAUDIO=yes, ENABLE_COREAUDIO=no)
1502 AS_IF([test "x$HAVE_SOLARIS" = "x1"], ENABLE_SOLARIS=yes, ENABLE_SOLARIS=no)
1503 AS_IF([test "x$HAVE_WAVEOUT" = "x1"], ENABLE_WAVEOUT=yes, ENABLE_WAVEOUT=no)
1504 AS_IF([test "x$HAVE_GLIB20" = "x1"], ENABLE_GLIB20=yes, ENABLE_GLIB20=no)
1505 AS_IF([test "x$HAVE_GTK30" = "x1"], ENABLE_GTK30=yes, ENABLE_GTK30=no)
1506 AS_IF([test "x$HAVE_GCONF" = "x1"], ENABLE_GCONF=yes, ENABLE_GCONF=no)
1507 AS_IF([test "x$HAVE_AVAHI" = "x1"], ENABLE_AVAHI=yes, ENABLE_AVAHI=no)
1508 AS_IF([test "x$HAVE_JACK" = "x1"], ENABLE_JACK=yes, ENABLE_JACK=no)
1509 AS_IF([test "x$HAVE_LIBASYNCNS" = "x1"], ENABLE_LIBASYNCNS=yes, ENABLE_LIBASYNCNS=no)
1510 AS_IF([test "x$HAVE_LIRC" = "x1"], ENABLE_LIRC=yes, ENABLE_LIRC=no)
1511 AS_IF([test "x$HAVE_XEN" = "x1"], ENABLE_XEN=yes, ENABLE_XEN=no)
1512 AS_IF([test "x$HAVE_DBUS" = "x1"], ENABLE_DBUS=yes, ENABLE_DBUS=no)
1513 AS_IF([test "x$HAVE_UDEV" = "x1"], ENABLE_UDEV=yes, ENABLE_UDEV=no)
1514 AS_IF([test "x$HAVE_SYSTEMD_DAEMON" = "x1"], ENABLE_SYSTEMD_DAEMON=yes, ENABLE_SYSTEMD_DAEMON=no)
1515 AS_IF([test "x$HAVE_SYSTEMD_LOGIN" = "x1"], ENABLE_SYSTEMD_LOGIN=yes, ENABLE_SYSTEMD_LOGIN=no)
1516 AS_IF([test "x$HAVE_SYSTEMD_JOURNAL" = "x1"], ENABLE_SYSTEMD_JOURNAL=yes, ENABLE_SYSTEMD_JOURNAL=no)
1517 AS_IF([test "x$HAVE_BLUEZ_4" = "x1"], ENABLE_BLUEZ_4=yes, ENABLE_BLUEZ_4=no)
1518 AS_IF([test "x$HAVE_BLUEZ_5" = "x1"], ENABLE_BLUEZ_5=yes, ENABLE_BLUEZ_5=no)
1519 AS_IF([test "x$HAVE_BLUEZ_5_OFONO_HEADSET" = "x1"], ENABLE_BLUEZ_5_OFONO_HEADSET=yes, ENABLE_BLUEZ_5_OFONO_HEADSET=no)
1520 AS_IF([test "x$HAVE_BLUEZ_5_NATIVE_HEADSET" = "x1"], ENABLE_BLUEZ_5_NATIVE_HEADSET=yes, ENABLE_BLUEZ_5_NATIVE_HEADSET=no)
1521 AS_IF([test "x$HAVE_HAL_COMPAT" = "x1"], ENABLE_HAL_COMPAT=yes, ENABLE_HAL_COMPAT=no)
1522 AS_IF([test "x$HAVE_TCPWRAP" = "x1"], ENABLE_TCPWRAP=yes, ENABLE_TCPWRAP=no)
1523 AS_IF([test "x$HAVE_LIBSAMPLERATE" = "x1"], ENABLE_LIBSAMPLERATE="yes (DEPRECATED)", ENABLE_LIBSAMPLERATE=no)
1524 AS_IF([test "x$HAVE_IPV6" = "x1"], ENABLE_IPV6=yes, ENABLE_IPV6=no)
1525 AS_IF([test "x$HAVE_OPENSSL" = "x1"], ENABLE_OPENSSL=yes, ENABLE_OPENSSL=no)
1526 AS_IF([test "x$HAVE_FFTW" = "x1"], ENABLE_FFTW=yes, ENABLE_FFTW=no)
1527 AS_IF([test "x$HAVE_ORC" = "xyes"], ENABLE_ORC=yes, ENABLE_ORC=no)
1528 AS_IF([test "x$HAVE_ADRIAN_EC" = "x1"], ENABLE_ADRIAN_EC=yes, ENABLE_ADRIAN_EC=no)
1529 AS_IF([test "x$HAVE_SPEEX" = "x1"], ENABLE_SPEEX=yes, ENABLE_SPEEX=no)
1530 AS_IF([test "x$HAVE_WEBRTC" = "x1"], ENABLE_WEBRTC=yes, ENABLE_WEBRTC=no)
1531 AS_IF([test "x$HAVE_TDB" = "x1"], ENABLE_TDB=yes, ENABLE_TDB=no)
1532 AS_IF([test "x$HAVE_GDBM" = "x1"], ENABLE_GDBM=yes, ENABLE_GDBM=no)
1533 AS_IF([test "x$HAVE_SIMPLEDB" = "x1"], ENABLE_SIMPLEDB=yes, ENABLE_SIMPLEDB=no)
1534 AS_IF([test "x$HAVE_ESOUND" = "x1"], ENABLE_ESOUND=yes, ENABLE_ESOUND=no)
1535 AS_IF([test "x$HAVE_ESOUND" = "x1" -a "x$USE_PER_USER_ESOUND_SOCKET" = "x1"], ENABLE_PER_USER_ESOUND_SOCKET=yes, ENABLE_PER_USER_ESOUND_SOCKET=no)
1536 AS_IF([test "x$HAVE_GCOV" = "x1"], ENABLE_GCOV=yes, ENABLE_GCOV=no)
1537 AS_IF([test "x$HAVE_LIBCHECK" = "x1"], ENABLE_TESTS=yes, ENABLE_TESTS=no)
1538 AS_IF([test "x$enable_legacy_database_entry_format" != "xno"], ENABLE_LEGACY_DATABASE_ENTRY_FORMAT=yes, ENABLE_LEGACY_DATABASE_ENTRY_FORMAT=no)
1539
1540 echo "
1541  ---{ $PACKAGE_NAME $VERSION }---
1542
1543     prefix:                        ${prefix}
1544     sysconfdir:                    ${sysconfdir}
1545     localstatedir:                 ${localstatedir}
1546     modlibexecdir:                 ${modlibexecdir}
1547     System Runtime Path:           ${PA_SYSTEM_RUNTIME_PATH}
1548     System State Path:             ${PA_SYSTEM_STATE_PATH}
1549     System Config Path:            ${PA_SYSTEM_CONFIG_PATH}
1550     Zsh completions directory:     ${zshcompletiondir}
1551     Compiler:                      ${CC}
1552     CFLAGS:                        ${CFLAGS}
1553     CPPFLAGS:                      ${CPPFLAGS}
1554     LIBS:                          ${LIBS}
1555
1556     Enable X11:                    ${ENABLE_X11}
1557     Enable OSS Output:             ${ENABLE_OSS_OUTPUT}
1558     Enable OSS Wrapper:            ${ENABLE_OSS_WRAPPER}
1559     Enable EsounD:                 ${ENABLE_ESOUND}
1560     Enable Alsa:                   ${ENABLE_ALSA}
1561     Enable CoreAudio:              ${ENABLE_COREAUDIO}
1562     Enable Solaris:                ${ENABLE_SOLARIS}
1563     Enable WaveOut:                ${ENABLE_WAVEOUT}
1564     Enable GLib 2.0:               ${ENABLE_GLIB20}
1565     Enable Gtk+ 3.0:               ${ENABLE_GTK30}
1566     Enable GConf:                  ${ENABLE_GCONF}
1567     Enable Avahi:                  ${ENABLE_AVAHI}
1568     Enable Jack:                   ${ENABLE_JACK}
1569     Enable Async DNS:              ${ENABLE_LIBASYNCNS}
1570     Enable LIRC:                   ${ENABLE_LIRC}
1571     Enable Xen PV driver:          ${ENABLE_XEN}
1572     Enable D-Bus:                  ${ENABLE_DBUS}
1573       Enable BlueZ 4:              ${ENABLE_BLUEZ_4}
1574       Enable BlueZ 5:              ${ENABLE_BLUEZ_5}
1575         Enable ofono headsets:     ${ENABLE_BLUEZ_5_OFONO_HEADSET}
1576         Enable native headsets:    ${ENABLE_BLUEZ_5_NATIVE_HEADSET}
1577     Enable udev:                   ${ENABLE_UDEV}
1578       Enable HAL->udev compat:     ${ENABLE_HAL_COMPAT}
1579     Enable systemd
1580       Daemon (Socket Activation):  ${ENABLE_SYSTEMD_DAEMON}
1581       Login (Session Tracking):    ${ENABLE_SYSTEMD_LOGIN}
1582       Journal (Logging):           ${ENABLE_SYSTEMD_JOURNAL}
1583     Enable TCP Wrappers:           ${ENABLE_TCPWRAP}
1584     Enable libsamplerate:          ${ENABLE_LIBSAMPLERATE}
1585     Enable IPv6:                   ${ENABLE_IPV6}
1586     Enable OpenSSL (for Airtunes): ${ENABLE_OPENSSL}
1587     Enable fftw:                   ${ENABLE_FFTW}
1588     Enable orc:                    ${ENABLE_ORC}
1589     Enable Adrian echo canceller:  ${ENABLE_ADRIAN_EC}
1590     Enable speex (resampler, AEC): ${ENABLE_SPEEX}
1591     Enable WebRTC echo canceller:  ${ENABLE_WEBRTC}
1592     Enable gcov coverage:          ${ENABLE_GCOV}
1593     Enable unit tests:             ${ENABLE_TESTS}
1594     Database
1595       tdb:                         ${ENABLE_TDB}
1596       gdbm:                        ${ENABLE_GDBM}
1597       simple database:             ${ENABLE_SIMPLEDB}
1598
1599     System User:                   ${PA_SYSTEM_USER}
1600     System Group:                  ${PA_SYSTEM_GROUP}
1601     Access Group:                  ${PA_ACCESS_GROUP}
1602     Enable per-user EsounD socket: ${ENABLE_PER_USER_ESOUND_SOCKET}
1603     Force preopen:                 ${FORCE_PREOPEN}
1604     Preopened modules:             ${PREOPEN_MODS}
1605
1606     Legacy Database Entry Support: ${ENABLE_LEGACY_DATABASE_ENTRY_FORMAT}
1607 "
1608
1609 if test "${ENABLE_SPEEX}" = "no" && test "${ENABLE_WEBRTC}" = "no" && test "${ENABLE_ADRIAN_EC}" = "no" ; then
1610 AC_MSG_ERROR([At least one echo canceller implementation must be available.])
1611 fi
1612
1613 if test "${ENABLE_DBUS}" = "no" && test "x$os_is_win32" != "x1" ; then
1614    echo "
1615 ===== WARNING WARNING WARNING WARNING WARNING WARNING WARNING =====
1616 You do not have D-Bus support enabled. It is strongly recommended
1617 that you enable D-Bus support if your platform supports it.
1618 Many parts of PulseAudio use D-Bus, from ConsoleKit interaction
1619 to the Device Reservation Protocol to speak to JACK, Bluetooth
1620 support and even a native control protocol for communicating and
1621 controling the PulseAudio daemon itself.
1622 ===== WARNING WARNING WARNING WARNING WARNING WARNING WARNING =====
1623 "
1624 fi
1625
1626 if test "${ENABLE_UDEV}" = "no" && test "x$os_is_win32" != "x1" ; then
1627    echo "
1628 ===== WARNING WARNING WARNING WARNING WARNING WARNING WARNING =====
1629 You do not have udev support enabled. It is strongly recommended
1630 that you enable udev support if your platform supports it as it is
1631 the primary method used to detect hardware audio devices (on Linux)
1632 and is thus a critical part of PulseAudio on that platform.
1633 ===== WARNING WARNING WARNING WARNING WARNING WARNING WARNING =====
1634 "
1635 fi
1636
1637 if test "${ENABLE_SPEEX}" = "no" && test "x$os_is_win32" != "x1" ; then
1638    echo "
1639 ===== WARNING WARNING WARNING WARNING WARNING WARNING WARNING =====
1640 You do not have speex support enabled. It is strongly recommended
1641 that you enable speex support if your platform supports it as it is
1642 the primary method used for audio resampling and is thus a critical
1643 part of PulseAudio on that platform.
1644 ===== WARNING WARNING WARNING WARNING WARNING WARNING WARNING =====
1645 "
1646 fi