configure.ac

   1 AC_PREREQ([2.64])
   2
   3 m4_define([libinput_major_version], [0])
   4 m4_define([libinput_minor_version], [4])
   5 m4_define([libinput_micro_version], [0])
   6 m4_define([libinput_version],
   7           [libinput_major_version.libinput_minor_version.libinput_micro_version])
   8
   9 AC_INIT([libinput],
  10         [libinput_version],
  11         [https://bugs.freedesktop.org/enter_bug.cgi?product=Wayland&component=libinput&version=libinput_version],
  12         [libinput],
  13         [http://www.freedesktop.org/wiki/Software/libinput/])
  14
  15 AC_SUBST([LIBINPUT_VERSION_MAJOR], [libinput_major_version])
  16 AC_SUBST([LIBINPUT_VERSION_MINOR], [libinput_minor_version])
  17 AC_SUBST([LIBINPUT_VERSION_MICRO], [libinput_micro_version])
  18 AC_SUBST([LIBINPUT_VERSION], [libinput_version])
  19
  20 AC_CONFIG_HEADERS([config.h])
  21 AC_CONFIG_MACRO_DIR([m4])
  22
  23 AM_INIT_AUTOMAKE([1.11 foreign no-dist-gzip dist-xz])
  24
  25 # Before making a release, the LIBINPUT_LT_VERSION string should be
  26 # modified.
  27 # The string is of the form C:R:A.
  28 # - If interfaces have been changed or added, but binary compatibility has
  29 #   been preserved, change to C+1:0:A+1
  30 # - If binary compatibility has been broken (eg removed or changed interfaces)
  31 #   change to C+1:0:0
  32 # - If the interface is the same as the previous version, change to C:R+1:A
  33 LIBINPUT_LT_VERSION=3:0:0
  34 AC_SUBST(LIBINPUT_LT_VERSION)
  35
  36 AM_SILENT_RULES([yes])
  37
  38 # Check for programs
  39 AC_PROG_CC_C99
  40 AC_PROG_CXX # Only used by build C++ test
  41
  42 # Initialize libtool
  43 LT_PREREQ([2.2])
  44 LT_INIT
  45
  46 AC_CHECK_DECL(EPOLL_CLOEXEC, [],
  47               [AC_MSG_ERROR("EPOLL_CLOEXEC is needed to compile libinput")],
  48               [[#include <sys/epoll.h>]])
  49 AC_CHECK_DECL(TFD_CLOEXEC,[],
  50               [AC_MSG_ERROR("TFD_CLOEXEC is needed to compile libinput")],
  51               [[#include <sys/timerfd.h>]])
  52 AC_CHECK_DECL(CLOCK_MONOTONIC,[],
  53               [AC_MSG_ERROR("CLOCK_MONOTONIC is needed to compile libinput")],
  54               [[#include <time.h>]])
  55
  56 PKG_PROG_PKG_CONFIG()
  57 PKG_CHECK_MODULES(MTDEV, [mtdev >= 1.1.0])
  58 PKG_CHECK_MODULES(LIBUDEV, [libudev])
  59 PKG_CHECK_MODULES(LIBEVDEV, [libevdev >= 0.4])
  60 AC_CHECK_LIB([m], [atan2])
  61
  62 if test "x$GCC" = "xyes"; then
  63         GCC_CXXFLAGS="-Wall -Wextra -Wno-unused-parameter -g -fvisibility=hidden"
  64         GCC_CFLAGS="$GCC_CXXFLAGS -Wmissing-prototypes -Wstrict-prototypes"
  65 fi
  66 AC_SUBST(GCC_CFLAGS)
  67 AC_SUBST(GCC_CXXFLAGS)
  68
  69 AC_PATH_PROG(DOXYGEN, [doxygen])
  70 if test "x$DOXYGEN" = "x"; then
  71         AC_MSG_WARN([doxygen not found - required for documentation])
  72         have_doxygen="no"
  73 else
  74         have_doxygen="yes"
  75 fi
  76 AM_CONDITIONAL([HAVE_DOXYGEN], [test "x$have_doxygen" = "xyes"])
  77
  78 AC_ARG_ENABLE(event-gui,
  79               AS_HELP_STRING([--enable-event-gui], [Build the GUI event viewer (default=auto)]),
  80               [build_eventgui="$enableval"],
  81               [build_eventgui="auto"])
  82 PKG_CHECK_EXISTS([cairo glib-2.0 gtk+-3.0], [HAVE_GUILIBS="yes"], [HAVE_GUILIBS="no"])
  83
  84 if test "x$build_eventgui" = "xauto"; then
  85         build_eventgui="$HAVE_GUILIBS"
  86 fi
  87 if test "x$build_eventgui" = "xyes"; then
  88         PKG_CHECK_MODULES(CAIRO, [cairo])
  89         PKG_CHECK_MODULES(GTK, [glib-2.0 gtk+-3.0])
  90 fi
  91 AM_CONDITIONAL(BUILD_EVENTGUI, [test "x$build_eventgui" = "xyes"])
  92
  93 AC_ARG_ENABLE(tests,
  94               AS_HELP_STRING([--enable-tests], [Build the tests (default=auto)]),
  95               [build_tests="$enableval"],
  96               [build_tests="auto"])
  97
  98 PKG_CHECK_MODULES(CHECK, [check >= 0.9.9], [HAVE_CHECK="yes"], [HAVE_CHECK="no"])
  99
 100 if test "x$build_tests" = "xauto"; then
 101         build_tests="$HAVE_CHECK"
 102 fi
 103 if test "x$build_tests" = "xyes"; then
 104         if test "x$HAVE_CHECK" = "xno"; then
 105                 AC_MSG_ERROR([Cannot build tests, check is missing])
 106         fi
 107
 108         AC_PATH_PROG(VALGRIND, [valgrind])
 109 fi
 110
 111 AM_CONDITIONAL(HAVE_VALGRIND, [test "x$VALGRIND" != "x"])
 112 AM_CONDITIONAL(BUILD_TESTS, [test "x$build_tests" = "xyes"])
 113
 114 AC_CONFIG_FILES([Makefile
 115                  doc/Makefile
 116                  doc/libinput.doxygen
 117                  src/Makefile
 118                  src/libinput.pc
 119                  src/libinput-version.h
 120                  test/Makefile
 121                  tools/Makefile])
 122 AC_OUTPUT