configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2 AC_PREREQ([2.62])
   3
   4 dnl ***********************************
   5 dnl *** include special GLib macros ***
   6 dnl ***********************************
   7
   8 m4_define(glib_configure_ac)
   9
  10 #
  11 # The following version number definitions apply to GLib, GModule, GObject,
  12 # GThread and GIO as a whole, so if changes occurred in any of them, they are
  13 # all treated with the same interface and binary age.
  14 #
  15 # Making releases:
  16 #   glib_micro_version += 1;
  17 #   glib_interface_age += 1;
  18 #   glib_binary_age += 1;
  19 # if any functions have been added, set glib_interface_age to 0.
  20 # if backwards compatibility has been broken,
  21 # set glib_binary_age _and_ glib_interface_age to 0.
  22 #
  23 # remember to add a GLIB_VERSION_2_xx macro every time the minor version is
  24 # bumped, as well as the GLIB_DEPRECATED_IN and GLIB_AVAILABLE_IN macros
  25 # for that version - see gversion.h for further information.
  26 #
  27 # in easier to understand terms:
  28 #
  29 # <mclasen> on the stable branch, interface age == micro
  30 # <mclasen> on the unstable (ie master), interface age = 0
  31
  32 m4_define([glib_major_version], [2])
  33 m4_define([glib_minor_version], [37])
  34 m4_define([glib_micro_version], [5])
  35 m4_define([glib_interface_age], [0])
  36 m4_define([glib_binary_age],
  37           [m4_eval(100 * glib_minor_version + glib_micro_version)])
  38 m4_define([glib_version],
  39           [glib_major_version.glib_minor_version.glib_micro_version])
  40
  41 # libtool version related macros
  42 m4_define([glib_lt_release], [glib_major_version.glib_minor_version])
  43 m4_define([glib_lt_current],
  44           [m4_eval(100 * glib_minor_version + glib_micro_version - glib_interface_age)])
  45 m4_define([glib_lt_revision], [glib_interface_age])
  46 m4_define([glib_lt_age], [m4_eval(glib_binary_age - glib_interface_age)])
  47 m4_define([glib_lt_current_minus_age],
  48           [m4_eval(glib_lt_current - glib_lt_age)])
  49
  50 # if the minor version number is odd, then we want debugging.  Otherwise
  51 # we only want minimal debugging support.
  52 m4_define([glib_debug_default],
  53           [m4_if(m4_eval(glib_minor_version % 2), [1], [yes], [minimum])])dnl
  54
  55
  56 AC_INIT(glib, [glib_version],
  57         [http://bugzilla.gnome.org/enter_bug.cgi?product=glib])
  58
  59 AC_CONFIG_HEADERS([config.h])
  60 AC_CONFIG_SRCDIR([glib/glib.h])
  61 AC_CONFIG_MACRO_DIR([m4macros])
  62
  63 # Save this value here, since automake will set cflags later
  64 cflags_set=${CFLAGS+set}
  65
  66 AM_INIT_AUTOMAKE([1.11 -Wno-portability no-define no-dist-gzip dist-xz tar-ustar])
  67 AM_MAINTAINER_MODE([enable])
  68
  69 # Support silent build rules. Disable
  70 # by either passing --disable-silent-rules to configure or passing V=1
  71 # to make
  72 AM_SILENT_RULES([yes])
  73
  74 GLIB_MAJOR_VERSION=glib_major_version
  75 GLIB_MINOR_VERSION=glib_minor_version
  76 GLIB_MICRO_VERSION=glib_micro_version
  77 GLIB_INTERFACE_AGE=glib_interface_age
  78 GLIB_BINARY_AGE=glib_binary_age
  79 GLIB_VERSION=glib_version
  80
  81 AC_SUBST(GLIB_MAJOR_VERSION)
  82 AC_SUBST(GLIB_MINOR_VERSION)
  83 AC_SUBST(GLIB_MICRO_VERSION)
  84 AC_SUBST(GLIB_VERSION)
  85 AC_SUBST(GLIB_INTERFACE_AGE)
  86 AC_SUBST(GLIB_BINARY_AGE)
  87
  88 AC_DEFINE(GLIB_MAJOR_VERSION, [glib_major_version],
  89           [Define to the GLIB major version])
  90 AC_DEFINE(GLIB_MINOR_VERSION, [glib_minor_version],
  91           [Define to the GLIB minor version])
  92 AC_DEFINE(GLIB_MICRO_VERSION, [glib_micro_version],
  93           [Define to the GLIB micro version])
  94 AC_DEFINE(GLIB_INTERFACE_AGE, [glib_interface_age],
  95           [Define to the GLIB interface age])
  96 AC_DEFINE(GLIB_BINARY_AGE, [glib_binary_age],
  97           [Define to the GLIB binary age])
  98
  99 # libtool versioning
 100 LT_RELEASE=glib_lt_release
 101 LT_CURRENT=glib_lt_current
 102 LT_REVISION=glib_lt_revision
 103 LT_AGE=glib_lt_age
 104 LT_CURRENT_MINUS_AGE=glib_lt_current_minus_age
 105 AC_SUBST(LT_RELEASE)
 106 AC_SUBST(LT_CURRENT)
 107 AC_SUBST(LT_REVISION)
 108 AC_SUBST(LT_AGE)
 109 AC_SUBST(LT_CURRENT_MINUS_AGE)
 110
 111 dnl Checks for programs.
 112 AC_PROG_CC
 113 AC_PROG_CPP
 114
 115 AM_CONDITIONAL(HAVE_GCC, [test "$GCC" = "yes"])
 116
 117 AC_CANONICAL_HOST
 118
 119 AC_MSG_CHECKING([for the BeOS])
 120 case $host in
 121   *-*-beos*)
 122     glib_native_beos="yes"
 123     ;;
 124   *)
 125     glib_native_beos="no"
 126     ;;
 127 esac
 128 AC_MSG_RESULT([$glib_native_beos])
 129
 130 dnl
 131
 132 AC_MSG_CHECKING([for Win32])
 133 LIB_EXE_MACHINE_FLAG=X86
 134 case "$host" in
 135   *-*-mingw*)
 136     glib_native_win32=yes
 137     glib_pid_type='void *'
 138     glib_cv_stack_grows=no
 139     # Unfortunately the mingw implementations of C99-style snprintf and vsnprintf
 140     # don't seem to be quite good enough, at least not in mingw-runtime-3.14.
 141     # (Sorry, I don't know exactly what is the problem, but it is related to
 142     # floating point formatting and decimal point vs. comma.)
 143     # The simple tests in AC_FUNC_VSNPRINTF_C99 and AC_FUNC_SNPRINTF_C99 aren't
 144     # rigorous enough to notice, though.
 145     # So preset the autoconf cache variables.
 146     ac_cv_func_vsnprintf_c99=no
 147     ac_cv_func_snprintf_c99=no
 148     case "$host" in
 149     x86_64-*-*)
 150       LIB_EXE_MACHINE_FLAG=X64
 151       ;;
 152     esac
 153
 154     AC_DEFINE([_WIN32_WINNT], [0x0501], [Target the Windows XP API])
 155     ;;
 156   *)
 157     glib_native_win32=no
 158     glib_pid_type=int
 159     ;;
 160 esac
 161 case $host in
 162   *-*-linux*)
 163     glib_os_linux=yes
 164     ;;
 165 esac
 166
 167 AC_MSG_RESULT([$glib_native_win32])
 168
 169 AC_MSG_CHECKING([for the Android])
 170 case $host in
 171   *android*)
 172     glib_native_android="yes"
 173     ;;
 174   *)
 175     glib_native_android="no"
 176     ;;
 177 esac
 178 AC_MSG_RESULT([$glib_native_android])
 179
 180 AC_SUBST(LIB_EXE_MACHINE_FLAG)
 181
 182 glib_have_carbon=no
 183 AC_MSG_CHECKING([for Mac OS X Carbon support])
 184 AC_TRY_CPP([
 185 #include <Carbon/Carbon.h>
 186 #include <CoreServices/CoreServices.h>
 187 ], glib_have_carbon=yes)
 188
 189 AC_MSG_RESULT([$glib_have_carbon])
 190
 191 glib_have_cocoa=no
 192 AC_MSG_CHECKING([for Mac OS X Cocoa support])
 193 AC_TRY_CPP([
 194 #include <Cocoa/Cocoa.h>
 195 #ifdef GNUSTEP_BASE_VERSION
 196 #error "Detected GNUstep, not Cocoa"
 197 #endif
 198 ], glib_have_cocoa=yes)
 199
 200 AC_MSG_RESULT([$glib_have_cocoa])
 201
 202 AM_CONDITIONAL(OS_WIN32, [test "$glib_native_win32" = "yes"])
 203 AM_CONDITIONAL(OS_WIN32_X64, [test "$LIB_EXE_MACHINE_FLAG" = "X64"])
 204 AM_CONDITIONAL(OS_UNIX, [test "$glib_native_win32" != "yes"])
 205 AM_CONDITIONAL(OS_LINUX, [test "$glib_os_linux" = "yes"])
 206 AM_CONDITIONAL(OS_CARBON, [test "$glib_have_carbon" = "yes"])
 207 AM_CONDITIONAL(OS_COCOA, [test "$glib_have_cocoa" = "yes"])
 208
 209 AS_IF([test "$glib_native_win32" = "yes"], [
 210   AC_CHECK_TOOL(WINDRES, windres, no)
 211   if test "$WINDRES" = no; then
 212     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 213   fi
 214   AC_CHECK_TOOL(NM, nm, no)
 215   if test "$NM" = no; then
 216     AC_MSG_ERROR([*** Could not find an implementation of nm in your PATH.])
 217   fi
 218   AC_CHECK_TOOL(RANLIB, ranlib, :)
 219   AC_CHECK_TOOL(DLLTOOL, dlltool, :)
 220   AC_CHECK_PROG(ms_librarian, [lib.exe], [yes], [no])
 221 ])
 222 AM_CONDITIONAL(MS_LIB_AVAILABLE, [test x$ms_librarian = xyes])
 223
 224 AS_IF([test "x$glib_have_carbon" = "xyes"], [
 225   AC_DEFINE(HAVE_CARBON, 1, [define to 1 if Carbon is available])
 226   LDFLAGS="$LDFLAGS -Wl,-framework,Carbon"
 227 ])
 228
 229 if test "x$glib_have_cocoa" = "xyes"; then
 230   AC_DEFINE(HAVE_COCOA, 1, [define to 1 if Cocoa is available])
 231   LDFLAGS="$LDFLAGS -Wl,-framework,Foundation"
 232 fi
 233
 234 gl_GLIBC21
 235 AS_IF([test "x$GLIBC21" = "xyes"], [
 236   AC_DEFINE([_GNU_SOURCE], 1, [Make all glibc extensions visible])
 237 ])
 238
 239 dnl declare --enable-* args and collect ac_help strings
 240 AC_ARG_ENABLE(debug,
 241               AS_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 242                              [turn on debugging @<:@default=glib_debug_default@:>@]),,
 243               enable_debug=glib_debug_default)
 244
 245 AC_ARG_ENABLE(gc_friendly,
 246               [AS_HELP_STRING([--enable-gc-friendly],
 247                               [turn on garbage collector friendliness [default=no]])],,
 248               [enable_gc_friendly=no])
 249 AC_ARG_ENABLE(mem_pools,
 250               [AS_HELP_STRING([--disable-mem-pools],
 251                               [disable all glib memory pools])],,
 252               [disable_mem_pools=no])
 253 AC_ARG_ENABLE(rebuilds,
 254               [AS_HELP_STRING([--disable-rebuilds],
 255                               [disable all source autogeneration rules])],,
 256               [enable_rebuilds=yes])
 257
 258 GLIB_TESTS
 259
 260 AC_MSG_CHECKING([whether to enable garbage collector friendliness])
 261 AS_IF([test "x$enable_gc_friendly" = "xyes"], [
 262   AC_DEFINE(ENABLE_GC_FRIENDLY_DEFAULT, 1, [Whether to enable GC friendliness by default])
 263   AC_MSG_RESULT([yes])
 264 ], [ AC_MSG_RESULT([no]) ])
 265
 266 AC_MSG_CHECKING([whether to disable memory pools])
 267 AS_IF([test "x$disable_mem_pools" = "xno"], [
 268   AC_MSG_RESULT([no])
 269 ], [
 270   AC_DEFINE(DISABLE_MEM_POOLS, [1], [Whether to disable memory pools])
 271   AC_MSG_RESULT([yes])
 272 ])
 273
 274 dnl location to install runtime libraries, e.g. ../../lib to install
 275 dnl to /lib if libdir is /usr/lib
 276 AC_ARG_WITH(runtime-libdir,
 277            [AS_HELP_STRING([--with-runtime-libdir=RELPATH],
 278                            [install runtime libraries relative to libdir])],
 279            [],
 280            [with_runtime_libdir=""])
 281 GLIB_RUNTIME_LIBDIR="$with_runtime_libdir"
 282 ABS_GLIB_RUNTIME_LIBDIR="`readlink -f $libdir/$with_runtime_libdir`"
 283 AC_SUBST(GLIB_RUNTIME_LIBDIR)
 284 AC_SUBST(ABS_GLIB_RUNTIME_LIBDIR)
 285 AM_CONDITIONAL(HAVE_GLIB_RUNTIME_LIBDIR, [test "x$with_runtime_libdir" != "x"])
 286
 287 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 288 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], [gcc])
 289 AC_LANG_SAVE
 290 AC_LANG_CPLUSPLUS
 291 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
 292 AM_CONDITIONAL(HAVE_CXX, [test "$CXX" != ""])
 293 AC_LANG_RESTORE
 294
 295 AM_PROG_CC_C_O
 296 AC_PROG_INSTALL
 297
 298 AC_SYS_LARGEFILE
 299
 300 PKG_PROG_PKG_CONFIG(0.16)
 301
 302 if test "x$enable_debug" = "xyes"; then
 303   if test x$cflags_set != xset ; then
 304       case " $CFLAGS " in
 305       *[[\ \    ]]-g[[\ \       ]]*) ;;
 306       *) CFLAGS="$CFLAGS -g" ;;
 307       esac
 308   fi
 309   GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 310 else
 311   GLIB_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 312
 313   if test "x$enable_debug" = "xno"; then
 314     GLIB_DEBUG_FLAGS="$GLIB_DEBUG_FLAGS -DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
 315   fi
 316 fi
 317
 318 # Ensure MSVC-compatible struct packing convention is used when
 319 # compiling for Win32 with gcc.
 320 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 321 # gcc2 uses "-fnative-struct".
 322 if test x"$glib_native_win32" = xyes; then
 323   if test x"$GCC" = xyes; then
 324     msnative_struct=''
 325     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 326     if test -z "$ac_cv_prog_CC"; then
 327       our_gcc="$CC"
 328     else
 329       our_gcc="$ac_cv_prog_CC"
 330     fi
 331     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 332       2.)
 333         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 334           msnative_struct='-fnative-struct'
 335         fi
 336         ;;
 337       *)
 338         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 339           msnative_struct='-mms-bitfields'
 340         fi
 341         ;;
 342     esac
 343     if test x"$msnative_struct" = x ; then
 344       AC_MSG_RESULT([no way])
 345       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 346     else
 347       CFLAGS="$CFLAGS $msnative_struct"
 348       AC_MSG_RESULT([${msnative_struct}])
 349     fi
 350   fi
 351 fi
 352 GLIB_EXTRA_CFLAGS="${msnative_struct}"
 353 AC_SUBST(GLIB_EXTRA_CFLAGS)
 354
 355 AC_EXEEXT
 356
 357 # define a MAINT-like variable REBUILD which is set if Perl
 358 # and awk are found, so autogenerated sources can be rebuilt
 359 AC_PROG_AWK
 360 AC_CHECK_PROGS(PERL, [perl5 perl])
 361 # We would like indent, but don't require it.
 362 AC_CHECK_PROG(INDENT, indent, indent)
 363 REBUILD=\#
 364 if test "x$enable_rebuilds" = "xyes" && \
 365      test -n "$PERL" && \
 366      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 && \
 367      test -n "$AWK" ; then
 368   REBUILD=
 369 fi
 370 AC_SUBST(REBUILD)
 371
 372 # Need full path to Perl for glib-mkenums
 373 #
 374 if test "x$PERL" != x ; then
 375   AC_PATH_PROG(PERL_PATH, [$PERL])
 376 fi
 377 if test "x$PERL_PATH" = x ; then
 378   PERL_PATH="/usr/bin/env perl"
 379 fi
 380 AC_SUBST(PERL_PATH)
 381
 382 # option to specify python interpreter to use; this just sets $PYTHON, so that
 383 # we will fallback to reading $PYTHON if --with-python is not given, and
 384 # python.m4 will get the expected input
 385 AC_ARG_WITH(python,
 386             AS_HELP_STRING([--with-python=PATH],
 387                            [Path to Python interpreter; searches $PATH if only a program name is given; if not given, searches for a few standard names such as "python3" or "python2"]),
 388             [PYTHON="$withval"], [])
 389 if test x"$PYTHON" = xyes; then
 390   AC_MSG_ERROR([--with-python option requires a path or program argument])
 391 fi
 392 AM_PATH_PYTHON(2.5,,PYTHON="/usr/bin/env python2.5")
 393
 394
 395 dnl ***********************
 396 dnl *** Tests for iconv ***
 397 dnl ***********************
 398 dnl
 399 dnl We do this before the gettext checks, to avoid distortion
 400
 401 dnl On Windows we use a native implementation
 402
 403 AS_IF([ test x"$glib_native_win32" = xyes], [
 404   with_libiconv=native
 405 ], [
 406   AC_ARG_WITH(libiconv,
 407               [AS_HELP_STRING([--with-libiconv=@<:@no/gnu/native@:>@],
 408                               [use the libiconv library])],,
 409               [with_libiconv=maybe])
 410
 411   found_iconv=no
 412   case $with_libiconv in
 413     maybe)
 414       # Check in the C library first
 415       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 416       # Check if we have GNU libiconv
 417       if test $found_iconv = "no"; then
 418         AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 419       fi
 420       # Check if we have a iconv in -liconv, possibly from vendor
 421       if test $found_iconv = "no"; then
 422         AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 423       fi
 424       ;;
 425     no)
 426       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 427       ;;
 428     gnu|yes)
 429       AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 430       ;;
 431     native)
 432       AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 433       ;;
 434   esac
 435
 436   if test "x$found_iconv" = "xno" ; then
 437      AC_MSG_ERROR([*** No iconv() implementation found in C library or libiconv])
 438   fi
 439 ])
 440
 441 AC_ARG_ENABLE(iconv-cache,
 442               [AS_HELP_STRING([--enable-iconv-cache=@<:@yes/no/auto@:>@],
 443                               [cache iconv descriptors [default=auto]])],,
 444               [enable_iconv_cache=auto])
 445
 446 AC_MSG_CHECKING([whether to cache iconv descriptors])
 447 case $enable_iconv_cache in
 448   auto)
 449     if test $ac_cv_gnu_library_2_1 = yes; then
 450       enable_iconv_cache=no
 451     else
 452       enable_iconv_cache=yes
 453     fi
 454   ;;
 455   yes|no)
 456   ;;
 457   *) AC_MSG_ERROR([Value given to --enable-iconv-cache must be one of yes, no or auto])
 458   ;;
 459 esac
 460
 461 if test $enable_iconv_cache = yes; then
 462    AC_DEFINE(NEED_ICONV_CACHE,1,[Do we cache iconv descriptors])
 463 fi
 464
 465 AC_MSG_RESULT($enable_iconv_cache)
 466
 467
 468 dnl
 469 dnl zlib support
 470 dnl
 471 PKG_CHECK_MODULES([ZLIB], [zlib], [found_zlib=yes], [found_zlib=no])
 472 AS_IF([test "x$found_zlib" = "xno"], [
 473   AC_CHECK_LIB(z, inflate, [AC_CHECK_HEADER(zlib.h, found_zlib=yes)])
 474   if test "x$found_zlib" = "xno" ; then
 475     AC_MSG_ERROR([*** Working zlib library and headers not found ***])
 476   fi
 477   ZLIB_LIBS='-lz'
 478   AC_SUBST(ZLIB_LIBS)
 479 ])
 480
 481 PKG_CHECK_MODULES(LIBFFI, [libffi >= 3.0.0])
 482 AC_SUBST(LIBFFI_CFLAGS)
 483 AC_SUBST(LIBFFI_LIBS)
 484
 485 dnl
 486 dnl gettext support
 487 dnl
 488
 489 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 490 AC_SUBST([CONFIG_STATUS_DEPENDENCIES],['$(top_srcdir)/po/LINGUAS'])
 491 GLIB_GNU_GETTEXT
 492
 493 if test "$gt_cv_have_gettext" != "yes" ; then
 494   AC_MSG_ERROR([
 495 *** You must have either have gettext support in your C library, or use the
 496 *** GNU gettext library. (http://www.gnu.org/software/gettext/gettext.html
 497 ])
 498 fi
 499
 500 LIBS="$INTLLIBS $LIBS"
 501
 502 GETTEXT_PACKAGE=glib20
 503 AC_SUBST(GETTEXT_PACKAGE)
 504 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
 505   [Define the gettext package to be used])
 506
 507 GLIB_DEFINE_LOCALEDIR(GLIB_LOCALE_DIR)
 508
 509 dnl
 510 dnl Now we are done with gettext checks, figure out ICONV_LIBS
 511 dnl
 512
 513 AS_IF([test x"$glib_native_win32" != xyes], [
 514   if test x$with_libiconv != xno ; then
 515     case " $INTLLIBS " in
 516     *[[\ \      ]]-liconv[[\ \  ]]*) ;;
 517     *) ICONV_LIBS="-liconv" ;;
 518     esac
 519   fi
 520 ])
 521 AC_SUBST(ICONV_LIBS)
 522
 523 case $with_libiconv in
 524   gnu)
 525     AC_DEFINE(USE_LIBICONV_GNU, 1, [Using GNU libiconv])
 526     ;;
 527   native)
 528     AC_DEFINE(USE_LIBICONV_NATIVE, 1, [Using a native implementation of iconv in a separate library])
 529     ;;
 530 esac
 531
 532 dnl Initialize libtool
 533 LT_PREREQ([2.2])
 534 LT_INIT([disable-static win32-dll])
 535 dnl when using libtool 2.x create libtool early, because it's used in configure
 536 m4_ifdef([LT_OUTPUT], [LT_OUTPUT])
 537
 538
 539 AS_IF([test "$glib_native_win32" = "yes"], [
 540   if test x$enable_static = xyes -a x$enable_shared = xyes; then
 541     AC_MSG_ERROR([Can not build both shared and static at the same time on Windows.])
 542   fi
 543   if test x$enable_static = xyes; then
 544     glib_win32_static_compilation=yes
 545     GLIB_WIN32_STATIC_COMPILATION_DEFINE="#define GLIB_STATIC_COMPILATION 1
 546 #define GOBJECT_STATIC_COMPILATION 1"
 547     AC_SUBST(GLIB_WIN32_STATIC_COMPILATION_DEFINE)
 548   fi
 549 ])
 550 AM_CONDITIONAL(OS_WIN32_AND_DLL_COMPILATION, [test x$glib_native_win32 = xyes -a x$glib_win32_static_compilation != xyes])
 551
 552 dnl
 553 dnl DU4 native cc currently needs -std1 for ANSI mode (instead of K&R)
 554 dnl
 555 AS_IF([test $cross_compiling != yes], [
 556     AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 557     glib_save_LIBS=$LIBS
 558     LIBS="$LIBS -lm"
 559     AC_TRY_RUN([#include <math.h>
 560                  int main (void) { return (log(1) != log(1.)); }],
 561          AC_MSG_RESULT(none needed),
 562          glib_save_CFLAGS=$CFLAGS
 563          CFLAGS="$CFLAGS -std1"
 564          AC_TRY_RUN([#include <math.h>
 565                      int main (void) { return (log(1) != log(1.)); }],
 566              AC_MSG_RESULT(-std1),
 567              AC_MSG_RESULT()
 568              CFLAGS=$glib_save_CFLAGS
 569              AC_MSG_WARN(
 570                     [No ANSI prototypes found in library. (-std1 didn't work.)])
 571          )
 572     )
 573     LIBS=$glib_save_LIBS
 574 ])
 575
 576 dnl NeXTStep cc seems to need this
 577 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 578 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 579   AC_MSG_RESULT(none needed),
 580   glib_save_CFLAGS=$CFLAGS
 581   CFLAGS="$CFLAGS -posix"
 582   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 583     AC_MSG_RESULT(-posix),
 584     AC_MSG_RESULT()
 585     CFLAGS=$glib_save_CFLAGS
 586     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 587
 588 # Checks for library functions.
 589 AC_FUNC_VPRINTF
 590 AC_FUNC_ALLOCA
 591 AC_CHECK_FUNCS(mmap posix_memalign memalign valloc fsync pipe2 issetugid)
 592 AC_CHECK_FUNCS(atexit on_exit timegm gmtime_r)
 593
 594 AC_CACHE_CHECK([for __libc_enable_secure], glib_cv_have_libc_enable_secure,
 595   [AC_TRY_LINK([#include <unistd.h>
 596     extern int __libc_enable_secure;],
 597     [return __libc_enable_secure;],
 598    glib_cv_have_libc_enable_secure=yes,
 599    glib_cv_have_libc_enable_secure=no)])
 600 AS_IF([test x$glib_cv_have_libc_enable_secure = xyes], [
 601    AC_DEFINE(HAVE_LIBC_ENABLE_SECURE, 1,
 602      [Define if you have the __libc_enable_secure variable (GNU libc, eglibc)])
 603 ])
 604
 605 AC_CHECK_SIZEOF(char)
 606 AC_CHECK_SIZEOF(short)
 607 AC_CHECK_SIZEOF(long)
 608 AC_CHECK_SIZEOF(int)
 609 AC_CHECK_SIZEOF(void *)
 610 AC_CHECK_SIZEOF(long long)
 611 AC_CHECK_SIZEOF(__int64)
 612
 613 AC_CACHE_CHECK([for sig_atomic_t], ac_cv_type_sig_atomic_t,
 614   [AC_TRY_LINK([#include <signal.h>
 615      #include <sys/types.h>
 616      sig_atomic_t val = 42;],
 617     [return val == 42 ? 0 : 1],
 618    ac_cv_type_sig_atomic_t=yes,
 619    ac_cv_type_sig_atomic_t=no)])
 620 if test x$ac_cv_type_sig_atomic_t = xyes; then
 621    AC_DEFINE(HAVE_SIG_ATOMIC_T, 1,
 622      [Define if you have the 'sig_atomic_t' type.])
 623 fi
 624
 625 if test x$ac_cv_sizeof_long = x8 || test x$ac_cv_sizeof_long_long = x8 || test x$ac_cv_sizeof___int64 = x8 ; then
 626   :
 627 else
 628   AC_MSG_ERROR([
 629 *** GLib requires a 64 bit type. You might want to consider
 630 *** using the GNU C compiler.
 631 ])
 632 fi
 633
 634 AS_IF([test x$glib_native_win32 != xyes && test x$ac_cv_sizeof_long_long = x8], [
 635         # long long is a 64 bit integer.
 636         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 637         AC_CACHE_VAL(glib_cv_long_long_format,[
 638                 for format in ll q I64; do
 639                   AC_TRY_RUN([#include <stdio.h>
 640                         int main()
 641                         {
 642                           long long b, a = -0x3AFAFAFAFAFAFAFALL;
 643                           char buffer[1000];
 644                           sprintf (buffer, "%${format}u", a);
 645                           sscanf (buffer, "%${format}u", &b);
 646                           exit (b!=a);
 647                         }
 648                         ],
 649                         [glib_cv_long_long_format=${format}
 650                         break],
 651                         [],[:])
 652                 done])
 653         AS_IF([ test -n "$glib_cv_long_long_format"], [
 654           AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 655           AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 656           if test x"$glib_cv_long_long_format" = xI64; then
 657             AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 658           fi
 659         ], [AC_MSG_RESULT(none)])
 660 ],[ test x$ac_cv_sizeof___int64 = x8], [
 661         # __int64 is a 64 bit integer.
 662         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 663         # We know this is MSVCRT.DLL, and what the formats are
 664         glib_cv_long_long_format=I64
 665         AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 666         AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 667         AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 668 ])
 669
 670 AC_C_CONST
 671
 672 dnl
 673 dnl check in which direction the stack grows
 674 dnl
 675 AC_CACHE_CHECK([for growing stack pointer],glib_cv_stack_grows,[
 676         AC_TRY_RUN([
 677         volatile int *a = 0, *b = 0;
 678         void foo (void);
 679         int main () { volatile int y = 7; a = &y; foo (); return b > a; }
 680         void foo (void) { volatile int x = 5; b = &x; }
 681         ],
 682         glib_cv_stack_grows=no
 683         ,
 684         glib_cv_stack_grows=yes
 685         ,)
 686 ])
 687
 688 dnl AC_C_INLINE is useless to us since it bails out too early, we need to
 689 dnl truely know which ones of `inline', `__inline' and `__inline__' are
 690 dnl actually supported.
 691 AC_CACHE_CHECK([for __inline],glib_cv_has__inline,[
 692         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 693         __inline int foo () { return 0; }
 694         int main () { return foo (); }
 695         ]])],
 696         glib_cv_has__inline=yes
 697         ,
 698         glib_cv_has__inline=no
 699         ,)
 700 ])
 701 case x$glib_cv_has__inline in
 702 xyes) AC_DEFINE(G_HAVE___INLINE,1,[Have __inline keyword])
 703 esac
 704 AC_CACHE_CHECK([for __inline__],glib_cv_has__inline__,[
 705         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 706         __inline__ int foo () { return 0; }
 707         int main () { return foo (); }
 708         ]])],
 709         glib_cv_has__inline__=yes
 710         ,
 711         glib_cv_has__inline__=no
 712         ,)
 713 ])
 714 case x$glib_cv_has__inline__ in
 715 xyes) AC_DEFINE(G_HAVE___INLINE__,1,[Have __inline__ keyword])
 716 esac
 717 AC_CACHE_CHECK([for inline], glib_cv_hasinline,[
 718         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 719         #undef inline
 720         inline int foo () { return 0; }
 721         int main () { return foo (); }
 722         ]])],
 723         glib_cv_hasinline=yes
 724         ,
 725         glib_cv_hasinline=no
 726         ,)
 727 ])
 728 case x$glib_cv_hasinline in
 729 xyes) AC_DEFINE(G_HAVE_INLINE,1,[Have inline keyword])
 730 esac
 731
 732 # if we can use inline functions in headers
 733 AC_MSG_CHECKING(if inline functions in headers work)
 734 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 735 #if defined (G_HAVE_INLINE) && defined (__GNUC__) && defined (__STRICT_ANSI__)
 736 #  undef inline
 737 #  define inline __inline__
 738 #elif !defined (G_HAVE_INLINE)
 739 #  undef inline
 740 #  if defined (G_HAVE___INLINE__)
 741 #    define inline __inline__
 742 #  elif defined (G_HAVE___INLINE)
 743 #    define inline __inline
 744 #  endif
 745 #endif
 746
 747 int glib_test_func2 (int);
 748
 749 static inline int
 750 glib_test_func1 (void) {
 751   return glib_test_func2 (1);
 752 }
 753
 754 int
 755 main (void) {
 756   int i = 1;
 757 }]])],[g_can_inline=yes],[g_can_inline=no])
 758 AC_MSG_RESULT($g_can_inline)
 759
 760 dnl *** check for working do while(0) macros ***
 761 AC_CACHE_CHECK([for working do while(0) macros], g_cv_support_dowhile_macros, [
 762         AC_TRY_COMPILE([],[
 763         #define STMT_START do
 764         #define STMT_END while(0)
 765         #define STMT_TEST STMT_START { i = 0; } STMT_END
 766         int main(void) { int i = 1; STMT_TEST; return i; }],
 767         [g_cv_support_dowhile_macros=yes],
 768         [g_cv_support_dowhile_macros=no],
 769         [g_cv_support_dowhile_macros=yes])
 770 ])
 771 if test x$g_cv_support_dowhile_macros = xyes; then
 772   AC_DEFINE(HAVE_DOWHILE_MACROS, 1, [define for working do while(0) macros])
 773 fi
 774
 775 # check for flavours of varargs macros
 776 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 777 AC_TRY_COMPILE([],[
 778 int a(int p1, int p2, int p3);
 779 #define call_a(...) a(1,__VA_ARGS__)
 780 call_a(2,3);
 781 ],g_have_iso_c_varargs=yes,g_have_iso_c_varargs=no)
 782 AC_MSG_RESULT($g_have_iso_c_varargs)
 783
 784 AC_MSG_CHECKING(for ISO C99 varargs macros in C++)
 785 AS_IF([test "$CXX" = ""], [
 786 dnl No C++ compiler
 787   g_have_iso_cxx_varargs=no
 788 else
 789   AC_LANG_CPLUSPLUS
 790   AC_TRY_COMPILE([],[
 791 int a(int p1, int p2, int p3);
 792 #define call_a(...) a(1,__VA_ARGS__)
 793 call_a(2,3);
 794 ],g_have_iso_cxx_varargs=yes,g_have_iso_cxx_varargs=no)
 795   AC_LANG_C
 796 ])
 797 AC_MSG_RESULT($g_have_iso_cxx_varargs)
 798
 799 AC_MSG_CHECKING(for GNUC varargs macros)
 800 AC_TRY_COMPILE([],[
 801 int a(int p1, int p2, int p3);
 802 #define call_a(params...) a(1,params)
 803 call_a(2,3);
 804 ],g_have_gnuc_varargs=yes,g_have_gnuc_varargs=no)
 805 AC_MSG_RESULT($g_have_gnuc_varargs)
 806
 807 # check for GNUC visibility support
 808 AC_MSG_CHECKING(for GNUC visibility attribute)
 809 GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 810 void
 811 __attribute__ ((visibility ("hidden")))
 812      f_hidden (void)
 813 {
 814 }
 815 void
 816 __attribute__ ((visibility ("internal")))
 817      f_internal (void)
 818 {
 819 }
 820 void
 821 __attribute__ ((visibility ("protected")))
 822      f_protected (void)
 823 {
 824 }
 825 void
 826 __attribute__ ((visibility ("default")))
 827      f_default (void)
 828 {
 829 }
 830 int main (void)
 831 {
 832         f_hidden();
 833         f_internal();
 834         f_protected();
 835         f_default();
 836         return 0;
 837 }
 838 ]])],g_have_gnuc_visibility=yes,g_have_gnuc_visibility=no)
 839 AC_MSG_RESULT($g_have_gnuc_visibility)
 840 AM_CONDITIONAL(HAVE_GNUC_VISIBILITY, [test x$g_have_gnuc_visibility = xyes])
 841
 842 AC_MSG_CHECKING([whether using Sun Studio C compiler])
 843 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#if defined(__SUNPRO_C) || (__SUNPRO_C >= 0x550)
 844 #else
 845 # include "error: this is not Sun Studio."
 846 #endif
 847 ]], [[]])], [ g_have_sunstudio_visibility=yes ], [ g_have_sunstudio_visibility=no ])
 848 AC_MSG_RESULT($g_have_sunstudio_visibility)
 849 AM_CONDITIONAL(HAVE_SUNSTUDIO_VISIBILITY, [test x$g_have_sunstudio_visibility = xyes])
 850
 851 # check for bytesex stuff
 852 AC_C_BIGENDIAN
 853 if test x$ac_cv_c_bigendian = xuniversal ; then
 854 AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __BIG_ENDIAN
 855 #else
 856 #error Not a big endian.
 857 #endif],
 858     ac_cv_c_bigendian=yes
 859     ,AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __LITTLE_ENDIAN
 860 #else
 861 #error Not a little endian.
 862 #endif],
 863     ac_cv_c_bigendian=no
 864     ,AC_MSG_WARN([Could not determine endianness.])))
 865 fi
 866
 867
 868 # check for header files
 869 AC_CHECK_HEADERS([dirent.h float.h limits.h pwd.h grp.h sys/param.h sys/poll.h sys/resource.h])
 870 AC_CHECK_HEADERS([sys/time.h sys/times.h sys/wait.h unistd.h values.h])
 871 AC_CHECK_HEADERS([sys/select.h sys/types.h stdint.h inttypes.h sched.h malloc.h])
 872 AC_CHECK_HEADERS([sys/vfs.h sys/vmount.h sys/statfs.h sys/statvfs.h sys/filio.h])
 873 AC_CHECK_HEADERS([mntent.h sys/mnttab.h sys/vfstab.h sys/mntctl.h fstab.h])
 874 AC_CHECK_HEADERS([sys/uio.h sys/mkdev.h])
 875 AC_CHECK_HEADERS([linux/magic.h])
 876 AC_CHECK_HEADERS([sys/prctl.h])
 877
 878 AC_CHECK_HEADERS([sys/mount.h sys/sysctl.h], [], [],
 879 [#if HAVE_SYS_PARAM_H
 880  #include <sys/param.h>
 881  #endif
 882 ])
 883 AC_CHECK_FUNCS(sysctlbyname)
 884
 885 AC_CHECK_HEADERS([xlocale.h])
 886
 887 # check for structure fields
 888 AC_CHECK_MEMBERS([struct stat.st_mtimensec, struct stat.st_mtim.tv_nsec, struct stat.st_atimensec, struct stat.st_atim.tv_nsec, struct stat.st_ctimensec, struct stat.st_ctim.tv_nsec])
 889 AC_CHECK_MEMBERS([struct stat.st_blksize, struct stat.st_blocks, struct statfs.f_fstypename, struct statfs.f_bavail],,, [#include <sys/types.h>
 890 #include <sys/stat.h>
 891 #include <unistd.h>
 892 #ifdef HAVE_SYS_STATFS_H
 893 #include <sys/statfs.h>
 894 #endif
 895 #ifdef HAVE_SYS_PARAM_H
 896 #include <sys/param.h>
 897 #endif
 898 #ifdef HAVE_SYS_MOUNT_H
 899 #include <sys/mount.h>
 900 #endif])
 901 # struct statvfs.f_basetype is available on Solaris but not for Linux.
 902 AC_CHECK_MEMBERS([struct statvfs.f_basetype],,, [#include <sys/statvfs.h>])
 903 AC_CHECK_MEMBERS([struct statvfs.f_fstypename],,, [#include <sys/statvfs.h>])
 904 AC_CHECK_MEMBERS([struct tm.tm_gmtoff, struct tm.__tm_gmtoff],,,[#include <time.h>])
 905
 906 AC_STRUCT_DIRENT_D_TYPE
 907
 908 # Checks for libcharset
 909 AM_LANGINFO_CODESET
 910 AC_CHECK_HEADERS([stddef.h stdlib.h string.h])
 911 AC_CHECK_FUNCS(setlocale)
 912
 913 # check additional type sizes
 914 AC_CHECK_SIZEOF(size_t)
 915
 916 dnl Try to figure out whether gsize should be long or int
 917 AC_MSG_CHECKING([for the appropriate definition for size_t])
 918
 919 case $ac_cv_sizeof_size_t in
 920   $ac_cv_sizeof_short)
 921       glib_size_type=short
 922       ;;
 923   $ac_cv_sizeof_int)
 924       glib_size_type=int
 925       ;;
 926   $ac_cv_sizeof_long)
 927       glib_size_type=long
 928       ;;
 929   $ac_cv_sizeof_long_long)
 930       glib_size_type='long long'
 931       ;;
 932   $ac_cv_sizeof__int64)
 933       glib_size_type='__int64'
 934       ;;
 935   *)  AC_MSG_ERROR([No type matching size_t in size])
 936       ;;
 937 esac
 938
 939 dnl If int/long are the same size, we see which one produces
 940 dnl warnings when used in the location as size_t. (This matters
 941 dnl on AIX with xlc)
 942 dnl
 943 AS_IF([test $ac_cv_sizeof_size_t = $ac_cv_sizeof_int &&
 944        test $ac_cv_sizeof_size_t = $ac_cv_sizeof_long], [
 945   GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 946 #if defined(_AIX) && !defined(__GNUC__)
 947 #pragma options langlvl=stdc89
 948 #endif
 949 #include <stddef.h>
 950 int main ()
 951 {
 952   size_t s = 1;
 953   unsigned int *size_int = &s;
 954   return (int)*size_int;
 955 }
 956     ]])],glib_size_type=int,
 957       [GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 958 #if defined(_AIX) && !defined(__GNUC__)
 959 #pragma options langlvl=stdc89
 960 #endif
 961 #include <stddef.h>
 962 int main ()
 963 {
 964    size_t s = 1;
 965    unsigned long *size_long = &s;
 966    return (int)*size_long;
 967 }
 968         ]])],glib_size_type=long)])
 969 ])
 970
 971 AC_MSG_RESULT(unsigned $glib_size_type)
 972
 973 AC_CHECK_SIZEOF(ssize_t)
 974
 975 dnl Try to figure out whether gssize should be long or int
 976 AC_MSG_CHECKING([for the appropriate definition for ssize_t])
 977
 978 case $ac_cv_sizeof_ssize_t in
 979   $ac_cv_sizeof_short)
 980       glib_ssize_type=short
 981       ;;
 982   $ac_cv_sizeof_int)
 983       glib_ssize_type=int
 984       ;;
 985   $ac_cv_sizeof_long)
 986       glib_ssize_type=long
 987       ;;
 988   $ac_cv_sizeof_long_long)
 989       glib_ssize_type='long long'
 990       ;;
 991   $ac_cv_sizeof__int64)
 992       glib_ssize_type='__int64'
 993       ;;
 994   *)  AC_MSG_ERROR([No type matching ssize_t in size])
 995       ;;
 996 esac
 997
 998 dnl If int/long are the same size, we see which one produces
 999 dnl warnings when used in the location as ssize_t. (This matters
1000 dnl on Android where ssize_t is long and size_t is unsigned int)
1001 dnl
1002 AS_IF([test $ac_cv_sizeof_ssize_t = $ac_cv_sizeof_int &&
1003        test $ac_cv_sizeof_ssize_t = $ac_cv_sizeof_long], [
1004   GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
1005 #if defined(_AIX) && !defined(__GNUC__)
1006 #pragma options langlvl=stdc89
1007 #endif
1008 #include <stddef.h>
1009 #ifdef HAVE_INTTYPES_H
1010 # include <inttypes.h>
1011 #endif
1012 #ifdef HAVE_STDINT_H
1013 # include <stdint.h>
1014 #endif
1015 #ifdef HAVE_UNISTD_H
1016 # include <unistd.h>
1017 #endif
1018 #ifdef HAVE_SYS_TYPES_H
1019 # include <sys/types.h>
1020 #endif
1021 int main ()
1022 {
1023   ssize_t s = 1;
1024   int *size_int = &s;
1025   return (int)*size_int;
1026 }
1027     ]])],glib_ssize_type=int,
1028       [GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
1029 #if defined(_AIX) && !defined(__GNUC__)
1030 #pragma options langlvl=stdc89
1031 #endif
1032 #include <stddef.h>
1033 #ifdef HAVE_INTTYPES_H
1034 # include <inttypes.h>
1035 #endif
1036 #ifdef HAVE_STDINT_H
1037 # include <stdint.h>
1038 #endif
1039 #ifdef HAVE_UNISTD_H
1040 # include <unistd.h>
1041 #endif
1042 #ifdef HAVE_SYS_TYPES_H
1043 # include <sys/types.h>
1044 #endif
1045 int main ()
1046 {
1047    ssize_t s = 1;
1048    long *size_long = &s;
1049    return (int)*size_long;
1050 }
1051         ]])],glib_ssize_type=long)])
1052 ])
1053
1054 AC_MSG_RESULT($glib_ssize_type)
1055
1056 # Check for some functions
1057 AC_CHECK_FUNCS(lstat strerror strsignal memmove vsnprintf stpcpy strcasecmp strncasecmp poll getcwd vasprintf setenv unsetenv getc_unlocked readlink symlink fdwalk memmem)
1058 AC_CHECK_FUNCS(chown lchmod lchown fchmod fchown link utimes getgrgid getpwuid getresuid)
1059 AC_CHECK_FUNCS(getmntent_r setmntent endmntent hasmntopt getfsstat getvfsstat fallocate)
1060 # Check for high-resolution sleep functions
1061 AC_CHECK_FUNCS(splice)
1062 AC_CHECK_FUNCS(prlimit)
1063
1064 # To avoid finding a compatibility unusable statfs, which typically
1065 # successfully compiles, but warns to use the newer statvfs interface:
1066 AS_IF([test $ac_cv_header_sys_statvfs_h = yes], [AC_CHECK_FUNCS([statvfs])])
1067 AS_IF([test $ac_cv_header_sys_statfs_h  = yes -o $ac_cv_header_sys_mount_h = yes], [AC_CHECK_FUNCS([statfs])])
1068
1069 AC_MSG_CHECKING([whether to use statfs or statvfs])
1070 # Some systems have both statfs and statvfs, pick the most "native" for these
1071 AS_IF([test x$ac_cv_func_statfs = xyes && test x$ac_cv_func_statvfs = xyes],
1072    [
1073    # on solaris and irix, statfs doesn't even have the f_bavail field
1074    AS_IF([test x$ac_cv_member_struct_statfs_f_bavail = xno],
1075       [ac_cv_func_statfs=no],
1076    # else, at least on linux, statfs is the actual syscall
1077       [ac_cv_func_statvfs=no])
1078    ])
1079
1080 AS_IF([test x$ac_cv_func_statfs = xyes],
1081       [
1082          AC_DEFINE([USE_STATFS], [1], [Define to use statfs()])
1083          AC_MSG_RESULT([statfs])
1084       ],
1085       [test x$ac_cv_func_statvfs = xyes],
1086       [
1087          AC_DEFINE([USE_STATVFS], [1], [Define to use statvfs()])
1088          AC_MSG_RESULT([statvfs])
1089       ],
1090       [  AC_MSG_RESULT([neither])])
1091
1092 AC_CHECK_HEADERS(crt_externs.h)
1093 AC_CHECK_FUNCS(_NSGetEnviron)
1094
1095 AC_CHECK_FUNCS(newlocale uselocale strtod_l strtoll_l strtoull_l)
1096
1097 AC_FUNC_VSNPRINTF_C99
1098 AC_FUNC_PRINTF_UNIX98
1099
1100 # Internet address families
1101 if test $glib_native_win32 = yes; then
1102   glib_inet_includes=["
1103 #include <winsock2.h>
1104   "]
1105 else
1106   glib_inet_includes=["
1107 #include <sys/types.h>
1108 #include <sys/socket.h>
1109   "]
1110 fi
1111
1112 glib_failed=false
1113 GLIB_CHECK_VALUE(AF_INET, $glib_inet_includes, glib_failed=true)
1114 GLIB_CHECK_VALUE(AF_INET6, $glib_inet_includes, glib_failed=true)
1115 # winsock defines this even though it doesn't support it
1116 GLIB_CHECK_VALUE(AF_UNIX, $glib_inet_includes, glib_failed=true)
1117 if $glib_failed ; then
1118   AC_MSG_ERROR([Could not determine values for AF_INET* constants])
1119 fi
1120
1121 glib_failed=false
1122 GLIB_CHECK_VALUE(MSG_PEEK, $glib_inet_includes, glib_failed=true)
1123 GLIB_CHECK_VALUE(MSG_OOB, $glib_inet_includes, glib_failed=true)
1124 GLIB_CHECK_VALUE(MSG_DONTROUTE, $glib_inet_includes, glib_failed=true)
1125 if $glib_failed ; then
1126   AC_MSG_ERROR([Could not determine values for MSG_* constants])
1127 fi
1128
1129 AC_CHECK_FUNCS(getprotobyname_r endservent if_nametoindex if_indextoname)
1130
1131 AS_IF([test $glib_native_win32 = yes], [
1132   # <wspiapi.h> in the Windows SDK and in mingw-w64 has wrappers for
1133   # inline workarounds for getaddrinfo, getnameinfo and freeaddrinfo if
1134   # they aren't present at run-time (on Windows 2000).
1135   AC_CHECK_HEADER([wspiapi.h], [WSPIAPI_INCLUDE="#include <wspiapi.h>"])
1136   AC_SUBST(WSPIAPI_INCLUDE)
1137 ], [
1138   # Android does not have C_IN in public headers, we define it wherever necessary
1139   AS_IF([test $glib_native_android != yes], [
1140     AC_MSG_CHECKING([if arpa/nameser_compat.h is needed])
1141     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
1142                                         #include <arpa/nameser.h>],
1143                                        [int qclass = C_IN;])],
1144                       [AC_MSG_RESULT([no])],
1145                       [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
1146                                                            #include <arpa/nameser.h>
1147                                                            #include <arpa/nameser_compat.h>],
1148                                                           [int qclass = C_IN;])],
1149                                          [AC_MSG_RESULT([yes])
1150                                           NAMESER_COMPAT_INCLUDE="#include <arpa/nameser_compat.h>"],
1151                                          [AC_MSG_ERROR([could not compile test program either way])])])])
1152   AC_SUBST(NAMESER_COMPAT_INCLUDE)
1153
1154   # We can't just use AC_CHECK_FUNC/AC_CHECK_LIB here. Bug 586150
1155   NETWORK_LIBS=""
1156   AC_MSG_CHECKING([for res_query])
1157   AC_TRY_LINK([#include <sys/types.h>
1158                #include <netinet/in.h>
1159                #include <arpa/nameser.h>
1160                #include <resolv.h>
1161               ],[
1162                res_query("test", 0, 0, (void *)0, 0);
1163               ],[AC_MSG_RESULT([yes])],
1164               [save_libs="$LIBS"
1165                LIBS="-lresolv $LIBS"
1166                AC_TRY_LINK([#include <sys/types.h>
1167                             #include <netinet/in.h>
1168                             #include <arpa/nameser.h>
1169                             #include <resolv.h>
1170                            ],[
1171                             res_query("test", 0, 0, (void *)0, 0);
1172                            ],[AC_MSG_RESULT([in -lresolv])
1173                               NETWORK_LIBS="-lresolv $NETWORK_LIBS"],
1174                            [LIBS="-lbind $save_libs"
1175                             AC_TRY_LINK([#include <resolv.h>],
1176                                         [res_query("test", 0, 0, (void *)0, 0);],
1177                                         [AC_MSG_RESULT([in -lbind])
1178                                          NETWORK_LIBS="-lbind $NETWORK_LIBS"],
1179                                         [AC_MSG_ERROR(not found)])])
1180                LIBS="$save_libs"])
1181   AC_CHECK_FUNC(socket, :, AC_CHECK_LIB(socket, socket,
1182                                         [NETWORK_LIBS="-lsocket $NETWORK_LIBS"],
1183                                         [AC_MSG_ERROR(Could not find socket())]))
1184   save_libs="$LIBS"
1185   LIBS="$LIBS $NETWORK_LIBS"
1186   AC_MSG_CHECKING([for res_init])
1187   AC_TRY_LINK([#include <sys/types.h>
1188                #include <netinet/in.h>
1189                #include <arpa/nameser.h>
1190                #include <resolv.h>
1191               ],[
1192                res_init();
1193               ],[AC_MSG_RESULT([yes])
1194                  AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if you have the 'res_init' function.])
1195               ],[AC_MSG_RESULT([no])])
1196   LIBS="$save_libs"
1197 ])
1198 AC_SUBST(NETWORK_LIBS)
1199
1200 AC_CHECK_HEADER([linux/netlink.h],
1201                 [AC_DEFINE(HAVE_NETLINK, 1, [We have AF_NETLINK sockets])],,
1202                 [#include <sys/socket.h>])
1203 AM_CONDITIONAL(HAVE_NETLINK, [test "$ac_cv_header_linux_netlink_h" = "yes"])
1204
1205 AC_CHECK_TYPE([struct ip_mreqn], [
1206               AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
1207               [#include <netinet/in.h>])
1208
1209 case $host in
1210   *-*-solaris* )
1211      AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1212      AC_DEFINE(_XOPEN_SOURCE,          2, Needed to get declarations for msg_control and msg_controllen on Solaris)
1213      AC_DEFINE(__EXTENSIONS__,         1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1214      ;;
1215 esac
1216
1217 dnl
1218 dnl if statfs() takes 2 arguments (Posix) or 4 (Solaris)
1219 dnl
1220 AS_IF([test "$ac_cv_func_statfs" = yes], [
1221   AC_MSG_CHECKING([number of arguments to statfs()])
1222   AC_TRY_COMPILE([#include <unistd.h>
1223   #ifdef HAVE_SYS_PARAM_H
1224   #include <sys/param.h>
1225   #endif
1226   #ifdef HAVE_SYS_VFS_H
1227   #include <sys/vfs.h>
1228   #endif
1229   #ifdef HAVE_SYS_MOUNT_H
1230   #include <sys/mount.h>
1231   #endif
1232   #ifdef HAVE_SYS_STATFS_H
1233   #include <sys/statfs.h>
1234   #endif], [struct statfs st;
1235   statfs(NULL, &st);],[
1236     AC_MSG_RESULT([2])
1237     AC_DEFINE(STATFS_ARGS, 2, [Number of arguments to statfs()])],[
1238     AC_TRY_COMPILE([#include <unistd.h>
1239   #ifdef HAVE_SYS_PARAM_H
1240   #include <sys/param.h>
1241   #endif
1242   #ifdef HAVE_SYS_VFS_H
1243   #include <sys/vfs.h>
1244   #endif
1245   #ifdef HAVE_SYS_MOUNT_H
1246   #include <sys/mount.h>
1247   #endif
1248   #ifdef HAVE_SYS_STATFS_H
1249   #include <sys/statfs.h>
1250   #endif], [struct statfs st;
1251   statfs(NULL, &st, sizeof (st), 0);],[
1252       AC_MSG_RESULT([4])
1253       AC_DEFINE(STATFS_ARGS, 4, [Number of arguments to statfs()])],[
1254       AC_MSG_RESULT(unknown)
1255       AC_MSG_ERROR([unable to determine number of arguments to statfs()])])])
1256 ])
1257
1258 #
1259 # Check whether to use an included printf
1260 #
1261
1262 AC_ARG_ENABLE(included-printf,
1263               [AS_HELP_STRING([--enable-included-printf],
1264                               [use included printf [default=auto]])],
1265               enable_included_printf="$enableval")
1266
1267 need_included_printf=no
1268 if test "x$enable_included_printf" = "xyes" ; then
1269   need_included_printf=yes
1270 fi
1271 if test "$ac_cv_func_vsnprintf_c99" != "yes" ; then
1272   need_included_printf=yes
1273 fi
1274 if test "$ac_cv_func_printf_unix98" != "yes" ; then
1275   need_included_printf=yes
1276 fi
1277 if test "x$ac_cv_sizeof_long_long" = "x8" &&
1278    test -z "$glib_cv_long_long_format" ; then
1279   need_included_printf=yes
1280 fi
1281
1282 if test "x$enable_included_printf" = "xno" &&
1283    test "x$need_included_printf" = "xyes" ; then
1284   AC_MSG_ERROR([
1285 *** Your C library's printf doesn't appear to have the features that
1286 *** GLib needs, but you specified --enable-included-printf=no.])
1287 fi
1288
1289 enable_included_printf=$need_included_printf
1290
1291 AM_CONDITIONAL(HAVE_GOOD_PRINTF, test "$enable_included_printf" != "yes")
1292 AS_IF([test "$enable_included_printf" != "yes"], [
1293   AC_DEFINE(HAVE_GOOD_PRINTF,1,[define to use system printf])
1294 ], [
1295   if test -z "$glib_cv_long_long_format" ; then
1296     glib_cv_long_long_format="ll"
1297   fi
1298   AC_DEFINE(HAVE_VASPRINTF,1)
1299 ])
1300
1301 # Checks needed for gnulib vasnprintf
1302 bh_C_SIGNED
1303 jm_AC_TYPE_LONG_LONG
1304 gt_TYPE_LONGDOUBLE
1305 gt_TYPE_WCHAR_T
1306 gt_TYPE_WINT_T
1307 AC_TYPE_SIZE_T
1308 AC_CHECK_TYPES(ptrdiff_t)
1309 jm_AC_TYPE_INTMAX_T
1310 AC_CHECK_FUNCS([snprintf wcslen])
1311 AC_FUNC_SNPRINTF_C99
1312
1313 # Check if bcopy can be used for overlapping copies, if memmove isn't found.
1314 # The check is borrowed from the PERL Configure script.
1315 AS_IF([test "$ac_cv_func_memmove" != "yes"], [
1316   AC_CACHE_CHECK(whether bcopy can handle overlapping copies,
1317     glib_cv_working_bcopy,[AC_TRY_RUN([
1318       int main() {
1319         char buf[128], abc[128], *b;
1320         int len, off, align;
1321         bcopy("abcdefghijklmnopqrstuvwxyz0123456789", abc, 36);
1322         for (align = 7; align >= 0; align--) {
1323           for (len = 36; len; len--) {
1324             b = buf+align; bcopy(abc, b, len);
1325             for (off = 1; off <= len; off++) {
1326               bcopy(b, b+off, len); bcopy(b+off, b, len);
1327                 if (bcmp(b, abc, len)) return(1);
1328             }
1329           }
1330         }
1331         return(0);
1332       }],glib_cv_working_bcopy=yes,glib_cv_working_bcopy=no)])
1333
1334   GLIB_ASSERT_SET(glib_cv_working_bcopy)
1335   if test "$glib_cv_working_bcopy" = "yes"; then
1336     AC_DEFINE(HAVE_WORKING_BCOPY,1,[Have a working bcopy])
1337   fi
1338 ])
1339
1340 # Check if <sys/select.h> needs to be included for fd_set
1341 AC_MSG_CHECKING([for fd_set])
1342 AC_TRY_COMPILE([#include <sys/types.h>],
1343         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
1344 AS_IF([test "$gtk_ok" = "yes"], [
1345     AC_MSG_RESULT([yes, found in sys/types.h])
1346 ], [
1347     AC_EGREP_HEADER(fd_set, sys/select.h, gtk_ok=yes)
1348     if test "$gtk_ok" = "yes"; then
1349         # *** FIXME: give it a different name
1350         AC_DEFINE(HAVE_SYS_SELECT_H,1,[found fd_set in sys/select.h])
1351         AC_MSG_RESULT([yes, found in sys/select.h])
1352     else
1353         AC_DEFINE(NO_FD_SET,1,[didn't find fd_set])
1354         AC_MSG_RESULT(no)
1355     fi
1356 ])
1357
1358 dnl Check for nl_langinfo and CODESET
1359 AC_LANG_SAVE
1360 AC_LANG_C
1361 AC_CACHE_CHECK([for nl_langinfo (CODESET)],glib_cv_langinfo_codeset,[
1362         AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1363                        [char *codeset = nl_langinfo (CODESET);])],
1364                 [glib_cv_langinfo_codeset=yes],
1365                 [glib_cv_langinfo_codeset=no])])
1366 if test x$glib_cv_langinfo_codeset = xyes; then
1367   AC_DEFINE(HAVE_CODESET,1,[Have nl_langinfo (CODESET)])
1368 fi
1369
1370 dnl Check for nl_langinfo and LC_TIME parts that are needed in gdatetime.c
1371 AC_CACHE_CHECK([for nl_langinfo (PM_STR)],glib_cv_langinfo_time,[
1372         AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1373                  [char *str;
1374                  str = nl_langinfo (PM_STR);
1375                  str = nl_langinfo (D_T_FMT);
1376                  str = nl_langinfo (D_FMT);
1377                  str = nl_langinfo (T_FMT);
1378                  str = nl_langinfo (T_FMT_AMPM);
1379                  str = nl_langinfo (MON_1);
1380                  str = nl_langinfo (ABMON_12);
1381                  str = nl_langinfo (DAY_1);
1382                  str = nl_langinfo (ABDAY_7);])],
1383                 [glib_cv_langinfo_time=yes],
1384                 [glib_cv_langinfo_time=no])])
1385 if test x$glib_cv_langinfo_time = xyes; then
1386   AC_DEFINE(HAVE_LANGINFO_TIME,1,[Have nl_langinfo (PM_STR)])
1387 fi
1388
1389 dnl Check for nl_langinfo and _NL_CTYPE_OUTDIGITn_MB
1390 AC_CACHE_CHECK([for nl_langinfo (_NL_CTYPE_OUTDIGITn_MB)], glib_cv_langinfo_outdigit,[
1391         AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1392                 [char *str;
1393                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT0_MB);
1394                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT1_MB);
1395                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT2_MB);
1396                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT3_MB);
1397                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT4_MB);
1398                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT5_MB);
1399                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT6_MB);
1400                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT7_MB);
1401                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT8_MB);
1402                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT9_MB);])],
1403                 [glib_cv_langinfo_outdigit=yes],
1404                 [glib_cv_langinfo_outdigit=no])])
1405 if test x$glib_cv_langinfo_outdigit = xyes; then
1406   AC_DEFINE(HAVE_LANGINFO_OUTDIGIT,1,[Have nl_langinfo (_NL_CTYPE_OUTDIGITn_MB)])
1407 fi
1408 AC_LANG_RESTORE
1409
1410 dnl ****************************************
1411 dnl *** posix_memalign                   ***
1412 dnl ****************************************
1413 AC_MSG_CHECKING(for a compliant posix_memalign() implementation)
1414 AC_CACHE_VAL(glib_cv_compliant_posix_memalign,[
1415     glib_cv_compliant_posix_memalign=0
1416     if test "$ac_cv_func_posix_memalign" = "yes" ; then
1417         AC_TRY_RUN([
1418                 #define _XOPEN_SOURCE 600
1419                 #include <stdlib.h> /* posix_memalign() should be defined here */
1420                 /* some systems break if #include <malloc.h> used */
1421                 static void test_memalign (size_t boundary, size_t size) {
1422                     void *mem = 0;
1423                     if (posix_memalign (&mem, boundary, size) != 0 || !mem)
1424                         exit (1);
1425                     else
1426                       free (mem);
1427                 }
1428                 int main() {
1429                     test_memalign (  128,   128 - 2 * sizeof (void*));
1430                     test_memalign (  256,   256 - 2 * sizeof (void*));
1431                     test_memalign (  512,   512 - 2 * sizeof (void*));
1432                     test_memalign ( 1024,  1024 - 2 * sizeof (void*));
1433                     test_memalign ( 2048,  2048 - 2 * sizeof (void*));
1434                     test_memalign ( 4096,  4096 - 2 * sizeof (void*));
1435                     test_memalign ( 8192,  8192 - 2 * sizeof (void*));
1436                     test_memalign (16384, 16384 - 2 * sizeof (void*));
1437                     test_memalign (32768, 32768 - 2 * sizeof (void*));
1438                     exit (0); /* success */
1439                 }
1440                 ],
1441             [glib_cv_compliant_posix_memalign=1], [], [:])
1442       :
1443     fi
1444     ])
1445 AS_IF([test "$glib_cv_compliant_posix_memalign" = "1"], [
1446     AC_MSG_RESULT(yes)
1447     AC_DEFINE(POSIX_MEMALIGN_WITH_COMPLIANT_ALLOCS, 1, [define if posix_memalign() can allocate any size])
1448 ], [
1449     AC_MSG_RESULT(no)
1450 ])
1451
1452
1453 dnl ****************************************
1454 dnl *** strlcpy/strlcat                  ***
1455 dnl ****************************************
1456 # Check for strlcpy
1457 AC_CACHE_CHECK([for OpenBSD strlcpy/strlcat],glib_cv_have_strlcpy,[
1458 AC_TRY_RUN([#include <stdlib.h>
1459 #include <string.h>
1460 int main() {
1461   char p[10];
1462   (void) strlcpy (p, "hi", 10);
1463   if (strlcat (p, "bye", 0) != 3)
1464     return 1;
1465   return 0;
1466 }], glib_cv_have_strlcpy=yes,
1467     glib_cv_have_strlcpy=no,
1468     glib_cv_have_strlcpy=no)])
1469 if test "$glib_cv_have_strlcpy" = "yes"; then
1470     AC_DEFINE(HAVE_STRLCPY,1,[Have functions strlcpy and strlcat])
1471 fi
1472
1473
1474 dnl **********************
1475 dnl *** va_copy checks ***
1476 dnl **********************
1477 dnl we currently check for all three va_copy possibilities, so we get
1478 dnl all results in config.log for bug reports.
1479 AC_CACHE_CHECK([for an implementation of va_copy()],glib_cv_va_copy,[
1480         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1481 #include <stdlib.h>
1482         void f (int i, ...) {
1483         va_list args1, args2;
1484         va_start (args1, i);
1485         va_copy (args2, args1);
1486         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1487           exit (1);
1488         va_end (args1); va_end (args2);
1489         }
1490         int main() {
1491           f (0, 42);
1492           return 0;
1493         }]])],
1494         [glib_cv_va_copy=yes],
1495         [glib_cv_va_copy=no])
1496 ])
1497 AC_CACHE_CHECK([for an implementation of __va_copy()],glib_cv___va_copy,[
1498         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1499 #include <stdlib.h>
1500         void f (int i, ...) {
1501         va_list args1, args2;
1502         va_start (args1, i);
1503         __va_copy (args2, args1);
1504         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1505           exit (1);
1506         va_end (args1); va_end (args2);
1507         }
1508         int main() {
1509           f (0, 42);
1510           return 0;
1511         }]])],
1512         [glib_cv___va_copy=yes],
1513         [glib_cv___va_copy=no])
1514 ])
1515
1516 if test "x$glib_cv_va_copy" = "xyes"; then
1517   g_va_copy_func=va_copy
1518 else if test "x$glib_cv___va_copy" = "xyes"; then
1519   g_va_copy_func=__va_copy
1520 fi
1521 fi
1522
1523 if test -n "$g_va_copy_func"; then
1524   AC_DEFINE_UNQUOTED(G_VA_COPY,$g_va_copy_func,[A 'va_copy' style function])
1525 fi
1526
1527 AC_CACHE_CHECK([whether va_lists can be copied by value],glib_cv_va_val_copy,[
1528         AC_TRY_RUN([#include <stdarg.h>
1529 #include <stdlib.h>
1530         void f (int i, ...) {
1531         va_list args1, args2;
1532         va_start (args1, i);
1533         args2 = args1;
1534         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1535           exit (1);
1536         va_end (args1); va_end (args2);
1537         }
1538         int main() {
1539           f (0, 42);
1540           return 0;
1541         }],
1542         [glib_cv_va_val_copy=yes],
1543         [glib_cv_va_val_copy=no],
1544         [glib_cv_va_val_copy=yes])
1545 ])
1546
1547 AS_IF([ test "x$glib_cv_va_val_copy" = "xno"], [
1548   AC_DEFINE(G_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
1549 ])
1550
1551 dnl ***********************
1552 dnl *** g_module checks ***
1553 dnl ***********************
1554 G_MODULE_LIBS=
1555 G_MODULE_LIBS_EXTRA=
1556 G_MODULE_PLUGIN_LIBS=
1557 if test x"$glib_native_win32" = xyes; then
1558   dnl No use for this on Win32
1559   G_MODULE_LDFLAGS=
1560 else
1561   export SED
1562   G_MODULE_LDFLAGS=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1563 fi
1564 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
1565 G_MODULE_NEED_USCORE=0
1566 G_MODULE_BROKEN_RTLD_GLOBAL=0
1567 G_MODULE_HAVE_DLERROR=0
1568 dnl *** force native WIN32 shared lib loader
1569 if test -z "$G_MODULE_IMPL"; then
1570   case "$host" in
1571   *-*-mingw*|*-*-cygwin*) G_MODULE_IMPL=G_MODULE_IMPL_WIN32 ;;
1572   esac
1573 fi
1574 dnl *** force native AIX library loader
1575 dnl *** dlopen() filepath must be of the form /path/libname.a(libname.so)
1576 if test -z "$G_MODULE_IMPL"; then
1577   case "$host" in
1578   *-*-aix*) G_MODULE_IMPL=G_MODULE_IMPL_AR ;;
1579   esac
1580 fi
1581 dnl *** dlopen() and dlsym() in system libraries
1582 AS_IF([ test -z "$G_MODULE_IMPL"], [
1583         AC_CHECK_FUNC(dlopen,
1584                       [AC_CHECK_FUNC(dlsym,
1585                                      [G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1586                       [])
1587 ])
1588 dnl *** load_image (BeOS)
1589 AS_IF([test -z "$G_MODULE_IMPL" && test "x$glib_native_beos" = "xyes"], [
1590   AC_CHECK_LIB(root, load_image,
1591       [G_MODULE_LIBS="-lbe -lroot -lglib-2.0 "
1592       G_MODULE_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
1593       G_MODULE_PLUGIN_LIBS="-L\$(top_builddir_full)/gmodule/.libs -lgmodule"
1594       G_MODULE_IMPL=G_MODULE_IMPL_BEOS],
1595       [])
1596 ])
1597 dnl *** NSLinkModule (dyld) in system libraries (Darwin)
1598 AS_IF([ test -z "$G_MODULE_IMPL" ], [
1599         AC_CHECK_FUNC(NSLinkModule,
1600                       [G_MODULE_IMPL=G_MODULE_IMPL_DYLD
1601                        G_MODULE_NEED_USCORE=1],
1602                       [])
1603 ])
1604 dnl *** dlopen() and dlsym() in libdl
1605 AS_IF([ test -z "$G_MODULE_IMPL"], [
1606         AC_CHECK_LIB(dl, dlopen,
1607                      [AC_CHECK_LIB(dl, dlsym,
1608                                    [G_MODULE_LIBS=-ldl
1609                                    G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1610                      [])
1611 ])
1612 dnl *** shl_load() in libdld (HP-UX)
1613 AS_IF([ test -z "$G_MODULE_IMPL"], [
1614         AC_CHECK_LIB(dld, shl_load,
1615                 [G_MODULE_LIBS=-ldld
1616                 G_MODULE_IMPL=G_MODULE_IMPL_DLD],
1617                 [])
1618 ])
1619 dnl *** additional checks for G_MODULE_IMPL_DL
1620 AS_IF([ test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL" ], [
1621         LIBS_orig="$LIBS"
1622         LDFLAGS_orig="$LDFLAGS"
1623         LIBS="$G_MODULE_LIBS $LIBS"
1624         LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
1625 dnl *** check for OSF1/5.0 RTLD_GLOBAL brokenness
1626         echo "void glib_plugin_test(void) { }" > plugin.c
1627         ${SHELL} ./libtool --mode=compile --tag=CC ${CC} ${CFLAGS} \
1628                 ${CPPFLAGS} -c -o plugin.lo plugin.c >/dev/null 2>&1
1629         ${SHELL} ./libtool --mode=link --tag=CC ${CC} ${CFLAGS} \
1630                 ${LDFLAGS} -module -o plugin.la -export-dynamic \
1631                 -shrext ".o" -avoid-version plugin.lo \
1632                 -rpath /dont/care >/dev/null 2>&1
1633         eval `./libtool --config | grep ^objdir`
1634         AC_CACHE_CHECK([for RTLD_GLOBAL brokenness],
1635                 glib_cv_rtldglobal_broken,[
1636                 AC_TRY_RUN([
1637 #include <dlfcn.h>
1638 #ifndef RTLD_GLOBAL
1639 #  define RTLD_GLOBAL 0
1640 #endif
1641 #ifndef RTLD_LAZY
1642 #  define RTLD_LAZY 0
1643 #endif
1644 int glib_plugin_test;
1645 int main () {
1646     void *handle, *global, *local;
1647     global = &glib_plugin_test;
1648     handle = dlopen ("./$objdir/plugin.o", RTLD_GLOBAL | RTLD_LAZY);
1649     if (!handle) return 0;
1650     local = dlsym (handle, "glib_plugin_test");
1651     return global == local;
1652 }                       ],
1653                         [glib_cv_rtldglobal_broken=no],
1654                         [glib_cv_rtldglobal_broken=yes],
1655                         [glib_cv_rtldglobal_broken=no])
1656                 rm -f plugin.c plugin.o plugin.lo plugin.la ${objdir}/plugin.*
1657                 rmdir ${objdir} 2>/dev/null
1658         ])
1659         if test "x$glib_cv_rtldglobal_broken" = "xyes"; then
1660                 G_MODULE_BROKEN_RTLD_GLOBAL=1
1661         else
1662                 G_MODULE_BROKEN_RTLD_GLOBAL=0
1663         fi
1664 dnl *** check whether we need preceeding underscores
1665         AC_CACHE_CHECK([for preceeding underscore in symbols],
1666                 glib_cv_uscore,[
1667                 AC_TRY_RUN([#include <dlfcn.h>
1668                 int glib_underscore_test (void) { return 42; }
1669                 int main() {
1670                   void *f1 = (void*)0, *f2 = (void*)0, *handle;
1671                   handle = dlopen ((void*)0, 0);
1672                   if (handle) {
1673                     f1 = dlsym (handle, "glib_underscore_test");
1674                     f2 = dlsym (handle, "_glib_underscore_test");
1675                   } return (!f2 || f1);
1676                 }],
1677                         [glib_cv_uscore=yes],
1678                         [glib_cv_uscore=no],
1679                         [])
1680                 rm -f plugin.c plugin.$ac_objext plugin.lo
1681         ])
1682         GLIB_ASSERT_SET(glib_cv_uscore)
1683         if test "x$glib_cv_uscore" = "xyes"; then
1684                 G_MODULE_NEED_USCORE=1
1685         else
1686                 G_MODULE_NEED_USCORE=0
1687         fi
1688
1689         LDFLAGS="$LDFLAGS_orig"
1690 dnl *** check for having dlerror()
1691         AC_CHECK_FUNC(dlerror,
1692                 [G_MODULE_HAVE_DLERROR=1],
1693                 [G_MODULE_HAVE_DLERROR=0])
1694         LIBS="$LIBS_orig"
1695 ])
1696 dnl *** done, have we got an implementation?
1697 if test -z "$G_MODULE_IMPL"; then
1698         G_MODULE_IMPL=0
1699         G_MODULE_SUPPORTED=false
1700 else
1701         G_MODULE_SUPPORTED=true
1702 fi
1703
1704 AC_MSG_CHECKING(for the suffix of module shared libraries)
1705 export SED
1706 shrext_cmds=`./libtool --config | grep '^shrext_cmds='`
1707 eval $shrext_cmds
1708 module=yes eval std_shrext=$shrext_cmds
1709 # chop the initial dot
1710 glib_gmodule_suffix=`echo $std_shrext | sed 's/^\.//'`
1711 AC_MSG_RESULT(.$glib_gmodule_suffix)
1712 # any reason it may fail?
1713 if test "x$glib_gmodule_suffix" = x; then
1714         AC_MSG_ERROR(Cannot determine shared library suffix from libtool)
1715 fi
1716
1717 AC_SUBST(G_MODULE_SUPPORTED)
1718 AC_SUBST(G_MODULE_IMPL)
1719 AC_SUBST(G_MODULE_LIBS)
1720 AC_SUBST(G_MODULE_LIBS_EXTRA)
1721 AC_SUBST(G_MODULE_PLUGIN_LIBS)
1722 AC_SUBST(G_MODULE_LDFLAGS)
1723 AC_SUBST(G_MODULE_HAVE_DLERROR)
1724 AC_SUBST(G_MODULE_BROKEN_RTLD_GLOBAL)
1725 AC_SUBST(G_MODULE_NEED_USCORE)
1726 AC_SUBST(GLIB_DEBUG_FLAGS)
1727
1728 dnl **********************
1729 dnl *** g_spawn checks ***
1730 dnl **********************
1731
1732 AC_MSG_CHECKING(for gspawn implementation)
1733 case "$host" in
1734   *-*-mingw*)
1735     GSPAWN=gspawn-win32.lo
1736     ;;
1737   *)
1738     GSPAWN=gspawn.lo
1739     ;;
1740 esac
1741 AC_MSG_RESULT($GSPAWN)
1742 AC_SUBST(GSPAWN)
1743
1744 dnl *************************
1745 dnl *** GIOChannel checks ***
1746 dnl *************************
1747
1748 AC_MSG_CHECKING(for GIOChannel implementation)
1749 case "$host" in
1750   *-*-mingw*)
1751     GIO=giowin32.lo
1752     ;;
1753   *)
1754     GIO=giounix.lo
1755     ;;
1756 esac
1757 AC_MSG_RESULT($GIO)
1758 AC_SUBST(GIO)
1759
1760 dnl *********************************
1761 dnl *** Directory for GIO modules ***
1762 dnl *********************************
1763
1764 AC_ARG_WITH(gio-module-dir,
1765            [AS_HELP_STRING([--with-gio-module-dir=DIR],
1766                            [load gio modules from this directory [LIBDIR/gio/modules]])],
1767            [],
1768            [with_gio_module_dir='${libdir}/gio/modules'])
1769 GIO_MODULE_DIR=$with_gio_module_dir
1770 AC_SUBST(GIO_MODULE_DIR)
1771
1772 dnl **********************************
1773 dnl *** Check for libselinux (GIO) ***
1774 dnl **********************************
1775 AC_ARG_ENABLE(selinux,
1776               AS_HELP_STRING([--disable-selinux],
1777                              [build without selinux support]))
1778 msg_selinux=no
1779 SELINUX_LIBS=
1780 AS_IF([ test "x$enable_selinux" != "xno"], [
1781
1782  AC_CHECK_LIB(selinux, is_selinux_enabled,
1783    [AC_CHECK_HEADERS(selinux/selinux.h,
1784      [AC_CHECK_LIB(selinux, lgetfilecon_raw,
1785        [AC_DEFINE(HAVE_SELINUX, 1, [Define to 1 if libselinux is available])
1786         SELINUX_LIBS="-lselinux"
1787         msg_selinux=yes])
1788      ])
1789    ])
1790 ])
1791 AC_SUBST(SELINUX_LIBS)
1792
1793 dnl *****************************
1794 dnl ** Check for inotify (GIO) **
1795 dnl *****************************
1796 inotify_support=no
1797 AC_CHECK_HEADERS([sys/inotify.h],
1798 [
1799         inotify_support=yes
1800         AC_CHECK_FUNCS(inotify_init1)
1801 ])
1802
1803 AM_CONDITIONAL(HAVE_INOTIFY, [test "$inotify_support" = "yes"])
1804
1805 dnl ****************************
1806 dnl ** Check for kqueue (GIO) **
1807 dnl ****************************
1808 kqueue_support=no
1809 AC_CHECK_HEADERS([sys/event.h],
1810 [
1811         AC_CHECK_FUNCS(kqueue kevent, [kqueue_support=yes])
1812 ])
1813
1814 AM_CONDITIONAL(HAVE_KQUEUE, [test "$kqueue_support" = "yes"])
1815
1816 dnl *********************************
1817 dnl ** Check for Solaris FEN (GIO) **
1818 dnl *********************************
1819 fen_support=no
1820 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
1821 #include <port.h>
1822 #ifndef PORT_SOURCE_FILE
1823 #error "Please upgrade to Nevada 72 or above to suppoert FEN"
1824 #endif
1825 int main() { return 0; } ]])],
1826 [
1827         fen_support=yes
1828 ],)
1829
1830 AM_CONDITIONAL(HAVE_FEN, [test "$fen_support" = "yes"])
1831
1832 dnl ****************************
1833 dnl *** Checks for FAM (GIO) ***
1834 dnl ****************************
1835
1836 should_disable_fam=no
1837
1838 AC_ARG_ENABLE(fam,
1839               AS_HELP_STRING([--disable-fam],
1840                              [don't use fam for file system monitoring]),
1841                          [
1842                                 if test "x$enable_fam" = "xno"; then
1843                                         should_disable_fam=yes
1844                                 fi
1845                          ]
1846                          )
1847 fam_support=no
1848 FAM_LIBS=
1849 if test "x$should_disable_fam" = "xno"; then
1850 AC_CHECK_LIB(fam, FAMOpen,
1851   [AC_CHECK_HEADERS(fam.h,
1852     [AC_DEFINE(HAVE_FAM, [], [Define if we have FAM])
1853      AC_CHECK_LIB(fam, FAMNoExists,
1854                   AC_DEFINE(HAVE_FAM_NO_EXISTS, [], [Define if we have FAMNoExists in fam]))
1855      FAM_LIBS="-lfam"]
1856      fam_support=yes,
1857     AC_MSG_WARN(*** FAM support will not be built (header files not found) ***))],
1858   AC_MSG_WARN(*** FAM support will not be built (FAM library not found) ***))
1859 AC_SUBST(FAM_LIBS)
1860 fi
1861 AM_CONDITIONAL(HAVE_FAM, [test "$fam_support" = "yes"])
1862
1863
1864 dnl *****************************
1865 dnl *** Check for xattr (GIO) ***
1866 dnl *****************************
1867 AC_ARG_ENABLE(xattr,
1868               AS_HELP_STRING([--disable-xattr], [build without xattr support]))
1869 msg_xattr=no
1870 XATTR_LIBS=
1871 AS_IF([ test "x$enable_xattr" != "xno"], [
1872
1873 dnl either glibc or libattr can provide xattr support
1874
1875 dnl for both of them, we check for getxattr being in
1876 dnl the library and a valid xattr header.
1877
1878 dnl try glibc
1879  AC_CHECK_LIB(c, getxattr,
1880    [AC_CHECK_HEADERS(sys/xattr.h,
1881      [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1882       msg_xattr=yes])
1883    ])
1884
1885   AS_IF([ test "x$msg_xattr" != "xyes"], [
1886 dnl   failure. try libattr
1887    AC_CHECK_LIB(attr, getxattr,
1888       [AC_CHECK_HEADERS(attr/xattr.h,
1889        [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1890         XATTR_LIBS="-lattr"
1891         msg_xattr=yes])
1892       ])
1893   ])
1894
1895   AS_IF([ test "x$msg_xattr" = "xyes"], [
1896     AC_MSG_CHECKING([for XATTR_NOFOLLOW])
1897     AC_TRY_COMPILE([
1898       #include <stdio.h>
1899       #ifdef HAVE_SYS_TYPES_H
1900       #include <sys/types.h>
1901       #endif
1902       #ifdef HAVE_SYS_XATTR_H
1903       #include <sys/xattr.h>
1904       #elif HAVE_ATTR_XATTR_H
1905       #include <attr/xattr.h>
1906       #endif
1907     ],
1908     [ssize_t len = getxattr("", "", NULL, 0, 0, XATTR_NOFOLLOW);],
1909     [
1910       AC_DEFINE([HAVE_XATTR_NOFOLLOW], [1], [Define to 1 if xattr API uses XATTR_NOFOLLOW])
1911       AC_MSG_RESULT([yes])
1912     ],
1913     [AC_MSG_RESULT([no])]
1914     )
1915   ])
1916 ])
1917 AC_SUBST(XATTR_LIBS)
1918
1919 dnl ************************
1920 dnl *** check for libelf ***
1921 dnl ************************
1922 AC_ARG_ENABLE(libelf,
1923               AS_HELP_STRING([--disable-libelf], [build without libelf support]))
1924 AS_IF([ test "x$enable_libelf" != "xno"],[
1925 PKG_CHECK_MODULES([LIBELF], [libelf >= 0.8.12], [have_libelf=yes], [have_libelf=maybe])
1926 AS_IF([ test $have_libelf = maybe ], [
1927   glib_save_LIBS=$LIBS
1928   AC_CHECK_LIB([elf], [elf_begin], [:], [have_libelf=no])
1929   AC_CHECK_LIB([elf], [elf_getshdrstrndx], [:], [have_libelf=no])
1930   AC_CHECK_LIB([elf], [elf_getshdrnum], [:], [have_libelf=no])
1931   AC_CHECK_HEADER([libelf.h], [:], [have_libelf=no])
1932   LIBS=$glib_save_LIBS
1933
1934   if test $have_libelf != no; then
1935     LIBELF_LIBS=-lelf
1936     have_libelf=yes
1937   fi
1938 ])
1939 ])
1940
1941 if test x$have_libelf = xyes; then
1942   AC_DEFINE(HAVE_LIBELF, 1, [Define if libelf is available])
1943 fi
1944
1945 dnl ****************************************
1946 dnl *** platform dependent source checks ***
1947 dnl ****************************************
1948
1949 AC_MSG_CHECKING(for platform-dependent source)
1950 case "$host" in
1951   *-*-cygwin*|*-*-mingw*)
1952     PLATFORMDEP=gwin32.lo
1953     ;;
1954   *)
1955     PLATFORMDEP=
1956     ;;
1957 esac
1958 AC_MSG_RESULT($PLATFORMDEP)
1959 AC_SUBST(PLATFORMDEP)
1960
1961 AC_MSG_CHECKING([whether to compile timeloop])
1962 case "$host" in
1963   *-*-cygwin*|*-*-mingw*|*-*-minix)
1964     enable_timeloop=no
1965     ;;
1966   *)
1967     enable_timeloop=yes
1968     ;;
1969 esac
1970 AC_MSG_RESULT($enable_timeloop)
1971 AM_CONDITIONAL(ENABLE_TIMELOOP, test x$enable_timeloop = xyes)
1972
1973 AC_MSG_CHECKING([if building for some Win32 platform])
1974 case "$host" in
1975   *-*-mingw*|*-*-cygwin*)
1976     platform_win32=yes
1977     ;;
1978   *)
1979     platform_win32=no
1980     ;;
1981 esac
1982 AC_MSG_RESULT($platform_win32)
1983 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
1984
1985 dnl ***********************
1986 dnl *** g_thread checks ***
1987 dnl ***********************
1988
1989 AC_ARG_WITH(threads,
1990            [AS_HELP_STRING([--with-threads=@<:@posix/win32@:>@],
1991                            [specify a thread implementation to use])],
1992            [],
1993            [with_threads=yes])
1994
1995 dnl error and warning message
1996 dnl *************************
1997
1998 THREAD_NO_IMPLEMENTATION="No thread implementation found."
1999
2000 FLAG_DOES_NOT_WORK="I can't find the MACRO to enable thread safety on your
2001                 platform (normally it's "_REENTRANT"). I'll not use any flag on
2002                 compilation now, but then your programs might not work.
2003                 Please provide information on how it is done on your system."
2004
2005 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
2006                  "
2007
2008 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
2009                   provide information on your thread implementation."
2010
2011 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
2012                 functions will not be MT-safe during their first call because
2013                 there is no working 'getpwuid_r' on your system."
2014
2015 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
2016                 because there is no 'localtime_r' on your system."
2017
2018 AIX_COMPILE_INFO="AIX's C compiler needs to be called by a different name, when
2019                 linking threaded applications. As GLib cannot do that
2020                 automatically, you will get an linkg error everytime you are
2021                 not using the right compiler. In that case you have to relink
2022                 with the right compiler. Ususally just '_r' is appended
2023                 to the compiler name."
2024
2025 dnl determination of thread implementation
2026 dnl ***************************************
2027
2028 AC_MSG_CHECKING(for thread implementation)
2029
2030 have_threads=no
2031 AS_IF([ test "x$with_threads" = xyes || test "x$with_threads" = xposix], [
2032         # -D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE is for DG/UX
2033         # -U_OSF_SOURCE is for Digital UNIX 4.0d
2034         GTHREAD_COMPILE_IMPL_DEFINES="-D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE -U_OSF_SOURCE"
2035         glib_save_CPPFLAGS="$CPPFLAGS"
2036         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2037         AS_IF([ test "x$have_threads" = xno], [
2038                 AC_TRY_COMPILE([#include <pthread.h>],
2039                         [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
2040                         have_threads=posix)
2041         ])
2042         # Tru64Unix requires -pthread to find pthread.h. See #103020
2043         CPPFLAGS="$CPPFLAGS -pthread"
2044         if test "x$have_threads" = xno; then
2045         AC_TRY_COMPILE([#include <pthread.h>],
2046                        [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
2047                        have_threads=posix)
2048         fi
2049         CPPFLAGS="$glib_save_CPPFLAGS"
2050 ])
2051 if test "x$with_threads" = xyes || test "x$with_threads" = xwin32; then
2052         case $host in
2053                 *-*-mingw*)
2054                 have_threads=win32
2055                 ;;
2056         esac
2057 fi
2058
2059 if test "x$have_threads" = xno; then
2060         AC_MSG_RESULT(none available)
2061         AC_MSG_ERROR($THREAD_NO_IMPLEMENTATION)
2062 else
2063         AC_MSG_RESULT($have_threads)
2064 fi
2065
2066
2067 dnl determination of G_THREAD_CFLAGS
2068 dnl ********************************
2069
2070 G_THREAD_LIBS=
2071 G_THREAD_LIBS_EXTRA=
2072 G_THREAD_CFLAGS=
2073
2074 dnl
2075 dnl Test program for basic POSIX threads functionality
2076 dnl
2077 m4_define([glib_thread_test],[
2078 #include <pthread.h>
2079 int check_me = 0;
2080 void* func(void* data) {check_me = 42; return &check_me;}
2081 int main()
2082  { pthread_t t;
2083    void *ret;
2084    pthread_create (&t, $1, func, 0);
2085    pthread_join (t, &ret);
2086    return (check_me != 42 || ret != &check_me);
2087 }])
2088
2089 AS_IF([ test x"$have_threads" = xposix], [
2090   # First we test for posix, whether -pthread or -pthreads do the trick as
2091   # both CPPFLAG and LIBS.
2092   # One of them does for most gcc versions and some other platforms/compilers
2093   # too and could be considered as the canonical way to go.
2094   case $host in
2095     *-*-cygwin*|*-*-darwin*)
2096        # skip cygwin and darwin -pthread or -pthreads test
2097        ;;
2098     *-solaris*)
2099       # These compiler/linker flags work with both Sun Studio and gcc
2100       # Sun Studio expands -mt to -D_REENTRANT and -lthread
2101       # gcc expands -pthreads to -D_REENTRANT -D_PTHREADS -lpthread
2102       G_THREAD_CFLAGS="-D_REENTRANT -D_PTHREADS"
2103       G_THREAD_LIBS="-lpthread -lthread"
2104       ;;
2105     *)
2106       for flag in pthread pthreads mt; do
2107         glib_save_CFLAGS="$CFLAGS"
2108         CFLAGS="$CFLAGS -$flag"
2109         AC_TRY_RUN(glib_thread_test(0),
2110                    glib_flag_works=yes,
2111                    glib_flag_works=no,
2112                    [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test(0))],
2113                                    glib_flag_works=yes,
2114                                    glib_flag_works=no)])
2115         CFLAGS="$glib_save_CFLAGS"
2116         if test $glib_flag_works = yes ; then
2117            G_THREAD_CFLAGS=-$flag
2118         G_THREAD_LIBS=-$flag
2119         break;
2120         fi
2121       done
2122        ;;
2123   esac
2124 ])
2125
2126 AS_IF([ test x"$G_THREAD_CFLAGS" = x], [
2127
2128   # The canonical -pthread[s] does not work. Try something different.
2129
2130   case $host in
2131         *-aix*)
2132                 if test x"$GCC" = xyes; then
2133                         # GCC 3.0 and above needs -pthread.
2134                         # Should be coverd by the case above.
2135                         # GCC 2.x and below needs -mthreads
2136                         G_THREAD_CFLAGS="-mthreads"
2137                         G_THREAD_LIBS=$G_THREAD_CFLAGS
2138                 else
2139                         # We are probably using the aix compiler. Normaly a
2140                         # program would have to be compiled with the _r variant
2141                         # of the corresponding compiler, but we as GLib cannot
2142                         # do that: but the good news is that for compiling the
2143                         # only difference is the added -D_THREAD_SAFE compile
2144                         # option. This is according to the "C for AIX User's
2145                         # Guide".
2146                         G_THREAD_CFLAGS="-D_THREAD_SAFE"
2147                 fi
2148                 ;;
2149         *-dg-dgux*)  # DG/UX
2150                 G_THREAD_CFLAGS="-D_REENTRANT -D_POSIX4A_DRAFT10_SOURCE"
2151                 ;;
2152         *-sysv5uw7*) # UnixWare 7
2153                 # We are not using gcc with -pthread. Catched above.
2154                 G_THREAD_CFLAGS="-Kthread"
2155                 G_THREAD_LIBS=$G_THREAD_CFLAGS
2156                 ;;
2157         *-mingw*)
2158                 # No flag needed when using MSVCRT.DLL
2159                 G_THREAD_CFLAGS=""
2160                 ;;
2161         *)
2162                 G_THREAD_CFLAGS="-D_REENTRANT" # good default guess otherwise
2163                 ;;
2164   esac
2165 ])
2166
2167 # if we are not finding the localtime_r function, then we probably are
2168 # not using the proper multithread flag
2169
2170 glib_save_CPPFLAGS="$CPPFLAGS"
2171 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2172
2173 # First we test, whether localtime_r is declared in time.h
2174 # directly. Then we test whether a macro localtime_r exists, in
2175 # which case localtime_r in the test program is replaced and thus
2176 # if we still find localtime_r in the output, it is not defined as
2177 # a macro.
2178
2179 AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>], ,
2180   [AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>
2181                                                            localtime_r(a,b)],
2182                    AC_MSG_WARN($FLAG_DOES_NOT_WORK))])
2183
2184 CPPFLAGS="$glib_save_CPPFLAGS"
2185
2186 AC_MSG_CHECKING(thread related cflags)
2187 AC_MSG_RESULT($G_THREAD_CFLAGS)
2188 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2189
2190 dnl determination of G_THREAD_LIBS
2191 dnl ******************************
2192
2193 AS_IF([test x$have_threads = xposix], [
2194           glib_save_CPPFLAGS="$CPPFLAGS"
2195           CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2196           AS_IF([ test x"$G_THREAD_LIBS" = x ], [
2197             case $host in
2198               *-aix*)
2199                 # We are not using gcc (would have set G_THREAD_LIBS) and thus
2200                 # probably using the aix compiler.
2201                 AC_MSG_WARN($AIX_COMPILE_INFO)
2202                 ;;
2203               *)
2204                 G_THREAD_LIBS=error
2205                 glib_save_LIBS="$LIBS"
2206                 for thread_lib in "" pthread pthread32 pthreads thread; do
2207                         if test x"$thread_lib" = x; then
2208                                 add_thread_lib=""
2209                                 IN=""
2210                         else
2211                                 add_thread_lib="-l$thread_lib"
2212                                 IN=" in -l$thread_lib"
2213                         fi
2214                         if test x"$have_threads" = xposix; then
2215                                 defattr=0
2216                         else
2217                                 defattr=pthread_attr_default
2218                         fi
2219
2220                         LIBS="$add_thread_lib $glib_save_LIBS"
2221
2222                         AC_MSG_CHECKING(for pthread_create/pthread_join$IN)
2223                         AC_TRY_RUN(glib_thread_test($defattr),
2224                                    glib_result=yes,
2225                                    glib_result=no,
2226                                    [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test($defattr))],
2227                                                    glib_result=yes,
2228                                                    glib_result=no)])
2229                         AC_MSG_RESULT($glib_result)
2230
2231                         if test "$glib_result" = "yes" ; then
2232                           G_THREAD_LIBS="$add_thread_lib"
2233                           break
2234                         fi
2235                 done
2236                 if test "x$G_THREAD_LIBS" = xerror; then
2237                   AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2238                 fi
2239                 LIBS="$glib_save_LIBS"
2240                 ;;
2241             esac
2242           ])
2243
2244           g_threads_impl="POSIX"
2245           AC_DEFINE([THREADS_POSIX], [1], [Use pthreads])
2246           AC_SUBST(GTHREAD_COMPILE_IMPL_DEFINES)
2247           CPPFLAGS="$glib_save_CPPFLAGS"
2248 ], [test x$have_threads = xwin32], [
2249            AC_DEFINE([THREADS_WIN32], [1], [Use w32 threads])
2250            g_threads_impl="WIN32"
2251 ], [
2252            AC_DEFINE([THREADS_NONE], [1], [Use no threads])
2253            g_threads_impl="NONE"
2254            G_THREAD_LIBS=error
2255 ])
2256 AM_CONDITIONAL(THREADS_POSIX, [test "$g_threads_impl" = "POSIX"])
2257 AM_CONDITIONAL(THREADS_WIN32, [test "$g_threads_impl" = "WIN32"])
2258 AM_CONDITIONAL(THREADS_NONE, [test "$g_threads_impl" = "NONE"])
2259
2260 if test "x$G_THREAD_LIBS" = xerror; then
2261         AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2262 fi
2263
2264 case $host in
2265   *-*-beos*)
2266     G_THREAD_LIBS="-lbe -lroot -lglib-2.0 "
2267     G_THREAD_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
2268     ;;
2269   *)
2270     ;;
2271 esac
2272
2273 AC_MSG_CHECKING(thread related libraries)
2274 AC_MSG_RESULT($G_THREAD_LIBS)
2275
2276 dnl check for mt safe function variants and some posix functions
2277 dnl ************************************************************
2278
2279 glib_save_LIBS="$LIBS"
2280 # we are not doing the following for now, as this might require glib
2281 # to always be linked with the thread libs on some platforms.
2282 # LIBS="$LIBS $G_THREAD_LIBS"
2283 AC_CHECK_FUNCS(localtime_r gmtime_r)
2284 AS_IF([ test "$ac_cv_header_pwd_h" = "yes"], [
2285         AC_CACHE_CHECK([for posix getpwuid_r],
2286                 ac_cv_func_posix_getpwuid_r,
2287                 [AC_TRY_RUN([
2288 #include <errno.h>
2289 #include <pwd.h>
2290 int main () {
2291     char buffer[10000];
2292     struct passwd pwd, *pwptr = &pwd;
2293     int error;
2294     errno = 0;
2295     error = getpwuid_r (0, &pwd, buffer,
2296                         sizeof (buffer), &pwptr);
2297    return (error < 0 && errno == ENOSYS)
2298            || error == ENOSYS;
2299 }                               ],
2300                         [ac_cv_func_posix_getpwuid_r=yes],
2301                         [ac_cv_func_posix_getpwuid_r=no])])
2302         GLIB_ASSERT_SET(ac_cv_func_posix_getpwuid_r)
2303         if test "$ac_cv_func_posix_getpwuid_r" = yes; then
2304                 AC_DEFINE(HAVE_POSIX_GETPWUID_R,1,
2305                         [Have POSIX function getpwuid_r])
2306         else
2307                 AC_CACHE_CHECK([for nonposix getpwuid_r],
2308                         ac_cv_func_nonposix_getpwuid_r,
2309                         [AC_TRY_LINK([#include <pwd.h>],
2310                                 [char buffer[10000];
2311                                 struct passwd pwd;
2312                                 getpwuid_r (0, &pwd, buffer,
2313                                                 sizeof (buffer));],
2314                                 [ac_cv_func_nonposix_getpwuid_r=yes],
2315                                 [ac_cv_func_nonposix_getpwuid_r=no])])
2316                 GLIB_ASSERT_SET(ac_cv_func_nonposix_getpwuid_r)
2317                 if test "$ac_cv_func_nonposix_getpwuid_r" = yes; then
2318                         AC_DEFINE(HAVE_NONPOSIX_GETPWUID_R,1,
2319                                 [Have non-POSIX function getpwuid_r])
2320                 fi
2321         fi
2322 ])
2323 AS_IF([ test "$ac_cv_header_grp_h" = "yes"], [
2324         AC_CACHE_CHECK([for posix getgrgid_r],
2325                 ac_cv_func_posix_getgrgid_r,
2326                 [AC_TRY_RUN([
2327 #include <errno.h>
2328 #include <grp.h>
2329 int main () {
2330     char buffer[10000];
2331     struct group grp, *grpptr = &grp;
2332     int error;
2333     errno = 0;
2334     error = getgrgid_r (0, &grp, buffer,
2335                         sizeof (buffer), &grpptr);
2336    return (error < 0 && errno == ENOSYS)
2337            || error == ENOSYS;
2338 }                              ],
2339                        [ac_cv_func_posix_getgrgid_r=yes],
2340                        [ac_cv_func_posix_getgrgid_r=no])])
2341         GLIB_ASSERT_SET(ac_cv_func_posix_getgrgid_r)
2342         AS_IF([ test "$ac_cv_func_posix_getgrgid_r" = yes ], [
2343                 AC_DEFINE(HAVE_POSIX_GETGRGID_R,1,
2344                         [Have POSIX function getgrgid_r])
2345         ], [
2346                 AC_CACHE_CHECK([for nonposix getgrgid_r],
2347                         ac_cv_func_nonposix_getgrgid_r,
2348                         [AC_TRY_LINK([#include <grp.h>],
2349                                 [char buffer[10000];
2350                                 struct group grp;
2351                                 getgrgid_r (0, &grp, buffer,
2352                                 sizeof (buffer));],
2353                         [ac_cv_func_nonposix_getgrgid_r=yes],
2354                         [ac_cv_func_nonposix_getgrgid_r=no])])
2355                 GLIB_ASSERT_SET(ac_cv_func_nonposix_getgrgid_r)
2356                 if test "$ac_cv_func_nonposix_getgrgid_r" = yes; then
2357                         AC_DEFINE(HAVE_NONPOSIX_GETGRGID_R,1,
2358                                 [Have non-POSIX function getgrgid_r])
2359                 fi
2360         ])
2361 ])
2362 LIBS="$G_THREAD_LIBS $LIBS"
2363 AS_IF([ test x"$have_threads" = xposix], [
2364         glib_save_CPPFLAGS="$CPPFLAGS"
2365         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2366         # This is not AC_CHECK_FUNC to also work with function
2367         # name mangling in header files.
2368         AC_MSG_CHECKING(for pthread_attr_setstacksize)
2369         AC_LINK_IFELSE(
2370             [AC_LANG_PROGRAM(
2371                 [#include <pthread.h>],
2372                 [pthread_attr_t t; pthread_attr_setstacksize(&t,0)])],
2373             [AC_MSG_RESULT(yes)
2374              AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE,1,
2375                 [Have function pthread_attr_setstacksize])],
2376             [AC_MSG_RESULT(no)])
2377         AC_MSG_CHECKING(for pthread_condattr_setclock)
2378         AC_LINK_IFELSE(
2379             [AC_LANG_PROGRAM(
2380                 [#include <pthread.h>],
2381                 [pthread_condattr_t a; pthread_condattr_setclock(&a,0)])],
2382             [AC_MSG_RESULT(yes)
2383              AC_DEFINE(HAVE_PTHREAD_CONDATTR_SETCLOCK,1,
2384                 [Have function pthread_condattr_setclock])],
2385             [AC_MSG_RESULT(no)])
2386         AC_MSG_CHECKING(for pthread_cond_timedwait_monotonic)
2387         AC_LINK_IFELSE(
2388             [AC_LANG_PROGRAM(
2389                 [#include <pthread.h>],
2390                 [pthread_cond_timedwait_monotonic(NULL, NULL, NULL)])],
2391             [AC_MSG_RESULT(yes)
2392              AC_DEFINE(HAVE_PTHREAD_COND_TIMEDWAIT_MONOTONIC,1,
2393                 [Have function pthread_cond_timedwait_monotonic])],
2394             [AC_MSG_RESULT(no)])
2395         AC_MSG_CHECKING(for pthread_cond_timedwait_monotonic_np)
2396         AC_LINK_IFELSE(
2397             [AC_LANG_PROGRAM(
2398                 [#include <pthread.h>],
2399                 [pthread_cond_timedwait_monotonic_np(NULL, NULL, NULL)])],
2400             [AC_MSG_RESULT(yes)
2401              AC_DEFINE(HAVE_PTHREAD_COND_TIMEDWAIT_MONOTONIC_NP,1,
2402                 [Have function pthread_cond_timedwait_monotonic_np])],
2403             [AC_MSG_RESULT(no)])
2404         CPPFLAGS="$glib_save_CPPFLAGS"
2405 ])
2406
2407 LIBS="$glib_save_LIBS"
2408
2409 # now spit out all the warnings.
2410 if test "$ac_cv_func_posix_getpwuid_r" != "yes" &&
2411    test "$ac_cv_func_nonposix_getpwuid_r" != "yes"; then
2412         AC_MSG_WARN($FUNC_NO_GETPWUID_R)
2413 fi
2414 if test "$ac_cv_func_localtime_r" != "yes"; then
2415         AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
2416 fi
2417
2418 #
2419 # Hack to deal with:
2420 #
2421 #  a) GCC < 3.3 for Linux doesn't include -lpthread when
2422 #     building shared libraries with linux.
2423 #  b) FreeBSD doesn't do this either.
2424 #
2425 case $host in
2426   *android*)
2427     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
2428     ;;
2429   *-*-freebsd*|*-*-linux*)
2430     G_THREAD_LIBS_FOR_GTHREAD="`echo $G_THREAD_LIBS | sed s/-pthread/-lpthread/`"
2431     ;;
2432   *-*-openbsd*)
2433     LDFLAGS="$LDFLAGS -pthread"
2434     ;;
2435   *)
2436     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
2437     ;;
2438 esac
2439
2440 AC_SUBST(G_THREAD_CFLAGS)
2441 AC_SUBST(G_THREAD_LIBS)
2442 AC_SUBST(G_THREAD_LIBS_FOR_GTHREAD)
2443 AC_SUBST(G_THREAD_LIBS_EXTRA)
2444
2445 AC_CHECK_FUNCS(clock_gettime, [], [
2446   AC_CHECK_LIB(rt, clock_gettime, [
2447     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
2448     G_THREAD_LIBS="$G_THREAD_LIBS -lrt"
2449     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS_FOR_GTHREAD -lrt"
2450   ])
2451 ])
2452
2453
2454 dnl ************************
2455 dnl *** g_atomic_* tests ***
2456 dnl ************************
2457
2458 dnl We need to decide at configure time if GLib will use real atomic
2459 dnl operations ("lock free") or emulated ones with a mutex.  This is
2460 dnl because we must put this information in glibconfig.h so we know if
2461 dnl it is safe or not to inline using compiler intrinsics directly from
2462 dnl the header.
2463 dnl
2464 dnl We also publish the information via G_ATOMIC_LOCK_FREE in case the
2465 dnl user is interested in knowing if they can use the atomic ops across
2466 dnl processes.
2467 dnl
2468 dnl We can currently support the atomic ops natively when building GLib
2469 dnl with recent versions of GCC or MSVC.  MSVC doesn't run ./configure,
2470 dnl so we skip that case here and define G_ATOMIC_LOCK_FREE exactly when
2471 dnl we are using GCC (and not mingw*).
2472 dnl
2473 dnl Note that the atomic ops are only available with GCC on x86 when
2474 dnl using -march=i486 or higher.  If we detect that the atomic ops are
2475 dnl not available but would be available given the right flags, we want
2476 dnl to abort and advise the user to fix their CFLAGS.  It's better to do
2477 dnl that then to silently fall back on emulated atomic ops just because
2478 dnl the user had the wrong build environment.
2479
2480 dnl We may add other compilers here in the future...
2481
2482 AC_CACHE_CHECK([for lock-free atomic intrinsics], glib_cv_g_atomic_lock_free, [
2483   case $host in
2484     *-*-mingw*)
2485       glib_cv_g_atomic_lock_free=yes
2486       ;;
2487     *)
2488       AC_TRY_COMPILE([],
2489                      [volatile int atomic = 2;\
2490                       __sync_bool_compare_and_swap (&atomic, 2, 3);],
2491                      [glib_cv_g_atomic_lock_free=yes],
2492                      [glib_cv_g_atomic_lock_free=no])
2493       if test "$glib_cv_g_atomic_lock_free" = "no"; then
2494         SAVE_CFLAGS="${CFLAGS}"
2495         CFLAGS="-march=i486"
2496         AC_TRY_COMPILE([],
2497                        [volatile int atomic = 2;\
2498                         __sync_bool_compare_and_swap (&atomic, 2, 3);],
2499                        [AC_MSG_ERROR([GLib must be build with -march=i486 or later.])],
2500                        [])
2501         CFLAGS="${SAVE_CFLAGS}"
2502       fi
2503       ;;
2504   esac])
2505
2506
2507 case $host in
2508   *-*-mingw*)
2509     ;;
2510   *)
2511     # Some compilers support atomic operations but do not define
2512     # __GCC_HAVE_SYNC_COMPARE_AND_SWAP_4, like clang
2513     if test x"$glib_cv_g_atomic_lock_free" = xyes; then
2514       AC_TRY_COMPILE([],
2515                      [__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4;],
2516                      [],
2517                      [AC_DEFINE(__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4, 1, [ compiler supports atomic operations])])
2518     fi
2519     ;;
2520  esac
2521
2522 dnl We need a more robust approach here...
2523 case $host_cpu in
2524   i?86|x86_64|s390|s390x|arm*|crisv32*|etrax*)
2525     glib_memory_barrier_needed=no
2526     ;;
2527   sparc*|alpha*|powerpc*|ia64)
2528     glib_memory_barrier_needed=yes
2529     ;;
2530   *)
2531     glib_memory_barrier_needed=yes
2532     ;;
2533 esac
2534
2535 dnl ************************
2536 dnl ** Check for futex(2) **
2537 dnl ************************
2538 AC_CACHE_CHECK(for futex(2) system call,
2539     glib_cv_futex,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2540 #include <linux/futex.h>
2541 #include <sys/syscall.h>
2542 #include <unistd.h>
2543 ],[
2544 int
2545 main (void)
2546 {
2547   /* it is not like this actually runs or anything... */
2548   syscall (__NR_futex, NULL, FUTEX_WAKE, FUTEX_WAIT);
2549   return 0;
2550 }
2551 ])],glib_cv_futex=yes,glib_cv_futex=no))
2552 if test x"$glib_cv_futex" = xyes; then
2553   AC_DEFINE(HAVE_FUTEX, 1, [we have the futex(2) system call])
2554 fi
2555
2556 AC_CACHE_CHECK(for eventfd(2) system call,
2557     glib_cv_eventfd,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2558 #include <sys/eventfd.h>
2559 #include <unistd.h>
2560 ],[
2561 int
2562 main (void)
2563 {
2564   eventfd (0, EFD_CLOEXEC);
2565   return 0;
2566 }
2567 ])],glib_cv_eventfd=yes,glib_cv_eventfd=no))
2568 if test x"$glib_cv_eventfd" = x"yes"; then
2569   AC_DEFINE(HAVE_EVENTFD, 1, [we have the eventfd(2) system call])
2570 fi
2571 AM_CONDITIONAL(HAVE_EVENTFD, [test "$glib_cv_eventfd" = "yes"])
2572
2573 dnl ****************************************
2574 dnl *** GLib POLL* compatibility defines ***
2575 dnl ****************************************
2576
2577 glib_poll_includes=["
2578 #include <sys/types.h>
2579 #include <sys/poll.h>
2580 "]
2581
2582 AS_IF([ test $ac_cv_header_sys_types_h = yes &&
2583    test $ac_cv_header_sys_poll_h = yes ], [
2584   glib_failed=false
2585   GLIB_CHECK_VALUE(POLLIN, $glib_poll_includes, glib_failed=true)
2586   GLIB_CHECK_VALUE(POLLOUT, $glib_poll_includes, glib_failed=true)
2587   GLIB_CHECK_VALUE(POLLPRI, $glib_poll_includes, glib_failed=true)
2588   GLIB_CHECK_VALUE(POLLERR, $glib_poll_includes, glib_failed=true)
2589   GLIB_CHECK_VALUE(POLLHUP, $glib_poll_includes, glib_failed=true)
2590   GLIB_CHECK_VALUE(POLLNVAL, $glib_poll_includes, glib_failed=true)
2591   if $glib_failed ; then
2592     AC_MSG_ERROR([Could not determine values for POLL* constants])
2593   fi
2594 ], [
2595   glib_cv_value_POLLIN=1
2596   glib_cv_value_POLLOUT=4
2597   glib_cv_value_POLLPRI=2
2598   glib_cv_value_POLLERR=8
2599   glib_cv_value_POLLHUP=16
2600   glib_cv_value_POLLNVAL=32
2601 ])
2602
2603 AC_MSG_CHECKING([for broken poll])
2604 AC_RUN_IFELSE([AC_LANG_SOURCE([[
2605         #include <stdlib.h>
2606         #include <fcntl.h>
2607         #include <poll.h>
2608         #ifdef HAVE_SYS_POLL_H
2609         #include <sys/poll.h>
2610         #endif
2611         int main(void) {
2612           struct pollfd fds[1];
2613           int fd;
2614           fd = open("/dev/null", 1);
2615           fds[0].fd = fd;
2616           fds[0].events = POLLIN;
2617           fds[0].revents = 0;
2618           if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
2619                 exit(1);  /* Does not work for devices -- fail */
2620           }
2621           exit(0);
2622         }]])],
2623   [broken_poll=no],
2624   [broken_poll=yes
2625    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
2626   [broken_poll="no (cross compiling)"])
2627 AC_MSG_RESULT($broken_poll)
2628
2629 dnl *********************
2630 dnl *** GRegex checks ***
2631 dnl *********************
2632
2633 PCRE_REQUIRED_VERSION=8.13
2634
2635 # Check if we should use the internal or the system-supplied pcre
2636 AC_ARG_WITH(pcre,
2637             [AS_HELP_STRING([--with-pcre=@<:@internal/system@:>@],
2638                             [whether to use system PCRE [default=internal]])])
2639
2640 AM_CONDITIONAL(USE_SYSTEM_PCRE, [test "x$with_pcre" = xsystem])
2641
2642 AS_IF([ test "x$with_pcre" = xsystem], [
2643   PKG_CHECK_MODULES(PCRE,
2644                     libpcre >= $PCRE_REQUIRED_VERSION)
2645   AC_CACHE_CHECK([for Unicode support in PCRE],glib_cv_pcre_has_unicode,[
2646                   glib_save_CFLAGS="$CFLAGS"
2647                   glib_save_LIBS="$LIBS"
2648                   CFLAGS="$CFLAGS $PCRE_CFLAGS" LIBS="$PCRE_LIBS"
2649                   AC_TRY_RUN([#include <pcre.h>
2650                               int main () {
2651                                 int support;
2652                                 pcre_config (PCRE_CONFIG_UTF8, &support);
2653                                 if (!support)
2654                                   return 1;
2655                                 pcre_config (PCRE_CONFIG_UNICODE_PROPERTIES, &support);
2656                                 if (!support)
2657                                   return 1;
2658                                 return 0;
2659                               }],
2660                   glib_cv_pcre_has_unicode=yes,
2661                   glib_cv_pcre_has_unicode=no,
2662                   glib_cv_pcre_has_unicode=yes)
2663                   CFLAGS="$glib_save_CFLAGS"
2664                   LIBS="$glib_save_LIBS"
2665       ])
2666   if test "$glib_cv_pcre_has_unicode" = "no"; then
2667     AC_MSG_ERROR([*** The system-supplied PCRE does not support Unicode properties or UTF-8.])
2668   fi
2669   AC_SUBST(PCRE_CFLAGS)
2670   AC_SUBST(PCRE_LIBS)
2671   AC_DEFINE(USE_SYSTEM_PCRE, [], [using the system-supplied PCRE library])
2672   PCRE_REQUIRES=libpcre
2673   AC_SUBST(PCRE_REQUIRES)
2674 ], [
2675   # If using gcc 4 pass -Wno-pointer-sign when compiling the internal PCRE
2676   AS_IF([ test x"$GCC" = xyes], [
2677     AC_MSG_CHECKING([whether compiler understands -Wno-pointer-sign])
2678     save_CFLAGS="$CFLAGS"
2679     CFLAGS="$CFLAGS -Wno-pointer-sign"
2680     AC_TRY_COMPILE([],[],[PCRE_WARN_CFLAGS="$PCRE_WARN_CFLAGS -Wno-pointer-sign"
2681                           AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
2682     CFLAGS="$save_CFLAGS"
2683   ])
2684 ])
2685 AC_SUBST(PCRE_WARN_CFLAGS)
2686
2687 dnl **********************
2688 dnl *** Win32 API libs ***
2689 dnl **********************
2690
2691 case $host in
2692   *-*-cygwin*)
2693         G_LIBS_EXTRA="-luser32 -lkernel32"
2694     ;;
2695   *-*-mingw*)
2696         G_LIBS_EXTRA="-lws2_32 -lole32 -lwinmm -lshlwapi"
2697     ;;
2698   *)
2699         G_LIBS_EXTRA=""
2700     ;;
2701 esac
2702 AC_SUBST(G_LIBS_EXTRA)
2703
2704 dnl If the system doesn't define EILSEQ, we should define EILSEQ ourselves
2705 dnl since we need it for g_iconv()
2706
2707 AC_MSG_CHECKING([for EILSEQ])
2708 AC_TRY_COMPILE([
2709 #include <errno.h>
2710 ],
2711 [
2712 int error = EILSEQ;
2713 ], have_eilseq=yes, have_eilseq=no);
2714 AC_MSG_RESULT($have_eilseq)
2715
2716 dnl ******************************************************************
2717 dnl *** If we are cross-compiling, look for glib-genmarshal and    ***
2718 dnl *** glib-compile-schemas in PATH                               ***
2719 dnl ******************************************************************
2720
2721 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
2722
2723 AS_IF([ test $cross_compiling = yes ], [
2724   AC_PATH_PROG(GLIB_GENMARSHAL, glib-genmarshal, no)
2725   if test x$GLIB_GENMARSHAL = xno; then
2726     AC_MSG_ERROR(Could not find a glib-genmarshal in your PATH)
2727   fi
2728
2729   AC_PATH_PROG(GLIB_COMPILE_SCHEMAS, glib-compile-schemas, no)
2730   if test x$GLIB_COMPILE_SCHEMAS = xno; then
2731     AC_MSG_ERROR(Could not find a glib-compile-schemas in your PATH)
2732   fi
2733
2734   AC_PATH_PROG(GLIB_COMPILE_RESOURCES, glib-compile-resources, no)
2735   if test x$GLIB_COMPILE_RESOURCES = xno; then
2736     AC_MSG_ERROR(Could not find a glib-compile-resources in your PATH)
2737   fi
2738 ])
2739
2740 dnl **************************
2741 dnl *** Checks for gtk-doc ***
2742 dnl **************************
2743 # gtkdocize greps for ^GTK_DOC_CHECK and parses it, so you need to have
2744 # it on it's own line.
2745 m4_ifdef([GTK_DOC_CHECK], [
2746 GTK_DOC_CHECK([1.15], [--flavour no-tmpl])
2747 ],[
2748 AM_CONDITIONAL([ENABLE_GTK_DOC],[false])
2749 ])
2750
2751 AC_ARG_ENABLE(man,
2752               [AS_HELP_STRING([--enable-man],
2753                               [generate man pages [default=auto]])],,
2754               enable_man=maybe)
2755
2756 AS_IF([test "$enable_man" != no], [
2757   AC_PATH_PROG([XSLTPROC], [xsltproc])
2758   AS_IF([test -z "$XSLTPROC"], [
2759     AS_IF([test "$enable_man" = yes], [
2760       AC_MSG_ERROR([xsltproc is required for --enable-man])
2761     ])
2762     enable_man=no
2763   ])
2764 ])
2765
2766 AS_IF([ test "$enable_man" != no ], [
2767   dnl check for DocBook DTD in the local catalog
2768   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
2769      [DocBook XML DTD V4.1.2], [have_docbook_dtd=yes], [have_docbook_dtd=no])
2770   AS_IF([test "$have_docbook_dtd" != yes], [
2771     AS_IF([test "$enable_man" = yes ], [
2772       AC_MSG_ERROR([DocBook DTD is required for --enable-man])
2773     ])
2774     enable_man=no
2775   ])
2776 ])
2777
2778 AS_IF([test "$enable_man" != no], [
2779   dnl check for DocBook XSL stylesheets in the local catalog
2780   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
2781      [DocBook XSL Stylesheets], [have_docbook_style=yes],[have_docbook_style=no])
2782   AS_IF([ test "$have_docbook_dtd" != yes ], [
2783     AS_IF([ test "$enable_man" = yes ], [
2784       AC_MSG_ERROR([DocBook XSL Stylesheets are required for --enable-man])
2785     ])
2786     enable_man=no
2787   ])
2788 ])
2789
2790 AM_CONDITIONAL(ENABLE_MAN, test "$enable_man" != no)
2791
2792 AC_MSG_CHECKING([whether to generate man pages])
2793 AS_IF([ test "$enable_man" != no ], [
2794   AC_MSG_RESULT([yes])
2795 ], [
2796   AC_MSG_RESULT([no])
2797 ])
2798
2799 dnl
2800 dnl Tracing
2801 dnl
2802
2803 AC_ARG_ENABLE([dtrace],
2804              [AS_HELP_STRING([--enable-dtrace],
2805                               [include tracing support for dtrace])])
2806 have_dtrace=no
2807 AC_MSG_CHECKING([whether to include dtrace tracing support])
2808 AS_IF([ test "x$enable_dtrace" != xno], [
2809   if test x$glib_have_carbon = xyes; then
2810     AC_MSG_RESULT([no (not yet compatible with MacOS dtrace)])
2811   else
2812     AC_MSG_RESULT([yes])
2813     AC_CHECK_PROGS(DTRACE, dtrace)
2814     if test -z "$DTRACE"; then
2815       if test "x$enable_dtrace" = xyes; then
2816         AC_MSG_ERROR([dtrace not found])
2817       fi
2818     else
2819       AC_CHECK_HEADER([sys/sdt.h],have_dtrace=yes,
2820                       [if test "x$enable_dtrace" = xyes; then
2821                         AC_MSG_ERROR([dtrace support needs sys/sdt.h header])
2822                        fi])
2823     fi
2824   fi
2825 ], [
2826   AC_MSG_RESULT([no])
2827 ])
2828 if test "x$have_dtrace" = xyes; then
2829   AC_DEFINE([HAVE_DTRACE], [1], [Define to 1 if using dtrace probes.])
2830 fi
2831 AM_CONDITIONAL([ENABLE_DTRACE], [test x$have_dtrace = xyes ])
2832
2833 AC_MSG_CHECKING([whether to include systemtap tracing support])
2834 AC_ARG_ENABLE([systemtap],
2835              [AS_HELP_STRING([--enable-systemtap],
2836                               [include tracing support for systemtap])])
2837 have_systemtap=no
2838 if test "x$enable_systemtap" != xno -a "x$have_dtrace" = xyes; then
2839   have_systemtap=yes
2840 fi
2841 AC_MSG_RESULT(${have_systemtap})
2842
2843 AM_CONDITIONAL([ENABLE_SYSTEMTAP], [test x$have_systemtap = xyes])
2844
2845 AC_ARG_WITH([tapset-install-dir],
2846             AS_HELP_STRING([--with-tapset-install-dir=DIR],
2847                             [path where systemtap tapsets are installed [DATADIR/systemtap/tapset]]),
2848             [if test "x${withval}" = x; then
2849                ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"
2850              else
2851                ABS_TAPSET_DIR="${withval}"
2852               fi],
2853             [ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"])
2854 AC_SUBST(ABS_TAPSET_DIR)
2855
2856 dnl ************************************
2857 dnl *** Enable lcov coverage reports ***
2858 dnl ************************************
2859
2860 AC_ARG_ENABLE(gcov,
2861   AS_HELP_STRING([--enable-gcov],
2862                  [enable coverage testing with gcov]),
2863   [use_gcov=$enableval], [use_gcov=no])
2864
2865 AS_IF([ test "x$use_gcov" = "xyes"], [
2866   dnl we need gcc:
2867   if test "$GCC" != "yes"; then
2868     AC_MSG_ERROR([GCC is required for --enable-gcov])
2869   fi
2870
2871   dnl Check if ccache is being used
2872   AC_CHECK_PROG(SHTOOL, shtool, shtool)
2873   case `$SHTOOL path $CC` in
2874     *ccache*[)] gcc_ccache=yes;;
2875     *[)] gcc_ccache=no;;
2876   esac
2877
2878   if test "$gcc_ccache" = "yes" && (test -z "$CCACHE_DISABLE" || test "$CCACHE_DISABLE" != "1"); then
2879     AC_MSG_ERROR([ccache must be disabled when --enable-gcov option is used. You can disable ccache by setting environment variable CCACHE_DISABLE=1.])
2880   fi
2881
2882   ltp_version_list="1.6 1.7 1.8 1.9 1.10"
2883   AC_CHECK_PROG(LTP, lcov, lcov)
2884   AC_CHECK_PROG(LTP_GENHTML, genhtml, genhtml)
2885
2886   AS_IF([ test "$LTP" ], [
2887     AC_CACHE_CHECK([for ltp version], glib_cv_ltp_version, [
2888       glib_cv_ltp_version=invalid
2889       ltp_version=`$LTP -v 2>/dev/null | $SED -e 's/^.* //'`
2890       for ltp_check_version in $ltp_version_list; do
2891         if test "$ltp_version" = "$ltp_check_version"; then
2892           glib_cv_ltp_version="$ltp_check_version (ok)"
2893         fi
2894       done
2895     ])
2896   ], [
2897     ltp_msg="To enable code coverage reporting you must have one of the following LTP versions installed: $ltp_version_list"
2898     AC_MSG_ERROR([$ltp_msg])
2899   ])
2900
2901   case $glib_cv_ltp_version in
2902     ""|invalid[)]
2903       ltp_msg="You must have one of the following versions of LTP: $ltp_version_list (found: $ltp_version)."
2904       AC_MSG_ERROR([$ltp_msg])
2905       LTP="exit 0;"
2906       ;;
2907   esac
2908
2909   if test -z "$LTP_GENHTML"; then
2910     AC_MSG_ERROR([Could not find genhtml from the LTP package])
2911   fi
2912
2913   dnl Remove all optimization flags from CFLAGS
2914   changequote({,})
2915   CFLAGS=`echo "$CFLAGS" | $SED -e 's/-O[0-9]*//g'`
2916   changequote([,])
2917
2918   dnl Add the special gcc flags
2919   CFLAGS="$CFLAGS -O0 -fprofile-arcs -ftest-coverage"
2920   LDFLAGS="$LDFLAGS -lgcov"
2921 ])
2922
2923 dnl ******************************
2924 dnl *** output the whole stuff ***
2925 dnl ******************************
2926
2927 dnl this section will only be run if config.status is invoked with no
2928 dnl arguments, or with "glib/glibconfig.h" as an argument.
2929 AC_CONFIG_COMMANDS([glib/glibconfig.h],
2930 [
2931         outfile=glib/glibconfig.h-tmp
2932         cat > $outfile <<\_______EOF
2933 /* glibconfig.h
2934  *
2935  * This is a generated file.  Please modify 'configure.ac'
2936  */
2937
2938 #ifndef __GLIBCONFIG_H__
2939 #define __GLIBCONFIG_H__
2940
2941 #include <glib/gmacros.h>
2942
2943 _______EOF
2944
2945         if test x$glib_limits_h = xyes; then
2946           echo '#include <limits.h>' >> $outfile
2947         fi
2948         if test x$glib_float_h = xyes; then
2949           echo '#include <float.h>' >> $outfile
2950         fi
2951         if test x$glib_values_h = xyes; then
2952           echo '#include <values.h>' >> $outfile
2953         fi
2954         if test "$glib_header_alloca_h" = "yes"; then
2955           echo '#define GLIB_HAVE_ALLOCA_H' >> $outfile
2956         fi
2957         if test x$glib_sys_poll_h = xyes; then
2958           echo '#define GLIB_HAVE_SYS_POLL_H' >> $outfile
2959         fi
2960         if test x$glib_included_printf != xyes; then
2961           echo "
2962 /* Specifies that GLib's g_print*() functions wrap the
2963  * system printf functions.  This is useful to know, for example,
2964  * when using glibc's register_printf_function().
2965  */" >> $outfile
2966           echo '#define GLIB_USING_SYSTEM_PRINTF' >> $outfile
2967         fi
2968
2969         cat >> $outfile <<_______EOF
2970
2971 G_BEGIN_DECLS
2972
2973 #define G_MINFLOAT      $glib_mf
2974 #define G_MAXFLOAT      $glib_Mf
2975 #define G_MINDOUBLE     $glib_md
2976 #define G_MAXDOUBLE     $glib_Md
2977 #define G_MINSHORT      $glib_ms
2978 #define G_MAXSHORT      $glib_Ms
2979 #define G_MAXUSHORT     $glib_Mus
2980 #define G_MININT        $glib_mi
2981 #define G_MAXINT        $glib_Mi
2982 #define G_MAXUINT       $glib_Mui
2983 #define G_MINLONG       $glib_ml
2984 #define G_MAXLONG       $glib_Ml
2985 #define G_MAXULONG      $glib_Mul
2986
2987 _______EOF
2988
2989
2990         ### this should always be true in a modern C/C++ compiler
2991         cat >>$outfile <<_______EOF
2992 typedef signed char gint8;
2993 typedef unsigned char guint8;
2994 _______EOF
2995
2996
2997         if test -n "$gint16"; then
2998           cat >>$outfile <<_______EOF
2999 typedef signed $gint16 gint16;
3000 typedef unsigned $gint16 guint16;
3001 #define G_GINT16_MODIFIER $gint16_modifier
3002 #define G_GINT16_FORMAT $gint16_format
3003 #define G_GUINT16_FORMAT $guint16_format
3004 _______EOF
3005         fi
3006
3007
3008         if test -n "$gint32"; then
3009           cat >>$outfile <<_______EOF
3010 typedef signed $gint32 gint32;
3011 typedef unsigned $gint32 guint32;
3012 #define G_GINT32_MODIFIER $gint32_modifier
3013 #define G_GINT32_FORMAT $gint32_format
3014 #define G_GUINT32_FORMAT $guint32_format
3015 _______EOF
3016         fi
3017
3018         cat >>$outfile <<_______EOF
3019 #define G_HAVE_GINT64 1          /* deprecated, always true */
3020
3021 ${glib_extension}typedef signed $gint64 gint64;
3022 ${glib_extension}typedef unsigned $gint64 guint64;
3023
3024 #define G_GINT64_CONSTANT(val)  $gint64_constant
3025 #define G_GUINT64_CONSTANT(val) $guint64_constant
3026 _______EOF
3027
3028         if test x$gint64_format != x ; then
3029           cat >>$outfile <<_______EOF
3030 #define G_GINT64_MODIFIER $gint64_modifier
3031 #define G_GINT64_FORMAT $gint64_format
3032 #define G_GUINT64_FORMAT $guint64_format
3033 _______EOF
3034         else
3035           cat >>$outfile <<_______EOF
3036 #undef G_GINT64_MODIFIER
3037 #undef G_GINT64_FORMAT
3038 #undef G_GUINT64_FORMAT
3039 _______EOF
3040         fi
3041
3042         cat >>$outfile <<_______EOF
3043
3044 #define GLIB_SIZEOF_VOID_P $glib_void_p
3045 #define GLIB_SIZEOF_LONG   $glib_long
3046 #define GLIB_SIZEOF_SIZE_T $glib_size_t
3047 #define GLIB_SIZEOF_SSIZE_T $glib_ssize_t
3048
3049 _______EOF
3050
3051         cat >>$outfile <<_______EOF
3052 typedef signed $glib_ssize_type_define gssize;
3053 typedef unsigned $glib_size_type_define gsize;
3054 #define G_GSIZE_MODIFIER $gsize_modifier
3055 #define G_GSSIZE_MODIFIER $gssize_modifier
3056 #define G_GSIZE_FORMAT $gsize_format
3057 #define G_GSSIZE_FORMAT $gssize_format
3058
3059 #define G_MAXSIZE       G_MAXU$glib_msize_type
3060 #define G_MINSSIZE      G_MIN$glib_mssize_type
3061 #define G_MAXSSIZE      G_MAX$glib_mssize_type
3062
3063 typedef gint64 goffset;
3064 #define G_MINOFFSET     G_MININT64
3065 #define G_MAXOFFSET     G_MAXINT64
3066
3067 #define G_GOFFSET_MODIFIER      G_GINT64_MODIFIER
3068 #define G_GOFFSET_FORMAT        G_GINT64_FORMAT
3069 #define G_GOFFSET_CONSTANT(val) G_GINT64_CONSTANT(val)
3070
3071 _______EOF
3072
3073         if test -z "$glib_unknown_void_p"; then
3074           cat >>$outfile <<_______EOF
3075
3076 #define GPOINTER_TO_INT(p)      ((gint)  ${glib_gpi_cast} (p))
3077 #define GPOINTER_TO_UINT(p)     ((guint) ${glib_gpui_cast} (p))
3078
3079 #define GINT_TO_POINTER(i)      ((gpointer) ${glib_gpi_cast} (i))
3080 #define GUINT_TO_POINTER(u)     ((gpointer) ${glib_gpui_cast} (u))
3081
3082 typedef signed $glib_intptr_type_define gintptr;
3083 typedef unsigned $glib_intptr_type_define guintptr;
3084
3085 #define G_GINTPTR_MODIFIER      $gintptr_modifier
3086 #define G_GINTPTR_FORMAT        $gintptr_format
3087 #define G_GUINTPTR_FORMAT       $guintptr_format
3088 _______EOF
3089         else
3090           echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
3091         fi
3092
3093
3094
3095         cat >>$outfile <<_______EOF
3096 $glib_atexit
3097 $glib_memmove
3098 $glib_defines
3099 $glib_os
3100 $glib_static_compilation
3101
3102 $glib_vacopy
3103
3104 #ifdef  __cplusplus
3105 #define G_HAVE_INLINE   1
3106 #else   /* !__cplusplus */
3107 $glib_inline
3108 #endif  /* !__cplusplus */
3109
3110 #ifdef  __cplusplus
3111 #define G_CAN_INLINE    1
3112 _______EOF
3113
3114         if test x$g_can_inline = xyes ; then
3115                 cat >>$outfile <<_______EOF
3116 #else   /* !__cplusplus */
3117 #define G_CAN_INLINE    1
3118 _______EOF
3119         fi
3120
3121         cat >>$outfile <<_______EOF
3122 #endif
3123
3124 _______EOF
3125
3126         if test x$g_have_iso_c_varargs = xyes ; then
3127                 cat >>$outfile <<_______EOF
3128 #ifndef __cplusplus
3129 # define G_HAVE_ISO_VARARGS 1
3130 #endif
3131 _______EOF
3132         fi
3133         if test x$g_have_iso_cxx_varargs = xyes ; then
3134                 cat >>$outfile <<_______EOF
3135 #ifdef __cplusplus
3136 # define G_HAVE_ISO_VARARGS 1
3137 #endif
3138 _______EOF
3139         fi
3140         if test x$g_have_gnuc_varargs = xyes ; then
3141                 cat >>$outfile <<_______EOF
3142
3143 /* gcc-2.95.x supports both gnu style and ISO varargs, but if -ansi
3144  * is passed ISO vararg support is turned off, and there is no work
3145  * around to turn it on, so we unconditionally turn it off.
3146  */
3147 #if __GNUC__ == 2 && __GNUC_MINOR__ == 95
3148 #  undef G_HAVE_ISO_VARARGS
3149 #endif
3150
3151 #define G_HAVE_GNUC_VARARGS 1
3152 _______EOF
3153         fi
3154
3155         case x$g_stack_grows in
3156         xyes) echo "#define G_HAVE_GROWING_STACK 1" >>$outfile ;;
3157         *)    echo "#define G_HAVE_GROWING_STACK 0" >>$outfile ;;
3158         esac
3159
3160
3161         echo >>$outfile
3162         if test x$g_have_eilseq = xno; then
3163                 cat >>$outfile <<_______EOF
3164 #ifndef EILSEQ
3165 /* On some systems, like SunOS and NetBSD, EILSEQ is not defined.
3166  * The correspondence between this and the corresponding definition
3167  * in libiconv is essential.
3168  */
3169 #  define EILSEQ ENOENT
3170 #endif
3171 _______EOF
3172
3173         fi
3174
3175         if test x$g_have_gnuc_visibility = xyes; then
3176                 cat >>$outfile <<_______EOF
3177 #define G_HAVE_GNUC_VISIBILITY 1
3178 _______EOF
3179         fi
3180                 cat >>$outfile <<_______EOF
3181 #if defined(__SUNPRO_C) && (__SUNPRO_C >= 0x590)
3182 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
3183 #elif defined(__SUNPRO_C) && (__SUNPRO_C >= 0x550)
3184 #define G_GNUC_INTERNAL __hidden
3185 #elif defined (__GNUC__) && defined (G_HAVE_GNUC_VISIBILITY)
3186 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
3187 #else
3188 #define G_GNUC_INTERNAL
3189 #endif
3190 _______EOF
3191
3192         echo >>$outfile
3193         cat >>$outfile <<_______EOF
3194 #define G_THREADS_ENABLED
3195 #define G_THREADS_IMPL_$g_threads_impl_def
3196 _______EOF
3197
3198         if test x"$g_memory_barrier_needed" != xno; then
3199           echo >>$outfile
3200           echo "#define G_ATOMIC_OP_MEMORY_BARRIER_NEEDED 1" >>$outfile
3201         fi
3202         if test x"$g_atomic_lock_free" = xyes; then
3203           echo >>$outfile
3204           echo "#define G_ATOMIC_LOCK_FREE" >>$outfile
3205         fi
3206         echo >>$outfile
3207         g_bit_sizes="16 32 64"
3208         for bits in $g_bit_sizes; do
3209           cat >>$outfile <<_______EOF
3210 #define GINT${bits}_TO_${g_bs_native}(val)      ((gint${bits}) (val))
3211 #define GUINT${bits}_TO_${g_bs_native}(val)     ((guint${bits}) (val))
3212 #define GINT${bits}_TO_${g_bs_alien}(val)       ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
3213 #define GUINT${bits}_TO_${g_bs_alien}(val)      (GUINT${bits}_SWAP_LE_BE (val))
3214 _______EOF
3215         done
3216
3217         cat >>$outfile <<_______EOF
3218 #define GLONG_TO_LE(val)        ((glong) GINT${glongbits}_TO_LE (val))
3219 #define GULONG_TO_LE(val)       ((gulong) GUINT${glongbits}_TO_LE (val))
3220 #define GLONG_TO_BE(val)        ((glong) GINT${glongbits}_TO_BE (val))
3221 #define GULONG_TO_BE(val)       ((gulong) GUINT${glongbits}_TO_BE (val))
3222 #define GINT_TO_LE(val)         ((gint) GINT${gintbits}_TO_LE (val))
3223 #define GUINT_TO_LE(val)        ((guint) GUINT${gintbits}_TO_LE (val))
3224 #define GINT_TO_BE(val)         ((gint) GINT${gintbits}_TO_BE (val))
3225 #define GUINT_TO_BE(val)        ((guint) GUINT${gintbits}_TO_BE (val))
3226 #define GSIZE_TO_LE(val)        ((gsize) GUINT${gsizebits}_TO_LE (val))
3227 #define GSSIZE_TO_LE(val)       ((gssize) GINT${gssizebits}_TO_LE (val))
3228 #define GSIZE_TO_BE(val)        ((gsize) GUINT${gsizebits}_TO_BE (val))
3229 #define GSSIZE_TO_BE(val)       ((gssize) GINT${gssizebits}_TO_BE (val))
3230 #define G_BYTE_ORDER $g_byte_order
3231
3232 #define GLIB_SYSDEF_POLLIN =$g_pollin
3233 #define GLIB_SYSDEF_POLLOUT =$g_pollout
3234 #define GLIB_SYSDEF_POLLPRI =$g_pollpri
3235 #define GLIB_SYSDEF_POLLHUP =$g_pollhup
3236 #define GLIB_SYSDEF_POLLERR =$g_pollerr
3237 #define GLIB_SYSDEF_POLLNVAL =$g_pollnval
3238
3239 #define G_MODULE_SUFFIX "$g_module_suffix"
3240
3241 typedef $g_pid_type GPid;
3242
3243 #define GLIB_SYSDEF_AF_UNIX $g_af_unix
3244 #define GLIB_SYSDEF_AF_INET $g_af_inet
3245 #define GLIB_SYSDEF_AF_INET6 $g_af_inet6
3246
3247 #define GLIB_SYSDEF_MSG_OOB $g_msg_oob
3248 #define GLIB_SYSDEF_MSG_PEEK $g_msg_peek
3249 #define GLIB_SYSDEF_MSG_DONTROUTE $g_msg_dontroute
3250
3251 G_END_DECLS
3252
3253 #endif /* __GLIBCONFIG_H__ */
3254 _______EOF
3255
3256
3257         if cmp -s $outfile glib/glibconfig.h; then
3258           AC_MSG_NOTICE([glib/glibconfig.h is unchanged])
3259           rm -f $outfile
3260         else
3261           mv $outfile glib/glibconfig.h
3262         fi
3263 ],[
3264
3265 # Note that if two cases are the same, case goes with the first one.
3266 # Note also that this is inside an AC_OUTPUT_COMMAND.  We do not depend
3267 # on variable expansion in case labels.  Look at the generated config.status
3268 # for a hint.
3269
3270 if test "x${ac_cv_working_alloca_h+set}" = xset ; then
3271   glib_header_alloca_h="$ac_cv_working_alloca_h"
3272 else
3273   glib_header_alloca_h="$ac_cv_header_alloca_h"
3274 fi
3275
3276 case xyes in
3277 x$ac_cv_header_float_h)
3278   glib_float_h=yes
3279   glib_mf=FLT_MIN glib_Mf=FLT_MAX
3280   glib_md=DBL_MIN glib_Md=DBL_MAX
3281   ;;
3282 x$ac_cv_header_values_h)
3283   glib_values_h=yes
3284   glib_mf=MINFLOAT  glib_Mf=MAXFLOAT
3285   glib_md=MINDOUBLE glib_Md=MAXDOUBLE
3286   ;;
3287 esac
3288
3289 case xyes in
3290 x$ac_cv_header_limits_h)
3291   glib_limits_h=yes
3292   glib_ms=SHRT_MIN glib_Ms=SHRT_MAX glib_Mus=USHRT_MAX
3293   glib_mi=INT_MIN  glib_Mi=INT_MAX  glib_Mui=UINT_MAX
3294   glib_ml=LONG_MIN glib_Ml=LONG_MAX glib_Mul=ULONG_MAX
3295   ;;
3296 x$ac_cv_header_values_h)
3297   glib_values_h=yes
3298   glib_ms=MINSHORT glib_Ms=MAXSHORT glib_Mus="(((gushort)G_MAXSHORT)*2+1)"
3299   glib_mi=MININT   glib_Mi=MAXINT   glib_Mui="(((guint)G_MAXINT)*2+1)"
3300   glib_ml=MINLONG  glib_Ml=MAXLONG  glib_Mul="(((gulong)G_MAXLONG)*2+1)"
3301   ;;
3302 esac
3303
3304 if test x$ac_cv_header_sys_poll_h = xyes ; then
3305   glib_sys_poll_h=yes
3306 fi
3307
3308 if test x$enable_included_printf = xyes ; then
3309   glib_included_printf=yes
3310 fi
3311
3312 case 2 in
3313 $ac_cv_sizeof_short)
3314   gint16=short
3315   gint16_modifier='"h"'
3316   gint16_format='"hi"'
3317   guint16_format='"hu"'
3318   ;;
3319 $ac_cv_sizeof_int)
3320   gint16=int
3321   gint16_modifier='""'
3322   gint16_format='"i"'
3323   guint16_format='"u"'
3324   ;;
3325 esac
3326 case 4 in
3327 $ac_cv_sizeof_short)
3328   gint32=short
3329   gint32_modifier='"h"'
3330   gint32_format='"hi"'
3331   guint32_format='"hu"'
3332   ;;
3333 $ac_cv_sizeof_int)
3334   gint32=int
3335   gint32_modifier='""'
3336   gint32_format='"i"'
3337   guint32_format='"u"'
3338   ;;
3339 $ac_cv_sizeof_long)
3340   gint32=long
3341   gint32_modifier='"l"'
3342   gint32_format='"li"'
3343   guint32_format='"lu"'
3344   ;;
3345 esac
3346 case 8 in
3347 $ac_cv_sizeof_int)
3348   gint64=int
3349   gint64_modifier='""'
3350   gint64_format='"i"'
3351   guint64_format='"u"'
3352   glib_extension=
3353   gint64_constant='(val)'
3354   guint64_constant='(val)'
3355   ;;
3356 $ac_cv_sizeof_long)
3357   gint64=long
3358   gint64_modifier='"l"'
3359   gint64_format='"li"'
3360   guint64_format='"lu"'
3361   glib_extension=
3362   gint64_constant='(val##L)'
3363   guint64_constant='(val##UL)'
3364   ;;
3365 $ac_cv_sizeof_long_long)
3366   gint64='long long'
3367   if test -n "$glib_cv_long_long_format"; then
3368     gint64_modifier='"'$glib_cv_long_long_format'"'
3369     gint64_format='"'$glib_cv_long_long_format'i"'
3370     guint64_format='"'$glib_cv_long_long_format'u"'
3371   fi
3372   glib_extension='G_GNUC_EXTENSION '
3373   gint64_constant='(G_GNUC_EXTENSION (val##LL))'
3374   guint64_constant='(G_GNUC_EXTENSION (val##ULL))'
3375   ;;
3376 $ac_cv_sizeof___int64)
3377   gint64='__int64'
3378   if test -n "$glib_cv_long_long_format"; then
3379     gint64_modifier='"'$glib_cv_long_long_format'"'
3380     gint64_format='"'$glib_cv_long_long_format'i"'
3381     guint64_format='"'$glib_cv_long_long_format'u"'
3382   fi
3383   glib_extension=
3384   gint64_constant='(val##i64)'
3385   guint64_constant='(val##ui64)'
3386   ;;
3387 esac
3388 glib_size_t=$ac_cv_sizeof_size_t
3389 glib_ssize_t=$ac_cv_sizeof_ssize_t
3390 glib_size_type_define="$glib_size_type"
3391 glib_ssize_type_define="$glib_ssize_type"
3392 glib_void_p=$ac_cv_sizeof_void_p
3393 glib_long=$ac_cv_sizeof_long
3394
3395 case "$glib_size_type" in
3396 short)
3397   gsize_modifier='"h"'
3398   gsize_format='"hu"'
3399   glib_msize_type='SHRT'
3400   ;;
3401 int)
3402   gsize_modifier='""'
3403   gsize_format='"u"'
3404   glib_msize_type='INT'
3405   ;;
3406 long)
3407   gsize_modifier='"l"'
3408   gsize_format='"lu"'
3409   glib_msize_type='LONG'
3410   ;;
3411 "long long"|__int64)
3412   gsize_modifier='"I64"'
3413   gsize_format='"I64u"'
3414   glib_msize_type='INT64'
3415   ;;
3416 esac
3417
3418 case "$glib_ssize_type" in
3419 short)
3420   gssize_modifier='"h"'
3421   gssize_format='"hi"'
3422   glib_mssize_type='SHRT'
3423   ;;
3424 int)
3425   gssize_modifier='""'
3426   gssize_format='"i"'
3427   glib_mssize_type='INT'
3428   ;;
3429 long)
3430   gssize_modifier='"l"'
3431   gssize_format='"li"'
3432   glib_mssize_type='LONG'
3433   ;;
3434 "long long"|__int64)
3435   gssize_modifier='"I64"'
3436   gssize_format='"I64i"'
3437   glib_mssize_type='INT64'
3438   ;;
3439 esac
3440
3441 gintbits=`expr $ac_cv_sizeof_int \* 8`
3442 glongbits=`expr $ac_cv_sizeof_long \* 8`
3443 gsizebits=`expr $ac_cv_sizeof_size_t \* 8`
3444 gssizebits=`expr $ac_cv_sizeof_ssize_t \* 8`
3445
3446 case $ac_cv_sizeof_void_p in
3447 $ac_cv_sizeof_int)
3448   glib_intptr_type_define=int
3449   gintptr_modifier='""'
3450   gintptr_format='"i"'
3451   guintptr_format='"u"'
3452   glib_gpi_cast='(gint)'
3453   glib_gpui_cast='(guint)'
3454   ;;
3455 $ac_cv_sizeof_long)
3456   glib_intptr_type_define=long
3457   gintptr_modifier='"l"'
3458   gintptr_format='"li"'
3459   guintptr_format='"lu"'
3460   glib_gpi_cast='(glong)'
3461   glib_gpui_cast='(gulong)'
3462   ;;
3463 $ac_cv_sizeof_long_long)
3464   glib_intptr_type_define='long long'
3465   gintptr_modifier='"I64"'
3466   gintptr_format='"I64i"'
3467   guintptr_format='"I64u"'
3468   glib_gpi_cast='(gint64)'
3469   glib_gpui_cast='(guint64)'
3470   ;;
3471 $ac_cv_sizeof___int64)
3472   glib_intptr_type_define=__int64
3473   gintptr_modifier='"I64"'
3474   gintptr_format='"I64i"'
3475   guintptr_format='"I64u"'
3476   glib_gpi_cast='(gint64)'
3477   glib_gpui_cast='(guint64)'
3478   ;;
3479 *)
3480   glib_unknown_void_p=yes
3481   ;;
3482 esac
3483
3484
3485 case xyes in
3486 x$ac_cv_func_atexit)
3487   glib_atexit="
3488 #ifdef NeXT /* @#%@! NeXTStep */
3489 # define g_ATEXIT(proc) (!atexit (proc))
3490 #else
3491 # define g_ATEXIT(proc) (atexit (proc))
3492 #endif"
3493   ;;
3494 x$ac_cv_func_on_exit)
3495   glib_atexit="
3496 #define g_ATEXIT(proc)  (on_exit ((void (*)(int, void*))(proc), NULL))"
3497   ;;
3498 esac
3499
3500 case xyes in
3501 x$ac_cv_func_memmove)
3502   glib_memmove='
3503 #define g_memmove(dest,src,len) G_STMT_START { memmove ((dest), (src), (len)); } G_STMT_END'
3504   ;;
3505 x$glib_cv_working_bcopy)
3506   glib_memmove="
3507 /* memmove isn't available, but bcopy can copy overlapping memory regions */
3508 #define g_memmove(d,s,n) G_STMT_START { bcopy ((s), (d), (n)); } G_STMT_END"
3509   ;;
3510 *)
3511   glib_memmove="
3512 /* memmove isn't found and bcopy can't copy overlapping memory regions,
3513  * so we have to roll our own copy routine. */
3514 void g_memmove (void* dest, const void * src, unsigned long len);"
3515   ;;
3516 esac
3517
3518 glib_defines="
3519 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
3520 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
3521 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
3522 "
3523
3524 case xyes in
3525 x$glib_cv_va_copy)      glib_vacopy='#define G_VA_COPY  va_copy' ;;
3526 x$glib_cv___va_copy)    glib_vacopy='#define G_VA_COPY  __va_copy' ;;
3527 *)                      glib_vacopy=''
3528 esac
3529
3530 if test x$glib_cv_va_val_copy = xno; then
3531   glib_vacopy="\$glib_vacopy
3532 #define G_VA_COPY_AS_ARRAY 1"
3533 fi
3534
3535 if test x$glib_cv_hasinline = xyes; then
3536     glib_inline='#define G_HAVE_INLINE 1'
3537 fi
3538 if test x$glib_cv_has__inline = xyes; then
3539     glib_inline="\$glib_inline
3540 #define G_HAVE___INLINE 1"
3541 fi
3542 if test x$glib_cv_has__inline__ = xyes; then
3543     glib_inline="\$glib_inline
3544 #define G_HAVE___INLINE__ 1"
3545 fi
3546
3547 g_have_gnuc_varargs=$g_have_gnuc_varargs
3548 g_have_iso_c_varargs=$g_have_iso_c_varargs
3549 g_have_iso_cxx_varargs=$g_have_iso_cxx_varargs
3550
3551 g_can_inline=$g_can_inline
3552 g_have_gnuc_visibility=$g_have_gnuc_visibility
3553 g_have_sunstudio_visibility=$g_have_sunstudio_visibility
3554
3555 if test x$ac_cv_c_bigendian = xyes; then
3556   g_byte_order=G_BIG_ENDIAN
3557   g_bs_native=BE
3558   g_bs_alien=LE
3559 else
3560   g_byte_order=G_LITTLE_ENDIAN
3561   g_bs_native=LE
3562   g_bs_alien=BE
3563 fi
3564
3565 g_pollin=$glib_cv_value_POLLIN
3566 g_pollout=$glib_cv_value_POLLOUT
3567 g_pollpri=$glib_cv_value_POLLPRI
3568 g_pollhup=$glib_cv_value_POLLHUP
3569 g_pollerr=$glib_cv_value_POLLERR
3570 g_pollnval=$glib_cv_value_POLLNVAL
3571
3572 # If a family is not found on the system, define that family to
3573 # a negative value, picking a different one for each undefined
3574 # family (-1 for AF_UNIX, -2 for the next one, -3 ...)
3575 # This is needed because glib-mkenums doesn't handle optional
3576 # values in enums, and thus we have to have all existing values
3577 # defined in the enum.
3578 if test "x$glib_cv_value_AF_UNIX" != "x"; then
3579   g_af_unix=$glib_cv_value_AF_UNIX
3580 else
3581   g_af_unix=-1
3582 fi
3583 g_af_inet=$glib_cv_value_AF_INET
3584 g_af_inet6=$glib_cv_value_AF_INET6
3585
3586 g_msg_peek=$glib_cv_value_MSG_PEEK
3587 g_msg_oob=$glib_cv_value_MSG_OOB
3588 g_msg_dontroute=$glib_cv_value_MSG_DONTROUTE
3589
3590 g_stack_grows=$glib_cv_stack_grows
3591
3592 g_have_eilseq=$have_eilseq
3593
3594 g_threads_impl_def=$g_threads_impl
3595
3596 g_atomic_lock_free="$glib_cv_g_atomic_lock_free"
3597 g_memory_barrier_needed="$glib_memory_barrier_needed"
3598 g_gcc_atomic_ops="$glib_cv_gcc_has_builtin_atomic_operations"
3599
3600 g_module_suffix="$glib_gmodule_suffix"
3601
3602 g_pid_type="$glib_pid_type"
3603 case $host in
3604   *-*-beos*)
3605     glib_os="#define G_OS_BEOS"
3606     ;;
3607   *-*-cygwin*)
3608     glib_os="#define G_OS_UNIX
3609 #define G_PLATFORM_WIN32
3610 #define G_WITH_CYGWIN"
3611     ;;
3612   *-*-mingw*)
3613     glib_os="#define G_OS_WIN32
3614 #define G_PLATFORM_WIN32"
3615     ;;
3616   *)
3617     glib_os="#define G_OS_UNIX"
3618     ;;
3619 esac
3620 glib_static_compilation=""
3621 if test x$glib_win32_static_compilation = xyes; then
3622   glib_static_compilation="#define GLIB_STATIC_COMPILATION 1
3623 #define GOBJECT_STATIC_COMPILATION 1"
3624 fi
3625 ])
3626
3627 # Redo enough to get guint32 and guint64 for the alignment checks below
3628 case 4 in
3629 $ac_cv_sizeof_short)
3630   gint32=short
3631   ;;
3632 $ac_cv_sizeof_int)
3633   gint32=int
3634   ;;
3635 $ac_cv_sizeof_long)
3636   gint32=long
3637   ;;
3638 esac
3639 case 8 in
3640 $ac_cv_sizeof_int)
3641   gint64=int
3642   ;;
3643 $ac_cv_sizeof_long)
3644   gint64=long
3645   ;;
3646 $ac_cv_sizeof_long_long)
3647   gint64='long long'
3648   ;;
3649 $ac_cv_sizeof___int64)
3650   gint64='__int64'
3651   ;;
3652 esac
3653
3654 AC_CHECK_TYPE([guint32],,,[typedef unsigned $gint32 guint32;])
3655 AC_CHECK_ALIGNOF([guint32], [AC_INCLUDES_DEFAULT
3656 typedef unsigned $gint32 guint32;])
3657 AC_CHECK_TYPE([guint64],,,[typedef unsigned $gint64 guint64;])
3658 AC_CHECK_ALIGNOF([guint64], [AC_INCLUDES_DEFAULT
3659 typedef unsigned $gint64 guint64;])
3660 AC_CHECK_TYPE([unsigned long])
3661 AC_CHECK_ALIGNOF([unsigned long])
3662
3663 # Check for libdbus1 - Optional - is only used in the GDBus test cases
3664 #
3665 # 1.2.14 required for dbus_message_set_serial
3666 PKG_CHECK_MODULES(DBUS1,
3667      dbus-1 >= 1.2.14,
3668      [AC_DEFINE(HAVE_DBUS1, 1, [Define if dbus-1 is available]) have_dbus1=yes],
3669      have_dbus1=no)
3670 AC_SUBST(DBUS1_CFLAGS)
3671 AC_SUBST(DBUS1_LIBS)
3672 AM_CONDITIONAL(HAVE_DBUS1, [test "x$have_dbus1" = "xyes"])
3673
3674 AC_CHECK_PROGS([DBUS_DAEMON], [dbus-daemon])
3675 AM_CONDITIONAL([HAVE_DBUS_DAEMON], [test x$DBUS_DAEMON = xdbus-daemon ])
3676
3677 dnl
3678 dnl Check for -Bsymbolic-functions linker flag used to avoid
3679 dnl intra-library PLT jumps, if available.
3680 dnl
3681
3682 AC_ARG_ENABLE(Bsymbolic,
3683               [AS_HELP_STRING([--disable-Bsymbolic],
3684                               [avoid linking with -Bsymbolic])],,
3685               [SAVED_LDFLAGS="${LDFLAGS}"
3686                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
3687                LDFLAGS=-Wl,-Bsymbolic-functions
3688                AC_TRY_LINK([], [int main (void) { return 0; }],
3689                            AC_MSG_RESULT(yes)
3690                            enable_Bsymbolic=yes,
3691                            AC_MSG_RESULT(no)
3692                            enable_Bsymbolic=no)
3693                LDFLAGS="${SAVED_LDFLAGS}"])
3694
3695 if test "x${enable_Bsymbolic}" = "xyes"; then
3696   GLIB_LINK_FLAGS=-Wl,-Bsymbolic-functions
3697 fi
3698
3699 AC_SUBST(GLIB_LINK_FLAGS)
3700
3701 dnl
3702 dnl Check for -fvisibility=hidden to determine if we can do GNU-style
3703 dnl visibility attributes for symbol export control
3704 dnl
3705 GLIB_HIDDEN_VISIBILITY_CFLAGS=""
3706 case "$host" in
3707   *-*-mingw*)
3708     dnl on mingw32 we do -fvisibility=hidden and __declspec(dllexport)
3709     AC_DEFINE([_GLIB_EXTERN], [__attribute__((visibility("default"))) __declspec(dllexport) extern],
3710               [defines how to decorate public symbols while building])
3711     CFLAGS="${CFLAGS} -fvisibility=hidden"
3712     ;;
3713   *)
3714     dnl on other compilers, check if we can do -fvisibility=hidden
3715     SAVED_CFLAGS="${CFLAGS}"
3716     CFLAGS="-fvisibility=hidden"
3717     AC_MSG_CHECKING([for -fvisibility=hidden compiler flag])
3718     AC_TRY_COMPILE([], [int main (void) { return 0; }],
3719                    AC_MSG_RESULT(yes)
3720                    enable_fvisibility_hidden=yes,
3721                    AC_MSG_RESULT(no)
3722                    enable_fvisibility_hidden=no)
3723     CFLAGS="${SAVED_CFLAGS}"
3724
3725     AS_IF([test "${enable_fvisibility_hidden}" = "yes"], [
3726       AC_DEFINE([_GLIB_EXTERN], [__attribute__((visibility("default"))) extern],
3727                 [defines how to decorate public symbols while building])
3728       GLIB_HIDDEN_VISIBILITY_CFLAGS="-fvisibility=hidden"
3729     ])
3730     ;;
3731 esac
3732 AC_SUBST(GLIB_HIDDEN_VISIBILITY_CFLAGS)
3733
3734 dnl Compiler flags; macro originates from systemd
3735 dnl See https://bugzilla.gnome.org/show_bug.cgi?id=608953
3736 AC_ARG_ENABLE(compile-warnings,
3737               [AS_HELP_STRING([--disable-compile-warnings],
3738                               [Don't use builtin compiler warnings])],,
3739                               enable_compile_warnings=yes)
3740 AS_IF([test "x$enable_compile_warnings" = xyes], [
3741   CC_CHECK_FLAGS_APPEND([GLIB_WARN_CFLAGS], [CFLAGS], [\
3742    -Wall -Wstrict-prototypes -Werror=declaration-after-statement \
3743    -Werror=missing-prototypes -Werror=implicit-function-declaration \
3744    -Werror=pointer-arith -Werror=init-self -Werror=format-security \
3745    -Werror=format=2 -Werror=missing-include-dirs])
3746 ])
3747 AC_SUBST(GLIB_WARN_CFLAGS)
3748
3749 #
3750 # Define variables corresponding to the correct include paths to use for
3751 # in-tree building.
3752 #
3753
3754 # for config.h:
3755 config_h_INCLUDES='-I$(top_builddir)'
3756 AC_SUBST(config_h_INCLUDES)
3757
3758 # glib:
3759 #   config.h
3760 #   $(top_builddir)/glib: for glibconfig.h
3761 #   $(top_srcdir)/glib:   for glib.h
3762 #   $(top_srcdir):        for everything
3763 glib_INCLUDES='$(config_h_INCLUDES) -I$(top_builddir)/glib -I$(top_srcdir)/glib -I$(top_srcdir)'
3764 AC_SUBST(glib_INCLUDES)
3765
3766 # gobject:
3767 #   same as glib
3768 gobject_INCLUDES='$(glib_INCLUDES)'
3769 AC_SUBST(gobject_INCLUDES)
3770
3771 # gmodule:
3772 #   glib includes
3773 #   $(top_srcdir)/gmodule: for gmodule.h
3774 gmodule_INCLUDES='$(glib_INCLUDES) -I$(top_srcdir)/gmodule'
3775 AC_SUBST(gmodule_INCLUDES)
3776
3777 # gio:
3778 #   same as gmodule
3779 gio_INCLUDES='$(gmodule_INCLUDES)'
3780 AC_SUBST(gio_INCLUDES)
3781
3782
3783 AC_CONFIG_FILES([
3784 glib-2.0.pc
3785 gmodule-2.0.pc
3786 gmodule-export-2.0.pc
3787 gmodule-no-export-2.0.pc
3788 gthread-2.0.pc
3789 gobject-2.0.pc
3790 gio-2.0.pc
3791 gio-unix-2.0.pc
3792 gio-windows-2.0.pc
3793 glib-zip
3794 glib-gettextize
3795 Makefile
3796 build/Makefile
3797 build/win32/Makefile
3798 build/win32/dirent/Makefile
3799 build/win32/vs9/Makefile
3800 build/win32/vs10/Makefile
3801 build/win32/vs11/Makefile
3802 glib/Makefile
3803 glib/glib.stp
3804 glib/libcharset/Makefile
3805 glib/gnulib/Makefile
3806 glib/pcre/Makefile
3807 glib/update-pcre/Makefile
3808 glib/tests/Makefile
3809 gmodule/Makefile
3810 gmodule/gmoduleconf.h
3811 gobject/Makefile
3812 gobject/gobject.stp
3813 gobject/glib-mkenums
3814 gobject/tests/Makefile
3815 gthread/Makefile
3816 gio/Makefile
3817 gio/gdbus-2.0/codegen/Makefile
3818 gio/gdbus-2.0/codegen/config.py
3819 gio/gnetworking.h
3820 gio/xdgmime/Makefile
3821 gio/inotify/Makefile
3822 gio/kqueue/Makefile
3823 gio/fen/Makefile
3824 gio/fam/Makefile
3825 gio/win32/Makefile
3826 gio/tests/Makefile
3827 gio/tests/gdbus-object-manager-example/Makefile
3828 gio/tests/services/Makefile
3829 gio/tests/services/org.gtk.GDBus.Examples.ObjectManager.service
3830 po/Makefile.in
3831 docs/Makefile
3832 docs/reference/Makefile
3833 docs/reference/glib/Makefile
3834 docs/reference/glib/version.xml
3835 docs/reference/gobject/Makefile
3836 docs/reference/gobject/version.xml
3837 docs/reference/gio/Makefile
3838 docs/reference/gio/gdbus-object-manager-example/Makefile
3839 docs/reference/gio/version.xml
3840 tests/Makefile
3841 tests/gobject/Makefile
3842 tests/refcount/Makefile
3843 m4macros/Makefile
3844 ])
3845
3846 AC_CONFIG_COMMANDS([chmod-scripts],
3847 [chmod 0755 glib-zip
3848 chmod 0755 glib-gettextize
3849 chmod 0755 gobject/glib-mkenums])
3850
3851 # we want to invoke this macro solely so that the config.status script
3852 # and automake generated makefiles know about these generated files.
3853 # They are only needed to distcheck the package
3854 if false; then
3855   AC_CONFIG_FILES([
3856     INSTALL
3857     README
3858     config.h.win32
3859     glib/glibconfig.h.win32
3860     glib/makefile.msc
3861     glib/glib.rc
3862     gmodule/makefile.msc
3863     gmodule/gmodule.rc
3864     gobject/makefile.msc
3865     gobject/gobject.rc
3866     gthread/makefile.msc
3867     gthread/gthread.rc
3868     gio/gio.rc
3869     tests/makefile.msc
3870   ])
3871 fi
3872
3873 AC_OUTPUT