configure.ac

   1 # intel-driver package version number
   2 m4_define([intel_driver_major_version], [1])
   3 m4_define([intel_driver_minor_version], [0])
   4 m4_define([intel_driver_micro_version], [16])
   5 m4_define([intel_driver_pre_version],   [1])
   6 m4_define([intel_driver_version],
   7           [intel_driver_major_version.intel_driver_minor_version.intel_driver_micro_version])
   8 m4_if(intel_driver_pre_version, [0], [], [
   9 m4_append([intel_driver_version], intel_driver_pre_version, [.pre])
  10 ])
  11
  12 # libva minimum version requirement
  13 m4_define([libva_version], [0.34])
  14 m4_define([libva_package_version], [1.2.0])
  15
  16 # libdrm minimum version requirement
  17 m4_define([libdrm_version], [2.4.23])
  18
  19 AC_PREREQ([2.57])
  20 AC_INIT([intel_driver], [intel_driver_version], [haihao.xiang@intel.com],
  21         [libva-driver-intel])
  22 AC_CONFIG_SRCDIR([Makefile.am])
  23 AM_INIT_AUTOMAKE([1.9 tar-ustar])
  24
  25 AM_CONFIG_HEADER([src/config.h])
  26
  27 INTEL_DRIVER_MAJOR_VERSION=intel_driver_major_version
  28 INTEL_DRIVER_MINOR_VERSION=intel_driver_minor_version
  29 INTEL_DRIVER_MICRO_VERSION=intel_driver_micro_version
  30 AC_DEFINE([INTEL_DRIVER_MAJOR_VERSION], [intel_driver_major_version], [Major version of the driver])
  31 AC_DEFINE([INTEL_DRIVER_MINOR_VERSION], [intel_driver_minor_version], [Minor version of the driver])
  32 AC_DEFINE([INTEL_DRIVER_MICRO_VERSION], [intel_driver_micro_version], [Micro version of the driver])
  33 AC_DEFINE([INTEL_DRIVER_PRE_VERSION], [intel_driver_pre_version], [Preversion of the driver])
  34
  35 INTEL_DRIVER_LT_LDFLAGS="-avoid-version"
  36 AC_SUBST(INTEL_DRIVER_LT_LDFLAGS)
  37
  38 dnl Use pretty build output with automake >= 1.11
  39 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])], [
  40     AM_DEFAULT_VERBOSITY=1
  41     AC_SUBST(AM_DEFAULT_VERBOSITY)
  42 ])
  43
  44 AC_ARG_ENABLE(drm,
  45     [AC_HELP_STRING([--enable-drm],
  46                     [build with VA/DRM API support @<:@default=yes@:>@])],
  47     [], [enable_drm="yes"])
  48
  49 AC_DISABLE_STATIC
  50 AC_PROG_LIBTOOL
  51 AC_PROG_CC
  52 AM_PROG_CC_C_O
  53
  54 AC_C_BIGENDIAN
  55 AC_HEADER_STDC
  56 AC_SYS_LARGEFILE
  57
  58 LIBVA_PACKAGE_VERSION=libva_package_version
  59 AC_SUBST(LIBVA_PACKAGE_VERSION)
  60
  61 dnl Check for recent enough DRM
  62 LIBDRM_VERSION=libdrm_version
  63 PKG_CHECK_MODULES([DRM], [libdrm >= $LIBDRM_VERSION])
  64 AC_SUBST(LIBDRM_VERSION)
  65
  66 dnl Check for gen4asm
  67 PKG_CHECK_MODULES(GEN4ASM, [intel-gen4asm >= 1.2], [gen4asm=yes], [gen4asm=no])
  68 AM_CONDITIONAL(HAVE_GEN4ASM, test x$gen4asm = xyes)
  69 AC_PATH_PROG([GEN4ASM], [intel-gen4asm])
  70
  71 dnl Check for VA-API
  72 PKG_CHECK_MODULES(LIBVA_DEPS,     [libva >= libva_version])
  73 PKG_CHECK_MODULES(LIBVA_X11_DEPS, [libva-x11])
  74
  75 dnl Check for VA/DRM API
  76 USE_DRM="$enable_drm"
  77 if test "$USE_DRM" = "yes"; then
  78     PKG_CHECK_MODULES(LIBVA_DRM_DEPS, [libva-drm],
  79       [AC_DEFINE([HAVE_VA_DRM], [1], [Defined to 1 if VA/DRM API is enabled])],
  80       [USE_DRM="no"])
  81
  82     # Check for <drm_fourcc.h>
  83     if test "$USE_DRM" = "yes"; then
  84         saved_CPPFLAGS="$CPPFLAGS"
  85         CPPFLAGS="$CPPFLAGS $DRM_CFLAGS"
  86         AC_CHECK_HEADERS([drm_fourcc.h], [:], [USE_DRM="no"])
  87         CPPFLAGS="$saved_CPPFLAGS"
  88     fi
  89 fi
  90 AM_CONDITIONAL(USE_DRM, test "$USE_DRM" = "yes")
  91
  92 VA_VERSION=`$PKG_CONFIG --modversion libva`
  93 VA_MAJOR_VERSION=`echo "$VA_VERSION" | cut -d'.' -f1`
  94 VA_MINOR_VERSION=`echo "$VA_VERSION" | cut -d'.' -f2`
  95 VA_MICRO_VERSION=`echo "$VA_VERSION" | cut -d'.' -f3`
  96 VA_VERSION_STR="$VA_VERSION"
  97
  98 va_full_version_int=`expr ${VA_MAJOR_VERSION:-0} "*" 1000000 + \
  99                           ${VA_MINOR_VERSION:-0} "*" 10000   + \
 100                           ${VA_MICRO_VERSION:-0} "*" 100     + \
 101                           0`
 102 VA_DRIVER_INIT_FUNC="__vaDriverInit_${VA_MAJOR_VERSION}_${VA_MINOR_VERSION}"
 103 AC_DEFINE_UNQUOTED([VA_DRIVER_INIT_FUNC], [$VA_DRIVER_INIT_FUNC],
 104     [Define driver entry-point])
 105
 106 dnl Check for VA-API drivers path
 107 AC_MSG_CHECKING([for VA drivers path])
 108 LIBVA_DRIVERS_PATH=`$PKG_CONFIG libva --variable driverdir`
 109 if test -z "$LIBVA_DRIVERS_PATH"; then
 110     LIBVA_DRIVERS_PATH="/usr/lib/xorg/modules/drivers"
 111 fi
 112 AC_MSG_RESULT([$LIBVA_DRIVERS_PATH])
 113 AC_SUBST(LIBVA_DRIVERS_PATH)
 114
 115 AC_OUTPUT([
 116     Makefile
 117     debian.upstream/Makefile
 118     src/Makefile
 119     src/shaders/Makefile
 120     src/shaders/h264/Makefile
 121     src/shaders/h264/ildb/Makefile
 122     src/shaders/h264/mc/Makefile
 123     src/shaders/mpeg2/Makefile
 124     src/shaders/mpeg2/vld/Makefile
 125     src/shaders/post_processing/Makefile
 126     src/shaders/post_processing/gen5_6/Makefile
 127     src/shaders/post_processing/gen7/Makefile
 128     src/shaders/render/Makefile
 129     src/shaders/utils/Makefile
 130     src/shaders/vme/Makefile
 131 ])
 132
 133 dnl Print summary
 134 BACKENDS="x11"
 135 AS_IF([test "$USE_DRM" = "yes"], [BACKENDS="$BACKENDS drm"])
 136
 137 echo
 138 echo $PACKAGE configuration summary:
 139 echo
 140 echo VA-API version ................... : $VA_VERSION_STR
 141 echo VA-API drivers path .............. : $LIBVA_DRIVERS_PATH
 142 echo Windowing systems ................ : $BACKENDS
 143 echo