configure.ac

   1 # If not 1, append datestamp to the version number
   2 m4_define([folks_released], [0])
   3
   4 m4_define([folks_major_version], [0])
   5 m4_define([folks_minor_version], [6])
   6 m4_define([folks_micro_version], [3])
   7 m4_define([folks_nano_version], [3])
   8
   9 # If library source has changed since last release, increment revision
  10 # If interfaces have been added, removed or changed since last release,
  11 #  increment current and set revision to 0
  12 # If interfaces have been added since last release, increment age
  13 # If interfaces have been removed since last release, set age to 0
  14 m4_define([folks_lt_current], [27])
  15 m4_define([folks_lt_revision], [2])
  16 m4_define([folks_lt_age], [2])
  17
  18 # Display the nano_version only if it's not '0'
  19 m4_define([folks_base_version],
  20           folks_major_version.folks_minor_version.folks_micro_version)
  21 m4_define([folks_full_version],
  22           [m4_if(folks_nano_version, [0],
  23                  folks_base_version, folks_base_version.folks_nano_version)])
  24
  25 m4_define([folks_maybe_datestamp],
  26           m4_if(folks_released, [1],
  27                 [], [m4_esyscmd([date +.%Y%m%d | tr -d '\n\r'])]))
  28
  29 m4_define([folks_version], folks_full_version[]folks_maybe_datestamp)
  30 m4_define([folks_major_minor_version], folks_major_version.folks_minor_version)
  31 m4_define([folks_module_version], folks_lt_current)
  32
  33 AC_INIT([folks], folks_version,
  34         [https://bugzilla.gnome.org/browse.cgi?product=folks], [folks],
  35         [http://telepathy.freedesktop.org/wiki/Folks])
  36 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  37
  38 AC_PREREQ([2.65])
  39 AC_COPYRIGHT([Copyright (C) 2010 Collabora Ltd.])
  40
  41 AC_CONFIG_MACRO_DIR([m4])
  42 AC_CONFIG_SRCDIR([Makefile.am])
  43 AC_CONFIG_HEADERS(config.h)
  44 AC_CONFIG_SRCDIR([configure.ac])
  45 AM_INIT_AUTOMAKE([1.11 dist-bzip2 no-define
  46                   no-dist-gzip tar-ustar -Wno-portability])
  47 AM_MAINTAINER_MODE([enable])
  48
  49 AC_PROG_CC
  50 AM_PROG_CC_C_O
  51 AC_DISABLE_STATIC
  52 LT_INIT
  53 PKG_PROG_PKG_CONFIG([0.21])
  54
  55 AC_SUBST([CFLAGS])
  56 AC_SUBST([CPPFLAGS])
  57 AC_SUBST([LDFLAGS])
  58
  59 LT_CURRENT=folks_lt_current
  60 LT_REVISION=folks_lt_revision
  61 LT_AGE=folks_lt_age
  62 AC_SUBST([LT_CURRENT])
  63 AC_SUBST([LT_REVISION])
  64 AC_SUBST([LT_AGE])
  65
  66 FOLKS_MAJOR_MINOR_VERSION=folks_major_minor_version
  67 AC_SUBST([FOLKS_MAJOR_MINOR_VERSION])
  68
  69 API_VERSION=0.6
  70 AC_SUBST([API_VERSION])
  71
  72 AC_ARG_ENABLE(tracker-backend,
  73         AC_HELP_STRING([--enable-tracker-backend],
  74                        [ build the Tracker backend]),
  75         enable_tracker_backend=$enableval,
  76         enable_tracker_backend=no )
  77
  78 AM_CONDITIONAL([ENABLE_TRACKER], [test "x$enable_tracker_backend" = "xyes"])
  79
  80 AC_ARG_ENABLE(eds-backend,
  81         AC_HELP_STRING([--enable-eds-backend],
  82                        [ build the E-D-S backend]),
  83         enable_eds_backend=$enableval,
  84         enable_eds_backend=yes )
  85
  86 AM_CONDITIONAL([ENABLE_EDS], [test "x$enable_eds_backend" = "xyes"])
  87
  88 # Automatically check the dependencies for the libsocialweb backend
  89 SW_CLIENT_REQUIRED=0.25.15
  90 AC_ARG_ENABLE(libsocialweb-backend,
  91         AC_HELP_STRING([--enable-libsocialweb-backend=@<:@no/yes/auto@:>@],
  92                        [build the Libsocialweb backend (default: auto)]),
  93         enable_libsocialweb_backend=$enableval,
  94         enable_libsocialweb_backend=auto )
  95
  96 if test "x$enable_libsocialweb_backend" != "xno"; then
  97   PKG_CHECK_MODULES([SW_CLIENT], [libsocialweb-client >= $SW_CLIENT_REQUIRED],
  98       have_libsocialweb_backend="yes", have_libsocialweb_backend="no")
  99   if test "x$have_libsocialweb_backend" = "xyes" -a \
 100           "x$enable_vala" = "xyes"; then
 101     VALA_CHECK_PACKAGES([telepathy-glib
 102                          gio-2.0
 103                          gee-1.0
 104                          libsocialweb-client],
 105         ,
 106         have_libsocialweb_backend="no")
 107   fi
 108
 109   if test "x$have_libsocialweb_backend" = "xyes"; then
 110     AC_DEFINE(HAVE_LIBSOCIALWEB, [],
 111               [Define if you have the libsocialweb backend])
 112   fi
 113 else
 114    have_libsocialweb_backend=no
 115 fi
 116
 117 if test "x$enable_libsocialweb_backend" = "xyes" -a \
 118   "x$have_libsocialweb_backend" != "xyes"; then
 119     AC_MSG_ERROR([Cannot find libsocialweb dependencies.])
 120 fi
 121
 122 AM_CONDITIONAL([ENABLE_LIBSOCIALWEB],
 123         [test "x$have_libsocialweb_backend" = "xyes"])
 124
 125 # -----------------------------------------------------------
 126 # Dependencies
 127 # -----------------------------------------------------------
 128
 129 GLIB_REQUIRED=2.24.0
 130 TP_GLIB_REQUIRED=0.13.1
 131 VALA_REQUIRED=0.13.4
 132 VALADOC_REQUIRED=0.3.1
 133 TRACKER_SPARQL_MAJOR=0.12
 134 TRACKER_SPARQL_REQUIRED=0.12.0
 135 GCONF2_REQUIRED=2.31
 136 EBOOK_REQUIRED=3.1.5
 137 EDATASERVER_REQUIRED=3.1.5
 138
 139 PKG_CHECK_MODULES([GLIB],
 140                   [glib-2.0 >= $GLIB_REQUIRED
 141                    gobject-2.0 >= $GLIB_REQUIRED])
 142 PKG_CHECK_MODULES([GMODULE], [gmodule-no-export-2.0])
 143 PKG_CHECK_MODULES([GIO], [gio-2.0 >= $GLIB_REQUIRED])
 144 PKG_CHECK_MODULES([DBUS_GLIB], [dbus-glib-1])
 145 PKG_CHECK_MODULES([GCONF2], [gconf-2.0 >= $GCONF2_REQUIRED])
 146
 147 # FIXME: We depend on libgee < 0.7 because 0.7 breaks API. bgo#627746
 148 PKG_CHECK_MODULES([GEE], [gee-1.0 < 0.7])
 149 PKG_CHECK_MODULES([TP_GLIB], [telepathy-glib >= $TP_GLIB_REQUIRED])
 150
 151 if test x$enable_tracker_backend = xyes; then
 152         PKG_CHECK_MODULES([TRACKER_SPARQL],
 153                           [tracker-sparql-$TRACKER_SPARQL_MAJOR >= \
 154                            $TRACKER_SPARQL_REQUIRED])
 155 fi
 156
 157 if test x$enable_eds_backend = xyes; then
 158         PKG_CHECK_MODULES([EBOOK], [libebook-1.2 >= $EBOOK_REQUIRED])
 159         PKG_CHECK_MODULES([EDATASERVER], [libedataserver-1.2 >= $EDATASERVER_REQUIRED])
 160 fi
 161
 162 #
 163 # Vala building options -- allows tarball builds without installing Vala
 164 #
 165 AC_ARG_ENABLE([vala],
 166               AS_HELP_STRING([--enable-vala],
 167                              [Enable building from the Vala sources]),
 168               [enable_vala=$enableval],
 169               [enable_vala=no])
 170
 171 # will be re-set as necessary below
 172 AM_CONDITIONAL([HAVE_INTROSPECTION], [test "x$enable_vala" = "xyes"])
 173 sd=${srcdir}/
 174
 175 # Force Vala for non-release builds
 176 m4_if(folks_released, [1], [],
 177     [
 178         enable_vala=yes
 179         echo "Vala compiler required for non-release builds; requiring Vala..."
 180     ])
 181
 182 # Force Vala if generated source is missing or outdated
 183 if test \
 184         ! -e ${sd}tools/folks_import_vala.stamp -o \
 185         ! -e ${sd}tests/folks/abstract_field_details_vala.stamp -o \
 186         ! -e ${sd}tests/folks/aggregation_vala.stamp -o \
 187         ! -e ${sd}tests/folks/backend_loading_vala.stamp -o \
 188         ! -e ${sd}tests/key-file/individual_retrieval_vala.stamp -o \
 189         ! -e ${sd}tests/lib/folks-test.vapi -o \
 190         ! -e ${sd}tests/lib/key-file/kf-test.vapi -o \
 191         ! -e ${sd}tests/lib/key-file/libkf_test_la_vala.stamp -o \
 192         ! -e ${sd}tests/lib/telepathy/contactlist/tp-test-contactlist.gir -o \
 193         ! -e ${sd}tests/lib/telepathy/contactlist/tp-test-contactlist.vapi -o \
 194         ! -e ${sd}tests/lib/libfolks_test_la_vala.stamp -o \
 195         ! -e ${sd}tests/telepathy/persona_store_capabilities_vala.stamp -o \
 196         ! -e ${sd}tests/telepathy/individual_retrieval_vala.stamp -o \
 197         ! -e ${sd}tests/telepathy/individual_properties_vala.stamp -o \
 198         ! -e ${sd}tests/folks/backend_loading_vala.stamp -o \
 199         ! -e ${sd}backends/key-file/key_file_la_vala.stamp -o \
 200         ! -e ${sd}backends/telepathy/telepathy_la_vala.stamp \
 201                 -o \
 202         ! -e ${sd}backends/telepathy/lib/folks-telepathy.vapi -o \
 203         ! -e ${sd}backends/telepathy/lib/tp-lowlevel.gir -o \
 204         ! -e ${sd}backends/telepathy/lib/tp-lowlevel.vapi -o \
 205         ! -e ${sd}backends/telepathy/lib/libfolks_telepathy_la_vala.stamp -o \
 206         ! -e ${sd}folks/folks.vapi -o \
 207         ! -e ${sd}folks/libfolks_la_vala.stamp ; then
 208         enable_vala=yes
 209         echo "Vala source needs to be re-compiled; requiring Vala..."
 210 fi
 211
 212 if test "x$enable_vala" = "xyes" ; then
 213         AM_PROG_VALAC([$VALA_REQUIRED])
 214         if test "x$VALAC" = "x"; then
 215               AC_MSG_ERROR([Vala requested but valac is not installed])
 216         fi
 217
 218         AC_PATH_PROG([VAPIGEN], [vapigen], [])
 219         if test "x$VAPIGEN" = "x"; then
 220               AC_MSG_ERROR([Vala must be built with --enable-vapigen])
 221         fi
 222
 223         # require GLib >= 2.24 so GLib.Array, etc. reffing is handled
 224         # automatically
 225         VALAFLAGS="$VALAFLAGS --target-glib=2.24"
 226         AC_SUBST([VALAFLAGS])
 227         AC_SUBST([VAPIGENFLAGS])
 228         AC_SUBST([VAPIDIR])
 229
 230         VALA_CHECK_PACKAGES([telepathy-glib
 231                              gio-2.0
 232                              gee-1.0])
 233
 234         if test x$enable_tracker_backend = xyes; then
 235           VALA_CHECK_PACKAGES([tracker-sparql-$TRACKER_SPARQL_MAJOR])
 236         fi
 237
 238         if test x$enable_eds_backend = xyes; then
 239           VALA_CHECK_PACKAGES([libebook-1.2 libedataserver-1.2 libxml-2.0])
 240         fi
 241 fi
 242
 243 # this will set HAVE_INTROSPECTION
 244 GOBJECT_INTROSPECTION_REQUIRE([0.9.12])
 245
 246 AM_CONDITIONAL([HAVE_VALA], [test "x$enable_vala" = "xyes"])
 247
 248 # Various functions that we need (used in C code generated from Vala)
 249 AC_CHECK_FUNCS([memset])
 250 AC_CHECK_FUNCS([strstr])
 251
 252 # -----------------------------------------------------------
 253 # Backends
 254 # -----------------------------------------------------------
 255
 256 FOLKS_MODULE_VERSION=folks_module_version
 257 AC_SUBST([FOLKS_MODULE_VERSION])
 258 AC_DEFINE([MODULE_VERSION], "folks_module_version", [Module interface version])
 259
 260 BACKEND_DIR='$(libdir)/folks/$(FOLKS_MODULE_VERSION)/backends'
 261 AC_SUBST([BACKEND_DIR])
 262
 263 BACKEND_KF='$(top_builddir)/backends/key-file/.libs/key-file.so'
 264 AC_SUBST([BACKEND_KF])
 265 BACKEND_TP='$(top_builddir)/backends/telepathy/.libs/telepathy.so'
 266 AC_SUBST([BACKEND_TP])
 267
 268 if test x$have_libsocialweb_backend = xyes; then
 269   BACKEND_LIBSOCIALWEB='$(top_builddir)/backends/libsocialweb/.libs/libsocialweb.so'
 270   AC_SUBST([BACKEND_LIBSOCIALWEB])
 271 fi
 272
 273 if test x$enable_tracker_backend = xyes; then
 274   BACKEND_TRACKER='$(top_builddir)/backends/tracker/.libs/tracker.so'
 275   AC_SUBST([BACKEND_TRACKER])
 276 fi
 277
 278 if test x$enable_eds_backend = xyes; then
 279   BACKEND_EDS='$(top_builddir)/backends/eds/.libs/eds.so'
 280   AC_SUBST([BACKEND_EDS])
 281 fi
 282
 283 # All of the backend libraries in our tree; to be used by the tests
 284 BACKEND_UNINST_PATH='$(BACKEND_KF):$(BACKEND_TP)'
 285 if test x$have_libsocialweb_backend = xyes; then
 286   LIBSOCIALWEB_BACKEND_UNINST_PATH='$(BACKEND_LIBSOCIALWEB)'
 287   BACKEND_UNINST_PATH="$BACKEND_UNINST_PATH:$LIBSOCIALWEB_BACKEND_UNINST_PATH"
 288 fi
 289 if test x$enable_tracker_backend = xyes; then
 290   TRACKER_BACKEND_UNINST_PATH='$(BACKEND_TRACKER)'
 291   BACKEND_UNINST_PATH="$BACKEND_UNINST_PATH:$TRACKER_BACKEND_UNINST_PATH"
 292 fi
 293 if test x$enable_eds_backend = xyes; then
 294   EDS_BACKEND_UNINST_PATH='$(BACKEND_EDS)'
 295   BACKEND_UNINST_PATH="$BACKEND_UNINST_PATH:$EDS_BACKEND_UNINST_PATH"
 296 fi
 297 AC_SUBST([BACKEND_UNINST_PATH])
 298
 299 # -----------------------------------------------------------
 300 # Tools
 301 # -----------------------------------------------------------
 302
 303 AC_ARG_ENABLE([import-tool],
 304               AS_HELP_STRING([--enable-import-tool],
 305                              [Enable building the meta-contact import tool]),
 306               [enable_import_tool=$enableval with_import_tool=$enableval],
 307               [enable_import_tool=maybe with_import_tool=no])
 308 AS_IF([test "$enable_import_tool" != "no"],
 309       [PKG_CHECK_MODULES([LIBXML], [libxml-2.0],
 310                          [with_import_tool=yes], [with_import_tool=no])])
 311 AS_IF([test "$enable_import_tool" = "yes" -a "$with_import_tool" = "no"],
 312       [AC_MSG_ERROR([Import tool explicitly enabled, but libxml2 not found])])
 313 AM_CONDITIONAL([ENABLE_IMPORT_TOOL], [test "$with_import_tool" = "yes"])
 314
 315 # Readline's required for the folks-inspect program
 316 AC_ARG_ENABLE([inspect-tool],
 317               AS_HELP_STRING([--enable-inspect-tool],
 318                              [Enable building the data inspection tool]),
 319               [enable_inspect_tool=$enableval with_inspect_tool=$enableval],
 320               [enable_inspect_tool=maybe with_inspect_tool=no])
 321 AS_IF([test "$enable_inspect_tool" = "yes" -a "$enable_vala" != "yes"],
 322       [AC_MSG_ERROR([Inspect tool explicitly enabled, but Vala wasn't enabled \
 323                      using --enable-vala])])
 324 AS_IF([test "$enable_inspect_tool" = "maybe" -a "$enable_vala" != "yes"],
 325       [AC_MSG_NOTICE([Inspect tool disabled, as Vala wasn't enabled using \
 326                       --enable-vala])])
 327 AS_IF([test "$enable_inspect_tool" != "no" -a "x$enable_vala" = "xyes"],
 328       [AC_CHECK_LIB([readline], [main],
 329                     [with_inspect_tool=yes], [with_inspect_tool=no],
 330                     [-lncurses])])
 331 AS_IF([test "$enable_inspect_tool" != "no" -a "$with_inspect_tool" = "yes" -a \
 332        "x$enable_vala" = "xyes"],
 333       [VALA_CHECK_PACKAGES([readline])
 334        LIBREADLINE="-lreadline -lncurses"
 335        AC_DEFINE([HAVE_LIBREADLINE], [1], [Define if you have libreadline])
 336        AC_SUBST([LIBREADLINE])])
 337 AS_IF([test "$enable_inspect_tool" = "yes" -a "$with_inspect_tool" = "no"],
 338       [AC_MSG_ERROR([Inspect tool explicitly enabled, but readline not found])])
 339 AM_CONDITIONAL([ENABLE_INSPECT_TOOL], [test "$with_inspect_tool" = "yes"])
 340
 341 # -----------------------------------------------------------
 342 # Documentation
 343 # -----------------------------------------------------------
 344
 345 AC_ARG_ENABLE([docs],
 346               AS_HELP_STRING([--enable-docs],[Enable documentation generation]),
 347               [enable_docs=$enableval], [enable_docs=no])
 348 AM_CONDITIONAL([ENABLE_DOCS], [test x$enable_docs = xyes])
 349
 350 have_valadoc=no
 351 if test x$enable_docs = xyes; then
 352   # make sure the library is new enough and the program exists
 353   PKG_CHECK_MODULES([VALADOC], [valadoc-1.0 >= $VALADOC_REQUIRED])
 354   AC_PATH_PROG([VALADOC], [valadoc], [:])
 355   AS_IF([test "$VALADOC" != :], have_valadoc=yes)
 356 fi
 357 AM_CONDITIONAL([HAVE_VALADOC], [test x$have_valadoc = xyes])
 358
 359 if test "x$enable_docs" = "xyes" -a "x$have_valadoc" != "xyes"; then
 360     AC_MSG_ERROR([Doc building requested but valadoc not installed.])
 361 fi
 362
 363 # -----------------------------------------------------------
 364 # Gettext
 365 # -----------------------------------------------------------
 366
 367 GETTEXT_PACKAGE=AC_PACKAGE_NAME
 368 AC_SUBST(GETTEXT_PACKAGE)
 369 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"], [Define the gettext package to be used])
 370 IT_PROG_INTLTOOL([0.35.0])
 371
 372 # -----------------------------------------------------------
 373 # Error flags
 374 # -----------------------------------------------------------
 375
 376 AS_COMPILER_FLAG([-Wall], [ERROR_CFLAGS="-Wall"], [ERROR_CFLAGS=""])
 377 AS_COMPILER_FLAG([-Werror], [werror=yes], [werror=no])
 378
 379 AC_ARG_ENABLE([debug],
 380               AS_HELP_STRING([--disable-debug],[compile without debug code]),
 381               [enable_debug=$enableval], [enable_debug=yes])
 382
 383 AC_ARG_ENABLE([Werror],
 384               AS_HELP_STRING([--disable-Werror],
 385                              [compile without -Werror (normally enabled in
 386                               development builds)]),
 387               [werror=$enableval], [werror=yes])
 388
 389 AS_COMPILER_FLAG([-Wextra], [wextra=yes], [wextra=no])
 390 AS_COMPILER_FLAG([-Wno-missing-field-initializers],
 391                  [wno_missing_field_initializers=yes],
 392                  [wno_missing_field_initializers=no])
 393 AS_COMPILER_FLAG([-Wno-unused-parameter],
 394                  [wno_unused_parameter=yes], [wno_unused_parameter=no])
 395
 396 m4_if(folks_released, [1], [],
 397     [
 398         if test x$werror = xyes; then
 399             ERROR_CFLAGS="$ERROR_CFLAGS -Werror"
 400         fi
 401         if test x$wextra = xyes -a \
 402             x$wno_missing_field_initializers = xyes -a \
 403             x$wno_unused_parameter = xyes; then
 404             ERROR_CFLAGS="$ERROR_CFLAGS -Wextra \
 405                 -Wno-missing-field-initializers -Wno-unused-parameter"
 406         fi
 407     ])
 408
 409 AS_COMPILER_FLAG([-D_POSIX_SOURCE], [ERROR_CFLAGS="$ERROR_CFLAGS -D_POSIX_SOURCE"])
 410 AS_COMPILER_FLAG([-std=c99], [ERROR_CFLAGS="$ERROR_CFLAGS -std=c99"])
 411 AS_COMPILER_FLAG([-Wshadow], [ERROR_CFLAGS="$ERROR_CFLAGS -Wshadow"])
 412 AS_COMPILER_FLAG([-Wmissing-prototypes], [ERROR_CFLAGS="$ERROR_CFLAGS \
 413                                           -Wmissing-prototypes"])
 414 AS_COMPILER_FLAG([-Wmissing-declarations], [ERROR_CFLAGS="$ERROR_CFLAGS \
 415                                             -Wmissing-declarations"])
 416 AS_COMPILER_FLAG([-Wstrict-prototypes], [ERROR_CFLAGS="$ERROR_CFLAGS \
 417                                          -Wstrict-prototypes"])
 418
 419 AC_SUBST([ERROR_CFLAGS])
 420
 421 # Vala-related flags
 422 AS_IF([test "x$enable_vala" = "xyes"],
 423       [ERROR_INTROSPECTION_SCANNER_ARGS="\
 424                         $ERROR_INTROSPECTION_SCANNER_ARGS --warn-error"
 425        ERROR_VALAFLAGS="$ERROR_VALAFLAGS --fatal-warnings"])
 426
 427 m4_if(folks_released, [1], [],
 428     [
 429         ERROR_VALAFLAGS="$ERROR_VALAFLAGS -g"
 430     ])
 431
 432 AC_SUBST([ERROR_INTROSPECTION_SCANNER_ARGS])
 433 AC_SUBST([ERROR_VALAFLAGS])
 434
 435 # -----------------------------------------------------------
 436 # Final output
 437 # -----------------------------------------------------------
 438
 439 AC_CONFIG_FILES([
 440     backends/telepathy/lib/folks-telepathy.pc
 441     backends/telepathy/lib/folks-telepathy-uninstalled.pc
 442     backends/tracker/lib/folks-tracker.pc
 443     backends/tracker/lib/folks-tracker-uninstalled.pc
 444     backends/eds/lib/folks-eds.pc
 445     backends/eds/lib/folks-eds-uninstalled.pc
 446     folks/folks.pc
 447     folks/folks-uninstalled.pc
 448     Makefile
 449     backends/Makefile
 450     backends/key-file/Makefile
 451     backends/libsocialweb/Makefile
 452     backends/libsocialweb/lib/Makefile
 453     backends/libsocialweb/lib/folks-libsocialweb.pc
 454     backends/libsocialweb/lib/folks-libsocialweb-uninstalled.pc
 455     backends/telepathy/Makefile
 456     backends/telepathy/lib/Makefile
 457     backends/tracker/Makefile
 458     backends/tracker/lib/Makefile
 459     backends/eds/Makefile
 460     backends/eds/lib/Makefile
 461     folks/Makefile
 462     docs/Makefile
 463     po/Makefile.in
 464     tests/Makefile
 465     tests/data/Makefile
 466     tests/data/gconf.path
 467     tests/folks/Makefile
 468     tests/key-file/Makefile
 469     tests/libsocialweb/Makefile
 470     tests/telepathy/Makefile
 471     tests/tracker/Makefile
 472     tests/lib/Makefile
 473     tests/lib/folks-test-uninstalled.pc
 474     tests/lib/key-file/Makefile
 475     tests/lib/libsocialweb/Makefile
 476     tests/lib/libsocialweb/session.conf
 477     tests/eds/Makefile
 478     tests/lib/eds/Makefile
 479     tests/lib/telepathy/Makefile
 480     tests/lib/tracker/Makefile
 481     tests/lib/telepathy/contactlist/Makefile
 482     tests/lib/telepathy/contactlist/session.conf
 483     tests/tools/Makefile
 484     tools/Makefile
 485     tools/inspect/Makefile
 486 ])
 487
 488 AC_OUTPUT
 489
 490 echo "
 491 Configure summary:
 492
 493         Vala........................:  ${enable_vala}
 494         Vala Compiler...............:  ${VALAC}
 495         C Compiler Flags............:  ${CFLAGS} ${ERROR_CFLAGS}
 496         Prefix......................:  ${prefix}
 497         Bugreporting URL............:  ${PACKAGE_BUGREPORT}
 498         Documentation...............:  ${have_valadoc}
 499         Import tool.................:  ${with_import_tool}
 500         Inspector tool..............:  ${with_inspect_tool}
 501         Tracker backend.............:  ${enable_tracker_backend}
 502         Libsocialweb backend........:  ${have_libsocialweb_backend}
 503         E-D-S backend...............:  ${enable_eds_backend}
 504
 505 "