configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Configure input file for elfutils.                     -*-autoconf-*-
   3 dnl
   4 dnl Copyright (C) 1996-2017 Red Hat, Inc.
   5 dnl
   6 dnl This file is part of elfutils.
   7 dnl
   8 dnl  This file is free software; you can redistribute it and/or modify
   9 dnl  it under the terms of the GNU General Public License as published by
  10 dnl  the Free Software Foundation; either version 3 of the License, or
  11 dnl  (at your option) any later version.
  12 dnl
  13 dnl  elfutils is distributed in the hope that it will be useful, but
  14 dnl  WITHOUT ANY WARRANTY; without even the implied warranty of
  15 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 dnl  GNU General Public License for more details.
  17 dnl
  18 dnl  You should have received a copy of the GNU General Public License
  19 dnl  along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20 AC_INIT([elfutils],[0.170],[https://sourceware.org/bugzilla],[elfutils],[http://elfutils.org/])
  21
  22 dnl Workaround for older autoconf < 2.64
  23 m4_ifndef([AC_PACKAGE_URL],
  24          [AC_DEFINE([PACKAGE_URL], ["http://elfutils.org/"],
  25                     [Define to home page for this package])
  26           AC_SUBST([PACKAGE_URL], ["http://elfutils.org/"])])
  27
  28 # We want eu- as default program prefix if none was given by the user.
  29 # But if the user explicitly provided --program-prefix="" then pretend
  30 # it wasn't set at all (NONE). We want to test this really early before
  31 # configure has a chance to use the value.
  32
  33 if test "x$program_prefix" = "xNONE"; then
  34   AC_MSG_NOTICE([No --program-prefix given, using "eu-"])
  35   program_prefix="eu-"
  36 elif test "x$program_prefix" = "x"; then
  37   AC_MSG_NOTICE([Using no program-prefix])
  38   program_prefix=NONE
  39 fi
  40
  41 AC_CONFIG_AUX_DIR([config])
  42 AC_CONFIG_FILES([config/Makefile])
  43
  44 AC_COPYRIGHT([Copyright (C) 1996-2017 The elfutils developers.])
  45 AC_PREREQ(2.63)                 dnl Minimum Autoconf version required.
  46
  47 dnl We use GNU make extensions; automake 1.10 defaults to -Wportability.
  48 AM_INIT_AUTOMAKE([gnits 1.11 -Wno-portability dist-bzip2 no-dist-gzip parallel-tests])
  49 AM_MAINTAINER_MODE
  50
  51 AM_SILENT_RULES([yes])
  52
  53 AC_CONFIG_SRCDIR([libelf/libelf.h])
  54 AC_CONFIG_FILES([Makefile])
  55 AC_CONFIG_HEADERS([config.h])
  56
  57 AC_CONFIG_MACRO_DIR([m4])
  58 AC_CONFIG_FILES([m4/Makefile])
  59
  60 dnl The RPM spec file.  We substitute a few values in the file.
  61 AC_CONFIG_FILES([elfutils.spec:config/elfutils.spec.in])
  62
  63
  64 AC_CANONICAL_HOST
  65
  66 AC_ARG_ENABLE(deterministic-archives,
  67 [AS_HELP_STRING([--enable-deterministic-archives],
  68                 [ar and ranlib default to -D behavior])], [
  69 if test "${enableval}" = no; then
  70   default_ar_deterministic=false
  71 else
  72   default_ar_deterministic=true
  73 fi], [default_ar_deterministic=false])
  74 AC_DEFINE_UNQUOTED(DEFAULT_AR_DETERMINISTIC, $default_ar_deterministic,
  75                    [Should ar and ranlib use -D behavior by default?])
  76
  77 AC_ARG_ENABLE([thread-safety],
  78 AS_HELP_STRING([--enable-thread-safety],
  79                [enable thread safety of libraries EXPERIMENTAL]),
  80                use_locks=$enableval, use_locks=no)
  81 AM_CONDITIONAL(USE_LOCKS, test "$use_locks" = yes)
  82 AS_IF([test "$use_locks" = yes], [AC_DEFINE(USE_LOCKS)])
  83 AS_IF([test "$use_locks" = yes],
  84       [AC_MSG_WARN([thread-safety is EXPERIMENTAL tests might fail.])])
  85
  86 AH_TEMPLATE([USE_LOCKS], [Defined if libraries should be thread-safe.])
  87
  88 AC_PROG_CC
  89 AC_PROG_RANLIB
  90 AC_PROG_YACC
  91 AM_PROG_LEX
  92 # Only available since automake 1.12
  93 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  94 AC_CHECK_TOOL([READELF], [readelf])
  95 AC_CHECK_TOOL([NM], [nm])
  96
  97 # We use -std=gnu99 but have explicit checks for some language constructs
  98 # and GNU extensions since some compilers claim GNU99 support, but don't
  99 # really support all language extensions. In particular we need
 100 # Mixed Declarations and Code
 101 # https://gcc.gnu.org/onlinedocs/gcc/Mixed-Declarations.html
 102 # Nested Functions
 103 # https://gcc.gnu.org/onlinedocs/gcc/Nested-Functions.html
 104 # Arrays of Variable Length
 105 # https://gcc.gnu.org/onlinedocs/gcc/Variable-Length.html
 106 AC_CACHE_CHECK([for gcc with GNU99 support], ac_cv_c99, [dnl
 107 old_CFLAGS="$CFLAGS"
 108 CFLAGS="$CFLAGS -std=gnu99"
 109 AC_COMPILE_IFELSE([AC_LANG_SOURCE([dnl
 110 int foo (int a)
 111 {
 112   for (int i = 0; i < a; ++i) if (i % 4) break; int s = a; return s;
 113 }
 114
 115 double bar (double a, double b)
 116 {
 117   double square (double z) { return z * z; }
 118   return square (a) + square (b);
 119 }
 120
 121 void baz (int n)
 122 {
 123   struct S { int x[[n]]; };
 124 }])],
 125                   ac_cv_c99=yes, ac_cv_c99=no)
 126 CFLAGS="$old_CFLAGS"])
 127 AS_IF([test "x$ac_cv_c99" != xyes],
 128       AC_MSG_ERROR([gcc with GNU99 support required]))
 129
 130 AC_CACHE_CHECK([whether gcc supports __attribute__((visibility()))],
 131         ac_cv_visibility, [dnl
 132 save_CFLAGS="$CFLAGS"
 133 CFLAGS="$save_CFLAGS -Werror"
 134 AC_COMPILE_IFELSE([AC_LANG_SOURCE([dnl
 135 int __attribute__((visibility("hidden")))
 136 foo (int a)
 137 {
 138   return a;
 139 }])], ac_cv_visibility=yes, ac_cv_visibility=no)
 140 CFLAGS="$save_CFLAGS"])
 141 if test "$ac_cv_visibility" = "yes"; then
 142         AC_DEFINE([HAVE_VISIBILITY], [1],
 143                   [Defined if __attribute__((visibility())) is supported])
 144 fi
 145
 146 AC_CACHE_CHECK([whether gcc supports __attribute__((gcc_struct))],
 147         ac_cv_gcc_struct, [dnl
 148 save_CFLAGS="$CFLAGS"
 149 CFLAGS="$save_CFLAGS -Werror"
 150 AC_COMPILE_IFELSE([AC_LANG_SOURCE([dnl
 151 struct test { int x; } __attribute__((gcc_struct));
 152 ])], ac_cv_gcc_struct=yes, ac_cv_gcc_struct=no)
 153 CFLAGS="$save_CFLAGS"])
 154 if test "$ac_cv_gcc_struct" = "yes"; then
 155         AC_DEFINE([HAVE_GCC_STRUCT], [1],
 156                   [Defined if __attribute__((gcc_struct)) is supported])
 157 fi
 158
 159 AC_CACHE_CHECK([whether gcc supports -fPIC], ac_cv_fpic, [dnl
 160 save_CFLAGS="$CFLAGS"
 161 CFLAGS="$save_CFLAGS -fPIC -Werror"
 162 AC_COMPILE_IFELSE([AC_LANG_SOURCE()], ac_cv_fpic=yes, ac_cv_fpic=no)
 163 CFLAGS="$save_CFLAGS"
 164 ])
 165 if test "$ac_cv_fpic" = "yes"; then
 166         fpic_CFLAGS="-fPIC"
 167 else
 168         fpic_CFLAGS=""
 169 fi
 170 AC_SUBST([fpic_CFLAGS])
 171
 172 AC_CACHE_CHECK([whether gcc supports -fPIE], ac_cv_fpie, [dnl
 173 save_CFLAGS="$CFLAGS"
 174 CFLAGS="$save_CFLAGS -fPIE -Werror"
 175 AC_COMPILE_IFELSE([AC_LANG_SOURCE()], ac_cv_fpie=yes, ac_cv_fpie=no)
 176 CFLAGS="$save_CFLAGS"
 177 ])
 178 if test "$ac_cv_fpie" = "yes"; then
 179         fpie_CFLAGS="-fPIE"
 180 else
 181         fpie_CFLAGS=""
 182 fi
 183 AC_SUBST([fpie_CFLAGS])
 184
 185 dso_LDFLAGS="-shared"
 186
 187 ZDEFS_LDFLAGS="-Wl,-z,defs"
 188 AC_CACHE_CHECK([whether gcc supports $ZDEFS_LDFLAGS], ac_cv_zdefs, [dnl
 189 save_LDFLAGS="$LDFLAGS"
 190 LDFLAGS="$ZDEFS_LDFLAGS $save_LDFLAGS"
 191 AC_LINK_IFELSE([AC_LANG_PROGRAM()], ac_cv_zdefs=yes, ac_cv_zdefs=no)
 192 LDFLAGS="$save_LDFLAGS"
 193 ])
 194 if test "$ac_cv_zdefs" = "yes"; then
 195         dso_LDFLAGS="$dso_LDFLAGS $ZDEFS_LDFLAGS"
 196 fi
 197
 198 ZRELRO_LDFLAGS="-Wl,-z,relro"
 199 AC_CACHE_CHECK([whether gcc supports $ZRELRO_LDFLAGS], ac_cv_zrelro, [dnl
 200 save_LDFLAGS="$LDFLAGS"
 201 LDFLAGS="$ZRELRO_LDFLAGS $save_LDFLAGS"
 202 AC_LINK_IFELSE([AC_LANG_PROGRAM()], ac_cv_zrelro=yes, ac_cv_zrelro=no)
 203 LDFLAGS="$save_LDFLAGS"
 204 ])
 205 if test "$ac_cv_zrelro" = "yes"; then
 206         dso_LDFLAGS="$dso_LDFLAGS $ZRELRO_LDFLAGS"
 207 fi
 208
 209 AC_SUBST([dso_LDFLAGS])
 210
 211 AC_CACHE_CHECK([for __thread support], ac_cv_tls, [dnl
 212 # Use the same flags that we use for our DSOs, so the test is representative.
 213 # Some old compiler/linker/libc combinations fail some ways and not others.
 214 save_CFLAGS="$CFLAGS"
 215 save_LDFLAGS="$LDFLAGS"
 216 CFLAGS="$fpic_CFLAGS $CFLAGS"
 217 LDFLAGS="$dso_LDFLAGS $LDFLAGS"
 218 AC_LINK_IFELSE([dnl
 219 AC_LANG_PROGRAM([[#include <stdlib.h>
 220 #undef __thread
 221 static __thread int a; int foo (int b) { return a + b; }]],
 222                 [[exit (foo (0));]])],
 223                ac_cv_tls=yes, ac_cv_tls=no)
 224 CFLAGS="$save_CFLAGS"
 225 LDFLAGS="$save_LDFLAGS"])
 226 AS_IF([test "x$ac_cv_tls" != xyes],
 227       AC_MSG_ERROR([__thread support required]))
 228
 229 dnl This test must come as early as possible after the compiler configuration
 230 dnl tests, because the choice of the file model can (in principle) affect
 231 dnl whether functions and headers are available, whether they work, etc.
 232 AC_SYS_LARGEFILE
 233
 234 dnl Older glibc had a broken fts that didn't work with Large File Systems.
 235 dnl We want the version that can handler LFS, but include workaround if we
 236 dnl get a bad one. Add define to CFLAGS (not AC_DEFINE it) since we need to
 237 dnl check it before including config.h (which might define _FILE_OFFSET_BITS).
 238 AC_CACHE_CHECK([whether fts.h is bad when included (with LFS)], ac_cv_bad_fts,
 239   [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[#include <fts.h>]])],
 240                      ac_cv_bad_fts=no, ac_cv_bad_fts=yes)])
 241 AS_IF([test "x$ac_cv_bad_fts" = "xyes"], [CFLAGS="$CFLAGS -DBAD_FTS=1"])
 242
 243 # See if we can add -D_FORTIFY_SOURCE=2. Don't do it if it is already
 244 # (differently) defined or if it generates warnings/errors because we
 245 # don't use the right optimisation level (string.h will warn about that).
 246 AC_MSG_CHECKING([whether to add -D_FORTIFY_SOURCE=2 to CFLAGS])
 247 case "$CFLAGS" in
 248   *-D_FORTIFY_SOURCE=2*)
 249     AC_MSG_RESULT([no, already there])
 250     ;;
 251   *)
 252     save_CFLAGS="$CFLAGS"
 253     CFLAGS="-D_FORTIFY_SOURCE=2 -Werror $CFLAGS"
 254     AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 255       #include <string.h>
 256       int main() { return 0; }
 257     ]])], [ AC_MSG_RESULT([yes])
 258             CFLAGS="-D_FORTIFY_SOURCE=2 $save_CFLAGS" ],
 259           [ AC_MSG_RESULT([no])
 260             CFLAGS="$save_CFLAGS"])
 261   ;;
 262 esac
 263
 264 dnl enable debugging of branch prediction.
 265 AC_ARG_ENABLE([debugpred],
 266 AS_HELP_STRING([--enable-debugpred],[build binaries with support to debug branch prediction]),
 267 [use_debugpred=$enableval], [use_debugpred=no])
 268 case $use_debugpred in
 269  yes) use_debugpred_val=1 ;;
 270  *)   use_debugpred_val=0 ;;
 271 esac
 272 AC_SUBST([DEBUGPRED], $use_debugpred_val)
 273
 274 dnl Enable gprof suport.
 275 AC_ARG_ENABLE([gprof],
 276 AS_HELP_STRING([--enable-gprof],[build binaries with gprof support]), [use_gprof=$enableval], [use_gprof=no])
 277 if test "$use_gprof" = yes; then
 278   CFLAGS="$CFLAGS -pg"
 279   LDFLAGS="$LDFLAGS -pg"
 280 fi
 281 AM_CONDITIONAL(GPROF, test "$use_gprof" = yes)
 282
 283 # Enable gcov suport.
 284 AC_ARG_ENABLE([gcov],
 285 AS_HELP_STRING([--enable-gcov],[build binaries with gcov support]), [use_gcov=$enableval], [use_gcov=no])
 286 if test "$use_gcov" = yes; then
 287   CFLAGS="$CFLAGS -fprofile-arcs -ftest-coverage"
 288   LDFLAGS="$LDFLAGS -fprofile-arcs"
 289 fi
 290 AM_CONDITIONAL(GCOV, test "$use_gcov" = yes)
 291
 292 AC_ARG_ENABLE([sanitize-undefined],
 293               AS_HELP_STRING([--enable-sanitize-undefined],
 294                              [Use gcc undefined behaviour sanitizer]),
 295                              [use_undefined=$enableval], [use_undefined=no])
 296 if test "$use_undefined" = yes; then
 297   old_CFLAGS="$CFLAGS"
 298   old_CXXFLAGS="$CXXFLAGS"
 299   # We explicitly use unaligned access when possible (see ALLOW_UNALIGNED)
 300   # We want to fail immediately on first error, don't try to recover.
 301   CFLAGS="$CFLAGS -fsanitize=undefined -fno-sanitize-recover"
 302   CXXFLAGS="$CXXFLAGS -fsanitize=undefined -fno-sanitize-recover"
 303   AC_LINK_IFELSE([AC_LANG_SOURCE([int main (int argc, char **argv) { return 0; }])], use_undefined=yes, use_undefined=no)
 304   AS_IF([test "x$use_undefined" != xyes],
 305         AC_MSG_WARN([gcc undefined behaviour sanitizer not available])
 306         CFLAGS="$old_CFLAGS" CXXFLAGS="$old_CXXFLAGS")
 307 fi
 308 case $use_undefined in
 309  yes) check_undefined_val=1 ;;
 310  *)   check_undefined_val=0 ;;
 311 esac
 312 AC_DEFINE_UNQUOTED(CHECK_UNDEFINED, $check_undefined_val,
 313                    [Building with -fsanitize=undefined or not])
 314
 315 AC_ARG_ENABLE([valgrind],
 316 AS_HELP_STRING([--enable-valgrind],[run all tests under valgrind]),
 317 [use_valgrind=$enableval], [use_valgrind=no])
 318 if test "$use_valgrind" = yes; then
 319   AC_CHECK_PROG(HAVE_VALGRIND, valgrind, yes, no)
 320   if test "$HAVE_VALGRIND" = "no"; then
 321     AC_MSG_ERROR([valgrind not found])
 322   fi
 323 fi
 324 AM_CONDITIONAL(USE_VALGRIND, test "$use_valgrind" = yes)
 325
 326 AM_CONDITIONAL(BUILD_STATIC, [dnl
 327 test "$use_gprof" = yes -o "$use_gcov" = yes])
 328
 329 AC_ARG_ENABLE([tests-rpath],
 330 AS_HELP_STRING([--enable-tests-rpath],[build $ORIGIN-using rpath into tests]),
 331                [tests_use_rpath=$enableval], [tests_use_rpath=no])
 332 AM_CONDITIONAL(TESTS_RPATH, test "$tests_use_rpath" = yes)
 333
 334 LIBEBL_SUBDIR="$PACKAGE"
 335 AC_ARG_ENABLE([libebl-subdir],
 336 AS_HELP_STRING([--enable-libebl-subdir=DIR],
 337 [install libebl_CPU modules in $(libdir)/DIR]), [dnl
 338 LIBEBL_SUBDIR="$enable_libebl_subdir"])
 339 AC_SUBST([LIBEBL_SUBDIR])
 340 AC_DEFINE_UNQUOTED(LIBEBL_SUBDIR, "$LIBEBL_SUBDIR")
 341 AH_TEMPLATE([LIBEBL_SUBDIR], [$libdir subdirectory containing libebl modules.])
 342
 343 dnl zlib is mandatory.
 344 save_LIBS="$LIBS"
 345 LIBS=
 346 eu_ZIPLIB(zlib,ZLIB,z,gzdirect,gzip)
 347 AS_IF([test "x$with_zlib" = xno], [AC_MSG_ERROR([zlib not found but is required])])
 348 LIBS="$save_LIBS"
 349
 350 dnl Test for bzlib and xz/lzma, gives BZLIB/LZMALIB .am
 351 dnl conditional and config.h USE_BZLIB/USE_LZMALIB #define.
 352 save_LIBS="$LIBS"
 353 LIBS=
 354 eu_ZIPLIB(bzlib,BZLIB,bz2,BZ2_bzdopen,bzip2)
 355 # We need this since bzip2 doesn't have a pkgconfig file.
 356 BZ2_LIB="$LIBS"
 357 AC_SUBST([BZ2_LIB])
 358 eu_ZIPLIB(lzma,LZMA,lzma,lzma_auto_decoder,[LZMA (xz)])
 359 AS_IF([test "x$with_lzma" = xyes], [LIBLZMA="liblzma"], [LIBLZMA=""])
 360 AC_SUBST([LIBLZMA])
 361 zip_LIBS="$LIBS"
 362 LIBS="$save_LIBS"
 363 AC_SUBST([zip_LIBS])
 364
 365 AC_CHECK_DECLS([memrchr, rawmemchr],[],[],
 366                [#define _GNU_SOURCE
 367                 #include <string.h>])
 368 AC_CHECK_DECLS([powerof2],[],[],[#include <sys/param.h>])
 369 AC_CHECK_DECLS([mempcpy],[],[],
 370                [#define _GNU_SOURCE
 371                 #include <string.h>])
 372
 373 AC_CHECK_LIB([stdc++], [__cxa_demangle], [dnl
 374 AC_DEFINE([USE_DEMANGLE], [1], [Defined if demangling is enabled])])
 375 AM_CONDITIONAL(DEMANGLE, test "x$ac_cv_lib_stdcpp___cxa_demangle" = "xyes")
 376 AS_IF([test "x$ac_cv_lib_stdcpp___cxa_demangle" = "xyes"],
 377       [enable_demangler=yes],[enable_demangler=no])
 378
 379 AC_ARG_ENABLE([textrelcheck],
 380 AS_HELP_STRING([--disable-textrelcheck],
 381                [Disable textrelcheck being a fatal error]))
 382 AM_CONDITIONAL(FATAL_TEXTREL, [test "x$enable_textrelcheck" != "xno"])
 383 AS_IF([test "x$enable_textrelcheck" != "xno"],
 384       [enable_textrelcheck=yes],[enable_textrelcheck=no])
 385
 386 AC_ARG_ENABLE([symbol-versioning],
 387 AS_HELP_STRING([--disable-symbol-versioning],
 388                [Disable symbol versioning in shared objects]))
 389
 390 AC_CACHE_CHECK([whether symbol versioning is supported], ac_cv_symbol_versioning, [dnl
 391 AC_COMPILE_IFELSE([AC_LANG_SOURCE([dnl
 392 #define NEW_VERSION(name, version) \
 393   asm (".symver " #name "," #name "@@@" #version);
 394 int foo(int x) { return x + 1; }
 395 NEW_VERSION (foo, ELFUTILS_12.12)
 396 ])], ac_cv_symbol_versioning=yes, ac_cv_symbol_versioning=no)])
 397 if test "$ac_cv_symbol_versioning" = "no"; then
 398     if test "x$enable_symbol_versioning" != "xno"; then
 399         AC_MSG_ERROR([Symbol versioning is not supported.
 400                       Use --disable-symbol-versioning to build without.])
 401     fi
 402 fi
 403
 404 AM_CONDITIONAL(SYMBOL_VERSIONING, [test "x$enable_symbol_versioning" != "xno"])
 405 AS_IF([test "x$enable_symbol_versioning" = "xno"],
 406       [AC_MSG_WARN([Disabling symbol versioning breaks ABI compatibility.])
 407        enable_symbol_versioning=no],[enable_symbol_versioning=yes])
 408
 409 AC_CACHE_CHECK([whether gcc accepts -Wstack-usage], ac_cv_stack_usage, [dnl
 410 old_CFLAGS="$CFLAGS"
 411 CFLAGS="$CFLAGS -Wstack-usage=262144 -Werror"
 412 AC_COMPILE_IFELSE([AC_LANG_SOURCE([])],
 413                   ac_cv_stack_usage=yes, ac_cv_stack_usage=no)
 414 CFLAGS="$old_CFLAGS"])
 415 AM_CONDITIONAL(ADD_STACK_USAGE_WARNING, [test "x$ac_cv_stack_usage" != "xno"])
 416
 417 # -Wlogical-op was too fragile in the past, make sure we get a sane one.
 418 AC_CACHE_CHECK([whether gcc has a sane -Wlogical-op], ac_cv_logical_op, [dnl
 419 old_CFLAGS="$CFLAGS"
 420 CFLAGS="$CFLAGS -Wlogical-op -Werror"
 421 AC_COMPILE_IFELSE([AC_LANG_SOURCE(
 422         [#define FLAG 1
 423         int f (int r, int f) { return (r && (FLAG || (FLAG & f))); }])],
 424                   ac_cv_logical_op=yes, ac_cv_logical_op=no)
 425 CFLAGS="$old_CFLAGS"])
 426 AM_CONDITIONAL(SANE_LOGICAL_OP_WARNING,
 427                [test "x$ac_cv_logical_op" != "xno"])
 428
 429 # -Wduplicated-cond was added by GCC6
 430 AC_CACHE_CHECK([whether gcc accepts -Wduplicated-cond], ac_cv_duplicated_cond, [dnl
 431 old_CFLAGS="$CFLAGS"
 432 CFLAGS="$CFLAGS -Wduplicated-cond -Werror"
 433 AC_COMPILE_IFELSE([AC_LANG_SOURCE([])],
 434                   ac_cv_duplicated_cond=yes, ac_cv_duplicated_cond=no)
 435 CFLAGS="$old_CFLAGS"])
 436 AM_CONDITIONAL(HAVE_DUPLICATED_COND_WARNING,
 437                [test "x$ac_cv_duplicated_cond" != "xno"])
 438
 439 # -Wnull-dereference was added by GCC6
 440 AC_CACHE_CHECK([whether gcc accepts -Wnull-dereference], ac_cv_null_dereference, [dnl
 441 old_CFLAGS="$CFLAGS"
 442 CFLAGS="$CFLAGS -Wnull-dereference -Werror"
 443 AC_COMPILE_IFELSE([AC_LANG_SOURCE([])],
 444                   ac_cv_null_dereference=yes, ac_cv_null_dereference=no)
 445 CFLAGS="$old_CFLAGS"])
 446 AM_CONDITIONAL(HAVE_NULL_DEREFERENCE_WARNING,
 447                [test "x$ac_cv_null_dereference" != "xno"])
 448
 449 # -Wimplicit-fallthrough was added by GCC7
 450 AC_CACHE_CHECK([whether gcc accepts -Wimplicit-fallthrough], ac_cv_implicit_fallthrough, [dnl
 451 old_CFLAGS="$CFLAGS"
 452 CFLAGS="$CFLAGS -Wimplicit-fallthrough -Werror"
 453 AC_COMPILE_IFELSE([AC_LANG_SOURCE([])],
 454                   ac_cv_implicit_fallthrough=yes, ac_cv_implicit_fallthrough=no)
 455 CFLAGS="$old_CFLAGS"])
 456 AM_CONDITIONAL(HAVE_IMPLICIT_FALLTHROUGH_WARNING,
 457                [test "x$ac_cv_implicit_fallthrough" != "xno"])
 458
 459 # Assume the fallthrough attribute is supported if -Wimplict-fallthrough is supported
 460 if test "$ac_cv_implicit_fallthrough" = "yes"; then
 461         AC_DEFINE([HAVE_FALLTHROUGH], [1],
 462                   [Defined if __attribute__((fallthrough)) is supported])
 463 fi
 464
 465 dnl Check if we have argp available from our libc
 466 AC_LINK_IFELSE(
 467         [AC_LANG_PROGRAM(
 468                 [#include <argp.h>],
 469                 [int argc=1; char *argv[]={"test"}; argp_parse(0,argc,&argv,0,0,0); return 0;]
 470                 )],
 471         [libc_has_argp="true"],
 472         [libc_has_argp="false"]
 473 )
 474
 475 dnl If our libc doesn't provide argp, then test for libargp
 476 if test "$libc_has_argp" = "false" ; then
 477         AC_MSG_WARN("libc does not have argp")
 478         AC_CHECK_LIB([argp], [argp_parse], [have_argp="true"], [have_argp="false"])
 479
 480         if test "$have_argp" = "false"; then
 481                 AC_MSG_ERROR("no libargp found")
 482         else
 483                 argp_LDADD="-largp"
 484         fi
 485 else
 486         argp_LDADD=""
 487 fi
 488 AC_SUBST([argp_LDADD])
 489
 490 dnl The directories with content.
 491
 492 dnl Documentation.
 493 dnl Commented out for now.
 494 dnl AC_CONFIG_FILES([doc/Makefile])
 495
 496 dnl Support library.
 497 AC_CONFIG_FILES([lib/Makefile])
 498
 499 dnl ELF library.
 500 AC_CONFIG_FILES([libelf/Makefile])
 501
 502 dnl Higher-level ELF support library.
 503 AC_CONFIG_FILES([libebl/Makefile])
 504
 505 dnl DWARF-ELF Lower-level Functions support library.
 506 AC_CONFIG_FILES([libdwelf/Makefile])
 507
 508 dnl DWARF library.
 509 AC_CONFIG_FILES([libdw/Makefile])
 510
 511 dnl Higher-level DWARF support library.
 512 AC_CONFIG_FILES([libdwfl/Makefile])
 513
 514 dnl CPU handling library.
 515 AC_CONFIG_FILES([libcpu/Makefile])
 516
 517 dnl Assembler library.
 518 AM_CONDITIONAL(HAVE_LIBASM, true)dnl Used in tests/Makefile.am, which see.
 519 AC_CONFIG_FILES([libasm/Makefile])
 520
 521 dnl CPU-specific backend libraries.
 522 AC_CONFIG_FILES([backends/Makefile])
 523
 524 dnl Tools.
 525 AC_CONFIG_FILES([src/Makefile po/Makefile.in])
 526
 527 dnl Test suite.
 528 AM_CONDITIONAL(STANDALONE, false)dnl Used in tests/Makefile.am, which see.
 529 AC_CONFIG_FILES([tests/Makefile])
 530
 531 dnl pkgconfig files
 532 AC_CONFIG_FILES([config/libelf.pc config/libdw.pc])
 533
 534 # Get the definitions necessary to create the Makefiles in the po
 535 # subdirectories.  This is a small subset of the gettext rules.
 536 AC_SUBST(USE_NLS, yes)
 537 AM_PO_SUBDIRS
 538
 539 dnl Appended to the config.h file.
 540 dnl We hide all kinds of configuration magic in lib/eu-config.h.
 541 AH_BOTTOM([#include <eu-config.h>])
 542
 543 dnl Version compatibility header.
 544 AC_CONFIG_FILES([version.h:config/version.h.in])
 545 AC_SUBST([eu_version])
 546
 547 # 1.234<whatever> -> 1234<whatever>
 548 case "$PACKAGE_VERSION" in
 549 [[0-9]].*) eu_version=`echo "$PACKAGE_VERSION" | sed 's@\.@@'` ;;
 550 *)         AC_MSG_ERROR([confused by version number '$PACKAGE_VERSION']) ;;
 551 esac
 552 case "$eu_version" in
 553 *.*)
 554   # 1234.567 -> "1234", "567"
 555   eu_extra_version="${eu_version#*.}"
 556   eu_version="${eu_version%%.*}"
 557   case "$eu_extra_version" in
 558   [[0-9]][[0-9]][[0-9]]) ;;
 559   [[0-9]][[0-9]])       eu_extra_version="${eu_extra_version}0" ;;
 560   [[0-9]])              eu_extra_version="${eu_extra_version}00" ;;
 561   *) AC_MSG_ERROR([confused by version number '$PACKAGE_VERSION']) ;;
 562   esac
 563   ;;
 564 *)
 565   eu_extra_version=000
 566   ;;
 567 esac
 568
 569 case "$eu_version" in
 570       0[[0-9]][[0-9]][[0-9]]) eu_version="${eu_version#0}$eu_extra_version" ;;
 571 [[0-9]][[0-9]][[0-9]][[0-9]]) eu_version="${eu_version}$eu_extra_version" ;;
 572 [[0-9]][[0-9]][[0-9]])        eu_version="${eu_version}0$eu_extra_version" ;;
 573 [[0-9]][[0-9]])               eu_version="${eu_version}00$eu_extra_version";;
 574 *) AC_MSG_ERROR([confused by version number '$PACKAGE_VERSION']) ;;
 575 esac
 576
 577 # Round up to the next release API (x.y) version.
 578 eu_version=$(( (eu_version + 999) / 1000 ))
 579
 580 dnl Unique ID for this build.
 581 MODVERSION="Build for ${LIBEBL_SUBDIR} ${eu_version} ${ac_cv_build}"
 582 AC_SUBST([MODVERSION])
 583 AC_DEFINE_UNQUOTED(MODVERSION, "$MODVERSION")
 584 AH_TEMPLATE([MODVERSION], [Identifier for modules in the build.])
 585
 586 AC_CHECK_SIZEOF(long)
 587
 588 # On aarch64 before glibc 2.20 we would get the kernel user_pt_regs instead
 589 # of the user_regs_struct from sys/user.h. They are structurally the same
 590 # but we get either one or the other.
 591 AC_CHECK_TYPE([struct user_regs_struct],
 592               [sys_user_has_user_regs=yes], [sys_user_has_user_regs=no],
 593               [[#include <sys/ptrace.h>]
 594                [#include <sys/time.h>]
 595                [#include <sys/user.h>]])
 596 if test "$sys_user_has_user_regs" = "yes"; then
 597   AC_DEFINE(HAVE_SYS_USER_REGS, 1,
 598             [Define to 1 if <sys/user.h> defines struct user_regs_struct])
 599 fi
 600
 601 # On a 64-bit host where can can use $CC -m32, we'll run two sets of tests.
 602 # Likewise in a 32-bit build on a host where $CC -m64 works.
 603 utrace_BIARCH
 604 # `$utrace_biarch' will be `-m64' even on an uniarch i386 machine.
 605 CC_BIARCH="$CC $utrace_biarch"
 606 AC_SUBST([CC_BIARCH])
 607
 608 # In maintainer mode we really need flex and bison.
 609 # Otherwise we really need a release dir with maintainer files generated.
 610 if test "x$enable_maintainer_mode" = xyes; then
 611   AC_CHECK_PROG(HAVE_FLEX, flex, yes, no)
 612   if test "$HAVE_FLEX" = "no"; then
 613     AC_MSG_ERROR([flex needed in maintainer mode])
 614   fi
 615   AC_CHECK_PROG(HAVE_BISON, bison, yes, no)
 616   if test "$HAVE_BISON" = "no"; then
 617     AC_MSG_ERROR([bison needed in maintainer mode])
 618   fi
 619 else
 620   if test ! -f ${srcdir}/libdw/known-dwarf.h; then
 621     AC_MSG_ERROR([No libdw/known-dwarf.h. configure --enable-maintainer-mode])
 622   fi
 623 fi
 624
 625 # The testfiles are all compressed, we need bunzip2 when running make check
 626 AC_CHECK_PROG(HAVE_BUNZIP2, bunzip2, yes, no)
 627 if test "$HAVE_BUNZIP2" = "no"; then
 628   AC_MSG_WARN([No bunzip2, needed to run make check])
 629 fi
 630
 631 AC_OUTPUT
 632
 633 AC_MSG_NOTICE([
 634 =====================================================================
 635         elfutils: ${PACKAGE_VERSION} (eu_version: ${eu_version})
 636 =====================================================================
 637
 638     Prefix                             : ${prefix}
 639     Program prefix ("eu-" recommended) : ${program_prefix}
 640     Source code location               : ${srcdir}
 641     Maintainer mode                    : ${enable_maintainer_mode}
 642     libebl modules subdirectory        : ${LIBEBL_SUBDIR}
 643     build arch                         : ${ac_cv_build}
 644
 645   RECOMMENDED FEATURES (should all be yes)
 646     gzip support                       : ${with_zlib}
 647     bzip2 support                      : ${with_bzlib}
 648     lzma/xz support                    : ${with_lzma}
 649     libstdc++ demangle support         : ${enable_demangler}
 650     File textrel check                 : ${enable_textrelcheck}
 651     Symbol versioning                  : ${enable_symbol_versioning}
 652
 653   NOT RECOMMENDED FEATURES (should all be no)
 654     Experimental thread safety         : ${use_locks}
 655
 656   OTHER FEATURES
 657     Deterministic archives by default  : ${default_ar_deterministic}
 658     Native language support            : ${USE_NLS}
 659
 660   EXTRA TEST FEATURES (used with make check)
 661     have bunzip2 installed (required)  : ${HAVE_BUNZIP2}
 662     debug branch prediction            : ${use_debugpred}
 663     gprof support                      : ${use_gprof}
 664     gcov support                       : ${use_gcov}
 665     run all tests under valgrind       : ${use_valgrind}
 666     gcc undefined behaviour sanitizer  : ${use_undefined}
 667     use rpath in tests                 : ${tests_use_rpath}
 668     test biarch                        : ${utrace_cv_cc_biarch}
 669 ])