configure.ac

   1 AC_PREREQ(2.52)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, cvs and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for cvs/prerelease
   8 AC_INIT(GStreamer Base Plug-ins, 0.10.22.1,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-base)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_CVS="no", GST_CVS="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/audiotestsrc/gstaudiotestsrc.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl our libraries and install dirs use major.minor as a version
  36 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  37 dnl we override it here if we need to for the release candidate of new series
  38 GST_MAJORMINOR=0.10
  39 AC_SUBST(GST_MAJORMINOR)
  40
  41 dnl CURRENT, REVISION, AGE
  42 dnl - library source changed -> increment REVISION
  43 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  44 dnl - interfaces added -> increment AGE
  45 dnl - interfaces removed -> AGE = 0
  46 dnl sets GST_LT_LDFLAGS
  47 AS_LIBTOOL(GST, 16, 0, 16)
  48
  49 dnl FIXME: this macro doesn't actually work;
  50 dnl the generated libtool script has no support for the listed tags.
  51 dnl So this needs to be fixed first if we want to use this
  52 dnl AS_LIBTOOL_TAGS
  53
  54 AC_LIBTOOL_WIN32_DLL
  55 AM_PROG_LIBTOOL
  56
  57 dnl *** required versions of GStreamer stuff ***
  58 GST_REQ=0.10.21.1
  59
  60 dnl *** autotools stuff ****
  61
  62 dnl allow for different autotools
  63 AS_AUTOTOOLS_ALTERNATE
  64
  65 dnl Add parameters for aclocal
  66 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  67
  68 dnl set up gettext
  69 dnl the version check needs to stay here because autopoint greps for it
  70 AM_GNU_GETTEXT_VERSION([0.17])
  71 AM_GNU_GETTEXT([external])
  72 AG_GST_GETTEXT([gst-plugins-base-$GST_MAJORMINOR])
  73
  74 dnl *** check for arguments to configure ***
  75
  76 AG_GST_ARG_DEBUG
  77 AG_GST_ARG_PROFILING
  78 AG_GST_ARG_VALGRIND
  79 AG_GST_ARG_GCOV
  80
  81 AG_GST_ARG_EXAMPLES
  82
  83 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  84 AG_GST_ARG_WITH_PACKAGE_NAME
  85 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  86
  87 dnl let distro override plugin install helper path
  88 AC_ARG_WITH(install-plugins-helper,
  89   AC_HELP_STRING([--with-install-plugins-helper],
  90     [specify path of helper script to call to install plugins]),
  91   [
  92     case "${withval}" in
  93       yes) AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
  94       no)  AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
  95       *)   GST_INSTALL_PLUGINS_HELPER="${withval}" ;;
  96     esac
  97   ],
  98   [
  99     dnl Default value
 100     AS_AC_EXPAND(GST_INSTALL_PLUGINS_HELPER,${libexecdir}/gst-install-plugins-helper)
 101   ]
 102 )
 103 AC_MSG_NOTICE(Using $GST_INSTALL_PLUGINS_HELPER as plugin install helper)
 104 AC_DEFINE_UNQUOTED(GST_INSTALL_PLUGINS_HELPER, "$GST_INSTALL_PLUGINS_HELPER",
 105     [plugin install helper script])
 106 AC_SUBST(GST_INSTALL_PLUGINS_HELPER)
 107
 108 AG_GST_ARG_WITH_PLUGINS
 109
 110 AG_GST_ARG_ENABLE_EXTERNAL
 111
 112 AG_GST_ARG_ENABLE_EXPERIMENTAL
 113
 114 dnl *** checks for platform ***
 115
 116 dnl * hardware/architecture *
 117
 118 dnl common/m4/gst-arch.m4
 119 dnl check CPU type
 120 AG_GST_ARCH
 121
 122 dnl check for large file support
 123 dnl affected plugins must include config.h
 124 AC_SYS_LARGEFILE
 125
 126 dnl *** checks for programs ***
 127
 128 dnl find a compiler
 129 AC_PROG_CC
 130
 131 dnl check if the compiler supports '-c' and '-o' options
 132 AM_PROG_CC_C_O
 133
 134 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 135 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 136
 137 dnl check for documentation tools
 138 GTK_DOC_CHECK([1.3])
 139 AS_PATH_PYTHON([2.1])
 140 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 141
 142 dnl *** checks for libraries ***
 143
 144 dnl libm, for sin() etc.
 145 AC_CHECK_LIBM
 146 AC_SUBST(LIBM)
 147
 148 dnl *** checks for header files ***
 149
 150 dnl check if we have ANSI C header files
 151 AC_HEADER_STDC
 152
 153 dnl used in gst/ffmpegcolorspace/mem.c
 154 dnl FIXME: could be fixed by redefining av_malloc and av_free to GLib's
 155 AC_CHECK_HEADERS([malloc.h])
 156
 157 dnl used in gst/subparse/gstsubparse.c
 158 AC_CHECK_HEADERS([regex.h], HAVE_REGEX_H="yes", HAVE_REGEX_H="no")
 159 AM_CONDITIONAL(HAVE_REGEX_H, test "x$HAVE_REGEX_H" = "xyes")
 160
 161 if test "x$HAVE_REGEX_H" = "xyes"; then
 162   ac_cppflags_save="$CPPFLAGS"
 163   CPPFLAGS="`$PKG_CONFIG --cflags libxml-2.0`"
 164   AC_COMPILE_IFELSE(
 165     AC_LANG_PROGRAM([
 166 #include <libxml/HTMLparser.h>
 167                      ],[
 168 #ifndef LIBXML_HTML_ENABLED
 169 #error libxml2 has no HTML support
 170 #endif /* LIBXML_HTML_ENABLED */
 171                      ]), HAVE_LIBXML_HTML="yes", HAVE_LIBXML_HTML="no")
 172   CPPFLAGS="$ac_cppflags_save"
 173 else
 174   HAVE_LIBXML_HTML="no"
 175 fi
 176 AM_CONDITIONAL(HAVE_LIBXML_HTML, test "x$HAVE_LIBXML_HTML" = "xyes")
 177
 178 dnl used in gst/tcp
 179 AC_CHECK_HEADERS([sys/socket.h],
 180   HAVE_SYS_SOCKET_H="yes", HAVE_SYS_SOCKET_H="no")
 181 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 182
 183 dnl used in gst-libs/gst/rtsp
 184 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 185 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 186   WIN32_LIBS="-lws2_32"
 187   AC_SUBST(WIN32_LIBS)
 188 fi
 189
 190 dnl check for hstrerror, for gst-libs/gst/rtsp
 191 save_libs="$LIBS"
 192 AC_CHECK_FUNC(hstrerror, ,
 193     AC_CHECK_LIB(resolv, hstrerror, ,
 194         [AC_DEFINE(NO_HSTRERROR, 1,
 195              [Define if you have no native hstrerror() function.])]))
 196 HSTRERROR_LIBS=$LIBS
 197 AC_SUBST(HSTRERROR_LIBS)
 198 LIBS="$save_libs"
 199
 200 dnl used in gst-libs/gst/pbutils and associated unit test
 201 AC_CHECK_HEADERS([process.h sys/types.h sys/wait.h sys/stat.h])
 202
 203 dnl ffmpegcolorspace includes _stdint.h
 204 dnl also, Windows does not have long long
 205 AX_CREATE_STDINT_H
 206
 207 dnl *** checks for functions ***
 208 AC_CHECK_FUNCS([localtime_r gmtime_r])
 209
 210 dnl *** checks for types/defines ***
 211
 212 dnl Check for FIONREAD ioctl declaration
 213 dnl used in gst/tcp
 214 GST_CHECK_FIONREAD
 215
 216 dnl *** checks for structures ***
 217
 218 dnl *** checks for compiler characteristics ***
 219
 220 dnl make sure we can use "inline" from C code
 221 AC_C_INLINE
 222
 223 dnl *** checks for library functions ***
 224
 225 dnl check for fseeko()
 226 AC_FUNC_FSEEKO
 227
 228 dnl Check for fast float to int casting as defined in C99
 229 dnl used in gst-libs/gst/floatcast/floatcast.h
 230 save_libs=$LIBS
 231 LIBS="$LIBS $LIBM"
 232 AC_C99_FUNC_LRINT
 233 AC_C99_FUNC_LRINTF
 234 LIBS=$save_libs
 235
 236 dnl Check for a way to display the function name in debug output
 237 AG_GST_CHECK_FUNCTION
 238
 239 dnl *** checks for socket and nsl libraries ***
 240 AC_CHECK_FUNC(socket,,[AC_CHECK_LIB(socket,socket)])
 241 AC_CHECK_FUNC(gethostbyname,,[AC_CHECK_LIB(nsl,gethostbyname)])
 242
 243 dnl *** checks for dependency libraries ***
 244
 245 dnl GLib is required
 246 AG_GST_GLIB_CHECK([2.12])
 247
 248 dnl liboil is required
 249 PKG_CHECK_MODULES(LIBOIL, liboil-0.3 >= 0.3.14, HAVE_LIBOIL=yes, HAVE_LIBOIL=no)
 250 if test "x$HAVE_LIBOIL" != "xyes"; then
 251   AC_ERROR([liboil-0.3.14 or later is required])
 252 fi
 253
 254 dnl checks for gstreamer
 255 dnl uninstalled is selected preferentially -- see pkg-config(1)
 256 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ], yes)
 257 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ], yes)
 258 AG_GST_CHECK_GST_GDP($GST_MAJORMINOR, [$GST_REQ], yes)
 259 AG_GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ], yes)
 260 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 261 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 262
 263 dnl Check for documentation xrefs
 264 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 265 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 266 AC_SUBST(GLIB_PREFIX)
 267 AC_SUBST(GST_PREFIX)
 268
 269 dnl GTK is optional and only used in examples
 270 PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.12.0, HAVE_GTK=yes, HAVE_GTK=no)
 271 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 272
 273 dnl some examples need gtk+-x11
 274 PKG_CHECK_MODULES(GTK_X11, gtk+-x11-2.0 >= 2.12.0,
 275     HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 276 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 277
 278 dnl *** set variables based on configure arguments ***
 279
 280 dnl set license and copyright notice
 281 GST_LICENSE="LGPL"
 282 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 283 AC_SUBST(GST_LICENSE)
 284
 285 dnl set location of plugin directory
 286 AG_GST_SET_PLUGINDIR
 287
 288 dnl define an ERROR_CFLAGS Makefile variable
 289 AG_GST_SET_ERROR_CFLAGS($GST_CVS)
 290
 291 dnl define correct level for debugging messages
 292 AG_GST_SET_LEVEL_DEFAULT($GST_CVS)
 293
 294 dnl used in examples
 295 AG_GST_DEFAULT_ELEMENTS
 296
 297 dnl *** plug-ins to include ***
 298
 299 dnl these are all the gst plug-ins, compilable without additional libs
 300 AG_GST_CHECK_PLUGIN(adder)
 301 AG_GST_CHECK_PLUGIN(app)
 302 AG_GST_CHECK_PLUGIN(audioconvert)
 303 AG_GST_CHECK_PLUGIN(audiorate)
 304 AG_GST_CHECK_PLUGIN(audiotestsrc)
 305 AG_GST_CHECK_PLUGIN(ffmpegcolorspace)
 306 AG_GST_CHECK_PLUGIN(gdp)
 307 AG_GST_CHECK_PLUGIN(playback)
 308 AG_GST_CHECK_PLUGIN(audioresample)
 309 AG_GST_CHECK_PLUGIN(subparse)
 310 AG_GST_CHECK_PLUGIN(tcp)
 311 AG_GST_CHECK_PLUGIN(typefind)
 312 AG_GST_CHECK_PLUGIN(videotestsrc)
 313 AG_GST_CHECK_PLUGIN(videorate)
 314 AG_GST_CHECK_PLUGIN(videoscale)
 315 AG_GST_CHECK_PLUGIN(volume)
 316
 317 dnl check for gstreamer core features (subsystems)
 318 GST_CONFIGPATH=`$PKG_CONFIG --variable=includedir gstreamer-0.10`"/gst/gstconfig.h"
 319 AG_GST_PARSE_SUBSYSTEM_DISABLES($GST_CONFIGPATH)
 320 AM_CONDITIONAL(USE_XML, test $GST_DISABLE_XML != "1")
 321
 322 dnl disable plug-ins that require libxml2's HTML support if it is not available
 323 if test "x$HAVE_LIBXML_HTML" != "xyes"; then
 324   AG_GST_DISABLE_PLUGIN(subparse)
 325 fi
 326
 327 dnl disable plug-ins that require sys/socket.h if it is not available
 328 if test "x$HAVE_SYS_SOCKET_H" != "xyes"; then
 329   AG_GST_DISABLE_PLUGIN(tcp)
 330 fi
 331
 332 dnl *** sys plug-ins ***
 333
 334 echo
 335 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 336 echo
 337
 338 dnl *** X11 ***
 339 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 340 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 341                   [ximagesink], [
 342   AC_PATH_XTRA
 343   ac_cflags_save="$CFLAGS"
 344   ac_cppflags_save="$CPPFLAGS"
 345   CFLAGS="$CFLAGS $X_CFLAGS"
 346   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 347
 348   dnl now try to find the HEADER
 349   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 350
 351   if test "x$HAVE_X" = "xno"
 352   then
 353     AC_MSG_NOTICE([cannot find X11 development files])
 354   else
 355     dnl this is much more than we want
 356     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 357     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 358     dnl it does not add the libs; therefore we add them here
 359     X_LIBS="$X_LIBS -lX11"
 360     AC_SUBST(X_CFLAGS)
 361     AC_SUBST(X_LIBS)
 362   fi
 363   AC_SUBST(HAVE_X)
 364   CFLAGS="$ac_cflags_save"
 365   CPPFLAGS="$ac_cppflags_save"
 366 ])
 367
 368 dnl Check for Xv extension
 369 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 370 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 371                   [xvimagesink], [
 372   AG_GST_CHECK_XV
 373 ])
 374
 375 dnl check for X Shm
 376 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 377 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 378   if test x$HAVE_X = xyes; then
 379     AC_CHECK_LIB(Xext, XShmAttach,
 380                  HAVE_XSHM="yes", HAVE_XSHM="no",
 381                  $X_LIBS)
 382     if test "x$HAVE_XSHM" = "xyes"; then
 383       XSHM_LIBS="-lXext"
 384     else
 385       dnl On AIX, it is in XextSam instead, but we still need -lXext
 386       AC_CHECK_LIB(XextSam, XShmAttach,
 387                    HAVE_XSHM="yes", HAVE_XSHM="no",
 388                    $X_LIBS)
 389       if test "x$HAVE_XSHM" = "xyes"; then
 390         XSHM_LIBS="-lXext -lXextSam"
 391       fi
 392     fi
 393   fi
 394 ], , [
 395   AC_SUBST(HAVE_XSHM)
 396   AC_SUBST(XSHM_LIBS)
 397 ])
 398
 399 dnl v4l/v4l2 checks have been moved down because they require X
 400
 401 dnl *** Video 4 Linux ***
 402 dnl for information about the header/define, see sys/v4l/gstv4lelement.h
 403 dnl renamed to GST_V4L in accordance with V4L2 below
 404 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L, true)
 405 AG_GST_CHECK_FEATURE(GST_V4L, [Video 4 Linux], video4linux, [
 406   AC_CHECK_DECL(VID_TYPE_MPEG_ENCODER, HAVE_GST_V4L="yes", HAVE_GST_V4L="no", [
 407 #include <sys/types.h>
 408 #define _LINUX_TIME_H
 409 #define __user
 410 #include <linux/videodev.h>
 411   ])
 412
 413   dnl we can build v4l without Xv, but then we won't have XOverlay support
 414   if test "x$HAVE_GST_V4L" = "xyes" -a "x$HAVE_XVIDEO" != "xyes"
 415   then
 416     AC_MSG_NOTICE([NO XVIDEO FOUND, VIDEO4LINUX WILL BE BUILT])
 417     AC_MSG_NOTICE([WITHOUT XOVERLAY SUPPORT])
 418   fi
 419 ])
 420
 421 dnl *** ext plug-ins ***
 422 dnl keep this list sorted alphabetically !
 423
 424 if test "x$BUILD_EXTERNAL" = "xyes"; then
 425
 426 echo
 427 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 428 echo
 429
 430 dnl *** alsa ***
 431 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 432 AG_GST_CHECK_FEATURE(ALSA, [ALSA], alsa, [
 433   PKG_CHECK_MODULES(ALSA, alsa >= 0.9.1, [
 434     HAVE_ALSA="yes"
 435     AC_SUBST(ALSA_CFLAGS)
 436     AC_SUBST(ALSA_LIBS)
 437   ], [
 438     AM_PATH_ALSA(0.9.1, HAVE_ALSA="yes", HAVE_ALSA="no")
 439   ])
 440 ])
 441
 442 dnl *** CDParanoia ***
 443 translit(dnm, m, l) AM_CONDITIONAL(USE_CDPARANOIA, true)
 444 AG_GST_CHECK_FEATURE(CDPARANOIA, [CDParanoia], cdparanoia, [
 445   AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 446                       cdda_open, -lm,
 447                       cdda_interface.h,
 448                       CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 449                       HEADER_DIR="no"
 450                       FOUND_CDPARANOIA="yes")
 451   if test "x$FOUND_CDPARANOIA" != "xyes";
 452   then
 453     AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 454                         cdda_open, -lm,
 455                         cdda/cdda_interface.h,
 456                         CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 457                         HEADER_DIR="yes"
 458                         FOUND_CDPARANOIA="yes")
 459   fi
 460   if test "x$HEADER_DIR" = "xyes";
 461   then
 462     AC_DEFINE_UNQUOTED(CDPARANOIA_HEADERS_IN_DIR, ,
 463                        defined if cdda headers are in a cdda/ directory)
 464   fi
 465   AC_SUBST(CDPARANOIA_LIBS)
 466 ])
 467 dnl FIXME : add second check somehow if that is necessary
 468 dnl AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
 469 dnl AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
 470
 471 dnl *** GNOME VFS ***
 472 translit(dnm, m, l) AM_CONDITIONAL(USE_GNOME_VFS, true)
 473 AG_GST_CHECK_FEATURE(GNOME_VFS, [GNOME VFS], gnomevfs, [
 474   PKG_CHECK_MODULES(GNOME_VFS, gnome-vfs-2.0, [
 475       HAVE_GNOME_VFS="yes"
 476       AC_SUBST(GNOME_VFS_CFLAGS)
 477       AC_SUBST(GNOME_VFS_LIBS)
 478       GNOME_VFS_MODULES_DIR="`$PKG_CONFIG --variable=modulesdir gnome-vfs-2.0`"
 479       AC_DEFINE_UNQUOTED(GNOME_VFS_MODULES_DIR, "$GNOME_VFS_MODULES_DIR",
 480              [The GnomeVFS modules directory.])
 481     ],[
 482       HAVE_GNOME_VFS="no"
 483     ]
 484     )
 485 ])
 486
 487 dnl *** libgio ***
 488 USE_GIO=$BUILD_EXPERIMENTAL
 489 translit(dnm, m, l) AM_CONDITIONAL(USE_GIO, true)
 490 AG_GST_CHECK_FEATURE(GIO, [GIO library], gio, [
 491   PKG_CHECK_MODULES(GIO, gio-2.0 >= 2.15.2, [
 492     HAVE_GIO="yes"
 493     GIO_MODULE_DIR="`$PKG_CONFIG --variable=giomoduledir gio-2.0`"
 494     AC_DEFINE_UNQUOTED(GIO_MODULE_DIR, "$GIO_MODULE_DIR",
 495            [The GIO modules directory.])
 496     GIO_LIBDIR="`$PKG_CONFIG --variable=libdir gio-2.0`"
 497     AC_DEFINE_UNQUOTED(GIO_LIBDIR, "$GIO_LIBDIR",
 498            [The GIO library directory.])
 499   ], [
 500     HAVE_GIO="no"
 501     AC_MSG_RESULT(no)
 502   ])
 503   AC_SUBST(GIO_CFLAGS)
 504   AC_SUBST(GIO_LIBS)
 505   AC_SUBST(GIO_LDFLAGS)
 506 ])
 507
 508 dnl *** libvisual ***
 509 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBVISUAL, true)
 510 AG_GST_CHECK_FEATURE(LIBVISUAL, [libvisual visualization library], libvisual, [
 511   AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual-0.4 >= 0.4.0)
 512   if test $HAVE_LIBVISUAL = no
 513   then
 514     AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual = 0.2.0)
 515     if test x$HAVE_LIBVISUAL == xyes; then
 516       LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.2`"
 517     fi
 518   else
 519     if test x$HAVE_LIBVISUAL == xyes; then
 520       LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.4`"
 521     fi
 522   fi
 523   AC_MSG_NOTICE([libvisual pluginsdir: $LIBVIS_PLUGINSDIR])
 524   if test x$LIBVIS_PLUGINSDIR != x; then
 525     AC_DEFINE_UNQUOTED(LIBVISUAL_PLUGINSBASEDIR,
 526         "$LIBVIS_PLUGINSDIR",
 527         [directory in which the detected libvisual's plugins are located])
 528   fi
 529 ])
 530
 531 dnl *** ogg ***
 532 translit(dnm, m, l) AM_CONDITIONAL(USE_OGG, true)
 533 AG_GST_CHECK_FEATURE(OGG, [Xiph Ogg library], ogg, [
 534   AG_GST_PKG_CHECK_MODULES(OGG, ogg >= 1.0)
 535   if test $HAVE_OGG = no
 536   then
 537     XIPH_PATH_OGG(HAVE_OGG="yes", HAVE_OGG="no")
 538     AS_SCRUB_INCLUDE(OGG_CFLAGS)
 539   fi
 540 ])
 541
 542 dnl *** pango ***
 543 translit(dnm, m, l) AM_CONDITIONAL(USE_PANGO, true)
 544 AG_GST_CHECK_FEATURE(PANGO, [Pango font rendering], pango, [
 545   AG_GST_PKG_CHECK_MODULES(PANGO, pango pangoft2)
 546 ])
 547
 548 dnl *** theora ***
 549 translit(dnm, m, l) AM_CONDITIONAL(USE_THEORA, true)
 550 AG_GST_CHECK_FEATURE(THEORA, [Xiph Theora video codec], theora, [
 551   dnl theora uses pkg-config version incorrectly, for pkg-config:
 552   dnl 1.0 < 1.0RCX < 1.0alphaX < 1.0betaX < 1.0.0
 553   dnl theoraenc and theoradec appeared in 1.0beta3
 554
 555   AG_GST_PKG_CHECK_MODULES(THEORA, theoradec theoraenc)
 556   if test x$HAVE_THEORA = xno; then
 557     AG_GST_PKG_CHECK_MODULES(THEORA, theora >= 1.0alpha5)
 558   fi
 559 ])
 560
 561 dnl *** vorbis ***
 562 dnl AM_PATH_VORBIS only takes two options
 563 translit(dnm, m, l) AM_CONDITIONAL(USE_VORBIS, true)
 564 AG_GST_CHECK_FEATURE(VORBIS, [Xiph Vorbis audio codec], vorbis, [
 565   AG_GST_PKG_CHECK_MODULES(VORBIS, vorbis >= 1.0 vorbisenc >= 1.0)
 566   if test $HAVE_VORBIS = no
 567   then
 568     XIPH_PATH_VORBIS(HAVE_VORBIS="yes", HAVE_VORBIS="no")
 569     AS_SCRUB_INCLUDE(VORBIS_CFLAGS)
 570   fi
 571 ])
 572
 573 if test "x$HAVE_VORBIS" = "xyes"; then
 574   ac_cflags_save="$CFLAGS"
 575   AC_COMPILE_IFELSE(
 576     AC_LANG_PROGRAM([
 577 #include <vorbis/codec.h>
 578                      ],[
 579 vorbis_dsp_state *v;
 580
 581 vorbis_synthesis_restart (v);
 582                      ]), HAVE_VSR=yes, HAVE_VSR=no)
 583   if test "x$HAVE_VSR" = "xyes"; then
 584     AC_DEFINE_UNQUOTED(HAVE_VORBIS_SYNTHESIS_RESTART, 1,
 585                        [defined if vorbis_synthesis_restart is present])
 586   fi
 587   CFLAGS="$ac_cflags_save"
 588 fi
 589
 590 else
 591
 592 dnl not building plugins with external dependencies,
 593 dnl but we still need to set the conditionals
 594 AM_CONDITIONAL(USE_ALSA, false)
 595 AM_CONDITIONAL(USE_CDPARANOIA, false)
 596 AM_CONDITIONAL(USE_GNOME_VFS, false)
 597 AM_CONDITIONAL(USE_GIO, false)
 598 AM_CONDITIONAL(USE_LIBVISUAL, false)
 599 AM_CONDITIONAL(USE_OGG, false)
 600 AM_CONDITIONAL(USE_PANGO, false)
 601 AM_CONDITIONAL(USE_THEORA, false)
 602 AM_CONDITIONAL(USE_VORBIS, false)
 603
 604 fi dnl of EXT plugins
 605
 606 dnl seeking needs freetype, so check for it here
 607 PKG_CHECK_MODULES(FT2, freetype2 >= 2.0.9, HAVE_FT2="yes", [
 608   AC_CHECK_FT2(2.0.9, HAVE_FT2="yes", HAVE_FT2="no")
 609 ])
 610 dnl make the HAVE_FT2 variable available to automake and Makefile.am
 611 AM_CONDITIONAL(HAVE_FT2, test "x$HAVE_FT2" = "xyes")
 612 AC_SUBST(FT2_CFLAGS)
 613 AC_SUBST(FT2_LIBS)
 614
 615 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 616
 617 dnl Overview:
 618 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 619 dnl GST_*:              flags shared by built objects to link against GStreamer
 620 dnl GST_PLUGINS_BASE_CFLAGS: to link internally against the plugins base libs
 621 dnl                          (compare to other modules) or for i18n
 622 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 623 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 624 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 625 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 626
 627 dnl GST_OPTION_CFLAGS
 628 if test "x$USE_DEBUG" = xyes; then
 629    PROFILE_CFLAGS="-g"
 630 fi
 631 AC_SUBST(PROFILE_CFLAGS)
 632
 633 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 634   dnl Define _only_ during CVS (not pre-releases or releases)
 635   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 636 else
 637   DEPRECATED_CFLAGS=""
 638 fi
 639 AC_SUBST(DEPRECATED_CFLAGS)
 640
 641 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time
 642 GST_OPTION_CFLAGS="\$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 643 AC_SUBST(GST_OPTION_CFLAGS)
 644
 645 dnl our libraries need to be versioned correctly
 646 AC_SUBST(GST_LT_LDFLAGS)
 647
 648 dnl GST_PLUGINS_BASE_CFLAGS
 649 dnl prefer internal headers to already installed ones
 650 dnl also add builddir include for enumtypes and marshal
 651 GST_PLUGINS_BASE_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs"
 652 AC_SUBST(GST_PLUGINS_BASE_CFLAGS)
 653
 654 dnl FIXME: do we want to rename to GST_ALL_* ?
 655 dnl add GST_OPTION_CFLAGS, but overridable
 656 GST_CFLAGS="$GST_CFLAGS \$(GST_OPTION_CFLAGS)"
 657 AC_SUBST(GST_CFLAGS)
 658 dnl add GCOV libs because libtool strips -fprofile-arcs -ftest-coverage
 659 GST_LIBS="$GST_LIBS \$(GCOV_LIBS)"
 660 AC_SUBST(GST_LIBS)
 661
 662 dnl LDFLAGS really should only contain flags, not libs - they get added before
 663 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 664 GST_ALL_LDFLAGS="-no-undefined"
 665 AC_SUBST(GST_ALL_LDFLAGS)
 666
 667 dnl GST_LIB_LDFLAGS
 668 dnl linker flags shared by all libraries
 669 dnl LDFLAGS modifier defining exported symbols from built libraries
 670 dnl (export _gst_foo but not __gst_foo)
 671 GST_LIB_LDFLAGS="-export-symbols-regex ^_?\(gst_\|Gst\|GST_\).*"
 672 AC_SUBST(GST_LIB_LDFLAGS)
 673
 674 dnl this really should only contain flags, not libs - they get added before
 675 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 676 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
 677 AC_SUBST(GST_PLUGIN_LDFLAGS)
 678
 679 dnl *** output files ***
 680
 681 AC_CONFIG_FILES(
 682 Makefile
 683 gst-plugins-base.spec
 684 gst/Makefile
 685 gst/adder/Makefile
 686 gst/app/Makefile
 687 gst/audioconvert/Makefile
 688 gst/audiorate/Makefile
 689 gst/audiotestsrc/Makefile
 690 gst/ffmpegcolorspace/Makefile
 691 gst/gdp/Makefile
 692 gst/playback/Makefile
 693 gst/audioresample/Makefile
 694 gst/subparse/Makefile
 695 gst/tcp/Makefile
 696 gst/typefind/Makefile
 697 gst/videotestsrc/Makefile
 698 gst/videorate/Makefile
 699 gst/videoscale/Makefile
 700 gst/volume/Makefile
 701 sys/Makefile
 702 sys/ximage/Makefile
 703 sys/xvimage/Makefile
 704 sys/v4l/Makefile
 705 ext/Makefile
 706 ext/alsa/Makefile
 707 ext/cdparanoia/Makefile
 708 ext/gnomevfs/Makefile
 709 ext/gio/Makefile
 710 ext/libvisual/Makefile
 711 ext/ogg/Makefile
 712 ext/pango/Makefile
 713 ext/theora/Makefile
 714 ext/vorbis/Makefile
 715 gst-libs/Makefile
 716 gst-libs/gst/Makefile
 717 gst-libs/gst/audio/Makefile
 718 gst-libs/gst/app/Makefile
 719 gst-libs/gst/cdda/Makefile
 720 gst-libs/gst/fft/Makefile
 721 gst-libs/gst/floatcast/Makefile
 722 gst-libs/gst/interfaces/Makefile
 723 gst-libs/gst/netbuffer/Makefile
 724 gst-libs/gst/riff/Makefile
 725 gst-libs/gst/rtp/Makefile
 726 gst-libs/gst/rtsp/Makefile
 727 gst-libs/gst/sdp/Makefile
 728 gst-libs/gst/tag/Makefile
 729 gst-libs/gst/pbutils/Makefile
 730 gst-libs/gst/video/Makefile
 731 tools/Makefile
 732 win32/common/config.h
 733 pkgconfig/Makefile
 734 pkgconfig/gstreamer-audio.pc
 735 pkgconfig/gstreamer-audio-uninstalled.pc
 736 pkgconfig/gstreamer-app.pc
 737 pkgconfig/gstreamer-app-uninstalled.pc
 738 pkgconfig/gstreamer-cdda.pc
 739 pkgconfig/gstreamer-cdda-uninstalled.pc
 740 pkgconfig/gstreamer-fft.pc
 741 pkgconfig/gstreamer-fft-uninstalled.pc
 742 pkgconfig/gstreamer-floatcast.pc
 743 pkgconfig/gstreamer-floatcast-uninstalled.pc
 744 pkgconfig/gstreamer-interfaces.pc
 745 pkgconfig/gstreamer-interfaces-uninstalled.pc
 746 pkgconfig/gstreamer-netbuffer.pc
 747 pkgconfig/gstreamer-netbuffer-uninstalled.pc
 748 pkgconfig/gstreamer-pbutils.pc
 749 pkgconfig/gstreamer-pbutils-uninstalled.pc
 750 pkgconfig/gstreamer-riff.pc
 751 pkgconfig/gstreamer-riff-uninstalled.pc
 752 pkgconfig/gstreamer-rtp.pc
 753 pkgconfig/gstreamer-rtp-uninstalled.pc
 754 pkgconfig/gstreamer-rtsp.pc
 755 pkgconfig/gstreamer-rtsp-uninstalled.pc
 756 pkgconfig/gstreamer-sdp.pc
 757 pkgconfig/gstreamer-sdp-uninstalled.pc
 758 pkgconfig/gstreamer-tag.pc
 759 pkgconfig/gstreamer-tag-uninstalled.pc
 760 pkgconfig/gstreamer-video.pc
 761 pkgconfig/gstreamer-video-uninstalled.pc
 762 pkgconfig/gstreamer-plugins-base.pc
 763 pkgconfig/gstreamer-plugins-base-uninstalled.pc
 764 tests/Makefile
 765 tests/check/Makefile
 766 tests/examples/Makefile
 767 tests/examples/app/Makefile
 768 tests/examples/dynamic/Makefile
 769 tests/examples/seek/Makefile
 770 tests/examples/volume/Makefile
 771 tests/examples/snapshot/Makefile
 772 tests/icles/Makefile
 773 docs/Makefile
 774 docs/design/Makefile
 775 docs/libs/Makefile
 776 docs/plugins/Makefile
 777 docs/version.entities
 778 po/Makefile.in
 779 common/Makefile
 780 common/m4/Makefile
 781 m4/Makefile
 782 )
 783 AC_OUTPUT
 784
 785 AG_GST_OUTPUT_PLUGINS