configure.ac

   1
   2 AC_INIT(openconnect, 3.13)
   3 PKG_PROG_PKG_CONFIG
   4 AC_LANG_C
   5 AM_MAINTAINER_MODE([enable])
   6 AM_INIT_AUTOMAKE([foreign])
   7 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
   8
   9 # Black magic: putting this before the conditional IT_PROG_LIBTOOL below
  10 # seems to avoid complaints about AMDEP being conditionally defined.
  11 AC_PROG_LIBTOOL
  12
  13 # Ick. IT_PROG_INTLTOOL isn't capable of doing this for itself? And hell,
  14 # we don't even *need* intltool for a build-from-tarball on most systems,
  15 # do we? But to avoid a whole chain of dependencies, we need it to be
  16 # optional.
  17 AC_PATH_PROG(INTLTOOL_UPDATE, [intltool-update])
  18 AC_PATH_PROG(INTLTOOL_MERGE, [intltool-merge])
  19 AC_PATH_PROG(INTLTOOL_EXTRACT, [intltool-extract])
  20 if test -z "$INTLTOOL_UPDATE" -o -z "$INTLTOOL_MERGE" -o -z "$INTLTOOL_EXTRACT"; then
  21     AC_MSG_NOTICE([The intltool scripts were not found. Disabling NLS.])
  22     USE_NLS=no
  23 else
  24     IT_PROG_INTLTOOL
  25 fi
  26
  27 AC_SUBST(GETTEXT_PACKAGE, [openconnect])
  28 AM_CONDITIONAL(USE_NLS, [test "$USE_NLS" = "yes"])
  29 if (test "$USE_NLS" = "yes"); then
  30    AC_DEFINE(ENABLE_NLS, 1)
  31 fi
  32
  33 AS_COMPILER_FLAGS(CFLAGS,
  34         "-Wall
  35          -Wextra
  36          -Wno-missing-field-initializers
  37          -Wno-sign-compare
  38          -Wno-unused-parameter
  39          -Werror=pointer-to-int-cast
  40          -Wdeclaration-after-statement
  41          -Werror-implicit-function-declaration
  42          -Wformat-nonliteral
  43          -Wformat-security
  44          -Winit-self
  45          -Wmissing-declarations
  46          -Wmissing-include-dirs
  47          -Wnested-externs
  48          -Wpointer-arith
  49          -Wwrite-strings")
  50
  51 AC_ARG_WITH([openssl],
  52             AS_HELP_STRING([--with-openssl],
  53                            [Location of OpenSSL build dir]),
  54             [OPENSSL_CFLAGS="-I${with_openssl}/include"
  55              OPENSSL_LIBS="${with_openssl}/libssl.a ${with_openssl}/libcrypto.a -ldl -lz"
  56              AC_SUBST(OPENSSL_CFLAGS)
  57              AC_SUBST(OPENSSL_LIBS)
  58              AC_ENABLE_STATIC
  59              AC_DISABLE_SHARED],
  60             [PKG_CHECK_MODULES(OPENSSL, openssl)
  61              AC_ENABLE_SHARED
  62              AC_DISABLE_STATIC])
  63
  64 AC_PROG_LIBTOOL
  65
  66 PKG_CHECK_MODULES(LIBXML2, libxml-2.0)
  67 PKG_CHECK_MODULES(ZLIB, zlib)
  68
  69 PKG_CHECK_MODULES(LIBPROXY, libproxy-1.0,
  70                 [AC_SUBST(LIBPROXY_PC, libproxy-1.0)
  71                  AC_DEFINE([LIBPROXY_HDR], ["proxy.h"])
  72                  libproxy_pkg=yes],
  73                  libproxy_pkg=no)
  74 dnl Libproxy *can* exist without a .pc file, and its header may be called
  75 dnl libproxy.h in that case.
  76 if (test "$libproxy_pkg" = "no"); then
  77    AC_CHECK_HEADER([proxy.h],
  78         [AC_DEFINE([LIBPROXY_HDR], ["proxy.h"])
  79          AC_SUBST([LIBPROXY_LIBS], [-lproxy])],
  80     [AC_CHECK_HEADER([libproxy.h],
  81         [AC_DEFINE([LIBPROXY_HDR], ["libproxy.h"])
  82          AC_SUBST([LIBPROXY_LIBS], [-lproxy])])])
  83 fi
  84
  85 AC_CHECK_HEADER([if_tun.h],
  86     [AC_DEFINE([IF_TUN_HDR], ["if_tun.h"])],
  87     [AC_CHECK_HEADER([linux/if_tun.h],
  88         [AC_DEFINE([IF_TUN_HDR], ["linux/if_tun.h"])],
  89         [AC_CHECK_HEADER([net/if_tun.h],
  90             [AC_DEFINE([IF_TUN_HDR], ["net/if_tun.h"])],
  91             [AC_CHECK_HEADER([net/tun/if_tun.h],
  92                 [AC_DEFINE([IF_TUN_HDR], ["net/tun/if_tun.h"])])])])])
  93
  94 AC_CHECK_LIB(ssl, ENGINE_by_id,
  95              AC_DEFINE(HAVE_ENGINE, [1], [OpenSSL has ENGINE support]),
  96              AC_MSG_NOTICE([Building without OpenSSL TPM ENGINE support]),
  97              ${OPENSSL_LIBS})
  98
  99 AC_CHECK_LIB(ssl, dtls1_stop_timer,
 100                   AC_DEFINE(HAVE_DTLS1_STOP_TIMER, [1], [OpenSSL has dtls1_stop_timer() function]),
 101                   ,,${OPENSSL_LIBS})
 102
 103 AC_PATH_PROG(PYTHON, [python], [], $PATH:/bin:/usr/bin)
 104 if (test -n "${ac_cv_path_PYTHON}"); then
 105    AC_SUBST(PYTHON, ${ac_cv_path_PYTHON})
 106 else
 107    AC_MSG_NOTICE([Python not found; not building HTML pages])
 108 fi
 109 AM_CONDITIONAL(BUILD_WWW, [test -n "${ac_cv_path_PYTHON}"])
 110
 111 AC_OUTPUT(Makefile openconnect.pc po/Makefile.in www/Makefile \
 112           www/styles/Makefile www/inc/Makefile www/images/Makefile)