configure.ac

   1 AC_PREREQ([2.69])
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/pre
   8 AC_INIT([GStreamer Good Plug-ins],[1.12.2],[http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer],[gst-plugins-good])
   9
  10 AG_GST_INIT
  11
  12 dnl initialize automake
  13 AM_INIT_AUTOMAKE([-Wno-portability 1.14 no-dist-gzip dist-xz tar-ustar subdir-objects])
  14
  15 dnl define PACKAGE_VERSION_* variables
  16 AS_VERSION
  17
  18 dnl check if this is a release version
  19 AS_NANO(GST_GIT="no", GST_GIT="yes")
  20
  21 dnl can autoconf find the source ?
  22 AC_CONFIG_SRCDIR([gst/law/alaw.c])
  23
  24 dnl define the output header for config
  25 AC_CONFIG_HEADERS([config.h])
  26
  27 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  28 AM_MAINTAINER_MODE([enable])
  29
  30 dnl sets host_* variables
  31 AC_CANONICAL_HOST
  32
  33 dnl use pretty build output with automake >= 1.11
  34 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  35   [AM_DEFAULT_VERBOSITY=1
  36    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  37
  38 dnl our libraries and install dirs use GST_API_VERSION in the filename
  39 dnl to allow side-by-side installation of different API versions
  40 GST_API_VERSION=1.0
  41 AC_SUBST(GST_API_VERSION)
  42 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION",
  43   [GStreamer API Version])
  44
  45 AG_GST_LIBTOOL_PREPARE
  46 AS_LIBTOOL(GST, 1202, 0, 1202)
  47
  48 dnl *** required versions of GStreamer stuff ***
  49 GST_REQ=1.12.0
  50 GSTPB_REQ=1.12.0
  51
  52 dnl *** autotools stuff ****
  53
  54 dnl allow for different autotools
  55 AS_AUTOTOOLS_ALTERNATE
  56
  57 dnl Add parameters for aclocal
  58 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  59
  60 dnl set up gettext
  61 dnl the version check needs to stay here because autopoint greps for it
  62 AM_GNU_GETTEXT_VERSION([0.17])
  63 AM_GNU_GETTEXT([external])
  64 AG_GST_GETTEXT([gst-plugins-good-$GST_API_VERSION])
  65
  66 dnl *** check for arguments to configure ***
  67
  68 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  69 AG_GST_ARG_ENABLE_EXTRA_CHECKS
  70
  71 AG_GST_ARG_DEBUG
  72 AG_GST_ARG_PROFILING
  73 AG_GST_ARG_VALGRIND
  74 AG_GST_ARG_GCOV
  75
  76 AG_GST_ARG_EXAMPLES
  77
  78 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  79 AG_GST_ARG_WITH_PACKAGE_NAME
  80 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  81
  82 AG_GST_ARG_WITH_PLUGINS
  83
  84 AG_GST_ARG_ENABLE_EXTERNAL
  85
  86 AG_GST_ARG_ENABLE_EXPERIMENTAL
  87
  88 AG_GST_PKG_CONFIG_PATH
  89
  90 dnl *** checks for platform ***
  91
  92 dnl * hardware/architecture *
  93
  94 dnl common/m4/gst-arch.m4
  95 dnl check CPU type
  96 AG_GST_ARCH
  97
  98 dnl Determine endianness
  99 AC_C_BIGENDIAN
 100
 101 dnl *** checks for programs ***
 102
 103 dnl find a compiler
 104 AC_PROG_CC
 105 AC_PROG_CC_STDC
 106
 107 dnl determine c++ compiler
 108 AC_PROG_CXX
 109 dnl determine if c++ is available on this system
 110 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 111
 112 dnl determine c++ preprocessor
 113 dnl FIXME: do we need this ?
 114 AC_PROG_CXXCPP
 115
 116 AC_PROG_OBJC
 117
 118 dnl check if the compiler supports '-c' and '-o' options
 119 AM_PROG_CC_C_O
 120
 121 dnl find an assembler
 122 AM_PROG_AS
 123
 124 dnl check if the compiler supports do while(0) macros
 125 AG_GST_CHECK_DOWHILE_MACROS
 126
 127 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 128 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 129
 130 dnl check for documentation tools
 131 GTK_DOC_CHECK([1.12])
 132 AG_GST_PLUGIN_DOCS([1.12])
 133
 134 dnl *** checks for libraries ***
 135
 136 dnl check for libm, for sin()
 137 LT_LIB_M
 138 AC_SUBST(LIBM)
 139
 140 AC_CHECK_FUNCS(clock_gettime, [], [
 141   AC_CHECK_LIB(rt, clock_gettime, [
 142     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
 143     LIBRT="-lrt"
 144     AC_SUBST([LIBRT])
 145   ])
 146 ])
 147
 148 dnl check for pthreads
 149 AX_PTHREAD
 150
 151 dnl *** checks for header files ***
 152
 153 dnl check if we have ANSI C header files
 154 AC_HEADER_STDC
 155
 156 dnl used by ext/wavpack
 157 AX_CREATE_STDINT_H
 158
 159 dnl used in gst/udp
 160 AC_CHECK_HEADERS([sys/time.h])
 161
 162 dnl used in gst/udp
 163 AC_CHECK_HEADERS([sys/socket.h])
 164
 165 dnl *** checks for types/defines ***
 166
 167 dnl Check for FIONREAD ioctl declaration.  This check is needed
 168 dnl for the UDP plugin to build on Solaris
 169 GST_CHECK_FIONREAD
 170
 171 dnl *** checks for structures ***
 172
 173 dnl *** checks for compiler characteristics ***
 174
 175 dnl check if we have GCC inline-asm
 176 AS_GCC_INLINE_ASSEMBLY([HAVE_GCC_ASM=yes], [HAVE_GCC_ASM=no])
 177 if test x$HAVE_GCC_ASM = xyes ; then
 178   AC_DEFINE(HAVE_GCC_ASM, 1,
 179     [Define if compiler supports gcc inline assembly])
 180 fi
 181 AM_CONDITIONAL(HAVE_GCC_ASM, test "x$HAVE_GCC_ASM" = "xyes")
 182
 183 dnl *** checks for library functions ***
 184
 185 LIBS_SAVE=$LIBS
 186 LIBS="$LIBS $LIBM"
 187 AC_CHECK_FUNCS(rint sinh cosh asinh fpclass)
 188 LIBS=$LIBS_SAVE
 189
 190 dnl Check whether isinf() is defined by math.h
 191 AC_CACHE_CHECK([for isinf], ac_cv_have_isinf,
 192     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; int i=isinf(f)]])],[ac_cv_have_isinf="yes"],[ac_cv_have_isinf="no"]))
 193 if test "$ac_cv_have_isinf" = "yes"
 194 then
 195     AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have the `isinf' function.])
 196 fi
 197
 198 dnl Check for mmap (needed by electricfence plugin)
 199 AC_FUNC_MMAP
 200 AM_CONDITIONAL(GST_HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 201
 202 dnl Check for mmap (needed by electricfence plugin)
 203
 204 AC_CHECK_TYPE([struct ip_mreqn], [
 205               AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
 206               [#include <netinet/in.h>])
 207
 208 dnl *** checks for dependency libraries ***
 209
 210
 211 dnl GLib
 212 GLIB_REQ=2.40.0
 213 AG_GST_GLIB_CHECK([$GLIB_REQ])
 214
 215 dnl Orc
 216 ORC_CHECK([0.4.17])
 217
 218 dnl checks for gstreamer
 219 dnl uninstalled is selected preferentially -- see pkg-config(1)
 220 AG_GST_CHECK_GST($GST_API_VERSION, [$GST_REQ], yes)
 221 AG_GST_CHECK_GST_BASE($GST_API_VERSION, [$GST_REQ], yes)
 222 AG_GST_CHECK_GST_CONTROLLER($GST_API_VERSION, [$GST_REQ], yes)
 223 AG_GST_CHECK_GST_NET($GST_API_VERSION, [$GST_REQ], yes)
 224 AG_GST_CHECK_GST_CHECK($GST_API_VERSION, [$GST_REQ], no)
 225 AG_GST_CHECK_GST_PLUGINS_BASE($GST_API_VERSION, [$GSTPB_REQ], yes)
 226
 227 GST_TOOLS_DIR=`$PKG_CONFIG --variable=toolsdir gstreamer-$GST_API_VERSION`
 228 if test -z $GST_TOOLS_DIR; then
 229   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 230 fi
 231 AC_SUBST(GST_TOOLS_DIR)
 232
 233 AC_MSG_NOTICE(Using GStreamer Core Plugins in $GST_PLUGINS_DIR)
 234 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 235
 236 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 237
 238 dnl Check for documentation xrefs
 239 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 240 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_API_VERSION`"
 241 GSTPB_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-plugins-base-$GST_API_VERSION`"
 242 AC_SUBST(GLIB_PREFIX)
 243 AC_SUBST(GST_PREFIX)
 244 AC_SUBST(GSTPB_PREFIX)
 245
 246 dnl GTK is optional and used in examples
 247 HAVE_GTK=no
 248 GTK_REQ=3.0.0
 249 if test "x$BUILD_EXAMPLES" = "xyes"; then
 250   PKG_CHECK_MODULES(GTK, gtk+-3.0 >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 251   dnl some examples need gtk+-x11
 252   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-3.0 >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 253   AC_SUBST(GTK_LIBS)
 254   AC_SUBST(GTK_CFLAGS)
 255 fi
 256 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 257 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 258
 259 AC_ARG_ENABLE(pcmdump, AC_HELP_STRING([--enable-pcmdump], [pcm dump]),
 260   [
 261     case "${enableval}" in
 262       yes) PCM_DUMP_ENABLE=yes ;;
 263       no)  PCM_DUMP_ENABLE=no ;;
 264       *)   AC_MSG_ERROR(bad value ${enableval} for --enable-pcmdump) ;;
 265     esac
 266   ],
 267   [PCM_DUMP_ENABLE=no])
 268 AM_CONDITIONAL([PCM_DUMP_ENABLE], [test "x$PCM_DUMP_ENABLE" = "xyes"])
 269
 270 if test "x$PCM_DUMP_ENABLE" = "xyes"; then
 271 PKG_CHECK_MODULES(VCONF, vconf)
 272 AC_SUBST(VCONF_CFLAGS)
 273 AC_SUBST(VCONF_LIBS)
 274 fi
 275
 276 dnl Check for -Bsymbolic-functions linker flag used to avoid
 277 dnl intra-library PLT jumps, if available.
 278 AC_ARG_ENABLE(Bsymbolic,
 279               [AS_HELP_STRING([--disable-Bsymbolic],[avoid linking with -Bsymbolic])],,
 280               [SAVED_LDFLAGS="${LDFLAGS}" SAVED_LIBS="${LIBS}"
 281                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 282                LDFLAGS=-Wl,-Bsymbolic-functions
 283                LIBS=
 284                AC_TRY_LINK([], [return 0],
 285                            AC_MSG_RESULT(yes)
 286                            enable_Bsymbolic=yes,
 287                            AC_MSG_RESULT(no)
 288                            enable_Bsymbolic=no)
 289                LDFLAGS="${SAVED_LDFLAGS}" LIBS="${SAVED_LIBS}"])
 290
 291 dnl *** set variables based on configure arguments ***
 292
 293 dnl set license and copyright notice
 294 GST_LICENSE="LGPL"
 295 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 296 AC_SUBST(GST_LICENSE)
 297
 298 dnl set location of plugin directory
 299 AG_GST_SET_PLUGINDIR
 300
 301 dnl set release date/time
 302 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 303   ["${srcdir}/gst-plugins-good.doap"],
 304   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 305
 306 dnl build static plugins or not
 307 AC_MSG_CHECKING([whether to build static plugins or not])
 308 AC_ARG_ENABLE(
 309   static-plugins,
 310   AC_HELP_STRING(
 311     [--enable-static-plugins],
 312     [build static plugins @<:@default=no@:>@]),
 313   [AS_CASE(
 314     [$enableval], [no], [], [yes], [],
 315     [AC_MSG_ERROR([bad value "$enableval" for --enable-static-plugins])])],
 316   [enable_static_plugins=no])
 317 AC_MSG_RESULT([$enable_static_plugins])
 318 if test "x$enable_static_plugins" = xyes; then
 319   AC_DEFINE(GST_PLUGIN_BUILD_STATIC, 1,
 320     [Define if static plugins should be built])
 321   GST_PLUGIN_LIBTOOLFLAGS=""
 322 else
 323   GST_PLUGIN_LIBTOOLFLAGS="--tag=disable-static"
 324 fi
 325 AC_SUBST(GST_PLUGIN_LIBTOOLFLAGS)
 326 AM_CONDITIONAL(GST_PLUGIN_BUILD_STATIC, test "x$enable_static_plugins" = "xyes")
 327
 328 # set by AG_GST_PARSE_SUBSYSTEM_DISABLES above
 329 dnl make sure it doesn't complain about unused variables if debugging is disabled
 330 NO_WARNINGS=""
 331 AG_GST_CHECK_GST_DEBUG_DISABLED([NO_WARNINGS="-Wno-unused"], [NO_WARNINGS=""])
 332
 333 dnl define an ERROR_CFLAGS Makefile variable
 334 dnl -Wundef: too many broken headers
 335 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [
 336       -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 337       -Wwrite-strings -Wold-style-definition -Waggregate-return
 338       -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar
 339       -Wnested-externs $NO_WARNINGS])
 340
 341 dnl define an ERROR_CXXFLAGS Makefile variable
 342 AG_GST_SET_ERROR_CXXFLAGS($FATAL_WARNINGS, [
 343         -Wmissing-declarations -Wredundant-decls
 344         -Wwrite-strings
 345         -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar
 346         $NO_WARNINGS])
 347
 348 dnl define an ERROR_OBJCFLAGS Makefile variable
 349 AG_GST_SET_ERROR_OBJCFLAGS($FATAL_WARNINGS, [
 350       -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 351       -Wwrite-strings -Wold-style-definition
 352       -Winit-self -Wmissing-include-dirs -Wno-multichar
 353       -Wnested-externs $NO_WARNINGS])
 354
 355 dnl define correct level for debugging messages
 356 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 357
 358 dnl used in examples
 359 AG_GST_DEFAULT_ELEMENTS
 360
 361 dnl *** plug-ins to include ***
 362
 363 dnl these are all the gst plug-ins, compilable without additional libs
 364 dnl videofilter is at the top because others depend on it
 365 AG_GST_CHECK_PLUGIN(alpha)
 366 AG_GST_CHECK_PLUGIN(apetag)
 367 AG_GST_CHECK_PLUGIN(audiofx)
 368 AG_GST_CHECK_PLUGIN(audioparsers)
 369 AG_GST_CHECK_PLUGIN(auparse)
 370 AG_GST_CHECK_PLUGIN(autodetect)
 371 AG_GST_CHECK_PLUGIN(avi)
 372 AG_GST_CHECK_PLUGIN(cutter)
 373 AG_GST_CHECK_PLUGIN(debugutils)
 374 AG_GST_CHECK_PLUGIN(deinterlace)
 375 AG_GST_CHECK_PLUGIN(dtmf)
 376 AG_GST_CHECK_PLUGIN(effectv)
 377 AG_GST_CHECK_PLUGIN(equalizer)
 378 AG_GST_CHECK_PLUGIN(flv)
 379 AG_GST_CHECK_PLUGIN(flx)
 380 AG_GST_CHECK_PLUGIN(goom)
 381 AG_GST_CHECK_PLUGIN(goom2k1)
 382 AG_GST_CHECK_PLUGIN(icydemux)
 383 AG_GST_CHECK_PLUGIN(id3demux)
 384 AG_GST_CHECK_PLUGIN(imagefreeze)
 385 AG_GST_CHECK_PLUGIN(interleave)
 386 AG_GST_CHECK_PLUGIN(isomp4)
 387 AG_GST_CHECK_PLUGIN(law)
 388 AG_GST_CHECK_PLUGIN(level)
 389 AG_GST_CHECK_PLUGIN(matroska)
 390 AG_GST_CHECK_PLUGIN(monoscope)
 391 AG_GST_CHECK_PLUGIN(multifile)
 392 AG_GST_CHECK_PLUGIN(multipart)
 393 AG_GST_CHECK_PLUGIN(replaygain)
 394 AG_GST_CHECK_PLUGIN(rtp)
 395 AG_GST_CHECK_PLUGIN(rtpmanager)
 396 AG_GST_CHECK_PLUGIN(rtsp)
 397 AG_GST_CHECK_PLUGIN(shapewipe)
 398 AG_GST_CHECK_PLUGIN(smpte)
 399 AG_GST_CHECK_PLUGIN(spectrum)
 400 AG_GST_CHECK_PLUGIN(udp)
 401 AG_GST_CHECK_PLUGIN(videobox)
 402 AG_GST_CHECK_PLUGIN(videocrop)
 403 AG_GST_CHECK_PLUGIN(videofilter)
 404 AG_GST_CHECK_PLUGIN(videomixer)
 405 AG_GST_CHECK_PLUGIN(wavenc)
 406 AG_GST_CHECK_PLUGIN(wavparse)
 407 AG_GST_CHECK_PLUGIN(y4m)
 408
 409 dnl disable experimental plug-ins
 410 if test "x$BUILD_EXPERIMENTAL" != "xyes"; then
 411   AG_GST_DISABLE_PLUGIN(monoscope)
 412 fi
 413
 414 dnl *** sys plug-ins ***
 415
 416 echo
 417 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 418 echo
 419
 420 dnl DirectSound
 421 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECTSOUND, true)
 422 AG_GST_CHECK_FEATURE(DIRECTSOUND, [DirectSound plug-in], directsoundsink, [
 423   HAVE_DIRECTSOUND="no"
 424   save_CFLAGS="$CFLAGS"
 425   save_LDFLAGS="$LDFLAGS"
 426   save_LIBS="$LIBS"
 427   CFLAGS="$CFLAGS $DIRECTSOUND_CFLAGS"
 428   LDFLAGS="$LDFLAGS $DIRECTSOUND_LDFLAGS"
 429   LIBS="$LIBS -ldsound -ldxerr9 -luser32 -lole32"
 430   AC_MSG_CHECKING(for DirectSound LDFLAGS)
 431   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 432 #include <windows.h>
 433 #include <dxerr9.h>
 434 #include <dsound.h>
 435 ]], [[
 436   DXGetErrorString9 (0);
 437   DirectSoundCreate(NULL, NULL, NULL);
 438   CLSIDFromString(NULL, NULL);
 439 ]])
 440 ],
 441     [HAVE_DIRECTSOUND="yes"],
 442     [HAVE_DIRECTSOUND="no"])
 443   AC_MSG_RESULT($HAVE_DIRECTSOUND)
 444   CFLAGS=$save_CFLAGS
 445   LDFLAGS=$save_LDFLAGS
 446   LIBS=$save_LIBS
 447
 448   if test "x$HAVE_DIRECTSOUND" = "xyes";  then
 449     dnl this is much more than we want
 450     DIRECTSOUND_LIBS="-ldsound -ldxerr9 -luser32 -lole32"
 451     AC_SUBST(DIRECTSOUND_CFLAGS)
 452     AC_SUBST(DIRECTSOUND_LDFLAGS)
 453     AC_SUBST(DIRECTSOUND_LIBS)
 454   fi
 455   AC_SUBST(HAVE_DIRECTSOUND)
 456 ])
 457
 458 dnl *** Win32 WaveOut ***
 459 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVEFORM, true)
 460 AG_GST_CHECK_FEATURE(WAVEFORM, [Win32 WaveForm], waveformsink, [
 461   AC_CHECK_HEADER(mmsystem.h, HAVE_WAVEFORM="yes", HAVE_WAVEFORM="no", [#include <windows.h>])
 462 ])
 463
 464 dnl *** OSS audio *** (Linux, *BSD)
 465 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS, true)
 466 AG_GST_CHECK_FEATURE(OSS, [OSS audio], ossaudio, [
 467  HAVE_OSS="yes"
 468 dnl Linux and newer BSD versions :
 469  AC_CHECK_HEADER(sys/soundcard.h, [
 470    AC_DEFINE(HAVE_OSS_INCLUDE_IN_SYS,, [Define if OSS includes are in /sys/])
 471    ] , [
 472 dnl Some old BSD versions and also newer OpenBSD versions :
 473    AC_CHECK_HEADER(soundcard.h, [
 474      AC_DEFINE(HAVE_OSS_INCLUDE_IN_ROOT,, [Define if OSS includes are in /])
 475      ], [
 476   dnl Some old BSD versions :
 477      AC_CHECK_HEADER(machine/soundcard.h, [
 478        AC_DEFINE(HAVE_OSS_INCLUDE_IN_MACHINE,,
 479          [Define if OSS includes are in /machine/])
 480        ], [
 481        HAVE_OSS="no"
 482      ])
 483    ])
 484  ])
 485 ])
 486
 487 dnl *** oss4 ***
 488 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS4, true)
 489 AG_GST_CHECK_FEATURE(OSS4, [Open Sound System 4], oss4, [
 490   AC_MSG_CHECKING([Checking if we can build the OSS4 elements])
 491   AC_CHECK_HEADERS([fcntl.h sys/ioctl.h sys/stat.h sys/types.h],
 492       [test -z "$OSS4_MISSING_HEADER" && HAVE_OSS4="yes"],
 493       [OSS4_MISSING_HEADER="yes";HAVE_OSS4="no"])
 494 ])
 495
 496 dnl *** Sun Audio ***
 497 translit(dnm, m, l) AM_CONDITIONAL(USE_SUNAUDIO, true)
 498 AG_GST_CHECK_FEATURE(SUNAUDIO, [Sun Audio], sunaudio, [
 499   AC_CHECK_HEADER(sys/audioio.h, HAVE_SUNAUDIO="yes", HAVE_SUNAUDIO="no")
 500 ])
 501
 502 dnl *** OSX Audio ***
 503 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_AUDIO, true)
 504 HAVE_IOS="no"
 505 AG_GST_CHECK_FEATURE(OSX_AUDIO, [OSX audio], osxaudio, [
 506   AC_CHECK_HEADER(CoreAudio/CoreAudio.h,
 507     [HAVE_OSX_AUDIO="yes"],
 508     [AC_CHECK_HEADER(CoreAudio/CoreAudioTypes.h,
 509     [
 510       HAVE_OSX_AUDIO="yes"
 511       HAVE_IOS="yes"
 512     ], [
 513       HAVE_OSX_AUDIO="no"
 514       HAVE_IOS="no"
 515     ])]
 516   )
 517 ])
 518 if test "x$HAVE_IOS" = "xyes"; then
 519   AC_DEFINE(HAVE_IOS, 1, [building for iOS platofrm])
 520 fi
 521 AM_CONDITIONAL(HAVE_IOS, test "x$HAVE_IOS" = "xyes")
 522
 523 dnl *** OS X video ***
 524 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_VIDEO, true)
 525 HAVE_OSX_VIDEO="no"
 526 AG_GST_CHECK_FEATURE(OSX_VIDEO, [OSX video], osxvideosink, [
 527   AC_CHECK_HEADER(OpenGL/gl.h, HAVE_OSX_VIDEO="yes", HAVE_OSX_VIDEO="no")
 528
 529   dnl in case header OpenGL/gl.h is found on other platforms (or older, unsupported OS X)
 530   dnl also require Snow Leopard or newer
 531
 532   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 533         #include <AvailabilityMacros.h>
 534         #if MAC_OS_X_VERSION_MIN_REQUIRED < 1060
 535         #error Too old OSX version
 536         #endif
 537       ]], [[return 0;]])],[HAVE_OSX_VIDEO="yes"],[HAVE_OSX_VIDEO="no"])
 538 ])
 539
 540 dnl *** Video 4 Linux 2 ***
 541 dnl renamed to GST_V4L2 because of some conflict with kernel headers
 542 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L2, true)
 543 HAVE_GST_V4L2=no
 544 AG_GST_CHECK_FEATURE(GST_V4L2, [Video 4 Linux 2], video4linux2, [
 545   AC_MSG_CHECKING([Checking for video4linux2 header ...])
 546   AC_CHECK_HEADER(linux/videodev2.h, [ HAVE_GST_V4L2=yes ],
 547   [
 548     AC_CHECK_HEADER(sys/videodev2.h, [ HAVE_GST_V4L2=yes ],
 549     [
 550       AC_CHECK_HEADER(sys/videoio.h, [ HAVE_GST_V4L2=yes ])
 551     ])
 552   ])
 553   if test "x$HAVE_VIDEODEV" = "xno"; then
 554      AC_MSG_WARN([video4linux2 was not found])
 555   fi
 556 ])
 557
 558 # Optional gudev for device probing
 559 AC_ARG_WITH([gudev],
 560   AS_HELP_STRING([--with-gudev],[device detection with gudev]),
 561   [],
 562   [with_gudev=check])
 563 if test x$HAVE_GST_V4L2 = xyes; then
 564   if test x$with_gudev != xno; then
 565     PKG_CHECK_MODULES(GUDEV, [ gudev-1.0 >= 147 ],
 566       [ AC_DEFINE(HAVE_GUDEV, 1,
 567           [Whether gudev is available for device detection])
 568       ],
 569       [true])
 570   fi
 571 fi
 572
 573 AC_SUBST(GUDEV_CFLAGS)
 574 AC_SUBST(GUDEV_LIBS)
 575
 576 # Make libv4l2 non-automagic
 577 AC_ARG_WITH([libv4l2],
 578   AS_HELP_STRING([--with-libv4l2],[support video buffer conversion using libv4l2]),
 579   [],
 580   [with_libv4l2=check])
 581 if test x$HAVE_GST_V4L2 = xyes; then
 582   if test x$with_libv4l2 != xno; then
 583       PKG_CHECK_MODULES(LIBV4L2, libv4l2,
 584           [ have_libv4l2=yes
 585             AC_DEFINE(HAVE_LIBV4L2, 1,
 586                 [Whether libv4l2 is available for video buffer conversion])
 587           ], [
 588           have_libv4l2=no
 589           ])
 590   else
 591     have_libv4l2=no
 592   fi
 593 fi
 594
 595 dnl Allow enabling v4l2 device probing
 596 AS_CASE([$host],
 597     [*-*linux*],
 598       [AS_CASE([$host_cpu],
 599         [arm*], [
 600           enable_v4l2_probe="yes"],
 601         [aarch64*], [
 602           enable_v4l2_probe="yes"])])
 603 AC_ARG_ENABLE(
 604   v4l2-probe,
 605   AC_HELP_STRING(
 606     [--enable-v4l2-probe],
 607     [enable V4L2 plugin to probe devices @<:@default=no@:>@]))
 608 if test "x$enable_v4l2_probe" = "xyes"; then
 609   AC_DEFINE(GST_V4L2_ENABLE_PROBE, 1,
 610     [Define if Video4Linux probe shall be run at plugin load])
 611 fi
 612
 613 dnl Check for X11
 614 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 615 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 616                   [ximagesrc], [
 617   AG_GST_CHECK_X
 618
 619   if test "x$HAVE_X" = "xyes"
 620   then
 621     dnl check for Xfixes
 622     PKG_CHECK_MODULES(XFIXES, xfixes, HAVE_XFIXES="yes", HAVE_XFIXES="no")
 623     if test "x$HAVE_XFIXES" = "xyes"
 624     then
 625         XFIXES_CFLAGS="-DHAVE_XFIXES $XFIXES_CFLAGS"
 626     fi
 627     AC_SUBST(XFIXES_LIBS)
 628     AC_SUBST(XFIXES_CFLAGS)
 629
 630     dnl check for Xdamage
 631     PKG_CHECK_MODULES(XDAMAGE, xdamage, HAVE_XDAMAGE="yes", HAVE_XDAMAGE="no")
 632     if test "x$HAVE_XDAMAGE" = "xyes"
 633     then
 634         XDAMAGE_CFLAGS="-DHAVE_XDAMAGE $XDAMAGE_CFLAGS"
 635     fi
 636     AC_SUBST(XDAMAGE_LIBS)
 637     AC_SUBST(XDAMAGE_CFLAGS)
 638   fi
 639 ])
 640
 641 dnl FIXME: this should be rolled into the test above, it's just an additional
 642 dnl feature of the ximagesrc plug-in
 643 dnl This is the same as in gst-plugins-base
 644 dnl check for X Shm
 645 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 646 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 647   if test x$HAVE_X = xyes; then
 648     AC_CHECK_LIB(Xext, XShmAttach,
 649                  HAVE_XSHM="yes", HAVE_XSHM="no",
 650                  $X_LIBS)
 651     if test "x$HAVE_XSHM" = "xyes"; then
 652       XSHM_LIBS="-lXext"
 653     else
 654       dnl On AIX, it is in XextSam instead, but we still need -lXext
 655       AC_CHECK_LIB(XextSam, XShmAttach,
 656                    HAVE_XSHM="yes", HAVE_XSHM="no",
 657                    $X_LIBS)
 658       if test "x$HAVE_XSHM" = "xyes"; then
 659         XSHM_LIBS="-lXext -lXextSam"
 660       fi
 661     fi
 662   fi
 663 ], ,[
 664   AC_SUBST(HAVE_XSHM)
 665   AC_SUBST(XSHM_LIBS)
 666 ])
 667
 668 dnl *** ext plug-ins ***
 669 dnl keep this list sorted alphabetically !
 670
 671 if test "x$BUILD_EXTERNAL" = "xyes"; then
 672
 673 echo
 674 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 675 echo
 676
 677 dnl *** aalib ***
 678 translit(dnm, m, l) AM_CONDITIONAL(USE_AALIB, true)
 679 AG_GST_CHECK_FEATURE(AALIB, [aalib ASCII Art library], aasink, [
 680   AM_PATH_AALIB(, HAVE_AALIB=yes, HAVE_AALIB=no)
 681 ])
 682
 683 dnl *** cairo ***
 684 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO, true)
 685 AG_GST_CHECK_FEATURE(CAIRO, [Cairo graphics rendering and gobject bindings], cairo, [
 686   AG_GST_PKG_CHECK_MODULES(CAIRO, cairo >= 1.10.0 cairo-gobject >= 1.10.0)
 687 ])
 688
 689 dnl *** FLAC ***
 690 translit(dnm, m, l) AM_CONDITIONAL(USE_FLAC, true)
 691 AG_GST_CHECK_FEATURE(FLAC, [FLAC lossless audio], flac, [
 692   AG_GST_PKG_CHECK_MODULES(FLAC, flac >= 1.1.4)
 693 ])
 694
 695 dnl *** GDK pixbuf ***
 696 translit(dnm, m, l) AM_CONDITIONAL(USE_GDK_PIXBUF, true)
 697 AG_GST_CHECK_FEATURE(GDK_PIXBUF, [GDK pixbuf], gdkpixbuf, [
 698   AG_GST_PKG_CHECK_MODULES(GDK_PIXBUF, gdk-pixbuf-2.0 >= 2.8.0)
 699 ])
 700
 701 dnl *** Jack ***
 702 translit(dnm, m, l) AM_CONDITIONAL(USE_JACK, true)
 703 AG_GST_CHECK_FEATURE(JACK, Jack, jack, [
 704   PKG_CHECK_MODULES(JACK, jack >= 0.99.10, HAVE_JACK="yes", HAVE_JACK="no")
 705   AC_SUBST(JACK_CFLAGS)
 706   AC_SUBST(JACK_LIBS)
 707
 708   AG_GST_PKG_CHECK_MODULES(JACK_0_120_1, jack >= 0.120.1 jack < 1.0)
 709   if test x$HAVE_JACK_0_120_1 = xyes; then
 710     AC_DEFINE(HAVE_JACK_0_120_1, 1, [defined if jack >= 0.120.1 is available])
 711   fi
 712   AG_GST_PKG_CHECK_MODULES(JACK_1_9_7, jack >= 1.9.7)
 713   if test x$HAVE_JACK_1_9_7 = xyes; then
 714     AC_DEFINE(HAVE_JACK_1_9_7, 1, [defined if jack >= 1.9.7 is available])
 715   fi
 716
 717 ])
 718
 719 dnl *** jpeg ***
 720 dnl FIXME: we could use header checks here as well IMO
 721 translit(dnm, m, l) AM_CONDITIONAL(USE_JPEG, true)
 722 AG_GST_CHECK_FEATURE(JPEG, [jpeg library], jpeg, [
 723   AC_ARG_WITH(jpeg-mmx,
 724     [  --with-jpeg-mmx, path to MMX'ified JPEG library])
 725   OLD_LIBS="$LIBS"
 726   if test x$with_jpeg_mmx != x; then
 727     LIBS="$LIBS -L$with_jpeg_mmx"
 728   fi
 729   AC_CHECK_LIB(jpeg-mmx, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 730   JPEG_LIBS="$LIBS -ljpeg-mmx"
 731   LIBS="$OLD_LIBS"
 732   if test x$HAVE_JPEG != xyes; then
 733     AC_CHECK_LIB(jpeg, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 734     JPEG_LIBS="-ljpeg"
 735   fi
 736   AC_SUBST(JPEG_LIBS)
 737 ])
 738
 739 dnl *** libcaca ***
 740 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBCACA, true)
 741 AG_GST_CHECK_FEATURE(LIBCACA, [libcaca coloured ASCII art], cacasink, [
 742   AG_GST_PKG_CHECK_MODULES(LIBCACA, caca)
 743 ])
 744
 745 dnl *** libdv ***
 746 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBDV, true)
 747 AG_GST_CHECK_FEATURE(LIBDV, [libdv DV demuxer/decoder], dv, [
 748   AG_GST_PKG_CHECK_MODULES(LIBDV, libdv >= 0.100)
 749 ])
 750
 751 dnl *** libpng ***
 752 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBPNG, true)
 753 AG_GST_CHECK_FEATURE(LIBPNG, [Portable Network Graphics library], png, [
 754   AG_GST_PKG_CHECK_MODULES(LIBPNG, libpng >= 1.2)
 755 ])
 756
 757 dnl *** pulseaudio ***
 758 translit(dnm, m, l) AM_CONDITIONAL(USE_PULSE, true)
 759 AG_GST_CHECK_FEATURE(PULSE, [pulseaudio plug-in], pulseaudio, [
 760
 761   dnl used in ext/pulse/pulseutil.c
 762   AC_CHECK_HEADERS([process.h])
 763
 764   AG_GST_PKG_CHECK_MODULES(PULSE, libpulse >= 2.0)
 765 ])
 766
 767 dnl *** dv1394 ***
 768 translit(dnm, m, l) AM_CONDITIONAL(USE_DV1394, true)
 769 AG_GST_CHECK_FEATURE(DV1394, [raw1394 and avc1394 library], 1394, [
 770   dnl first test for libraw1394 >= 2.0.0
 771   AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 2.0.0)
 772   AG_GST_PKG_CHECK_MODULES(LIBIEC61883, libiec61883 >= 1.0.0)
 773   dnl now see how far we got
 774   if test x$HAVE_RAW1394 = xyes && \
 775      test x$HAVE_LIBIEC61883 = xyes; then
 776        AG_GST_CHECK_LIBHEADER(AVC1394,
 777         avc1394, avc1394_send_command, $RAW1394_LIBS,
 778         libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 779        AG_GST_CHECK_LIBHEADER(ROM1394,
 780         rom1394, rom1394_free_directory, $RAW1394_LIBS,
 781         libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 782        if test x$HAVE_AVC1394 = xyes && \
 783           test x$HAVE_AVC1394 = xyes && \
 784           test x$HAVE_ROM1394 = xyes; then
 785           HAVE_DV1394=yes
 786           DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS $LIBIEC61883_LIBS"
 787           DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 788           AC_SUBST(DV1394_CFLAGS)
 789           AC_SUBST(DV1394_LIBS)
 790         fi
 791   else
 792        if test x$HAVE_RAW1394 = xno; then
 793           AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.1.0)
 794           AG_GST_CHECK_LIBHEADER(AVC1394,
 795            avc1394, avc1394_send_command, $RAW1394_LIBS,
 796            libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 797           AG_GST_CHECK_LIBHEADER(ROM1394,
 798            rom1394, rom1394_free_directory, $RAW1394_LIBS,
 799            libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 800           if test x$HAVE_RAW1394 = xyes && \
 801              test x$HAVE_AVC1394 = xyes && \
 802              test x$HAVE_ROM1394 = xyes; then
 803              HAVE_DV1394=yes
 804              DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS"
 805              DV1394_CFLAGS="$RAW1394_CFLAGS"
 806              if test x$HAVE_LIBIEC61883 = xyes; then
 807                DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 808                DV1394_LIBS="$DV1394_LIBS $LIBIEC61883_LIBS"
 809              fi
 810              AC_SUBST(DV1394_CFLAGS)
 811              AC_SUBST(DV1394_LIBS)
 812            fi
 813          fi
 814   fi
 815 ])
 816 AM_CONDITIONAL(USE_LIBIEC61883, [ test "x${HAVE_LIBIEC61883}" = xyes ] )
 817
 818 dnl *** shout2 ***
 819 translit(dnm, m, l) AM_CONDITIONAL(USE_SHOUT2, true)
 820 AG_GST_CHECK_FEATURE(SHOUT2, [Shoutcast/Icecast client library], shout2, [
 821   AG_GST_PKG_CHECK_MODULES(SHOUT2, shout >= 2.0)
 822 ])
 823
 824 dnl *** soup ***
 825 translit(dnm, m, l) AM_CONDITIONAL(USE_SOUP, true)
 826 AG_GST_CHECK_FEATURE(SOUP, [soup http client plugin (2.4)], souphttpsrc, [
 827   PKG_CHECK_MODULES(SOUP, libsoup-2.4 >= 2.46, [HAVE_SOUP="yes"], [HAVE_SOUP="no"])
 828   AC_SUBST(SOUP_CFLAGS)
 829   AC_SUBST(SOUP_LIBS)
 830 ])
 831
 832 dnl *** speex ***
 833 translit(dnm, m, l) AM_CONDITIONAL(USE_SPEEX, true)
 834 AG_GST_CHECK_FEATURE(SPEEX, [speex speech codec], speex, [
 835   AG_GST_PKG_CHECK_MODULES(SPEEX, speex >= 1.1.6)
 836 ])
 837
 838 dnl *** taglib ***
 839 translit(dnm, m, l) AM_CONDITIONAL(USE_TAGLIB, true)
 840 AG_GST_CHECK_FEATURE(TAGLIB, [taglib tagging library], taglib, [
 841   AG_GST_PKG_CHECK_MODULES(TAGLIB, taglib >= 1.5)
 842   if test "x$HAVE_CXX" != "xyes"; then
 843     USE_TAGLIB=false
 844     AC_MSG_NOTICE([Not building taglib plugin: no C++ compiler found])
 845   else
 846     dnl work around bug in taglib 1.5 headers, remove once there is a 1.6
 847     AS_CXX_COMPILER_FLAG([-Wno-attributes], [
 848         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS -Wno-attributes"
 849       ], [
 850         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS"
 851     ])
 852     AC_SUBST(TAGLIB_CXXFLAGS)
 853   fi
 854 ])
 855
 856 dnl *** vpx ***
 857 translit(dnm, m, l) AM_CONDITIONAL(USE_VPX, vpx)
 858 AG_GST_CHECK_FEATURE(VPX, [VPX decoder], vpx, [
 859   PKG_CHECK_MODULES(VPX, vpx >= 1.1.0, [HAVE_VPX="yes"], [HAVE_VPX="no"])
 860   HAVE_VP8=no
 861   HAVE_VP9=no
 862
 863   if test $HAVE_VPX = "yes"; then
 864     OLD_LIBS="$LIBS"
 865     OLD_CFLAGS="$CFLAGS"
 866     CFLAGS="$CFLAGS $VPX_CFLAGS"
 867     LIBS="$LIBS $VPX_LIBS"
 868     AC_CHECK_LIB(vpx, vpx_codec_vp8_cx_algo, [
 869       HAVE_VP8=yes
 870       AC_DEFINE(HAVE_VP8_ENCODER, 1, [Defined if the VP8 encoder is available])
 871     ])
 872     AC_CHECK_LIB(vpx, vpx_codec_vp8_dx_algo, [
 873       HAVE_VP8=yes
 874       AC_DEFINE(HAVE_VP8_DECODER, 1, [Defined if the VP8 decoder is available])
 875     ])
 876
 877     PKG_CHECK_MODULES(VPX_130, vpx >= 1.3.0, [
 878       AC_CHECK_LIB(vpx, vpx_codec_vp9_cx_algo, [
 879         HAVE_VP9=yes
 880         AC_DEFINE(HAVE_VP9_ENCODER, 1, [Defined if the VP9 encoder is available])
 881       ])
 882       AC_CHECK_LIB(vpx, vpx_codec_vp9_dx_algo, [
 883         HAVE_VP9=yes
 884         AC_DEFINE(HAVE_VP9_DECODER, 1, [Defined if the VP9 decoder is available])
 885       ])
 886     ], [true])
 887
 888     PKG_CHECK_MODULES(VPX_140, vpx >= 1.4.0, [
 889       AC_DEFINE(HAVE_VPX_1_4, 1, [Defined if the VPX library version is 1.4 or bigger])
 890     ], [true])
 891
 892     LIBS="$OLD_LIBS"
 893     CFLAGS="$OLD_CFLAGS"
 894   fi
 895   AC_SUBST(VPX_LIBS)
 896   AC_SUBST(VPX_CFLAGS)
 897 ])
 898
 899 dnl *** wavpack ***
 900 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVPACK, true)
 901 AG_GST_CHECK_FEATURE(WAVPACK, [wavpack plug-in], wavpack, [
 902   AG_GST_PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.60.0)
 903 ])
 904
 905 dnl *** qtdemux & matroska prefer to have zlib ***
 906 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 907 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for qtdemux/matroska],, [
 908   AG_GST_CHECK_LIBHEADER(ZLIB,
 909     z, uncompress,, zlib.h, [
 910     HAVE_ZLIB="yes"
 911     ZLIB_LIBS="-lz"
 912     AC_SUBST(ZLIB_LIBS)
 913   ])
 914 ])
 915
 916 dnl *** matroska prefers to have bz2 ***
 917 translit(dnm, m, l) AM_CONDITIONAL(USE_BZ2, true)
 918 AG_GST_CHECK_FEATURE(BZ2, [bz2 library for matroska ],, [
 919   save_LIBS=$LIBS
 920   LIBS="$LIBS -lbz2"
 921   AC_MSG_CHECKING([for BZ2_bzlibVersion in -lbz2])
 922   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <bzlib.h>]], [[const char *version = BZ2_bzlibVersion ();]])],[HAVE_BZ2=yes],[HAVE_BZ2=no])
 923   AC_MSG_RESULT($HAVE_BZ2)
 924   LIBS=$save_LIBS
 925   if test "x$HAVE_BZ2" = "xyes"; then
 926     BZ2_LIBS="-lbz2"
 927   fi
 928   AC_SUBST(BZ2_LIBS)
 929 ])
 930
 931 else
 932
 933 dnl not building plugins with external dependencies,
 934 dnl but we still need to set the conditionals
 935 AM_CONDITIONAL(USE_AALIB, false)
 936 AM_CONDITIONAL(USE_BZ2, false)
 937 AM_CONDITIONAL(USE_CAIRO, false)
 938 AM_CONDITIONAL(USE_DIRECTSOUND, false)
 939 AM_CONDITIONAL(USE_DV1394, false)
 940 AM_CONDITIONAL(USE_FLAC, false)
 941 AM_CONDITIONAL(USE_GDK_PIXBUF, false)
 942 AM_CONDITIONAL(USE_JACK, false)
 943 AM_CONDITIONAL(USE_JPEG, false)
 944 AM_CONDITIONAL(USE_LIBCACA, false)
 945 AM_CONDITIONAL(USE_LIBDV, false)
 946 AM_CONDITIONAL(USE_LIBIEC61883, false)
 947 AM_CONDITIONAL(USE_LIBPNG, false)
 948 AM_CONDITIONAL(USE_OSS, false)
 949 AM_CONDITIONAL(USE_OSS4, false)
 950 AM_CONDITIONAL(USE_OSX_AUDIO, false)
 951 AM_CONDITIONAL(USE_OSX_VIDEO, false)
 952 AM_CONDITIONAL(USE_PULSE, false)
 953 AM_CONDITIONAL(USE_SHOUT2, false)
 954 AM_CONDITIONAL(USE_SOUP, false)
 955 AM_CONDITIONAL(USE_SPEEX, false)
 956 AM_CONDITIONAL(USE_SUNAUDIO, false)
 957 AM_CONDITIONAL(USE_TAGLIB, false)
 958 AM_CONDITIONAL(USE_VPX, false)
 959 AM_CONDITIONAL(USE_WAVEFORM, false)
 960 AM_CONDITIONAL(USE_WAVPACK, false)
 961 AM_CONDITIONAL(USE_X, false)
 962 AM_CONDITIONAL(USE_XSHM, false)
 963 AM_CONDITIONAL(USE_ZLIB, false)
 964
 965 fi dnl of EXT plugins
 966
 967 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 968
 969 dnl Overview:
 970 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 971 dnl GST_*:              flags shared by all built objects
 972 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 973 dnl GST_LIB_LDFLAGS:    not needed, we don't install libraries
 974 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 975 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 976
 977 dnl GST_OPTION_CFLAGS
 978 if test "x$USE_DEBUG" = xyes; then
 979    PROFILE_CFLAGS="-g"
 980 fi
 981 AC_SUBST(PROFILE_CFLAGS)
 982
 983 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 984   dnl Define _only_ for git (not pre-releases or releases)
 985   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 986 else
 987   DEPRECATED_CFLAGS=""
 988 fi
 989 AC_SUBST(DEPRECATED_CFLAGS)
 990
 991 dnl every flag in GST_OPTION_CFLAGS, GST_OPTION_CXXFLAGS and GST_OPTION_OBJCFLAGS can be overridden
 992 dnl at make time with e.g. make ERROR_CFLAGS=""
 993 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 994 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 995 GST_OPTION_OBJCFLAGS="\$(WARNING_OBJCFLAGS) \$(ERROR_OBJCFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 996 AC_SUBST(GST_OPTION_CFLAGS)
 997 AC_SUBST(GST_OPTION_CXXFLAGS)
 998 AC_SUBST(GST_OPTION_OBJCFLAGS)
 999
1000 dnl our libraries need to be versioned correctly
1001 AC_SUBST(GST_LT_LDFLAGS)
1002
1003 dnl FIXME: do we want to rename to GST_ALL_* ?
1004 dnl prefer internal headers to already installed ones
1005 dnl also add builddir include for enumtypes and marshal
1006 dnl add ERROR_CFLAGS, but overridable
1007 GST_CFLAGS="$GST_CFLAGS -DGST_USE_UNSTABLE_API"
1008 GST_CXXFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CXXFLAGS)"
1009 GST_OBJCFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_OBJCFLAGS)"
1010 GST_CFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CFLAGS)"
1011 AC_SUBST(GST_CFLAGS)
1012 AC_SUBST(GST_CXXFLAGS)
1013 AC_SUBST(GST_OBJCFLAGS)
1014 AC_SUBST(GST_LIBS)
1015
1016 dnl LDFLAGS really should only contain flags, not libs - they get added before
1017 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1018 GST_ALL_LDFLAGS="-no-undefined"
1019 if test "x${enable_Bsymbolic}" = "xyes"; then
1020   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
1021 fi
1022 AC_SUBST(GST_ALL_LDFLAGS)
1023
1024 dnl this really should only contain flags, not libs - they get added before
1025 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1026 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_.*' $GST_ALL_LDFLAGS"
1027 AC_SUBST(GST_PLUGIN_LDFLAGS)
1028
1029 dnl *** output files ***
1030
1031 $MKDIR_P tests/check/orc
1032
1033 dnl keep this alphabetic per directory, please
1034 AC_CONFIG_FILES(
1035 Makefile
1036 gst/Makefile
1037 gst/alpha/Makefile
1038 gst/apetag/Makefile
1039 gst/audiofx/Makefile
1040 gst/audioparsers/Makefile
1041 gst/auparse/Makefile
1042 gst/autodetect/Makefile
1043 gst/avi/Makefile
1044 gst/cutter/Makefile
1045 gst/deinterlace/Makefile
1046 gst/dtmf/Makefile
1047 gst/debugutils/Makefile
1048 gst/effectv/Makefile
1049 gst/equalizer/Makefile
1050 gst/flv/Makefile
1051 gst/goom/Makefile
1052 gst/goom2k1/Makefile
1053 gst/id3demux/Makefile
1054 gst/icydemux/Makefile
1055 gst/imagefreeze/Makefile
1056 gst/interleave/Makefile
1057 gst/isomp4/Makefile
1058 gst/law/Makefile
1059 gst/level/Makefile
1060 gst/matroska/Makefile
1061 gst/monoscope/Makefile
1062 gst/multifile/Makefile
1063 gst/multipart/Makefile
1064 gst/replaygain/Makefile
1065 gst/rtp/Makefile
1066 gst/rtpmanager/Makefile
1067 gst/rtsp/Makefile
1068 gst/shapewipe/Makefile
1069 gst/smpte/Makefile
1070 gst/spectrum/Makefile
1071 gst/udp/Makefile
1072 gst/videobox/Makefile
1073 gst/videocrop/Makefile
1074 gst/videofilter/Makefile
1075 gst/videomixer/Makefile
1076 gst/wavenc/Makefile
1077 gst/wavparse/Makefile
1078 gst/flx/Makefile
1079 gst/y4m/Makefile
1080 ext/Makefile
1081 ext/aalib/Makefile
1082 ext/cairo/Makefile
1083 ext/dv/Makefile
1084 ext/flac/Makefile
1085 ext/gdk_pixbuf/Makefile
1086 ext/jack/Makefile
1087 ext/jpeg/Makefile
1088 ext/libcaca/Makefile
1089 ext/libpng/Makefile
1090 ext/pulse/Makefile
1091 ext/raw1394/Makefile
1092 ext/shout2/Makefile
1093 ext/soup/Makefile
1094 ext/speex/Makefile
1095 ext/taglib/Makefile
1096 ext/vpx/Makefile
1097 ext/wavpack/Makefile
1098 sys/Makefile
1099 sys/directsound/Makefile
1100 sys/oss/Makefile
1101 sys/oss4/Makefile
1102 sys/osxaudio/Makefile
1103 sys/osxvideo/Makefile
1104 sys/sunaudio/Makefile
1105 sys/v4l2/Makefile
1106 sys/waveform/Makefile
1107 sys/ximage/Makefile
1108 po/Makefile.in
1109 tests/Makefile
1110 tests/check/Makefile
1111 tests/examples/Makefile
1112 tests/examples/audiofx/Makefile
1113 tests/examples/cairo/Makefile
1114 tests/examples/equalizer/Makefile
1115 tests/examples/jack/Makefile
1116 tests/examples/level/Makefile
1117 tests/examples/rtp/Makefile
1118 tests/examples/shapewipe/Makefile
1119 tests/examples/spectrum/Makefile
1120 tests/examples/v4l2/Makefile
1121 tests/files/Makefile
1122 tests/icles/Makefile
1123 common/Makefile
1124 common/m4/Makefile
1125 m4/Makefile
1126 docs/Makefile
1127 docs/plugins/Makefile
1128 docs/version.entities
1129 pkgconfig/Makefile
1130 pkgconfig/gstreamer-plugins-good-uninstalled.pc
1131 )
1132 AC_OUTPUT
1133
1134 AG_GST_OUTPUT_PLUGINS
1135 ORC_OUTPUT
1136