configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2 AC_PREREQ([2.62])
   3
   4 dnl ***********************************
   5 dnl *** include special GLib macros ***
   6 dnl ***********************************
   7
   8 m4_define(glib_configure_ac)
   9
  10 #
  11 # The following version number definitions apply to GLib, GModule, GObject,
  12 # GThread and GIO as a whole, so if changes occurred in any of them, they are
  13 # all treated with the same interface and binary age.
  14 #
  15 # Making releases:
  16 #   glib_micro_version += 1;
  17 #   glib_interface_age += 1;
  18 #   glib_binary_age += 1;
  19 # if any functions have been added, set glib_interface_age to 0.
  20 # if backwards compatibility has been broken,
  21 # set glib_binary_age _and_ glib_interface_age to 0.
  22 #
  23 # remember to add a GLIB_VERSION_2_xx macro every time the minor version is
  24 # bumped, as well as the GLIB_DEPRECATED_IN and GLIB_AVAILABLE_IN macros
  25 # for that version - see gversion.h for further information.
  26 #
  27 # in easier to understand terms:
  28 #
  29 # <mclasen> on the stable branch, interface age == micro
  30 # <mclasen> on the unstable (ie master), interface age = 0
  31
  32 m4_define([glib_major_version], [2])
  33 m4_define([glib_minor_version], [33])
  34 m4_define([glib_micro_version], [1])
  35 m4_define([glib_interface_age], [0])
  36 m4_define([glib_binary_age],
  37           [m4_eval(100 * glib_minor_version + glib_micro_version)])
  38 m4_define([glib_version],
  39           [glib_major_version.glib_minor_version.glib_micro_version])
  40
  41 # libtool version related macros
  42 m4_define([glib_lt_release], [glib_major_version.glib_minor_version])
  43 m4_define([glib_lt_current],
  44           [m4_eval(100 * glib_minor_version + glib_micro_version - glib_interface_age)])
  45 m4_define([glib_lt_revision], [glib_interface_age])
  46 m4_define([glib_lt_age], [m4_eval(glib_binary_age - glib_interface_age)])
  47 m4_define([glib_lt_current_minus_age],
  48           [m4_eval(glib_lt_current - glib_lt_age)])
  49
  50 # if the minor version number is odd, then we want debugging.  Otherwise
  51 # we only want minimal debugging support.
  52 m4_define([glib_debug_default],
  53           [m4_if(m4_eval(glib_minor_version % 2), [1], [yes], [minimum])])dnl
  54
  55
  56 AC_INIT(glib, [glib_version],
  57         [http://bugzilla.gnome.org/enter_bug.cgi?product=glib])
  58
  59 AC_CONFIG_HEADER([config.h])
  60 AC_CONFIG_SRCDIR([glib/glib.h])
  61 AC_CONFIG_MACRO_DIR([m4macros])
  62
  63 # Save this value here, since automake will set cflags later
  64 cflags_set=${CFLAGS+set}
  65
  66 AM_INIT_AUTOMAKE([1.11 no-define no-dist-gzip dist-xz tar-ustar])
  67 AM_MAINTAINER_MODE([enable])
  68
  69 # Support silent build rules. Disable
  70 # by either passing --disable-silent-rules to configure or passing V=1
  71 # to make
  72 AM_SILENT_RULES([yes])
  73
  74 GLIB_MAJOR_VERSION=glib_major_version
  75 GLIB_MINOR_VERSION=glib_minor_version
  76 GLIB_MICRO_VERSION=glib_micro_version
  77 GLIB_INTERFACE_AGE=glib_interface_age
  78 GLIB_BINARY_AGE=glib_binary_age
  79 GLIB_VERSION=glib_version
  80
  81 AC_SUBST(GLIB_MAJOR_VERSION)
  82 AC_SUBST(GLIB_MINOR_VERSION)
  83 AC_SUBST(GLIB_MICRO_VERSION)
  84 AC_SUBST(GLIB_VERSION)
  85 AC_SUBST(GLIB_INTERFACE_AGE)
  86 AC_SUBST(GLIB_BINARY_AGE)
  87
  88 AC_DEFINE(GLIB_MAJOR_VERSION, [glib_major_version],
  89           [Define to the GLIB major version])
  90 AC_DEFINE(GLIB_MINOR_VERSION, [glib_minor_version],
  91           [Define to the GLIB minor version])
  92 AC_DEFINE(GLIB_MICRO_VERSION, [glib_micro_version],
  93           [Define to the GLIB micro version])
  94 AC_DEFINE(GLIB_INTERFACE_AGE, [glib_interface_age],
  95           [Define to the GLIB interface age])
  96 AC_DEFINE(GLIB_BINARY_AGE, [glib_binary_age],
  97           [Define to the GLIB binary age])
  98
  99 # libtool versioning
 100 LT_RELEASE=glib_lt_release
 101 LT_CURRENT=glib_lt_current
 102 LT_REVISION=glib_lt_revision
 103 LT_AGE=glib_lt_age
 104 LT_CURRENT_MINUS_AGE=glib_lt_current_minus_age
 105 AC_SUBST(LT_RELEASE)
 106 AC_SUBST(LT_CURRENT)
 107 AC_SUBST(LT_REVISION)
 108 AC_SUBST(LT_AGE)
 109 AC_SUBST(LT_CURRENT_MINUS_AGE)
 110
 111 dnl Checks for programs.
 112 AC_PROG_CC
 113 AC_PROG_CPP
 114
 115 AM_CONDITIONAL(HAVE_GCC, [test "$GCC" = "yes"])
 116
 117 AC_CANONICAL_HOST
 118
 119 AC_MSG_CHECKING([for the BeOS])
 120 case $host in
 121   *-*-beos*)
 122     glib_native_beos="yes"
 123     ;;
 124   *)
 125     glib_native_beos="no"
 126     ;;
 127 esac
 128 AC_MSG_RESULT([$glib_native_beos])
 129
 130 dnl
 131
 132 AC_MSG_CHECKING([for Win32])
 133 LIB_EXE_MACHINE_FLAG=X86
 134 case "$host" in
 135   *-*-mingw*)
 136     glib_native_win32=yes
 137     glib_pid_type='void *'
 138     glib_cv_stack_grows=no
 139     # Unfortunately the mingw implementations of C99-style snprintf and vsnprintf
 140     # don't seem to be quite good enough, at least not in mingw-runtime-3.14.
 141     # (Sorry, I don't know exactly what is the problem, but it is related to
 142     # floating point formatting and decimal point vs. comma.)
 143     # The simple tests in AC_FUNC_VSNPRINTF_C99 and AC_FUNC_SNPRINTF_C99 aren't
 144     # rigorous enough to notice, though.
 145     # So preset the autoconf cache variables.
 146     ac_cv_func_vsnprintf_c99=no
 147     ac_cv_func_snprintf_c99=no
 148     case "$host" in
 149     x86_64-*-*)
 150       LIB_EXE_MACHINE_FLAG=X64
 151       ;;
 152     esac
 153     ;;
 154   *)
 155     glib_native_win32=no
 156     glib_pid_type=int
 157     ;;
 158 esac
 159 case $host in
 160   *-*-linux*)
 161     glib_os_linux=yes
 162     ;;
 163 esac
 164
 165 AC_MSG_RESULT([$glib_native_win32])
 166
 167 AC_SUBST(LIB_EXE_MACHINE_FLAG)
 168
 169 glib_have_carbon=no
 170 AC_MSG_CHECKING([for Mac OS X Carbon support])
 171 AC_TRY_CPP([
 172 #include <Carbon/Carbon.h>
 173 #include <CoreServices/CoreServices.h>
 174 ], glib_have_carbon=yes)
 175
 176 AC_MSG_RESULT([$glib_have_carbon])
 177
 178 glib_have_cocoa=no
 179 AC_MSG_CHECKING([for Mac OS X Cocoa support])
 180 AC_TRY_CPP([
 181 #include <Cocoa/Cocoa.h>
 182 #ifdef GNUSTEP_BASE_VERSION
 183 #error "Detected GNUstep, not Cocoa"
 184 #endif
 185 ], glib_have_cocoa=yes)
 186
 187 AC_MSG_RESULT([$glib_have_cocoa])
 188
 189 AM_CONDITIONAL(OS_WIN32, [test "$glib_native_win32" = "yes"])
 190 AM_CONDITIONAL(OS_WIN32_X64, [test "$LIB_EXE_MACHINE_FLAG" = "X64"])
 191 AM_CONDITIONAL(OS_UNIX, [test "$glib_native_win32" != "yes"])
 192 AM_CONDITIONAL(OS_LINUX, [test "$glib_os_linux" = "yes"])
 193 AM_CONDITIONAL(OS_CARBON, [test "$glib_have_carbon" = "yes"])
 194 AM_CONDITIONAL(OS_COCOA, [test "$glib_have_cocoa" = "yes"])
 195
 196 AS_IF([test "$glib_native_win32" = "yes"], [
 197   AC_CHECK_TOOL(WINDRES, windres, no)
 198   if test "$WINDRES" = no; then
 199     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 200   fi
 201   AC_CHECK_TOOL(NM, nm, no)
 202   if test "$NM" = no; then
 203     AC_MSG_ERROR([*** Could not find an implementation of nm in your PATH.])
 204   fi
 205   AC_CHECK_TOOL(RANLIB, ranlib, :)
 206   AC_CHECK_PROG(ms_librarian, [lib.exe], [yes], [no])
 207 ])
 208 AM_CONDITIONAL(MS_LIB_AVAILABLE, [test x$ms_librarian = xyes])
 209
 210 if test "$glib_native_win32" != yes; then
 211     # libtool option to control which symbols are exported
 212     # right now, symbols starting with _ are not exported
 213     LIBTOOL_EXPORT_OPTIONS='-export-symbols-regex "^g.*"'
 214 else
 215     # We currently use .def files on Windows
 216     LIBTOOL_EXPORT_OPTIONS=
 217 fi
 218 AC_SUBST(LIBTOOL_EXPORT_OPTIONS)
 219
 220 AS_IF([test "x$glib_have_carbon" = "xyes"], [
 221   AC_DEFINE(HAVE_CARBON, 1, [define to 1 if Carbon is available])
 222   LDFLAGS="$LDFLAGS -framework Carbon"
 223 ])
 224
 225 if test "x$glib_have_cocoa" = "xyes"; then
 226   AC_DEFINE(HAVE_COCOA, 1, [define to 1 if Cocoa is available])
 227   LDFLAGS="$LDFLAGS -framework Foundation"
 228 fi
 229
 230 gl_GLIBC21
 231 AS_IF([test "x$GLIBC21" = "xyes"], [
 232   AC_DEFINE([_GNU_SOURCE], 1, [Make all glibc extensions visible])
 233 ])
 234
 235 dnl declare --enable-* args and collect ac_help strings
 236 AC_ARG_ENABLE(debug,
 237               AC_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 238                              [turn on debugging @<:@default=glib_debug_default@:>@]),,
 239               enable_debug=glib_debug_default)
 240
 241 AC_ARG_ENABLE(gc_friendly,
 242               [AC_HELP_STRING([--enable-gc-friendly],
 243                               [turn on garbage collector friendliness [default=no]])],,
 244               [enable_gc_friendly=no])
 245 AC_ARG_ENABLE(mem_pools,
 246               [AC_HELP_STRING([--disable-mem-pools],
 247                               [disable all glib memory pools])],,
 248               [disable_mem_pools=no])
 249 AC_ARG_ENABLE(rebuilds,
 250               [AC_HELP_STRING([--disable-rebuilds],
 251                               [disable all source autogeneration rules])],,
 252               [enable_rebuilds=yes])
 253 AC_ARG_ENABLE(modular_tests,
 254               AC_HELP_STRING([--disable-modular-tests],
 255                              [Disable build of test programs (default: no)]),,
 256               [enable_modular_tests=yes])
 257 AM_CONDITIONAL(BUILD_MODULAR_TESTS, test x$enable_modular_tests = xyes)
 258
 259 AC_MSG_CHECKING([whether to enable garbage collector friendliness])
 260 AS_IF([test "x$enable_gc_friendly" = "xyes"], [
 261   AC_DEFINE(ENABLE_GC_FRIENDLY_DEFAULT, 1, [Whether to enable GC friendliness by default])
 262   AC_MSG_RESULT([yes])
 263 ], [ AC_MSG_RESULT([no]) ])
 264
 265 AC_MSG_CHECKING([whether to disable memory pools])
 266 AS_IF([test "x$disable_mem_pools" = "xno"], [
 267   AC_MSG_RESULT([no])
 268 ], [
 269   AC_DEFINE(DISABLE_MEM_POOLS, [1], [Whether to disable memory pools])
 270   AC_MSG_RESULT([yes])
 271 ])
 272
 273 dnl location to install runtime libraries, e.g. ../../lib to install
 274 dnl to /lib if libdir is /usr/lib
 275 AC_ARG_WITH(runtime-libdir,
 276            [AC_HELP_STRING([--with-runtime-libdir=RELPATH],
 277                            [install runtime libraries relative to libdir])],
 278            [],
 279            [with_runtime_libdir=""])
 280 GLIB_RUNTIME_LIBDIR="$with_runtime_libdir"
 281 ABS_GLIB_RUNTIME_LIBDIR="`readlink -f $libdir/$with_runtime_libdir`"
 282 AC_SUBST(GLIB_RUNTIME_LIBDIR)
 283 AC_SUBST(ABS_GLIB_RUNTIME_LIBDIR)
 284 AM_CONDITIONAL(HAVE_GLIB_RUNTIME_LIBDIR, [test "x$with_runtime_libdir" != "x"])
 285
 286 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 287 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], [gcc])
 288 AC_LANG_SAVE
 289 AC_LANG_CPLUSPLUS
 290 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
 291 AM_CONDITIONAL(HAVE_CXX, [test "$CXX" != ""])
 292 AC_LANG_RESTORE
 293
 294 AM_PROG_CC_STDC
 295 AM_PROG_CC_C_O
 296 AC_PROG_INSTALL
 297
 298 AC_SYS_LARGEFILE
 299
 300 PKG_PROG_PKG_CONFIG(0.16)
 301
 302 if test "x$enable_debug" = "xyes"; then
 303   if test x$cflags_set != xset ; then
 304       case " $CFLAGS " in
 305       *[[\ \    ]]-g[[\ \       ]]*) ;;
 306       *) CFLAGS="$CFLAGS -g" ;;
 307       esac
 308   fi
 309   GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 310 else
 311   GLIB_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 312
 313   if test "x$enable_debug" = "xno"; then
 314     GLIB_DEBUG_FLAGS="$GLIB_DEBUG_FLAGS -DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
 315   fi
 316 fi
 317
 318 # Ensure MSVC-compatible struct packing convention is used when
 319 # compiling for Win32 with gcc.
 320 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 321 # gcc2 uses "-fnative-struct".
 322 if test x"$glib_native_win32" = xyes; then
 323   if test x"$GCC" = xyes; then
 324     msnative_struct=''
 325     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 326     if test -z "$ac_cv_prog_CC"; then
 327       our_gcc="$CC"
 328     else
 329       our_gcc="$ac_cv_prog_CC"
 330     fi
 331     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 332       2.)
 333         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 334           msnative_struct='-fnative-struct'
 335         fi
 336         ;;
 337       *)
 338         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 339           msnative_struct='-mms-bitfields'
 340         fi
 341         ;;
 342     esac
 343     if test x"$msnative_struct" = x ; then
 344       AC_MSG_RESULT([no way])
 345       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 346     else
 347       CFLAGS="$CFLAGS $msnative_struct"
 348       AC_MSG_RESULT([${msnative_struct}])
 349     fi
 350   fi
 351 fi
 352 GLIB_EXTRA_CFLAGS="${msnative_struct}"
 353 AC_SUBST(GLIB_EXTRA_CFLAGS)
 354
 355 AC_EXEEXT
 356
 357 # define a MAINT-like variable REBUILD which is set if Perl
 358 # and awk are found, so autogenerated sources can be rebuilt
 359 AC_PROG_AWK
 360 AC_CHECK_PROGS(PERL, [perl5 perl])
 361 # We would like indent, but don't require it.
 362 AC_CHECK_PROG(INDENT, indent, indent)
 363 REBUILD=\#
 364 if test "x$enable_rebuilds" = "xyes" && \
 365      test -n "$PERL" && \
 366      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 && \
 367      test -n "$AWK" ; then
 368   REBUILD=
 369 fi
 370 AC_SUBST(REBUILD)
 371
 372 # Need full path to Perl for glib-mkenums
 373 #
 374 if test "x$PERL" != x ; then
 375   AC_PATH_PROG(PERL_PATH, [$PERL])
 376 fi
 377 if test "x$PERL_PATH" = x ; then
 378   PERL_PATH="/usr/bin/env perl"
 379 fi
 380 AC_SUBST(PERL_PATH)
 381
 382 # Need suitable python path for greport
 383 AM_PATH_PYTHON(2.5,,PYTHON="/usr/bin/env python2.5")
 384
 385
 386 dnl ***********************
 387 dnl *** Tests for iconv ***
 388 dnl ***********************
 389 dnl
 390 dnl We do this before the gettext checks, to avoid distortion
 391
 392 dnl On Windows we use a native implementation
 393
 394 AS_IF([ test x"$glib_native_win32" = xyes], [
 395   with_libiconv=native
 396 ], [
 397   AC_ARG_WITH(libiconv,
 398               [AC_HELP_STRING([--with-libiconv=@<:@no/gnu/native@:>@],
 399                               [use the libiconv library])],,
 400               [with_libiconv=maybe])
 401
 402   found_iconv=no
 403   case $with_libiconv in
 404     maybe)
 405       # Check in the C library first
 406       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 407       # Check if we have GNU libiconv
 408       if test $found_iconv = "no"; then
 409         AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 410       fi
 411       # Check if we have a iconv in -liconv, possibly from vendor
 412       if test $found_iconv = "no"; then
 413         AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 414       fi
 415       ;;
 416     no)
 417       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 418       ;;
 419     gnu|yes)
 420       AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 421       ;;
 422     native)
 423       AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 424       ;;
 425   esac
 426
 427   if test "x$found_iconv" = "xno" ; then
 428      AC_MSG_ERROR([*** No iconv() implementation found in C library or libiconv])
 429   fi
 430 ])
 431
 432 AC_ARG_ENABLE(iconv-cache,
 433               [AC_HELP_STRING([--enable-iconv-cache=@<:@yes/no/auto@:>@],
 434                               [cache iconv descriptors [default=auto]])],,
 435               [enable_iconv_cache=auto])
 436
 437 AC_MSG_CHECKING([whether to cache iconv descriptors])
 438 case $enable_iconv_cache in
 439   auto)
 440     if test $ac_cv_gnu_library_2_1 = yes; then
 441       enable_iconv_cache=no
 442     else
 443       enable_iconv_cache=yes
 444     fi
 445   ;;
 446   yes|no)
 447   ;;
 448   *) AC_MSG_ERROR([Value given to --enable-iconv-cache must be one of yes, no or auto])
 449   ;;
 450 esac
 451
 452 if test $enable_iconv_cache = yes; then
 453    AC_DEFINE(NEED_ICONV_CACHE,1,[Do we cache iconv descriptors])
 454 fi
 455
 456 AC_MSG_RESULT($enable_iconv_cache)
 457
 458
 459 dnl
 460 dnl zlib support
 461 dnl
 462 PKG_CHECK_MODULES([ZLIB], [zlib], [found_zlib=yes], [found_zlib=no])
 463 AS_IF([test "x$found_zlib" = "xno"], [
 464   AC_CHECK_LIB(z, inflate, [AC_CHECK_HEADER(zlib.h, found_zlib=yes)])
 465   if test "x$found_zlib" = "xno" ; then
 466     AC_MSG_ERROR([*** Working zlib library and headers not found ***])
 467   fi
 468   ZLIB_LIBS='-lz'
 469   AC_SUBST(ZLIB_LIBS)
 470 ])
 471
 472 PKG_CHECK_MODULES(LIBFFI, [libffi >= 3.0.0])
 473 AC_SUBST(LIBFFI_CFLAGS)
 474 AC_SUBST(LIBFFI_LIBS)
 475
 476 dnl
 477 dnl gettext support
 478 dnl
 479
 480 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 481 AC_SUBST([CONFIG_STATUS_DEPENDENCIES],['$(top_srcdir)/po/LINGUAS'])
 482 GLIB_GNU_GETTEXT
 483
 484 if test "$gt_cv_have_gettext" != "yes" ; then
 485   AC_MSG_ERROR([
 486 *** You must have either have gettext support in your C library, or use the
 487 *** GNU gettext library. (http://www.gnu.org/software/gettext/gettext.html
 488 ])
 489 fi
 490
 491 LIBS="$INTLLIBS $LIBS"
 492
 493 GETTEXT_PACKAGE=glib20
 494 AC_SUBST(GETTEXT_PACKAGE)
 495 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
 496   [Define the gettext package to be used])
 497
 498 GLIB_DEFINE_LOCALEDIR(GLIB_LOCALE_DIR)
 499
 500 dnl
 501 dnl Now we are done with gettext checks, figure out ICONV_LIBS
 502 dnl
 503
 504 AS_IF([test x"$glib_native_win32" != xyes], [
 505   if test x$with_libiconv != xno ; then
 506     case " $INTLLIBS " in
 507     *[[\ \      ]]-liconv[[\ \  ]]*) ;;
 508     *) ICONV_LIBS="-liconv" ;;
 509     esac
 510   fi
 511 ])
 512 AC_SUBST(ICONV_LIBS)
 513
 514 case $with_libiconv in
 515   gnu)
 516     AC_DEFINE(USE_LIBICONV_GNU, 1, [Using GNU libiconv])
 517     ;;
 518   native)
 519     AC_DEFINE(USE_LIBICONV_NATIVE, 1, [Using a native implementation of iconv in a separate library])
 520     ;;
 521 esac
 522
 523 dnl Initialize libtool
 524 LT_PREREQ([2.2])
 525 LT_INIT([disable-static win32-dll])
 526 dnl when using libtool 2.x create libtool early, because it's used in configure
 527 m4_ifdef([LT_OUTPUT], [LT_OUTPUT])
 528
 529
 530 if test "x$GCC" = "xyes"; then
 531   case " $CFLAGS " in
 532   *[[\ \        ]]-Wall[[\ \    ]]*) ;;
 533   *) CFLAGS="$CFLAGS -Wall" ;;
 534   esac
 535 fi
 536
 537 AS_IF([test "$glib_native_win32" = "yes"], [
 538   if test x$enable_static = xyes -a x$enable_shared = xyes; then
 539     AC_MSG_ERROR([Can not build both shared and static at the same time on Windows.])
 540   fi
 541   if test x$enable_static = xyes; then
 542     glib_win32_static_compilation=yes
 543     GLIB_WIN32_STATIC_COMPILATION_DEFINE="#define GLIB_STATIC_COMPILATION 1
 544 #define GOBJECT_STATIC_COMPILATION 1"
 545     AC_SUBST(GLIB_WIN32_STATIC_COMPILATION_DEFINE)
 546   fi
 547 ])
 548 AM_CONDITIONAL(OS_WIN32_AND_DLL_COMPILATION, [test x$glib_native_win32 = xyes -a x$glib_win32_static_compilation != xyes])
 549
 550 dnl
 551 dnl DU4 native cc currently needs -std1 for ANSI mode (instead of K&R)
 552 dnl
 553 AS_IF([test $cross_compiling != yes], [
 554     AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 555     glib_save_LIBS=$LIBS
 556     LIBS="$LIBS -lm"
 557     AC_TRY_RUN([#include <math.h>
 558                  int main (void) { return (log(1) != log(1.)); }],
 559          AC_MSG_RESULT(none needed),
 560          glib_save_CFLAGS=$CFLAGS
 561          CFLAGS="$CFLAGS -std1"
 562          AC_TRY_RUN([#include <math.h>
 563                      int main (void) { return (log(1) != log(1.)); }],
 564              AC_MSG_RESULT(-std1),
 565              AC_MSG_RESULT()
 566              CFLAGS=$glib_save_CFLAGS
 567              AC_MSG_WARN(
 568                     [No ANSI prototypes found in library. (-std1 didn't work.)])
 569          )
 570     )
 571     LIBS=$glib_save_LIBS
 572 ])
 573
 574 dnl NeXTStep cc seems to need this
 575 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 576 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 577   AC_MSG_RESULT(none needed),
 578   glib_save_CFLAGS=$CFLAGS
 579   CFLAGS="$CFLAGS -posix"
 580   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 581     AC_MSG_RESULT(-posix),
 582     AC_MSG_RESULT()
 583     CFLAGS=$glib_save_CFLAGS
 584     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 585
 586 # Checks for library functions.
 587 AC_FUNC_VPRINTF
 588 AC_FUNC_ALLOCA
 589 AC_CHECK_FUNCS(mmap posix_memalign memalign valloc fsync pipe2)
 590 AC_CHECK_FUNCS(atexit on_exit timegm gmtime_r)
 591
 592 AC_CHECK_SIZEOF(char)
 593 AC_CHECK_SIZEOF(short)
 594 AC_CHECK_SIZEOF(long)
 595 AC_CHECK_SIZEOF(int)
 596 AC_CHECK_SIZEOF(void *)
 597 AC_CHECK_SIZEOF(long long)
 598 AC_CHECK_SIZEOF(__int64)
 599
 600 AC_CACHE_CHECK([for sig_atomic_t], ac_cv_type_sig_atomic_t,
 601   [AC_TRY_LINK([#include <signal.h>
 602      #include <sys/types.h>
 603      sig_atomic_t val = 42;],
 604     [return val == 42 ? 0 : 1],
 605    ac_cv_type_sig_atomic_t=yes,
 606    ac_cv_type_sig_atomic_t=no)])
 607 if test x$ac_cv_type_sig_atomic_t = xyes; then
 608    AC_DEFINE(HAVE_SIG_ATOMIC_T, 1,
 609      [Define if you have the 'sig_atomic_t' type.])
 610 fi
 611
 612 if test x$ac_cv_sizeof_long = x8 || test x$ac_cv_sizeof_long_long = x8 || test x$ac_cv_sizeof___int64 = x8 ; then
 613   :
 614 else
 615   AC_MSG_ERROR([
 616 *** GLib requires a 64 bit type. You might want to consider
 617 *** using the GNU C compiler.
 618 ])
 619 fi
 620
 621 AS_IF([test x$glib_native_win32 != xyes && test x$ac_cv_sizeof_long_long = x8], [
 622         # long long is a 64 bit integer.
 623         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 624         AC_CACHE_VAL(glib_cv_long_long_format,[
 625                 for format in ll q I64; do
 626                   AC_TRY_RUN([#include <stdio.h>
 627                         int main()
 628                         {
 629                           long long b, a = -0x3AFAFAFAFAFAFAFALL;
 630                           char buffer[1000];
 631                           sprintf (buffer, "%${format}u", a);
 632                           sscanf (buffer, "%${format}u", &b);
 633                           exit (b!=a);
 634                         }
 635                         ],
 636                         [glib_cv_long_long_format=${format}
 637                         break],
 638                         [],[:])
 639                 done])
 640         AS_IF([ test -n "$glib_cv_long_long_format"], [
 641           AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 642           AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 643           if test x"$glib_cv_long_long_format" = xI64; then
 644             AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 645           fi
 646         ], [AC_MSG_RESULT(none)])
 647 ],[ test x$ac_cv_sizeof___int64 = x8], [
 648         # __int64 is a 64 bit integer.
 649         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 650         # We know this is MSVCRT.DLL, and what the formats are
 651         glib_cv_long_long_format=I64
 652         AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 653         AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 654         AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 655 ])
 656
 657 AC_C_CONST
 658
 659 dnl ok, here we try to check whether the systems prototypes for
 660 dnl malloc and friends actually match the prototypes provided
 661 dnl by gmem.h (keep in sync). i currently only know how to check
 662 dnl this reliably with gcc (-Werror), improvements for other
 663 dnl compilers are apprechiated.
 664 SANE_MALLOC_PROTOS=no
 665 AC_MSG_CHECKING([if malloc() and friends prototypes are gmem.h compatible])
 666 glib_save_CFLAGS=$CFLAGS
 667 AS_IF([test "x$GCC" = "xyes"], [
 668   CFLAGS="$CFLAGS -Werror"
 669   AC_TRY_COMPILE([#include <stdlib.h>], [
 670     void* (*my_calloc_p)  (size_t, size_t) = calloc;
 671     void* (*my_malloc_p)  (size_t)         = malloc;
 672     void  (*my_free_p)    (void*)          = free;
 673     void* (*my_realloc_p) (void*, size_t)  = realloc;
 674     my_calloc_p = 0;
 675     my_malloc_p = 0;
 676     my_free_p = 0;
 677     my_realloc_p = 0;
 678   ],
 679     AC_DEFINE(SANE_MALLOC_PROTOS, 1,
 680       [Define if you have correct malloc prototypes])
 681     SANE_MALLOC_PROTOS=yes)
 682 ])
 683 AC_MSG_RESULT($SANE_MALLOC_PROTOS)
 684 CFLAGS=$glib_save_CFLAGS
 685
 686 dnl
 687 dnl check in which direction the stack grows
 688 dnl
 689 AC_CACHE_CHECK([for growing stack pointer],glib_cv_stack_grows,[
 690         AC_TRY_RUN([
 691         volatile int *a = 0, *b = 0;
 692         void foo (void);
 693         int main () { volatile int y = 7; a = &y; foo (); return b > a; }
 694         void foo (void) { volatile int x = 5; b = &x; }
 695         ],
 696         glib_cv_stack_grows=no
 697         ,
 698         glib_cv_stack_grows=yes
 699         ,)
 700 ])
 701
 702 dnl AC_C_INLINE is useless to us since it bails out too early, we need to
 703 dnl truely know which ones of `inline', `__inline' and `__inline__' are
 704 dnl actually supported.
 705 AC_CACHE_CHECK([for __inline],glib_cv_has__inline,[
 706         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 707         __inline int foo () { return 0; }
 708         int main () { return foo (); }
 709         ]])],
 710         glib_cv_has__inline=yes
 711         ,
 712         glib_cv_has__inline=no
 713         ,)
 714 ])
 715 case x$glib_cv_has__inline in
 716 xyes) AC_DEFINE(G_HAVE___INLINE,1,[Have __inline keyword])
 717 esac
 718 AC_CACHE_CHECK([for __inline__],glib_cv_has__inline__,[
 719         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 720         __inline__ int foo () { return 0; }
 721         int main () { return foo (); }
 722         ]])],
 723         glib_cv_has__inline__=yes
 724         ,
 725         glib_cv_has__inline__=no
 726         ,)
 727 ])
 728 case x$glib_cv_has__inline__ in
 729 xyes) AC_DEFINE(G_HAVE___INLINE__,1,[Have __inline__ keyword])
 730 esac
 731 AC_CACHE_CHECK([for inline], glib_cv_hasinline,[
 732         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 733         #undef inline
 734         inline int foo () { return 0; }
 735         int main () { return foo (); }
 736         ]])],
 737         glib_cv_hasinline=yes
 738         ,
 739         glib_cv_hasinline=no
 740         ,)
 741 ])
 742 case x$glib_cv_hasinline in
 743 xyes) AC_DEFINE(G_HAVE_INLINE,1,[Have inline keyword])
 744 esac
 745
 746 # if we can use inline functions in headers
 747 AC_MSG_CHECKING(if inline functions in headers work)
 748 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 749 #if defined (G_HAVE_INLINE) && defined (__GNUC__) && defined (__STRICT_ANSI__)
 750 #  undef inline
 751 #  define inline __inline__
 752 #elif !defined (G_HAVE_INLINE)
 753 #  undef inline
 754 #  if defined (G_HAVE___INLINE__)
 755 #    define inline __inline__
 756 #  elif defined (G_HAVE___INLINE)
 757 #    define inline __inline
 758 #  endif
 759 #endif
 760
 761 int glib_test_func2 (int);
 762
 763 static inline int
 764 glib_test_func1 (void) {
 765   return glib_test_func2 (1);
 766 }
 767
 768 int
 769 main (void) {
 770   int i = 1;
 771 }]])],[g_can_inline=yes],[g_can_inline=no])
 772 AC_MSG_RESULT($g_can_inline)
 773
 774 dnl *** check for working do while(0) macros ***
 775 AC_CACHE_CHECK([for working do while(0) macros], g_cv_support_dowhile_macros, [
 776         AC_TRY_COMPILE([],[
 777         #define STMT_START do
 778         #define STMT_END while(0)
 779         #define STMT_TEST STMT_START { i = 0; } STMT_END
 780         int main(void) { int i = 1; STMT_TEST; return i; }],
 781         [g_cv_support_dowhile_macros=yes],
 782         [g_cv_support_dowhile_macros=no],
 783         [g_cv_support_dowhile_macros=yes])
 784 ])
 785 if test x$g_cv_support_dowhile_macros = xyes; then
 786   AC_DEFINE(HAVE_DOWHILE_MACROS, 1, [define for working do while(0) macros])
 787 fi
 788
 789 # check for flavours of varargs macros
 790 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 791 AC_TRY_COMPILE([],[
 792 int a(int p1, int p2, int p3);
 793 #define call_a(...) a(1,__VA_ARGS__)
 794 call_a(2,3);
 795 ],g_have_iso_c_varargs=yes,g_have_iso_c_varargs=no)
 796 AC_MSG_RESULT($g_have_iso_c_varargs)
 797
 798 AC_MSG_CHECKING(for ISO C99 varargs macros in C++)
 799 AS_IF([test "$CXX" = ""], [
 800 dnl No C++ compiler
 801   g_have_iso_cxx_varargs=no
 802 else
 803   AC_LANG_CPLUSPLUS
 804   AC_TRY_COMPILE([],[
 805 int a(int p1, int p2, int p3);
 806 #define call_a(...) a(1,__VA_ARGS__)
 807 call_a(2,3);
 808 ],g_have_iso_cxx_varargs=yes,g_have_iso_cxx_varargs=no)
 809   AC_LANG_C
 810 ])
 811 AC_MSG_RESULT($g_have_iso_cxx_varargs)
 812
 813 AC_MSG_CHECKING(for GNUC varargs macros)
 814 AC_TRY_COMPILE([],[
 815 int a(int p1, int p2, int p3);
 816 #define call_a(params...) a(1,params)
 817 call_a(2,3);
 818 ],g_have_gnuc_varargs=yes,g_have_gnuc_varargs=no)
 819 AC_MSG_RESULT($g_have_gnuc_varargs)
 820
 821 # check for GNUC visibility support
 822 AC_MSG_CHECKING(for GNUC visibility attribute)
 823 GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 824 void
 825 __attribute__ ((visibility ("hidden")))
 826      f_hidden (void)
 827 {
 828 }
 829 void
 830 __attribute__ ((visibility ("internal")))
 831      f_internal (void)
 832 {
 833 }
 834 void
 835 __attribute__ ((visibility ("protected")))
 836      f_protected (void)
 837 {
 838 }
 839 void
 840 __attribute__ ((visibility ("default")))
 841      f_default (void)
 842 {
 843 }
 844 int main (int argc, char **argv)
 845 {
 846         f_hidden();
 847         f_internal();
 848         f_protected();
 849         f_default();
 850         return 0;
 851 }
 852 ]])],g_have_gnuc_visibility=yes,g_have_gnuc_visibility=no)
 853 AC_MSG_RESULT($g_have_gnuc_visibility)
 854 AM_CONDITIONAL(HAVE_GNUC_VISIBILITY, [test x$g_have_gnuc_visibility = xyes])
 855
 856 AC_MSG_CHECKING([whether using Sun Studio C compiler])
 857 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#if defined(__SUNPRO_C) || (__SUNPRO_C >= 0x550)
 858 #else
 859 # include "error: this is not Sun Studio."
 860 #endif
 861 ]], [[]])], [ g_have_sunstudio_visibility=yes ], [ g_have_sunstudio_visibility=no ])
 862 AC_MSG_RESULT($g_have_sunstudio_visibility)
 863 AM_CONDITIONAL(HAVE_SUNSTUDIO_VISIBILITY, [test x$g_have_sunstudio_visibility = xyes])
 864
 865 # check for bytesex stuff
 866 AC_C_BIGENDIAN
 867 if test x$ac_cv_c_bigendian = xuniversal ; then
 868 AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __BIG_ENDIAN
 869 #else
 870 #error Not a big endian.
 871 #endif],
 872     ac_cv_c_bigendian=yes
 873     ,AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __LITTLE_ENDIAN
 874 #else
 875 #error Not a little endian.
 876 #endif],
 877     ac_cv_c_bigendian=no
 878     ,AC_MSG_WARN([Could not determine endianness.])))
 879 fi
 880
 881
 882 # check for header files
 883 AC_CHECK_HEADERS([dirent.h float.h limits.h pwd.h grp.h sys/param.h sys/poll.h sys/resource.h])
 884 AC_CHECK_HEADERS([sys/time.h sys/times.h sys/wait.h unistd.h values.h])
 885 AC_CHECK_HEADERS([sys/select.h sys/types.h stdint.h inttypes.h sched.h malloc.h])
 886 AC_CHECK_HEADERS([sys/vfs.h sys/vmount.h sys/statfs.h sys/statvfs.h])
 887 AC_CHECK_HEADERS([mntent.h sys/mnttab.h sys/vfstab.h sys/mntctl.h fstab.h])
 888 AC_CHECK_HEADERS([sys/uio.h sys/mkdev.h])
 889 AC_CHECK_HEADERS([linux/magic.h])
 890 AC_CHECK_HEADERS([sys/prctl.h])
 891
 892 AC_CHECK_HEADERS([sys/mount.h sys/sysctl.h], [], [],
 893 [#if HAVE_SYS_PARAM_H
 894  #include <sys/param.h>
 895  #endif
 896 ])
 897
 898 AC_CHECK_HEADERS([xlocale.h])
 899
 900 # check for structure fields
 901 AC_CHECK_MEMBERS([struct stat.st_mtimensec, struct stat.st_mtim.tv_nsec, struct stat.st_atimensec, struct stat.st_atim.tv_nsec, struct stat.st_ctimensec, struct stat.st_ctim.tv_nsec])
 902 AC_CHECK_MEMBERS([struct stat.st_blksize, struct stat.st_blocks, struct statfs.f_fstypename, struct statfs.f_bavail],,, [#include <sys/types.h>
 903 #include <sys/stat.h>
 904 #include <unistd.h>
 905 #ifdef HAVE_SYS_STATFS_H
 906 #include <sys/statfs.h>
 907 #endif
 908 #ifdef HAVE_SYS_PARAM_H
 909 #include <sys/param.h>
 910 #endif
 911 #ifdef HAVE_SYS_MOUNT_H
 912 #include <sys/mount.h>
 913 #endif])
 914 # struct statvfs.f_basetype is available on Solaris but not for Linux.
 915 AC_CHECK_MEMBERS([struct statvfs.f_basetype],,, [#include <sys/statvfs.h>])
 916 AC_CHECK_MEMBERS([struct statvfs.f_fstypename],,, [#include <sys/statvfs.h>])
 917 AC_CHECK_MEMBERS([struct tm.tm_gmtoff, struct tm.__tm_gmtoff],,,[#include <time.h>])
 918
 919 AC_STRUCT_DIRENT_D_TYPE
 920
 921 # Checks for libcharset
 922 AM_LANGINFO_CODESET
 923 AC_CHECK_HEADERS([stddef.h stdlib.h string.h])
 924 AC_CHECK_FUNCS(setlocale)
 925
 926 # check additional type sizes
 927 AC_CHECK_SIZEOF(size_t)
 928
 929 dnl Try to figure out whether gsize, gssize should be long or int
 930 AC_MSG_CHECKING([for the appropriate definition for size_t])
 931
 932 case $ac_cv_sizeof_size_t in
 933   $ac_cv_sizeof_short)
 934       glib_size_type=short
 935       ;;
 936   $ac_cv_sizeof_int)
 937       glib_size_type=int
 938       ;;
 939   $ac_cv_sizeof_long)
 940       glib_size_type=long
 941       ;;
 942   $ac_cv_sizeof_long_long)
 943       glib_size_type='long long'
 944       ;;
 945   $ac_cv_sizeof__int64)
 946       glib_size_type='__int64'
 947       ;;
 948   *)  AC_MSG_ERROR([No type matching size_t in size])
 949       ;;
 950 esac
 951
 952 dnl If int/long are the same size, we see which one produces
 953 dnl warnings when used in the location as size_t. (This matters
 954 dnl on AIX with xlc)
 955 dnl
 956 AS_IF([test $ac_cv_sizeof_size_t = $ac_cv_sizeof_int &&
 957        test $ac_cv_sizeof_size_t = $ac_cv_sizeof_long], [
 958   GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 959 #if defined(_AIX) && !defined(__GNUC__)
 960 #pragma options langlvl=stdc89
 961 #endif
 962 #include <stddef.h>
 963 int main ()
 964 {
 965   size_t s = 1;
 966   unsigned int *size_int = &s;
 967   return (int)*size_int;
 968 }
 969     ]])],glib_size_type=int,
 970       [GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 971 #if defined(_AIX) && !defined(__GNUC__)
 972 #pragma options langlvl=stdc89
 973 #endif
 974 #include <stddef.h>
 975 int main ()
 976 {
 977    size_t s = 1;
 978    unsigned long *size_long = &s;
 979    return (int)*size_long;
 980 }
 981         ]])],glib_size_type=long)])
 982 ])
 983
 984 AC_MSG_RESULT(unsigned $glib_size_type)
 985
 986 # Check for some functions
 987 AC_CHECK_FUNCS(lstat strerror strsignal memmove vsnprintf stpcpy strcasecmp strncasecmp poll getcwd vasprintf setenv unsetenv getc_unlocked readlink symlink fdwalk memmem)
 988 AC_CHECK_FUNCS(chown lchmod lchown fchmod fchown link utimes getgrgid getpwuid)
 989 AC_CHECK_FUNCS(getmntent_r setmntent endmntent hasmntopt getfsstat getvfsstat)
 990 # Check for high-resolution sleep functions
 991 AC_CHECK_FUNCS(splice)
 992 AC_CHECK_FUNCS(prlimit)
 993
 994 # To avoid finding a compatibility unusable statfs, which typically
 995 # successfully compiles, but warns to use the newer statvfs interface:
 996 AS_IF([test $ac_cv_header_sys_statvfs_h = yes], [AC_CHECK_FUNCS([statvfs])])
 997 AS_IF([test $ac_cv_header_sys_statfs_h  = yes -o $ac_cv_header_sys_mount_h = yes], [AC_CHECK_FUNCS([statfs])])
 998
 999 AC_MSG_CHECKING([whether to use statfs or statvfs])
