configure.ac

   1 AC_PREREQ([2.69])
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/pre
   8 AC_INIT([GStreamer Good Plug-ins],[1.13.0.1],[http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer],[gst-plugins-good])
   9
  10 AG_GST_INIT
  11
  12 dnl initialize automake
  13 AM_INIT_AUTOMAKE([-Wno-portability 1.14 no-dist-gzip dist-xz tar-ustar subdir-objects])
  14
  15 dnl define PACKAGE_VERSION_* variables
  16 AS_VERSION
  17
  18 dnl check if this is a release version
  19 AS_NANO(GST_GIT="no", GST_GIT="yes")
  20
  21 dnl can autoconf find the source ?
  22 AC_CONFIG_SRCDIR([gst/law/alaw.c])
  23
  24 dnl define the output header for config
  25 AC_CONFIG_HEADERS([config.h])
  26
  27 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  28 AM_MAINTAINER_MODE([enable])
  29
  30 dnl sets host_* variables
  31 AC_CANONICAL_HOST
  32
  33 dnl use pretty build output with automake >= 1.11
  34 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  35   [AM_DEFAULT_VERBOSITY=1
  36    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  37
  38 dnl our libraries and install dirs use GST_API_VERSION in the filename
  39 dnl to allow side-by-side installation of different API versions
  40 GST_API_VERSION=1.0
  41 AC_SUBST(GST_API_VERSION)
  42 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION",
  43   [GStreamer API Version])
  44
  45 AG_GST_LIBTOOL_PREPARE
  46 AS_LIBTOOL(GST, 1300, 0, 1300)
  47
  48 dnl *** required versions of GStreamer stuff ***
  49 GST_REQ=1.13.0.1
  50 GSTPB_REQ=1.13.0.1
  51
  52 dnl *** autotools stuff ****
  53
  54 dnl allow for different autotools
  55 AS_AUTOTOOLS_ALTERNATE
  56
  57 dnl Add parameters for aclocal
  58 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  59
  60 dnl set up gettext
  61 dnl the version check needs to stay here because autopoint greps for it
  62 AM_GNU_GETTEXT_VERSION([0.17])
  63 AM_GNU_GETTEXT([external])
  64 AG_GST_GETTEXT([gst-plugins-good-$GST_API_VERSION])
  65
  66 dnl *** check for arguments to configure ***
  67
  68 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  69 AG_GST_ARG_ENABLE_EXTRA_CHECKS
  70
  71 AG_GST_ARG_DEBUG
  72 AG_GST_ARG_PROFILING
  73 AG_GST_ARG_VALGRIND
  74 AG_GST_ARG_GCOV
  75
  76 AG_GST_ARG_EXAMPLES
  77
  78 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  79 AG_GST_ARG_WITH_PACKAGE_NAME
  80 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  81
  82 AG_GST_ARG_WITH_PLUGINS
  83
  84 AG_GST_ARG_ENABLE_EXTERNAL
  85
  86 AG_GST_ARG_ENABLE_EXPERIMENTAL
  87
  88 AG_GST_PKG_CONFIG_PATH
  89
  90 dnl *** checks for platform ***
  91
  92 dnl * hardware/architecture *
  93
  94 dnl common/m4/gst-arch.m4
  95 dnl check CPU type
  96 AG_GST_ARCH
  97
  98 dnl Determine endianness
  99 AC_C_BIGENDIAN
 100
 101 dnl *** checks for programs ***
 102
 103 dnl find a compiler
 104 AC_PROG_CC
 105 AC_PROG_CC_STDC
 106
 107 dnl determine c++ compiler
 108 AC_PROG_CXX
 109 dnl determine if c++ is available on this system
 110 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 111
 112 dnl determine c++ preprocessor
 113 dnl FIXME: do we need this ?
 114 AC_PROG_CXXCPP
 115
 116 AC_PROG_OBJC
 117
 118 dnl check if the compiler supports '-c' and '-o' options
 119 AM_PROG_CC_C_O
 120
 121 dnl find an assembler
 122 AM_PROG_AS
 123
 124 dnl check if the compiler supports do while(0) macros
 125 AG_GST_CHECK_DOWHILE_MACROS
 126
 127 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 128 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 129
 130 dnl check for documentation tools
 131 GTK_DOC_CHECK([1.12])
 132 AG_GST_PLUGIN_DOCS([1.12])
 133
 134 dnl *** checks for libraries ***
 135
 136 dnl check for libm, for sin()
 137 LT_LIB_M
 138 AC_SUBST(LIBM)
 139
 140 AC_CHECK_FUNCS(clock_gettime, [], [
 141   AC_CHECK_LIB(rt, clock_gettime, [
 142     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
 143     LIBRT="-lrt"
 144     AC_SUBST([LIBRT])
 145   ])
 146 ])
 147
 148 dnl check for pthreads
 149 AX_PTHREAD
 150
 151 dnl *** checks for header files ***
 152
 153 dnl check if we have ANSI C header files
 154 AC_HEADER_STDC
 155
 156 dnl used by ext/wavpack
 157 AX_CREATE_STDINT_H
 158
 159 dnl used in gst/udp
 160 AC_CHECK_HEADERS([sys/time.h])
 161
 162 dnl used in gst/udp
 163 AC_CHECK_HEADERS([sys/socket.h])
 164
 165 dnl *** checks for types/defines ***
 166
 167 dnl Check for FIONREAD ioctl declaration.  This check is needed
 168 dnl for the UDP plugin to build on Solaris
 169 GST_CHECK_FIONREAD
 170
 171 dnl *** checks for structures ***
 172
 173 dnl *** checks for compiler characteristics ***
 174
 175 dnl check if we have GCC inline-asm
 176 AS_GCC_INLINE_ASSEMBLY([HAVE_GCC_ASM=yes], [HAVE_GCC_ASM=no])
 177 if test x$HAVE_GCC_ASM = xyes ; then
 178   AC_DEFINE(HAVE_GCC_ASM, 1,
 179     [Define if compiler supports gcc inline assembly])
 180 fi
 181 AM_CONDITIONAL(HAVE_GCC_ASM, test "x$HAVE_GCC_ASM" = "xyes")
 182
 183 dnl *** checks for library functions ***
 184
 185 LIBS_SAVE=$LIBS
 186 LIBS="$LIBS $LIBM"
 187 AC_CHECK_FUNCS(rint sinh cosh asinh fpclass)
 188 LIBS=$LIBS_SAVE
 189
 190 dnl Check whether isinf() is defined by math.h
 191 AC_CACHE_CHECK([for isinf], ac_cv_have_isinf,
 192     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; int i=isinf(f)]])],[ac_cv_have_isinf="yes"],[ac_cv_have_isinf="no"]))
 193 if test "$ac_cv_have_isinf" = "yes"
 194 then
 195     AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have the `isinf' function.])
 196 fi
 197
 198 dnl Check for mmap (needed by electricfence plugin)
 199 AC_FUNC_MMAP
 200 AM_CONDITIONAL(GST_HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 201
 202 dnl Check for mmap (needed by electricfence plugin)
 203
 204 AC_CHECK_TYPE([struct ip_mreqn], [
 205               AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
 206               [#include <netinet/in.h>])
 207
 208 dnl *** checks for dependency libraries ***
 209
 210
 211 dnl GLib
 212 GLIB_REQ=2.40.0
 213 AG_GST_GLIB_CHECK([$GLIB_REQ])
 214
 215 dnl Orc
 216 ORC_CHECK([0.4.17])
 217
 218 dnl checks for gstreamer
 219 dnl uninstalled is selected preferentially -- see pkg-config(1)
 220 AG_GST_CHECK_GST($GST_API_VERSION, [$GST_REQ], yes)
 221 AG_GST_CHECK_GST_BASE($GST_API_VERSION, [$GST_REQ], yes)
 222 AG_GST_CHECK_GST_CONTROLLER($GST_API_VERSION, [$GST_REQ], yes)
 223 AG_GST_CHECK_GST_NET($GST_API_VERSION, [$GST_REQ], yes)
 224 AG_GST_CHECK_GST_CHECK($GST_API_VERSION, [$GST_REQ], no)
 225 AG_GST_CHECK_GST_PLUGINS_BASE($GST_API_VERSION, [$GSTPB_REQ], yes)
 226
 227 GST_TOOLS_DIR=`$PKG_CONFIG --variable=toolsdir gstreamer-$GST_API_VERSION`
 228 if test -z $GST_TOOLS_DIR; then
 229   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 230 fi
 231 AC_SUBST(GST_TOOLS_DIR)
 232
 233 AC_MSG_NOTICE(Using GStreamer Core Plugins in $GST_PLUGINS_DIR)
 234 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 235
 236 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 237
 238 dnl Check for documentation xrefs
 239 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 240 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_API_VERSION`"
 241 GSTPB_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-plugins-base-$GST_API_VERSION`"
 242 AC_SUBST(GLIB_PREFIX)
 243 AC_SUBST(GST_PREFIX)
 244 AC_SUBST(GSTPB_PREFIX)
 245
 246 dnl GTK is optional and used in examples
 247 HAVE_GTK=no
 248 GTK_REQ=3.0.0
 249 if test "x$BUILD_EXAMPLES" = "xyes"; then
 250   PKG_CHECK_MODULES(GTK, gtk+-3.0 >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 251   dnl some examples need gtk+-x11
 252   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-3.0 >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 253   AC_SUBST(GTK_LIBS)
 254   AC_SUBST(GTK_CFLAGS)
 255 fi
 256 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 257 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 258
 259 dnl Check for -Bsymbolic-functions linker flag used to avoid
 260 dnl intra-library PLT jumps, if available.
 261 AC_ARG_ENABLE(Bsymbolic,
 262               [AS_HELP_STRING([--disable-Bsymbolic],[avoid linking with -Bsymbolic])],,
 263               [SAVED_LDFLAGS="${LDFLAGS}" SAVED_LIBS="${LIBS}"
 264                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 265                LDFLAGS=-Wl,-Bsymbolic-functions
 266                LIBS=
 267                AC_TRY_LINK([], [return 0],
 268                            AC_MSG_RESULT(yes)
 269                            enable_Bsymbolic=yes,
 270                            AC_MSG_RESULT(no)
 271                            enable_Bsymbolic=no)
 272                LDFLAGS="${SAVED_LDFLAGS}" LIBS="${SAVED_LIBS}"])
 273
 274 dnl *** set variables based on configure arguments ***
 275
 276 dnl set license and copyright notice
 277 GST_LICENSE="LGPL"
 278 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 279 AC_SUBST(GST_LICENSE)
 280
 281 dnl set location of plugin directory
 282 AG_GST_SET_PLUGINDIR
 283
 284 dnl set release date/time
 285 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 286   ["${srcdir}/gst-plugins-good.doap"],
 287   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 288
 289 # set by AG_GST_PARSE_SUBSYSTEM_DISABLES above
 290 dnl make sure it doesn't complain about unused variables if debugging is disabled
 291 NO_WARNINGS=""
 292 AG_GST_CHECK_GST_DEBUG_DISABLED([NO_WARNINGS="-Wno-unused"], [NO_WARNINGS=""])
 293
 294 dnl define an ERROR_CFLAGS Makefile variable
 295 dnl -Wundef: too many broken headers
 296 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [
 297       -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 298       -Wwrite-strings -Wold-style-definition -Waggregate-return
 299       -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar
 300       -Wnested-externs $NO_WARNINGS])
 301
 302 dnl define an ERROR_CXXFLAGS Makefile variable
 303 AG_GST_SET_ERROR_CXXFLAGS($FATAL_WARNINGS, [
 304         -Wmissing-declarations -Wredundant-decls
 305         -Wwrite-strings
 306         -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar
 307         $NO_WARNINGS])
 308
 309 dnl define an ERROR_OBJCFLAGS Makefile variable
 310 AG_GST_SET_ERROR_OBJCFLAGS($FATAL_WARNINGS, [
 311       -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 312       -Wwrite-strings -Wold-style-definition
 313       -Winit-self -Wmissing-include-dirs -Wno-multichar
 314       -Wnested-externs $NO_WARNINGS])
 315
 316 dnl define correct level for debugging messages
 317 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 318
 319 dnl used in examples
 320 AG_GST_DEFAULT_ELEMENTS
 321
 322 dnl *** plug-ins to include ***
 323
 324 dnl these are all the gst plug-ins, compilable without additional libs
 325 dnl videofilter is at the top because others depend on it
 326 AG_GST_CHECK_PLUGIN(alpha)
 327 AG_GST_CHECK_PLUGIN(apetag)
 328 AG_GST_CHECK_PLUGIN(audiofx)
 329 AG_GST_CHECK_PLUGIN(audioparsers)
 330 AG_GST_CHECK_PLUGIN(auparse)
 331 AG_GST_CHECK_PLUGIN(autodetect)
 332 AG_GST_CHECK_PLUGIN(avi)
 333 AG_GST_CHECK_PLUGIN(cutter)
 334 AG_GST_CHECK_PLUGIN(debugutils)
 335 AG_GST_CHECK_PLUGIN(deinterlace)
 336 AG_GST_CHECK_PLUGIN(dtmf)
 337 AG_GST_CHECK_PLUGIN(effectv)
 338 AG_GST_CHECK_PLUGIN(equalizer)
 339 AG_GST_CHECK_PLUGIN(flv)
 340 AG_GST_CHECK_PLUGIN(flx)
 341 AG_GST_CHECK_PLUGIN(goom)
 342 AG_GST_CHECK_PLUGIN(goom2k1)
 343 AG_GST_CHECK_PLUGIN(icydemux)
 344 AG_GST_CHECK_PLUGIN(id3demux)
 345 AG_GST_CHECK_PLUGIN(imagefreeze)
 346 AG_GST_CHECK_PLUGIN(interleave)
 347 AG_GST_CHECK_PLUGIN(isomp4)
 348 AG_GST_CHECK_PLUGIN(law)
 349 AG_GST_CHECK_PLUGIN(level)
 350 AG_GST_CHECK_PLUGIN(matroska)
 351 AG_GST_CHECK_PLUGIN(monoscope)
 352 AG_GST_CHECK_PLUGIN(multifile)
 353 AG_GST_CHECK_PLUGIN(multipart)
 354 AG_GST_CHECK_PLUGIN(replaygain)
 355 AG_GST_CHECK_PLUGIN(rtp)
 356 AG_GST_CHECK_PLUGIN(rtpmanager)
 357 AG_GST_CHECK_PLUGIN(rtsp)
 358 AG_GST_CHECK_PLUGIN(shapewipe)
 359 AG_GST_CHECK_PLUGIN(smpte)
 360 AG_GST_CHECK_PLUGIN(spectrum)
 361 AG_GST_CHECK_PLUGIN(udp)
 362 AG_GST_CHECK_PLUGIN(videobox)
 363 AG_GST_CHECK_PLUGIN(videocrop)
 364 AG_GST_CHECK_PLUGIN(videofilter)
 365 AG_GST_CHECK_PLUGIN(videomixer)
 366 AG_GST_CHECK_PLUGIN(wavenc)
 367 AG_GST_CHECK_PLUGIN(wavparse)
 368 AG_GST_CHECK_PLUGIN(y4m)
 369
 370 dnl disable experimental plug-ins
 371 if test "x$BUILD_EXPERIMENTAL" != "xyes"; then
 372   AG_GST_DISABLE_PLUGIN(monoscope)
 373 fi
 374
 375 dnl *** sys plug-ins ***
 376
 377 echo
 378 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 379 echo
 380
 381 dnl DirectSound
 382 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECTSOUND, true)
 383 AG_GST_CHECK_FEATURE(DIRECTSOUND, [DirectSound plug-in], directsoundsink, [
 384   HAVE_DIRECTSOUND="no"
 385   save_CFLAGS="$CFLAGS"
 386   save_LDFLAGS="$LDFLAGS"
 387   save_LIBS="$LIBS"
 388   CFLAGS="$CFLAGS $DIRECTSOUND_CFLAGS"
 389   LDFLAGS="$LDFLAGS $DIRECTSOUND_LDFLAGS"
 390   LIBS="$LIBS -ldsound -ldxerr9 -luser32 -lole32"
 391   AC_MSG_CHECKING(for DirectSound LDFLAGS)
 392   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 393 #include <windows.h>
 394 #include <dxerr9.h>
 395 #include <dsound.h>
 396 ]], [[
 397   DXGetErrorString9 (0);
 398   DirectSoundCreate(NULL, NULL, NULL);
 399   CLSIDFromString(NULL, NULL);
 400 ]])
 401 ],
 402     [HAVE_DIRECTSOUND="yes"],
 403     [HAVE_DIRECTSOUND="no"])
 404   AC_MSG_RESULT($HAVE_DIRECTSOUND)
 405   CFLAGS=$save_CFLAGS
 406   LDFLAGS=$save_LDFLAGS
 407   LIBS=$save_LIBS
 408
 409   if test "x$HAVE_DIRECTSOUND" = "xyes";  then
 410     dnl this is much more than we want
 411     DIRECTSOUND_LIBS="-ldsound -ldxerr9 -luser32 -lole32"
 412     AC_SUBST(DIRECTSOUND_CFLAGS)
 413     AC_SUBST(DIRECTSOUND_LDFLAGS)
 414     AC_SUBST(DIRECTSOUND_LIBS)
 415   fi
 416   AC_SUBST(HAVE_DIRECTSOUND)
 417 ])
 418
 419 dnl *** Win32 WaveOut ***
 420 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVEFORM, true)
 421 AG_GST_CHECK_FEATURE(WAVEFORM, [Win32 WaveForm], waveformsink, [
 422   AC_CHECK_HEADER(mmsystem.h, HAVE_WAVEFORM="yes", HAVE_WAVEFORM="no", [#include <windows.h>])
 423 ])
 424
 425 dnl *** OSS audio *** (Linux, *BSD)
 426 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS, true)
 427 AG_GST_CHECK_FEATURE(OSS, [OSS audio], ossaudio, [
 428  HAVE_OSS="yes"
 429 dnl Linux and newer BSD versions :
 430  AC_CHECK_HEADER(sys/soundcard.h, [
 431    AC_DEFINE(HAVE_OSS_INCLUDE_IN_SYS,, [Define if OSS includes are in /sys/])
 432    ] , [
 433 dnl Some old BSD versions and also newer OpenBSD versions :
 434    AC_CHECK_HEADER(soundcard.h, [
 435      AC_DEFINE(HAVE_OSS_INCLUDE_IN_ROOT,, [Define if OSS includes are in /])
 436      ], [
 437   dnl Some old BSD versions :
 438      AC_CHECK_HEADER(machine/soundcard.h, [
 439        AC_DEFINE(HAVE_OSS_INCLUDE_IN_MACHINE,,
 440          [Define if OSS includes are in /machine/])
 441        ], [
 442        HAVE_OSS="no"
 443      ])
 444    ])
 445  ])
 446 ])
 447
 448 dnl *** oss4 ***
 449 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS4, true)
 450 AG_GST_CHECK_FEATURE(OSS4, [Open Sound System 4], oss4, [
 451   AC_MSG_CHECKING([Checking if we can build the OSS4 elements])
 452   AC_CHECK_HEADERS([fcntl.h sys/ioctl.h sys/stat.h sys/types.h],
 453       [test -z "$OSS4_MISSING_HEADER" && HAVE_OSS4="yes"],
 454       [OSS4_MISSING_HEADER="yes";HAVE_OSS4="no"])
 455 ])
 456
 457 dnl *** OSX Audio ***
 458 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_AUDIO, true)
 459 HAVE_IOS="no"
 460 AG_GST_CHECK_FEATURE(OSX_AUDIO, [OSX audio], osxaudio, [
 461   AC_CHECK_HEADER(CoreAudio/CoreAudio.h,
 462     [HAVE_OSX_AUDIO="yes"],
 463     [AC_CHECK_HEADER(CoreAudio/CoreAudioTypes.h,
 464     [
 465       HAVE_OSX_AUDIO="yes"
 466       HAVE_IOS="yes"
 467     ], [
 468       HAVE_OSX_AUDIO="no"
 469       HAVE_IOS="no"
 470     ])]
 471   )
 472 ])
 473 if test "x$HAVE_IOS" = "xyes"; then
 474   AC_DEFINE(HAVE_IOS, 1, [building for iOS platofrm])
 475 fi
 476 AM_CONDITIONAL(HAVE_IOS, test "x$HAVE_IOS" = "xyes")
 477
 478 dnl *** OS X video ***
 479 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_VIDEO, true)
 480 HAVE_OSX_VIDEO="no"
 481 AG_GST_CHECK_FEATURE(OSX_VIDEO, [OSX video], osxvideosink, [
 482   AC_CHECK_HEADER(OpenGL/gl.h, HAVE_OSX_VIDEO="yes", HAVE_OSX_VIDEO="no")
 483
 484   dnl in case header OpenGL/gl.h is found on other platforms (or older, unsupported OS X)
 485   dnl also require Snow Leopard or newer
 486
 487   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 488         #include <AvailabilityMacros.h>
 489         #if MAC_OS_X_VERSION_MIN_REQUIRED < 1060
 490         #error Too old OSX version
 491         #endif
 492       ]], [[return 0;]])],[HAVE_OSX_VIDEO="yes"],[HAVE_OSX_VIDEO="no"])
 493 ])
 494
 495 dnl *** Video 4 Linux 2 ***
 496 dnl renamed to GST_V4L2 because of some conflict with kernel headers
 497 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L2, true)
 498 HAVE_GST_V4L2=no
 499 AG_GST_CHECK_FEATURE(GST_V4L2, [Video 4 Linux 2], video4linux2, [
 500   AC_MSG_CHECKING([Checking for video4linux2 header ...])
 501   AC_CHECK_HEADER(linux/videodev2.h, [ HAVE_GST_V4L2=yes ],
 502   [
 503     AC_CHECK_HEADER(sys/videodev2.h, [ HAVE_GST_V4L2=yes ],
 504     [
 505       AC_CHECK_HEADER(sys/videoio.h, [ HAVE_GST_V4L2=yes ])
 506     ])
 507   ])
 508   if test "x$HAVE_VIDEODEV" = "xno"; then
 509      AC_MSG_WARN([video4linux2 was not found])
 510   fi
 511 ])
 512
 513 # Optional gudev for device probing
 514 AC_ARG_WITH([gudev],
 515   AS_HELP_STRING([--with-gudev],[device detection with gudev]),
 516   [],
 517   [with_gudev=check])
 518 if test x$HAVE_GST_V4L2 = xyes; then
 519   if test x$with_gudev != xno; then
 520     PKG_CHECK_MODULES(GUDEV, [ gudev-1.0 >= 147 ],
 521       [ AC_DEFINE(HAVE_GUDEV, 1,
 522           [Whether gudev is available for device detection])
 523       ],
 524       [true])
 525   fi
 526 fi
 527
 528 AC_SUBST(GUDEV_CFLAGS)
 529 AC_SUBST(GUDEV_LIBS)
 530
 531 # Make libv4l2 non-automagic
 532 AC_ARG_WITH([libv4l2],
 533   AS_HELP_STRING([--with-libv4l2],[support video buffer conversion using libv4l2]),
 534   [],
 535   [with_libv4l2=check])
 536 if test x$HAVE_GST_V4L2 = xyes; then
 537   if test x$with_libv4l2 != xno; then
 538       PKG_CHECK_MODULES(LIBV4L2, libv4l2,
 539           [ have_libv4l2=yes
 540             AC_DEFINE(HAVE_LIBV4L2, 1,
 541                 [Whether libv4l2 is available for video buffer conversion])
 542           ], [
 543           have_libv4l2=no
 544           ])
 545   else
 546     have_libv4l2=no
 547   fi
 548 fi
 549
 550 dnl Allow enabling v4l2 device probing
 551 AS_CASE([$host],
 552     [*-*linux*],
 553       [AS_CASE([$host_cpu],
 554         [arm*], [
 555           enable_v4l2_probe="yes"],
 556         [aarch64*], [
 557           enable_v4l2_probe="yes"])])
 558 AC_ARG_ENABLE(
 559   v4l2-probe,
 560   AC_HELP_STRING(
 561     [--enable-v4l2-probe],
 562     [enable V4L2 plugin to probe devices @<:@default=no@:>@]))
 563 if test "x$enable_v4l2_probe" = "xyes"; then
 564   AC_DEFINE(GST_V4L2_ENABLE_PROBE, 1,
 565     [Define if Video4Linux probe shall be run at plugin load])
 566 fi
 567
 568 dnl Check for X11
 569 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 570 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 571                   [ximagesrc], [
 572   PKG_CHECK_MODULES([X], [x11], [
 573     HAVE_X="yes"
 574     dnl check for Xfixes
 575     PKG_CHECK_MODULES([XFIXES], [ xfixes ], [
 576       AC_DEFINE(HAVE_XFIXES, 1, [Defined if Xfixes is available])
 577     ], [ HAVE_XFIXES="no" ])
 578
 579     dnl check for Xdamage
 580     PKG_CHECK_MODULES([XDAMAGE], [ xdamage ], [
 581       AC_DEFINE(HAVE_XDAMAGE, 1, [Defined if Xdamage is available])
 582     ], [ HAVE_XDAMAGE="no" ])
 583
 584     dnl check for X Shm
 585     PKG_CHECK_MODULES([XEXT], [ xext ], [
 586       AC_CHECK_LIB([Xext], [ XShmAttach ], [
 587         AC_DEFINE(HAVE_XSHM, 1, [Defined if XShm is available])
 588         XSHM_LIBS="$XEXT_LIBS"
 589         XSHM_CFLAGS="$XEXT_CFLAGS"
 590       ], [ HAVE_XEXT="no" ] , [ $X_LIBS ])
 591     ])
 592     AC_SUBST(XSHM_LIBS)
 593     AC_SUBST(XSHM_CFLAGS)
 594   ], [ HAVE_X="no" ])
 595 ])
 596
 597 dnl *** ext plug-ins ***
 598 dnl keep this list sorted alphabetically !
 599
 600 if test "x$BUILD_EXTERNAL" = "xyes"; then
 601
 602 echo
 603 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 604 echo
 605
 606 dnl *** aalib ***
 607 translit(dnm, m, l) AM_CONDITIONAL(USE_AALIB, true)
 608 AG_GST_CHECK_FEATURE(AALIB, [aalib ASCII Art library], aasink, [
 609   AM_PATH_AALIB(, HAVE_AALIB=yes, HAVE_AALIB=no)
 610 ])
 611
 612 dnl *** cairo ***
 613 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO, true)
 614 AG_GST_CHECK_FEATURE(CAIRO, [Cairo graphics rendering and gobject bindings], cairo, [
 615   AG_GST_PKG_CHECK_MODULES(CAIRO, cairo >= 1.10.0 cairo-gobject >= 1.10.0)
 616 ])
 617
 618 dnl *** FLAC ***
 619 translit(dnm, m, l) AM_CONDITIONAL(USE_FLAC, true)
 620 AG_GST_CHECK_FEATURE(FLAC, [FLAC lossless audio], flac, [
 621   AG_GST_PKG_CHECK_MODULES(FLAC, flac >= 1.1.4)
 622 ])
 623
 624 dnl *** GDK pixbuf ***
 625 translit(dnm, m, l) AM_CONDITIONAL(USE_GDK_PIXBUF, true)
 626 AG_GST_CHECK_FEATURE(GDK_PIXBUF, [GDK pixbuf], gdkpixbuf, [
 627   AG_GST_PKG_CHECK_MODULES(GDK_PIXBUF, gdk-pixbuf-2.0 >= 2.8.0)
 628 ])
 629
 630 dnl *** Jack ***
 631 translit(dnm, m, l) AM_CONDITIONAL(USE_JACK, true)
 632 AG_GST_CHECK_FEATURE(JACK, Jack, jack, [
 633   PKG_CHECK_MODULES(JACK, jack >= 0.99.10, HAVE_JACK="yes", HAVE_JACK="no")
 634   AC_SUBST(JACK_CFLAGS)
 635   AC_SUBST(JACK_LIBS)
 636
 637   AG_GST_PKG_CHECK_MODULES(JACK_0_120_1, jack >= 0.120.1 jack < 1.0)
 638   if test x$HAVE_JACK_0_120_1 = xyes; then
 639     AC_DEFINE(HAVE_JACK_0_120_1, 1, [defined if jack >= 0.120.1 is available])
 640   fi
 641   AG_GST_PKG_CHECK_MODULES(JACK_1_9_7, jack >= 1.9.7)
 642   if test x$HAVE_JACK_1_9_7 = xyes; then
 643     AC_DEFINE(HAVE_JACK_1_9_7, 1, [defined if jack >= 1.9.7 is available])
 644   fi
 645
 646 ])
 647
 648 dnl *** jpeg ***
 649 dnl FIXME: we could use header checks here as well IMO
 650 translit(dnm, m, l) AM_CONDITIONAL(USE_JPEG, true)
 651 AG_GST_CHECK_FEATURE(JPEG, [jpeg library], jpeg, [
 652   AC_ARG_WITH(jpeg-mmx,
 653     [  --with-jpeg-mmx, path to MMX'ified JPEG library])
 654   OLD_LIBS="$LIBS"
 655   if test x$with_jpeg_mmx != x; then
 656     LIBS="$LIBS -L$with_jpeg_mmx"
 657   fi
 658   AC_CHECK_LIB(jpeg-mmx, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 659   JPEG_LIBS="$LIBS -ljpeg-mmx"
 660   LIBS="$OLD_LIBS"
 661   if test x$HAVE_JPEG != xyes; then
 662     AC_CHECK_LIB(jpeg, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 663     JPEG_LIBS="-ljpeg"
 664   fi
 665   AC_SUBST(JPEG_LIBS)
 666 ])
 667
 668 dnl *** lame ***
 669 translit(dnm, m, l) AM_CONDITIONAL(USE_LAME, true)
 670 AG_GST_CHECK_FEATURE(LAME, [lame mp3 encoder library], lame, [
 671   AG_GST_CHECK_LIBHEADER(LAME, mp3lame, lame_init, $LIBM, lame/lame.h,
 672   [
 673     HAVE_LAME="yes"
 674     LAME_LIBS="-lmp3lame $LIBM"
 675     dnl is lame presets available
 676     LAME_CFLAGS=""
 677     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <lame/lame.h>]], [[ int preset = MEDIUM ]])],[LAME_CFLAGS="-DGSTLAME_PRESET"],[LAME_CFLAGS=""
 678     ])
 679     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <lame/lame.h>]], [[
 680         void *ptr = &lame_set_VBR_quality
 681       ]])],[LAME_CFLAGS="$LAME_CFLAGS -DHAVE_LAME_SET_VBR_QUALITY"],[LAME_CFLAGS="$LAME_CFLAGS"
 682     ])
 683   AC_SUBST(LAME_CFLAGS)
 684   AC_SUBST(LAME_LIBS)
 685   ])
 686 ])
 687
 688 dnl *** libcaca ***
 689 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBCACA, true)
 690 AG_GST_CHECK_FEATURE(LIBCACA, [libcaca coloured ASCII art], cacasink, [
 691   AG_GST_PKG_CHECK_MODULES(LIBCACA, caca)
 692 ])
 693
 694 dnl *** libdv ***
 695 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBDV, true)
 696 AG_GST_CHECK_FEATURE(LIBDV, [libdv DV demuxer/decoder], dv, [
 697   AG_GST_PKG_CHECK_MODULES(LIBDV, libdv >= 0.100)
 698 ])
 699
 700 dnl *** libpng ***
 701 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBPNG, true)
 702 AG_GST_CHECK_FEATURE(LIBPNG, [Portable Network Graphics library], png, [
 703   AG_GST_PKG_CHECK_MODULES(LIBPNG, libpng >= 1.2)
 704   if test $HAVE_LIBPNG = "yes"; then
 705     PKG_CHECK_MODULES(LIBPNG, libpng >= 1.5.1, [
 706         AC_DEFINE(HAVE_LIBPNG_1_5, 1, [Defined if libpng version is 1.5.1 or newer])
 707       ], [true])
 708   fi
 709 ])
 710
 711 dnl *** mpg123 ***
 712 translit(dnm, m, l) AM_CONDITIONAL(USE_MPG123, true)
 713 AG_GST_CHECK_FEATURE(MPG123, [mpg123 audio decoder], mpg123, [
 714   PKG_CHECK_MODULES(MPG123, libmpg123 >= 1.13, HAVE_MPG123="yes", HAVE_MPG123="no")
 715   AC_SUBST(MPG123_CFLAGS)
 716   AC_SUBST(MPG123_LIBS)
 717 ])
 718
 719 dnl *** pulseaudio ***
 720 translit(dnm, m, l) AM_CONDITIONAL(USE_PULSE, true)
 721 AG_GST_CHECK_FEATURE(PULSE, [pulseaudio plug-in], pulseaudio, [
 722
 723   dnl used in ext/pulse/pulseutil.c
 724   AC_CHECK_HEADERS([process.h])
 725
 726   AG_GST_PKG_CHECK_MODULES(PULSE, libpulse >= 2.0)
 727 ])
 728
 729 dnl *** dv1394 ***
 730 translit(dnm, m, l) AM_CONDITIONAL(USE_DV1394, true)
 731 AG_GST_CHECK_FEATURE(DV1394, [raw1394 and avc1394 library], 1394, [
 732   dnl first test for libraw1394 >= 2.0.0
 733   AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 2.0.0)
 734   AG_GST_PKG_CHECK_MODULES(LIBIEC61883, libiec61883 >= 1.0.0)
 735   dnl now see how far we got
 736   if test x$HAVE_RAW1394 = xyes && \
 737      test x$HAVE_LIBIEC61883 = xyes; then
 738        AG_GST_CHECK_LIBHEADER(AVC1394,
 739         avc1394, avc1394_send_command, $RAW1394_LIBS,
 740         libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 741        AG_GST_CHECK_LIBHEADER(ROM1394,
 742         rom1394, rom1394_free_directory, $RAW1394_LIBS,
 743         libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 744        if test x$HAVE_AVC1394 = xyes && \
 745           test x$HAVE_AVC1394 = xyes && \
 746           test x$HAVE_ROM1394 = xyes; then
 747           HAVE_DV1394=yes
 748           DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS $LIBIEC61883_LIBS"
 749           DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 750           AC_SUBST(DV1394_CFLAGS)
 751           AC_SUBST(DV1394_LIBS)
 752         fi
 753   else
 754        if test x$HAVE_RAW1394 = xno; then
 755           AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.1.0)
 756           AG_GST_CHECK_LIBHEADER(AVC1394,
 757            avc1394, avc1394_send_command, $RAW1394_LIBS,
 758            libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 759           AG_GST_CHECK_LIBHEADER(ROM1394,
 760            rom1394, rom1394_free_directory, $RAW1394_LIBS,
 761            libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 762           if test x$HAVE_RAW1394 = xyes && \
 763              test x$HAVE_AVC1394 = xyes && \
 764              test x$HAVE_ROM1394 = xyes; then
 765              HAVE_DV1394=yes
 766              DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS"
 767              DV1394_CFLAGS="$RAW1394_CFLAGS"
 768              if test x$HAVE_LIBIEC61883 = xyes; then
 769                DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 770                DV1394_LIBS="$DV1394_LIBS $LIBIEC61883_LIBS"
 771              fi
 772              AC_SUBST(DV1394_CFLAGS)
 773              AC_SUBST(DV1394_LIBS)
 774            fi
 775          fi
 776   fi
 777 ])
 778 AM_CONDITIONAL(USE_LIBIEC61883, [ test "x${HAVE_LIBIEC61883}" = xyes ] )
 779
 780 dnl *** shout2 ***
 781 translit(dnm, m, l) AM_CONDITIONAL(USE_SHOUT2, true)
 782 AG_GST_CHECK_FEATURE(SHOUT2, [Shoutcast/Icecast client library], shout2, [
 783   AG_GST_PKG_CHECK_MODULES(SHOUT2, shout >= 2.0)
 784 ])
 785
 786 dnl *** soup ***
 787 translit(dnm, m, l) AM_CONDITIONAL(USE_SOUP, true)
 788 AG_GST_CHECK_FEATURE(SOUP, [soup http client plugin (2.4)], souphttpsrc, [
 789   PKG_CHECK_MODULES(SOUP, libsoup-2.4 >= 2.48, [HAVE_SOUP="yes"], [HAVE_SOUP="no"])
 790   AC_SUBST(SOUP_CFLAGS)
 791   AC_SUBST(SOUP_LIBS)
 792 ])
 793
 794 dnl *** speex ***
 795 translit(dnm, m, l) AM_CONDITIONAL(USE_SPEEX, true)
 796 AG_GST_CHECK_FEATURE(SPEEX, [speex speech codec], speex, [
 797   AG_GST_PKG_CHECK_MODULES(SPEEX, speex >= 1.1.6)
 798 ])
 799
 800 dnl *** taglib ***
 801 translit(dnm, m, l) AM_CONDITIONAL(USE_TAGLIB, true)
 802 AG_GST_CHECK_FEATURE(TAGLIB, [taglib tagging library], taglib, [
 803   AG_GST_PKG_CHECK_MODULES(TAGLIB, taglib >= 1.5)
 804   if test "x$HAVE_CXX" != "xyes"; then
 805     USE_TAGLIB=false
 806     AC_MSG_NOTICE([Not building taglib plugin: no C++ compiler found])
 807   else
 808     dnl work around bug in taglib 1.5 headers, remove once there is a 1.6
 809     AS_CXX_COMPILER_FLAG([-Wno-attributes], [
 810         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS -Wno-attributes"
 811       ], [
 812         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS"
 813     ])
 814     AC_SUBST(TAGLIB_CXXFLAGS)
 815   fi
 816 ])
 817
 818 dnl *** twolame ***
 819 translit(dnm, m, l) AM_CONDITIONAL(USE_TWOLAME, true)
 820 AG_GST_CHECK_FEATURE(TWOLAME, [twolame], twolame, [
 821   PKG_CHECK_MODULES(TWOLAME, twolame >= 0.3.10, [
 822       HAVE_TWOLAME="yes"], [
 823       HAVE_TWOLAME="no"
 824   ])
 825   AC_SUBST(TWOLAME_CFLAGS)
 826   AC_SUBST(TWOLAME_LIBS)
 827 ])
 828
 829
 830 dnl *** vpx ***
 831 translit(dnm, m, l) AM_CONDITIONAL(USE_VPX, vpx)
 832 AG_GST_CHECK_FEATURE(VPX, [VPX decoder], vpx, [
 833   PKG_CHECK_MODULES(VPX, vpx >= 1.1.0, [HAVE_VPX="yes"], [HAVE_VPX="no"])
 834   HAVE_VP8=no
 835   HAVE_VP9=no
 836
 837   if test $HAVE_VPX = "yes"; then
 838     OLD_LIBS="$LIBS"
 839     OLD_CFLAGS="$CFLAGS"
 840     CFLAGS="$CFLAGS $VPX_CFLAGS"
 841     LIBS="$LIBS $VPX_LIBS"
 842     AC_CHECK_LIB(vpx, vpx_codec_vp8_cx_algo, [
 843       HAVE_VP8=yes
 844       AC_DEFINE(HAVE_VP8_ENCODER, 1, [Defined if the VP8 encoder is available])
 845     ])
 846     AC_CHECK_LIB(vpx, vpx_codec_vp8_dx_algo, [
 847       HAVE_VP8=yes
 848       AC_DEFINE(HAVE_VP8_DECODER, 1, [Defined if the VP8 decoder is available])
 849     ])
 850
 851     PKG_CHECK_MODULES(VPX_130, vpx >= 1.3.0, [
 852       AC_CHECK_LIB(vpx, vpx_codec_vp9_cx_algo, [
 853         HAVE_VP9=yes
 854         AC_DEFINE(HAVE_VP9_ENCODER, 1, [Defined if the VP9 encoder is available])
 855       ])
 856       AC_CHECK_LIB(vpx, vpx_codec_vp9_dx_algo, [
 857         HAVE_VP9=yes
 858         AC_DEFINE(HAVE_VP9_DECODER, 1, [Defined if the VP9 decoder is available])
 859       ])
 860     ], [true])
 861
 862     PKG_CHECK_MODULES(VPX_140, vpx >= 1.4.0, [
 863       AC_DEFINE(HAVE_VPX_1_4, 1, [Defined if the VPX library version is 1.4 or bigger])
 864     ], [true])
 865
 866     LIBS="$OLD_LIBS"
 867     CFLAGS="$OLD_CFLAGS"
 868   fi
 869   AC_SUBST(VPX_LIBS)
 870   AC_SUBST(VPX_CFLAGS)
 871 ])
 872
 873 dnl *** wavpack ***
 874 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVPACK, true)
 875 AG_GST_CHECK_FEATURE(WAVPACK, [wavpack plug-in], wavpack, [
 876   AG_GST_PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.60.0)
 877 ])
 878
 879 dnl *** qtdemux & matroska prefer to have zlib ***
 880 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 881 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for qtdemux/matroska],, [
 882   AG_GST_CHECK_LIBHEADER(ZLIB,
 883     z, uncompress,, zlib.h, [
 884     HAVE_ZLIB="yes"
 885     ZLIB_LIBS="-lz"
 886     AC_SUBST(ZLIB_LIBS)
 887   ])
 888 ])
 889
 890 dnl *** matroska prefers to have bz2 ***
 891 translit(dnm, m, l) AM_CONDITIONAL(USE_BZ2, true)
 892 AG_GST_CHECK_FEATURE(BZ2, [bz2 library for matroska ],, [
 893   save_LIBS=$LIBS
 894   LIBS="$LIBS -lbz2"
 895   AC_MSG_CHECKING([for BZ2_bzlibVersion in -lbz2])
 896   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <bzlib.h>]], [[const char *version = BZ2_bzlibVersion ();]])],[HAVE_BZ2=yes],[HAVE_BZ2=no])
 897   AC_MSG_RESULT($HAVE_BZ2)
 898   LIBS=$save_LIBS
 899   if test "x$HAVE_BZ2" = "xyes"; then
 900     BZ2_LIBS="-lbz2"
 901   fi
 902   AC_SUBST(BZ2_LIBS)
 903 ])
 904
 905 else
 906
 907 dnl not building plugins with external dependencies,
 908 dnl but we still need to set the conditionals
 909 AM_CONDITIONAL(USE_AALIB, false)
 910 AM_CONDITIONAL(USE_BZ2, false)
 911 AM_CONDITIONAL(USE_CAIRO, false)
 912 AM_CONDITIONAL(USE_DIRECTSOUND, false)
 913 AM_CONDITIONAL(USE_DV1394, false)
 914 AM_CONDITIONAL(USE_FLAC, false)
 915 AM_CONDITIONAL(USE_GDK_PIXBUF, false)
 916 AM_CONDITIONAL(USE_JACK, false)
 917 AM_CONDITIONAL(USE_JPEG, false)
 918 AM_CONDITIONAL(USE_LAME, false)
 919 AM_CONDITIONAL(USE_LIBCACA, false)
 920 AM_CONDITIONAL(USE_LIBDV, false)
 921 AM_CONDITIONAL(USE_LIBIEC61883, false)
 922 AM_CONDITIONAL(USE_LIBPNG, false)
 923 AM_CONDITIONAL(USE_MPG123, false)
 924 AM_CONDITIONAL(USE_OSS, false)
 925 AM_CONDITIONAL(USE_OSS4, false)
 926 AM_CONDITIONAL(USE_OSX_AUDIO, false)
 927 AM_CONDITIONAL(USE_OSX_VIDEO, false)
 928 AM_CONDITIONAL(USE_PULSE, false)
 929 AM_CONDITIONAL(USE_SHOUT2, false)
 930 AM_CONDITIONAL(USE_SOUP, false)
 931 AM_CONDITIONAL(USE_SPEEX, false)
 932 AM_CONDITIONAL(USE_TAGLIB, false)
 933 AM_CONDITIONAL(USE_TWOLAME, false)
 934 AM_CONDITIONAL(USE_VPX, false)
 935 AM_CONDITIONAL(USE_WAVEFORM, false)
 936 AM_CONDITIONAL(USE_WAVPACK, false)
 937 AM_CONDITIONAL(USE_X, false)
 938 AM_CONDITIONAL(USE_ZLIB, false)
 939
 940 fi dnl of EXT plugins
 941
 942 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 943
 944 dnl Overview:
 945 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 946 dnl GST_*:              flags shared by all built objects
 947 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 948 dnl GST_LIB_LDFLAGS:    not needed, we don't install libraries
 949 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 950 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 951
 952 dnl GST_OPTION_CFLAGS
 953 if test "x$USE_DEBUG" = xyes; then
 954    PROFILE_CFLAGS="-g"
 955 fi
 956 AC_SUBST(PROFILE_CFLAGS)
 957
 958 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 959   dnl Define _only_ for git (not pre-releases or releases)
 960   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 961 else
 962   DEPRECATED_CFLAGS=""
 963 fi
 964 AC_SUBST(DEPRECATED_CFLAGS)
 965
 966 dnl every flag in GST_OPTION_CFLAGS, GST_OPTION_CXXFLAGS and GST_OPTION_OBJCFLAGS can be overridden
 967 dnl at make time with e.g. make ERROR_CFLAGS=""
 968 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 969 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 970 GST_OPTION_OBJCFLAGS="\$(WARNING_OBJCFLAGS) \$(ERROR_OBJCFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 971 AC_SUBST(GST_OPTION_CFLAGS)
 972 AC_SUBST(GST_OPTION_CXXFLAGS)
 973 AC_SUBST(GST_OPTION_OBJCFLAGS)
 974
 975 dnl our libraries need to be versioned correctly
 976 AC_SUBST(GST_LT_LDFLAGS)
 977
 978 dnl FIXME: do we want to rename to GST_ALL_* ?
 979 dnl prefer internal headers to already installed ones
 980 dnl also add builddir include for enumtypes and marshal
 981 dnl add ERROR_CFLAGS, but overridable
 982 GST_CFLAGS="$GST_CFLAGS -DGST_USE_UNSTABLE_API"
 983 GST_CXXFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CXXFLAGS)"
 984 GST_OBJCFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_OBJCFLAGS)"
 985 GST_CFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CFLAGS)"
 986 AC_SUBST(GST_CFLAGS)
 987 AC_SUBST(GST_CXXFLAGS)
 988 AC_SUBST(GST_OBJCFLAGS)
 989 AC_SUBST(GST_LIBS)
 990
 991 dnl LDFLAGS really should only contain flags, not libs - they get added before
 992 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 993 GST_ALL_LDFLAGS="-no-undefined"
 994 if test "x${enable_Bsymbolic}" = "xyes"; then
 995   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
 996 fi
 997 AC_SUBST(GST_ALL_LDFLAGS)
 998
 999 dnl this really should only contain flags, not libs - they get added before
1000 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1001 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_.*' $GST_ALL_LDFLAGS"
1002 AC_SUBST(GST_PLUGIN_LDFLAGS)
1003
1004 dnl *** output files ***
1005
1006 $MKDIR_P tests/check/orc
1007
1008 dnl keep this alphabetic per directory, please
1009 AC_CONFIG_FILES(
1010 Makefile
1011 gst/Makefile
1012 gst/alpha/Makefile
1013 gst/apetag/Makefile
1014 gst/audiofx/Makefile
1015 gst/audioparsers/Makefile
1016 gst/auparse/Makefile
1017 gst/autodetect/Makefile
1018 gst/avi/Makefile
1019 gst/cutter/Makefile
1020 gst/deinterlace/Makefile
1021 gst/dtmf/Makefile
1022 gst/debugutils/Makefile
1023 gst/effectv/Makefile
1024 gst/equalizer/Makefile
1025 gst/flv/Makefile
1026 gst/goom/Makefile
1027 gst/goom2k1/Makefile
1028 gst/id3demux/Makefile
1029 gst/icydemux/Makefile
1030 gst/imagefreeze/Makefile
1031 gst/interleave/Makefile
1032 gst/isomp4/Makefile
1033 gst/law/Makefile
1034 gst/level/Makefile
1035 gst/matroska/Makefile
1036 gst/monoscope/Makefile
1037 gst/multifile/Makefile
1038 gst/multipart/Makefile
1039 gst/replaygain/Makefile
1040 gst/rtp/Makefile
1041 gst/rtpmanager/Makefile
1042 gst/rtsp/Makefile
1043 gst/shapewipe/Makefile
1044 gst/smpte/Makefile
1045 gst/spectrum/Makefile
1046 gst/udp/Makefile
1047 gst/videobox/Makefile
1048 gst/videocrop/Makefile
1049 gst/videofilter/Makefile
1050 gst/videomixer/Makefile
1051 gst/wavenc/Makefile
1052 gst/wavparse/Makefile
1053 gst/flx/Makefile
1054 gst/y4m/Makefile
1055 ext/Makefile
1056 ext/aalib/Makefile
1057 ext/cairo/Makefile
1058 ext/dv/Makefile
1059 ext/flac/Makefile
1060 ext/gdk_pixbuf/Makefile
1061 ext/jack/Makefile
1062 ext/jpeg/Makefile
1063 ext/lame/Makefile
1064 ext/libcaca/Makefile
1065 ext/libpng/Makefile
1066 ext/mpg123/Makefile
1067 ext/pulse/Makefile
1068 ext/raw1394/Makefile
1069 ext/shout2/Makefile
1070 ext/soup/Makefile
1071 ext/speex/Makefile
1072 ext/taglib/Makefile
1073 ext/twolame/Makefile
1074 ext/vpx/Makefile
1075 ext/wavpack/Makefile
1076 sys/Makefile
1077 sys/directsound/Makefile
1078 sys/oss/Makefile
1079 sys/oss4/Makefile
1080 sys/osxaudio/Makefile
1081 sys/osxvideo/Makefile
1082 sys/v4l2/Makefile
1083 sys/waveform/Makefile
1084 sys/ximage/Makefile
1085 po/Makefile.in
1086 tests/Makefile
1087 tests/check/Makefile
1088 tests/examples/Makefile
1089 tests/examples/audiofx/Makefile
1090 tests/examples/cairo/Makefile
1091 tests/examples/equalizer/Makefile
1092 tests/examples/jack/Makefile
1093 tests/examples/level/Makefile
1094 tests/examples/rtp/Makefile
1095 tests/examples/shapewipe/Makefile
1096 tests/examples/spectrum/Makefile
1097 tests/examples/v4l2/Makefile
1098 tests/files/Makefile
1099 tests/icles/Makefile
1100 common/Makefile
1101 common/m4/Makefile
1102 m4/Makefile
1103 docs/Makefile
1104 docs/plugins/Makefile
1105 docs/version.entities
1106 pkgconfig/Makefile
1107 pkgconfig/gstreamer-plugins-good-uninstalled.pc
1108 )
1109 AC_OUTPUT
1110
1111 AG_GST_OUTPUT_PLUGINS
1112 ORC_OUTPUT
1113