configure.ac

   1 AC_PREREQ(2.52)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/prerelease
   8 AC_INIT(GStreamer Base Plug-ins, 0.10.24.1,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-base)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE([-Wno-portability])
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_GIT="no", GST_GIT="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/audiotestsrc/gstaudiotestsrc.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl our libraries and install dirs use major.minor as a version
  36 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  37 dnl we override it here if we need to for the release candidate of new series
  38 GST_MAJORMINOR=0.10
  39 AC_SUBST(GST_MAJORMINOR)
  40
  41 dnl CURRENT, REVISION, AGE
  42 dnl - library source changed -> increment REVISION
  43 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  44 dnl - interfaces added -> increment AGE
  45 dnl - interfaces removed -> AGE = 0
  46 dnl sets GST_LT_LDFLAGS
  47 AS_LIBTOOL(GST, 17, 0, 17)
  48
  49 dnl FIXME: this macro doesn't actually work;
  50 dnl the generated libtool script has no support for the listed tags.
  51 dnl So this needs to be fixed first if we want to use this
  52 dnl AS_LIBTOOL_TAGS
  53
  54 AC_LIBTOOL_WIN32_DLL
  55 AM_PROG_LIBTOOL
  56
  57 dnl *** required versions of GStreamer stuff ***
  58 GST_REQ=0.10.24.1
  59
  60 dnl *** autotools stuff ****
  61
  62 dnl allow for different autotools
  63 AS_AUTOTOOLS_ALTERNATE
  64
  65 dnl Add parameters for aclocal
  66 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  67
  68 dnl set up gettext
  69 dnl the version check needs to stay here because autopoint greps for it
  70 AM_GNU_GETTEXT_VERSION([0.17])
  71 AM_GNU_GETTEXT([external])
  72 AG_GST_GETTEXT([gst-plugins-base-$GST_MAJORMINOR])
  73
  74 dnl *** check for arguments to configure ***
  75
  76 AG_GST_ARG_DEBUG
  77 AG_GST_ARG_PROFILING
  78 AG_GST_ARG_VALGRIND
  79 AG_GST_ARG_GCOV
  80
  81 AG_GST_ARG_EXAMPLES
  82
  83 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  84 AG_GST_ARG_WITH_PACKAGE_NAME
  85 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  86
  87 dnl let distro override plugin install helper path
  88 AC_ARG_WITH(install-plugins-helper,
  89   AC_HELP_STRING([--with-install-plugins-helper],
  90     [specify path of helper script to call to install plugins]),
  91   [
  92     case "${withval}" in
  93       yes) AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
  94       no)  AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
  95       *)   GST_INSTALL_PLUGINS_HELPER="${withval}" ;;
  96     esac
  97   ],
  98   [
  99     dnl Default value
 100     AS_AC_EXPAND(GST_INSTALL_PLUGINS_HELPER,${libexecdir}/gst-install-plugins-helper)
 101   ]
 102 )
 103 AC_MSG_NOTICE(Using $GST_INSTALL_PLUGINS_HELPER as plugin install helper)
 104 AC_DEFINE_UNQUOTED(GST_INSTALL_PLUGINS_HELPER, "$GST_INSTALL_PLUGINS_HELPER",
 105     [plugin install helper script])
 106 AC_SUBST(GST_INSTALL_PLUGINS_HELPER)
 107
 108 AG_GST_ARG_WITH_PLUGINS
 109
 110 AG_GST_ARG_ENABLE_EXTERNAL
 111
 112 AG_GST_ARG_ENABLE_EXPERIMENTAL
 113
 114 dnl *** checks for platform ***
 115
 116 dnl * hardware/architecture *
 117
 118 dnl common/m4/gst-arch.m4
 119 dnl check CPU type
 120 AG_GST_ARCH
 121
 122 dnl check for large file support
 123 dnl affected plugins must include config.h
 124 AC_SYS_LARGEFILE
 125
 126 dnl *** checks for programs ***
 127
 128 dnl find a compiler
 129 AC_PROG_CC
 130
 131 dnl check if the compiler supports '-c' and '-o' options
 132 AM_PROG_CC_C_O
 133
 134 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 135 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 136
 137 dnl check for documentation tools
 138 GTK_DOC_CHECK([1.3])
 139 AS_PATH_PYTHON([2.1])
 140 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 141
 142 dnl *** checks for libraries ***
 143
 144 dnl libm, for sin() etc.
 145 AC_CHECK_LIBM
 146 AC_SUBST(LIBM)
 147
 148 dnl *** checks for header files ***
 149
 150 dnl check if we have ANSI C header files
 151 AC_HEADER_STDC
 152
 153 dnl used in gst/ffmpegcolorspace/mem.c
 154 dnl FIXME: could be fixed by redefining av_malloc and av_free to GLib's
 155 AC_CHECK_HEADERS([malloc.h])
 156
 157 ac_cppflags_save="$CPPFLAGS"
 158 CPPFLAGS="`$PKG_CONFIG --cflags libxml-2.0`"
 159 AC_COMPILE_IFELSE(
 160   AC_LANG_PROGRAM([
 161 #include <libxml/HTMLparser.h>
 162                      ],[
 163 #ifndef LIBXML_HTML_ENABLED
 164 #error libxml2 has no HTML support
 165 #endif /* LIBXML_HTML_ENABLED */
 166                    ]), HAVE_LIBXML_HTML="yes", HAVE_LIBXML_HTML="no")
 167 CPPFLAGS="$ac_cppflags_save"
 168 AM_CONDITIONAL(HAVE_LIBXML_HTML, test "x$HAVE_LIBXML_HTML" = "xyes")
 169
 170 dnl used in gst/tcp
 171 AC_CHECK_HEADERS([sys/socket.h],
 172   HAVE_SYS_SOCKET_H="yes", HAVE_SYS_SOCKET_H="no")
 173 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 174
 175 dnl used in gst-libs/gst/rtsp
 176 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 177 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 178   WIN32_LIBS="-lws2_32"
 179   AC_SUBST(WIN32_LIBS)
 180 fi
 181
 182 dnl check for hstrerror, for gst-libs/gst/rtsp
 183 save_libs="$LIBS"
 184 AC_CHECK_FUNC(hstrerror, ,
 185     AC_CHECK_LIB(resolv, hstrerror, ,
 186         [AC_DEFINE(NO_HSTRERROR, 1,
 187              [Define if you have no native hstrerror() function.])]))
 188 HSTRERROR_LIBS=$LIBS
 189 AC_SUBST(HSTRERROR_LIBS)
 190 LIBS="$save_libs"
 191
 192 dnl used in gst-libs/gst/pbutils and associated unit test
 193 AC_CHECK_HEADERS([process.h sys/types.h sys/wait.h sys/stat.h])
 194
 195 dnl ffmpegcolorspace includes _stdint.h
 196 dnl also, Windows does not have long long
 197 AX_CREATE_STDINT_H
 198
 199 dnl *** checks for functions ***
 200 AC_CHECK_FUNCS([localtime_r gmtime_r])
 201
 202 dnl *** checks for types/defines ***
 203
 204 dnl Check for FIONREAD ioctl declaration
 205 dnl used in gst/tcp
 206 GST_CHECK_FIONREAD
 207
 208 dnl *** checks for structures ***
 209
 210 dnl *** checks for compiler characteristics ***
 211
 212 dnl *** checks for library functions ***
 213
 214 dnl check for fseeko()
 215 AC_FUNC_FSEEKO
 216
 217 dnl Check for fast float to int casting as defined in C99
 218 dnl used in gst-libs/gst/floatcast/floatcast.h
 219 save_libs=$LIBS
 220 LIBS="$LIBS $LIBM"
 221 AC_C99_FUNC_LRINT
 222 AC_C99_FUNC_LRINTF
 223 LIBS=$save_libs
 224
 225 dnl Check for a way to display the function name in debug output
 226 AG_GST_CHECK_FUNCTION
 227
 228 dnl *** checks for socket and nsl libraries ***
 229 AC_CHECK_FUNC(socket,,[AC_CHECK_LIB(socket,socket)])
 230 AC_CHECK_FUNC(gethostbyname,,[AC_CHECK_LIB(nsl,gethostbyname)])
 231
 232 dnl *** checks for dependency libraries ***
 233
 234 dnl GLib is required
 235 AG_GST_GLIB_CHECK([2.16])
 236
 237 dnl liboil is required
 238 PKG_CHECK_MODULES(LIBOIL, liboil-0.3 >= 0.3.14, HAVE_LIBOIL=yes, HAVE_LIBOIL=no)
 239 if test "x$HAVE_LIBOIL" != "xyes"; then
 240   AC_ERROR([liboil-0.3.14 or later is required])
 241 fi
 242
 243 dnl checks for gstreamer
 244 dnl uninstalled is selected preferentially -- see pkg-config(1)
 245 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ], yes)
 246 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ], yes)
 247 AG_GST_CHECK_GST_GDP($GST_MAJORMINOR, [$GST_REQ], yes)
 248 AG_GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ], yes)
 249 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 250 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 251
 252 dnl Check for documentation xrefs
 253 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 254 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 255 AC_SUBST(GLIB_PREFIX)
 256 AC_SUBST(GST_PREFIX)
 257
 258 dnl GTK is optional and only used in examples
 259 PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.14.0, HAVE_GTK=yes, HAVE_GTK=no)
 260 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 261
 262 dnl some examples need gtk+-x11
 263 PKG_CHECK_MODULES(GTK_X11, gtk+-x11-2.0 >= 2.14.0,
 264     HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 265 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 266
 267 dnl *** set variables based on configure arguments ***
 268
 269 dnl set license and copyright notice
 270 GST_LICENSE="LGPL"
 271 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 272 AC_SUBST(GST_LICENSE)
 273
 274 dnl set location of plugin directory
 275 AG_GST_SET_PLUGINDIR
 276
 277 dnl define an ERROR_CFLAGS Makefile variable
 278 AG_GST_SET_ERROR_CFLAGS($GST_GIT)
 279
 280 dnl define correct level for debugging messages
 281 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 282
 283 dnl used in examples
 284 AG_GST_DEFAULT_ELEMENTS
 285
 286 dnl behaviour of speex based audio resampler
 287 AC_MSG_CHECKING(which audio resample format to use for integer)
 288 AC_ARG_WITH([audioresample_format],
 289         AS_HELP_STRING([--with-audioresample-format],[Which implementation should be used for integer audio resampling, int/float/auto, (default is auto)]),
 290         [ac_cv_audioresample_format=$withval], [ac_cv_audioresample_format=auto])dnl
 291 AC_MSG_RESULT($ac_cv_audioresample_format)
 292 case $ac_cv_audioresample_format in
 293   int)
 294     AC_DEFINE(AUDIORESAMPLE_FORMAT_INT,1,[The int implementation should be used for integer audio resampling])
 295     AC_SUBST(AUDIORESAMPLE_FORMAT_INT)
 296   ;;
 297   float)
 298     AC_DEFINE(AUDIORESAMPLE_FORMAT_FLOAT,1,[The float implementation should be used for integer audio resampling])
 299     AC_SUBST(AUDIORESAMPLE_FORMAT_FLOAT)
 300   ;;
 301   auto)
 302     AC_DEFINE(AUDIORESAMPLE_FORMAT_AUTO,1,[The implementation that should be used for integer audio resampling witll be benchmarked at runtime])
 303     AC_SUBST(AUDIORESAMPLE_FORMAT_AUTO)
 304 esac
 305 AM_CONDITIONAL(AUDIORESAMPLE_NEEDS_LIBOIL, test "$ac_cv_audioresample_format" = "auto")
 306
 307 dnl *** plug-ins to include ***
 308
 309 dnl these are all the gst plug-ins, compilable without additional libs
 310 AG_GST_CHECK_PLUGIN(adder)
 311 AG_GST_CHECK_PLUGIN(app)
 312 AG_GST_CHECK_PLUGIN(audioconvert)
 313 AG_GST_CHECK_PLUGIN(audiorate)
 314 AG_GST_CHECK_PLUGIN(audiotestsrc)
 315 AG_GST_CHECK_PLUGIN(ffmpegcolorspace)
 316 AG_GST_CHECK_PLUGIN(gdp)
 317 AG_GST_CHECK_PLUGIN(playback)
 318 AG_GST_CHECK_PLUGIN(audioresample)
 319 AG_GST_CHECK_PLUGIN(subparse)
 320 AG_GST_CHECK_PLUGIN(tcp)
 321 AG_GST_CHECK_PLUGIN(typefind)
 322 AG_GST_CHECK_PLUGIN(videotestsrc)
 323 AG_GST_CHECK_PLUGIN(videorate)
 324 AG_GST_CHECK_PLUGIN(videoscale)
 325 AG_GST_CHECK_PLUGIN(volume)
 326
 327 dnl check for gstreamer core features (subsystems)
 328 GST_CONFIGPATH=`$PKG_CONFIG --variable=includedir gstreamer-0.10`"/gst/gstconfig.h"
 329 AG_GST_PARSE_SUBSYSTEM_DISABLES($GST_CONFIGPATH)
 330 AM_CONDITIONAL(USE_XML, test $GST_DISABLE_XML != "1")
 331
 332 dnl disable plug-ins that require libxml2's HTML support if it is not available
 333 if test "x$HAVE_LIBXML_HTML" != "xyes"; then
 334   AG_GST_DISABLE_PLUGIN(subparse)
 335 fi
 336
 337 dnl disable plug-ins that require sys/socket.h if it is not available
 338 if test "x$HAVE_SYS_SOCKET_H" != "xyes"; then
 339   AG_GST_DISABLE_PLUGIN(tcp)
 340 fi
 341
 342 dnl *** sys plug-ins ***
 343
 344 echo
 345 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 346 echo
 347
 348 dnl *** X11 ***
 349 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 350 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 351                   [ximagesink], [
 352   AC_PATH_XTRA
 353   ac_cflags_save="$CFLAGS"
 354   ac_cppflags_save="$CPPFLAGS"
 355   CFLAGS="$CFLAGS $X_CFLAGS"
 356   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 357
 358   dnl now try to find the HEADER
 359   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 360
 361   if test "x$HAVE_X" = "xno"
 362   then
 363     AC_MSG_NOTICE([cannot find X11 development files])
 364   else
 365     dnl this is much more than we want
 366     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 367     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 368     dnl it does not add the libs; therefore we add them here
 369     X_LIBS="$X_LIBS -lX11"
 370     AC_SUBST(X_CFLAGS)
 371     AC_SUBST(X_LIBS)
 372   fi
 373   AC_SUBST(HAVE_X)
 374   CFLAGS="$ac_cflags_save"
 375   CPPFLAGS="$ac_cppflags_save"
 376 ])
 377
 378 dnl Check for Xv extension
 379 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 380 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 381                   [xvimagesink], [
 382   AG_GST_CHECK_XV
 383 ])
 384
 385 dnl check for X Shm
 386 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 387 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 388   if test x$HAVE_X = xyes; then
 389     AC_CHECK_LIB(Xext, XShmAttach,
 390                  HAVE_XSHM="yes", HAVE_XSHM="no",
 391                  $X_LIBS)
 392     if test "x$HAVE_XSHM" = "xyes"; then
 393       XSHM_LIBS="-lXext"
 394     else
 395       dnl On AIX, it is in XextSam instead, but we still need -lXext
 396       AC_CHECK_LIB(XextSam, XShmAttach,
 397                    HAVE_XSHM="yes", HAVE_XSHM="no",
 398                    $X_LIBS)
 399       if test "x$HAVE_XSHM" = "xyes"; then
 400         XSHM_LIBS="-lXext -lXextSam"
 401       fi
 402     fi
 403   fi
 404 ], , [
 405   AC_SUBST(HAVE_XSHM)
 406   AC_SUBST(XSHM_LIBS)
 407 ])
 408
 409 dnl v4l/v4l2 checks have been moved down because they require X
 410
 411 dnl *** Video 4 Linux ***
 412 dnl for information about the header/define, see sys/v4l/gstv4lelement.h
 413 dnl renamed to GST_V4L in accordance with V4L2 below
 414 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L, true)
 415 AG_GST_CHECK_FEATURE(GST_V4L, [Video 4 Linux], video4linux, [
 416   AC_CHECK_DECL(VID_TYPE_MPEG_ENCODER, HAVE_GST_V4L="yes", HAVE_GST_V4L="no", [
 417 #include <sys/types.h>
 418 #define _LINUX_TIME_H
 419 #define __user
 420 #include <linux/videodev.h>
 421   ])
 422
 423   dnl we can build v4l without Xv, but then we won't have XOverlay support
 424   if test "x$HAVE_GST_V4L" = "xyes" -a "x$HAVE_XVIDEO" != "xyes"
 425   then
 426     AC_MSG_NOTICE([NO XVIDEO FOUND, VIDEO4LINUX WILL BE BUILT])
 427     AC_MSG_NOTICE([WITHOUT XOVERLAY SUPPORT])
 428   fi
 429 ])
 430
 431 # Optional gudev for device probing
 432 AC_ARG_WITH([gudev],
 433   AC_HELP_STRING([--with-gudev],
 434     [device detection with gudev]),
 435   [],
 436   [with_gudev=check])
 437 if test x$HAVE_GST_V4L = xyes; then
 438   if test x$with_gudev != xno; then
 439       PKG_CHECK_MODULES(GUDEV, [ gudev-1.0 >= 143 ],
 440           [ have_gudev=yes
 441             AC_DEFINE(HAVE_GUDEV, 1,
 442                [Whether gudev is available for device detection])
 443             AC_DEFINE([G_UDEV_API_IS_SUBJECT_TO_CHANGE], 1, [I know the API is subject to change.])
 444           ], [
 445           have_gudev=no
 446           ])
 447   else
 448     have_gudev=no
 449   fi
 450 fi
 451 AC_SUBST(GUDEV_CFLAGS)
 452 AC_SUBST(GUDEV_LIBS)
 453
 454 dnl *** ext plug-ins ***
 455 dnl keep this list sorted alphabetically !
 456
 457 if test "x$BUILD_EXTERNAL" = "xyes"; then
 458
 459 echo
 460 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 461 echo
 462
 463 dnl *** alsa ***
 464 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 465 AG_GST_CHECK_FEATURE(ALSA, [ALSA], alsa, [
 466   PKG_CHECK_MODULES(ALSA, alsa >= 0.9.1, [
 467     HAVE_ALSA="yes"
 468     AC_SUBST(ALSA_CFLAGS)
 469     AC_SUBST(ALSA_LIBS)
 470   ], [
 471     AM_PATH_ALSA(0.9.1, HAVE_ALSA="yes", HAVE_ALSA="no")
 472   ])
 473 ])
 474
 475 dnl *** CDParanoia ***
 476 translit(dnm, m, l) AM_CONDITIONAL(USE_CDPARANOIA, true)
 477 AG_GST_CHECK_FEATURE(CDPARANOIA, [CDParanoia], cdparanoia, [
 478   AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 479                       cdda_open, -lm,
 480                       cdda_interface.h,
 481                       CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 482                       HEADER_DIR="no"
 483                       FOUND_CDPARANOIA="yes")
 484   if test "x$FOUND_CDPARANOIA" != "xyes";
 485   then
 486     AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 487                         cdda_open, -lm,
 488                         cdda/cdda_interface.h,
 489                         CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 490                         HEADER_DIR="yes"
 491                         FOUND_CDPARANOIA="yes")
 492   fi
 493   if test "x$HEADER_DIR" = "xyes";
 494   then
 495     AC_DEFINE_UNQUOTED(CDPARANOIA_HEADERS_IN_DIR, ,
 496                        defined if cdda headers are in a cdda/ directory)
 497   fi
 498   if test "x$FOUND_CDPARANOIA" = "xyes";
 499   then
 500     AC_CHECK_LIB(cdda_paranoia,
 501                  paranoia_cachemodel_size,
 502                  : ,
 503                  HAVE_CDPARANOIA=no)
 504   fi
 505
 506   AC_SUBST(CDPARANOIA_LIBS)
 507 ])
 508 dnl FIXME : add second check somehow if that is necessary
 509 dnl AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
 510 dnl AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
 511
 512 dnl *** GNOME VFS ***
 513 translit(dnm, m, l) AM_CONDITIONAL(USE_GNOME_VFS, true)
 514 AG_GST_CHECK_FEATURE(GNOME_VFS, [GNOME VFS], gnomevfs, [
 515   PKG_CHECK_MODULES(GNOME_VFS, gnome-vfs-2.0, [
 516       HAVE_GNOME_VFS="yes"
 517       AC_SUBST(GNOME_VFS_CFLAGS)
 518       AC_SUBST(GNOME_VFS_LIBS)
 519       GNOME_VFS_MODULES_DIR="`$PKG_CONFIG --variable=modulesdir gnome-vfs-2.0`"
 520       AC_DEFINE_UNQUOTED(GNOME_VFS_MODULES_DIR, "$GNOME_VFS_MODULES_DIR",
 521              [The GnomeVFS modules directory.])
 522     ],[
 523       HAVE_GNOME_VFS="no"
 524     ]
 525     )
 526 ])
 527
 528 dnl *** libgio ***
 529 translit(dnm, m, l) AM_CONDITIONAL(USE_GIO, true)
 530 AG_GST_CHECK_FEATURE(GIO, [GIO library], gio, [
 531   PKG_CHECK_MODULES(GIO, gio-2.0 >= 2.15.2, [
 532     HAVE_GIO="yes"
 533     GIO_MODULE_DIR="`$PKG_CONFIG --variable=giomoduledir gio-2.0`"
 534     AC_DEFINE_UNQUOTED(GIO_MODULE_DIR, "$GIO_MODULE_DIR",
 535            [The GIO modules directory.])
 536     GIO_LIBDIR="`$PKG_CONFIG --variable=libdir gio-2.0`"
 537     AC_DEFINE_UNQUOTED(GIO_LIBDIR, "$GIO_LIBDIR",
 538            [The GIO library directory.])
 539   ], [
 540     HAVE_GIO="no"
 541     AC_MSG_RESULT(no)
 542   ])
 543   AC_SUBST(GIO_CFLAGS)
 544   AC_SUBST(GIO_LIBS)
 545   AC_SUBST(GIO_LDFLAGS)
 546 ])
 547
 548 dnl *** libvisual ***
 549 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBVISUAL, true)
 550 AG_GST_CHECK_FEATURE(LIBVISUAL, [libvisual visualization library], libvisual, [
 551   AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual-0.4 >= 0.4.0)
 552   if test $HAVE_LIBVISUAL = no
 553   then
 554     AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual = 0.2.0)
 555     if test x$HAVE_LIBVISUAL == xyes; then
 556       LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.2`"
 557     fi
 558   else
 559     if test x$HAVE_LIBVISUAL == xyes; then
 560       LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.4`"
 561     fi
 562   fi
 563   AC_MSG_NOTICE([libvisual pluginsdir: $LIBVIS_PLUGINSDIR])
 564   if test x$LIBVIS_PLUGINSDIR != x; then
 565     AC_DEFINE_UNQUOTED(LIBVISUAL_PLUGINSBASEDIR,
 566         "$LIBVIS_PLUGINSDIR",
 567         [directory in which the detected libvisual's plugins are located])
 568   fi
 569 ])
 570
 571 dnl *** ogg ***
 572 translit(dnm, m, l) AM_CONDITIONAL(USE_OGG, true)
 573 AG_GST_CHECK_FEATURE(OGG, [Xiph Ogg library], ogg, [
 574   AG_GST_PKG_CHECK_MODULES(OGG, ogg >= 1.0)
 575   if test $HAVE_OGG = no
 576   then
 577     XIPH_PATH_OGG(HAVE_OGG="yes", HAVE_OGG="no")
 578     AS_SCRUB_INCLUDE(OGG_CFLAGS)
 579   fi
 580 ])
 581
 582 dnl *** pango ***
 583 translit(dnm, m, l) AM_CONDITIONAL(USE_PANGO, true)
 584 AG_GST_CHECK_FEATURE(PANGO, [Pango font rendering], pango, [
 585   AG_GST_PKG_CHECK_MODULES(PANGO, pango pangocairo)
 586   PKG_CHECK_MODULES(PANGOCAIRO_1_15_4, pangocairo >= 1.15.4, [ AC_DEFINE(HAVE_PANGO_VERTICAL_WRITING, 1, [Defined if pango can write vertically])])
 587 ])
 588
 589 dnl *** theora ***
 590 translit(dnm, m, l) AM_CONDITIONAL(USE_THEORA, true)
 591 AG_GST_CHECK_FEATURE(THEORA, [Xiph Theora video codec], theora, [
 592   dnl theora uses pkg-config version incorrectly, for pkg-config:
 593   dnl 1.0 < 1.0RCX < 1.0alphaX < 1.0betaX < 1.0.0
 594   dnl theoraenc and theoradec appeared in 1.0beta3
 595
 596   AG_GST_PKG_CHECK_MODULES(THEORA, theoradec theoraenc)
 597   if test x$HAVE_THEORA = xno; then
 598     AG_GST_PKG_CHECK_MODULES(THEORA, theora >= 1.0alpha5)
 599   fi
 600 ])
 601
 602 dnl *** vorbis ***
 603 dnl AM_PATH_VORBIS only takes two options
 604 translit(dnm, m, l) AM_CONDITIONAL(USE_VORBIS, true)
 605 AG_GST_CHECK_FEATURE(VORBIS, [Xiph Vorbis audio codec], vorbis, [
 606   AG_GST_PKG_CHECK_MODULES(VORBIS, vorbis >= 1.0 vorbisenc >= 1.0)
 607   if test $HAVE_VORBIS = no
 608   then
 609     XIPH_PATH_VORBIS(HAVE_VORBIS="yes", HAVE_VORBIS="no")
 610     AS_SCRUB_INCLUDE(VORBIS_CFLAGS)
 611   fi
 612 ])
 613
 614 if test "x$HAVE_VORBIS" = "xyes"; then
 615   ac_cflags_save="$CFLAGS"
 616   AC_COMPILE_IFELSE(
 617     AC_LANG_PROGRAM([
 618 #include <vorbis/codec.h>
 619                      ],[
 620 vorbis_dsp_state *v;
 621
 622 vorbis_synthesis_restart (v);
 623                      ]), HAVE_VSR=yes, HAVE_VSR=no)
 624   if test "x$HAVE_VSR" = "xyes"; then
 625     AC_DEFINE_UNQUOTED(HAVE_VORBIS_SYNTHESIS_RESTART, 1,
 626                        [defined if vorbis_synthesis_restart is present])
 627   fi
 628   CFLAGS="$ac_cflags_save"
 629 fi
 630
 631 else
 632
 633 dnl not building plugins with external dependencies,
 634 dnl but we still need to set the conditionals
 635 AM_CONDITIONAL(USE_ALSA, false)
 636 AM_CONDITIONAL(USE_CDPARANOIA, false)
 637 AM_CONDITIONAL(USE_GNOME_VFS, false)
 638 AM_CONDITIONAL(USE_GIO, false)
 639 AM_CONDITIONAL(USE_LIBVISUAL, false)
 640 AM_CONDITIONAL(USE_OGG, false)
 641 AM_CONDITIONAL(USE_PANGO, false)
 642 AM_CONDITIONAL(USE_THEORA, false)
 643 AM_CONDITIONAL(USE_VORBIS, false)
 644
 645 fi dnl of EXT plugins
 646
 647 dnl seeking needs freetype, so check for it here
 648 PKG_CHECK_MODULES(FT2, freetype2 >= 2.0.9, HAVE_FT2="yes", [
 649   AC_CHECK_FT2(2.0.9, HAVE_FT2="yes", HAVE_FT2="no")
 650 ])
 651 dnl make the HAVE_FT2 variable available to automake and Makefile.am
 652 AM_CONDITIONAL(HAVE_FT2, test "x$HAVE_FT2" = "xyes")
 653 AC_SUBST(FT2_CFLAGS)
 654 AC_SUBST(FT2_LIBS)
 655
 656 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 657
 658 dnl Overview:
 659 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 660 dnl GST_*:              flags shared by built objects to link against GStreamer
 661 dnl GST_PLUGINS_BASE_CFLAGS: to link internally against the plugins base libs
 662 dnl                          (compare to other modules) or for i18n
 663 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 664 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 665 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 666 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 667
 668 dnl GST_OPTION_CFLAGS
 669 if test "x$USE_DEBUG" = xyes; then
 670    PROFILE_CFLAGS="-g"
 671 fi
 672 AC_SUBST(PROFILE_CFLAGS)
 673
 674 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 675   dnl Define _only_ when compiling a git version (not pre-releases or releases)
 676   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 677 else
 678   DEPRECATED_CFLAGS=""
 679 fi
 680 AC_SUBST(DEPRECATED_CFLAGS)
 681
 682 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time
 683 GST_OPTION_CFLAGS="\$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 684 AC_SUBST(GST_OPTION_CFLAGS)
 685
 686 dnl our libraries need to be versioned correctly
 687 AC_SUBST(GST_LT_LDFLAGS)
 688
 689 dnl GST_PLUGINS_BASE_CFLAGS
 690 dnl prefer internal headers to already installed ones
 691 dnl also add builddir include for enumtypes and marshal
 692 GST_PLUGINS_BASE_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs"
 693 AC_SUBST(GST_PLUGINS_BASE_CFLAGS)
 694
 695 dnl FIXME: do we want to rename to GST_ALL_* ?
 696 dnl add GST_OPTION_CFLAGS, but overridable
 697 GST_CFLAGS="$GST_CFLAGS \$(GST_OPTION_CFLAGS)"
 698 AC_SUBST(GST_CFLAGS)
 699 dnl add GCOV libs because libtool strips -fprofile-arcs -ftest-coverage
 700 GST_LIBS="$GST_LIBS \$(GCOV_LIBS)"
 701 AC_SUBST(GST_LIBS)
 702
 703 dnl LDFLAGS really should only contain flags, not libs - they get added before
 704 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 705 GST_ALL_LDFLAGS="-no-undefined"
 706 AC_SUBST(GST_ALL_LDFLAGS)
 707
 708 dnl GST_LIB_LDFLAGS
 709 dnl linker flags shared by all libraries
 710 dnl LDFLAGS modifier defining exported symbols from built libraries
 711 dnl (export _gst_foo but not __gst_foo)
 712 GST_LIB_LDFLAGS="-export-symbols-regex ^_?\(gst_\|Gst\|GST_\).*"
 713 AC_SUBST(GST_LIB_LDFLAGS)
 714
 715 dnl this really should only contain flags, not libs - they get added before
 716 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 717 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
 718 AC_SUBST(GST_PLUGIN_LDFLAGS)
 719
 720 SHAVE_INIT([common],[enable])
 721
 722 dnl *** output files ***
 723
 724 AC_CONFIG_FILES(
 725 Makefile
 726 common/shave
 727 common/shave-libtool
 728 gst-plugins-base.spec
 729 gst/Makefile
 730 gst/adder/Makefile
 731 gst/app/Makefile
 732 gst/audioconvert/Makefile
 733 gst/audiorate/Makefile
 734 gst/audiotestsrc/Makefile
 735 gst/ffmpegcolorspace/Makefile
 736 gst/gdp/Makefile
 737 gst/playback/Makefile
 738 gst/audioresample/Makefile
 739 gst/subparse/Makefile
 740 gst/tcp/Makefile
 741 gst/typefind/Makefile
 742 gst/videotestsrc/Makefile
 743 gst/videorate/Makefile
 744 gst/videoscale/Makefile
 745 gst/volume/Makefile
 746 sys/Makefile
 747 sys/ximage/Makefile
 748 sys/xvimage/Makefile
 749 sys/v4l/Makefile
 750 ext/Makefile
 751 ext/alsa/Makefile
 752 ext/cdparanoia/Makefile
 753 ext/gnomevfs/Makefile
 754 ext/gio/Makefile
 755 ext/libvisual/Makefile
 756 ext/ogg/Makefile
 757 ext/pango/Makefile
 758 ext/theora/Makefile
 759 ext/vorbis/Makefile
 760 gst-libs/Makefile
 761 gst-libs/gst/Makefile
 762 gst-libs/gst/audio/Makefile
 763 gst-libs/gst/app/Makefile
 764 gst-libs/gst/cdda/Makefile
 765 gst-libs/gst/fft/Makefile
 766 gst-libs/gst/floatcast/Makefile
 767 gst-libs/gst/interfaces/Makefile
 768 gst-libs/gst/netbuffer/Makefile
 769 gst-libs/gst/riff/Makefile
 770 gst-libs/gst/rtp/Makefile
 771 gst-libs/gst/rtsp/Makefile
 772 gst-libs/gst/sdp/Makefile
 773 gst-libs/gst/tag/Makefile
 774 gst-libs/gst/pbutils/Makefile
 775 gst-libs/gst/video/Makefile
 776 tools/Makefile
 777 pkgconfig/Makefile
 778 pkgconfig/gstreamer-audio.pc
 779 pkgconfig/gstreamer-audio-uninstalled.pc
 780 pkgconfig/gstreamer-app.pc
 781 pkgconfig/gstreamer-app-uninstalled.pc
 782 pkgconfig/gstreamer-cdda.pc
 783 pkgconfig/gstreamer-cdda-uninstalled.pc
 784 pkgconfig/gstreamer-fft.pc
 785 pkgconfig/gstreamer-fft-uninstalled.pc
 786 pkgconfig/gstreamer-floatcast.pc
 787 pkgconfig/gstreamer-floatcast-uninstalled.pc
 788 pkgconfig/gstreamer-interfaces.pc
 789 pkgconfig/gstreamer-interfaces-uninstalled.pc
 790 pkgconfig/gstreamer-netbuffer.pc
 791 pkgconfig/gstreamer-netbuffer-uninstalled.pc
 792 pkgconfig/gstreamer-pbutils.pc
 793 pkgconfig/gstreamer-pbutils-uninstalled.pc
 794 pkgconfig/gstreamer-riff.pc
 795 pkgconfig/gstreamer-riff-uninstalled.pc
 796 pkgconfig/gstreamer-rtp.pc
 797 pkgconfig/gstreamer-rtp-uninstalled.pc
 798 pkgconfig/gstreamer-rtsp.pc
 799 pkgconfig/gstreamer-rtsp-uninstalled.pc
 800 pkgconfig/gstreamer-sdp.pc
 801 pkgconfig/gstreamer-sdp-uninstalled.pc
 802 pkgconfig/gstreamer-tag.pc
 803 pkgconfig/gstreamer-tag-uninstalled.pc
 804 pkgconfig/gstreamer-video.pc
 805 pkgconfig/gstreamer-video-uninstalled.pc
 806 pkgconfig/gstreamer-plugins-base.pc
 807 pkgconfig/gstreamer-plugins-base-uninstalled.pc
 808 tests/Makefile
 809 tests/check/Makefile
 810 tests/examples/Makefile
 811 tests/examples/app/Makefile
 812 tests/examples/dynamic/Makefile
 813 tests/examples/seek/Makefile
 814 tests/examples/volume/Makefile
 815 tests/examples/snapshot/Makefile
 816 tests/examples/gio/Makefile
 817 tests/examples/v4l/Makefile
 818 tests/icles/Makefile
 819 docs/Makefile
 820 docs/design/Makefile
 821 docs/libs/Makefile
 822 docs/plugins/Makefile
 823 docs/version.entities
 824 po/Makefile.in
 825 common/Makefile
 826 common/m4/Makefile
 827 m4/Makefile
 828 )
 829
 830 dnl Create the config.h file for Visual Studio builds
 831 dnl Beware of spaces and /'s in some of the shell variable contents.
 832 sed \
 833     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"/' \
 834     -e 's/.* GST_INSTALL_PLUGINS_HELPER/#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
 835     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
 836     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
 837     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
 838     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
 839     -e 's/.* GST_MAJORMINOR$/#define GST_MAJORMINOR "'$GST_MAJORMINOR'"/' \
 840     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
 841     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
 842     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
 843     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
 844     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
 845     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
 846     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
 847     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
 848     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
 849     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
 850     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
 851     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
 852     -e 's/.* HAVE_WINSOCK2_H$/#define HAVE_WINSOCK2_H 1/' \
 853     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
 854     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
 855     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
 856     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
 857     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
 858     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
 859     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
 860     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
 861     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
 862     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.10"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.10"\n#endif/' \
 863     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
 864     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
 865     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directaudiosink\"/" \
 866     -e "s/.* DEFAULT_VIDEOSINK$/#define DEFAULT_VIDEOSINK \"directdrawsink\"/" \
 867     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
 868     config.h.in >win32/common/config.h-new
 869
 870
 871
 872 AC_OUTPUT
 873
 874 AG_GST_OUTPUT_PLUGINS