1000 # Some systems have both statfs and statvfs, pick the most "native" for these
1001 AS_IF([test x$ac_cv_func_statfs = xyes && test x$ac_cv_func_statvfs = xyes],
1002    [
1003    # on solaris and irix, statfs doesn't even have the f_bavail field
1004    AS_IF([test x$ac_cv_member_struct_statfs_f_bavail = xno],
1005       [ac_cv_func_statfs=no],
1006    # else, at least on linux, statfs is the actual syscall
1007       [ac_cv_func_statvfs=no])
1008    ])
1009
1010 AS_IF([test x$ac_cv_func_statfs = xyes],
1011       [
1012          AC_DEFINE([USE_STATFS], [1], [Define to use statfs()])
1013          AC_MSG_RESULT([statfs])
1014       ],
1015       [test x$ac_cv_func_statvfs = xyes],
1016       [
1017          AC_DEFINE([USE_STATVFS], [1], [Define to use statvfs()])
1018          AC_MSG_RESULT([statvfs])
1019       ],
1020       [  AC_MSG_RESULT([neither])])
1021
1022 AC_CHECK_HEADERS(crt_externs.h)
1023 AC_CHECK_FUNCS(_NSGetEnviron)
1024
1025 AC_CHECK_FUNCS(newlocale uselocale strtod_l strtoll_l strtoull_l)
1026
1027 AC_FUNC_VSNPRINTF_C99
1028 AC_FUNC_PRINTF_UNIX98
1029
1030 # Internet address families
1031 if test $glib_native_win32 = yes; then
1032   glib_inet_includes=["
1033 #include <winsock2.h>
1034   "]
1035 else
1036   glib_inet_includes=["
1037 #include <sys/types.h>
1038 #include <sys/socket.h>
1039   "]
1040 fi
1041
1042 glib_failed=false
1043 GLIB_CHECK_VALUE(AF_INET, $glib_inet_includes, glib_failed=true)
1044 GLIB_CHECK_VALUE(AF_INET6, $glib_inet_includes, glib_failed=true)
1045 # winsock defines this even though it doesn't support it
1046 GLIB_CHECK_VALUE(AF_UNIX, $glib_inet_includes, glib_failed=true)
1047 if $glib_failed ; then
1048   AC_MSG_ERROR([Could not determine values for AF_INET* constants])
1049 fi
1050
1051 glib_failed=false
1052 GLIB_CHECK_VALUE(MSG_PEEK, $glib_inet_includes, glib_failed=true)
1053 GLIB_CHECK_VALUE(MSG_OOB, $glib_inet_includes, glib_failed=true)
1054 GLIB_CHECK_VALUE(MSG_DONTROUTE, $glib_inet_includes, glib_failed=true)
1055 if $glib_failed ; then
1056   AC_MSG_ERROR([Could not determine values for MSG_* constants])
1057 fi
1058
1059 AC_CHECK_FUNCS(getprotobyname_r endservent if_nametoindex)
1060 AC_CHECK_HEADERS([netdb.h wspiapi.h arpa/nameser_compat.h])
1061
1062 AS_IF([test $glib_native_win32 = no], [
1063   # We can't just use AC_CHECK_FUNC/AC_CHECK_LIB here. Bug 586150
1064   NETWORK_LIBS=""
1065   AC_MSG_CHECKING([for res_query])
1066   AC_TRY_LINK([#include <sys/types.h>
1067                #include <netinet/in.h>
1068                #include <arpa/nameser.h>
1069                #include <resolv.h>
1070               ],[
1071                res_query("test", 0, 0, (void *)0, 0);
1072               ],[AC_MSG_RESULT([yes])],
1073               [save_libs="$LIBS"
1074                LIBS="-lresolv $LIBS"
1075                AC_TRY_LINK([#include <sys/types.h>
1076                             #include <netinet/in.h>
1077                             #include <arpa/nameser.h>
1078                             #include <resolv.h>
1079                            ],[
1080                             res_query("test", 0, 0, (void *)0, 0);
1081                            ],[AC_MSG_RESULT([in -lresolv])
1082                               NETWORK_LIBS="-lresolv $NETWORK_LIBS"],
1083                            [LIBS="-lbind $save_libs"
1084                             AC_TRY_LINK([#include <resolv.h>],
1085                                         [res_query("test", 0, 0, (void *)0, 0);],
1086                                         [AC_MSG_RESULT([in -lbind])
1087                                          NETWORK_LIBS="-lbind $NETWORK_LIBS"],
1088                                         [AC_MSG_ERROR(not found)])])
1089                LIBS="$save_libs"])
1090   AC_CHECK_FUNC(socket, :, AC_CHECK_LIB(socket, socket,
1091                                         [NETWORK_LIBS="-lsocket $NETWORK_LIBS"],
1092                                         [AC_MSG_ERROR(Could not find socket())]))
1093 ])
1094 AC_SUBST(NETWORK_LIBS)
1095
1096 AC_CHECK_HEADER([linux/netlink.h],
1097                 [AC_DEFINE(HAVE_NETLINK, 1, [We have AF_NETLINK sockets])],,
1098                 [#include <sys/socket.h>])
1099 AM_CONDITIONAL(HAVE_NETLINK, [test "$ac_cv_header_linux_netlink_h" = "yes"])
1100
1101 AC_CHECK_TYPE([struct ip_mreqn], [
1102               AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
1103               [#include <netinet/in.h>])
1104
1105 case $host in
1106   *-*-solaris* )
1107      AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1108      AC_DEFINE(_XOPEN_SOURCE,          2, Needed to get declarations for msg_control and msg_controllen on Solaris)
1109      AC_DEFINE(__EXTENSIONS__,         1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1110      ;;
1111 esac
1112
1113 dnl
1114 dnl if statfs() takes 2 arguments (Posix) or 4 (Solaris)
1115 dnl
1116 AS_IF([test "$ac_cv_func_statfs" = yes], [
1117   AC_MSG_CHECKING([number of arguments to statfs()])
1118   AC_TRY_COMPILE([#include <unistd.h>
1119   #ifdef HAVE_SYS_PARAM_H
1120   #include <sys/param.h>
1121   #endif
1122   #ifdef HAVE_SYS_VFS_H
1123   #include <sys/vfs.h>
1124   #endif
1125   #ifdef HAVE_SYS_MOUNT_H
1126   #include <sys/mount.h>
1127   #endif
1128   #ifdef HAVE_SYS_STATFS_H
1129   #include <sys/statfs.h>
1130   #endif], [struct statfs st;
1131   statfs(NULL, &st);],[
1132     AC_MSG_RESULT([2])
1133     AC_DEFINE(STATFS_ARGS, 2, [Number of arguments to statfs()])],[
1134     AC_TRY_COMPILE([#include <unistd.h>
1135   #ifdef HAVE_SYS_PARAM_H
1136   #include <sys/param.h>
1137   #endif
1138   #ifdef HAVE_SYS_VFS_H
1139   #include <sys/vfs.h>
1140   #endif
1141   #ifdef HAVE_SYS_MOUNT_H
1142   #include <sys/mount.h>
1143   #endif
1144   #ifdef HAVE_SYS_STATFS_H
1145   #include <sys/statfs.h>
1146   #endif], [struct statfs st;
1147   statfs(NULL, &st, sizeof (st), 0);],[
1148       AC_MSG_RESULT([4])
1149       AC_DEFINE(STATFS_ARGS, 4, [Number of arguments to statfs()])],[
1150       AC_MSG_RESULT(unknown)
1151       AC_MSG_ERROR([unable to determine number of arguments to statfs()])])])
1152 ])
1153
1154 #
1155 # Check whether to use an included printf
1156 #
1157
1158 AC_ARG_ENABLE(included-printf,
1159               [AC_HELP_STRING([--enable-included-printf],
1160                               [use included printf [default=auto]])],
1161               enable_included_printf="$enableval")
1162
1163 need_included_printf=no
1164 if test "x$enable_included_printf" = "xyes" ; then
1165   need_included_printf=yes
1166 fi
1167 if test "$ac_cv_func_vsnprintf_c99" != "yes" ; then
1168   need_included_printf=yes
1169 fi
1170 if test "$ac_cv_func_printf_unix98" != "yes" ; then
1171   need_included_printf=yes
1172 fi
1173 if test "x$ac_cv_sizeof_long_long" = "x8" &&
1174    test -z "$glib_cv_long_long_format" ; then
1175   need_included_printf=yes
1176 fi
1177
1178 if test "x$enable_included_printf" = "xno" &&
1179    test "x$need_included_printf" = "xyes" ; then
1180   AC_MSG_ERROR([
1181 *** Your C library's printf doesn't appear to have the features that
1182 *** GLib needs, but you specified --enable-included-printf=no.])
1183 fi
1184
1185 enable_included_printf=$need_included_printf
1186
1187 AM_CONDITIONAL(HAVE_GOOD_PRINTF, test "$enable_included_printf" != "yes")
1188 AS_IF([test "$enable_included_printf" != "yes"], [
1189   AC_DEFINE(HAVE_GOOD_PRINTF,1,[define to use system printf])
1190 ], [
1191   if test -z "$glib_cv_long_long_format" ; then
1192     glib_cv_long_long_format="ll"
1193   fi
1194   AC_DEFINE(HAVE_VASPRINTF,1)
1195 ])
1196
1197 # Checks needed for gnulib vasnprintf
1198 bh_C_SIGNED
1199 jm_AC_TYPE_LONG_LONG
1200 gt_TYPE_LONGDOUBLE
1201 gt_TYPE_WCHAR_T
1202 gt_TYPE_WINT_T
1203 AC_TYPE_SIZE_T
1204 AC_CHECK_TYPES(ptrdiff_t)
1205 jm_AC_TYPE_INTMAX_T
1206 AC_CHECK_FUNCS([snprintf wcslen])
1207 AC_FUNC_SNPRINTF_C99
1208
1209 # Check if bcopy can be used for overlapping copies, if memmove isn't found.
1210 # The check is borrowed from the PERL Configure script.
1211 AS_IF([test "$ac_cv_func_memmove" != "yes"],
1212   AC_CACHE_CHECK(whether bcopy can handle overlapping copies,
1213     glib_cv_working_bcopy,[AC_TRY_RUN([
1214       int main() {
1215         char buf[128], abc[128], *b;
1216         int len, off, align;
1217         bcopy("abcdefghijklmnopqrstuvwxyz0123456789", abc, 36);
1218         for (align = 7; align >= 0; align--) {
1219           for (len = 36; len; len--) {
1220             b = buf+align; bcopy(abc, b, len);
1221             for (off = 1; off <= len; off++) {
1222               bcopy(b, b+off, len); bcopy(b+off, b, len);
1223                 if (bcmp(b, abc, len)) return(1);
1224             }
1225           }
1226         }
1227         return(0);
1228       }],glib_cv_working_bcopy=yes,glib_cv_working_bcopy=no)])
1229
1230   GLIB_ASSERT_SET(glib_cv_working_bcopy)
1231   if test "$glib_cv_working_bcopy" = "yes"; then
1232     AC_DEFINE(HAVE_WORKING_BCOPY,1,[Have a working bcopy])
1233   fi
1234 ])
1235
1236 # Check if <sys/select.h> needs to be included for fd_set
1237 AC_MSG_CHECKING([for fd_set])
1238 AC_TRY_COMPILE([#include <sys/types.h>],
1239         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
1240 AS_IF([test "$gtk_ok" = "yes"], [
1241     AC_MSG_RESULT([yes, found in sys/types.h])
1242 ], [
1243     AC_EGREP_HEADER(fd_set, sys/select.h, gtk_ok=yes)
1244     if test "$gtk_ok" = "yes"; then
1245         # *** FIXME: give it a different name
1246         AC_DEFINE(HAVE_SYS_SELECT_H,1,[found fd_set in sys/select.h])
1247         AC_MSG_RESULT([yes, found in sys/select.h])
1248     else
1249         AC_DEFINE(NO_FD_SET,1,[didn't find fd_set])
1250         AC_MSG_RESULT(no)
1251     fi
1252 ])
1253
1254 dnl *** check for sane realloc() ***
1255 AC_CACHE_CHECK([whether realloc (NULL,) will work],glib_cv_sane_realloc,[
1256         AC_TRY_RUN([#include <stdlib.h>
1257         int main() {
1258           return realloc (0, sizeof (int)) == 0;
1259         }],
1260         [glib_cv_sane_realloc=yes],
1261         [glib_cv_sane_realloc=no],
1262         [glib_cv_sane_realloc=yes])
1263 ])
1264 AS_IF([test x$glib_cv_sane_realloc = xyes], [
1265   AC_DEFINE(REALLOC_0_WORKS,1,[whether realloc (NULL,) works])
1266 ])
1267
1268 dnl Check for nl_langinfo and CODESET
1269 AC_CACHE_CHECK([for nl_langinfo (CODESET)],glib_cv_langinfo_codeset,[
1270         AC_TRY_COMPILE([#include <langinfo.h>],
1271                 [char *codeset = nl_langinfo (CODESET);],
1272                 [glib_cv_langinfo_codeset=yes],
1273                 [glib_cv_langinfo_codeset=no])])
1274 if test x$glib_cv_langinfo_codeset = xyes; then
1275   AC_DEFINE(HAVE_CODESET,1,[Have nl_langinfo (CODESET)])
1276 fi
1277
1278 dnl Check for nl_langinfo and LC_TIME parts that are needed in gdatetime.c
1279 AC_CACHE_CHECK([for nl_langinfo (PM_STR)],glib_cv_langinfo_time,[
1280         AC_TRY_COMPILE([#include <langinfo.h>],
1281                 [char *str;
1282                  str = nl_langinfo (PM_STR);
1283                  str = nl_langinfo (D_T_FMT);
1284                  str = nl_langinfo (D_FMT);
1285                  str = nl_langinfo (T_FMT);
1286                  str = nl_langinfo (T_FMT_AMPM);
1287                  str = nl_langinfo (MON_1);
1288                  str = nl_langinfo (ABMON_12);
1289                  str = nl_langinfo (DAY_1);
1290                  str = nl_langinfo (ABDAY_7);],
1291                 [glib_cv_langinfo_time=yes],
1292                 [glib_cv_langinfo_time=no])])
1293 if test x$glib_cv_langinfo_time = xyes; then
1294   AC_DEFINE(HAVE_LANGINFO_TIME,1,[Have nl_langinfo (PM_STR)])
1295 fi
1296
1297 dnl Check for nl_langinfo and _NL_CTYPE_OUTDIGITn_MB
1298 AC_CACHE_CHECK([for nl_langinfo (_NL_CTYPE_OUTDIGITn_MB)], glib_cv_langinfo_outdigit,[
1299         AC_TRY_COMPILE([#include <langinfo.h>],
1300                 [char *str;
1301                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT0_MB);
1302                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT1_MB);
1303                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT2_MB);
1304                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT3_MB);
1305                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT4_MB);
1306                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT5_MB);
1307                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT6_MB);
1308                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT7_MB);
1309                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT8_MB);
1310                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT9_MB);],
1311                 [glib_cv_langinfo_outdigit=yes],
1312                 [glib_cv_langinfo_outdigit=no])])
1313 if test x$glib_cv_langinfo_outdigit = xyes; then
1314   AC_DEFINE(HAVE_LANGINFO_OUTDIGIT,1,[Have nl_langinfo (_NL_CTYPE_OUTDIGITn_MB)])
1315 fi
1316
1317 dnl ****************************************
1318 dnl *** posix_memalign                   ***
1319 dnl ****************************************
1320 AC_MSG_CHECKING(for a compliant posix_memalign() implementation)
1321 AC_CACHE_VAL(glib_cv_compliant_posix_memalign,[
1322     glib_cv_compliant_posix_memalign=0
1323     if test "$ac_cv_func_posix_memalign" = "yes" ; then
1324         AC_TRY_RUN([
1325                 #define _XOPEN_SOURCE 600
1326                 #include <stdlib.h> /* posix_memalign() should be defined here */
1327                 /* some systems break if #include <malloc.h> used */
1328                 static void test_memalign (size_t boundary, size_t size) {
1329                     void *mem = 0;
1330                     if (posix_memalign (&mem, boundary, size) != 0 || !mem)
1331                         exit (1);
1332                     else
1333                       free (mem);
1334                 }
1335                 int main() {
1336                     test_memalign (  128,   128 - 2 * sizeof (void*));
1337                     test_memalign (  256,   256 - 2 * sizeof (void*));
1338                     test_memalign (  512,   512 - 2 * sizeof (void*));
1339                     test_memalign ( 1024,  1024 - 2 * sizeof (void*));
1340                     test_memalign ( 2048,  2048 - 2 * sizeof (void*));
1341                     test_memalign ( 4096,  4096 - 2 * sizeof (void*));
1342                     test_memalign ( 8192,  8192 - 2 * sizeof (void*));
1343                     test_memalign (16384, 16384 - 2 * sizeof (void*));
1344                     test_memalign (32768, 32768 - 2 * sizeof (void*));
1345                     exit (0); /* success */
1346                 }
1347                 ],
1348             [glib_cv_compliant_posix_memalign=1], [], [:])
1349       :
1350     fi
1351     ])
1352 AS_IF([test "$glib_cv_compliant_posix_memalign" = "1"], [
1353     AC_MSG_RESULT(yes)
1354     AC_DEFINE(POSIX_MEMALIGN_WITH_COMPLIANT_ALLOCS, 1, [define if posix_memalign() can allocate any size])
1355 ], [
1356     AC_MSG_RESULT(no)
1357 ])
1358
1359
1360 dnl ****************************************
1361 dnl *** strlcpy/strlcat                  ***
1362 dnl ****************************************
1363 # Check for strlcpy
1364 AC_CACHE_CHECK([for OpenBSD strlcpy/strlcat],glib_cv_have_strlcpy,[
1365 AC_TRY_RUN([#include <stdlib.h>
1366 #include <string.h>
1367 int main() {
1368   char p[10];
1369   (void) strlcpy (p, "hi", 10);
1370   if (strlcat (p, "bye", 0) != 3)
1371     return 1;
1372   return 0;
1373 }], glib_cv_have_strlcpy=yes,
1374     glib_cv_have_strlcpy=no,
1375     glib_cv_have_strlcpy=no)])
1376 if test "$glib_cv_have_strlcpy" = "yes"; then
1377     AC_DEFINE(HAVE_STRLCPY,1,[Have functions strlcpy and strlcat])
1378 fi
1379
1380
1381 dnl **********************
1382 dnl *** va_copy checks ***
1383 dnl **********************
1384 dnl we currently check for all three va_copy possibilities, so we get
1385 dnl all results in config.log for bug reports.
1386 AC_CACHE_CHECK([for an implementation of va_copy()],glib_cv_va_copy,[
1387         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1388 #include <stdlib.h>
1389         void f (int i, ...) {
1390         va_list args1, args2;
1391         va_start (args1, i);
1392         va_copy (args2, args1);
1393         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1394           exit (1);
1395         va_end (args1); va_end (args2);
1396         }
1397         int main() {
1398           f (0, 42);
1399           return 0;
1400         }]])],
1401         [glib_cv_va_copy=yes],
1402         [glib_cv_va_copy=no])
1403 ])
1404 AC_CACHE_CHECK([for an implementation of __va_copy()],glib_cv___va_copy,[
1405         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1406 #include <stdlib.h>
1407         void f (int i, ...) {
1408         va_list args1, args2;
1409         va_start (args1, i);
1410         __va_copy (args2, args1);
1411         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1412           exit (1);
1413         va_end (args1); va_end (args2);
1414         }
1415         int main() {
1416           f (0, 42);
1417           return 0;
1418         }]])],
1419         [glib_cv___va_copy=yes],
1420         [glib_cv___va_copy=no])
1421 ])
1422
1423 if test "x$glib_cv_va_copy" = "xyes"; then
1424   g_va_copy_func=va_copy
1425 else if test "x$glib_cv___va_copy" = "xyes"; then
1426   g_va_copy_func=__va_copy
1427 fi
1428 fi
1429
1430 if test -n "$g_va_copy_func"; then
1431   AC_DEFINE_UNQUOTED(G_VA_COPY,$g_va_copy_func,[A 'va_copy' style function])
1432 fi
1433
1434 AC_CACHE_CHECK([whether va_lists can be copied by value],glib_cv_va_val_copy,[
1435         AC_TRY_RUN([#include <stdarg.h>
1436 #include <stdlib.h>
1437         void f (int i, ...) {
1438         va_list args1, args2;
1439         va_start (args1, i);
1440         args2 = args1;
1441         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1442           exit (1);
1443         va_end (args1); va_end (args2);
1444         }
1445         int main() {
1446           f (0, 42);
1447           return 0;
1448         }],
1449         [glib_cv_va_val_copy=yes],
1450         [glib_cv_va_val_copy=no],
1451         [glib_cv_va_val_copy=yes])
1452 ])
1453
1454 AS_IF([ test "x$glib_cv_va_val_copy" = "xno"], [
1455   AC_DEFINE(G_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
1456 ])
1457
1458 dnl ***********************
1459 dnl *** g_module checks ***
1460 dnl ***********************
1461 G_MODULE_LIBS=
1462 G_MODULE_LIBS_EXTRA=
1463 G_MODULE_PLUGIN_LIBS=
1464 if test x"$glib_native_win32" = xyes; then
1465   dnl No use for this on Win32
1466   G_MODULE_LDFLAGS=
1467 else
1468   export SED
1469   G_MODULE_LDFLAGS=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1470 fi
1471 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
1472 G_MODULE_NEED_USCORE=0
1473 G_MODULE_BROKEN_RTLD_GLOBAL=0
1474 G_MODULE_HAVE_DLERROR=0
1475 dnl *** force native WIN32 shared lib loader
1476 if test -z "$G_MODULE_IMPL"; then
1477   case "$host" in
1478   *-*-mingw*|*-*-cygwin*) G_MODULE_IMPL=G_MODULE_IMPL_WIN32 ;;
1479   esac
1480 fi
1481 dnl *** force native AIX library loader
1482 dnl *** dlopen() filepath must be of the form /path/libname.a(libname.so)
1483 if test -z "$G_MODULE_IMPL"; then
1484   case "$host" in
1485   *-*-aix*) G_MODULE_IMPL=G_MODULE_IMPL_AR ;;
1486   esac
1487 fi
1488 dnl *** dlopen() and dlsym() in system libraries
1489 AS_IF([ test -z "$G_MODULE_IMPL"], [
1490         AC_CHECK_FUNC(dlopen,
1491                       [AC_CHECK_FUNC(dlsym,
1492                                      [G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1493                       [])
1494 ])
1495 dnl *** load_image (BeOS)
1496 AS_IF([test -z "$G_MODULE_IMPL" && test "x$glib_native_beos" = "xyes"], [
1497   AC_CHECK_LIB(root, load_image,
1498       [G_MODULE_LIBS="-lbe -lroot -lglib-2.0 "
1499       G_MODULE_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
1500       G_MODULE_PLUGIN_LIBS="-L\$(top_builddir_full)/gmodule/.libs -lgmodule"
1501       G_MODULE_IMPL=G_MODULE_IMPL_BEOS],
1502       [])
1503 ])
1504 dnl *** NSLinkModule (dyld) in system libraries (Darwin)
1505 AS_IF([ test -z "$G_MODULE_IMPL" ], [
1506         AC_CHECK_FUNC(NSLinkModule,
1507                       [G_MODULE_IMPL=G_MODULE_IMPL_DYLD
1508                        G_MODULE_NEED_USCORE=1],
1509                       [])
1510 ])
1511 dnl *** dlopen() and dlsym() in libdl
1512 AS_IF([ test -z "$G_MODULE_IMPL"], [
1513         AC_CHECK_LIB(dl, dlopen,
1514                      [AC_CHECK_LIB(dl, dlsym,
1515                                    [G_MODULE_LIBS=-ldl
1516                                    G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1517                      [])
1518 ])
1519 dnl *** shl_load() in libdld (HP-UX)
1520 AS_IF([ test -z "$G_MODULE_IMPL"], [
1521         AC_CHECK_LIB(dld, shl_load,
1522                 [G_MODULE_LIBS=-ldld
1523                 G_MODULE_IMPL=G_MODULE_IMPL_DLD],
1524                 [])
1525 ])
1526 dnl *** additional checks for G_MODULE_IMPL_DL
1527 AS_IF([ test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL" ], [
1528         LIBS_orig="$LIBS"
1529         LDFLAGS_orig="$LDFLAGS"
1530         LIBS="$G_MODULE_LIBS $LIBS"
1531         LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
1532 dnl *** check for OSF1/5.0 RTLD_GLOBAL brokenness
1533         echo "void glib_plugin_test(void) { }" > plugin.c
1534         ${SHELL} ./libtool --mode=compile --tag=CC ${CC} ${CFLAGS} \
1535                 ${CPPFLAGS} -c -o plugin.lo plugin.c >/dev/null 2>&1
1536         ${SHELL} ./libtool --mode=link --tag=CC ${CC} ${CFLAGS} \
1537                 ${LDFLAGS} -module -o plugin.la -export-dynamic \
1538                 -shrext ".o" -avoid-version plugin.lo \
1539                 -rpath /dont/care >/dev/null 2>&1
1540         eval `./libtool --config | grep ^objdir`
1541         AC_CACHE_CHECK([for RTLD_GLOBAL brokenness],
1542                 glib_cv_rtldglobal_broken,[
1543                 AC_TRY_RUN([
1544 #include <dlfcn.h>
1545 #ifndef RTLD_GLOBAL
1546 #  define RTLD_GLOBAL 0
1547 #endif
1548 #ifndef RTLD_LAZY
1549 #  define RTLD_LAZY 0
1550 #endif
1551 int glib_plugin_test;
1552 int main () {
1553     void *handle, *global, *local;
1554     global = &glib_plugin_test;
1555     handle = dlopen ("./$objdir/plugin.o", RTLD_GLOBAL | RTLD_LAZY);
1556     if (!handle) return 0;
1557     local = dlsym (handle, "glib_plugin_test");
1558     return global == local;
1559 }                       ],
1560                         [glib_cv_rtldglobal_broken=no],
1561                         [glib_cv_rtldglobal_broken=yes],
1562                         [glib_cv_rtldglobal_broken=no])
1563                 rm -f plugin.c plugin.o plugin.lo plugin.la ${objdir}/plugin.*
1564                 rmdir ${objdir} 2>/dev/null
1565         ])
1566         if test "x$glib_cv_rtldglobal_broken" = "xyes"; then
1567                 G_MODULE_BROKEN_RTLD_GLOBAL=1
1568         else
1569                 G_MODULE_BROKEN_RTLD_GLOBAL=0
1570         fi
1571 dnl *** check whether we need preceeding underscores
1572         AC_CACHE_CHECK([for preceeding underscore in symbols],
1573                 glib_cv_uscore,[
1574                 AC_TRY_RUN([#include <dlfcn.h>
1575                 int glib_underscore_test (void) { return 42; }
1576                 int main() {
1577                   void *f1 = (void*)0, *f2 = (void*)0, *handle;
1578                   handle = dlopen ((void*)0, 0);
1579                   if (handle) {
1580                     f1 = dlsym (handle, "glib_underscore_test");
1581                     f2 = dlsym (handle, "_glib_underscore_test");
1582                   } return (!f2 || f1);
1583                 }],
1584                         [glib_cv_uscore=yes],
1585                         [glib_cv_uscore=no],
1586                         [])
1587                 rm -f plugin.c plugin.$ac_objext plugin.lo
1588         ])
1589         GLIB_ASSERT_SET(glib_cv_uscore)
1590         if test "x$glib_cv_uscore" = "xyes"; then
1591                 G_MODULE_NEED_USCORE=1
1592         else
1593                 G_MODULE_NEED_USCORE=0
1594         fi
1595
1596         LDFLAGS="$LDFLAGS_orig"
1597 dnl *** check for having dlerror()
1598         AC_CHECK_FUNC(dlerror,
1599                 [G_MODULE_HAVE_DLERROR=1],
1600                 [G_MODULE_HAVE_DLERROR=0])
1601         LIBS="$LIBS_orig"
1602 ])
1603 dnl *** done, have we got an implementation?
1604 if test -z "$G_MODULE_IMPL"; then
1605         G_MODULE_IMPL=0
1606         G_MODULE_SUPPORTED=false
1607 else
1608         G_MODULE_SUPPORTED=true
1609 fi
1610
1611 AC_MSG_CHECKING(for the suffix of module shared libraries)
1612 export SED
1613 shrext_cmds=`./libtool --config | grep '^shrext_cmds='`
1614 eval $shrext_cmds
1615 module=yes eval std_shrext=$shrext_cmds
1616 # chop the initial dot
1617 glib_gmodule_suffix=`echo $std_shrext | sed 's/^\.//'`
1618 AC_MSG_RESULT(.$glib_gmodule_suffix)
1619 # any reason it may fail?
1620 if test "x$glib_gmodule_suffix" = x; then
1621         AC_MSG_ERROR(Cannot determine shared library suffix from libtool)
1622 fi
1623
1624 AC_SUBST(G_MODULE_SUPPORTED)
1625 AC_SUBST(G_MODULE_IMPL)
1626 AC_SUBST(G_MODULE_LIBS)
1627 AC_SUBST(G_MODULE_LIBS_EXTRA)
1628 AC_SUBST(G_MODULE_PLUGIN_LIBS)
1629 AC_SUBST(G_MODULE_LDFLAGS)
1630 AC_SUBST(G_MODULE_HAVE_DLERROR)
1631 AC_SUBST(G_MODULE_BROKEN_RTLD_GLOBAL)
1632 AC_SUBST(G_MODULE_NEED_USCORE)
1633 AC_SUBST(GLIB_DEBUG_FLAGS)
1634
1635 dnl **********************
1636 dnl *** g_spawn checks ***
1637 dnl **********************
1638
1639 AC_MSG_CHECKING(for gspawn implementation)
1640 case "$host" in
1641   *-*-mingw*)
1642     GSPAWN=gspawn-win32.lo
1643     ;;
1644   *)
1645     GSPAWN=gspawn.lo
1646     ;;
1647 esac
1648 AC_MSG_RESULT($GSPAWN)
1649 AC_SUBST(GSPAWN)
1650
1651 dnl *************************
1652 dnl *** GIOChannel checks ***
1653 dnl *************************
1654
1655 AC_MSG_CHECKING(for GIOChannel implementation)
1656 case "$host" in
1657   *-*-mingw*)
1658     GIO=giowin32.lo
1659     ;;
1660   *)
1661     GIO=giounix.lo
1662     ;;
1663 esac
1664 AC_MSG_RESULT($GIO)
1665 AC_SUBST(GIO)
1666
1667 dnl *********************************
1668 dnl *** Directory for GIO modules ***
1669 dnl *********************************
1670
1671 AC_ARG_WITH(gio-module-dir,
1672            [AC_HELP_STRING([--with-gio-module-dir=DIR],
1673                            [load gio modules from this directory [LIBDIR/gio/modules]])],
1674            [],
1675            [with_gio_module_dir='${libdir}/gio/modules'])
1676 GIO_MODULE_DIR=$with_gio_module_dir
1677 AC_SUBST(GIO_MODULE_DIR)
1678
1679 dnl **********************************
1680 dnl *** Check for libselinux (GIO) ***
1681 dnl **********************************
1682 AC_ARG_ENABLE(selinux,
1683               AC_HELP_STRING([--disable-selinux],
1684                              [build without selinux support]))
1685 msg_selinux=no
1686 SELINUX_LIBS=
1687 AS_IF([ test "x$enable_selinux" != "xno"], [
1688
1689  AC_CHECK_LIB(selinux, is_selinux_enabled,
1690    [AC_CHECK_HEADERS(selinux/selinux.h,
1691      [AC_CHECK_LIB(selinux, lgetfilecon_raw,
1692        [AC_DEFINE(HAVE_SELINUX, 1, [Define to 1 if libselinux is available])
1693         SELINUX_LIBS="-lselinux"
1694         msg_selinux=yes])
1695      ])
1696    ])
1697 ])
1698 AC_SUBST(SELINUX_LIBS)
1699
1700 dnl *****************************
1701 dnl ** Check for inotify (GIO) **
1702 dnl *****************************
1703 inotify_support=no
1704 AC_CHECK_HEADERS([sys/inotify.h],
1705 [
1706         inotify_support=yes
1707         AC_CHECK_FUNCS(inotify_init1)
1708 ])
1709
1710 AM_CONDITIONAL(HAVE_INOTIFY, [test "$inotify_support" = "yes"])
1711
1712 dnl *********************************
1713 dnl ** Check for Solaris FEN (GIO) **
1714 dnl *********************************
1715 fen_support=no
1716 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
1717 #include <port.h>
1718 #ifndef PORT_SOURCE_FILE
1719 #error "Please upgrade to Nevada 72 or above to suppoert FEN"
1720 #endif
1721 int main() { return 0; } ]])],
1722 [
1723         fen_support=yes
1724 ],)
1725
1726 AM_CONDITIONAL(HAVE_FEN, [test "$fen_support" = "yes"])
1727
1728 dnl ****************************
1729 dnl *** Checks for FAM (GIO) ***
1730 dnl ****************************
1731
1732 should_disable_fam=no
1733
1734 AC_ARG_ENABLE(fam,
1735               AC_HELP_STRING([--disable-fam],
1736                              [don't use fam for file system monitoring]),
1737                          [
1738                                 if test "x$enable_fam" = "xno"; then
1739                                         should_disable_fam=yes
1740                                 fi
1741                          ]
1742                          )
1743 fam_support=no
1744 FAM_LIBS=
1745 if test "x$should_disable_fam" = "xno"; then
1746 AC_CHECK_LIB(fam, FAMOpen,
1747   [AC_CHECK_HEADERS(fam.h,
1748     [AC_DEFINE(HAVE_FAM, [], [Define if we have FAM])
1749      AC_CHECK_LIB(fam, FAMNoExists,
1750                   AC_DEFINE(HAVE_FAM_NO_EXISTS, [], [Define if we have FAMNoExists in fam]))
1751      FAM_LIBS="-lfam"]
1752      fam_support=yes,
1753     AC_MSG_WARN(*** FAM support will not be built (header files not found) ***))],
1754   AC_MSG_WARN(*** FAM support will not be built (FAM library not found) ***))
1755 AC_SUBST(FAM_LIBS)
1756 fi
1757 AM_CONDITIONAL(HAVE_FAM, [test "$fam_support" = "yes"])
1758
1759
1760 dnl *****************************
1761 dnl *** Check for xattr (GIO) ***
1762 dnl *****************************
1763 AC_ARG_ENABLE(xattr,
1764               AC_HELP_STRING([--disable-xattr], [build without xattr support]))
1765 msg_xattr=no
1766 XATTR_LIBS=
1767 AS_IF([ test "x$enable_xattr" != "xno"], [
1768
1769 dnl either glibc or libattr can provide xattr support
1770
1771 dnl for both of them, we check for getxattr being in
1772 dnl the library and a valid xattr header.
1773
1774 dnl try glibc
1775  AC_CHECK_LIB(c, getxattr,
1776    [AC_CHECK_HEADERS(sys/xattr.h,
1777      [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1778       msg_xattr=yes])
1779    ])
1780
1781   AS_IF([ test "x$msg_xattr" != "xyes"], [
1782 dnl   failure. try libattr
1783    AC_CHECK_LIB(attr, getxattr,
1784       [AC_CHECK_HEADERS(attr/xattr.h,
1785        [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1786         XATTR_LIBS="-lattr"
1787         msg_xattr=yes])
1788       ])
1789   ])
1790
1791   AS_IF([ test "x$msg_xattr" = "xyes"], [
1792     AC_MSG_CHECKING([for XATTR_NOFOLLOW])
1793     AC_TRY_COMPILE([
1794       #include <stdio.h>
1795       #ifdef HAVE_SYS_TYPES_H
1796       #include <sys/types.h>
1797       #endif
1798       #ifdef HAVE_SYS_XATTR_H
1799       #include <sys/xattr.h>
1800       #elif HAVE_ATTR_XATTR_H
1801       #include <attr/xattr.h>
1802       #endif
1803     ],
1804     [ssize_t len = getxattr("", "", NULL, 0, 0, XATTR_NOFOLLOW);],
1805     [
1806       AC_DEFINE([HAVE_XATTR_NOFOLLOW], [1], [Define to 1 if xattr API uses XATTR_NOFOLLOW])
1807       AC_MSG_RESULT([yes])
1808     ],
1809     [AC_MSG_RESULT([no])]
1810     )
1811   ])
1812 ])
1813 AC_SUBST(XATTR_LIBS)
1814
1815 dnl ************************
1816 dnl *** check for libelf ***
1817 dnl ************************
1818
1819 PKG_CHECK_MODULES([LIBELF], [libelf], [have_libelf=yes], [have_libelf=maybe])
1820
1821 AS_IF([ test $have_libelf = maybe], [
1822   glib_save_LIBS=$LIBS
1823   AC_CHECK_LIB([elf], [elf_begin], , [have_libelf=no])
1824   AC_CHECK_LIB([elf], [elf_getshdrstrndx], , [have_libelf=no])
1825   AC_CHECK_LIB([elf], [elf_getshdrnum], , [have_libelf=no])
1826   AC_CHECK_HEADER([libelf.h], , [have_libelf=no])
1827   LIBS=$glib_save_LIBS
1828
1829   if test $have_libelf != no; then
1830     LIBELF_LIBS=-lelf
1831     have_libelf=yes
1832   fi
1833 ])
1834
1835 if test $have_libelf = yes; then
1836   AC_DEFINE(HAVE_LIBELF, 1, [Define if libelf is available])
1837 fi
1838
1839 dnl ****************************************
1840 dnl *** platform dependent source checks ***
1841 dnl ****************************************
1842
1843 AC_MSG_CHECKING(for platform-dependent source)
1844 case "$host" in
1845   *-*-cygwin*|*-*-mingw*)
1846     PLATFORMDEP=gwin32.lo
1847     ;;
1848   *)
1849     PLATFORMDEP=
1850     ;;
1851 esac
1852 AC_MSG_RESULT($PLATFORMDEP)
1853 AC_SUBST(PLATFORMDEP)
1854
1855 AC_MSG_CHECKING([whether to compile timeloop])
1856 case "$host" in
1857   *-*-cygwin*|*-*-mingw*|*-*-minix)
1858     enable_timeloop=no
1859     ;;
1860   *)
1861     enable_timeloop=yes
1862     ;;
1863 esac
1864 AC_MSG_RESULT($enable_timeloop)
1865 AM_CONDITIONAL(ENABLE_TIMELOOP, test x$enable_timeloop = xyes)
1866
1867 AC_MSG_CHECKING([if building for some Win32 platform])
1868 case "$host" in
1869   *-*-mingw*|*-*-cygwin*)
1870     platform_win32=yes
1871     ;;
1872   *)
1873     platform_win32=no
1874     ;;
1875 esac
1876 AC_MSG_RESULT($platform_win32)
1877 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
1878
1879 dnl ***********************
1880 dnl *** g_thread checks ***
1881 dnl ***********************
1882
1883 AC_ARG_WITH(threads,
1884            [AC_HELP_STRING([--with-threads=@<:@posix/win32@:>@],
1885                            [specify a thread implementation to use])],
1886            [],
1887            [with_threads=yes])
1888
1889 dnl error and warning message
1890 dnl *************************
1891
1892 THREAD_NO_IMPLEMENTATION="No thread implementation found."
1893
1894 FLAG_DOES_NOT_WORK="I can't find the MACRO to enable thread safety on your
1895                 platform (normally it's "_REENTRANT"). I'll not use any flag on
1896                 compilation now, but then your programs might not work.
1897                 Please provide information on how it is done on your system."
1898
1899 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
1900                  "
1901
1902 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
1903                   provide information on your thread implementation."
1904
1905 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
1906                 functions will not be MT-safe during their first call because
1907                 there is no working 'getpwuid_r' on your system."
1908
1909 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
1910                 because there is no 'localtime_r' on your system."
1911
1912 AIX_COMPILE_INFO="AIX's C compiler needs to be called by a different name, when
1913                 linking threaded applications. As GLib cannot do that
1914                 automatically, you will get an linkg error everytime you are
1915                 not using the right compiler. In that case you have to relink
1916                 with the right compiler. Ususally just '_r' is appended
1917                 to the compiler name."
1918
1919 dnl determination of thread implementation
1920 dnl ***************************************
1921
1922 AC_MSG_CHECKING(for thread implementation)
1923
1924 have_threads=no
1925 AS_IF([ test "x$with_threads" = xyes || test "x$with_threads" = xposix], [
1926         # -D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE is for DG/UX
1927         # -U_OSF_SOURCE is for Digital UNIX 4.0d
1928         GTHREAD_COMPILE_IMPL_DEFINES="-D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE -U_OSF_SOURCE"
1929         glib_save_CPPFLAGS="$CPPFLAGS"
1930         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1931         AS_IF([ test "x$have_threads" = xno], [
1932                 AC_TRY_COMPILE([#include <pthread.h>],
1933                         [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1934                         have_threads=posix)
1935         ])
1936         # Tru64Unix requires -pthread to find pthread.h. See #103020
1937         CPPFLAGS="$CPPFLAGS -pthread"
1938         if test "x$have_threads" = xno; then
1939         AC_TRY_COMPILE([#include <pthread.h>],
1940                        [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1941                        have_threads=posix)
1942         fi
1943         CPPFLAGS="$glib_save_CPPFLAGS"
1944 ])
1945 if test "x$with_threads" = xyes || test "x$with_threads" = xwin32; then
1946         case $host in
1947                 *-*-mingw*)
1948                 have_threads=win32
1949                 ;;
1950         esac
1951 fi
1952
1953 if test "x$have_threads" = xno; then
1954         AC_MSG_RESULT(none available)
1955         AC_MSG_ERROR($THREAD_NO_IMPLEMENTATION)
1956 else
1957         AC_MSG_RESULT($have_threads)
1958 fi
1959
1960
1961 dnl determination of G_THREAD_CFLAGS
1962 dnl ********************************
1963
1964 G_THREAD_LIBS=
1965 G_THREAD_LIBS_EXTRA=
1966 G_THREAD_CFLAGS=
1967
1968 dnl
1969 dnl Test program for basic POSIX threads functionality
1970 dnl
1971 m4_define([glib_thread_test],[
1972 #include <pthread.h>
1973 int check_me = 0;
1974 void* func(void* data) {check_me = 42; return &check_me;}
1975 int main()
1976  { pthread_t t;
1977    void *ret;
1978    pthread_create (&t, $1, func, 0);
1979    pthread_join (t, &ret);
1980    return (check_me != 42 || ret != &check_me);
1981 }])
1982
1983 AS_IF([ test x"$have_threads" = xposix], [
1984   # First we test for posix, whether -pthread or -pthreads do the trick as
1985   # both CPPFLAG and LIBS.
1986   # One of them does for most gcc versions and some other platforms/compilers
1987   # too and could be considered as the canonical way to go.
1988   case $host in
1989     *-*-cygwin*|*-*-darwin*)
1990        # skip cygwin and darwin -pthread or -pthreads test
1991        ;;
1992     *-solaris*)
1993       # These compiler/linker flags work with both Sun Studio and gcc
1994       # Sun Studio expands -mt to -D_REENTRANT and -lthread
1995       # gcc expands -pthreads to -D_REENTRANT -D_PTHREADS -lpthread
1996       G_THREAD_CFLAGS="-D_REENTRANT -D_PTHREADS"
1997       G_THREAD_LIBS="-lpthread -lthread"
1998       ;;
1999     *)
2000       for flag in pthread pthreads mt; do
2001         glib_save_CFLAGS="$CFLAGS"
2002         CFLAGS="$CFLAGS -$flag"
2003         AC_TRY_RUN(glib_thread_test(0),
2004                    glib_flag_works=yes,
2005                    glib_flag_works=no,
2006                    [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test(0))],
2007                                    glib_flag_works=yes,
2008                                    glib_flag_works=no)])
2009         CFLAGS="$glib_save_CFLAGS"
2010         if test $glib_flag_works = yes ; then
2011            G_THREAD_CFLAGS=-$flag
2012         G_THREAD_LIBS=-$flag
2013         break;
2014         fi
2015       done
2016        ;;
2017   esac
2018 ])
2019
2020 AS_IF([ test x"$G_THREAD_CFLAGS" = x], [
2021
2022   # The canonical -pthread[s] does not work. Try something different.
2023
2024   case $host in
2025         *-aix*)
2026                 if test x"$GCC" = xyes; then
2027                         # GCC 3.0 and above needs -pthread.
2028                         # Should be coverd by the case above.
2029                         # GCC 2.x and below needs -mthreads
2030                         G_THREAD_CFLAGS="-mthreads"
2031                         G_THREAD_LIBS=$G_THREAD_CFLAGS
2032                 else
2033                         # We are probably using the aix compiler. Normaly a
2034                         # program would have to be compiled with the _r variant
2035                         # of the corresponding compiler, but we as GLib cannot
2036                         # do that: but the good news is that for compiling the
2037                         # only difference is the added -D_THREAD_SAFE compile
2038                         # option. This is according to the "C for AIX User's
2039                         # Guide".
2040                         G_THREAD_CFLAGS="-D_THREAD_SAFE"
2041                 fi
2042                 ;;
2043         *-dg-dgux*)  # DG/UX
2044                 G_THREAD_CFLAGS="-D_REENTRANT -D_POSIX4A_DRAFT10_SOURCE"
2045                 ;;
2046         *-sysv5uw7*) # UnixWare 7
2047                 # We are not using gcc with -pthread. Catched above.
2048                 G_THREAD_CFLAGS="-Kthread"
2049                 G_THREAD_LIBS=$G_THREAD_CFLAGS
2050                 ;;
2051         *-mingw*)
2052                 # No flag needed when using MSVCRT.DLL
2053                 G_THREAD_CFLAGS=""
2054                 ;;
2055         *)
2056                 G_THREAD_CFLAGS="-D_REENTRANT" # good default guess otherwise
2057                 ;;
2058   esac
2059 ])
2060
2061 # if we are not finding the localtime_r function, then we probably are
2062 # not using the proper multithread flag
2063
2064 glib_save_CPPFLAGS="$CPPFLAGS"
2065 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2066
2067 # First we test, whether localtime_r is declared in time.h
2068 # directly. Then we test whether a macro localtime_r exists, in
2069 # which case localtime_r in the test program is replaced and thus
2070 # if we still find localtime_r in the output, it is not defined as
2071 # a macro.
2072
2073 AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>], ,
2074   [AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>
2075                                                            localtime_r(a,b)],
2076                    AC_MSG_WARN($FLAG_DOES_NOT_WORK))])
2077
2078 CPPFLAGS="$glib_save_CPPFLAGS"
2079
2080 AC_MSG_CHECKING(thread related cflags)
2081 AC_MSG_RESULT($G_THREAD_CFLAGS)
2082 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2083
2084 dnl determination of G_THREAD_LIBS
2085 dnl ******************************
2086
2087 AS_IF([test x$have_threads = xposix], [
2088           glib_save_CPPFLAGS="$CPPFLAGS"
2089           CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2090           AS_IF([ test x"$G_THREAD_LIBS" = x ], [
2091             case $host in
2092               *-aix*)
2093                 # We are not using gcc (would have set G_THREAD_LIBS) and thus
2094                 # probably using the aix compiler.
2095                 AC_MSG_WARN($AIX_COMPILE_INFO)
2096                 ;;
2097               *)
2098                 G_THREAD_LIBS=error
2099                 glib_save_LIBS="$LIBS"
2100                 for thread_lib in "" pthread pthread32 pthreads thread; do
2101                         if test x"$thread_lib" = x; then
2102                                 add_thread_lib=""
2103                                 IN=""
2104                         else
2105                                 add_thread_lib="-l$thread_lib"
2106                                 IN=" in -l$thread_lib"
2107                         fi
2108                         if test x"$have_threads" = xposix; then
2109                                 defattr=0
2110                         else
2111                                 defattr=pthread_attr_default
2112                         fi
2113
2114                         LIBS="$add_thread_lib $glib_save_LIBS"
2115
2116                         AC_MSG_CHECKING(for pthread_create/pthread_join$IN)
2117                         AC_TRY_RUN(glib_thread_test($defattr),
2118                                    glib_result=yes,
2119                                    glib_result=no,
2120                                    [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test($defattr))],
2121                                                    glib_result=yes,
2122                                                    glib_result=no)])
2123                         AC_MSG_RESULT($glib_result)
2124
2125                         if test "$glib_result" = "yes" ; then
2126                           G_THREAD_LIBS="$add_thread_lib"
2127                           break
2128                         fi
2129                 done
2130                 if test "x$G_THREAD_LIBS" = xerror; then
2131                   AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2132                 fi
2133                 LIBS="$glib_save_LIBS"
2134                 ;;
2135             esac
2136           ])
2137
2138           g_threads_impl="POSIX"
2139           AC_SUBST(GTHREAD_COMPILE_IMPL_DEFINES)
2140           CPPFLAGS="$glib_save_CPPFLAGS"
2141 ], [test x$have_threads = xwin32], [
2142            g_threads_impl="WIN32"
2143 ], [
2144            g_threads_impl="NONE"
2145            G_THREAD_LIBS=error
2146 ])
2147
2148 if test "x$G_THREAD_LIBS" = xerror; then
2149         AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2150 fi
2151
2152 case $host in
2153   *-*-beos*)
2154     G_THREAD_LIBS="-lbe -lroot -lglib-2.0 "
2155     G_THREAD_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
2156     ;;
2157   *)
2158     ;;
2159 esac
2160
2161 AC_MSG_CHECKING(thread related libraries)
2162 AC_MSG_RESULT($G_THREAD_LIBS)
2163
2164 dnl check for mt safe function variants and some posix functions
2165 dnl ************************************************************
2166
2167 glib_save_LIBS="$LIBS"
2168 # we are not doing the following for now, as this might require glib
2169 # to always be linked with the thread libs on some platforms.
2170 # LIBS="$LIBS $G_THREAD_LIBS"
2171 AC_CHECK_FUNCS(localtime_r gmtime_r)
2172 AS_IF([ test "$ac_cv_header_pwd_h" = "yes"], [
2173         AC_CACHE_CHECK([for posix getpwuid_r],
2174                 ac_cv_func_posix_getpwuid_r,
2175                 [AC_TRY_RUN([
2176 #include <errno.h>
2177 #include <pwd.h>
2178 int main () {
2179     char buffer[10000];
2180     struct passwd pwd, *pwptr = &pwd;
2181     int error;
2182     errno = 0;
2183     error = getpwuid_r (0, &pwd, buffer,
2184                         sizeof (buffer), &pwptr);
2185    return (error < 0 && errno == ENOSYS)
2186            || error == ENOSYS;
2187 }                               ],
2188                         [ac_cv_func_posix_getpwuid_r=yes],
2189                         [ac_cv_func_posix_getpwuid_r=no])])
2190         GLIB_ASSERT_SET(ac_cv_func_posix_getpwuid_r)
2191         if test "$ac_cv_func_posix_getpwuid_r" = yes; then
2192                 AC_DEFINE(HAVE_POSIX_GETPWUID_R,1,
2193                         [Have POSIX function getpwuid_r])
2194         else
2195                 AC_CACHE_CHECK([for nonposix getpwuid_r],
2196                         ac_cv_func_nonposix_getpwuid_r,
2197                         [AC_TRY_LINK([#include <pwd.h>],
2198                                 [char buffer[10000];
2199                                 struct passwd pwd;
2200                                 getpwuid_r (0, &pwd, buffer,
2201                                                 sizeof (buffer));],
2202                                 [ac_cv_func_nonposix_getpwuid_r=yes],
2203                                 [ac_cv_func_nonposix_getpwuid_r=no])])
2204                 GLIB_ASSERT_SET(ac_cv_func_nonposix_getpwuid_r)
2205                 if test "$ac_cv_func_nonposix_getpwuid_r" = yes; then
2206                         AC_DEFINE(HAVE_NONPOSIX_GETPWUID_R,1,
2207                                 [Have non-POSIX function getpwuid_r])
2208                 fi
2209         fi
2210 ])
2211 AS_IF([ test "$ac_cv_header_grp_h" = "yes"], [
2212         AC_CACHE_CHECK([for posix getgrgid_r],
2213                 ac_cv_func_posix_getgrgid_r,
2214                 [AC_TRY_RUN([
2215 #include <errno.h>
2216 #include <grp.h>
2217 int main () {
2218     char buffer[10000];
2219     struct group grp, *grpptr = &grp;
2220     int error;
2221     errno = 0;
2222     error = getgrgid_r (0, &grp, buffer,
2223                         sizeof (buffer), &grpptr);
2224    return (error < 0 && errno == ENOSYS)
2225            || error == ENOSYS;
2226 }                              ],
2227                        [ac_cv_func_posix_getgrgid_r=yes],
2228                        [ac_cv_func_posix_getgrgid_r=no])])
2229         GLIB_ASSERT_SET(ac_cv_func_posix_getgrgid_r)
2230         AS_IF([ test "$ac_cv_func_posix_getgrgid_r" = yes ], [
2231                 AC_DEFINE(HAVE_POSIX_GETGRGID_R,1,
2232                         [Have POSIX function getgrgid_r])
2233         ], [
2234                 AC_CACHE_CHECK([for nonposix getgrgid_r],
2235                         ac_cv_func_nonposix_getgrgid_r,
2236                         [AC_TRY_LINK([#include <grp.h>],
2237                                 [char buffer[10000];
2238                                 struct group grp;
2239                                 getgrgid_r (0, &grp, buffer,
2240                                 sizeof (buffer));],
2241                         [ac_cv_func_nonposix_getgrgid_r=yes],
2242                         [ac_cv_func_nonposix_getgrgid_r=no])])
2243                 GLIB_ASSERT_SET(ac_cv_func_nonposix_getgrgid_r)
2244                 if test "$ac_cv_func_nonposix_getgrgid_r" = yes; then
2245                         AC_DEFINE(HAVE_NONPOSIX_GETGRGID_R,1,
2246                                 [Have non-POSIX function getgrgid_r])
2247                 fi
2248         ])
2249 ])
2250 LIBS="$G_THREAD_LIBS $LIBS"
2251 AS_IF([ test x"$have_threads" = xposix], [
2252         glib_save_CPPFLAGS="$CPPFLAGS"
2253         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2254         # This is not AC_CHECK_FUNC to also work with function
2255         # name mangling in header files.
2256         AC_MSG_CHECKING(for pthread_attr_setstacksize)
2257         AC_LINK_IFELSE(
2258             [AC_LANG_PROGRAM(
2259                 [#include <pthread.h>],
2260                 [pthread_attr_t t; pthread_attr_setstacksize(&t,0)])],
2261             [AC_MSG_RESULT(yes)
2262              AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE,1,
2263                 [Have function pthread_attr_setstacksize])],
2264             [AC_MSG_RESULT(no)])
2265         AC_MSG_CHECKING(for pthread_condattr_setclock)
2266         AC_LINK_IFELSE(
2267             [AC_LANG_PROGRAM(
2268                 [#include <pthread.h>],
2269                 [pthread_condattr_t a; pthread_condattr_setclock(&a,0)])],
2270             [AC_MSG_RESULT(yes)
2271              AC_DEFINE(HAVE_PTHREAD_CONDATTR_SETCLOCK,1,
2272                 [Have function pthread_condattr_setclock])],
2273             [AC_MSG_RESULT(no)])
2274         CPPFLAGS="$glib_save_CPPFLAGS"
2275 ])
2276
2277 LIBS="$glib_save_LIBS"
2278
2279 # now spit out all the warnings.
2280 if test "$ac_cv_func_posix_getpwuid_r" != "yes" &&
2281    test "$ac_cv_func_nonposix_getpwuid_r" != "yes"; then
2282         AC_MSG_WARN($FUNC_NO_GETPWUID_R)
2283 fi
2284 if test "$ac_cv_func_localtime_r" != "yes"; then
2285         AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
2286 fi
2287
2288 #
2289 # Hack to deal with:
2290 #
2291 #  a) GCC < 3.3 for Linux doesn't include -lpthread when
2292 #     building shared libraries with linux.
2293 #  b) FreeBSD doesn't do this either.
2294 #
2295 case $host in
2296   *-*-freebsd*|*-*-linux*)
2297     G_THREAD_LIBS_FOR_GTHREAD="`echo $G_THREAD_LIBS | sed s/-pthread/-lpthread/`"
2298     ;;
2299   *-*-openbsd*)
2300     LDFLAGS="$LDFLAGS -pthread"
2301     ;;
2302   *)
2303     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
2304     ;;
2305 esac
2306
2307 AC_SUBST(G_THREAD_CFLAGS)
2308 AC_SUBST(G_THREAD_LIBS)
2309 AC_SUBST(G_THREAD_LIBS_FOR_GTHREAD)
2310 AC_SUBST(G_THREAD_LIBS_EXTRA)
2311
2312 AC_CHECK_FUNCS(clock_gettime, [], [
2313   AC_CHECK_LIB(rt, clock_gettime, [
2314     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
2315     G_THREAD_LIBS="$G_THREAD_LIBS -lrt"
2316     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS_FOR_GTHREAD -lrt"
2317   ])
2318 ])
2319
2320
2321 dnl ************************
2322 dnl *** g_atomic_* tests ***
2323 dnl ************************
2324
2325 dnl We need to decide at configure time if GLib will use real atomic
2326 dnl operations ("lock free") or emulated ones with a mutex.  This is
2327 dnl because we must put this information in glibconfig.h so we know if
2328 dnl it is safe or not to inline using compiler intrinsics directly from
2329 dnl the header.
2330 dnl
2331 dnl We also publish the information via G_ATOMIC_LOCK_FREE in case the
2332 dnl user is interested in knowing if they can use the atomic ops across
2333 dnl processes.
2334 dnl
2335 dnl We can currently support the atomic ops natively when building GLib
2336 dnl with recent versions of GCC or MSVC.  MSVC doesn't run ./configure,
2337 dnl so we skip that case here and define G_ATOMIC_LOCK_FREE exactly when
2338 dnl we are using GCC.
2339 dnl
2340 dnl Note that the atomic ops are only available with GCC on x86 when
2341 dnl using -march=i486 or higher.  If we detect that the atomic ops are
2342 dnl not available but would be available given the right flags, we want
2343 dnl to abort and advise the user to fix their CFLAGS.  It's better to do
2344 dnl that then to silently fall back on emulated atomic ops just because
2345 dnl the user had the wrong build environment.
2346
2347 dnl We may add other compilers here in the future...
2348
2349 AC_CACHE_CHECK([for lock-free atomic intrinsics], glib_cv_g_atomic_lock_free, [
2350   AC_TRY_COMPILE([],
2351                  [__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4;],
2352                  [glib_cv_g_atomic_lock_free=yes],
2353                  [glib_cv_g_atomic_lock_free=no])])
2354
2355 if test "$glib_cv_g_atomic_lock_free" = "no"; then
2356   SAVE_CFLAGS="${CFLAGS}"
2357   CFLAGS="-march=i486"
2358   AC_TRY_COMPILE([],
2359                  [__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4;],
2360                  [AC_MSG_ERROR([GLib must be build with -march=i486 or later.])],
2361                  [])
2362   CFLAGS="${SAVE_CFLAGS}"
2363 fi
2364
2365 dnl We need a more robust approach here...
2366 case $host_cpu in
2367   i?86|x86_64|s390|s390x|arm*|crisv32*|etrax*)
2368     glib_memory_barrier_needed=no
2369     ;;
2370   sparc*|alpha*|powerpc*|ia64)
2371     glib_memory_barrier_needed=yes
2372     ;;
2373   *)
2374     glib_memory_barrier_needed=yes
2375     ;;
2376 esac
2377
2378 dnl ************************
2379 dnl ** Check for futex(2) **
2380 dnl ************************
2381 AC_CACHE_CHECK(for futex(2) system call,
2382     glib_cv_futex,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2383 #include <linux/futex.h>
2384 #include <sys/syscall.h>
2385 #include <unistd.h>
2386 ],[
2387 int
2388 main (void)
2389 {
2390   /* it is not like this actually runs or anything... */
2391   syscall (__NR_futex, NULL, FUTEX_WAKE, FUTEX_WAIT);
2392   return 0;
2393 }
2394 ])],glib_cv_futex=yes,glib_cv_futex=no))
2395 if test x"$glib_cv_futex" = xyes; then
2396   AC_DEFINE(HAVE_FUTEX, 1, [we have the futex(2) system call])
2397 fi
2398
2399 AC_CACHE_CHECK(for eventfd(2) system call,
2400     glib_cv_eventfd,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2401 #include <sys/eventfd.h>
2402 #include <unistd.h>
2403 ],[
2404 int
2405 main (void)
2406 {
2407   eventfd (0, EFD_CLOEXEC);
2408   return 0;
2409 }
2410 ])],glib_cv_eventfd=yes,glib_cv_eventfd=no))
2411 if test x"$glib_cv_eventfd" = x"yes"; then
2412   AC_DEFINE(HAVE_EVENTFD, 1, [we have the eventfd(2) system call])
2413 fi
2414 AM_CONDITIONAL(HAVE_EVENTFD, [test "$glib_cv_eventfd" = "yes"])
2415
2416 dnl ****************************************
2417 dnl *** GLib POLL* compatibility defines ***
2418 dnl ****************************************
2419
2420 glib_poll_includes=["
2421 #include <sys/types.h>
2422 #include <sys/poll.h>
2423 "]
2424
2425 AS_IF([ test $ac_cv_header_sys_types_h = yes &&
2426    test $ac_cv_header_sys_poll_h = yes ], [
2427   glib_failed=false
2428   GLIB_CHECK_VALUE(POLLIN, $glib_poll_includes, glib_failed=true)
2429   GLIB_CHECK_VALUE(POLLOUT, $glib_poll_includes, glib_failed=true)
2430   GLIB_CHECK_VALUE(POLLPRI, $glib_poll_includes, glib_failed=true)
2431   GLIB_CHECK_VALUE(POLLERR, $glib_poll_includes, glib_failed=true)
2432   GLIB_CHECK_VALUE(POLLHUP, $glib_poll_includes, glib_failed=true)
2433   GLIB_CHECK_VALUE(POLLNVAL, $glib_poll_includes, glib_failed=true)
2434   if $glib_failed ; then
2435     AC_MSG_ERROR([Could not determine values for POLL* constants])
2436   fi
2437 ], [
2438   glib_cv_value_POLLIN=1
2439   glib_cv_value_POLLOUT=4
2440   glib_cv_value_POLLPRI=2
2441   glib_cv_value_POLLERR=8
2442   glib_cv_value_POLLHUP=16
2443   glib_cv_value_POLLNVAL=32
2444 ])
2445
2446 AC_MSG_CHECKING([for broken poll])
2447 AC_RUN_IFELSE([AC_LANG_SOURCE([[
2448         #include <stdlib.h>
2449         #include <fcntl.h>
2450         #include <poll.h>
2451         #ifdef HAVE_SYS_POLL_H
2452         #include <sys/poll.h>
2453         #endif
2454         int main(void) {
2455           struct pollfd fds[1];
2456           int fd;
2457           fd = open("/dev/null", 1);
2458           fds[0].fd = fd;
2459           fds[0].events = POLLIN;
2460           fds[0].revents = 0;
2461           if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
2462                 exit(1);  /* Does not work for devices -- fail */
2463           }
2464           exit(0);
2465         }]])],
2466   [broken_poll=no],
2467   [broken_poll=yes
2468    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
2469   [broken_poll="no (cross compiling)"])
2470 AC_MSG_RESULT($broken_poll)
2471
2472 dnl *********************
2473 dnl *** GRegex checks ***
2474 dnl *********************
2475
2476 PCRE_REQUIRED_VERSION=8.11
2477
2478 # Check if we should use the internal or the system-supplied pcre
2479 AC_ARG_WITH(pcre,
2480             [AC_HELP_STRING([--with-pcre=@<:@internal/system@:>@],
2481                             [whether to use system PCRE [default=internal]])])
2482
2483 AM_CONDITIONAL(USE_SYSTEM_PCRE, [test "x$with_pcre" = xsystem])
2484
2485 AS_IF([ test "x$with_pcre" = xsystem], [
2486   PKG_CHECK_MODULES(PCRE,
2487                     libpcre >= $PCRE_REQUIRED_VERSION)
2488   AC_CACHE_CHECK([for Unicode support in PCRE],glib_cv_pcre_has_unicode,[
2489                   glib_save_CFLAGS="$CFLAGS"
2490                   glib_save_LIBS="$LIBS"
2491                   CFLAGS="$CFLAGS $PCRE_CFLAGS" LIBS="$PCRE_LIBS"
2492                   AC_TRY_RUN([#include <pcre.h>
2493                               int main () {
2494                                 int support;
2495                                 pcre_config (PCRE_CONFIG_UTF8, &support);
2496                                 if (!support)
2497                                   return 1;
2498                                 pcre_config (PCRE_CONFIG_UNICODE_PROPERTIES, &support);
2499                                 if (!support)
2500                                   return 1;
2501                                 return 0;
2502                               }],
2503                   glib_cv_pcre_has_unicode=yes,
2504                   glib_cv_pcre_has_unicode=no,
2505                   glib_cv_pcre_has_unicode=yes)
2506                   CFLAGS="$glib_save_CFLAGS"
2507                   LIBS="$glib_save_LIBS"
2508       ])
2509   if test "$glib_cv_pcre_has_unicode" = "no"; then
2510     AC_MSG_ERROR([*** The system-supplied PCRE does not support Unicode properties or UTF-8.])
2511   fi
2512   AC_SUBST(PCRE_CFLAGS)
2513   AC_SUBST(PCRE_LIBS)
2514   AC_DEFINE(USE_SYSTEM_PCRE, [], [using the system-supplied PCRE library])
2515   PCRE_REQUIRES=libpcre
2516   AC_SUBST(PCRE_REQUIRES)
2517 ], [
2518   # If using gcc 4 pass -Wno-pointer-sign when compiling the internal PCRE
2519   AS_IF([ test x"$GCC" = xyes], [
2520     AC_MSG_CHECKING([whether compiler understands -Wno-pointer-sign])
2521     save_CFLAGS="$CFLAGS"
2522     CFLAGS="$CFLAGS -Wno-pointer-sign"
2523     AC_TRY_COMPILE([],[],[PCRE_WARN_CFLAGS="$PCRE_WARN_CFLAGS -Wno-pointer-sign"
2524                           AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
2525     CFLAGS="$save_CFLAGS"
2526   ])
2527 ])
2528 AC_SUBST(PCRE_WARN_CFLAGS)
2529
2530 dnl **********************
2531 dnl *** Win32 API libs ***
2532 dnl **********************
2533
2534 case $host in
2535   *-*-cygwin*)
2536         G_LIBS_EXTRA="-luser32 -lkernel32"
2537     ;;
2538   *-*-mingw*)
2539         G_LIBS_EXTRA="-lws2_32 -lole32 -lwinmm -lshlwapi"
2540     ;;
2541   *)
2542         G_LIBS_EXTRA=""
2543     ;;
2544 esac
2545 AC_SUBST(G_LIBS_EXTRA)
2546
2547 dnl If the system doesn't define EILSEQ, we should define EILSEQ ourselves
2548 dnl since we need it for g_iconv()
2549
2550 AC_MSG_CHECKING([for EILSEQ])
2551 AC_TRY_COMPILE([
2552 #include <errno.h>
2553 ],
2554 [
2555 int error = EILSEQ;
2556 ], have_eilseq=yes, have_eilseq=no);
2557 AC_MSG_RESULT($have_eilseq)
2558
2559 dnl ******************************************************************
2560 dnl *** If we are cross-compiling, look for glib-genmarshal and    ***
2561 dnl *** glib-compile-schemas in PATH                               ***
2562 dnl ******************************************************************
2563
2564 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
2565
2566 AS_IF([ test $cross_compiling = yes && test x$enable_modular_tests = xyes], [
2567   AC_PATH_PROG(GLIB_GENMARSHAL, glib-genmarshal, no)
2568   if test x$GLIB_GENMARSHAL = xno; then
2569     AC_MSG_ERROR(Could not find a glib-genmarshal in your PATH)
2570   fi
2571
2572   AC_PATH_PROG(GLIB_COMPILE_SCHEMAS, glib-compile-schemas, no)
2573   if test x$GLIB_COMPILE_SCHEMAS = xno; then
2574     AC_MSG_ERROR(Could not find a glib-compile-schemas in your PATH)
2575   fi
2576
2577   AC_PATH_PROG(GLIB_COMPILE_RESOURCES, glib-compile-resources, no)
2578   if test x$GLIB_COMPILE_RESOURCES = xno; then
2579     AC_MSG_ERROR(Could not find a glib-compile-resources in your PATH)
2580   fi
2581 ])
2582
2583 dnl **************************
2584 dnl *** Checks for gtk-doc ***
2585 dnl **************************
2586
2587 GTK_DOC_CHECK([1.15], [--flavour no-tmpl])
2588
2589 AC_ARG_ENABLE(man,
2590               [AC_HELP_STRING([--enable-man],
2591                               [regenerate man pages from Docbook [default=no]])],enable_man=yes,
2592               enable_man=no)
2593
2594 if test "${enable_man}" != no; then
2595 dnl
2596 dnl Check for xsltproc
2597 dnl
2598 AC_PATH_PROG([XSLTPROC], [xsltproc])
2599   if test -z "$XSLTPROC"; then
2600     enable_man=no
2601   fi
2602
2603   dnl check for DocBook DTD and stylesheets in the local catalog.
2604   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
2605      [DocBook XML DTD V4.1.2],,enable_man=no)
2606   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
2607      [DocBook XSL Stylesheets],,enable_man=no)
2608 fi
2609
2610 AM_CONDITIONAL(ENABLE_MAN, test x$enable_man != xno)
2611
2612 dnl
2613 dnl Tracing
2614 dnl
2615
2616 AC_ARG_ENABLE([dtrace],
2617              [AS_HELP_STRING([--enable-dtrace],
2618                               [include tracing support for dtrace])])
2619 have_dtrace=no
2620 AC_MSG_CHECKING([whether to include dtrace tracing support])
2621 AS_IF([ test "x$enable_dtrace" != xno], [
2622   if test x$glib_have_carbon = xyes; then
2623     AC_MSG_RESULT([no (not yet compatible with MacOS dtrace)])
2624   else
2625     AC_MSG_RESULT([yes])
2626     AC_CHECK_PROGS(DTRACE, dtrace)
2627     if test -z "$DTRACE"; then
2628       if test "x$enable_dtrace" = xyes; then
2629         AC_MSG_ERROR([dtrace not found])
2630       fi
2631     else
2632       AC_CHECK_HEADER([sys/sdt.h],have_dtrace=yes,
2633                       [if test "x$enable_dtrace" = xyes; then
2634                         AC_MSG_ERROR([dtrace support needs sys/sdt.h header])
2635                        fi])
2636     fi
2637   fi
2638 ], [
2639   AC_MSG_RESULT([no])
2640 ])
2641 if test "x$have_dtrace" = xyes; then
2642   AC_DEFINE([HAVE_DTRACE], [1], [Define to 1 if using dtrace probes.])
2643 fi
2644 AM_CONDITIONAL([ENABLE_DTRACE], [test x$have_dtrace = xyes ])
2645
2646 AC_MSG_CHECKING([whether to include systemtap tracing support])
2647 AC_ARG_ENABLE([systemtap],
2648              [AS_HELP_STRING([--enable-systemtap],
2649                               [include tracing support for systemtap])])
2650 have_systemtap=no
2651 if test "x$enable_systemtap" != xno -a "x$have_dtrace" = xyes; then
2652   have_systemtap=yes
2653 fi
2654 AC_MSG_RESULT(${have_systemtap})
2655
2656 AM_CONDITIONAL([ENABLE_SYSTEMTAP], [test x$have_systemtap = xyes])
2657
2658 AC_ARG_WITH([tapset-install-dir],
2659             AS_HELP_STRING([--with-tapset-install-dir=DIR],
2660                             [path where systemtap tapsets are installed [DATADIR/systemtap/tapset]]),
2661             [if test "x${withval}" = x; then
2662                ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"
2663              else
2664                ABS_TAPSET_DIR="${withval}"
2665               fi],
2666             [ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"])
2667 AC_SUBST(ABS_TAPSET_DIR)
2668
2669 dnl ************************************
2670 dnl *** Enable lcov coverage reports ***
2671 dnl ************************************
2672
2673 AC_ARG_ENABLE(gcov,
2674   AS_HELP_STRING([--enable-gcov],
2675                  [enable coverage testing with gcov]),
2676   [use_gcov=$enableval], [use_gcov=no])
2677
2678 AS_IF([ test "x$use_gcov" = "xyes"], [
2679   dnl we need gcc:
2680   if test "$GCC" != "yes"; then
2681     AC_MSG_ERROR([GCC is required for --enable-gcov])
2682   fi
2683
2684   dnl Check if ccache is being used
2685   AC_CHECK_PROG(SHTOOL, shtool, shtool)
2686   case `$SHTOOL path $CC` in
2687     *ccache*[)] gcc_ccache=yes;;
2688     *[)] gcc_ccache=no;;
2689   esac
2690
2691   if test "$gcc_ccache" = "yes" && (test -z "$CCACHE_DISABLE" || test "$CCACHE_DISABLE" != "1"); then
2692     AC_MSG_ERROR([ccache must be disabled when --enable-gcov option is used. You can disable ccache by setting environment variable CCACHE_DISABLE=1.])
2693   fi
2694
2695   ltp_version_list="1.6 1.7 1.8 1.9"
2696   AC_CHECK_PROG(LTP, lcov, lcov)
2697   AC_CHECK_PROG(LTP_GENHTML, genhtml, genhtml)
2698
2699   AS_IF([ test "$LTP" ], [
2700     AC_CACHE_CHECK([for ltp version], glib_cv_ltp_version, [
2701       glib_cv_ltp_version=invalid
2702       ltp_version=`$LTP -v 2>/dev/null | $SED -e 's/^.* //'`
2703       for ltp_check_version in $ltp_version_list; do
2704         if test "$ltp_version" = "$ltp_check_version"; then
2705           glib_cv_ltp_version="$ltp_check_version (ok)"
2706         fi
2707       done
2708     ])
2709   ], [
2710     ltp_msg="To enable code coverage reporting you must have one of the following LTP versions installed: $ltp_version_list"
2711     AC_MSG_ERROR([$ltp_msg])
2712   ])
2713
2714   case $glib_cv_ltp_version in
2715     ""|invalid[)]
2716       ltp_msg="You must have one of the following versions of LTP: $ltp_version_list (found: $ltp_version)."
2717       AC_MSG_ERROR([$ltp_msg])
2718       LTP="exit 0;"
2719       ;;
2720   esac
2721
2722   if test -z "$LTP_GENHTML"; then
2723     AC_MSG_ERROR([Could not find genhtml from the LTP package])
2724   fi
2725
2726   dnl Remove all optimization flags from CFLAGS
2727   changequote({,})
2728   CFLAGS=`echo "$CFLAGS" | $SED -e 's/-O[0-9]*//g'`
2729   changequote([,])
2730
2731   dnl Add the special gcc flags
2732   CFLAGS="$CFLAGS -O0 -fprofile-arcs -ftest-coverage"
2733   LDFLAGS="$LDFLAGS -lgcov"
2734 ])
2735
2736 dnl ******************************
2737 dnl *** output the whole stuff ***
2738 dnl ******************************
2739
2740 dnl this section will only be run if config.status is invoked with no
2741 dnl arguments, or with "glib/glibconfig.h" as an argument.
2742 AC_CONFIG_COMMANDS([glib/glibconfig.h],
2743 [
2744         outfile=glib/glibconfig.h-tmp
2745         cat > $outfile <<\_______EOF
2746 /* glibconfig.h
2747  *
2748  * This is a generated file.  Please modify 'configure.ac'
2749  */
2750
2751 #ifndef __GLIBCONFIG_H__
2752 #define __GLIBCONFIG_H__
2753
2754 #include <glib/gmacros.h>
2755
2756 _______EOF
2757
2758         if test x$glib_limits_h = xyes; then
2759           echo '#include <limits.h>' >> $outfile
2760         fi
2761         if test x$glib_float_h = xyes; then
2762           echo '#include <float.h>' >> $outfile
2763         fi
2764         if test x$glib_values_h = xyes; then
2765           echo '#include <values.h>' >> $outfile
2766         fi
2767         if test "$glib_header_alloca_h" = "yes"; then
2768           echo '#define GLIB_HAVE_ALLOCA_H' >> $outfile
2769         fi
2770         if test x$glib_sys_poll_h = xyes; then
2771           echo '#define GLIB_HAVE_SYS_POLL_H' >> $outfile
2772         fi
2773         if test x$glib_included_printf != xyes; then
2774           echo "
2775 /* Specifies that GLib's g_print*() functions wrap the
2776  * system printf functions.  This is useful to know, for example,
2777  * when using glibc's register_printf_function().
2778  */" >> $outfile
2779           echo '#define GLIB_USING_SYSTEM_PRINTF' >> $outfile
2780         fi
2781
2782         cat >> $outfile <<_______EOF
2783
2784 G_BEGIN_DECLS
2785
2786 #define G_MINFLOAT      $glib_mf
2787 #define G_MAXFLOAT      $glib_Mf
2788 #define G_MINDOUBLE     $glib_md
2789 #define G_MAXDOUBLE     $glib_Md
2790 #define G_MINSHORT      $glib_ms
2791 #define G_MAXSHORT      $glib_Ms
2792 #define G_MAXUSHORT     $glib_Mus
2793 #define G_MININT        $glib_mi
2794 #define G_MAXINT        $glib_Mi
2795 #define G_MAXUINT       $glib_Mui
2796 #define G_MINLONG       $glib_ml
2797 #define G_MAXLONG       $glib_Ml
2798 #define G_MAXULONG      $glib_Mul
2799
2800 _______EOF
2801
2802
2803         ### this should always be true in a modern C/C++ compiler
2804         cat >>$outfile <<_______EOF
2805 typedef signed char gint8;
2806 typedef unsigned char guint8;
2807 _______EOF
2808
2809
2810         if test -n "$gint16"; then
2811           cat >>$outfile <<_______EOF
2812 typedef signed $gint16 gint16;
2813 typedef unsigned $gint16 guint16;
2814 #define G_GINT16_MODIFIER $gint16_modifier
2815 #define G_GINT16_FORMAT $gint16_format
2816 #define G_GUINT16_FORMAT $guint16_format
2817 _______EOF
2818         fi
2819
2820
2821         if test -n "$gint32"; then
2822           cat >>$outfile <<_______EOF
2823 typedef signed $gint32 gint32;
2824 typedef unsigned $gint32 guint32;
2825 #define G_GINT32_MODIFIER $gint32_modifier
2826 #define G_GINT32_FORMAT $gint32_format
2827 #define G_GUINT32_FORMAT $guint32_format
2828 _______EOF
2829         fi
2830
2831         cat >>$outfile <<_______EOF
2832 #define G_HAVE_GINT64 1          /* deprecated, always true */
2833
2834 ${glib_extension}typedef signed $gint64 gint64;
2835 ${glib_extension}typedef unsigned $gint64 guint64;
2836
2837 #define G_GINT64_CONSTANT(val)  $gint64_constant
2838 #define G_GUINT64_CONSTANT(val) $guint64_constant
2839 _______EOF
2840
2841         if test x$gint64_format != x ; then
2842           cat >>$outfile <<_______EOF
2843 #define G_GINT64_MODIFIER $gint64_modifier
2844 #define G_GINT64_FORMAT $gint64_format
2845 #define G_GUINT64_FORMAT $guint64_format
2846 _______EOF
2847         else
2848           cat >>$outfile <<_______EOF
2849 #undef G_GINT64_MODIFIER
2850 #undef G_GINT64_FORMAT
2851 #undef G_GUINT64_FORMAT
2852 _______EOF
2853         fi
2854
2855         cat >>$outfile <<_______EOF
2856
2857 #define GLIB_SIZEOF_VOID_P $glib_void_p
2858 #define GLIB_SIZEOF_LONG   $glib_long
2859 #define GLIB_SIZEOF_SIZE_T $glib_size_t
2860
2861 _______EOF
2862
2863         cat >>$outfile <<_______EOF
2864 typedef signed $glib_size_type_define gssize;
2865 typedef unsigned $glib_size_type_define gsize;
2866 #define G_GSIZE_MODIFIER $gsize_modifier
2867 #define G_GSSIZE_FORMAT $gssize_format
2868 #define G_GSIZE_FORMAT $gsize_format
2869
2870 #define G_MAXSIZE       G_MAXU$glib_msize_type
2871 #define G_MINSSIZE      G_MIN$glib_msize_type
2872 #define G_MAXSSIZE      G_MAX$glib_msize_type
2873
2874 typedef gint64 goffset;
2875 #define G_MINOFFSET     G_MININT64
2876 #define G_MAXOFFSET     G_MAXINT64
2877
2878 #define G_GOFFSET_MODIFIER      G_GINT64_MODIFIER
2879 #define G_GOFFSET_FORMAT        G_GINT64_FORMAT
2880 #define G_GOFFSET_CONSTANT(val) G_GINT64_CONSTANT(val)
2881
2882 _______EOF
2883
2884         if test -z "$glib_unknown_void_p"; then
2885           cat >>$outfile <<_______EOF
2886
2887 #define GPOINTER_TO_INT(p)      ((gint)  ${glib_gpi_cast} (p))
2888 #define GPOINTER_TO_UINT(p)     ((guint) ${glib_gpui_cast} (p))
2889
2890 #define GINT_TO_POINTER(i)      ((gpointer) ${glib_gpi_cast} (i))
2891 #define GUINT_TO_POINTER(u)     ((gpointer) ${glib_gpui_cast} (u))
2892
2893 typedef signed $glib_intptr_type_define gintptr;
2894 typedef unsigned $glib_intptr_type_define guintptr;
2895
2896 #define G_GINTPTR_MODIFIER      $gintptr_modifier
2897 #define G_GINTPTR_FORMAT        $gintptr_format
2898 #define G_GUINTPTR_FORMAT       $guintptr_format
2899 _______EOF
2900         else
2901           echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
2902         fi
2903
2904
2905
2906         cat >>$outfile <<_______EOF
2907 $glib_atexit
2908 $glib_memmove
2909 $glib_defines
2910 $glib_os
2911 $glib_static_compilation
2912
2913 $glib_vacopy
2914
2915 #ifdef  __cplusplus
2916 #define G_HAVE_INLINE   1
2917 #else   /* !__cplusplus */
2918 $glib_inline
2919 #endif  /* !__cplusplus */
2920
2921 #ifdef  __cplusplus
2922 #define G_CAN_INLINE    1
2923 _______EOF
2924
2925         if test x$g_can_inline = xyes ; then
2926                 cat >>$outfile <<_______EOF
2927 #else   /* !__cplusplus */
2928 #define G_CAN_INLINE    1
2929 _______EOF
2930         fi
2931
2932         cat >>$outfile <<_______EOF
2933 #endif
2934
2935 _______EOF
2936
2937         if test x$g_have_iso_c_varargs = xyes ; then
2938                 cat >>$outfile <<_______EOF
2939 #ifndef __cplusplus
2940 # define G_HAVE_ISO_VARARGS 1
2941 #endif
2942 _______EOF
2943         fi
2944         if test x$g_have_iso_cxx_varargs = xyes ; then
2945                 cat >>$outfile <<_______EOF
2946 #ifdef __cplusplus
2947 # define G_HAVE_ISO_VARARGS 1
2948 #endif
2949 _______EOF
2950         fi
2951         if test x$g_have_gnuc_varargs = xyes ; then
2952                 cat >>$outfile <<_______EOF
2953
2954 /* gcc-2.95.x supports both gnu style and ISO varargs, but if -ansi
2955  * is passed ISO vararg support is turned off, and there is no work
2956  * around to turn it on, so we unconditionally turn it off.
2957  */
2958 #if __GNUC__ == 2 && __GNUC_MINOR__ == 95
2959 #  undef G_HAVE_ISO_VARARGS
2960 #endif
2961
2962 #define G_HAVE_GNUC_VARARGS 1
2963 _______EOF
2964         fi
2965
2966         case x$g_stack_grows in
2967         xyes) echo "#define G_HAVE_GROWING_STACK 1" >>$outfile ;;
2968         *)    echo "#define G_HAVE_GROWING_STACK 0" >>$outfile ;;
2969         esac
2970
2971
2972         echo >>$outfile
2973         if test x$g_have_eilseq = xno; then
2974                 cat >>$outfile <<_______EOF
2975 #ifndef EILSEQ
2976 /* On some systems, like SunOS and NetBSD, EILSEQ is not defined.
2977  * The correspondence between this and the corresponding definition
2978  * in libiconv is essential.
2979  */
2980 #  define EILSEQ ENOENT
2981 #endif
2982 _______EOF
2983
2984         fi
2985
2986         if test x$g_have_gnuc_visibility = xyes; then
2987                 cat >>$outfile <<_______EOF
2988 #define G_HAVE_GNUC_VISIBILITY 1
2989 _______EOF
2990         fi
2991                 cat >>$outfile <<_______EOF
2992 #if defined(__SUNPRO_C) && (__SUNPRO_C >= 0x590)
2993 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
2994 #elif defined(__SUNPRO_C) && (__SUNPRO_C >= 0x550)
2995 #define G_GNUC_INTERNAL __hidden
2996 #elif defined (__GNUC__) && defined (G_HAVE_GNUC_VISIBILITY)
2997 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
2998 #else
2999 #define G_GNUC_INTERNAL
3000 #endif
3001 _______EOF
3002
3003         echo >>$outfile
3004         cat >>$outfile <<_______EOF
3005 #define G_THREADS_ENABLED
3006 #define G_THREADS_IMPL_$g_threads_impl_def
3007 _______EOF
3008
3009         if test x"$g_memory_barrier_needed" != xno; then
3010           echo >>$outfile
3011           echo "#define G_ATOMIC_OP_MEMORY_BARRIER_NEEDED 1" >>$outfile
3012         fi
3013         if test x"$g_atomic_lock_free" = xyes; then
3014           echo >>$outfile
3015           echo "#define G_ATOMIC_LOCK_FREE" >>$outfile
3016         fi
3017         echo >>$outfile
3018         g_bit_sizes="16 32 64"
3019         for bits in $g_bit_sizes; do
3020           cat >>$outfile <<_______EOF
3021 #define GINT${bits}_TO_${g_bs_native}(val)      ((gint${bits}) (val))
3022 #define GUINT${bits}_TO_${g_bs_native}(val)     ((guint${bits}) (val))
3023 #define GINT${bits}_TO_${g_bs_alien}(val)       ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
3024 #define GUINT${bits}_TO_${g_bs_alien}(val)      (GUINT${bits}_SWAP_LE_BE (val))
3025 _______EOF
3026         done
3027
3028         cat >>$outfile <<_______EOF
3029 #define GLONG_TO_LE(val)        ((glong) GINT${glongbits}_TO_LE (val))
3030 #define GULONG_TO_LE(val)       ((gulong) GUINT${glongbits}_TO_LE (val))
3031 #define GLONG_TO_BE(val)        ((glong) GINT${glongbits}_TO_BE (val))
3032 #define GULONG_TO_BE(val)       ((gulong) GUINT${glongbits}_TO_BE (val))
3033 #define GINT_TO_LE(val)         ((gint) GINT${gintbits}_TO_LE (val))
3034 #define GUINT_TO_LE(val)        ((guint) GUINT${gintbits}_TO_LE (val))
3035 #define GINT_TO_BE(val)         ((gint) GINT${gintbits}_TO_BE (val))
3036 #define GUINT_TO_BE(val)        ((guint) GUINT${gintbits}_TO_BE (val))
3037 #define GSIZE_TO_LE(val)        ((gsize) GUINT${gsizebits}_TO_LE (val))
3038 #define GSSIZE_TO_LE(val)       ((gssize) GINT${gsizebits}_TO_LE (val))
3039 #define GSIZE_TO_BE(val)        ((gsize) GUINT${gsizebits}_TO_BE (val))
3040 #define GSSIZE_TO_BE(val)       ((gssize) GINT${gsizebits}_TO_BE (val))
3041 #define G_BYTE_ORDER $g_byte_order
3042
3043 #define GLIB_SYSDEF_POLLIN =$g_pollin
3044 #define GLIB_SYSDEF_POLLOUT =$g_pollout
3045 #define GLIB_SYSDEF_POLLPRI =$g_pollpri
3046 #define GLIB_SYSDEF_POLLHUP =$g_pollhup
3047 #define GLIB_SYSDEF_POLLERR =$g_pollerr
3048 #define GLIB_SYSDEF_POLLNVAL =$g_pollnval
3049
3050 #define G_MODULE_SUFFIX "$g_module_suffix"
3051
3052 typedef $g_pid_type GPid;
3053
3054 #define GLIB_SYSDEF_AF_UNIX $g_af_unix
3055 #define GLIB_SYSDEF_AF_INET $g_af_inet
3056 #define GLIB_SYSDEF_AF_INET6 $g_af_inet6
3057
3058 #define GLIB_SYSDEF_MSG_OOB $g_msg_oob
3059 #define GLIB_SYSDEF_MSG_PEEK $g_msg_peek
3060 #define GLIB_SYSDEF_MSG_DONTROUTE $g_msg_dontroute
3061
3062 G_END_DECLS
3063
3064 #endif /* __GLIBCONFIG_H__ */
3065 _______EOF
3066
3067
3068         if cmp -s $outfile glib/glibconfig.h; then
3069           AC_MSG_NOTICE([glib/glibconfig.h is unchanged])
3070           rm -f $outfile
3071         else
3072           mv $outfile glib/glibconfig.h
3073         fi
3074 ],[
3075
3076 # Note that if two cases are the same, case goes with the first one.
3077 # Note also that this is inside an AC_OUTPUT_COMMAND.  We do not depend
3078 # on variable expansion in case labels.  Look at the generated config.status
3079 # for a hint.
3080
3081 if test "x${ac_cv_working_alloca_h+set}" = xset ; then
3082   glib_header_alloca_h="$ac_cv_working_alloca_h"
3083 else
3084   glib_header_alloca_h="$ac_cv_header_alloca_h"
3085 fi
3086
3087 case xyes in
3088 x$ac_cv_header_float_h)
3089   glib_float_h=yes
3090   glib_mf=FLT_MIN glib_Mf=FLT_MAX
3091   glib_md=DBL_MIN glib_Md=DBL_MAX
3092   ;;
3093 x$ac_cv_header_values_h)
3094   glib_values_h=yes
3095   glib_mf=MINFLOAT  glib_Mf=MAXFLOAT
3096   glib_md=MINDOUBLE glib_Md=MAXDOUBLE
3097   ;;
3098 esac
3099
3100 case xyes in
3101 x$ac_cv_header_limits_h)
3102   glib_limits_h=yes
3103   glib_ms=SHRT_MIN glib_Ms=SHRT_MAX glib_Mus=USHRT_MAX
3104   glib_mi=INT_MIN  glib_Mi=INT_MAX  glib_Mui=UINT_MAX
3105   glib_ml=LONG_MIN glib_Ml=LONG_MAX glib_Mul=ULONG_MAX
3106   ;;
3107 x$ac_cv_header_values_h)
3108   glib_values_h=yes
3109   glib_ms=MINSHORT glib_Ms=MAXSHORT glib_Mus="(((gushort)G_MAXSHORT)*2+1)"
3110   glib_mi=MININT   glib_Mi=MAXINT   glib_Mui="(((guint)G_MAXINT)*2+1)"
3111   glib_ml=MINLONG  glib_Ml=MAXLONG  glib_Mul="(((gulong)G_MAXLONG)*2+1)"
3112   ;;
3113 esac
3114
3115 if test x$ac_cv_header_sys_poll_h = xyes ; then
3116   glib_sys_poll_h=yes
3117 fi
3118
3119 if test x$enable_included_printf = xyes ; then
3120   glib_included_printf=yes
3121 fi
3122
3123 case 2 in
3124 $ac_cv_sizeof_short)
3125   gint16=short
3126   gint16_modifier='"h"'
3127   gint16_format='"hi"'
3128   guint16_format='"hu"'
3129   ;;
3130 $ac_cv_sizeof_int)
3131   gint16=int
3132   gint16_modifier='""'
3133   gint16_format='"i"'
3134   guint16_format='"u"'
3135   ;;
3136 esac
3137 case 4 in
3138 $ac_cv_sizeof_short)
3139   gint32=short
3140   gint32_modifier='"h"'
3141   gint32_format='"hi"'
3142   guint32_format='"hu"'
3143   ;;
3144 $ac_cv_sizeof_int)
3145   gint32=int
3146   gint32_modifier='""'
3147   gint32_format='"i"'
3148   guint32_format='"u"'
3149   ;;
3150 $ac_cv_sizeof_long)
3151   gint32=long
3152   gint32_modifier='"l"'
3153   gint32_format='"li"'
3154   guint32_format='"lu"'
3155   ;;
3156 esac
3157 case 8 in
3158 $ac_cv_sizeof_int)
3159   gint64=int
3160   gint64_modifier='""'
3161   gint64_format='"i"'
3162   guint64_format='"u"'
3163   glib_extension=
3164   gint64_constant='(val)'
3165   guint64_constant='(val)'
3166   ;;
3167 $ac_cv_sizeof_long)
3168   gint64=long
3169   gint64_modifier='"l"'
3170   gint64_format='"li"'
3171   guint64_format='"lu"'
3172   glib_extension=
3173   gint64_constant='(val##L)'
3174   guint64_constant='(val##UL)'
3175   ;;
3176 $ac_cv_sizeof_long_long)
3177   gint64='long long'
3178   if test -n "$glib_cv_long_long_format"; then
3179     gint64_modifier='"'$glib_cv_long_long_format'"'
3180     gint64_format='"'$glib_cv_long_long_format'i"'
3181     guint64_format='"'$glib_cv_long_long_format'u"'
3182   fi
3183   glib_extension='G_GNUC_EXTENSION '
3184   gint64_constant='(G_GNUC_EXTENSION (val##LL))'
3185   guint64_constant='(G_GNUC_EXTENSION (val##ULL))'
3186   ;;
3187 $ac_cv_sizeof___int64)
3188   gint64='__int64'
3189   if test -n "$glib_cv_long_long_format"; then
3190     gint64_modifier='"'$glib_cv_long_long_format'"'
3191     gint64_format='"'$glib_cv_long_long_format'i"'
3192     guint64_format='"'$glib_cv_long_long_format'u"'
3193   fi
3194   glib_extension=
3195   gint64_constant='(val##i64)'
3196   guint64_constant='(val##ui64)'
3197   ;;
3198 esac
3199 glib_size_t=$ac_cv_sizeof_size_t
3200 glib_size_type_define="$glib_size_type"
3201 glib_void_p=$ac_cv_sizeof_void_p
3202 glib_long=$ac_cv_sizeof_long
3203
3204 case "$glib_size_type" in
3205 short)
3206   gsize_modifier='"h"'
3207   gsize_format='"hu"'
3208   gssize_format='"hi"'
3209   glib_msize_type='SHRT'
3210   ;;
3211 int)
3212   gsize_modifier='""'
3213   gsize_format='"u"'
3214   gssize_format='"i"'
3215   glib_msize_type='INT'
3216   ;;
3217 long)
3218   gsize_modifier='"l"'
3219   gsize_format='"lu"'
3220   gssize_format='"li"'
3221   glib_msize_type='LONG'
3222   ;;
3223 "long long"|__int64)
3224   gsize_modifier='"I64"'
3225   gsize_format='"I64u"'
3226   gssize_format='"I64i"'
3227   glib_msize_type='INT64'
3228   ;;
3229 esac
3230
3231 gintbits=`expr $ac_cv_sizeof_int \* 8`
3232 glongbits=`expr $ac_cv_sizeof_long \* 8`
3233 gsizebits=`expr $ac_cv_sizeof_size_t \* 8`
3234
3235 case $ac_cv_sizeof_void_p in
3236 $ac_cv_sizeof_int)
3237   glib_intptr_type_define=int
3238   gintptr_modifier='""'
3239   gintptr_format='"i"'
3240   guintptr_format='"u"'
3241   glib_gpi_cast='(gint)'
3242   glib_gpui_cast='(guint)'
3243   ;;
3244 $ac_cv_sizeof_long)
3245   glib_intptr_type_define=long
3246   gintptr_modifier='"l"'
3247   gintptr_format='"li"'
3248   guintptr_format='"lu"'
3249   glib_gpi_cast='(glong)'
3250   glib_gpui_cast='(gulong)'
3251   ;;
3252 $ac_cv_sizeof_long_long)
3253   glib_intptr_type_define='long long'
3254   gintptr_modifier='"I64"'
3255   gintptr_format='"I64i"'
3256   guintptr_format='"I64u"'
3257   glib_gpi_cast='(gint64)'
3258   glib_gpui_cast='(guint64)'
3259   ;;
3260 $ac_cv_sizeof___int64)
3261   glib_intptr_type_define=__int64
3262   gintptr_modifier='"I64"'
3263   gintptr_format='"I64i"'
3264   guintptr_format='"I64u"'
3265   glib_gpi_cast='(gint64)'
3266   glib_gpui_cast='(guint64)'
3267   ;;
3268 *)
3269   glib_unknown_void_p=yes
3270   ;;
3271 esac
3272
3273
3274 case xyes in
3275 x$ac_cv_func_atexit)
3276   glib_atexit="
3277 #ifdef NeXT /* @#%@! NeXTStep */
3278 # define g_ATEXIT(proc) (!atexit (proc))
3279 #else
3280 # define g_ATEXIT(proc) (atexit (proc))
3281 #endif"
3282   ;;
3283 x$ac_cv_func_on_exit)
3284   glib_atexit="
3285 #define g_ATEXIT(proc)  (on_exit ((void (*)(int, void*))(proc), NULL))"
3286   ;;
3287 esac
3288
3289 case xyes in
3290 x$ac_cv_func_memmove)
3291   glib_memmove='
3292 #define g_memmove(dest,src,len) G_STMT_START { memmove ((dest), (src), (len)); } G_STMT_END'
3293   ;;
3294 x$glib_cv_working_bcopy)
3295   glib_memmove="
3296 /* memmove isn't available, but bcopy can copy overlapping memory regions */
3297 #define g_memmove(d,s,n) G_STMT_START { bcopy ((s), (d), (n)); } G_STMT_END"
3298   ;;
3299 *)
3300   glib_memmove="
3301 /* memmove isn't found and bcopy can't copy overlapping memory regions,
3302  * so we have to roll our own copy routine. */
3303 void g_memmove (void* dest, const void * src, unsigned long len);"
3304   ;;
3305 esac
3306
3307 glib_defines="
3308 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
3309 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
3310 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
3311 "
3312
3313 case xyes in
3314 x$glib_cv_va_copy)      glib_vacopy='#define G_VA_COPY  va_copy' ;;
3315 x$glib_cv___va_copy)    glib_vacopy='#define G_VA_COPY  __va_copy' ;;
3316 *)                      glib_vacopy=''
3317 esac
3318
3319 if test x$glib_cv_va_val_copy = xno; then
3320   glib_vacopy="\$glib_vacopy
3321 #define G_VA_COPY_AS_ARRAY 1"
3322 fi
3323
3324 if test x$glib_cv_hasinline = xyes; then
3325     glib_inline='#define G_HAVE_INLINE 1'
3326 fi
3327 if test x$glib_cv_has__inline = xyes; then
3328     glib_inline="\$glib_inline
3329 #define G_HAVE___INLINE 1"
3330 fi
3331 if test x$glib_cv_has__inline__ = xyes; then
3332     glib_inline="\$glib_inline
3333 #define G_HAVE___INLINE__ 1"
3334 fi
3335
3336 g_have_gnuc_varargs=$g_have_gnuc_varargs
3337 g_have_iso_c_varargs=$g_have_iso_c_varargs
3338 g_have_iso_cxx_varargs=$g_have_iso_cxx_varargs
3339
3340 g_can_inline=$g_can_inline
3341 g_have_gnuc_visibility=$g_have_gnuc_visibility
3342 g_have_sunstudio_visibility=$g_have_sunstudio_visibility
3343
3344 if test x$ac_cv_c_bigendian = xyes; then
3345   g_byte_order=G_BIG_ENDIAN
3346   g_bs_native=BE
3347   g_bs_alien=LE
3348 else
3349   g_byte_order=G_LITTLE_ENDIAN
3350   g_bs_native=LE
3351   g_bs_alien=BE
3352 fi
3353
3354 g_pollin=$glib_cv_value_POLLIN
3355 g_pollout=$glib_cv_value_POLLOUT
3356 g_pollpri=$glib_cv_value_POLLPRI
3357 g_pollhup=$glib_cv_value_POLLHUP
3358 g_pollerr=$glib_cv_value_POLLERR
3359 g_pollnval=$glib_cv_value_POLLNVAL
3360
3361 # If a family is not found on the system, define that family to
3362 # a negative value, picking a different one for each undefined
3363 # family (-1 for AF_UNIX, -2 for the next one, -3 ...)
3364 # This is needed because glib-mkenums doesn't handle optional
3365 # values in enums, and thus we have to have all existing values
3366 # defined in the enum.
3367 if test "x$glib_cv_value_AF_UNIX" != "x"; then
3368   g_af_unix=$glib_cv_value_AF_UNIX
3369 else
3370   g_af_unix=-1
3371 fi
3372 g_af_inet=$glib_cv_value_AF_INET
3373 g_af_inet6=$glib_cv_value_AF_INET6
3374
3375 g_msg_peek=$glib_cv_value_MSG_PEEK
3376 g_msg_oob=$glib_cv_value_MSG_OOB
3377 g_msg_dontroute=$glib_cv_value_MSG_DONTROUTE
3378
3379 g_stack_grows=$glib_cv_stack_grows
3380
3381 g_have_eilseq=$have_eilseq
3382
3383 g_threads_impl_def=$g_threads_impl
3384
3385 g_atomic_lock_free="$glib_cv_g_atomic_lock_free"
3386 g_memory_barrier_needed="$glib_memory_barrier_needed"
3387 g_gcc_atomic_ops="$glib_cv_gcc_has_builtin_atomic_operations"
3388
3389 g_module_suffix="$glib_gmodule_suffix"
3390
3391 g_pid_type="$glib_pid_type"
3392 case $host in
3393   *-*-beos*)
3394     glib_os="#define G_OS_BEOS"
3395     ;;
3396   *-*-cygwin*)
3397     glib_os="#define G_OS_UNIX
3398 #define G_PLATFORM_WIN32
3399 #define G_WITH_CYGWIN"
3400     ;;
3401   *-*-mingw*)
3402     glib_os="#define G_OS_WIN32
3403 #define G_PLATFORM_WIN32"
3404     ;;
3405   *)
3406     glib_os="#define G_OS_UNIX"
3407     ;;
3408 esac
3409 glib_static_compilation=""
3410 if test x$glib_win32_static_compilation = xyes; then
3411   glib_static_compilation="#define GLIB_STATIC_COMPILATION 1
3412 #define GOBJECT_STATIC_COMPILATION 1"
3413 fi
3414 ])
3415
3416 # Redo enough to get guint32 and guint64 for the alignment checks below
3417 case 4 in
3418 $ac_cv_sizeof_short)
3419   gint32=short
3420   ;;
3421 $ac_cv_sizeof_int)
3422   gint32=int
3423   ;;
3424 $ac_cv_sizeof_long)
3425   gint32=long
3426   ;;
3427 esac
3428 case 8 in
3429 $ac_cv_sizeof_int)
3430   gint64=int
3431   ;;
3432 $ac_cv_sizeof_long)
3433   gint64=long
3434   ;;
3435 $ac_cv_sizeof_long_long)
3436   gint64='long long'
3437   ;;
3438 $ac_cv_sizeof___int64)
3439   gint64='__int64'
3440   ;;
3441 esac
3442
3443 AC_CHECK_TYPE([guint32],,,[typedef unsigned $gint32 guint32;])
3444 AC_CHECK_ALIGNOF([guint32], [AC_INCLUDES_DEFAULT
3445 typedef unsigned $gint32 guint32;])
3446 AC_CHECK_TYPE([guint64],,,[typedef unsigned $gint64 guint64;])
3447 AC_CHECK_ALIGNOF([guint64], [AC_INCLUDES_DEFAULT
3448 typedef unsigned $gint64 guint64;])
3449 AC_CHECK_TYPE([unsigned long])
3450 AC_CHECK_ALIGNOF([unsigned long])
3451
3452 # Check for libdbus1 - Optional - is only used in the GDBus test cases
3453 #
3454 # 1.2.14 required for dbus_message_set_serial
3455 AS_IF([ test x$enable_modular_tests = xyes], [
3456    PKG_CHECK_MODULES(DBUS1,
3457                      dbus-1 >= 1.2.14,
3458                      [AC_DEFINE(HAVE_DBUS1, 1, [Define if dbus-1 is available]) have_dbus1=yes],
3459                      have_dbus1=no)
3460    AC_SUBST(DBUS1_CFLAGS)
3461    AC_SUBST(DBUS1_LIBS)
3462 ])
3463 AM_CONDITIONAL(HAVE_DBUS1, [test "x$have_dbus1" = "xyes"])
3464
3465 AC_CHECK_PROGS([DBUS_DAEMON], [dbus-daemon])
3466 AM_CONDITIONAL([HAVE_DBUS_DAEMON], [test x$DBUS_DAEMON = xdbus-daemon ])
3467
3468 dnl
3469 dnl Check for -Bsymbolic-functions linker flag used to avoid
3470 dnl intra-library PLT jumps, if available.
3471 dnl
3472
3473 AC_ARG_ENABLE(Bsymbolic,
3474               [AC_HELP_STRING([--disable-Bsymbolic],
3475                               [avoid linking with -Bsymbolic])],,
3476               [SAVED_LDFLAGS="${LDFLAGS}"
3477                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
3478                LDFLAGS=-Wl,-Bsymbolic-functions
3479                AC_TRY_LINK([], [int main (void) { return 0; }],
3480                            AC_MSG_RESULT(yes)
3481                            enable_Bsymbolic=yes,
3482                            AC_MSG_RESULT(no)
3483                            enable_Bsymbolic=no)
3484                LDFLAGS="${SAVED_LDFLAGS}"])
3485
3486 if test "x${enable_Bsymbolic}" = "xyes"; then
3487   GLIB_LINK_FLAGS=-Wl,-Bsymbolic-functions
3488 fi
3489
3490 AC_SUBST(GLIB_LINK_FLAGS)
3491
3492 #
3493 # Define variables corresponding to the correct include paths to use for
3494 # in-tree building.
3495 #
3496
3497 # for config.h:
3498 config_h_INCLUDES='-I$(top_builddir)'
3499 AC_SUBST(config_h_INCLUDES)
3500
3501 # glib:
3502 #   config.h
3503 #   $(top_builddir)/glib: for glibconfig.h
3504 #   $(top_srcdir)/glib:   for glib.h
3505 #   $(top_srcdir):        for everything
3506 glib_INCLUDES='$(config_h_INCLUDES) -I$(top_builddir)/glib -I$(top_srcdir)/glib -I$(top_srcdir)'
3507 AC_SUBST(glib_INCLUDES)
3508
3509 # gthread:
3510 #   same as glib
3511 gthread_INCLUDES='$(glib_INCLUDES)'
3512 AC_SUBST(gthread_INCLUDES)
3513
3514 # gobject:
3515 #   same as gthread
3516 gobject_INCLUDES='$(gthread_INCLUDES)'
3517 AC_SUBST(gobject_INCLUDES)
3518
3519 # gmodule:
3520 #   glib includes
3521 #   $(top_srcdir)/gmodule: for gmodule.h
3522 gmodule_INCLUDES='$(glib_INCLUDES) -I$(top_srcdir)/gmodule'
3523 AC_SUBST(gmodule_INCLUDES)
3524
3525 # gio:
3526 #   same as gmodule
3527 gio_INCLUDES='$(gmodule_INCLUDES)'
3528 AC_SUBST(gio_INCLUDES)
3529
3530
3531 AC_CONFIG_FILES([
3532 glib-2.0.pc
3533 gmodule-2.0.pc
3534 gmodule-export-2.0.pc
3535 gmodule-no-export-2.0.pc
3536 gthread-2.0.pc
3537 gobject-2.0.pc
3538 gio-2.0.pc
3539 gio-unix-2.0.pc
3540 gio-windows-2.0.pc
3541 glib-zip
3542 glib-gettextize
3543 Makefile
3544 build/Makefile
3545 build/win32/Makefile
3546 build/win32/dirent/Makefile
3547 build/win32/vs9/Makefile
3548 build/win32/vs10/Makefile
3549 glib/Makefile
3550 glib/glib.stp
3551 glib/libcharset/Makefile
3552 glib/gnulib/Makefile
3553 glib/pcre/Makefile
3554 glib/update-pcre/Makefile
3555 glib/tests/Makefile
3556 gmodule/Makefile
3557 gmodule/gmoduleconf.h
3558 gobject/Makefile
3559 gobject/gobject.stp
3560 gobject/glib-mkenums
3561 gobject/tests/Makefile
3562 gthread/Makefile
3563 gio/Makefile
3564 gio/gdbus-2.0/codegen/Makefile
3565 gio/gdbus-2.0/codegen/config.py
3566 gio/xdgmime/Makefile
3567 gio/inotify/Makefile
3568 gio/fen/Makefile
3569 gio/fam/Makefile
3570 gio/win32/Makefile
3571 gio/tests/Makefile
3572 gio/tests/gdbus-object-manager-example/Makefile
3573 po/Makefile.in
3574 docs/Makefile
3575 docs/reference/Makefile
3576 docs/reference/glib/Makefile
3577 docs/reference/glib/version.xml
3578 docs/reference/gobject/Makefile
3579 docs/reference/gobject/version.xml
3580 docs/reference/gio/Makefile
3581 docs/reference/gio/gdbus-object-manager-example/Makefile
3582 docs/reference/gio/version.xml
3583 tests/Makefile
3584 tests/gobject/Makefile
3585 tests/refcount/Makefile
3586 m4macros/Makefile
3587 ])
3588
3589 AC_CONFIG_COMMANDS([chmod-scripts],
3590 [chmod 0755 glib-zip
3591 chmod 0755 glib-gettextize
3592 chmod 0755 gobject/glib-mkenums])
3593
3594 # we want to invoke this macro solely so that the config.status script
3595 # and automake generated makefiles know about these generated files.
3596 # They are only needed to distcheck the package
3597 if false; then
3598   AC_CONFIG_FILES([
3599     INSTALL
3600     README
3601     config.h.win32
3602     glib/glibconfig.h.win32
3603     glib/makefile.msc
3604     glib/glib.rc
3605     gmodule/makefile.msc
3606     gmodule/gmodule.rc
3607     gobject/makefile.msc
3608     gobject/gobject.rc
3609     gthread/makefile.msc
3610     gthread/gthread.rc
3611     gio/gio.rc
3612     tests/makefile.msc
3613   ])
3614 fi
3615
3616 AC_OUTPUT