configure.ac

   1 AC_PREREQ(2.69)
   2
   3 dnl initialize autoconf
   4 dnl when going to/from release please set the nano (fourth number) right !
   5 dnl releases only do Wall, cvs and prerelease does Werror too
   6 AC_INIT(GStreamer libav, 1.7.0.1,
   7     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
   8     gst-libav)
   9
  10 AG_GST_INIT
  11
  12 dnl initialize automake
  13 AM_INIT_AUTOMAKE([-Wno-portability 1.14 no-dist-gzip dist-xz tar-ustar subdir-objects])
  14
  15 dnl define PACKAGE_VERSION_* variables
  16 AS_VERSION
  17
  18 dnl check if this is a release version
  19 AS_NANO(GST_GIT="no", GST_GIT="yes")
  20
  21 dnl can autoconf find the source ?
  22 AC_CONFIG_SRCDIR([ext/libav/gstav.c])
  23
  24 dnl define the output header for config
  25 AC_CONFIG_HEADERS([config.h])
  26
  27 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  28 AM_MAINTAINER_MODE([enable])
  29
  30 dnl sets host_* variables
  31 AC_CANONICAL_HOST
  32
  33 dnl use pretty build output by default
  34 AM_SILENT_RULES([yes])
  35
  36 dnl our libraries and install dirs use major.minor as a version
  37 GST_API_VERSION=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  38 dnl we override it here if we need to for the release candidate of new series
  39 GST_API_VERSION=1.0
  40 AC_SUBST(GST_API_VERSION)
  41
  42 AG_GST_LIBTOOL_PREPARE
  43 AS_LIBTOOL(GST, 700, 0, 700)
  44
  45 dnl *** required versions of GStreamer stuff ***
  46 GST_REQ=1.7.0.1
  47 GST_PBREQ=1.7.0.1
  48
  49 ORC_REQ=0.4.16
  50 ORC_CHECK([$ORC_REQ])
  51
  52 dnl *** autotools stuff ****
  53
  54 dnl allow for different autotools
  55 AS_AUTOTOOLS_ALTERNATE
  56
  57 dnl Add parameters for aclocal
  58 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  59
  60 dnl *** check for arguments to configure ***
  61
  62 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  63
  64 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  65 AG_GST_ARG_WITH_PACKAGE_NAME
  66 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  67 AG_GST_ARG_VALGRIND
  68 AG_GST_ARG_GCOV
  69
  70 dnl *** checks for platform ***
  71
  72 dnl * hardware/architecture *
  73
  74 dnl common/m4/gst-arch.m4
  75 dnl check CPU type
  76 AG_GST_ARCH
  77
  78 dnl *** checks for programs ***
  79
  80 dnl find a compiler
  81 AC_PROG_CC
  82 AC_PROG_CC_STDC
  83
  84 dnl check if the compiler supports '-c' and '-o' options
  85 AM_PROG_CC_C_O
  86
  87 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
  88 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
  89
  90 dnl check for documentation tools
  91 GTK_DOC_CHECK([1.12])
  92 AG_GST_PLUGIN_DOCS([1.12])
  93
  94 dnl *** checks for libraries ***
  95
  96 dnl check for libm, for sin()
  97 LT_LIB_M
  98 AC_SUBST(LIBM)
  99
 100 dnl *** checks for header files ***
 101
 102 dnl check if we have ANSI C header files
 103 AC_HEADER_STDC
 104
 105 dnl *** checks for types/defines ***
 106
 107 dnl *** checks for structures ***
 108
 109 dnl *** checks for compiler characteristics ***
 110
 111 dnl *** checks for library functions ***
 112
 113 dnl *** checks for dependancy libraries ***
 114
 115 dnl GLib is required
 116 GLIB_REQ=2.40.0
 117 AC_SUBST([GLIB_REQ])
 118 AG_GST_GLIB_CHECK([$GLIB_REQ])
 119
 120 dnl checks for gstreamer
 121 dnl uninstalled is selected preferentially -- see pkg-config(1)
 122 AG_GST_CHECK_GST($GST_API_VERSION, [$GST_REQ])
 123 AG_GST_CHECK_GST_BASE($GST_API_VERSION, [$GST_REQ])
 124 AG_GST_CHECK_GST_PLUGINS_BASE($GST_API_VERSION, [$GST_PBREQ])
 125 AG_GST_CHECK_GST_CHECK($GST_API_VERSION, [$GST_REQ], no)
 126 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 127
 128 AC_MSG_NOTICE(Using GStreamer Core Plugins in $GST_PLUGINS_DIR)
 129 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 130
 131 dnl *** set variables based on configure arguments ***
 132
 133 dnl set location of plugin directory
 134 AG_GST_SET_PLUGINDIR
 135
 136 dnl build static plugins or not
 137 AC_MSG_CHECKING([whether to build static plugins or not])
 138 AC_ARG_ENABLE(
 139   static-plugins,
 140   AC_HELP_STRING(
 141     [--enable-static-plugins],
 142     [build static plugins @<:@default=no@:>@]),
 143   [AS_CASE(
 144     [$enableval], [no], [], [yes], [],
 145     [AC_MSG_ERROR([bad value "$enableval" for --enable-static-plugins])])],
 146   [enable_static_plugins=no])
 147 AC_MSG_RESULT([$enable_static_plugins])
 148 if test "x$enable_static_plugins" = xyes; then
 149   AC_DEFINE(GST_PLUGIN_BUILD_STATIC, 1,
 150     [Define if static plugins should be built])
 151   GST_PLUGIN_LIBTOOLFLAGS=""
 152 else
 153   GST_PLUGIN_LIBTOOLFLAGS="--tag=disable-static"
 154 fi
 155 AC_SUBST(GST_PLUGIN_LIBTOOLFLAGS)
 156 AM_CONDITIONAL(GST_PLUGIN_BUILD_STATIC, test "x$enable_static_plugins" = "xyes")
 157
 158 dnl define an ERROR_CFLAGS Makefile variable
 159 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [
 160     -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef
 161     -Wwrite-strings -Wformat-nonliteral -Wformat-security -Wold-style-definition
 162     -Winit-self -Wmissing-include-dirs -Waddress
 163     -Waggregate-return -Wno-multichar -Wnested-externs ])
 164
 165 dnl define correct level for debugging messages
 166 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 167
 168 dnl *** finalize CFLAGS, LDFLAGS, LIBS ***
 169
 170 dnl Overview:
 171 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 172 dnl GST_*:              flags shared by built objects to link against GStreamer
 173 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 174 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 175 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 176 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 177
 178 dnl GST_OPTION_CFLAGS
 179 if test "x$USE_DEBUG" = xyes; then
 180    PROFILE_CFLAGS="-g"
 181 fi
 182 AC_SUBST(PROFILE_CFLAGS)
 183
 184 if test "x$GST_GIT" = "xyes"; then
 185   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 186 else
 187   DEPRECATED_CFLAGS=""
 188 fi
 189 AC_SUBST(DEPRECATED_CFLAGS)
 190
 191 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time
 192 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 193
 194 AC_SUBST(GST_OPTION_CFLAGS)
 195
 196 dnl FIXME: do we want to rename to GST_ALL_* ?
 197 dnl prefer internal headers to already installed ones
 198 dnl also add builddir include for enumtypes and marshal
 199 dnl add GST_OPTION_CFLAGS, but overridable
 200 GST_CFLAGS="$GST_CFLAGS"
 201 GST_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CFLAGS)"
 202 AC_SUBST(GST_CFLAGS)
 203 AC_SUBST(GST_LIBS)
 204
 205 GST_ALL_LDFLAGS="-no-undefined"
 206 AC_SUBST(GST_ALL_LDFLAGS)
 207
 208 dnl this really should only contain flags, not libs - they get added before
 209 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 210 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_.*' $GST_ALL_LDFLAGS"
 211 AC_SUBST(GST_PLUGIN_LDFLAGS)
 212
 213 dnl Add MacOSX specific flags
 214 AC_CANONICAL_HOST
 215 case $host_os in
 216      darwin*)
 217         DARWIN_LDFLAGS="-Wl,-read_only_relocs,suppress"
 218         ;;
 219      *)
 220         DARWIN_LDFLAGS=""
 221         ;;
 222 esac
 223 AC_SUBST(DARWIN_LDFLAGS)
 224
 225 dnl *** Check for bz2
 226 save_LIBS=$LIBS
 227 LIBS="$LIBS -lbz2"
 228 AC_MSG_CHECKING([for BZ2_bzlibVersion in -lbz2])
 229 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <bzlib.h>]], [[const char *version = BZ2_bzlibVersion ();]])],[HAVE_BZ2=yes],[HAVE_BZ2=no])
 230 AC_MSG_RESULT($HAVE_BZ2)
 231 LIBS=$save_LIBS
 232 AM_CONDITIONAL(HAVE_BZ2, test "x$HAVE_BZ2" = "xyes")
 233 if test "x$HAVE_BZ2" = "xno"; then
 234   AC_WARN([libbz2 not found, matroska demuxer will not be able to read bz2 tracks])
 235 fi
 236
 237 dnl *** Check for lzma
 238 save_LIBS=$LIBS
 239 LIBS="$LIBS -llzma"
 240 AC_MSG_CHECKING([for lzma_version_string in -llzma])
 241 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <lzma.h>]], [[const char *version = lzma_version_string ();]])],[HAVE_LZMA=yes],[HAVE_LZMA=no])
 242 AC_MSG_RESULT($HAVE_LZMA)
 243 LIBS=$save_LIBS
 244 AM_CONDITIONAL(HAVE_LZMA, test "x$HAVE_LZMA" = "xyes")
 245 if test "x$HAVE_LZMA" = "xno"; then
 246     AC_WARN([lzma not found, tiff reader will not be able to read lzma files])
 247 fi
 248
 249 AC_ARG_ENABLE(gpl,
 250               [AC_HELP_STRING([--enable-gpl], [build a GPL licensed gst-libav])])
 251 AM_CONDITIONAL(GST_LIBAV_ENABLE_GPL, test "x$enable_gpl" = "xyes")
 252 if test "x$enable_gpl" = "xyes"; then
 253   AC_DEFINE([GST_LIBAV_ENABLE_GPL], [], [Defined if building a GPL-licensed version of gst-libav])
 254 fi
 255
 256 dnl *** configure external libs ***
 257
 258 HAVE_LIBAV_UNINSTALLED=1
 259
 260 AC_ARG_WITH(system-libav,
 261             [AC_HELP_STRING([--with-system-libav], [use system Libav libraries])])
 262
 263 if test "x$with_system_libav" = "xyes"; then
 264   PKG_CHECK_MODULES(LIBAV, libavformat libavcodec libavutil)
 265   PKG_CHECK_MODULES(SWSCALE, libswscale libavutil)
 266   saved_CPPFLAGS="$CPPFLAGS"
 267   CPPFLAGS="$CPPFLAGS $LIBAV_CFLAGS"
 268   AC_CHECK_HEADERS([avi.h])
 269   CPPFLAGS="$saved_CPPFLAGS"
 270   AC_DEFINE([LIBAV_SOURCE], ["system install"], [Describes where the Libav libraries come from.])
 271   HAVE_LIBAV_UNINSTALLED=0
 272   AC_MSG_NOTICE([Using system-installed libav code])
 273 else
 274   AC_MSG_NOTICE([Using local Libav snapshot])
 275
 276   dnl libgstlibav.la: include dirs
 277   LIBAV_CFLAGS="-I \$(top_srcdir)/gst-libs/ext/libav \
 278                 -I \$(top_builddir)/gst-libs/ext/libav \
 279                  -Wno-deprecated-declarations"
 280
 281   LIBAV_DEPS="\$(top_builddir)/gst-libs/ext/libav/libavformat/libavformat.a \
 282               \$(top_builddir)/gst-libs/ext/libav/libavcodec/libavcodec.a \
 283               \$(top_builddir)/gst-libs/ext/libav/libswresample/libswresample.a \
 284               \$(top_builddir)/gst-libs/ext/libav/libavutil/libavutil.a"
 285   if test "x$enable_static_plugins" = xyes; then
 286       dnl with static linking we can't use the .a archive directly as they would
 287       dnl be included in the final libgstlibav.a as a file and won't be usable.
 288       dnl libav*.a must be copied to the final destination too
 289       LIBAV_LIBS="-lavformat -lavcodec -lswresample -lavutil"
 290   else
 291       dnl libgstlibav.la: libs to statically link to
 292       LIBAV_LIBS="$LIBAV_DEPS"
 293   fi
 294
 295   dnl
 296   SWSCALE_CFLAGS="-I \$(top_srcdir)/gst-libs/ext/libav \
 297                   -I \$(top_builddir)/gst-libs/ext/libav \
 298                   -Wno-deprecated-declarations"
 299
 300   SWSCALE_DEPS="\$(top_builddir)/gst-libs/ext/libav/libswscale/libswscale.a \
 301                 \$(top_builddir)/gst-libs/ext/libav/libavutil/libavutil.a"
 302   if test "x$enable_static_plugins" = xyes; then
 303       dnl with static linking we can't use the .a archive directly as they would
 304       dnl be included in the final libgstswscale.a as a file and won't be usable.
 305       dnl libav*.a must be copied to the final destination too
 306       SWSCALE_LIBS="-lswscale -lavutil"
 307   else
 308       dnl libgstswscale.la: libs to statically link to
 309       SWSCALE_LIBS="$SWSCALE_DEPS"
 310   fi
 311
 312   LIBAV_SUBDIRS=gst-libs
 313   AC_DEFINE(HAVE_AVI_H)
 314   AC_DEFINE([LIBAV_SOURCE], ["local snapshot"], [Describes where the Libav libraries come from.])
 315
 316   AC_ARG_WITH(libav-extra-configure,
 317       AC_HELP_STRING([--with-libav-extra-configure="xxx"],
 318       [extra configure options for internal libav ./configure script]),,
 319       with_libav=no)
 320
 321   # basic arguments
 322   emblibav_configure_args="--prefix=$prefix"
 323
 324   # Enable pic and static so that we get .a files, but with PIC code.
 325   emblibav_configure_args="$emblibav_configure_args \
 326         --enable-static --enable-pic \
 327         --disable-avdevice --disable-postproc --disable-avfilter \
 328         --disable-programs --disable-ffserver --disable-ffplay --disable-ffprobe --disable-ffmpeg \
 329         --disable-encoder=flac --disable-protocols --disable-devices \
 330         --disable-network --disable-hwaccels --disable-dxva2 --disable-vdpau \
 331         --disable-filters --disable-doc --disable-vda --disable-d3d11va --disable-dxva2 \
 332         --disable-iconv --enable-optimizations"
 333
 334   if test "x$enable_gpl" == "xyes"; then
 335     emblibav_configure_args="$emblibav_configure_args --enable-gpl"
 336   fi
 337
 338   # if we are cross-compiling, tell libav so
 339   case $host in
 340       *android*)
 341         target_os=linux
 342       ;;
 343       *darwin*)
 344         target_os=darwin
 345       ;;
 346       *)
 347         target_os=`echo $host_os | sed 's/-gnu//'`
 348       ;;
 349   esac
 350
 351   if test "x$cross_compiling" = xyes; then
 352     emblibav_configure_args="$emblibav_configure_args --enable-cross-compile \
 353         --target-os=$target_os --arch=$host_cpu --cross-prefix=$host_alias-"
 354   fi
 355
 356   case $host_os in
 357     mingw32*)
 358       emblibav_configure_args="$emblibav_configure_args --enable-memalign-hack"
 359       WIN32_LIBS="-lws2_32"
 360       ;;
 361     *)
 362       WIN32_LIBS=
 363       ;;
 364   esac
 365
 366   if test x"$AR" != x; then
 367     emblibav_configure_args="$emblibav_configure_args --ar=\\\"\\\$AR\\\""
 368   fi
 369
 370   if test x"$AS" != x; then
 371     emblibav_configure_args="$emblibav_configure_args --as=\\\"\\\$CC\\\""
 372   fi
 373
 374   if test x"$CC" != x; then
 375     emblibav_configure_args="$emblibav_configure_args --cc=\\\"\\\$CC\\\""
 376   fi
 377
 378   if test x"$LD" != x; then
 379     emblibav_configure_args="$emblibav_configure_args --ld=\\\"\\\$CC\\\""
 380   fi
 381
 382   if test x"$NM" != x; then
 383     emblibav_configure_args="$emblibav_configure_args --nm=\\\"\\\$NM\\\""
 384   fi
 385
 386   dnl checks for extra enable/disable flags
 387   LIBAV_OPTS=`cd $srcdir/gst-libs/ext/libav && ./configure --help`
 388   # Let's check if we can disable the building of the libav binary
 389   can_disable=`echo "$LIBAV_OPTS" | grep 'disable-ffmpeg'`
 390   if test "$can_disable" != ""; then
 391     emblibav_configure_args="$emblibav_configure_args --disable-ffmpeg"
 392   fi
 393   dnl check if libswscale needs enabling explicitly
 394   can_enable=`echo "$LIBAV_OPTS" | grep 'enable-swscale'`
 395   if test "$can_enable" != ""; then
 396     emblibav_configure_args="$emblibav_configure_args --enable-swscale"
 397   fi
 398
 399   # append extra configure options to emblibav_configure_args if needed
 400   if test "x$with_libav_extra_configure" != "xno"; then
 401     emblibav_configure_args="$emblibav_configure_args $with_libav_extra_configure"
 402   fi
 403
 404   AC_SUBST(LIBAV_CO_DIR)
 405   AC_SUBST(LIBAV_SVN)
 406   AC_SUBST(LIBAV_REVISION)
 407   AC_SUBST(LIBAV_EXTERNALS_REVISION)
 408   AC_CONFIG_COMMANDS([configure-embedded-libav],
 409     [echo "Configuring included Libav instance with args $emblibav_configure_args"
 410      origdir=`pwd`
 411      dnl Don't put path on the configure call when not needed, as FFmpeg's configure relies on it
 412      dnl to detect out-of-tree builds
 413      if test -z "$srcdir" -o "$srcdir" = .; then
 414        confcmd=./configure
 415      else
 416        confcmd="$ac_abs_top_srcdir"/gst-libs/ext/libav/configure
 417      fi
 418
 419      AS_MKDIR_P(["$ac_top_build_prefix"gst-libs/ext/libav])
 420      cd "$ac_top_build_prefix"gst-libs/ext/libav &&
 421          eval "$confcmd $emblibav_configure_args" ||
 422          AC_MSG_ERROR([Failed to configure embedded Libav tree])
 423      cd "$origdir"
 424     ],
 425     [emblibav_configure_args="$emblibav_configure_args"])
 426   AC_MSG_NOTICE([Using included Libav code])
 427 fi
 428
 429 AC_SUBST(LIBAV_CFLAGS)
 430 AC_SUBST(LIBAV_DEPS)
 431 AC_SUBST(LIBAV_LIBS)
 432 AC_SUBST(LIBAV_SUBDIRS)
 433 AC_SUBST(SWSCALE_CFLAGS)
 434 AC_SUBST(SWSCALE_DEPS)
 435 AC_SUBST(SWSCALE_LIBS)
 436 AC_SUBST(WIN32_LIBS)
 437
 438 if test x$HAVE_LIBAV_UNINSTALLED = x1; then
 439   AC_DEFINE(HAVE_LIBAV_UNINSTALLED, [], [Defined if building against uninstalled Libav source])
 440 fi
 441 AM_CONDITIONAL(HAVE_LIBAV_UNINSTALLED, test x$HAVE_LIBAV_UNINSTALLED = x1)
 442
 443 AC_CONFIG_FILES(
 444 Makefile
 445 common/Makefile
 446 common/m4/Makefile
 447 gst-libav.spec
 448 ext/Makefile
 449 ext/libav/Makefile
 450 ext/libswscale/Makefile
 451 gst-libs/Makefile
 452 gst-libs/ext/Makefile
 453 docs/Makefile
 454 docs/plugins/Makefile
 455 docs/version.entities
 456 tests/Makefile
 457 tests/check/Makefile
 458 tests/files/Makefile
 459 pkgconfig/Makefile
 460 pkgconfig/gstreamer-plugins-libav-uninstalled.pc
 461 )
 462 AC_OUTPUT
 463
 464 ORC_OUTPUT