configure.ac

   1 AC_PREREQ([2.68])
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/prerelease
   8 AC_INIT([GStreamer Base Plug-ins],[1.3.0.1],[http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer],[gst-plugins-base])
   9
  10 AG_GST_INIT
  11
  12 dnl initialize automake
  13 AM_INIT_AUTOMAKE([-Wno-portability 1.11 no-dist-gzip dist-xz tar-ustar subdir-objects])
  14
  15 dnl define PACKAGE_VERSION_* variables
  16 AS_VERSION
  17
  18 dnl check if this is a release version
  19 AS_NANO(GST_GIT="no", GST_GIT="yes")
  20
  21 dnl can autoconf find the source ?
  22 AC_CONFIG_SRCDIR([gst/audiotestsrc/gstaudiotestsrc.c])
  23
  24 dnl define the output header for config
  25 AC_CONFIG_HEADERS([config.h])
  26
  27 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  28 AM_MAINTAINER_MODE([enable])
  29
  30 dnl sets host_* variables
  31 AC_CANONICAL_HOST
  32
  33 dnl use pretty build output with automake >= 1.11
  34 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  35   [AM_DEFAULT_VERBOSITY=1
  36    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  37
  38 dnl our libraries and install dirs use GST_API_VERSION in the filename
  39 dnl to allow side-by-side installation of different API versions
  40 GST_API_VERSION=1.0
  41 AC_SUBST(GST_API_VERSION)
  42 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION",
  43   [GStreamer API Version])
  44
  45 dnl CURRENT, REVISION, AGE
  46 dnl - library source changed -> increment REVISION
  47 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  48 dnl - interfaces added -> increment AGE
  49 dnl - interfaces removed -> AGE = 0
  50 dnl
  51 dnl Keep CURRENT as MINOR * 100 + MICRO
  52 dnl Ex : 1.0.0 => 0
  53 dnl      1.0.3 => 3
  54 dnl      1.1.0 => 100
  55 dnl      1.2.5 => 205
  56 dnl      1.10.9 (who knows) => 1009
  57 dnl
  58 dnl sets GST_LT_LDFLAGS
  59 AS_LIBTOOL(GST, 300, 0, 300)
  60
  61 dnl *** required versions of GStreamer stuff ***
  62 GST_REQ=1.3.0.1
  63
  64 dnl *** autotools stuff ****
  65
  66 dnl allow for different autotools
  67 AS_AUTOTOOLS_ALTERNATE
  68
  69 dnl Add parameters for aclocal
  70 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  71
  72 dnl set up gettext
  73 dnl the version check needs to stay here because autopoint greps for it
  74 AM_GNU_GETTEXT_VERSION([0.17])
  75 AM_GNU_GETTEXT([external])
  76 AG_GST_GETTEXT([gst-plugins-base-$GST_API_VERSION])
  77
  78 dnl *** check for arguments to configure ***
  79
  80 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  81
  82 AG_GST_ARG_DEBUG
  83 AG_GST_ARG_PROFILING
  84 AG_GST_ARG_VALGRIND
  85 AG_GST_ARG_GCOV
  86
  87 AG_GST_ARG_EXAMPLES
  88
  89 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  90 AG_GST_ARG_WITH_PACKAGE_NAME
  91 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  92
  93 AG_GST_PKG_CONFIG_PATH
  94
  95 dnl let distro override plugin install helper path
  96 AC_ARG_WITH(install-plugins-helper,
  97   AS_HELP_STRING([--with-install-plugins-helper],[specify path of helper script to call to install plugins]),
  98   [
  99     case "${withval}" in
 100       yes) AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
 101       no)  AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
 102       *)   GST_INSTALL_PLUGINS_HELPER="${withval}" ;;
 103     esac
 104   ],
 105   [
 106     dnl Default value
 107     AS_AC_EXPAND(GST_INSTALL_PLUGINS_HELPER,${libexecdir}/gst-install-plugins-helper)
 108   ]
 109 )
 110 AC_MSG_NOTICE(Using $GST_INSTALL_PLUGINS_HELPER as plugin install helper)
 111 AC_DEFINE_UNQUOTED(GST_INSTALL_PLUGINS_HELPER, "$GST_INSTALL_PLUGINS_HELPER",
 112     [plugin install helper script])
 113 AC_SUBST(GST_INSTALL_PLUGINS_HELPER)
 114
 115 AG_GST_ARG_WITH_PLUGINS
 116
 117 AG_GST_ARG_ENABLE_EXTERNAL
 118
 119 AG_GST_ARG_ENABLE_EXPERIMENTAL
 120
 121 dnl *** checks for platform ***
 122 AG_GST_PLATFORM
 123
 124 dnl * hardware/architecture *
 125
 126 dnl common/m4/gst-arch.m4
 127 dnl check CPU type
 128 AG_GST_ARCH
 129
 130 dnl check for large file support
 131 dnl affected plugins must include config.h
 132 AC_SYS_LARGEFILE
 133
 134 dnl *** checks for programs ***
 135
 136 dnl find a compiler
 137 AC_PROG_CC
 138 AC_PROG_CC_STDC
 139
 140 dnl check if the compiler supports '-c' and '-o' options
 141 AM_PROG_CC_C_O
 142
 143 dnl determine if c++ is available on this system
 144 AC_PROG_CXX
 145 dnl CXX may be set to some default even if no c++ compiler is available
 146 dnl (thanks autotools!), so just try to compile some c++ code to make sure
 147 AC_LANG_PUSH([C++])
 148 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[ class Foo { int bar; };]], [[]])],[working_cxx=yes],[working_cxx=no])
 149 AC_LANG_POP([C++])
 150 AC_MSG_NOTICE([working c++ compiler found: $working_cxx])
 151 AM_CONDITIONAL(HAVE_CXX, test "x$working_cxx" = "xyes")
 152
 153 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 154 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 155
 156 dnl check for gobject-introspection
 157 GOBJECT_INTROSPECTION_CHECK([1.31.1])
 158
 159 dnl check for documentation tools
 160 GTK_DOC_CHECK([1.12])
 161 AG_GST_PLUGIN_DOCS([1.12])
 162
 163 dnl *** checks for libraries ***
 164
 165 dnl libm, for sin() etc.
 166 LT_LIB_M
 167 AC_SUBST(LIBM)
 168
 169 dnl *** checks for header files ***
 170
 171 dnl check if we have ANSI C header files
 172 AC_HEADER_STDC
 173
 174 dnl check for GCC specific SSE headers
 175 dnl these are used by the speex resampler code
 176 AC_CHECK_HEADERS([xmmintrin.h emmintrin.h])
 177
 178 dnl used in gst/tcp
 179 AC_CHECK_HEADERS([sys/socket.h],
 180   [HAVE_SYS_SOCKET_H="yes"], [HAVE_SYS_SOCKET_H="no"], [AC_INCLUDES_DEFAULT])
 181 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 182
 183 dnl used in gst-libs/gst/pbutils and associated unit test
 184 AC_CHECK_HEADERS([process.h sys/types.h sys/wait.h sys/stat.h], [], [], [AC_INCLUDES_DEFAULT])
 185
 186 dnl checks for ARM NEON support
 187 dnl this instruction set is used by the speex resampler code
 188 AC_MSG_CHECKING(for ARM NEON support in current arch/CFLAGS)
 189 AC_LINK_IFELSE([
 190 AC_LANG_PROGRAM([[
 191   #include <arm_neon.h>
 192   int32x4_t testfunc(int16_t *a, int16_t *b) {
 193       asm volatile ("vmull.s16 q0, d0, d0" : : : "q0");
 194       return vmull_s16(vld1_s16(a), vld1_s16(b));
 195   }
 196 ]])],
 197 [
 198   AC_DEFINE(HAVE_ARM_NEON,[],[ARM NEON support is enabled])
 199   AC_MSG_RESULT(yes)
 200 ],
 201 [
 202   AC_MSG_RESULT(no)
 203 ])
 204
 205 dnl also, Windows does not have long long
 206 AX_CREATE_STDINT_H
 207
 208 dnl *** checks for functions ***
 209 AC_CHECK_FUNCS([localtime_r gmtime_r])
 210
 211 dnl *** checks for math functions ***
 212 LIBS_SAVE=$LIBS
 213 LIBS="$LIBS $LIBM"
 214 AC_CHECK_FUNCS(log2)
 215 LIBS=$LIBS_SAVE
 216
 217 dnl *** checks for types/defines ***
 218
 219 dnl *** checks for structures ***
 220
 221 dnl *** checks for compiler characteristics ***
 222
 223 dnl *** checks for library functions ***
 224
 225 dnl check for fseeko()
 226 AC_FUNC_FSEEKO
 227
 228 dnl Check for fast float to int casting as defined in C99
 229 dnl used to be used in gst-libs/gst/floatcast/floatcast.h (FIXME: still needed?)
 230 save_libs=$LIBS
 231 LIBS="$LIBS $LIBM"
 232 AC_C99_FUNC_LRINT
 233 AC_C99_FUNC_LRINTF
 234 LIBS=$save_libs
 235
 236 dnl Check for a way to display the function name in debug output
 237 AG_GST_CHECK_FUNCTION
 238
 239 dnl *** checks for dependency libraries ***
 240
 241 dnl GLib
 242 GLIB_REQ=2.32
 243 AG_GST_GLIB_CHECK([$GLIB_REQ])
 244
 245 ORC_CHECK([0.4.18])
 246
 247 dnl checks for gstreamer
 248 dnl uninstalled is selected preferentially -- see pkg-config(1)
 249 AG_GST_CHECK_GST($GST_API_VERSION, [$GST_REQ], yes)
 250 AG_GST_CHECK_GST_BASE($GST_API_VERSION, [$GST_REQ], yes)
 251 AG_GST_CHECK_GST_CONTROLLER($GST_API_VERSION, [$GST_REQ], yes)
 252 AG_GST_CHECK_GST_CHECK($GST_API_VERSION, [$GST_REQ], no)
 253 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 254
 255 dnl Check for documentation xrefs
 256 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 257 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_API_VERSION`"
 258 AC_SUBST(GLIB_PREFIX)
 259 AC_SUBST(GST_PREFIX)
 260
 261 dnl GTK is optional and only used in examples
 262 HAVE_GTK=no
 263 HAVE_GTK_X11=no
 264 GTK_REQ=3.0.0
 265 if test "x$BUILD_EXAMPLES" = "xyes"; then
 266   PKG_CHECK_MODULES(GTK, gtk+-3.0 >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 267   dnl some examples need gtk+-x11
 268   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-3.0 >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 269   PKG_CHECK_MODULES(GTK_QUARTZ, gtk+-quartz-3.0 >= $GTK_REQ, HAVE_GTK_QUARTZ=yes, HAVE_GTK_QUARTZ=no)
 270   AC_SUBST(GTK_LIBS)
 271   AC_SUBST(GTK_CFLAGS)
 272 fi
 273 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 274 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 275 AM_CONDITIONAL(HAVE_GTK_QUARTZ, test "x$HAVE_GTK_QUARTZ" = "xyes")
 276
 277 dnl QT is optional and only used in examples
 278 PKG_CHECK_MODULES(QT, Qt5Gui Qt5Widgets, [
 279   HAVE_QT=yes
 280 ], [
 281   HAVE_QT=no
 282 ])
 283 if test "x$HAVE_QT" = "xyes"; then
 284   AC_CHECK_TOOL(QT_MOC, moc)
 285   AC_MSG_CHECKING([for Qt5 moc])
 286   mocversion=`$QT_MOC -v 2>&1`
 287   mocversiongrep=`echo $mocversion | grep "Qt 5\|moc 5"`
 288   if test x"$mocversiongrep" != x"$mocversion"; then
 289     AC_MSG_RESULT([no])
 290     # moc was not the qt5 one, try with moc-qt5
 291     AC_CHECK_TOOL(QT_MOC, moc-qt5)
 292     AC_MSG_CHECKING([for Qt5 moc-qt5])
 293     mocversion=`$QT_MOC -v 2>&1`
 294     mocversiongrep=`echo $mocversion | grep "Qt 5\|moc 5"`
 295     if test x"$mocversiongrep" != x"$mocversion"; then
 296       AC_CHECK_TOOL(QTCHOOSER, qtchooser)
 297       AC_MSG_CHECKING([for qtchooser])
 298       qt5tooldir=`QT_SELECT=qt5 qtchooser -print-env | grep QTTOOLDIR | cut -d '=' -f 2 | cut -d \" -f 2`
 299       mocversion=`$qt5tooldir/moc -v 2>&1`
 300       mocversiongrep=`echo $mocversion | grep "Qt 5\|moc 5"`
 301       if test x"$mocversiongrep" != x"$mocversion"; then
 302         # no valid moc found
 303         QT_MOC="no"
 304       else
 305         QT_MOC=$qt5tooldir/moc
 306       fi
 307     else
 308       QT_MOC=$QT_MOC
 309     fi
 310   fi
 311   AC_SUBST(QT_MOC)
 312   AC_MSG_RESULT([$QT_MOC])
 313 fi
 314 AM_CONDITIONAL(HAVE_QT, test "x$HAVE_QT" = "xyes")
 315 AM_CONDITIONAL(HAVE_QT_MOC, test "x$HAVE_QT_MOC" != "xno")
 316
 317 dnl chck for linux headers needed by the joystick seek example
 318 AC_COMPILE_IFELSE(
 319 [
 320   AC_LANG_PROGRAM([
 321     #include <linux/input.h>
 322     #include <linux/joystick.h>
 323   ],[
 324     struct js_event js;
 325     js.type = JS_EVENT_AXIS;
 326   ])
 327 ], [
 328   HAVE_LINUX_JOYSTICK_HEADERS="yes"
 329 ], [
 330   HAVE_LINUX_JOYSTICK_HEADERS="no"
 331 ])
 332 AM_CONDITIONAL(HAVE_LINUX_JOYSTICK_HEADERS, test "x$HAVE_LINUX_JOYSTICK_HEADERS" = "xyes")
 333
 334 dnl Check for -Bsymbolic-functions linker flag used to avoid
 335 dnl intra-library PLT jumps, if available.
 336 AC_ARG_ENABLE(Bsymbolic,
 337               [AS_HELP_STRING([--disable-Bsymbolic],[avoid linking with -Bsymbolic])],,
 338               [SAVED_LDFLAGS="${LDFLAGS}"
 339                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 340                LDFLAGS=-Wl,-Bsymbolic-functions
 341                AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int main (void) { return 0; }]])],[
 342                            AC_MSG_RESULT(yes)
 343                            enable_Bsymbolic=yes],[
 344                            AC_MSG_RESULT(no)
 345                            enable_Bsymbolic=no])
 346                LDFLAGS="${SAVED_LDFLAGS}"])
 347
 348
 349 dnl *** set variables based on configure arguments ***
 350
 351 dnl set license and copyright notice
 352 GST_LICENSE="LGPL"
 353 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 354 AC_SUBST(GST_LICENSE)
 355
 356 dnl set location of plugin directory
 357 AG_GST_SET_PLUGINDIR
 358
 359 dnl set release date/time
 360 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 361   ["${srcdir}/gst-plugins-base.doap"],
 362   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 363
 364 dnl build static plugins or not
 365 AC_MSG_CHECKING([whether to build static plugins or not])
 366 AC_ARG_ENABLE(
 367   static-plugins,
 368   AC_HELP_STRING(
 369     [--enable-static-plugins],
 370     [build static plugins @<:@default=no@:>@]),
 371   [AS_CASE(
 372     [$enableval], [no], [], [yes], [],
 373     [AC_MSG_ERROR([bad value "$enableval" for --enable-static-plugins])])],
 374   [enable_static_plugins=no])
 375 AC_MSG_RESULT([$enable_static_plugins])
 376 if test "x$enable_static_plugins" = xyes; then
 377   AC_DEFINE(GST_PLUGIN_BUILD_STATIC, 1,
 378     [Define if static plugins should be built])
 379   GST_PLUGIN_LIBTOOLFLAGS=""
 380 else
 381   GST_PLUGIN_LIBTOOLFLAGS="--tag=disable-static"
 382 fi
 383 AC_SUBST(GST_PLUGIN_LIBTOOLFLAGS)
 384 AM_CONDITIONAL(GST_PLUGIN_BUILD_STATIC, test "x$enable_static_plugins" = "xyes")
 385
 386 # set by AG_GST_PARSE_SUBSYSTEM_DISABLES above
 387 dnl make sure it doesn't complain about unused variables if debugging is disabled
 388 NO_WARNINGS=""
 389 AG_GST_CHECK_GST_DEBUG_DISABLED([NO_WARNINGS="-Wno-unused"], [NO_WARNINGS=""])
 390
 391 dnl define an ERROR_CFLAGS Makefile variable
 392 dnl -Wformat-nonliteral - see ext/pango/gstclockoverlay.c and http://gcc.gnu.org/bugzilla/show_bug.cgi?id=39438
 393 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [
 394     -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef
 395     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 396     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 397     -Wno-multichar -Wnested-externs $NO_WARNINGS])
 398
 399 dnl define an ERROR_CXXFLAGS Makefile variable
 400 AG_GST_SET_ERROR_CXXFLAGS($FATAL_WARNINGS, [
 401     -Wmissing-declarations -Wredundant-decls -Wundef
 402     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 403     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 404     -Wno-multichar $NO_WARNINGS])
 405
 406 dnl define correct level for debugging messages
 407 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 408
 409 dnl used in examples
 410 AG_GST_DEFAULT_ELEMENTS
 411
 412 dnl needed for encoding-target
 413 GST_DATADIR="$GST_PREFIX/share"
 414 AC_DEFINE_UNQUOTED(GST_DATADIR, "$GST_DATADIR", [system wide data directory])
 415 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION", [major/minor version])
 416
 417 dnl behaviour of speex based audio resampler
 418 AC_MSG_CHECKING(which audio resample format to use for integer)
 419 AC_ARG_WITH([audioresample_format],
 420         AS_HELP_STRING([--with-audioresample-format],[Which implementation should be used for integer audio resampling, int/float/auto, (default is auto)]),
 421         [ac_cv_audioresample_format=$withval], [ac_cv_audioresample_format=auto])dnl
 422 AC_MSG_RESULT($ac_cv_audioresample_format)
 423 case $ac_cv_audioresample_format in
 424   int)
 425     AC_DEFINE(AUDIORESAMPLE_FORMAT_INT,1,[The int implementation should be used for integer audio resampling])
 426     AC_SUBST(AUDIORESAMPLE_FORMAT_INT)
 427   ;;
 428   float)
 429     AC_DEFINE(AUDIORESAMPLE_FORMAT_FLOAT,1,[The float implementation should be used for integer audio resampling])
 430     AC_SUBST(AUDIORESAMPLE_FORMAT_FLOAT)
 431   ;;
 432   auto)
 433     AC_DEFINE(AUDIORESAMPLE_FORMAT_AUTO,1,[The implementation that should be used for integer audio resampling witll be benchmarked at runtime])
 434     AC_SUBST(AUDIORESAMPLE_FORMAT_AUTO)
 435 esac
 436
 437 dnl Check for mmap (needed by allocators library)
 438 AC_CHECK_FUNC([mmap], [AC_DEFINE(HAVE_MMAP, 1, [Defined if mmap is supported])])
 439
 440 dnl *** plug-ins to include ***
 441
 442 dnl these are all the gst plug-ins, compilable without additional libs
 443 AG_GST_CHECK_PLUGIN(adder)
 444 AG_GST_CHECK_PLUGIN(app)
 445 AG_GST_CHECK_PLUGIN(audioconvert)
 446 AG_GST_CHECK_PLUGIN(audiorate)
 447 AG_GST_CHECK_PLUGIN(audiotestsrc)
 448 AG_GST_CHECK_PLUGIN(encoding)
 449 AG_GST_CHECK_PLUGIN(videoconvert)
 450 AG_GST_CHECK_PLUGIN(gio)
 451 AG_GST_CHECK_PLUGIN(playback)
 452 AG_GST_CHECK_PLUGIN(audioresample)
 453 AG_GST_CHECK_PLUGIN(subparse)
 454 AG_GST_CHECK_PLUGIN(tcp)
 455 AG_GST_CHECK_PLUGIN(typefind)
 456 AG_GST_CHECK_PLUGIN(videotestsrc)
 457 AG_GST_CHECK_PLUGIN(videorate)
 458 AG_GST_CHECK_PLUGIN(videoscale)
 459 AG_GST_CHECK_PLUGIN(volume)
 460
 461 dnl iso-codes is optional, used by libgsttag
 462 AC_ARG_ENABLE(iso-codes,
 463 AS_HELP_STRING([--enable-iso-codes],[use iso-codes if installed]),
 464 [case "${enableval}" in
 465   yes) enable_iso_codes=yes ;;
 466   no)  enable_iso_codes=no ;;
 467   *) AC_MSG_ERROR(bad value ${enableval} for --enable-iso-codes) ;;
 468 esac
 469 ],
 470 [enable_iso_codes=yes]) dnl Default value
 471
 472 AC_MSG_CHECKING([whether to use iso-codes if they are available])
 473 if test "x$enable_iso_codes" = "xyes"; then
 474   AC_MSG_RESULT([yes])
 475   have_iso_codes=no
 476   AC_MSG_CHECKING([whether iso-codes are available on this system])
 477   if $PKG_CONFIG iso-codes; then
 478     AC_MSG_RESULT([yes])
 479     AC_MSG_CHECKING([whether iso-codes has iso-639 domain])
 480     if $PKG_CONFIG --variable=domains iso-codes | $GREP -q 639 ; then
 481       AC_MSG_RESULT([yes])
 482       AC_MSG_CHECKING([for iso-codes prefix])
 483       ISO_CODES_PREFIX=`$PKG_CONFIG --variable=prefix iso-codes`
 484       if test -d "$ISO_CODES_PREFIX"; then
 485         AC_MSG_RESULT([yes])
 486         AC_MSG_CHECKING([ISO_CODES_PREFIX])
 487         AC_MSG_RESULT([$ISO_CODES_PREFIX])
 488         ISO_639_DOMAIN="iso_639"
 489         AC_MSG_CHECKING([ISO_639_DOMAIN])
 490         AC_MSG_RESULT([$ISO_639_DOMAIN])
 491         have_iso_codes=yes
 492         AC_DEFINE([HAVE_ISO_CODES], [1], [make use of iso-codes for ISO-639])
 493         AC_DEFINE_UNQUOTED([ISO_CODES_PREFIX], ["$ISO_CODES_PREFIX"], [prefix])
 494         ISO_CODES_VERSION=`$PKG_CONFIG --modversion iso-codes`
 495         AC_DEFINE_UNQUOTED([ISO_CODES_VERSION], ["$ISO_CODES_VERSION"], [ ])
 496       else
 497         AC_MSG_RESULT([no])
 498       fi
 499     else
 500       AC_MSG_RESULT([no])
 501     fi
 502   else
 503     AC_MSG_RESULT([no])
 504   fi
 505   AM_CONDITIONAL(USE_ISO_CODES, test "x$have_iso_codes" = "xyes")
 506 else
 507   AC_MSG_RESULT([no (disabled via --disable-iso-codes)])
 508   AM_CONDITIONAL(USE_ISO_CODES, false)
 509 fi
 510
 511 dnl *** zlib is optionally used by id3 tag parsing in libgsttag ***
 512 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 513 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for ID3 parsing in libgsttag],, [
 514   PKG_CHECK_MODULES(ZLIB, [ zlib ], [
 515       HAVE_ZLIB="yes"
 516     ], [
 517       AG_GST_CHECK_LIBHEADER(ZLIB, z, uncompress,, zlib.h, [
 518         HAVE_ZLIB="yes"
 519         ZLIB_LIBS="-lz"
 520         AC_SUBST(ZLIB_LIBS)
 521       ])
 522     ])
 523 ])
 524
 525 dnl *** sys plug-ins ***
 526
 527 echo
 528 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 529 echo
 530
 531 dnl *** X11 ***
 532 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 533 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 534                   [ximagesink], [
 535   AC_PATH_XTRA
 536   ac_cflags_save="$CFLAGS"
 537   ac_cppflags_save="$CPPFLAGS"
 538   CFLAGS="$CFLAGS $X_CFLAGS"
 539   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 540
 541   dnl now try to find the HEADER
 542   AC_CHECK_HEADER([X11/Xlib.h], [HAVE_X="yes"], [HAVE_X="no"], [AC_INCLUDES_DEFAULT])
 543
 544   if test "x$HAVE_X" = "xno"
 545   then
 546     AC_MSG_NOTICE([cannot find X11 development files])
 547   else
 548     dnl this is much more than we want
 549     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 550     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 551     dnl it does not add the libs; therefore we add them here
 552     X_LIBS="$X_LIBS -lX11"
 553     AC_SUBST(X_CFLAGS)
 554     AC_SUBST(X_LIBS)
 555   fi
 556   AC_SUBST(HAVE_X)
 557   CFLAGS="$ac_cflags_save"
 558   CPPFLAGS="$ac_cppflags_save"
 559 ])
 560
 561 dnl Check for Xv extension
 562 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 563 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 564                   [xvimagesink], [
 565   AG_GST_CHECK_XV
 566 ])
 567
 568 dnl check for X Shm
 569 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 570 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 571   if test x$HAVE_X = xyes; then
 572     AC_CHECK_LIB(Xext, XShmAttach,
 573                  HAVE_XSHM="yes", HAVE_XSHM="no",
 574                  $X_LIBS)
 575     if test "x$HAVE_XSHM" = "xyes"; then
 576       XSHM_LIBS="-lXext"
 577     else
 578       dnl On AIX, it is in XextSam instead, but we still need -lXext
 579       AC_CHECK_LIB(XextSam, XShmAttach,
 580                    HAVE_XSHM="yes", HAVE_XSHM="no",
 581                    $X_LIBS)
 582       if test "x$HAVE_XSHM" = "xyes"; then
 583         XSHM_LIBS="-lXext -lXextSam"
 584       fi
 585     fi
 586   fi
 587 ], , [
 588   AC_SUBST(HAVE_XSHM)
 589   AC_SUBST(XSHM_LIBS)
 590 ])
 591
 592 dnl *** ext plug-ins ***
 593 dnl keep this list sorted alphabetically !
 594
 595 if test "x$BUILD_EXTERNAL" = "xyes"; then
 596
 597 echo
 598 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 599 echo
 600
 601 dnl *** alsa ***
 602 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 603 AG_GST_CHECK_FEATURE(ALSA, [ALSA], alsa, [
 604   PKG_CHECK_MODULES(ALSA, alsa >= 0.9.1, [
 605     HAVE_ALSA="yes"
 606     AC_SUBST(ALSA_CFLAGS)
 607     AC_SUBST(ALSA_LIBS)
 608   ], [
 609     AM_PATH_ALSA(0.9.1, HAVE_ALSA="yes", HAVE_ALSA="no")
 610   ])
 611 ])
 612
 613 dnl *** CDParanoia ***
 614 dnl Note: upstream has a pkg-config file only in post-10.2 SVN so far
 615 translit(dnm, m, l) AM_CONDITIONAL(USE_CDPARANOIA, true)
 616 AG_GST_CHECK_FEATURE(CDPARANOIA, [CDParanoia], cdparanoia, [
 617   PKG_CHECK_MODULES(CDPARANOIA, cdparanoia-3 >= 10.2, [
 618     HAVE_CDPARANOIA="yes"
 619   ], [
 620     AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 621                         cdda_open, -lm,
 622                         cdda_interface.h,
 623                         CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 624                         HEADER_DIR="no"
 625                         FOUND_CDPARANOIA="yes")
 626     if test "x$FOUND_CDPARANOIA" != "xyes";
 627     then
 628       AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 629                           cdda_open, -lm,
 630                           cdda/cdda_interface.h,
 631                           CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 632                           HEADER_DIR="yes"
 633                           FOUND_CDPARANOIA="yes")
 634     fi
 635     if test "x$HEADER_DIR" = "xyes";
 636     then
 637       AC_DEFINE_UNQUOTED(CDPARANOIA_HEADERS_IN_DIR, ,
 638                          defined if cdda headers are in a cdda/ directory)
 639     fi
 640     if test "x$FOUND_CDPARANOIA" = "xyes";
 641     then
 642       AC_CHECK_LIB(cdda_paranoia,
 643                    paranoia_cachemodel_size,
 644                    : ,
 645                    HAVE_CDPARANOIA=no,
 646                  [-lcdda_interface])
 647     fi
 648
 649     AC_SUBST(CDPARANOIA_LIBS)
 650   ])
 651 ])
 652 dnl FIXME : add second check somehow if that is necessary
 653 dnl AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
 654 dnl AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
 655
 656 dnl *** ivorbis ***
 657 dnl AM_PATH_IVORBIS only takes two options
 658 translit(dnm, m, l) AM_CONDITIONAL(USE_IVORBIS, true)
 659 AG_GST_CHECK_FEATURE(IVORBIS, [integer vorbis plug-in], ivorbisdec, [
 660   AG_GST_PKG_CHECK_MODULES(IVORBIS, vorbisidec)
 661   if test $HAVE_IVORBIS = no
 662   then
 663     IVORBIS_LIBS=
 664     IVORBIS_CFLAGS=
 665     AC_CHECK_LIB(vorbisidec, vorbis_block_init,
 666       [IVORBIS_LIBS=-lvorbisidec
 667       HAVE_IVORBIS=yes
 668       case $host in
 669       arm-*-*)
 670         IVORBIS_CFLAGS="-D_ARM_ASSEM_ $IVORBIS_CFLAGS"
 671       esac
 672       ],
 673       HAVE_IVORBIS=no)
 674     AC_SUBST(IVORBIS_LIBS)
 675     AC_SUBST(IVORBIS_CFLAGS)
 676   else
 677     AC_CHECK_LIB(vorbisidec, vorbis_dsp_pcmout,
 678       AC_DEFINE([USE_TREMOLO],1, "Define if building for android"),
 679       USE_TREMOLO=no)
 680   fi
 681 ])
 682
 683 dnl *** libvisual ***
 684 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBVISUAL, true)
 685 AG_GST_CHECK_FEATURE(LIBVISUAL, [libvisual visualization library], libvisual, [
 686   AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual-0.4 >= 0.4.0)
 687   if test $HAVE_LIBVISUAL = no
 688   then
 689     AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual = 0.2.0)
 690     if test x$HAVE_LIBVISUAL = xyes; then
 691       LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.2`"
 692     fi
 693   else
 694     if test x$HAVE_LIBVISUAL = xyes; then
 695       LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.4`"
 696     fi
 697   fi
 698   AC_MSG_NOTICE([libvisual pluginsdir: $LIBVIS_PLUGINSDIR])
 699   if test x$LIBVIS_PLUGINSDIR != x; then
 700     AC_DEFINE_UNQUOTED(LIBVISUAL_PLUGINSBASEDIR,
 701         "$LIBVIS_PLUGINSDIR",
 702         [directory in which the detected libvisual's plugins are located])
 703   fi
 704 ])
 705
 706 dnl *** ogg ***
 707 translit(dnm, m, l) AM_CONDITIONAL(USE_OGG, true)
 708 AG_GST_CHECK_FEATURE(OGG, [Xiph Ogg library], ogg, [
 709   AG_GST_PKG_CHECK_MODULES(OGG, ogg >= 1.0)
 710 ])
 711
 712 dnl *** pango ***
 713 translit(dnm, m, l) AM_CONDITIONAL(USE_PANGO, true)
 714 AG_GST_CHECK_FEATURE(PANGO, [Pango font rendering], pango, [
 715   AG_GST_PKG_CHECK_MODULES(PANGO, pango >= 1.22.0  pangocairo >= 1.22.0)
 716 ])
 717
 718 dnl *** theora ***
 719 translit(dnm, m, l) AM_CONDITIONAL(USE_THEORA, true)
 720 AG_GST_CHECK_FEATURE(THEORA, [Xiph Theora video codec], theora, [
 721   AG_GST_PKG_CHECK_MODULES(THEORA, theoradec >= 1.1 theoraenc >= 1.1)
 722 ])
 723
 724 dnl *** vorbis ***
 725 translit(dnm, m, l) AM_CONDITIONAL(USE_VORBIS, true)
 726 AG_GST_CHECK_FEATURE(VORBIS, [Xiph Vorbis audio codec], vorbis, [
 727   AG_GST_PKG_CHECK_MODULES(VORBIS, vorbis >= 1.0 vorbisenc >= 1.0)
 728 ])
 729
 730 if test "x$HAVE_VORBIS" = "xyes"; then
 731   ac_cflags_save="$CFLAGS"
 732   AC_COMPILE_IFELSE([
 733     AC_LANG_PROGRAM([[
 734 #include <vorbis/codec.h>
 735                      ]],[[
 736 vorbis_dsp_state *v;
 737
 738 vorbis_synthesis_restart (v);
 739                      ]])], HAVE_VSR=yes, HAVE_VSR=no)
 740   if test "x$HAVE_VSR" = "xyes"; then
 741     AC_DEFINE_UNQUOTED(HAVE_VORBIS_SYNTHESIS_RESTART, 1,
 742                        [defined if vorbis_synthesis_restart is present])
 743   fi
 744   CFLAGS="$ac_cflags_save"
 745 fi
 746
 747 else
 748
 749 dnl not building plugins with external dependencies,
 750 dnl but we still need to set the conditionals
 751 AM_CONDITIONAL(USE_ALSA, false)
 752 AM_CONDITIONAL(USE_CDPARANOIA, false)
 753 AM_CONDITIONAL(USE_IVORBIS, false)
 754 AM_CONDITIONAL(USE_LIBVISUAL, false)
 755 AM_CONDITIONAL(USE_OGG, false)
 756 AM_CONDITIONAL(USE_PANGO, false)
 757 AM_CONDITIONAL(USE_THEORA, false)
 758 AM_CONDITIONAL(USE_VORBIS, false)
 759
 760 fi dnl of EXT plugins
 761
 762 dnl seeking needs freetype, so check for it here
 763 PKG_CHECK_MODULES(FT2, freetype2 >= 2.0.9, HAVE_FT2="yes", [
 764   AC_CHECK_FT2(2.0.9, HAVE_FT2="yes", HAVE_FT2="no")
 765 ])
 766 dnl make the HAVE_FT2 variable available to automake and Makefile.am
 767 AM_CONDITIONAL(HAVE_FT2, test "x$HAVE_FT2" = "xyes")
 768 AC_SUBST(FT2_CFLAGS)
 769 AC_SUBST(FT2_LIBS)
 770
 771 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 772
 773 dnl Overview:
 774 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 775 dnl GST_*:              flags shared by built objects to link against GStreamer
 776 dnl GST_PLUGINS_BASE_CFLAGS: to link internally against the plugins base libs
 777 dnl                          (compare to other modules) or for i18n
 778 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 779 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 780 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 781 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 782
 783 dnl GST_OPTION_CFLAGS
 784 if test "x$USE_DEBUG" = xyes; then
 785    PROFILE_CFLAGS="-g"
 786 fi
 787 AC_SUBST(PROFILE_CFLAGS)
 788
 789 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 790   dnl Define _only_ when compiling a git version (not pre-releases or releases)
 791   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 792 else
 793   DEPRECATED_CFLAGS=""
 794 fi
 795 AC_SUBST(DEPRECATED_CFLAGS)
 796
 797 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
 798 dnl at make time with e.g. make ERROR_CFLAGS=""
 799 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 800 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 801 AC_SUBST(GST_OPTION_CFLAGS)
 802 AC_SUBST(GST_OPTION_CXXFLAGS)
 803
 804 dnl our libraries need to be versioned correctly
 805 AC_SUBST(GST_LT_LDFLAGS)
 806
 807 dnl GST_PLUGINS_BASE_CFLAGS
 808 dnl prefer internal headers to already installed ones
 809 dnl also add builddir include for enumtypes and marshal
 810 GST_PLUGINS_BASE_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs"
 811 AC_SUBST(GST_PLUGINS_BASE_CFLAGS)
 812
 813 dnl FIXME: do we want to rename to GST_ALL_* ?
 814 dnl add GST_OPTION_CFLAGS, but overridable
 815 GST_CFLAGS="$GST_CFLAGS"
 816 GST_CXXFLAGS="$GLIB_CFLAGS $GST_CFLAGS \$(GLIB_EXTRA_CFLAGS) \$(GST_OPTION_CXXFLAGS)"
 817 GST_CFLAGS="$GLIB_CFLAGS $GST_CFLAGS \$(GLIB_EXTRA_CFLAGS) \$(GST_OPTION_CFLAGS)"
 818 AC_SUBST(GST_CFLAGS)
 819 AC_SUBST(GST_CXXFLAGS)
 820 dnl add GCOV libs because libtool strips -fprofile-arcs -ftest-coverage
 821 GST_LIBS="$GST_LIBS \$(GCOV_LIBS)"
 822 AC_SUBST(GST_LIBS)
 823
 824 dnl LDFLAGS really should only contain flags, not libs - they get added before
 825 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 826 GST_ALL_LDFLAGS="-no-undefined"
 827 if test "x${enable_Bsymbolic}" = "xyes"; then
 828   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
 829 fi
 830 AC_SUBST(GST_ALL_LDFLAGS)
 831
 832 dnl GST_LIB_LDFLAGS
 833 dnl linker flags shared by all libraries
 834 dnl LDFLAGS modifier defining exported symbols from built libraries
 835 dnl (export _gst_foo but not __gst_foo)
 836 GST_LIB_LDFLAGS="-export-symbols-regex ^_?\(gst_\|Gst\|GST_\).*"
 837 AC_SUBST(GST_LIB_LDFLAGS)
 838
 839 dnl this really should only contain flags, not libs - they get added before
 840 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 841 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_.*' $GST_ALL_LDFLAGS"
 842 AC_SUBST(GST_PLUGIN_LDFLAGS)
 843
 844 dnl *** output files ***
 845
 846 $MKDIR_P tests/check/orc
 847
 848 AC_CONFIG_FILES(
 849 Makefile
 850 gst-plugins-base.spec
 851 gst/Makefile
 852 gst/adder/Makefile
 853 gst/app/Makefile
 854 gst/audioconvert/Makefile
 855 gst/audiorate/Makefile
 856 gst/audiotestsrc/Makefile
 857 gst/encoding/Makefile
 858 gst/videoconvert/Makefile
 859 gst/gio/Makefile
 860 gst/playback/Makefile
 861 gst/audioresample/Makefile
 862 gst/subparse/Makefile
 863 gst/tcp/Makefile
 864 gst/typefind/Makefile
 865 gst/videotestsrc/Makefile
 866 gst/videorate/Makefile
 867 gst/videoscale/Makefile
 868 gst/volume/Makefile
 869 sys/Makefile
 870 sys/ximage/Makefile
 871 sys/xvimage/Makefile
 872 ext/Makefile
 873 ext/alsa/Makefile
 874 ext/cdparanoia/Makefile
 875 ext/libvisual/Makefile
 876 ext/ogg/Makefile
 877 ext/pango/Makefile
 878 ext/theora/Makefile
 879 ext/vorbis/Makefile
 880 gst-libs/Makefile
 881 gst-libs/gst/Makefile
 882 gst-libs/gst/allocators/Makefile
 883 gst-libs/gst/audio/Makefile
 884 gst-libs/gst/app/Makefile
 885 gst-libs/gst/fft/Makefile
 886 gst-libs/gst/riff/Makefile
 887 gst-libs/gst/rtp/Makefile
 888 gst-libs/gst/rtsp/Makefile
 889 gst-libs/gst/sdp/Makefile
 890 gst-libs/gst/tag/Makefile
 891 gst-libs/gst/pbutils/Makefile
 892 gst-libs/gst/pbutils/gstpluginsbaseversion.h
 893 gst-libs/gst/video/Makefile
 894 tools/Makefile
 895 pkgconfig/Makefile
 896 pkgconfig/gstreamer-allocators.pc
 897 pkgconfig/gstreamer-allocators-uninstalled.pc
 898 pkgconfig/gstreamer-audio.pc
 899 pkgconfig/gstreamer-audio-uninstalled.pc
 900 pkgconfig/gstreamer-app.pc
 901 pkgconfig/gstreamer-app-uninstalled.pc
 902 pkgconfig/gstreamer-fft.pc
 903 pkgconfig/gstreamer-fft-uninstalled.pc
 904 pkgconfig/gstreamer-pbutils.pc
 905 pkgconfig/gstreamer-pbutils-uninstalled.pc
 906 pkgconfig/gstreamer-riff.pc
 907 pkgconfig/gstreamer-riff-uninstalled.pc
 908 pkgconfig/gstreamer-rtp.pc
 909 pkgconfig/gstreamer-rtp-uninstalled.pc
 910 pkgconfig/gstreamer-rtsp.pc
 911 pkgconfig/gstreamer-rtsp-uninstalled.pc
 912 pkgconfig/gstreamer-sdp.pc
 913 pkgconfig/gstreamer-sdp-uninstalled.pc
 914 pkgconfig/gstreamer-tag.pc
 915 pkgconfig/gstreamer-tag-uninstalled.pc
 916 pkgconfig/gstreamer-video.pc
 917 pkgconfig/gstreamer-video-uninstalled.pc
 918 pkgconfig/gstreamer-plugins-base.pc
 919 pkgconfig/gstreamer-plugins-base-uninstalled.pc
 920 tests/Makefile
 921 tests/check/Makefile
 922 tests/examples/Makefile
 923 tests/examples/app/Makefile
 924 tests/examples/audio/Makefile
 925 tests/examples/dynamic/Makefile
 926 tests/examples/encoding/Makefile
 927 tests/examples/fft/Makefile
 928 tests/examples/gio/Makefile
 929 tests/examples/overlay/Makefile
 930 tests/examples/seek/Makefile
 931 tests/examples/snapshot/Makefile
 932 tests/examples/playback/Makefile
 933 tests/examples/playrec/Makefile
 934 tests/files/Makefile
 935 tests/icles/Makefile
 936 tests/icles/playback/Makefile
 937 docs/Makefile
 938 docs/design/Makefile
 939 docs/libs/Makefile
 940 docs/plugins/Makefile
 941 docs/version.entities
 942 po/Makefile.in
 943 common/Makefile
 944 common/m4/Makefile
 945 m4/Makefile
 946 )
 947
 948 dnl Create the config.h file for Visual Studio builds
 949 dnl Beware of spaces and /'s in some of the shell variable contents.
 950 sed \
 951     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"/' \
 952     -e 's/.* GST_INSTALL_PLUGINS_HELPER/#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
 953     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
 954     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
 955     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
 956     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
 957     -e 's/.* GST_API_VERSION$/#define GST_API_VERSION "'$GST_API_VERSION'"/' \
 958     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
 959     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
 960     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
 961     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
 962     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
 963     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
 964     -e 's/.* HAVE_ISO_CODES$/#undef HAVE_ISO_CODES/' \
 965     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
 966     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
 967     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
 968     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
 969     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
 970     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
 971     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
 972     -e 's/.* ISO_CODES_PREFIX$/#undef ISO_CODES_PREFIX/' \
 973     -e 's/.* ISO_CODES_VERSION$/#undef ISO_CODES_VERSION/' \
 974     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
 975     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
 976     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
 977     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
 978     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
 979     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
 980     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
 981     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
 982     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.11"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.11"\n#endif/' \
 983     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
 984     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
 985     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directsoundsink\"/" \
 986     -e "s/.* DEFAULT_VIDEOSINK$/#define DEFAULT_VIDEOSINK \"directdrawsink\"/" \
 987     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
 988     config.h.in >win32/common/config.h-new
 989
 990
 991
 992 AC_OUTPUT
 993
 994 AG_GST_OUTPUT_PLUGINS
 995 ORC_OUTPUT
 996