configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2
   3 # Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003,
   4 # 2004, 2006, 2007, 2008, 2009, 2010, 2011 Free Software Foundation,
   5 # Inc.
   6 #
   7 # This program is free software; you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 2, or (at your option)
  10 # any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 AC_PREREQ([2.68])
  21 AC_INIT([GNU Automake], [1.11a], [bug-automake@gnu.org])
  22
  23 AC_CONFIG_SRCDIR([automake.in])
  24 AC_CONFIG_AUX_DIR([lib])
  25
  26 AC_CANONICAL_HOST
  27 AC_CANONICAL_BUILD
  28
  29 # Save the AUTOCONF setting before AM_INIT_AUTOMAKE overrides it; this
  30 # way we can run Autoconf tests from configure (or from the test
  31 # suite) without being bothered by `missing'.  Likewise for autom4te,
  32 # autoreconf, autoheader, and autoupdate.
  33 AC_SUBST([am_AUTOCONF], ["${AUTOCONF-autoconf}"])
  34 AC_SUBST([am_AUTOM4TE], ["${AUTOM4TE-autom4te}"])
  35 AC_SUBST([am_AUTORECONF], ["${AUTORECONF-autoreconf}"])
  36 AC_SUBST([am_AUTOHEADER], ["${AUTOHEADER-autoheader}"])
  37 AC_SUBST([am_AUTOUPDATE], ["${AUTOUPDATE-autoupdate}"])
  38
  39 AM_INIT_AUTOMAKE([1.10a dist-xz filename-length-max=99 color-tests
  40                   parallel-tests silent-rules])
  41
  42 # The API version is the base version.  We must guarantee
  43 # compatibility for all releases with the same API version.
  44 # Our current rule is that:
  45 # * All releases, including the prereleases, in an X.Y series
  46 #   are compatible.  So 1.5.1c is compatible with 1.5.
  47 # * Prereleases on the trunk are all incompatible -- 1.5b and 1.5c
  48 #   aren't the same.
  49 APIVERSION=`echo "$VERSION" | sed -e 's/^\([[0-9]]*\.[[0-9]]*[[a-z]]*\).*$/\1/'`
  50 AC_SUBST([APIVERSION])
  51
  52 AC_SUBST([pkgvdatadir], ["\${datadir}/$PACKAGE-$APIVERSION"])
  53 AC_SUBST([scriptdir], ["\${pkgvdatadir}"])
  54 AC_SUBST([amdir], ["\${pkgvdatadir}/am"])
  55 AC_SUBST([automake_acdir], ["\${datadir}/aclocal-$APIVERSION"])
  56 AC_SUBST([system_acdir], ["\${datadir}/aclocal"])
  57
  58 # $AUTOMAKE and $ACLOCAL are always run after a `cd $top_srcdir',
  59 # hence `.' is really what we want for perllibdir, libdir, and acdir.
  60 ACLOCAL="perllibdir=\"`pwd`/lib$PATH_SEPARATOR./lib\" \"`pwd`/aclocal\" --acdir=m4 -I m4"
  61 AUTOMAKE="perllibdir=\"`pwd`/lib$PATH_SEPARATOR./lib\" \"`pwd`/automake\" --libdir=lib"
  62
  63 AC_PATH_PROG([PERL], [perl])
  64 if test -z "$PERL"; then
  65    AC_MSG_ERROR([perl not found])
  66 fi
  67 # Save details about the selected perl interpreter in config.log.
  68 AM_RUN_LOG([$PERL --version])
  69 $PERL -e 'require 5.006;' || {
  70    AC_MSG_ERROR(
  71 [perl 5.6 or better is required; perl 5.8.2 or better
  72 is recommended.  If you have several perl versions
  73 installed, select the one Automake should use using
  74   ./configure PERL=/path/to/perl])
  75 }
  76
  77 # We require ithreads support, and version 5.7.2 for CLONE.
  78 AC_CACHE_CHECK([whether $PERL supports ithreads], [am_cv_prog_PERL_ithreads],
  79 [if $PERL -e '
  80     require 5.007_002;
  81     use Config;
  82     if ($Config{useithreads})
  83       {
  84         require threads;
  85         import threads;
  86         require Thread::Queue;
  87         import Thread::Queue;
  88         exit 0;
  89       }
  90     exit 1;' >&AS_MESSAGE_LOG_FD 2>&1
  91 then
  92   am_cv_prog_PERL_ithreads=yes
  93 else
  94   am_cv_prog_PERL_ithreads=no
  95 fi])
  96 if test $am_cv_prog_PERL_ithreads = yes; then
  97   PERL_THREADS=1;
  98 else
  99   PERL_THREADS=0;
 100 fi
 101 AC_SUBST([PERL_THREADS])
 102
 103 # The test suite will skip some tests if tex is absent.
 104 AC_CHECK_PROG([TEX], [tex], [tex])
 105 # Save details about the selected TeX program in config.log.
 106 # Redirect input from /dev/null, as TeX might otherwise hang waiting
 107 # for input from the terminal.
 108 AM_RUN_LOG([$TEX --version </dev/null])
 109
 110 # Generate man pages.
 111 AM_MISSING_PROG([HELP2MAN], [help2man])
 112
 113 # Test for Autoconf.  We run Autoconf in a subdirectory to ease
 114 # deletion of any files created (such as those added to
 115 # autom4te.cache).  We used to perform only the last of the three
 116 # following tests, but some users were unable to figure out that their
 117 # installation was broken since --version appeared to work.
 118
 119 required_autoconf_version=2.62
 120 AC_CACHE_CHECK([whether autoconf is installed], [am_cv_autoconf_installed],
 121 [if AM_RUN_LOG([$am_AUTOCONF --version]);
 122 then
 123   am_cv_autoconf_installed=yes
 124 else
 125   am_cv_autoconf_installed=no
 126 fi])
 127 if test "$am_cv_autoconf_installed" = no; then
 128   AC_MSG_ERROR([Autoconf $required_autoconf_version or better is required.
 129     Please make sure it is installed and in your PATH.])
 130 fi
 131
 132 AC_CACHE_CHECK([whether autoconf works], [am_cv_autoconf_works],
 133 [mkdir conftest
 134 echo 'AC''_INIT' > conftest/conftest.ac
 135 if AM_RUN_LOG([cd conftest && $am_AUTOCONF -o /dev/null conftest.ac]);
 136 then
 137   am_cv_autoconf_works=yes
 138 else
 139   am_cv_autoconf_works=no
 140 fi
 141 rm -rf conftest])
 142 if test "$am_cv_autoconf_works" = no; then
 143   AC_MSG_ERROR([The installed version of autoconf does not work.
 144     Please check config.log for error messages before this one.])
 145 fi
 146
 147 AC_CACHE_CHECK([whether autoconf is recent enough], [am_cv_autoconf_version],
 148 [mkdir conftest
 149 dnl Creative quoting required to avoid spurious expansion of AC_PREREQ macro
 150 echo 'AC'"_PREREQ([[$required_autoconf_version]])" > conftest/conftest.ac
 151 if AM_RUN_LOG([cd conftest && $am_AUTOCONF -o /dev/null conftest.ac]);
 152 then
 153   am_cv_autoconf_version=yes
 154 else
 155   am_cv_autoconf_version=no
 156 fi
 157 rm -rf conftest])
 158 if test "$am_cv_autoconf_version" = no; then
 159   AC_MSG_ERROR([Autoconf $required_autoconf_version or better is required.])
 160 fi
 161
 162 # Test for ln.  We need use it to install the versioned binaries.
 163 AC_MSG_CHECKING([whether ln works])
 164 AC_CACHE_VAL([am_cv_prog_ln], [
 165 rm -f conftest conftest.file
 166 : >conftest.file
 167 if ln conftest.file conftest 2>/dev/null; then
 168   am_cv_prog_ln=ln
 169 else
 170   am_cv_prog_ln='cp -p'
 171 fi
 172 rm -f conftest conftest.file])
 173 AC_SUBST([LN], [$am_cv_prog_ln])
 174 result=no
 175 test "x$am_cv_prog_ln" = xln && result=yes
 176 AC_MSG_RESULT([$result])
 177
 178 # The amount we should wait after modifying files depends on the platform.
 179 # On Windows '95, '98 and ME, files modifications have 2-seconds
 180 # granularity and can be up to 3 seconds in the future w.r.t. the
 181 # system clock.  When it is important to ensure one file is older
 182 # than another we wait at least 5 seconds between creations.
 183 case $build in
 184   *-pc-msdosdjgpp) MODIFICATION_DELAY=5;;
 185   *)               MODIFICATION_DELAY=2;;
 186 esac
 187 AC_SUBST([MODIFICATION_DELAY])
 188
 189 # Test for things needed by the test suite.
 190 AC_PROG_EGREP
 191 AC_PROG_FGREP
 192
 193 AC_CACHE_CHECK([whether $SHELL has working 'set -e' with exit trap],
 194 [am_cv_sh_errexit_works],
 195 [if $SHELL -ec "trap 'exit \$?' 0; (exit 77); exit 77"; test $? = 77
 196 then
 197   am_cv_sh_errexit_works=yes
 198 else
 199   am_cv_sh_errexit_works=no
 200 fi
 201 ])
 202 if test $am_cv_sh_errexit_works = no; then
 203   AC_MSG_WARN([`${MAKE-make} check' will leave leftover directories tests/*.dir])
 204   AC_MSG_WARN([you can clean them up manually using `${MAKE-make} clean' or])
 205   AC_MSG_WARN([`cd tests && ${MAKE-make} clean-local-check'])
 206   dnl restore font-lock: `
 207 fi
 208 AC_SUBST([sh_errexit_works], [$am_cv_sh_errexit_works])
 209
 210 AC_CONFIG_FILES([
 211   Makefile
 212   doc/Makefile
 213   lib/Automake/Makefile
 214   lib/Automake/tests/Makefile
 215   lib/Makefile
 216   lib/am/Makefile
 217   m4/Makefile
 218   tests/Makefile
 219 ])
 220 AC_CONFIG_LINKS([tests/defs:tests/defs])
 221 AC_CONFIG_FILES([tests/aclocal-${APIVERSION}:tests/aclocal.in],
 222                 [chmod +x tests/aclocal-${APIVERSION}],
 223                 [APIVERSION=$APIVERSION])
 224 AC_CONFIG_FILES([tests/automake-${APIVERSION}:tests/automake.in],
 225                 [chmod +x tests/automake-${APIVERSION}])
 226
 227 AC_OUTPUT
 228
 229 # Inform the user if this version of automake is a beta release or
 230 # a development snapshot.
 231 # According to HACKING, the version of a development snapshot should
 232 # end with an "odd" letter (a, c, ...), the version of a test release
 233 # should end wit an "even" letter (b, d, ...).
 234
 235 am_stable_version_rx='[[1-9]\.[0-9]+(\.[0-9]+)?]'
 236 am_beta_version_rx="[$am_stable_version_rx[bdfhjlnprtvxz]]"
 237
 238 am_release_type=`AS_ECHO(["$PACKAGE_VERSION"]) | LC_ALL=C awk ["
 239   /^$am_stable_version_rx$/ { print \"stable\"; exit(0); }
 240   /^$am_beta_version_rx$/ { print \"beta version\"; exit(0); }
 241   { print \"development snapshot\"; }"]`
 242
 243 test "$am_release_type" = stable || cat <<EOF
 244
 245 WARNING: You are about to use a $am_release_type of automake.
 246 WARNING: It might easily suffer from new bugs or regressions.
 247 WARNING: You are strongly advised not to use it in production code.
 248
 249 Please report bugs, problems and feedback to <bug-automake@gnu.org>.
 250 EOF
 251
 252 AS_EXIT([0])