configure.ac

   1 #   Copyright (C) 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999, 2000,
   2 #   2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011, 2012,
   3 #   2014, 2015 Free Software Foundation, Inc.
   4 #
   5 # This file is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 # General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; see the file COPYING3.  If not see
  17 # <http://www.gnu.org/licenses/>.
  18
  19 ##############################################################################
  20 ### WARNING: this file contains embedded tabs.  Do not run untabify on this file.
  21
  22 m4_include(config/acx.m4)
  23 m4_include(config/override.m4)
  24 m4_include(config/proginstall.m4)
  25 m4_include(config/elf.m4)
  26 m4_include([libtool.m4])
  27 m4_include([ltoptions.m4])
  28 m4_include([ltsugar.m4])
  29 m4_include([ltversion.m4])
  30 m4_include([lt~obsolete.m4])
  31 m4_include([config/isl.m4])
  32
  33 AC_INIT(move-if-change)
  34 AC_PREREQ(2.64)
  35 AC_DISABLE_OPTION_CHECKING
  36
  37 progname=$0
  38 # if PWD already has a value, it is probably wrong.
  39 if test -n "$PWD" ; then PWD=`${PWDCMD-pwd}`; fi
  40
  41 # Export original configure arguments for use by sub-configures.
  42 # Quote arguments with shell meta charatcers.
  43 TOPLEVEL_CONFIGURE_ARGUMENTS=
  44 set -- "$progname" "$@"
  45 for ac_arg
  46 do
  47   case "$ac_arg" in
  48   *" "*|*"      "*|*[[\[\]\~\#\$\^\&\*\(\)\{\}\\\|\;\<\>\?\']]*)
  49     ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"`
  50     # if the argument is of the form -foo=baz, quote the baz part only
  51     ac_arg=`echo "'$ac_arg'" | sed "s/^'\([[-a-zA-Z0-9]]*=\)/\\1'/"` ;;
  52   *) ;;
  53   esac
  54   # Add the quoted argument to the list.
  55   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS $ac_arg"
  56 done
  57 if test "$silent" = yes; then
  58   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS --silent"
  59 fi
  60 # Remove the initial space we just introduced and, as these will be
  61 # expanded by make, quote '$'.
  62 TOPLEVEL_CONFIGURE_ARGUMENTS=`echo "x$TOPLEVEL_CONFIGURE_ARGUMENTS" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
  63 AC_SUBST(TOPLEVEL_CONFIGURE_ARGUMENTS)
  64
  65 # Find the build, host, and target systems.
  66 ACX_NONCANONICAL_BUILD
  67 ACX_NONCANONICAL_HOST
  68 ACX_NONCANONICAL_TARGET
  69
  70 dnl Autoconf 2.5x and later will set a default program prefix if
  71 dnl --target was used, even if it was the same as --host.  Disable
  72 dnl that behavior.  This must be done before AC_CANONICAL_SYSTEM
  73 dnl to take effect.
  74 test "$host_noncanonical" = "$target_noncanonical" &&
  75   test "$program_prefix$program_suffix$program_transform_name" = \
  76     NONENONEs,x,x, &&
  77   program_transform_name=s,y,y,
  78
  79 AC_CANONICAL_SYSTEM
  80 AC_ARG_PROGRAM
  81
  82 m4_pattern_allow([^AS_FOR_TARGET$])dnl
  83 m4_pattern_allow([^AS_FOR_BUILD$])dnl
  84
  85 # Get 'install' or 'install-sh' and its variants.
  86 AC_PROG_INSTALL
  87 ACX_PROG_LN
  88 AC_PROG_LN_S
  89 AC_PROG_SED
  90 AC_PROG_AWK
  91
  92 srcpwd=`cd ${srcdir} ; ${PWDCMD-pwd}`
  93
  94 # We pass INSTALL explicitly to sub-makes.  Make sure that it is not
  95 # a relative path.
  96 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
  97   INSTALL="${srcpwd}/install-sh -c"
  98 fi
  99
 100 # Set srcdir to "." if that's what it is.
 101 # This is important for multilib support.
 102 pwd=`${PWDCMD-pwd}`
 103 if test "${pwd}" = "${srcpwd}" ; then
 104   srcdir=.
 105 fi
 106
 107 topsrcdir=$srcpwd
 108
 109 extra_host_args=
 110
 111 ### To add a new directory to the tree, first choose whether it is a target
 112 ### or a host dependent tool.  Then put it into the appropriate list
 113 ### (library or tools, host or target), doing a dependency sort.
 114
 115 # Subdirs will be configured in the order listed in build_configdirs,
 116 # configdirs, or target_configdirs; see the serialization section below.
 117
 118 # Dependency sorting is only needed when *configuration* must be done in
 119 # a particular order.  In all cases a dependency should be specified in
 120 # the Makefile, whether or not it's implicitly specified here.
 121
 122 # Double entries in build_configdirs, configdirs, or target_configdirs may
 123 # cause circular dependencies and break everything horribly.
 124
 125 # these library is used by various programs built for the build
 126 # environment
 127 #
 128 build_libs="build-libiberty build-libcpp"
 129
 130 # these tools are built for the build environment
 131 build_tools="build-texinfo build-flex build-bison build-m4 build-fixincludes"
 132
 133 # these libraries are used by various programs built for the host environment
 134 #f
 135 host_libs="intl libiberty opcodes bfd readline tcl tk itcl libgui zlib libbacktrace libcpp libdecnumber gmp mpfr mpc isl libelf libiconv"
 136
 137 # these tools are built for the host environment
 138 # Note, the powerpc-eabi build depends on sim occurring before gdb in order to
 139 # know that we are building the simulator.
 140 # binutils, gas and ld appear in that order because it makes sense to run
 141 # "make check" in that particular order.
 142 # If --enable-gold is used, "gold" may replace "ld".
 143 host_tools="texinfo flex bison binutils gas ld fixincludes gcc cgen sid sim gdb gprof etc expect dejagnu m4 utils guile fastjar gnattools libcc1 gotools"
 144
 145 # libgcj represents the runtime libraries only used by gcj.
 146 libgcj="target-libffi \
 147         target-zlib \
 148         target-libjava"
 149
 150 # these libraries are built for the target environment, and are built after
 151 # the host libraries and the host tools (which may be a cross compiler)
 152 # Note that libiberty is not a target library.
 153 target_libraries="target-libgcc \
 154                 target-libbacktrace \
 155                 target-libgloss \
 156                 target-newlib \
 157                 target-libgomp \
 158                 target-libcilkrts \
 159                 target-liboffloadmic \
 160                 target-libatomic \
 161                 target-libitm \
 162                 target-libstdc++-v3 \
 163                 target-libsanitizer \
 164                 target-libvtv \
 165                 target-libmpx \
 166                 target-libssp \
 167                 target-libquadmath \
 168                 target-libgfortran \
 169                 target-boehm-gc \
 170                 ${libgcj} \
 171                 target-libobjc \
 172                 target-libada \
 173                 target-libgo"
 174
 175 # these tools are built using the target libraries, and are intended to
 176 # run only in the target environment
 177 #
 178 # note: any program that *uses* libraries that are in the "target_libraries"
 179 # list belongs in this list.
 180 #
 181 target_tools="target-rda"
 182
 183 ################################################################################
 184
 185 ## All tools belong in one of the four categories, and are assigned above
 186 ## We assign ${configdirs} this way to remove all embedded newlines.  This
 187 ## is important because configure will choke if they ever get through.
 188 ## ${configdirs} is directories we build using the host tools.
 189 ## ${target_configdirs} is directories we build using the target tools.
 190 configdirs=`echo ${host_libs} ${host_tools}`
 191 target_configdirs=`echo ${target_libraries} ${target_tools}`
 192 build_configdirs=`echo ${build_libs} ${build_tools}`
 193
 194 m4_divert_text([PARSE_ARGS],
 195 [case $srcdir in
 196   *" "*)
 197 m4_pushdef([AS_MESSAGE_LOG_FD], [])dnl
 198     AC_MSG_ERROR([path to source, $srcdir, contains spaces])
 199 m4_popdef([AS_MESSAGE_LOG_FD])dnl
 200     ;;
 201 esac
 202 ac_subdirs_all=`cd $srcdir && echo */configure | sed 's,/configure,,g'`
 203 ])
 204
 205 ################################################################################
 206
 207 srcname="gnu development package"
 208
 209 # This gets set non-empty for some net releases of packages.
 210 appdirs=""
 211
 212 # Define is_cross_compiler to save on calls to 'test'.
 213 is_cross_compiler=
 214 if test x"${host}" = x"${target}" ; then
 215   is_cross_compiler=no
 216 else
 217   is_cross_compiler=yes
 218 fi
 219
 220 # Find the build and target subdir names.
 221 GCC_TOPLEV_SUBDIRS
 222 # Be sure to cover against remnants of an in-tree build.
 223 if test $srcdir != .  && test -d $srcdir/host-${host_noncanonical}; then
 224   AC_MSG_ERROR([building out of tree but $srcdir contains host-${host_noncanonical}.
 225 Use a pristine source tree when building in a separate tree])
 226 fi
 227
 228 # Skipdirs are removed silently.
 229 skipdirs=
 230 # Noconfigdirs are removed loudly.
 231 noconfigdirs=""
 232
 233 use_gnu_ld=
 234 # Make sure we don't let GNU ld be added if we didn't want it.
 235 if test x$with_gnu_ld = xno ; then
 236   use_gnu_ld=no
 237   noconfigdirs="$noconfigdirs ld gold"
 238 fi
 239
 240 use_gnu_as=
 241 # Make sure we don't let GNU as be added if we didn't want it.
 242 if test x$with_gnu_as = xno ; then
 243   use_gnu_as=no
 244   noconfigdirs="$noconfigdirs gas"
 245 fi
 246
 247 use_included_zlib=
 248 # Make sure we don't let ZLIB be added if we didn't want it.
 249 if test x$with_system_zlib = xyes ; then
 250   use_included_zlib=no
 251   noconfigdirs="$noconfigdirs zlib"
 252 fi
 253
 254 # some tools are so dependent upon X11 that if we're not building with X,
 255 # it's not even worth trying to configure, much less build, that tool.
 256
 257 case ${with_x} in
 258   yes | "") ;; # the default value for this tree is that X11 is available
 259   no)
 260     skipdirs="${skipdirs} tk itcl libgui"
 261     # We won't be able to build gdbtk without X.
 262     enable_gdbtk=no
 263     ;;
 264   *)  echo "*** bad value \"${with_x}\" for -with-x flag; ignored" 1>&2 ;;
 265 esac
 266
 267 # Some are only suitable for cross toolchains.
 268 # Remove these if host=target.
 269 cross_only="target-libgloss target-newlib target-opcodes"
 270
 271 case $is_cross_compiler in
 272   no) skipdirs="${skipdirs} ${cross_only}" ;;
 273 esac
 274
 275 # If both --with-headers and --with-libs are specified, default to
 276 # --without-newlib.
 277 if test x"${with_headers}" != x && test x"${with_headers}" != xno \
 278    && test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
 279   if test x"${with_newlib}" = x ; then
 280     with_newlib=no
 281   fi
 282 fi
 283
 284 # Recognize --with-newlib/--without-newlib.
 285 case ${with_newlib} in
 286   no) skipdirs="${skipdirs} target-newlib" ;;
 287   yes) skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'` ;;
 288 esac
 289
 290 AC_ARG_ENABLE(as-accelerator-for,
 291 [AS_HELP_STRING([--enable-as-accelerator-for=ARG],
 292                 [build as offload target compiler.
 293                 Specify offload host triple by ARG])])
 294
 295 AC_ARG_ENABLE(offload-targets,
 296 [AS_HELP_STRING([--enable-offload-targets=LIST],
 297                 [enable offloading to devices from comma-separated LIST of
 298                 TARGET[=DIR]. Use optional path to find offload target compiler
 299                 during the build])],
 300 [
 301   if test x"$enable_offload_targets" = x; then
 302     AC_MSG_ERROR([no offload targets specified])
 303   fi
 304 ], [enable_offload_targets=])
 305
 306 # Handle --enable-gold, --enable-ld.
 307 # --disable-gold [--enable-ld]
 308 #     Build only ld.  Default option.
 309 # --enable-gold [--enable-ld]
 310 #     Build both gold and ld.  Install gold as "ld.gold", install ld
 311 #     as "ld.bfd" and "ld".
 312 # --enable-gold=default [--enable-ld]
 313 #     Build both gold and ld.  Install gold as "ld.gold" and "ld",
 314 #     install ld as "ld.bfd".
 315 # --enable-gold[=default] --disable-ld
 316 #     Build only gold, which is then installed as both "ld.gold" and "ld".
 317 # --enable-gold --enable-ld=default
 318 #     Build both gold (installed as "ld.gold") and ld (installed as "ld"
 319 #     and ld.bfd).
 320 #     In other words, ld is default
 321 # --enable-gold=default --enable-ld=default
 322 #     Error.
 323
 324 default_ld=
 325 AC_ARG_ENABLE(gold,
 326 [AS_HELP_STRING([[--enable-gold[=ARG]]],
 327                 [build gold @<:@ARG={default,yes,no}@:>@])],
 328 ENABLE_GOLD=$enableval,
 329 ENABLE_GOLD=no)
 330 case "${ENABLE_GOLD}" in
 331   yes|default)
 332     # Check for ELF target.
 333     is_elf=no
 334     case "${target}" in
 335       *-*-elf* | *-*-sysv4* | *-*-unixware* | *-*-eabi* | hppa*64*-*-hpux* \
 336       | *-*-linux* | *-*-gnu* | frv-*-uclinux* | *-*-irix5* | *-*-irix6* \
 337       | *-*-netbsd* | *-*-openbsd* | *-*-freebsd* | *-*-dragonfly* \
 338       | *-*-solaris2* | *-*-nto* | *-*-nacl*)
 339         case "${target}" in
 340           *-*-linux*aout* | *-*-linux*oldld*)
 341             ;;
 342           *)
 343             is_elf=yes
 344             ;;
 345         esac
 346     esac
 347
 348     if test "$is_elf" = "yes"; then
 349       # Check for target supported by gold.
 350       case "${target}" in
 351         i?86-*-* | x86_64-*-* | sparc*-*-* | powerpc*-*-* | arm*-*-* \
 352         | aarch64*-*-* | tilegx*-*-*)
 353           configdirs="$configdirs gold"
 354           if test x${ENABLE_GOLD} = xdefault; then
 355             default_ld=gold
 356           fi
 357           ENABLE_GOLD=yes
 358           ;;
 359       esac
 360     fi
 361     ;;
 362   no)
 363     ;;
 364   *)
 365     AC_MSG_ERROR([invalid --enable-gold argument])
 366     ;;
 367 esac
 368
 369 AC_ARG_ENABLE(ld,
 370 [AS_HELP_STRING([[--enable-ld[=ARG]]],
 371                 [build ld @<:@ARG={default,yes,no}@:>@])],
 372 ENABLE_LD=$enableval,
 373 ENABLE_LD=yes)
 374
 375 case "${ENABLE_LD}" in
 376   default)
 377     if test x${default_ld} != x; then
 378       AC_MSG_ERROR([either gold or ld can be the default ld])
 379     fi
 380     ;;
 381   yes)
 382     ;;
 383   no)
 384     if test x${ENABLE_GOLD} != xyes; then
 385       AC_MSG_WARN([neither ld nor gold are enabled])
 386     fi
 387     configdirs=`echo " ${configdirs} " | sed -e 's/ ld / /'`
 388     ;;
 389   *)
 390     AC_MSG_ERROR([invalid --enable-ld argument])
 391     ;;
 392 esac
 393
 394 # Configure extra directories which are host specific
 395
 396 case "${host}" in
 397   *-cygwin*)
 398     configdirs="$configdirs libtermcap" ;;
 399 esac
 400
 401 # A target can indicate whether a language isn't supported for some reason.
 402 # Only spaces may be used in this macro; not newlines or tabs.
 403 unsupported_languages=
 404
 405 # Remove more programs from consideration, based on the host or
 406 # target this usually means that a port of the program doesn't
 407 # exist yet.
 408
 409 case "${host}" in
 410   i[[3456789]]86-*-msdosdjgpp*)
 411     noconfigdirs="$noconfigdirs tcl tk itcl"
 412     ;;
 413 esac
 414
 415
 416 AC_ARG_ENABLE(libquadmath,
 417 AS_HELP_STRING([--disable-libquadmath],
 418   [do not build libquadmath directory]),
 419 ENABLE_LIBQUADMATH=$enableval,
 420 ENABLE_LIBQUADMATH=yes)
 421 if test "${ENABLE_LIBQUADMATH}" = "no" ; then
 422   noconfigdirs="$noconfigdirs target-libquadmath"
 423 fi
 424
 425
 426 AC_ARG_ENABLE(libquadmath-support,
 427 AS_HELP_STRING([--disable-libquadmath-support],
 428   [disable libquadmath support for Fortran]),
 429 ENABLE_LIBQUADMATH_SUPPORT=$enableval,
 430 ENABLE_LIBQUADMATH_SUPPORT=yes)
 431 enable_libquadmath_support=
 432 if test "${ENABLE_LIBQUADMATH_SUPPORT}" = "no" ; then
 433   enable_libquadmath_support=no
 434 fi
 435
 436
 437 AC_ARG_ENABLE(libada,
 438 [AS_HELP_STRING([--enable-libada], [build libada directory])],
 439 ENABLE_LIBADA=$enableval,
 440 ENABLE_LIBADA=yes)
 441 if test "${ENABLE_LIBADA}" != "yes" ; then
 442   noconfigdirs="$noconfigdirs gnattools"
 443 fi
 444
 445 AC_ARG_ENABLE(libssp,
 446 [AS_HELP_STRING([--enable-libssp], [build libssp directory])],
 447 ENABLE_LIBSSP=$enableval,
 448 ENABLE_LIBSSP=yes)
 449
 450 AC_ARG_ENABLE(libstdcxx,
 451 AS_HELP_STRING([--disable-libstdcxx],
 452   [do not build libstdc++-v3 directory]),
 453 ENABLE_LIBSTDCXX=$enableval,
 454 ENABLE_LIBSTDCXX=default)
 455 [if test "${ENABLE_LIBSTDCXX}" = "no" ; then
 456   noconfigdirs="$noconfigdirs target-libstdc++-v3"
 457 fi]
 458
 459 # If this is accelerator compiler and its target is intelmic we enable
 460 # target liboffloadmic by default.  If this is compiler with offloading
 461 # for intelmic we enable host liboffloadmic by default.  Otherwise
 462 # liboffloadmic is disabled by default.
 463 AC_ARG_ENABLE([liboffloadmic],
 464 AC_HELP_STRING([[--enable-liboffloadmic[=ARG]]],
 465                [build liboffloadmic @<:@ARG={no,host,target}@:>@]),
 466 [case "$enableval" in
 467   no | host | target)
 468     enable_liboffloadmic=$enableval ;;
 469   *)
 470     AC_MSG_ERROR([--enable-liboffloadmic=no/host/target]) ;;
 471 esac],
 472 [if test x"$enable_as_accelerator_for" != x; then
 473   case "${target}" in
 474     *-intelmic-* | *-intelmicemul-*)
 475       enable_liboffloadmic=target
 476       extra_liboffloadmic_configure_flags="--enable-liboffloadmic=target"
 477       ;;
 478     *)
 479       enable_liboffloadmic=no
 480       ;;
 481   esac
 482 else
 483   case "${enable_offload_targets}" in
 484     *-intelmic-* | *-intelmicemul-*)
 485       enable_liboffloadmic=host
 486       extra_liboffloadmic_configure_flags="--enable-liboffloadmic=host"
 487       ;;
 488     *)
 489       enable_liboffloadmic=no
 490       ;;
 491     esac
 492 fi])
 493 AC_SUBST(extra_liboffloadmic_configure_flags)
 494
 495 # Save it here so that, even in case of --enable-libgcj, if the Java
 496 # front-end isn't enabled, we still get libgcj disabled.
 497 libgcj_saved=$libgcj
 498 case $enable_libgcj in
 499 yes)
 500   # If we reset it here, it won't get added to noconfigdirs in the
 501   # target-specific build rules, so it will be forcibly enabled
 502   # (unless the Java language itself isn't enabled).
 503   libgcj=
 504   ;;
 505 no)
 506   # Make sure we get it printed in the list of not supported target libs.
 507   # Don't disable libffi, though, other languages use it.
 508   noconfigdirs="$noconfigdirs `echo ${libgcj} | sed -e 's/target-libffi//'`"
 509   # Clear libgcj_saved so that even if java is enabled libffi won't be
 510   # built.
 511   libgcj_saved=
 512   ;;
 513 esac
 514
 515 AC_ARG_ENABLE(static-libjava,
 516 [AS_HELP_STRING([[--enable-static-libjava[=ARG]]],
 517                 [build static libjava @<:@default=no@:>@])],
 518 ENABLE_STATIC_LIBJAVA=$enableval,
 519 ENABLE_STATIC_LIBJAVA=no)
 520 enable_static_libjava=
 521 if test "${ENABLE_STATIC_LIBJAVA}" = "yes" ; then
 522   enable_static_libjava=yes
 523 fi
 524
 525 if test x$enable_static_libjava != xyes ; then
 526   EXTRA_CONFIGARGS_LIBJAVA=--disable-static
 527 fi
 528 AC_SUBST(EXTRA_CONFIGARGS_LIBJAVA)
 529
 530 # Disable libgomp on non POSIX hosted systems.
 531 if test x$enable_libgomp = x ; then
 532     # Enable libgomp by default on hosted POSIX systems.
 533     case "${target}" in
 534     *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 535         ;;
 536     *-*-netbsd* | *-*-freebsd* | *-*-openbsd* | *-*-dragonfly*)
 537         ;;
 538     *-*-solaris2* | *-*-hpux11*)
 539         ;;
 540     *-*-darwin* | *-*-aix*)
 541         ;;
 542     *)
 543         noconfigdirs="$noconfigdirs target-libgomp"
 544         ;;
 545     esac
 546 fi
 547
 548 # Disable libatomic on unsupported systems.
 549 if test -d ${srcdir}/libatomic; then
 550     if test x$enable_libatomic = x; then
 551         AC_MSG_CHECKING([for libatomic support])
 552         if (srcdir=${srcdir}/libatomic; \
 553                 . ${srcdir}/configure.tgt; \
 554                 test -n "$UNSUPPORTED")
 555         then
 556             AC_MSG_RESULT([no])
 557             noconfigdirs="$noconfigdirs target-libatomic"
 558         else
 559             AC_MSG_RESULT([yes])
 560         fi
 561     fi
 562 fi
 563
 564 # Disable libcilkrts on unsupported systems.
 565 if test -d ${srcdir}/libcilkrts; then
 566     if test x$enable_libcilkrts = x; then
 567         AC_MSG_CHECKING([for libcilkrts support])
 568         if (srcdir=${srcdir}/libcilkrts; \
 569                 . ${srcdir}/configure.tgt; \
 570                 test -n "$UNSUPPORTED")
 571         then
 572             AC_MSG_RESULT([no])
 573             noconfigdirs="$noconfigdirs target-libcilkrts"
 574         else
 575             AC_MSG_RESULT([yes])
 576         fi
 577     fi
 578 fi
 579
 580 # Disable liboffloadmic on unsupported systems.
 581 if test -d ${srcdir}/liboffloadmic; then
 582     if test x$enable_liboffloadmic != xno; then
 583         AC_MSG_CHECKING([for liboffloadmic support])
 584         if (srcdir=${srcdir}/liboffloadmic; \
 585                 . ${srcdir}/configure.tgt; \
 586                 test -n "$UNSUPPORTED")
 587         then
 588             AC_MSG_RESULT([no])
 589             noconfigdirs="$noconfigdirs target-liboffloadmic"
 590         else
 591             AC_MSG_RESULT([yes])
 592         fi
 593     fi
 594 fi
 595
 596 # Disable libitm on unsupported systems.
 597 if test -d ${srcdir}/libitm; then
 598     if test x$enable_libitm = x; then
 599         AC_MSG_CHECKING([for libitm support])
 600         if (srcdir=${srcdir}/libitm; \
 601                 . ${srcdir}/configure.tgt; \
 602                 test -n "$UNSUPPORTED")
 603         then
 604             AC_MSG_RESULT([no])
 605             noconfigdirs="$noconfigdirs target-libitm"
 606         else
 607             AC_MSG_RESULT([yes])
 608         fi
 609     fi
 610 fi
 611
 612 # Disable libsanitizer on unsupported systems.
 613 if test -d ${srcdir}/libsanitizer; then
 614     if test x$enable_libsanitizer = x; then
 615         AC_MSG_CHECKING([for libsanitizer support])
 616         if (srcdir=${srcdir}/libsanitizer; \
 617                 . ${srcdir}/configure.tgt; \
 618                 test -n "$UNSUPPORTED")
 619         then
 620             AC_MSG_RESULT([no])
 621             noconfigdirs="$noconfigdirs target-libsanitizer"
 622         else
 623             AC_MSG_RESULT([yes])
 624         fi
 625     fi
 626 fi
 627
 628 # Disable libvtv on unsupported systems.
 629 if test -d ${srcdir}/libvtv; then
 630     if test x$enable_libvtv = x; then
 631         AC_MSG_CHECKING([for libvtv support])
 632         if (srcdir=${srcdir}/libvtv; \
 633                 . ${srcdir}/configure.tgt; \
 634                 test "$VTV_SUPPORTED" != "yes")
 635         then
 636             AC_MSG_RESULT([no])
 637             noconfigdirs="$noconfigdirs target-libvtv"
 638         else
 639             AC_MSG_RESULT([yes])
 640         fi
 641     fi
 642 fi
 643
 644
 645 # Enable libmpx on supported systems by request.
 646 if test -d ${srcdir}/libmpx; then
 647     if test x$enable_libmpx = xyes; then
 648        AC_MSG_CHECKING([for libmpx support])
 649        if (srcdir=${srcdir}/libmpx; \
 650                . ${srcdir}/configure.tgt; \
 651                test "$LIBMPX_SUPPORTED" != "yes")
 652        then
 653            AC_MSG_RESULT([no])
 654            noconfigdirs="$noconfigdirs target-libmpx"
 655        else
 656            AC_MSG_RESULT([yes])
 657        fi
 658     else
 659        noconfigdirs="$noconfigdirs target-libmpx"
 660     fi
 661 fi
 662
 663
 664
 665 # Disable libquadmath for some systems.
 666 case "${target}" in
 667   avr-*-*)
 668     noconfigdirs="$noconfigdirs target-libquadmath"
 669     ;;
 670   # libquadmath is unused on AIX and libquadmath build process use of
 671   # LD_LIBRARY_PATH can break AIX bootstrap.
 672   powerpc-*-aix* | rs6000-*-aix*)
 673     noconfigdirs="$noconfigdirs target-libquadmath"
 674     ;;
 675 esac
 676
 677 # Disable libssp for some systems.
 678 case "${target}" in
 679   avr-*-*)
 680     # No hosted I/O support.
 681     noconfigdirs="$noconfigdirs target-libssp"
 682     ;;
 683   powerpc-*-aix* | rs6000-*-aix*)
 684     noconfigdirs="$noconfigdirs target-libssp"
 685     ;;
 686   rl78-*-*)
 687     # libssp uses a misaligned load to trigger a fault, but the RL78
 688     # doesn't fault for those - instead, it gives a build-time error
 689     # for explicit misaligned loads.
 690     noconfigdirs="$noconfigdirs target-libssp"
 691     ;;
 692   visium-*-*)
 693     # No hosted I/O support.
 694     noconfigdirs="$noconfigdirs target-libssp"
 695     ;;
 696 esac
 697
 698 # Disable libstdc++-v3 for some systems.
 699 # Allow user to override this if they pass --enable-libstdc++-v3
 700 if test "${ENABLE_LIBSTDCXX}" = "default" ; then
 701   case "${target}" in
 702     *-*-vxworks*)
 703       # VxWorks uses the Dinkumware C++ library.
 704       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 705       ;;
 706     arm*-wince-pe*)
 707       # the C++ libraries don't build on top of CE's C libraries
 708       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 709       ;;
 710     avr-*-*)
 711       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 712       ;;
 713   esac
 714 fi
 715
 716 # Disable Fortran for some systems.
 717 case "${target}" in
 718   mmix-*-*)
 719     # See <http://gcc.gnu.org/ml/gcc-patches/2004-11/msg00572.html>.
 720     unsupported_languages="$unsupported_languages fortran"
 721     ;;
 722 esac
 723
 724 # Disable Java if libffi is not supported.
 725 case "${target}" in
 726   aarch64-*-*)
 727     ;;
 728   alpha*-*-*)
 729     ;;
 730   arm*-*-*)
 731     ;;
 732   cris-*-*)
 733     ;;
 734   frv-*-*)
 735     ;;
 736   hppa*-*-linux*)
 737     ;;
 738   hppa*-*-hpux*)
 739     ;;
 740   i?86-*-*)
 741     ;;
 742   ia64*-*-*)
 743     ;;
 744   m32r*-*-*)
 745     ;;
 746   m68k-*-*)
 747     ;;
 748   mips*-*-rtems*)
 749     ;;
 750   mips*-*-linux*)
 751     ;;
 752   powerpc*-*-linux*)
 753     ;;
 754   powerpc-*-darwin*)
 755     ;;
 756   powerpc-*-aix* | rs6000-*-aix*)
 757     ;;
 758   powerpc-*-freebsd*)
 759     ;;
 760   powerpc64-*-freebsd*)
 761     ;;
 762   powerpc*-*-rtems*)
 763     ;;
 764   s390-*-* | s390x-*-*)
 765     ;;
 766   sh-*-* | sh[[34]]*-*-*)
 767     ;;
 768   sh64-*-* | sh5*-*-*)
 769     ;;
 770   sparc*-*-*)
 771     ;;
 772   x86_64-*-*)
 773     ;;
 774   *-*-*)
 775     unsupported_languages="$unsupported_languages java"
 776     ;;
 777 esac
 778
 779 # Disable Java, libgcj or related libraries for some systems.
 780 case "${target}" in
 781   powerpc-*-darwin*)
 782     ;;
 783   i[[3456789]]86-*-darwin*)
 784     ;;
 785   x86_64-*-darwin[[912]]*)
 786     ;;
 787   *-*-darwin*)
 788     noconfigdirs="$noconfigdirs ${libgcj}"
 789     ;;
 790   *-*-netware*)
 791     noconfigdirs="$noconfigdirs ${libgcj}"
 792     ;;
 793   *-*-rtems*)
 794     noconfigdirs="$noconfigdirs ${libgcj}"
 795     ;;
 796   *-*-tpf*)
 797     noconfigdirs="$noconfigdirs ${libgcj}"
 798     ;;
 799   *-*-uclinux*)
 800     noconfigdirs="$noconfigdirs ${libgcj}"
 801     ;;
 802   *-*-vxworks*)
 803     noconfigdirs="$noconfigdirs ${libgcj}"
 804     ;;
 805   alpha*-*-*vms*)
 806     noconfigdirs="$noconfigdirs ${libgcj}"
 807     ;;
 808   arm*-*-freebsd*)
 809     noconfigdirs="$noconfigdirs ${libgcj}"
 810     ;;
 811   arm-wince-pe)
 812     noconfigdirs="$noconfigdirs ${libgcj}"
 813     ;;
 814   arm*-*-symbianelf*)
 815     noconfigdirs="$noconfigdirs ${libgcj}"
 816     ;;
 817   bfin-*-*)
 818     noconfigdirs="$noconfigdirs target-boehm-gc"
 819     ;;
 820   cris-*-* | crisv32-*-*)
 821     unsupported_languages="$unsupported_languages java"
 822     case "${target}" in
 823       *-*-linux*)
 824         ;;
 825       *) # See PR46792 regarding target-libffi.
 826         noconfigdirs="$noconfigdirs target-libffi target-boehm-gc";;
 827     esac
 828     ;;
 829   hppa*64*-*-linux*)
 830     # In this case, it's because the hppa64-linux target is for
 831     # the kernel only at this point and has no libc, and thus no
 832     # headers, crt*.o, etc., all of which are needed by these.
 833     unsupported_languages="$unsupported_languages java"
 834     ;;
 835   hppa*64*-*-hpux*)
 836     noconfigdirs="$noconfigdirs ${libgcj}"
 837     ;;
 838   hppa*-hp-hpux11*)
 839     ;;
 840   hppa*-*-hpux*)
 841     # According to Alexandre Oliva <aoliva@redhat.com>, libjava won't
 842     # build on HP-UX 10.20.
 843     noconfigdirs="$noconfigdirs ${libgcj}"
 844     ;;
 845   ia64*-*-*vms*)
 846     noconfigdirs="$noconfigdirs ${libgcj}"
 847     ;;
 848   i[[3456789]]86-w64-mingw*)
 849     noconfigdirs="$noconfigdirs ${libgcj}"
 850     ;;
 851   i[[3456789]]86-*-mingw*)
 852     noconfigdirs="$noconfigdirs ${libgcj}"
 853     ;;
 854   x86_64-*-mingw*)
 855     noconfigdirs="$noconfigdirs ${libgcj}"
 856     ;;
 857   mmix-*-*)
 858     noconfigdirs="$noconfigdirs target-libffi target-boehm-gc"
 859     ;;
 860   powerpc-*-aix*)
 861     # copied from rs6000-*-* entry
 862     noconfigdirs="$noconfigdirs ${libgcj}"
 863     ;;
 864   rs6000-*-aix*)
 865     noconfigdirs="$noconfigdirs ${libgcj}"
 866     ;;
 867   *-*-lynxos*)
 868     noconfigdirs="$noconfigdirs ${libgcj}"
 869     ;;
 870 esac
 871
 872 # Disable the go frontend on systems where it is known to not work. Please keep
 873 # this in sync with contrib/config-list.mk.
 874 case "${target}" in
 875 *-*-darwin* | *-*-cygwin* | *-*-mingw* | *-*-aix*)
 876     unsupported_languages="$unsupported_languages go"
 877     ;;
 878 esac
 879
 880 # Disable libgo for some systems where it is known to not work.
 881 # For testing, you can easily override this with --enable-libgo.
 882 if test x$enable_libgo = x; then
 883     case "${target}" in
 884     *-*-darwin*)
 885         # PR 46986
 886         noconfigdirs="$noconfigdirs target-libgo"
 887         ;;
 888     *-*-cygwin* | *-*-mingw*)
 889         noconfigdirs="$noconfigdirs target-libgo"
 890         ;;
 891     *-*-aix*)
 892         noconfigdirs="$noconfigdirs target-libgo"
 893         ;;
 894     esac
 895 fi
 896
 897 # Default libgloss CPU subdirectory.
 898 libgloss_dir="$target_cpu"
 899
 900 case "${target}" in
 901   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 902     libgloss_dir=wince
 903     ;;
 904   aarch64*-*-* )
 905     libgloss_dir=aarch64
 906     ;;
 907   arm*-*-*)
 908     libgloss_dir=arm
 909     ;;
 910   cris-*-* | crisv32-*-*)
 911     libgloss_dir=cris
 912     ;;
 913   hppa*-*-*)
 914     libgloss_dir=pa
 915     ;;
 916   i[[3456789]]86-*-*)
 917     libgloss_dir=i386
 918     ;;
 919   m68hc11-*-*|m6811-*-*|m68hc12-*-*|m6812-*-*)
 920     libgloss_dir=m68hc11
 921     ;;
 922   m68*-*-* | fido-*-*)
 923     libgloss_dir=m68k
 924     ;;
 925   mips*-*-*)
 926     libgloss_dir=mips
 927     ;;
 928   powerpc*-*-*)
 929     libgloss_dir=rs6000
 930     ;;
 931   sparc*-*-*)
 932     libgloss_dir=sparc
 933     ;;
 934 esac
 935
 936 # Disable newlib and libgloss for various target OSes.
 937 case "${target}" in
 938   alpha*-dec-osf*)
 939     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 940     ;;
 941   i[[3456789]]86-*-linux*)
 942     # This section makes it possible to build newlib natively on linux.
 943     # If we are using a cross compiler then don't configure newlib.
 944     if test x${is_cross_compiler} != xno ; then
 945       noconfigdirs="$noconfigdirs target-newlib"
 946     fi
 947     noconfigdirs="$noconfigdirs target-libgloss"
 948     # If we are not using a cross compiler, do configure newlib.
 949     # Note however, that newlib will only be configured in this situation
 950     # if the --with-newlib option has been given, because otherwise
 951     # 'target-newlib' will appear in skipdirs.
 952     ;;
 953   i[[3456789]]86-*-rdos*)
 954     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 955     ;;
 956   sh*-*-pe|mips*-*-pe|arm-wince-pe)
 957     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 958     ;;
 959   sparc-*-sunos4*)
 960     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 961     ;;
 962   *-*-aix*)
 963     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 964     ;;
 965   *-*-beos*)
 966     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 967     ;;
 968   *-*-chorusos)
 969     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 970     ;;
 971   *-*-dragonfly*)
 972     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 973     ;;
 974   *-*-freebsd*)
 975     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 976     ;;
 977   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 978     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 979     ;;
 980   *-*-lynxos*)
 981     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 982     ;;
 983   *-*-mingw*)
 984     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 985     ;;
 986   *-*-netbsd*)
 987     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 988     ;;
 989   *-*-netware*)
 990     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 991     ;;
 992   *-*-tpf*)
 993     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 994     ;;
 995   *-*-uclinux*)
 996     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 997     ;;
 998   *-*-vxworks*)
 999     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1000     ;;
1001 esac
1002
1003 case "${target}" in
1004   *-*-chorusos)
1005     ;;
1006   powerpc-*-darwin*)
1007     noconfigdirs="$noconfigdirs ld gas gdb gprof"
1008     noconfigdirs="$noconfigdirs sim target-rda"
1009     ;;
1010   i[[3456789]]86-*-darwin*)
1011     noconfigdirs="$noconfigdirs ld gprof"
1012     noconfigdirs="$noconfigdirs sim target-rda"
1013     ;;
1014   x86_64-*-darwin[[912]]*)
1015     noconfigdirs="$noconfigdirs ld gas gprof"
1016     noconfigdirs="$noconfigdirs sim target-rda"
1017     ;;
1018   *-*-darwin*)
1019     noconfigdirs="$noconfigdirs ld gas gdb gprof"
1020     noconfigdirs="$noconfigdirs sim target-rda"
1021     ;;
1022   *-*-dragonfly*)
1023     ;;
1024   *-*-freebsd*)
1025     if test "x$with_gmp" = x && test "x$with_gmp_dir" = x \
1026         && test -f /usr/local/include/gmp.h; then
1027       with_gmp=/usr/local
1028     fi
1029     ;;
1030   *-*-kaos*)
1031     # Remove unsupported stuff on all kaOS configurations.
1032     noconfigdirs="$noconfigdirs target-libgloss"
1033     ;;
1034   *-*-netbsd*)
1035     ;;
1036   *-*-netware*)
1037     ;;
1038   *-*-rtems*)
1039     noconfigdirs="$noconfigdirs target-libgloss"
1040     # this is not caught below because this stanza matches earlier
1041     case $target in
1042       or1k*-*-*) noconfigdirs="$noconfigdirs gdb" ;;
1043     esac
1044     ;;
1045     # The tpf target doesn't support gdb yet.
1046   *-*-tpf*)
1047     noconfigdirs="$noconfigdirs gdb tcl tk libgui itcl"
1048     ;;
1049   *-*-uclinux*)
1050     noconfigdirs="$noconfigdirs target-rda"
1051     ;;
1052   *-*-vxworks*)
1053     ;;
1054   alpha*-dec-osf*)
1055     # ld works, but does not support shared libraries.
1056     # gas doesn't generate exception information.
1057     noconfigdirs="$noconfigdirs gas ld"
1058     ;;
1059   alpha*-*-*vms*)
1060     noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss"
1061     ;;
1062   alpha*-*-*)
1063     # newlib is not 64 bit ready
1064     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1065     ;;
1066   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
1067     noconfigdirs="$noconfigdirs tcl tk itcl libgui sim"
1068     ;;
1069   arc-*-*|arceb-*-*)
1070     noconfigdirs="$noconfigdirs target-libgloss"
1071     ;;
1072   arm-*-pe*)
1073     noconfigdirs="$noconfigdirs target-libgloss"
1074     ;;
1075   arm-*-riscix*)
1076     noconfigdirs="$noconfigdirs ld target-libgloss"
1077     ;;
1078   avr-*-rtems*)
1079     ;;
1080   avr-*-*)
1081     if test x${with_avrlibc} != xno; then
1082       noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1083     fi
1084     ;;
1085   c4x-*-* | tic4x-*-*)
1086     noconfigdirs="$noconfigdirs target-libgloss"
1087     ;;
1088   tic54x-*-*)
1089     noconfigdirs="$noconfigdirs target-libgloss gdb"
1090     ;;
1091   d10v-*-*)
1092     noconfigdirs="$noconfigdirs target-libgloss"
1093     ;;
1094   d30v-*-*)
1095     noconfigdirs="$noconfigdirs gdb"
1096     ;;
1097   fr30-*-elf*)
1098     noconfigdirs="$noconfigdirs gdb"
1099     ;;
1100   moxie-*-*)
1101     noconfigdirs="$noconfigdirs gprof"
1102     ;;
1103   h8300*-*-*)
1104     noconfigdirs="$noconfigdirs target-libgloss"
1105     ;;
1106   h8500-*-*)
1107     noconfigdirs="$noconfigdirs target-libgloss"
1108     ;;
1109   hppa1.1-*-osf* | hppa1.1-*-bsd* )
1110     ;;
1111   hppa*64*-*-linux*)
1112     ;;
1113   hppa*-*-linux*)
1114     ;;
1115   hppa*-*-*elf* | \
1116   hppa*-*-lites* | \
1117   hppa*-*-openbsd* | \
1118   hppa*64*-*-*)
1119     ;;
1120   hppa*-hp-hpux11*)
1121     noconfigdirs="$noconfigdirs ld"
1122     ;;
1123   hppa*-*-pro*)
1124     ;;
1125   hppa*-*-*)
1126     noconfigdirs="$noconfigdirs ld"
1127     ;;
1128   i960-*-*)
1129     noconfigdirs="$noconfigdirs gdb"
1130     ;;
1131   ia64*-*-elf*)
1132     # No gdb support yet.
1133     noconfigdirs="$noconfigdirs readline libgui itcl gdb"
1134     ;;
1135   ia64*-**-hpux*)
1136     # No ld support yet.
1137     noconfigdirs="$noconfigdirs libgui itcl ld"
1138     ;;
1139   ia64*-*-*vms*)
1140     # No ld support yet.
1141     noconfigdirs="$noconfigdirs libgui itcl ld"
1142     ;;
1143   i[[3456789]]86-w64-mingw*)
1144     ;;
1145   i[[3456789]]86-*-mingw*)
1146     target_configdirs="$target_configdirs target-winsup"
1147     ;;
1148   *-*-cygwin*)
1149     target_configdirs="$target_configdirs target-libtermcap target-winsup"
1150     noconfigdirs="$noconfigdirs target-libgloss"
1151     # always build newlib if winsup directory is present.
1152     if test -d "$srcdir/winsup/cygwin"; then
1153       skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1154     elif test -d "$srcdir/newlib"; then
1155       echo "Warning: winsup/cygwin is missing so newlib can't be built."
1156     fi
1157     ;;
1158   i[[3456789]]86-*-pe)
1159     noconfigdirs="$noconfigdirs target-libgloss"
1160     ;;
1161   i[[3456789]]86-*-sco3.2v5*)
1162     # The linker does not yet know about weak symbols in COFF,
1163     # and is not configured to handle mixed ELF and COFF.
1164     noconfigdirs="$noconfigdirs ld target-libgloss"
1165     ;;
1166   i[[3456789]]86-*-sco*)
1167     noconfigdirs="$noconfigdirs gprof target-libgloss"
1168     ;;
1169   i[[3456789]]86-*-solaris2* | x86_64-*-solaris2.1[[0-9]]*)
1170     noconfigdirs="$noconfigdirs target-libgloss"
1171     ;;
1172   i[[3456789]]86-*-sysv4*)
1173     noconfigdirs="$noconfigdirs target-libgloss"
1174     ;;
1175   i[[3456789]]86-*-beos*)
1176     noconfigdirs="$noconfigdirs gdb"
1177     ;;
1178   i[[3456789]]86-*-rdos*)
1179     noconfigdirs="$noconfigdirs gdb"
1180     ;;
1181   mmix-*-*)
1182     noconfigdirs="$noconfigdirs gdb"
1183     ;;
1184   mt-*-*)
1185     noconfigdirs="$noconfigdirs sim"
1186     ;;
1187   powerpc-*-aix*)
1188     # copied from rs6000-*-* entry
1189     noconfigdirs="$noconfigdirs gprof"
1190     ;;
1191   powerpc*-*-winnt* | powerpc*-*-pe*)
1192     target_configdirs="$target_configdirs target-winsup"
1193     noconfigdirs="$noconfigdirs gdb tcl tk target-libgloss itcl"
1194     # always build newlib.
1195     skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1196     ;;
1197     # This is temporary until we can link against shared libraries
1198   powerpcle-*-solaris*)
1199     noconfigdirs="$noconfigdirs gdb sim tcl tk itcl"
1200     ;;
1201   powerpc-*-beos*)
1202     noconfigdirs="$noconfigdirs gdb"
1203     ;;
1204   rs6000-*-lynxos*)
1205     noconfigdirs="$noconfigdirs gprof"
1206     ;;
1207   rs6000-*-aix*)
1208     noconfigdirs="$noconfigdirs gprof"
1209     ;;
1210   rs6000-*-*)
1211     noconfigdirs="$noconfigdirs gprof"
1212     ;;
1213   m68k-apollo-*)
1214     noconfigdirs="$noconfigdirs ld binutils gprof target-libgloss"
1215     ;;
1216   microblaze*)
1217     noconfigdirs="$noconfigdirs gprof"
1218     ;;
1219   mips*-sde-elf* | mips*-mti-elf* | mips*-img-elf*)
1220     if test x$with_newlib = xyes; then
1221       noconfigdirs="$noconfigdirs gprof"
1222     fi
1223     ;;
1224   mips*-*-irix5*)
1225     noconfigdirs="$noconfigdirs gprof target-libgloss"
1226     ;;
1227   mips*-*-irix6*)
1228     noconfigdirs="$noconfigdirs gprof target-libgloss"
1229     ;;
1230   mips*-*-bsd*)
1231     noconfigdirs="$noconfigdirs ld gas gprof target-libgloss"
1232     ;;
1233   mips*-*-linux*)
1234     ;;
1235   mips*-*-ultrix* | mips*-*-osf* | mips*-*-ecoff* | mips*-*-pe* \
1236   | mips*-*-irix* | mips*-*-lnews* | mips*-*-riscos*)
1237     noconfigdirs="$noconfigdirs ld gas gprof"
1238     ;;
1239   mips*-*-*)
1240     noconfigdirs="$noconfigdirs gprof"
1241     ;;
1242   nds32*-*-*)
1243     noconfigdirs="$noconfigdirs gdb"
1244     ;;
1245   nvptx*-*-*)
1246     # nvptx is just a compiler
1247     noconfigdirs="$noconfigdirs target-libssp target-libstdc++-v3 target-libobjc"
1248     ;;
1249   or1k*-*-*)
1250     noconfigdirs="$noconfigdirs gdb"
1251     ;;
1252   sh-*-* | sh64-*-*)
1253     case "${target}" in
1254       sh*-*-elf)
1255          ;;
1256       *)
1257          noconfigdirs="$noconfigdirs target-libgloss" ;;
1258     esac
1259     ;;
1260   sparc-*-sunos4*)
1261     if test x${is_cross_compiler} = xno ; then
1262            use_gnu_ld=no
1263     fi
1264     ;;
1265   tic6x-*-*)
1266     noconfigdirs="$noconfigdirs sim"
1267     ;;
1268   tilepro*-*-* | tilegx*-*-*)
1269     noconfigdirs="$noconfigdirs sim"
1270     ;;
1271   v810-*-*)
1272     noconfigdirs="$noconfigdirs bfd binutils gas gdb ld opcodes target-libgloss"
1273     ;;
1274   vax-*-*)
1275     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1276     ;;
1277 esac
1278
1279 # If we aren't building newlib, then don't build libgloss, since libgloss
1280 # depends upon some newlib header files.
1281 case "${noconfigdirs}" in
1282   *target-libgloss*) ;;
1283   *target-newlib*) noconfigdirs="$noconfigdirs target-libgloss" ;;
1284 esac
1285
1286 # Work in distributions that contain no compiler tools, like Autoconf.
1287 host_makefile_frag=/dev/null
1288 if test -d ${srcdir}/config ; then
1289 case "${host}" in
1290   i[[3456789]]86-*-msdosdjgpp*)
1291     host_makefile_frag="config/mh-djgpp"
1292     ;;
1293   *-cygwin*)
1294     ACX_CHECK_CYGWIN_CAT_WORKS
1295     host_makefile_frag="config/mh-cygwin"
1296     ;;
1297   *-mingw*)
1298     host_makefile_frag="config/mh-mingw"
1299     ;;
1300   hppa*-hp-hpux10*)
1301     host_makefile_frag="config/mh-pa-hpux10"
1302     ;;
1303   hppa*-hp-hpux*)
1304     host_makefile_frag="config/mh-pa"
1305     ;;
1306   hppa*-*)
1307     host_makefile_frag="config/mh-pa"
1308     ;;
1309   *-*-darwin*)
1310     host_makefile_frag="config/mh-darwin"
1311     ;;
1312   powerpc-*-aix*)
1313     host_makefile_frag="config/mh-ppc-aix"
1314     ;;
1315   rs6000-*-aix*)
1316     host_makefile_frag="config/mh-ppc-aix"
1317     ;;
1318 esac
1319 fi
1320
1321 if test "${build}" != "${host}" ; then
1322   AR_FOR_BUILD=${AR_FOR_BUILD-ar}
1323   AS_FOR_BUILD=${AS_FOR_BUILD-as}
1324   CC_FOR_BUILD=${CC_FOR_BUILD-gcc}
1325   CXX_FOR_BUILD=${CXX_FOR_BUILD-g++}
1326   GCJ_FOR_BUILD=${GCJ_FOR_BUILD-gcj}
1327   GFORTRAN_FOR_BUILD=${GFORTRAN_FOR_BUILD-gfortran}
1328   GOC_FOR_BUILD=${GOC_FOR_BUILD-gccgo}
1329   DLLTOOL_FOR_BUILD=${DLLTOOL_FOR_BUILD-dlltool}
1330   LD_FOR_BUILD=${LD_FOR_BUILD-ld}
1331   NM_FOR_BUILD=${NM_FOR_BUILD-nm}
1332   RANLIB_FOR_BUILD=${RANLIB_FOR_BUILD-ranlib}
1333   WINDRES_FOR_BUILD=${WINDRES_FOR_BUILD-windres}
1334   WINDMC_FOR_BUILD=${WINDMC_FOR_BUILD-windmc}
1335 else
1336   AR_FOR_BUILD="\$(AR)"
1337   AS_FOR_BUILD="\$(AS)"
1338   CC_FOR_BUILD="\$(CC)"
1339   CXX_FOR_BUILD="\$(CXX)"
1340   GCJ_FOR_BUILD="\$(GCJ)"
1341   GFORTRAN_FOR_BUILD="\$(GFORTRAN)"
1342   GOC_FOR_BUILD="\$(GOC)"
1343   DLLTOOL_FOR_BUILD="\$(DLLTOOL)"
1344   LD_FOR_BUILD="\$(LD)"
1345   NM_FOR_BUILD="\$(NM)"
1346   RANLIB_FOR_BUILD="\$(RANLIB)"
1347   WINDRES_FOR_BUILD="\$(WINDRES)"
1348   WINDMC_FOR_BUILD="\$(WINDMC)"
1349 fi
1350
1351 AC_PROG_CC
1352 AC_PROG_CXX
1353
1354 # We must set the default linker to the linker used by gcc for the correct
1355 # operation of libtool.  If LD is not defined and we are using gcc, try to
1356 # set the LD default to the ld used by gcc.
1357 if test -z "$LD"; then
1358   if test "$GCC" = yes; then
1359     case $build in
1360     *-*-mingw*)
1361       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1 | tr -d '\015'` ;;
1362     *)
1363       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1` ;;
1364     esac
1365     case $gcc_prog_ld in
1366     # Accept absolute paths.
1367     [[\\/]* | [A-Za-z]:[\\/]*)]
1368       LD="$gcc_prog_ld" ;;
1369     esac
1370   fi
1371 fi
1372
1373 # Check whether -static-libstdc++ -static-libgcc is supported.
1374 have_static_libs=no
1375 if test "$GCC" = yes; then
1376   saved_LDFLAGS="$LDFLAGS"
1377
1378   LDFLAGS="$LDFLAGS -static-libstdc++ -static-libgcc"
1379   AC_MSG_CHECKING([whether g++ accepts -static-libstdc++ -static-libgcc])
1380   AC_LANG_PUSH(C++)
1381   AC_LINK_IFELSE([
1382 #if (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 5)
1383 #error -static-libstdc++ not implemented
1384 #endif
1385 int main() {}],
1386     [AC_MSG_RESULT([yes]); have_static_libs=yes],
1387     [AC_MSG_RESULT([no])])
1388   AC_LANG_POP(C++)
1389
1390   LDFLAGS="$saved_LDFLAGS"
1391 fi
1392
1393 ACX_PROG_GNAT
1394 ACX_PROG_CMP_IGNORE_INITIAL
1395
1396 AC_ARG_ENABLE([bootstrap],
1397 [AS_HELP_STRING([--enable-bootstrap],
1398                 [enable bootstrapping @<:@yes if native build@:>@])],,
1399 enable_bootstrap=default)
1400
1401 # Issue errors and warnings for invalid/strange bootstrap combinations.
1402 if test -r $srcdir/gcc/configure; then
1403   have_compiler=yes
1404 else
1405   have_compiler=no
1406 fi
1407
1408 case "$have_compiler:$host:$target:$enable_bootstrap" in
1409   *:*:*:no) ;;
1410
1411   # Default behavior.  Enable bootstrap if we have a compiler
1412   # and we are in a native configuration.
1413   yes:$build:$build:default)
1414     enable_bootstrap=yes ;;
1415
1416   *:*:*:default)
1417     enable_bootstrap=no ;;
1418
1419   # We have a compiler and we are in a native configuration, bootstrap is ok
1420   yes:$build:$build:yes)
1421     ;;
1422
1423   # Other configurations, but we have a compiler.  Assume the user knows
1424   # what he's doing.
1425   yes:*:*:yes)
1426     AC_MSG_WARN([trying to bootstrap a cross compiler])
1427     ;;
1428
1429   # No compiler: if they passed --enable-bootstrap explicitly, fail
1430   no:*:*:yes)
1431     AC_MSG_ERROR([cannot bootstrap without a compiler]) ;;
1432
1433   # Fail if wrong command line
1434   *)
1435     AC_MSG_ERROR([invalid option for --enable-bootstrap])
1436     ;;
1437 esac
1438
1439 # Used for setting $lt_cv_objdir
1440 _LT_CHECK_OBJDIR
1441
1442 # Check for GMP, MPFR and MPC
1443 gmplibs="-lmpc -lmpfr -lgmp"
1444 gmpinc=
1445 have_gmp=no
1446
1447 # Specify a location for mpc
1448 # check for this first so it ends up on the link line before mpfr.
1449 AC_ARG_WITH(mpc,
1450 [AS_HELP_STRING([--with-mpc=PATH],
1451                 [specify prefix directory for installed MPC package.
1452                  Equivalent to --with-mpc-include=PATH/include
1453                  plus --with-mpc-lib=PATH/lib])])
1454 AC_ARG_WITH(mpc-include,
1455 [AS_HELP_STRING([--with-mpc-include=PATH],
1456                 [specify directory for installed MPC include files])])
1457 AC_ARG_WITH(mpc-lib,
1458 [AS_HELP_STRING([--with-mpc-lib=PATH],
1459                 [specify directory for the installed MPC library])])
1460
1461 if test "x$with_mpc" != x; then
1462   gmplibs="-L$with_mpc/lib $gmplibs"
1463   gmpinc="-I$with_mpc/include $gmpinc"
1464 fi
1465 if test "x$with_mpc_include" != x; then
1466   gmpinc="-I$with_mpc_include $gmpinc"
1467 fi
1468 if test "x$with_mpc_lib" != x; then
1469   gmplibs="-L$with_mpc_lib $gmplibs"
1470 fi
1471 if test "x$with_mpc$with_mpc_include$with_mpc_lib" = x && test -d ${srcdir}/mpc; then
1472   gmplibs='-L$$r/$(HOST_SUBDIR)/mpc/src/'"$lt_cv_objdir $gmplibs"
1473   gmpinc='-I$$s/mpc/src '"$gmpinc"
1474   # Do not test the mpc version.  Assume that it is sufficient, since
1475   # it is in the source tree, and the library has not been built yet
1476   # but it would be included on the link line in the version check below
1477   # hence making the test fail.
1478   have_gmp=yes
1479 fi
1480
1481 # Specify a location for mpfr
1482 # check for this first so it ends up on the link line before gmp.
1483 AC_ARG_WITH(mpfr-dir,
1484 [AS_HELP_STRING([--with-mpfr-dir=PATH], [this option has been REMOVED])],
1485 [AC_MSG_ERROR([The --with-mpfr-dir=PATH option has been removed.
1486 Use --with-mpfr=PATH or --with-mpfr-include=PATH plus --with-mpfr-lib=PATH])])
1487
1488 AC_ARG_WITH(mpfr,
1489 [AS_HELP_STRING([--with-mpfr=PATH],
1490                 [specify prefix directory for installed MPFR package.
1491                  Equivalent to --with-mpfr-include=PATH/include
1492                  plus --with-mpfr-lib=PATH/lib])])
1493 AC_ARG_WITH(mpfr-include,
1494 [AS_HELP_STRING([--with-mpfr-include=PATH],
1495                 [specify directory for installed MPFR include files])])
1496 AC_ARG_WITH(mpfr-lib,
1497 [AS_HELP_STRING([--with-mpfr-lib=PATH],
1498                 [specify directory for the installed MPFR library])])
1499
1500 if test "x$with_mpfr" != x; then
1501   gmplibs="-L$with_mpfr/lib $gmplibs"
1502   gmpinc="-I$with_mpfr/include $gmpinc"
1503 fi
1504 if test "x$with_mpfr_include" != x; then
1505   gmpinc="-I$with_mpfr_include $gmpinc"
1506 fi
1507 if test "x$with_mpfr_lib" != x; then
1508   gmplibs="-L$with_mpfr_lib $gmplibs"
1509 fi
1510 if test "x$with_mpfr$with_mpfr_include$with_mpfr_lib" = x && test -d ${srcdir}/mpfr; then
1511   # MPFR v3.1.0 moved the sources into a src sub-directory.
1512   if test -d ${srcdir}/mpfr/src; then
1513     gmplibs='-L$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir $gmplibs"
1514     gmpinc='-I$$r/$(HOST_SUBDIR)/mpfr/src -I$$s/mpfr/src '"$gmpinc"
1515     extra_mpc_mpfr_configure_flags='--with-mpfr-include=$$s/mpfr/src --with-mpfr-lib=$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir"
1516   else
1517     gmplibs='-L$$r/$(HOST_SUBDIR)/mpfr/'"$lt_cv_objdir $gmplibs"
1518     gmpinc='-I$$r/$(HOST_SUBDIR)/mpfr -I$$s/mpfr '"$gmpinc"
1519     extra_mpc_mpfr_configure_flags='--with-mpfr-include=$$s/mpfr --with-mpfr-lib=$$r/$(HOST_SUBDIR)/mpfr/'"$lt_cv_objdir"
1520   fi
1521   # Do not test the mpfr version.  Assume that it is sufficient, since
1522   # it is in the source tree, and the library has not been built yet
1523   # but it would be included on the link line in the version check below
1524   # hence making the test fail.
1525   have_gmp=yes
1526 fi
1527
1528 # Specify a location for gmp
1529 AC_ARG_WITH(gmp-dir,
1530 [AS_HELP_STRING([--with-gmp-dir=PATH], [this option has been REMOVED])],
1531 [AC_MSG_ERROR([The --with-gmp-dir=PATH option has been removed.
1532 Use --with-gmp=PATH or --with-gmp-include=PATH plus --with-gmp-lib=PATH])])
1533
1534 AC_ARG_WITH(gmp,
1535 [AS_HELP_STRING([--with-gmp=PATH],
1536                 [specify prefix directory for the installed GMP package.
1537                  Equivalent to --with-gmp-include=PATH/include
1538                  plus --with-gmp-lib=PATH/lib])])
1539 AC_ARG_WITH(gmp-include,
1540 [AS_HELP_STRING([--with-gmp-include=PATH],
1541                 [specify directory for installed GMP include files])])
1542 AC_ARG_WITH(gmp-lib,
1543 [AS_HELP_STRING([--with-gmp-lib=PATH],
1544                 [specify directory for the installed GMP library])])
1545
1546
1547 if test "x$with_gmp" != x; then
1548   gmplibs="-L$with_gmp/lib $gmplibs"
1549   gmpinc="-I$with_gmp/include $gmpinc"
1550 fi
1551 if test "x$with_gmp_include" != x; then
1552   gmpinc="-I$with_gmp_include $gmpinc"
1553 fi
1554 if test "x$with_gmp_lib" != x; then
1555   gmplibs="-L$with_gmp_lib $gmplibs"
1556 fi
1557 if test "x$with_gmp$with_gmp_include$with_gmp_lib" = x && test -d ${srcdir}/gmp; then
1558   gmplibs='-L$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir $gmplibs"
1559   gmpinc='-I$$r/$(HOST_SUBDIR)/gmp -I$$s/gmp '"$gmpinc"
1560   extra_mpfr_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1561   extra_mpc_gmp_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1562   extra_isl_gmp_configure_flags='--with-gmp-builddir=$$r/$(HOST_SUBDIR)/gmp'
1563   # Do not test the gmp version.  Assume that it is sufficient, since
1564   # it is in the source tree, and the library has not been built yet
1565   # but it would be included on the link line in the version check below
1566   # hence making the test fail.
1567   have_gmp=yes
1568 fi
1569
1570 if test -d ${srcdir}/gcc && test "x$have_gmp" = xno; then
1571   have_gmp=yes
1572   saved_CFLAGS="$CFLAGS"
1573   CFLAGS="$CFLAGS $gmpinc"
1574   # Check for the recommended and required versions of GMP.
1575   AC_MSG_CHECKING([for the correct version of gmp.h])
1576   AC_TRY_COMPILE([#include "gmp.h"],[
1577   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1578   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1579   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,2,3)
1580   choke me
1581   #endif
1582   ], [AC_TRY_COMPILE([#include <gmp.h>],[
1583   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1584   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1585   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,3,2)
1586   choke me
1587   #endif
1588   ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1589    [AC_MSG_RESULT([no]); have_gmp=no])
1590
1591   # If we have GMP, check the MPFR version.
1592   if test x"$have_gmp" = xyes; then
1593     # Check for the recommended and required versions of MPFR.
1594     AC_MSG_CHECKING([for the correct version of mpfr.h])
1595     AC_TRY_COMPILE([#include <gmp.h>
1596     #include <mpfr.h>],[
1597     #if MPFR_VERSION < MPFR_VERSION_NUM(2,4,0)
1598     choke me
1599     #endif
1600     ], [AC_TRY_COMPILE([#include <gmp.h>
1601     #include <mpfr.h>],[
1602     #if MPFR_VERSION < MPFR_VERSION_NUM(2,4,2)
1603     choke me
1604     #endif
1605     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1606      [AC_MSG_RESULT([no]); have_gmp=no])
1607   fi
1608
1609   # Check for the MPC header version.
1610   if test x"$have_gmp" = xyes ; then
1611     # Check for the recommended and required versions of MPC.
1612     AC_MSG_CHECKING([for the correct version of mpc.h])
1613     AC_TRY_COMPILE([#include <mpc.h>],[
1614     #if MPC_VERSION < MPC_VERSION_NUM(0,8,0)
1615     choke me
1616     #endif
1617     ], [AC_TRY_COMPILE([#include <mpc.h>],[
1618     #if MPC_VERSION < MPC_VERSION_NUM(0,8,1)
1619     choke me
1620     #endif
1621     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1622      [AC_MSG_RESULT([no]); have_gmp=no])
1623   fi
1624
1625   # Now check the MPFR library.
1626   if test x"$have_gmp" = xyes; then
1627     saved_LIBS="$LIBS"
1628     LIBS="$LIBS $gmplibs"
1629     AC_MSG_CHECKING([for the correct version of the gmp/mpfr/mpc libraries])
1630     AC_TRY_LINK([#include <mpc.h>],[
1631     mpfr_t n;
1632     mpfr_t x;
1633     mpc_t c;
1634     int t;
1635     mpfr_init (n);
1636     mpfr_init (x);
1637     mpfr_atan2 (n, n, x, GMP_RNDN);
1638     mpfr_erfc (n, x, GMP_RNDN);
1639     mpfr_subnormalize (x, t, GMP_RNDN);
1640     mpfr_clear(n);
1641     mpfr_clear(x);
1642     mpc_init2 (c, 53);
1643     mpc_set_ui_ui (c, 1, 1, MPC_RNDNN);
1644     mpc_cosh (c, c, MPC_RNDNN);
1645     mpc_pow (c, c, c, MPC_RNDNN);
1646     mpc_acosh (c, c, MPC_RNDNN);
1647     mpc_clear (c);
1648     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); have_gmp=no])
1649     LIBS="$saved_LIBS"
1650   fi
1651
1652   CFLAGS="$saved_CFLAGS"
1653
1654 # The library versions listed in the error message below should match
1655 # the HARD-minimums enforced above.
1656   if test x$have_gmp != xyes; then
1657     AC_MSG_ERROR([Building GCC requires GMP 4.2+, MPFR 2.4.0+ and MPC 0.8.0+.
1658 Try the --with-gmp, --with-mpfr and/or --with-mpc options to specify
1659 their locations.  Source code for these libraries can be found at
1660 their respective hosting sites as well as at
1661 ftp://gcc.gnu.org/pub/gcc/infrastructure/.  See also
1662 http://gcc.gnu.org/install/prerequisites.html for additional info.  If
1663 you obtained GMP, MPFR and/or MPC from a vendor distribution package,
1664 make sure that you have installed both the libraries and the header
1665 files.  They may be located in separate packages.])
1666   fi
1667 fi
1668
1669 # Flags needed for both GMP, MPFR and/or MPC.
1670 AC_SUBST(gmplibs)
1671 AC_SUBST(gmpinc)
1672 AC_SUBST(extra_mpfr_configure_flags)
1673 AC_SUBST(extra_mpc_gmp_configure_flags)
1674 AC_SUBST(extra_mpc_mpfr_configure_flags)
1675 AC_SUBST(extra_isl_gmp_configure_flags)
1676
1677 # Allow host libstdc++ to be specified for static linking with PPL.
1678 AC_ARG_WITH(host-libstdcxx,
1679 [AS_HELP_STRING([--with-host-libstdcxx=L],
1680                 [use linker arguments L to link with libstdc++
1681                  when linking with PPL])])
1682
1683 case $with_host_libstdcxx in
1684   no|yes)
1685     AC_MSG_ERROR([-with-host-libstdcxx needs an argument])
1686     ;;
1687 esac
1688
1689 # Libraries to use for stage1 or when not bootstrapping.
1690 AC_ARG_WITH(stage1-libs,
1691 [AS_HELP_STRING([--with-stage1-libs=LIBS], [libraries for stage1])],
1692 [if test "$withval" = "no" -o "$withval" = "yes"; then
1693    stage1_libs=
1694  else
1695    stage1_libs=$withval
1696  fi],
1697 [stage1_libs=$with_host_libstdcxx])
1698 AC_SUBST(stage1_libs)
1699
1700 # Linker flags to use for stage1 or when not bootstrapping.
1701 AC_ARG_WITH(stage1-ldflags,
1702 [AS_HELP_STRING([--with-stage1-ldflags=FLAGS], [linker flags for stage1])],
1703 [if test "$withval" = "no" -o "$withval" = "yes"; then
1704    stage1_ldflags=
1705  else
1706    stage1_ldflags=$withval
1707  fi],
1708 [stage1_ldflags=
1709  # In stage 1, default to linking libstdc++ and libgcc statically with GCC
1710  # if supported.  But if the user explicitly specified the libraries to use,
1711  # trust that they are doing what they want.
1712  if test "$stage1_libs" = "" -a "$have_static_libs" = yes; then
1713    stage1_ldflags="-static-libstdc++ -static-libgcc"
1714  fi])
1715 AC_SUBST(stage1_ldflags)
1716
1717 # Libraries to use for stage2 and later builds.  This defaults to the
1718 # argument passed to --with-host-libstdcxx.
1719 AC_ARG_WITH(boot-libs,
1720 [AS_HELP_STRING([--with-boot-libs=LIBS], [libraries for stage2 and later])],
1721 [if test "$withval" = "no" -o "$withval" = "yes"; then
1722    poststage1_libs=
1723  else
1724    poststage1_libs=$withval
1725  fi],
1726 [poststage1_libs=$with_host_libstdcxx])
1727 AC_SUBST(poststage1_libs)
1728
1729 # Linker flags to use for stage2 and later builds.
1730 AC_ARG_WITH(boot-ldflags,
1731 [AS_HELP_STRING([--with-boot-ldflags=FLAGS],
1732                 [linker flags for stage2 and later])],
1733 [if test "$withval" = "no" -o "$withval" = "yes"; then
1734    poststage1_ldflags=
1735  else
1736    poststage1_ldflags=$withval
1737  fi],
1738 [poststage1_ldflags=
1739  # In stages 2 and 3, default to linking libstdc++ and libgcc
1740  # statically.  But if the user explicitly specified the libraries to
1741  # use, trust that they are doing what they want.
1742  if test "$poststage1_libs" = ""; then
1743    poststage1_ldflags="-static-libstdc++ -static-libgcc"
1744  fi])
1745 AC_SUBST(poststage1_ldflags)
1746
1747 # GCC GRAPHITE dependency ISL.
1748 # Basic setup is inlined here, actual checks are in config/isl.m4
1749
1750 AC_ARG_WITH(isl,
1751   [AS_HELP_STRING(
1752    [--with-isl=PATH],
1753    [Specify prefix directory for the installed ISL package.
1754     Equivalent to --with-isl-include=PATH/include
1755     plus --with-isl-lib=PATH/lib])])
1756
1757 # Treat --without-isl as a request to disable
1758 # GRAPHITE support and skip all following checks.
1759 if test "x$with_isl" != "xno"; then
1760   # Check for ISL
1761   dnl Provide configure switches and initialize islinc & isllibs
1762   dnl with user input.
1763   ISL_INIT_FLAGS
1764   dnl The versions of ISL that work for Graphite
1765   ISL_CHECK_VERSION()
1766   dnl Only execute fail-action, if ISL has been requested.
1767   ISL_IF_FAILED([
1768     AC_MSG_ERROR([Unable to find a usable ISL.  See config.log for details.])])
1769 fi
1770
1771 # If the ISL check failed, disable builds of in-tree variant of ISL
1772 if test "x$with_isl" = xno ||
1773    test "x$gcc_cv_isl" = xno; then
1774   noconfigdirs="$noconfigdirs isl"
1775   islinc=
1776 fi
1777
1778 AC_SUBST(isllibs)
1779 AC_SUBST(islinc)
1780
1781 # Check for LTO support.
1782 AC_ARG_ENABLE(lto,
1783 [AS_HELP_STRING([--enable-lto], [enable link time optimization support])],
1784 enable_lto=$enableval,
1785 enable_lto=yes; default_enable_lto=yes)
1786
1787 ACX_ELF_TARGET_IFELSE([# ELF platforms build the lto-plugin always.
1788   build_lto_plugin=yes
1789 ],[if test x"$default_enable_lto" = x"yes" ; then
1790     case $target in
1791       *-apple-darwin9* | *-cygwin* | *-mingw*) ;;
1792       # On other non-ELF platforms, LTO has yet to be validated.
1793       *) enable_lto=no ;;
1794     esac
1795   else
1796   # Apart from ELF platforms, only Windows and Darwin support LTO so far.
1797   # It would also be nice to check the binutils support, but we don't
1798   # have gcc_GAS_CHECK_FEATURE available here.  For now, we'll just
1799   # warn during gcc/ subconfigure; unless you're bootstrapping with
1800   # -flto it won't be needed until after installation anyway.
1801     case $target in
1802       *-cygwin* | *-mingw* | *-apple-darwin*) ;;
1803       *) if test x"$enable_lto" = x"yes"; then
1804         AC_MSG_ERROR([LTO support is not enabled for this target.])
1805         fi
1806       ;;
1807     esac
1808   fi
1809   # Among non-ELF, only Windows platforms support the lto-plugin so far.
1810   # Build it unless LTO was explicitly disabled.
1811   case $target in
1812     *-cygwin* | *-mingw*) build_lto_plugin=$enable_lto ;;
1813     *) ;;
1814   esac
1815 ])
1816
1817 AC_ARG_ENABLE(linker-plugin-configure-flags,
1818   [AS_HELP_STRING([[--enable-linker-plugin-configure-flags=FLAGS]],
1819     [additional flags for configuring linker plugins @<:@none@:>@])],
1820   extra_linker_plugin_configure_flags=$enableval,
1821   extra_linker_plugin_configure_flags=)
1822 AC_SUBST(extra_linker_plugin_configure_flags)
1823 AC_ARG_ENABLE(linker-plugin-flags,
1824   [AS_HELP_STRING([[--enable-linker-plugin-flags=FLAGS]],
1825     [additional flags for configuring and building linker plugins @<:@none@:>@])],
1826   extra_linker_plugin_flags=$enableval,
1827   extra_linker_plugin_flags=)
1828 AC_SUBST(extra_linker_plugin_flags)
1829
1830
1831 # By default, C and C++ are the only stage 1 languages.
1832 stage1_languages=,c,
1833
1834 # Target libraries that we bootstrap.
1835 bootstrap_target_libs=,target-libgcc,
1836
1837 # Figure out what language subdirectories are present.
1838 # Look if the user specified --enable-languages="..."; if not, use
1839 # the environment variable $LANGUAGES if defined. $LANGUAGES might
1840 # go away some day.
1841 # NB:  embedded tabs in this IF block -- do not untabify
1842 if test -d ${srcdir}/gcc; then
1843   if test x"${enable_languages+set}" != xset; then
1844     if test x"${LANGUAGES+set}" = xset; then
1845       enable_languages="${LANGUAGES}"
1846         echo configure.in: warning: setting LANGUAGES is deprecated, use --enable-languages instead 1>&2
1847     else
1848       enable_languages=all
1849     fi
1850   else
1851     if test x"${enable_languages}" = x ||
1852        test x"${enable_languages}" = xyes;
1853        then
1854       echo configure.in: --enable-languages needs at least one language argument 1>&2
1855       exit 1
1856     fi
1857   fi
1858   enable_languages=`echo "${enable_languages}" | sed -e 's/[[   ,]][[   ,]]*/,/g' -e 's/,$//'`
1859
1860   # 'f95' is the old name for the 'fortran' language. We issue a warning
1861   # and make the substitution.
1862   case ,${enable_languages}, in
1863     *,f95,*)
1864       echo configure.in: warning: 'f95' as language name is deprecated, use 'fortran' instead 1>&2
1865       enable_languages=`echo "${enable_languages}" | sed -e 's/f95/fortran/g'`
1866       ;;
1867   esac
1868
1869   # If bootstrapping, C++ must be enabled.
1870   case ",$enable_languages,:$enable_bootstrap" in
1871     *,c++,*:*) ;;
1872     *:yes)
1873       if test -f ${srcdir}/gcc/cp/config-lang.in; then
1874         enable_languages="${enable_languages},c++"
1875       else
1876         AC_MSG_ERROR([bootstrapping requires c++ sources])
1877       fi
1878       ;;
1879   esac
1880
1881   # First scan to see if an enabled language requires some other language.
1882   # We assume that a given config-lang.in will list all the language
1883   # front ends it requires, even if some are required indirectly.
1884   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1885     case ${lang_frag} in
1886       ..) ;;
1887       # The odd quoting in the next line works around
1888       # an apparent bug in bash 1.12 on linux.
1889       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1890       *)
1891         # From the config-lang.in, get $language, $lang_requires, and
1892         # $lang_requires_boot_languages.
1893         language=
1894         lang_requires=
1895         lang_requires_boot_languages=
1896         . ${lang_frag}
1897         for other in ${lang_requires} ${lang_requires_boot_languages}; do
1898           case ,${enable_languages}, in
1899             *,$other,*) ;;
1900             *,all,*) ;;
1901             *,$language,*)
1902               echo " \`$other' language required by \`$language'; enabling" 1>&2
1903               enable_languages="${enable_languages},${other}"
1904               ;;
1905           esac
1906         done
1907         for other in ${lang_requires_boot_languages} ; do
1908           if test "$other" != "c"; then
1909             case ,${enable_stage1_languages}, in
1910               *,$other,*) ;;
1911               *,all,*) ;;
1912               *)
1913                 case ,${enable_languages}, in
1914                   *,$language,*)
1915                     echo " '$other' language required by '$language' in stage 1; enabling" 1>&2
1916                     enable_stage1_languages="$enable_stage1_languages,${other}"
1917                     ;;
1918                 esac
1919                 ;;
1920             esac
1921           fi
1922         done
1923         ;;
1924     esac
1925   done
1926
1927   new_enable_languages=,c,
1928
1929   # If LTO is enabled, add the LTO front end.
1930   if test "$enable_lto" = "yes" ; then
1931     case ,${enable_languages}, in
1932       *,lto,*) ;;
1933       *) enable_languages="${enable_languages},lto" ;;
1934     esac
1935     if test "${build_lto_plugin}" = "yes" ; then
1936       configdirs="$configdirs lto-plugin"
1937     fi
1938   fi
1939
1940   # If we're building an offloading compiler, add the LTO front end.
1941   if test x"$enable_as_accelerator_for" != x ; then
1942     case ,${enable_languages}, in
1943       *,lto,*) ;;
1944       *) enable_languages="${enable_languages},lto" ;;
1945     esac
1946   fi
1947
1948   missing_languages=`echo ",$enable_languages," | sed -e s/,all,/,/ -e s/,c,/,/ `
1949   potential_languages=,c,
1950
1951   enabled_target_libs=
1952   disabled_target_libs=
1953
1954   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1955     case ${lang_frag} in
1956       ..) ;;
1957       # The odd quoting in the next line works around
1958       # an apparent bug in bash 1.12 on linux.
1959       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1960       *)
1961         # From the config-lang.in, get $language, $target_libs,
1962         # $lang_dirs, $boot_language, and $build_by_default
1963         language=
1964         target_libs=
1965         lang_dirs=
1966         subdir_requires=
1967         boot_language=no
1968         build_by_default=yes
1969         . ${lang_frag}
1970         if test x${language} = x; then
1971           echo "${lang_frag} doesn't set \$language." 1>&2
1972           exit 1
1973         fi
1974
1975         if test "$language" = "c++"; then
1976           boot_language=yes
1977         fi
1978
1979         add_this_lang=no
1980         case ,${enable_languages}, in
1981           *,${language},*)
1982             # Language was explicitly selected; include it
1983             # unless it is C, which is enabled by default.
1984             if test "$language" != "c"; then
1985               add_this_lang=yes
1986             fi
1987             ;;
1988           *,all,*)
1989             # 'all' was selected, select it if it is a default language
1990             if test "$language" != "c"; then
1991               add_this_lang=${build_by_default}
1992             fi
1993             ;;
1994         esac
1995
1996         # Disable languages that need other directories if these aren't available.
1997         for i in $subdir_requires; do
1998           test -f "$srcdir/gcc/$i/config-lang.in" && continue
1999           case ,${enable_languages}, in
2000             *,${language},*)
2001               # Specifically requested language; tell them.
2002               AC_MSG_ERROR([The gcc/$i directory contains parts of $language but is missing])
2003               ;;
2004             *)
2005               # Silently disable.
2006               add_this_lang=unsupported
2007               ;;
2008           esac
2009         done
2010
2011         # Disable Ada if no preexisting GNAT is available.
2012         case ,${enable_languages},:${language}:${have_gnat} in
2013           *,${language},*:ada:no)
2014             # Specifically requested language; tell them.
2015             AC_MSG_ERROR([GNAT is required to build $language])
2016             ;;
2017           *:ada:no)
2018             # Silently disable.
2019             add_this_lang=unsupported
2020             ;;
2021         esac
2022
2023         # Disable a language that is unsupported by the target.
2024         case " $unsupported_languages " in
2025           *" $language "*)
2026             add_this_lang=unsupported
2027             ;;
2028         esac
2029
2030         case $add_this_lang in
2031           unsupported)
2032             # Remove language-dependent dirs.
2033             disabled_target_libs="$disabled_target_libs $target_libs"
2034             noconfigdirs="$noconfigdirs $lang_dirs"
2035             ;;
2036           no)
2037             # Remove language-dependent dirs; still show language as supported.
2038             disabled_target_libs="$disabled_target_libs $target_libs"
2039             noconfigdirs="$noconfigdirs $lang_dirs"
2040             potential_languages="${potential_languages}${language},"
2041             ;;
2042           yes)
2043             new_enable_languages="${new_enable_languages}${language},"
2044             potential_languages="${potential_languages}${language},"
2045             missing_languages=`echo "$missing_languages" | sed "s/,$language,/,/"`
2046             enabled_target_libs="$enabled_target_libs $target_libs"
2047             case "${boot_language}:,$enable_stage1_languages," in
2048               yes:* | *:*,$language,* | *:*,yes, | *:*,all,)
2049                 # Add to (comma-separated) list of stage 1 languages.
2050                 case ",$stage1_languages," in
2051                   *,$language,* | ,yes, | ,all,) ;;
2052                   *) stage1_languages="${stage1_languages}${language}," ;;
2053                 esac
2054                 # We need to bootstrap any supporting libraries.
2055                 bootstrap_target_libs="${bootstrap_target_libs}${target_libs},"
2056                 ;;
2057             esac
2058             ;;
2059         esac
2060         ;;
2061     esac
2062   done
2063
2064   # Add target libraries which are only needed for disabled languages
2065   # to noconfigdirs.
2066   if test -n "$disabled_target_libs"; then
2067     for dir in $disabled_target_libs; do
2068       case " $enabled_target_libs " in
2069       *" ${dir} "*) ;;
2070       *) noconfigdirs="$noconfigdirs $dir" ;;
2071       esac
2072     done
2073   fi
2074
2075   AC_ARG_ENABLE(stage1-languages,
2076   [AS_HELP_STRING([[--enable-stage1-languages[=all]]],
2077                   [choose additional languages to build during
2078                   stage1.  Mostly useful for compiler development])],
2079   [case ,${enable_stage1_languages}, in
2080     ,no,|,,)
2081       # Set it to something that will have no effect in the loop below
2082       enable_stage1_languages=c ;;
2083     ,yes,)
2084       enable_stage1_languages=`echo $new_enable_languages | \
2085         sed -e "s/^,//" -e "s/,$//" ` ;;
2086     *,all,*)
2087       enable_stage1_languages=`echo ,$enable_stage1_languages, | \
2088         sed -e "s/,all,/$new_enable_languages/" -e "s/^,//" -e "s/,$//" ` ;;
2089   esac
2090
2091   # Add "good" languages from enable_stage1_languages to stage1_languages,
2092   # while "bad" languages go in missing_languages.  Leave no duplicates.
2093   for i in `echo $enable_stage1_languages | sed 's/,/ /g' `; do
2094     case $potential_languages in
2095       *,$i,*)
2096         case $stage1_languages in
2097           *,$i,*) ;;
2098           *) stage1_languages="$stage1_languages$i," ;;
2099         esac ;;
2100       *)
2101         case $missing_languages in
2102           *,$i,*) ;;
2103           *) missing_languages="$missing_languages$i," ;;
2104         esac ;;
2105      esac
2106   done])
2107
2108   # Remove leading/trailing commas that were added for simplicity
2109   potential_languages=`echo "$potential_languages" | sed -e "s/^,//" -e "s/,$//"`
2110   missing_languages=`echo "$missing_languages" | sed -e "s/^,//" -e "s/,$//"`
2111   stage1_languages=`echo "$stage1_languages" | sed -e "s/^,//" -e "s/,$//"`
2112   new_enable_languages=`echo "$new_enable_languages" | sed -e "s/^,//" -e "s/,$//"`
2113
2114   if test "x$missing_languages" != x; then
2115     AC_MSG_ERROR([
2116 The following requested languages could not be built: ${missing_languages}
2117 Supported languages are: ${potential_languages}])
2118   fi
2119   if test "x$new_enable_languages" != "x$enable_languages"; then
2120     echo The following languages will be built: ${new_enable_languages}
2121     enable_languages="$new_enable_languages"
2122   fi
2123
2124   AC_SUBST(stage1_languages)
2125   ac_configure_args=`echo " $ac_configure_args" | sed -e "s/ '--enable-languages=[[^ ]]*'//g" -e "s/$/ '--enable-languages="$enable_languages"'/" `
2126 fi
2127
2128 # Handle --disable-<component> generically.
2129 for dir in $configdirs $build_configdirs $target_configdirs ; do
2130   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g -e s/-/_/g`
2131   varname=`echo $dirname | sed -e s/+/_/g`
2132   if eval test x\${enable_${varname}} "=" xno ; then
2133     noconfigdirs="$noconfigdirs $dir"
2134   fi
2135 done
2136
2137 # Check for Boehm's garbage collector
2138 AC_ARG_ENABLE(objc-gc,
2139 [AS_HELP_STRING([--enable-objc-gc],
2140                 [enable use of Boehm's garbage collector with the
2141                  GNU Objective-C runtime])],
2142 [case ,${enable_languages},:${enable_objc_gc}:${noconfigdirs} in
2143   *,objc,*:*:yes:*target-boehm-gc*)
2144     AC_MSG_ERROR([Boehm's garbage collector was requested yet not supported in this configuration])
2145     ;;
2146 esac])
2147
2148 # Make sure we only build Boehm's garbage collector if required.
2149 case ,${enable_languages},:${enable_objc_gc} in
2150   *,objc,*:yes)
2151     # Keep target-boehm-gc if requested for Objective-C.
2152     ;;
2153   *)
2154     # Otherwise remove target-boehm-gc depending on target-libjava.
2155     if echo " ${noconfigdirs} " | grep "target-libjava" >/dev/null 2>&1; then
2156       noconfigdirs="$noconfigdirs target-boehm-gc"
2157     fi
2158     ;;
2159 esac
2160
2161 # Disable libcilkrts, libitm, libsanitizer, libvtv, liboffloadmic if we're not building C++
2162 case ,${enable_languages}, in
2163   *,c++,*)
2164     # Disable libcilkrts, libitm, libsanitizer if we're not building libstdc++
2165     case "${noconfigdirs}" in
2166       *target-libstdc++-v3*)
2167         noconfigdirs="$noconfigdirs target-libcilkrts target-libitm target-libsanitizer"
2168         ;;
2169       *) ;;
2170     esac
2171     ;;
2172   *)
2173     noconfigdirs="$noconfigdirs target-libcilkrts target-liboffloadmic target-libitm target-libsanitizer target-libvtv"
2174     ;;
2175 esac
2176
2177 # Remove the entries in $skipdirs and $noconfigdirs from $configdirs,
2178 # $build_configdirs and $target_configdirs.
2179 # If we have the source for $noconfigdirs entries, add them to $notsupp.
2180
2181 notsupp=""
2182 for dir in . $skipdirs $noconfigdirs ; do
2183   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g`
2184   if test $dir != .  && echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2185     configdirs=`echo " ${configdirs} " | sed -e "s/ ${dir} / /"`
2186     if test -r $srcdir/$dirname/configure ; then
2187       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2188         true
2189       else
2190         notsupp="$notsupp $dir"
2191       fi
2192     fi
2193   fi
2194   if test $dir != .  && echo " ${build_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2195     build_configdirs=`echo " ${build_configdirs} " | sed -e "s/ ${dir} / /"`
2196     if test -r $srcdir/$dirname/configure ; then
2197       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2198         true
2199       else
2200         notsupp="$notsupp $dir"
2201       fi
2202     fi
2203   fi
2204   if test $dir != . && echo " ${target_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2205     target_configdirs=`echo " ${target_configdirs} " | sed -e "s/ ${dir} / /"`
2206     if test -r $srcdir/$dirname/configure ; then
2207       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2208         true
2209       else
2210         notsupp="$notsupp $dir"
2211       fi
2212     fi
2213   fi
2214 done
2215
2216 # Quietly strip out all directories which aren't configurable in this tree.
2217 # This relies on all configurable subdirectories being autoconfiscated, which
2218 # is now the case.
2219 build_configdirs_all="$build_configdirs"
2220 build_configdirs=
2221 for i in ${build_configdirs_all} ; do
2222   j=`echo $i | sed -e s/build-//g`
2223   if test -f ${srcdir}/$j/configure ; then
2224     build_configdirs="${build_configdirs} $i"
2225   fi
2226 done
2227
2228 configdirs_all="$configdirs"
2229 configdirs=
2230 for i in ${configdirs_all} ; do
2231   if test -f ${srcdir}/$i/configure ; then
2232     configdirs="${configdirs} $i"
2233   fi
2234 done
2235
2236 target_configdirs_all="$target_configdirs"
2237 target_configdirs=
2238 for i in ${target_configdirs_all} ; do
2239   j=`echo $i | sed -e s/target-//g`
2240   if test -f ${srcdir}/$j/configure ; then
2241     target_configdirs="${target_configdirs} $i"
2242   fi
2243 done
2244
2245 # libiberty-linker-plugin is special: it doesn't have its own source directory,
2246 # so we have to add it after the preceding checks.
2247 if test x"$extra_linker_plugin_flags$extra_linker_plugin_configure_flags" != x
2248 then
2249   case " $configdirs " in
2250     *" libiberty "*)
2251       # If we can build libiberty, we can also build libiberty-linker-plugin.
2252       configdirs="$configdirs libiberty-linker-plugin"
2253       extra_linker_plugin_configure_flags="$extra_linker_plugin_configure_flags \
2254         --with-libiberty=../libiberty-linker-plugin";;
2255     *)
2256       AC_MSG_ERROR([libiberty missing]);;
2257   esac
2258 fi
2259
2260 # Sometimes we have special requirements for the host libiberty.
2261 extra_host_libiberty_configure_flags=
2262 case " $configdirs " in
2263   *" lto-plugin "* | *" libcc1 "*)
2264     # When these are to be built as shared libraries, the same applies to
2265     # libiberty.
2266     extra_host_libiberty_configure_flags=--enable-shared
2267     ;;
2268 esac
2269 AC_SUBST(extra_host_libiberty_configure_flags)
2270
2271 # Produce a warning message for the subdirs we can't configure.
2272 # This isn't especially interesting in the Cygnus tree, but in the individual
2273 # FSF releases, it's important to let people know when their machine isn't
2274 # supported by the one or two programs in a package.
2275
2276 if test -n "${notsupp}" && test -z "${norecursion}" ; then
2277   # If $appdirs is non-empty, at least one of those directories must still
2278   # be configured, or we error out.  (E.g., if the gas release supports a
2279   # specified target in some subdirs but not the gas subdir, we shouldn't
2280   # pretend that all is well.)
2281   if test -n "$appdirs" ; then
2282     for dir in $appdirs ; do
2283       if test -r $dir/Makefile.in ; then
2284         if echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2285           appdirs=""
2286           break
2287         fi
2288         if echo " ${target_configdirs} " | grep " target-${dir} " >/dev/null 2>&1; then
2289           appdirs=""
2290           break
2291         fi
2292       fi
2293     done
2294     if test -n "$appdirs" ; then
2295       echo "*** This configuration is not supported by this package." 1>&2
2296       exit 1
2297     fi
2298   fi
2299   # Okay, some application will build, or we don't care to check.  Still
2300   # notify of subdirs not getting built.
2301   echo "*** This configuration is not supported in the following subdirectories:" 1>&2
2302   echo "    ${notsupp}" 1>&2
2303   echo "    (Any other directories should still work fine.)" 1>&2
2304 fi
2305
2306 case "$host" in
2307   *msdosdjgpp*)
2308     enable_gdbtk=no ;;
2309 esac
2310
2311 # To find our prefix, in gcc_cv_tool_prefix.
2312 ACX_TOOL_DIRS
2313
2314 copy_dirs=
2315
2316 AC_ARG_WITH([build-sysroot],
2317   [AS_HELP_STRING([--with-build-sysroot=SYSROOT],
2318                   [use sysroot as the system root during the build])],
2319   [if test x"$withval" != x ; then
2320      SYSROOT_CFLAGS_FOR_TARGET="--sysroot=$withval"
2321    fi],
2322   [SYSROOT_CFLAGS_FOR_TARGET=])
2323 AC_SUBST(SYSROOT_CFLAGS_FOR_TARGET)
2324
2325 AC_ARG_WITH([debug-prefix-map],
2326   [AS_HELP_STRING([--with-debug-prefix-map='A=B C=D ...'],
2327                   [map A to B, C to D ... in debug information])],
2328   [if test x"$withval" != x; then
2329      DEBUG_PREFIX_CFLAGS_FOR_TARGET=
2330      for debug_map in $withval; do
2331        DEBUG_PREFIX_CFLAGS_FOR_TARGET="$DEBUG_PREFIX_CFLAGS_FOR_TARGET -fdebug-prefix-map=$debug_map"
2332      done
2333    fi],
2334   [DEBUG_PREFIX_CFLAGS_FOR_TARGET=])
2335 AC_SUBST(DEBUG_PREFIX_CFLAGS_FOR_TARGET)
2336
2337 # During gcc bootstrap, if we use some random cc for stage1 then CFLAGS
2338 # might be empty or "-g".  We don't require a C++ compiler, so CXXFLAGS
2339 # might also be empty (or "-g", if a non-GCC C++ compiler is in the path).
2340 # We want to ensure that TARGET libraries (which we know are built with
2341 # gcc) are built with "-O2 -g", so include those options when setting
2342 # CFLAGS_FOR_TARGET and CXXFLAGS_FOR_TARGET.
2343 if test "x$CFLAGS_FOR_TARGET" = x; then
2344   CFLAGS_FOR_TARGET=$CFLAGS
2345   case " $CFLAGS " in
2346     *" -O2 "*) ;;
2347     *) CFLAGS_FOR_TARGET="-O2 $CFLAGS_FOR_TARGET" ;;
2348   esac
2349   case " $CFLAGS " in
2350     *" -g "* | *" -g3 "*) ;;
2351     *) CFLAGS_FOR_TARGET="-g $CFLAGS_FOR_TARGET" ;;
2352   esac
2353 fi
2354 AC_SUBST(CFLAGS_FOR_TARGET)
2355
2356 if test "x$CXXFLAGS_FOR_TARGET" = x; then
2357   CXXFLAGS_FOR_TARGET=$CXXFLAGS
2358   case " $CXXFLAGS " in
2359     *" -O2 "*) ;;
2360     *) CXXFLAGS_FOR_TARGET="-O2 $CXXFLAGS_FOR_TARGET" ;;
2361   esac
2362   case " $CXXFLAGS " in
2363     *" -g "* | *" -g3 "*) ;;
2364     *) CXXFLAGS_FOR_TARGET="-g $CXXFLAGS_FOR_TARGET" ;;
2365   esac
2366 fi
2367 AC_SUBST(CXXFLAGS_FOR_TARGET)
2368
2369 AC_SUBST(LDFLAGS_FOR_TARGET)
2370
2371 # Handle --with-headers=XXX.  If the value is not "yes", the contents of
2372 # the named directory are copied to $(tooldir)/sys-include.
2373 if test x"${with_headers}" != x && test x"${with_headers}" != xno ; then
2374   if test x${is_cross_compiler} = xno ; then
2375     echo 1>&2 '***' --with-headers is only supported when cross compiling
2376     exit 1
2377   fi
2378   if test x"${with_headers}" != xyes ; then
2379     x=${gcc_cv_tool_prefix}
2380     copy_dirs="${copy_dirs} ${with_headers} $x/${target_noncanonical}/sys-include"
2381   fi
2382 fi
2383
2384 # Handle --with-libs=XXX.  If the value is not "yes", the contents of
2385 # the name directories are copied to $(tooldir)/lib.  Multiple directories
2386 # are permitted.
2387 if test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
2388   if test x${is_cross_compiler} = xno ; then
2389     echo 1>&2 '***' --with-libs is only supported when cross compiling
2390     exit 1
2391   fi
2392   if test x"${with_libs}" != xyes ; then
2393     # Copy the libraries in reverse order, so that files in the first named
2394     # library override files in subsequent libraries.
2395     x=${gcc_cv_tool_prefix}
2396     for l in ${with_libs}; do
2397       copy_dirs="$l $x/${target_noncanonical}/lib ${copy_dirs}"
2398     done
2399   fi
2400 fi
2401
2402 # Set with_gnu_as, with_gnu_ld, and with_system_zlib as appropriate.
2403 #
2404 # This is done by determining whether or not the appropriate directory
2405 # is available, and by checking whether or not specific configurations
2406 # have requested that this magic not happen.
2407 #
2408 # The command line options always override the explicit settings in
2409 # configure.in, and the settings in configure.in override this magic.
2410 #
2411 # If the default for a toolchain is to use GNU as and ld, and you don't
2412 # want to do that, then you should use the --without-gnu-as and
2413 # --without-gnu-ld options for the configure script.  Similarly, if
2414 # the default is to use the included zlib and you don't want to do that,
2415 # you should use the --with-system-zlib option for the configure script.
2416
2417 if test x${use_gnu_as} = x &&
2418    echo " ${configdirs} " | grep " gas " > /dev/null 2>&1 ; then
2419   with_gnu_as=yes
2420   extra_host_args="$extra_host_args --with-gnu-as"
2421 fi
2422
2423 if test x${use_gnu_ld} = x &&
2424    echo " ${configdirs} " | egrep " (go)?ld " > /dev/null 2>&1 ; then
2425   with_gnu_ld=yes
2426   extra_host_args="$extra_host_args --with-gnu-ld"
2427 fi
2428
2429 if test x${use_included_zlib} = x &&
2430    echo " ${configdirs} " | grep " zlib " > /dev/null 2>&1 ; then
2431   :
2432 else
2433   with_system_zlib=yes
2434   extra_host_args="$extra_host_args --with-system-zlib"
2435 fi
2436
2437 # If using newlib, add --with-newlib to the extra_host_args so that gcc/configure
2438 # can detect this case.
2439
2440 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " target-newlib " > /dev/null 2>&1 ; then
2441   with_newlib=yes
2442   extra_host_args="$extra_host_args --with-newlib"
2443 fi
2444
2445 # Handle ${copy_dirs}
2446 set fnord ${copy_dirs}
2447 shift
2448 while test $# != 0 ; do
2449   if test -f $2/COPIED && test x"`cat $2/COPIED`" = x"$1" ; then
2450     :
2451   else
2452     echo Copying $1 to $2
2453
2454     # Use the install script to create the directory and all required
2455     # parent directories.
2456     if test -d $2 ; then
2457       :
2458     else
2459       echo >config.temp
2460       ${srcdir}/install-sh -c -m 644 config.temp $2/COPIED
2461     fi
2462
2463     # Copy the directory, assuming we have tar.
2464     # FIXME: Should we use B in the second tar?  Not all systems support it.
2465     (cd $1; tar -cf - .) | (cd $2; tar -xpf -)
2466
2467     # It is the responsibility of the user to correctly adjust all
2468     # symlinks.  If somebody can figure out how to handle them correctly
2469     # here, feel free to add the code.
2470
2471     echo $1 > $2/COPIED
2472   fi
2473   shift; shift
2474 done
2475
2476 # Determine a target-dependent exec_prefix that the installed
2477 # gcc will search in.  Keep this list sorted by triplet, with
2478 # the *-*-osname triplets last.
2479 md_exec_prefix=
2480 case "${target}" in
2481   i[[34567]]86-pc-msdosdjgpp*)
2482     md_exec_prefix=/dev/env/DJDIR/bin
2483     ;;
2484   *-*-hpux* | \
2485   *-*-nto-qnx* | \
2486   *-*-solaris2*)
2487     md_exec_prefix=/usr/ccs/bin
2488     ;;
2489 esac
2490
2491 extra_arflags_for_target=
2492 extra_nmflags_for_target=
2493 extra_ranlibflags_for_target=
2494 target_makefile_frag=/dev/null
2495 case "${target}" in
2496   spu-*-*)
2497     target_makefile_frag="config/mt-spu"
2498     ;;
2499   mips*-sde-elf* | mips*-mti-elf* | mips*-img-elf*)
2500     target_makefile_frag="config/mt-sde"
2501     ;;
2502   mipsisa*-*-elfoabi*)
2503     target_makefile_frag="config/mt-mips-elfoabi"
2504     ;;
2505   mips*-*-*linux* | mips*-*-gnu*)
2506     target_makefile_frag="config/mt-mips-gnu"
2507     ;;
2508   nios2-*-elf*)
2509     target_makefile_frag="config/mt-nios2-elf"
2510     ;;
2511   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
2512     target_makefile_frag="config/mt-gnu"
2513     ;;
2514   *-*-aix4.[[3456789]]* | *-*-aix[[56789]].*)
2515     # nm and ar from AIX 4.3 and above require -X32_64 flag to all ar and nm
2516     # commands to handle both 32-bit and 64-bit objects.  These flags are
2517     # harmless if we're using GNU nm or ar.
2518     extra_arflags_for_target=" -X32_64"
2519     extra_nmflags_for_target=" -B -X32_64"
2520     ;;
2521 esac
2522
2523 alphaieee_frag=/dev/null
2524 case $target in
2525   alpha*-*-*)
2526     # This just makes sure to use the -mieee option to build target libs.
2527     # This should probably be set individually by each library.
2528     alphaieee_frag="config/mt-alphaieee"
2529     ;;
2530 esac
2531
2532 # If --enable-target-optspace always use -Os instead of -O2 to build
2533 # the target libraries, similarly if it is not specified, use -Os
2534 # on selected platforms.
2535 ospace_frag=/dev/null
2536 case "${enable_target_optspace}:${target}" in
2537   yes:*)
2538     ospace_frag="config/mt-ospace"
2539     ;;
2540   :d30v-*)
2541     ospace_frag="config/mt-d30v"
2542     ;;
2543   :m32r-* | :d10v-* | :fr30-*)
2544     ospace_frag="config/mt-ospace"
2545     ;;
2546   no:* | :*)
2547     ;;
2548   *)
2549     echo "*** bad value \"${enable_target_optspace}\" for --enable-target-optspace flag; ignored" 1>&2
2550     ;;
2551 esac
2552
2553 # Some systems (e.g., one of the i386-aix systems the gas testers are
2554 # using) don't handle "\$" correctly, so don't use it here.
2555 tooldir='${exec_prefix}'/${target_noncanonical}
2556 build_tooldir=${tooldir}
2557
2558 # Create a .gdbinit file which runs the one in srcdir
2559 # and tells GDB to look there for source files.
2560
2561 if test -r ${srcdir}/.gdbinit ; then
2562   case ${srcdir} in
2563     .) ;;
2564     *) cat > ./.gdbinit <<EOF
2565 # ${NO_EDIT}
2566 dir ${srcdir}
2567 dir .
2568 source ${srcdir}/.gdbinit
2569 EOF
2570     ;;
2571   esac
2572 fi
2573
2574 # Make sure that the compiler is able to generate an executable.  If it
2575 # can't, we are probably in trouble.  We don't care whether we can run the
2576 # executable--we might be using a cross compiler--we only care whether it
2577 # can be created.  At this point the main configure script has set CC.
2578 we_are_ok=no
2579 echo "int main () { return 0; }" > conftest.c
2580 ${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
2581 if test $? = 0 ; then
2582   if test -s conftest || test -s conftest.exe ; then
2583     we_are_ok=yes
2584   fi
2585 fi
2586 case $we_are_ok in
2587   no)
2588     echo 1>&2 "*** The command '${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c' failed."
2589     echo 1>&2 "*** You must set the environment variable CC to a working compiler."
2590     rm -f conftest*
2591     exit 1
2592     ;;
2593 esac
2594 rm -f conftest*
2595
2596 # Decide which environment variable is used to find dynamic libraries.
2597 case "${host}" in
2598   *-*-hpux*) RPATH_ENVVAR=SHLIB_PATH ;;
2599   *-*-darwin*) RPATH_ENVVAR=DYLD_LIBRARY_PATH ;;
2600   *-*-mingw* | *-*-cygwin ) RPATH_ENVVAR=PATH ;;
2601   *) RPATH_ENVVAR=LD_LIBRARY_PATH ;;
2602 esac
2603
2604 # On systems where the dynamic library environment variable is PATH,
2605 # gcc/ will put dynamic libraries into a subdirectory to avoid adding
2606 # built executables to PATH.
2607 if test "$RPATH_ENVVAR" = PATH; then
2608   GCC_SHLIB_SUBDIR=/shlib
2609 else
2610   GCC_SHLIB_SUBDIR=
2611 fi
2612
2613 # Adjust the toplevel makefile according to whether bootstrap was selected.
2614 case $enable_bootstrap in
2615   yes)
2616     bootstrap_suffix=bootstrap
2617     BUILD_CONFIG=bootstrap-debug
2618     ;;
2619   no)
2620     bootstrap_suffix=no-bootstrap
2621     BUILD_CONFIG=
2622     ;;
2623 esac
2624
2625 AC_MSG_CHECKING(for default BUILD_CONFIG)
2626
2627 AC_ARG_WITH([build-config],
2628   [AS_HELP_STRING([--with-build-config='NAME NAME2...'],
2629                   [use config/NAME.mk build configuration])],
2630   [case $with_build_config in
2631    yes) with_build_config= ;;
2632    no) with_build_config= BUILD_CONFIG= ;;
2633    esac])
2634
2635 if test "x${with_build_config}" != x; then
2636   BUILD_CONFIG=$with_build_config
2637 else
2638   case $BUILD_CONFIG in
2639   bootstrap-debug)
2640     if echo "int f (void) { return 0; }" > conftest.c &&
2641        ${CC} -c conftest.c &&
2642        mv conftest.o conftest.o.g0 &&
2643        ${CC} -c -g conftest.c &&
2644        mv conftest.o conftest.o.g &&
2645        ${srcdir}/contrib/compare-debug conftest.o.g0 conftest.o.g > /dev/null 2>&1; then
2646       :
2647     else
2648       BUILD_CONFIG=
2649     fi
2650     rm -f conftest.c conftest.o conftest.o.g0 conftest.o.g
2651     ;;
2652   esac
2653 fi
2654 AC_MSG_RESULT($BUILD_CONFIG)
2655 AC_SUBST(BUILD_CONFIG)
2656
2657 # Use same top-level configure hooks in libgcc/libstdc++/libvtv.
2658 AC_MSG_CHECKING([for --enable-vtable-verify])
2659 AC_ARG_ENABLE(vtable-verify,
2660 [  --enable-vtable-verify    Enable vtable verification feature ],
2661 [case "$enableval" in
2662  yes) enable_vtable_verify=yes ;;
2663  no)  enable_vtable_verify=no ;;
2664  *)   enable_vtable_verify=no;;
2665  esac],
2666 [enable_vtable_verify=no])
2667 AC_MSG_RESULT($enable_vtable_verify)
2668
2669 # Record target_configdirs and the configure arguments for target and
2670 # build configuration in Makefile.
2671 target_configdirs=`echo "${target_configdirs}" | sed -e 's/target-//g'`
2672 build_configdirs=`echo "${build_configdirs}" | sed -e 's/build-//g'`
2673 bootstrap_fixincludes=no
2674
2675 # If we are building libgomp, bootstrap it.
2676 if echo " ${target_configdirs} " | grep " libgomp " > /dev/null 2>&1 ; then
2677   bootstrap_target_libs=${bootstrap_target_libs}target-libgomp,
2678 fi
2679
2680 # If we are building libsanitizer and $BUILD_CONFIG contains bootstrap-asan
2681 # or bootstrap-ubsan, bootstrap it.
2682 if echo " ${target_configdirs} " | grep " libsanitizer " > /dev/null 2>&1; then
2683   case "$BUILD_CONFIG" in
2684     *bootstrap-asan* | *bootstrap-ubsan* )
2685       bootstrap_target_libs=${bootstrap_target_libs}target-libsanitizer,
2686       bootstrap_fixincludes=yes
2687       ;;
2688   esac
2689 fi
2690
2691 # If we are building libvtv and --enable-vtable-verify, bootstrap it.
2692 if echo " ${target_configdirs} " | grep " libvtv " > /dev/null 2>&1 &&
2693    test "$enable_vtable_verify" != no; then
2694   bootstrap_target_libs=${bootstrap_target_libs}target-libvtv,
2695 fi
2696
2697 # If we are building libmpx, bootstrap it.
2698 if echo " ${target_configdirs} " | grep " libmpx " > /dev/null 2>&1; then
2699   bootstrap_target_libs=${bootstrap_target_libs}target-libmpx,
2700 fi
2701
2702 # Determine whether gdb needs tk/tcl or not.
2703 # Use 'maybe' since enable_gdbtk might be true even if tk isn't available
2704 # and in that case we want gdb to be built without tk.  Ugh!
2705 # In fact I believe gdb is the *only* package directly dependent on tk,
2706 # so we should be able to put the 'maybe's in unconditionally and
2707 # leave out the maybe dependencies when enable_gdbtk is false.  I'm not
2708 # 100% sure that that's safe though.
2709
2710 gdb_tk="maybe-all-tcl maybe-all-tk maybe-all-itcl maybe-all-libgui"
2711 case "$enable_gdbtk" in
2712   no)
2713     GDB_TK="" ;;
2714   yes)
2715     GDB_TK="${gdb_tk}" ;;
2716   *)
2717     # Only add the dependency on gdbtk when GDBtk is part of the gdb
2718     # distro.  Eventually someone will fix this and move Insight, nee
2719     # gdbtk to a separate directory.
2720     if test -d ${srcdir}/gdb/gdbtk ; then
2721       GDB_TK="${gdb_tk}"
2722     else
2723       GDB_TK=""
2724     fi
2725     ;;
2726 esac
2727 CONFIGURE_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-configure-/g`
2728 INSTALL_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-install-/g`
2729
2730 # Strip out unwanted targets.
2731
2732 # While at that, we remove Makefiles if we were started for recursive
2733 # configuration, so that the top-level Makefile reconfigures them,
2734 # like we used to do when configure itself was recursive.
2735
2736 # Loop over modules.  We used to use the "$extrasub" feature from Autoconf
2737 # but now we're fixing up the Makefile ourselves with the additional
2738 # commands passed to AC_CONFIG_FILES.  Use separate variables
2739 # extrasub-{build,host,target} not because there is any reason to split
2740 # the substitutions up that way, but only to remain below the limit of
2741 # 99 commands in a script, for HP-UX sed.
2742 # Do not nest @if/@endif pairs, because configure will not warn you at all.
2743
2744 case "$enable_bootstrap:$ENABLE_GOLD: $configdirs :,$stage1_languages," in
2745   yes:yes:*\ gold\ *:*,c++,*) ;;
2746   yes:yes:*\ gold\ *:*)
2747     AC_MSG_ERROR([in a combined tree, bootstrapping with --enable-gold requires c++ in stage1_languages])
2748     ;;
2749 esac
2750
2751 extrasub_build=
2752 for module in ${build_configdirs} ; do
2753   if test -z "${no_recursion}" \
2754      && test -f ${build_subdir}/${module}/Makefile; then
2755     echo 1>&2 "*** removing ${build_subdir}/${module}/Makefile to force reconfigure"
2756     rm -f ${build_subdir}/${module}/Makefile
2757   fi
2758   extrasub_build="$extrasub_build
2759 /^@if build-$module\$/d
2760 /^@endif build-$module\$/d
2761 /^@if build-$module-$bootstrap_suffix\$/d
2762 /^@endif build-$module-$bootstrap_suffix\$/d"
2763 done
2764 extrasub_host=
2765 for module in ${configdirs} ; do
2766   if test -z "${no_recursion}"; then
2767     for file in stage*-${module}/Makefile prev-${module}/Makefile ${module}/Makefile; do
2768       if test -f ${file}; then
2769         echo 1>&2 "*** removing ${file} to force reconfigure"
2770         rm -f ${file}
2771       fi
2772     done
2773   fi
2774   case ${module},${bootstrap_fixincludes} in
2775     fixincludes,no) host_bootstrap_suffix=no-bootstrap ;;
2776     *) host_bootstrap_suffix=$bootstrap_suffix ;;
2777   esac
2778   extrasub_host="$extrasub_host
2779 /^@if $module\$/d
2780 /^@endif $module\$/d
2781 /^@if $module-$host_bootstrap_suffix\$/d
2782 /^@endif $module-$host_bootstrap_suffix\$/d"
2783 done
2784 extrasub_target=
2785 for module in ${target_configdirs} ; do
2786   if test -z "${no_recursion}" \
2787      && test -f ${target_subdir}/${module}/Makefile; then
2788     echo 1>&2 "*** removing ${target_subdir}/${module}/Makefile to force reconfigure"
2789     rm -f ${target_subdir}/${module}/Makefile
2790   fi
2791
2792   # We only bootstrap target libraries listed in bootstrap_target_libs.
2793   case $bootstrap_target_libs in
2794     *,target-$module,*) target_bootstrap_suffix=$bootstrap_suffix ;;
2795     *) target_bootstrap_suffix=no-bootstrap ;;
2796   esac
2797
2798   extrasub_target="$extrasub_target
2799 /^@if target-$module\$/d
2800 /^@endif target-$module\$/d
2801 /^@if target-$module-$target_bootstrap_suffix\$/d
2802 /^@endif target-$module-$target_bootstrap_suffix\$/d"
2803 done
2804
2805 # Do the final fixup along with target modules.
2806 extrasub_target="$extrasub_target
2807 /^@if /,/^@endif /d"
2808
2809 # Create the serialization dependencies.  This uses a temporary file.
2810
2811 AC_ARG_ENABLE([serial-configure],
2812 [AS_HELP_STRING([[--enable-serial-[{host,target,build}-]configure]],
2813                 [force sequential configuration of
2814                  sub-packages for the host, target or build
2815                  machine, or all sub-packages])])
2816
2817 case ${enable_serial_configure} in
2818   yes)
2819     enable_serial_build_configure=yes
2820     enable_serial_host_configure=yes
2821     enable_serial_target_configure=yes
2822     ;;
2823 esac
2824
2825 # These force 'configure's to be done one at a time, to avoid problems
2826 # with contention over a shared config.cache.
2827 rm -f serdep.tmp
2828 echo '# serdep.tmp' > serdep.tmp
2829 olditem=
2830 test "x${enable_serial_build_configure}" = xyes &&
2831 for item in ${build_configdirs} ; do
2832   case ${olditem} in
2833     "") ;;
2834     *) echo "configure-build-${item}: configure-build-${olditem}" >> serdep.tmp ;;
2835   esac
2836   olditem=${item}
2837 done
2838 olditem=
2839 test "x${enable_serial_host_configure}" = xyes &&
2840 for item in ${configdirs} ; do
2841   case ${olditem} in
2842     "") ;;
2843     *) echo "configure-${item}: configure-${olditem}" >> serdep.tmp ;;
2844   esac
2845   olditem=${item}
2846 done
2847 olditem=
2848 test "x${enable_serial_target_configure}" = xyes &&
2849 for item in ${target_configdirs} ; do
2850   case ${olditem} in
2851     "") ;;
2852     *) echo "configure-target-${item}: configure-target-${olditem}" >> serdep.tmp ;;
2853   esac
2854   olditem=${item}
2855 done
2856 serialization_dependencies=serdep.tmp
2857 AC_SUBST_FILE(serialization_dependencies)
2858
2859 # Base args.  Strip norecursion, cache-file, srcdir, host, build,
2860 # target, nonopt, and variable assignments.  These are the ones we
2861 # might not want to pass down to subconfigures.  The exception being
2862 # --cache-file=/dev/null, which is used to turn off the use of cache
2863 # files altogether, and which should be passed on to subconfigures.
2864 # Also strip program-prefix, program-suffix, and program-transform-name,
2865 # so that we can pass down a consistent program-transform-name.
2866 baseargs=
2867 tbaseargs=
2868 keep_next=no
2869 skip_next=no
2870 eval "set -- $ac_configure_args"
2871 for ac_arg
2872 do
2873   if test X"$skip_next" = X"yes"; then
2874     skip_next=no
2875     continue
2876   fi
2877   if test X"$keep_next" = X"yes"; then
2878     case $ac_arg in
2879       *\'*)
2880         ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
2881     esac
2882     baseargs="$baseargs '$ac_arg'"
2883     tbaseargs="$tbaseargs '$ac_arg'"
2884     keep_next=no
2885     continue
2886   fi
2887
2888   # Handle separated arguments.  Based on the logic generated by
2889   # autoconf 2.59.
2890   case $ac_arg in
2891     *=* | --config-cache | -C | -disable-* | --disable-* \
2892       | -enable-* | --enable-* | -gas | --g* | -nfp | --nf* \
2893       | -q | -quiet | --q* | -silent | --sil* | -v | -verb* \
2894       | -with-* | --with-* | -without-* | --without-* | --x)
2895       separate_arg=no
2896       ;;
2897     -*)
2898       separate_arg=yes
2899       ;;
2900     *)
2901       separate_arg=no
2902       ;;
2903   esac
2904
2905   skip_targ=no
2906   case $ac_arg in
2907 changequote(,)
2908   --with-* | --without-*)
2909     libopt=`echo "$ac_arg" | sed -e 's,^--[^-_]*[-_],,' -e 's,=.*$,,'`
2910
2911     case $libopt in
2912     *[-_]include)
2913       lib=`echo "$libopt" | sed 's,[-_]include$,,'`
2914       ;;
2915     *[-_]lib)
2916       lib=`echo "$libopt" | sed 's,[-_]lib$,,'`
2917       ;;
2918     *)
2919       lib=$libopt
2920       ;;
2921     esac
2922 changequote([,])
2923
2924     case $lib in
2925     mpc | mpfr | gmp | isl)
2926       # If we're processing --with-$lib, --with-$lib-include or
2927       # --with-$lib-lib, for one of the libs above, and target is
2928       # different from host, don't pass the current argument to any
2929       # target library's configure.
2930       if test x$is_cross_compiler = xyes; then
2931         skip_targ=yes
2932       fi
2933       ;;
2934     esac
2935     ;;
2936   esac
2937
2938   case "$ac_arg" in
2939     --cache-file=/dev/null | \
2940     -cache-file=/dev/null )
2941       # Handled here to avoid the test to skip args below.
2942       baseargs="$baseargs '$ac_arg'"
2943       tbaseargs="$tbaseargs '$ac_arg'"
2944       # Assert: $separate_arg should always be no.
2945       keep_next=$separate_arg
2946       ;;
2947     --no*)
2948       continue
2949       ;;
2950     --c* | \
2951     --sr* | \
2952     --ho* | \
2953     --bu* | \
2954     --t* | \
2955     --program-* | \
2956     -cache_file* | \
2957     -srcdir* | \
2958     -host* | \
2959     -build* | \
2960     -target* | \
2961     -program-prefix* | \
2962     -program-suffix* | \
2963     -program-transform-name* )
2964       skip_next=$separate_arg
2965       continue
2966       ;;
2967     -*)
2968       # An option.  Add it.
2969       case $ac_arg in
2970         *\'*)
2971           ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
2972       esac
2973       baseargs="$baseargs '$ac_arg'"
2974       if test X"$skip_targ" = Xno; then
2975         tbaseargs="$tbaseargs '$ac_arg'"
2976       fi
2977       keep_next=$separate_arg
2978       ;;
2979     *)
2980       # Either a variable assignment, or a nonopt (triplet).  Don't
2981       # pass it down; let the Makefile handle this.
2982       continue
2983       ;;
2984   esac
2985 done
2986 # Remove the initial space we just introduced and, as these will be
2987 # expanded by make, quote '$'.
2988 baseargs=`echo "x$baseargs" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
2989
2990 # Add in --program-transform-name, after --program-prefix and
2991 # --program-suffix have been applied to it.  Autoconf has already
2992 # doubled dollar signs and backslashes in program_transform_name; we want
2993 # the backslashes un-doubled, and then the entire thing wrapped in single
2994 # quotes, because this will be expanded first by make and then by the shell.
2995 # Also, because we want to override the logic in subdir configure scripts to
2996 # choose program_transform_name, replace any s,x,x, with s,y,y,.
2997 sed -e "s,\\\\\\\\,\\\\,g; s,','\\\\'',g; s/s,x,x,/s,y,y,/" <<EOF_SED > conftestsed.out
2998 ${program_transform_name}
2999 EOF_SED
3000 gcc_transform_name=`cat conftestsed.out`
3001 rm -f conftestsed.out
3002 baseargs="$baseargs --program-transform-name='${gcc_transform_name}'"
3003 tbaseargs="$tbaseargs --program-transform-name='${gcc_transform_name}'"
3004 if test "$silent" = yes; then
3005   baseargs="$baseargs --silent"
3006   tbaseargs="$tbaseargs --silent"
3007 fi
3008 baseargs="$baseargs --disable-option-checking"
3009 tbaseargs="$tbaseargs --disable-option-checking"
3010
3011 # Record and document user additions to sub configure arguments.
3012 AC_ARG_VAR([build_configargs],
3013            [additional configure arguments for build directories])
3014 AC_ARG_VAR([host_configargs],
3015            [additional configure arguments for host directories])
3016 AC_ARG_VAR([target_configargs],
3017            [additional configure arguments for target directories])
3018
3019 # For the build-side libraries, we just need to pretend we're native,
3020 # and not use the same cache file.  Multilibs are neither needed nor
3021 # desired.  We can't even use the same cache file for all build-side
3022 # libraries, as they're compiled differently; some with C, some with
3023 # C++ or with different feature-enabling options.
3024 build_configargs="$build_configargs --cache-file=./config.cache ${baseargs}"
3025
3026 # For host modules, accept cache file option, or specification as blank.
3027 case "${cache_file}" in
3028 "") # empty
3029   cache_file_option="" ;;
3030 /* | [[A-Za-z]]:[[\\/]]* ) # absolute path
3031   cache_file_option="--cache-file=${cache_file}" ;;
3032 *) # relative path
3033   cache_file_option="--cache-file=../${cache_file}" ;;
3034 esac
3035
3036 # Host dirs don't like to share a cache file either, horribly enough.
3037 # This seems to be due to autoconf 2.5x stupidity.
3038 host_configargs="$host_configargs --cache-file=./config.cache ${extra_host_args} ${baseargs}"
3039
3040 target_configargs="$target_configargs ${tbaseargs}"
3041
3042 # Passing a --with-cross-host argument lets the target libraries know
3043 # whether they are being built with a cross-compiler or being built
3044 # native.  However, it would be better to use other mechanisms to make the
3045 # sorts of decisions they want to make on this basis.  Please consider
3046 # this option to be deprecated.  FIXME.
3047 if test x${is_cross_compiler} = xyes ; then
3048   target_configargs="--with-cross-host=${host_noncanonical} ${target_configargs}"
3049 fi
3050
3051 # Special user-friendly check for native x86_64-linux build, if
3052 # multilib is not explicitly enabled.
3053 case "$target:$have_compiler:$host:$target:$enable_multilib" in
3054   x86_64-*linux*:yes:$build:$build:)
3055     # Make sure we have a developement environment that handles 32-bit
3056     dev64=no
3057     echo "int main () { return 0; }" > conftest.c
3058     ${CC} -m32 -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
3059     if test $? = 0 ; then
3060       if test -s conftest || test -s conftest.exe ; then
3061         dev64=yes
3062       fi
3063     fi
3064     rm -f conftest*
3065     if test x${dev64} != xyes ; then
3066       AC_MSG_ERROR([I suspect your system does not have 32-bit developement libraries (libc and headers). If you have them, rerun configure with --enable-multilib. If you do not have them, and want to build a 64-bit-only compiler, rerun configure with --disable-multilib.])
3067     fi
3068     ;;
3069 esac
3070
3071 # Default to --enable-multilib.
3072 if test x${enable_multilib} = x ; then
3073   target_configargs="--enable-multilib ${target_configargs}"
3074 fi
3075
3076 # Pass --with-newlib if appropriate.  Note that target_configdirs has
3077 # changed from the earlier setting of with_newlib.
3078 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " newlib " > /dev/null 2>&1 && test -d ${srcdir}/newlib ; then
3079   target_configargs="--with-newlib ${target_configargs}"
3080 fi
3081
3082 # Different target subdirs use different values of certain variables
3083 # (notably CXX).  Worse, multilibs use *lots* of different values.
3084 # Worse yet, autoconf 2.5x makes some of these 'precious', meaning that
3085 # it doesn't automatically accept command-line overrides of them.
3086 # This means it's not safe for target subdirs to share a cache file,
3087 # which is disgusting, but there you have it.  Hopefully this can be
3088 # fixed in future.  It's still worthwhile to use a cache file for each
3089 # directory.  I think.
3090
3091 # Pass the appropriate --build, --host, --target and --cache-file arguments.
3092 # We need to pass --target, as newer autoconf's requires consistency
3093 # for target_alias and gcc doesn't manage it consistently.
3094 target_configargs="--cache-file=./config.cache ${target_configargs}"
3095
3096 FLAGS_FOR_TARGET=
3097 case " $target_configdirs " in
3098  *" newlib "*)
3099   case " $target_configargs " in
3100   *" --with-newlib "*)
3101    case "$target" in
3102     *-cygwin*)
3103       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/cygwin -isystem $$s/winsup/cygwin/include'
3104       ;;
3105    esac
3106
3107    # If we're not building GCC, don't discard standard headers.
3108    if test -d ${srcdir}/gcc; then
3109      FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -nostdinc'
3110
3111      if test "${build}" != "${host}"; then
3112        # On Canadian crosses, CC_FOR_TARGET will have already been set
3113        # by `configure', so we won't have an opportunity to add -Bgcc/
3114        # to it.  This is right: we don't want to search that directory
3115        # for binaries, but we want the header files in there, so add
3116        # them explicitly.
3117        FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -isystem $$r/$(HOST_SUBDIR)/gcc/include -isystem $$r/$(HOST_SUBDIR)/gcc/include-fixed'
3118
3119        # Someone might think of using the pre-installed headers on
3120        # Canadian crosses, in case the installed compiler is not fully
3121        # compatible with the compiler being built.  In this case, it
3122        # would be better to flag an error than risking having
3123        # incompatible object files being constructed.  We can't
3124        # guarantee that an error will be flagged, but let's hope the
3125        # compiler will do it, when presented with incompatible header
3126        # files.
3127      fi
3128    fi
3129
3130    case "${target}-${is_cross_compiler}" in
3131    i[[3456789]]86-*-linux*-no)
3132       # Here host == target, so we don't need to build gcc,
3133       # so we don't want to discard standard headers.
3134       FLAGS_FOR_TARGET=`echo " $FLAGS_FOR_TARGET " | sed -e 's/ -nostdinc / /'`
3135       ;;
3136    *)
3137       # If we're building newlib, use its generic headers last, but search
3138       # for any libc-related directories first (so make it the last -B
3139       # switch).
3140       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/newlib/ -isystem $$r/$(TARGET_SUBDIR)/newlib/targ-include -isystem $$s/newlib/libc/include'
3141
3142       # If we're building libgloss, find the startup file, simulator library
3143       # and linker script.
3144       case " $target_configdirs " in
3145         *" libgloss "*)
3146         # Look for startup file, simulator library and maybe linker script.
3147         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/libgloss/'"$libgloss_dir"
3148         # Look for libnosys.a in case the target needs it.
3149         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/libgloss/libnosys'
3150         # Most targets have the linker script in the source directory.
3151         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$s/libgloss/'"$libgloss_dir"
3152         ;;
3153       esac
3154       ;;
3155    esac
3156    ;;
3157   esac
3158   ;;
3159 esac
3160
3161 case "$target" in
3162   x86_64-*mingw* | *-w64-mingw*)
3163   # MinGW-w64 does not use newlib, nor does it use winsup. It may,
3164   # however, use a symlink named 'mingw' in ${prefix} .
3165     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L${prefix}/${target}/lib -L${prefix}/mingw/lib -isystem ${prefix}/${target}/include -isystem ${prefix}/mingw/include'
3166     ;;
3167   *-mingw*)
3168   # MinGW can't be handled as Cygwin above since it does not use newlib.
3169     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/mingw -L$$r/$(TARGET_SUBDIR)/winsup/w32api/lib -isystem $$s/winsup/mingw/include -isystem $$s/winsup/w32api/include'
3170     ;;
3171 esac
3172
3173 # Allow the user to override the flags for
3174 # our build compiler if desired.
3175 if test x"${build}" = x"${host}" ; then
3176   CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-${CFLAGS}}
3177   CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-${CXXFLAGS}}
3178   LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-${LDFLAGS}}
3179 fi
3180
3181 # On Canadian crosses, we'll be searching the right directories for
3182 # the previously-installed cross compiler, so don't bother to add
3183 # flags for directories within the install tree of the compiler
3184 # being built; programs in there won't even run.
3185 if test "${build}" = "${host}" && test -d ${srcdir}/gcc; then
3186   # Search for pre-installed headers if nothing else fits.
3187   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$(build_tooldir)/bin/ -B$(build_tooldir)/lib/ -isystem $(build_tooldir)/include -isystem $(build_tooldir)/sys-include'
3188 fi
3189
3190 if test "x${use_gnu_ld}" = x &&
3191    echo " ${configdirs} " | grep " ld " > /dev/null ; then
3192   # Arrange for us to find uninstalled linker scripts.
3193   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(HOST_SUBDIR)/ld'
3194 fi
3195
3196 # Search for other target-specific linker scripts and such.
3197 case "${target}" in
3198   mep*)
3199     FLAGS_FOR_TARGET="$FLAGS_FOR_TARGET -mlibrary"
3200     ;;
3201 esac
3202
3203 # Makefile fragments.
3204 for frag in host_makefile_frag target_makefile_frag alphaieee_frag ospace_frag;
3205 do
3206   eval fragval=\$$frag
3207   if test $fragval != /dev/null; then
3208     eval $frag=${srcdir}/$fragval
3209   fi
3210 done
3211 AC_SUBST_FILE(host_makefile_frag)
3212 AC_SUBST_FILE(target_makefile_frag)
3213 AC_SUBST_FILE(alphaieee_frag)
3214 AC_SUBST_FILE(ospace_frag)
3215
3216 # Miscellanea: directories, flags, etc.
3217 AC_SUBST(RPATH_ENVVAR)
3218 AC_SUBST(GCC_SHLIB_SUBDIR)
3219 AC_SUBST(tooldir)
3220 AC_SUBST(build_tooldir)
3221 AC_SUBST(CONFIGURE_GDB_TK)
3222 AC_SUBST(GDB_TK)
3223 AC_SUBST(INSTALL_GDB_TK)
3224
3225 # Build module lists & subconfigure args.
3226 AC_SUBST(build_configargs)
3227 AC_SUBST(build_configdirs)
3228
3229 # Host module lists & subconfigure args.
3230 AC_SUBST(host_configargs)
3231 AC_SUBST(configdirs)
3232 AC_SUBST(target_configdirs)
3233
3234 # Target module lists & subconfigure args.
3235 AC_SUBST(target_configargs)
3236
3237
3238 # Build tools.
3239 AC_SUBST(AR_FOR_BUILD)
3240 AC_SUBST(AS_FOR_BUILD)
3241 AC_SUBST(CC_FOR_BUILD)
3242 AC_SUBST(CFLAGS_FOR_BUILD)
3243 AC_SUBST(CXXFLAGS_FOR_BUILD)
3244 AC_SUBST(CXX_FOR_BUILD)
3245 AC_SUBST(DLLTOOL_FOR_BUILD)
3246 AC_SUBST(GCJ_FOR_BUILD)
3247 AC_SUBST(GFORTRAN_FOR_BUILD)
3248 AC_SUBST(GOC_FOR_BUILD)
3249 AC_SUBST(LDFLAGS_FOR_BUILD)
3250 AC_SUBST(LD_FOR_BUILD)
3251 AC_SUBST(NM_FOR_BUILD)
3252 AC_SUBST(RANLIB_FOR_BUILD)
3253 AC_SUBST(WINDMC_FOR_BUILD)
3254 AC_SUBST(WINDRES_FOR_BUILD)
3255
3256 # Generate default definitions for YACC, M4, LEX and other programs that run
3257 # on the build machine.  These are used if the Makefile can't locate these
3258 # programs in objdir.
3259 MISSING=`cd $ac_aux_dir && ${PWDCMD-pwd}`/missing
3260
3261 AC_CHECK_PROGS([YACC], ['bison -y' byacc yacc], [$MISSING bison -y])
3262 case " $build_configdirs " in
3263   *" bison "*) YACC='$$r/$(BUILD_SUBDIR)/bison/tests/bison -y' ;;
3264 esac
3265
3266 AC_CHECK_PROGS([BISON], [bison], [$MISSING bison])
3267 case " $build_configdirs " in
3268   *" bison "*) BISON='$$r/$(BUILD_SUBDIR)/bison/tests/bison' ;;
3269 esac
3270
3271 AC_CHECK_PROGS([M4], [gm4 gnum4 m4], [$MISSING m4])
3272 case " $build_configdirs " in
3273   *" m4 "*) M4='$$r/$(BUILD_SUBDIR)/m4/m4' ;;
3274 esac
3275
3276 AC_CHECK_PROGS([LEX], [flex lex], [$MISSING flex])
3277 case " $build_configdirs " in
3278   *" flex "*) LEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3279   *" lex "*) LEX='$$r/$(BUILD_SUBDIR)/lex/lex' ;;
3280 esac
3281
3282 AC_CHECK_PROGS([FLEX], [flex], [$MISSING flex])
3283 case " $build_configdirs " in
3284   *" flex "*) FLEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3285 esac
3286
3287 AC_CHECK_PROGS([MAKEINFO], makeinfo, [$MISSING makeinfo])
3288 case " $build_configdirs " in
3289   *" texinfo "*) MAKEINFO='$$r/$(BUILD_SUBDIR)/texinfo/makeinfo/makeinfo' ;;
3290   *)
3291 changequote(,)
3292     # For an installed makeinfo, we require it to be from texinfo 4.7 or
3293     # higher, else we use the "missing" dummy.
3294     if ${MAKEINFO} --version \
3295        | egrep 'texinfo[^0-9]*(4\.([7-9]|[1-9][0-9])|[5-9]|[1-9][0-9])' >/dev/null 2>&1; then
3296       :
3297     else
3298       MAKEINFO="$MISSING makeinfo"
3299     fi
3300     ;;
3301 changequote([,])
3302 esac
3303
3304 # FIXME: expect and dejagnu may become build tools?
3305
3306 AC_CHECK_PROGS(EXPECT, expect, expect)
3307 case " $configdirs " in
3308   *" expect "*)
3309     test $host = $build && EXPECT='$$r/$(HOST_SUBDIR)/expect/expect'
3310     ;;
3311 esac
3312
3313 AC_CHECK_PROGS(RUNTEST, runtest, runtest)
3314 case " $configdirs " in
3315   *" dejagnu "*)
3316     test $host = $build && RUNTEST='$$s/$(HOST_SUBDIR)/dejagnu/runtest'
3317     ;;
3318 esac
3319
3320
3321 # Host tools.
3322 NCN_STRICT_CHECK_TOOLS(AR, ar)
3323 NCN_STRICT_CHECK_TOOLS(AS, as)
3324 NCN_STRICT_CHECK_TOOLS(DLLTOOL, dlltool)
3325 NCN_STRICT_CHECK_TOOLS(LD, ld)
3326 NCN_STRICT_CHECK_TOOLS(LIPO, lipo)
3327 NCN_STRICT_CHECK_TOOLS(NM, nm)
3328 NCN_STRICT_CHECK_TOOLS(RANLIB, ranlib, true)
3329 NCN_STRICT_CHECK_TOOLS(STRIP, strip, true)
3330 NCN_STRICT_CHECK_TOOLS(WINDRES, windres)
3331 NCN_STRICT_CHECK_TOOLS(WINDMC, windmc)
3332 NCN_STRICT_CHECK_TOOLS(OBJCOPY, objcopy)
3333 NCN_STRICT_CHECK_TOOLS(OBJDUMP, objdump)
3334 NCN_STRICT_CHECK_TOOLS(READELF, readelf)
3335 AC_SUBST(CC)
3336 AC_SUBST(CXX)
3337 AC_SUBST(CFLAGS)
3338 AC_SUBST(CXXFLAGS)
3339
3340 # Target tools.
3341 AC_ARG_WITH([build-time-tools],
3342   [AS_HELP_STRING([--with-build-time-tools=PATH],
3343                   [use given path to find target tools during the build])],
3344   [case x"$withval" in
3345      x/*) ;;
3346      *)
3347        with_build_time_tools=
3348        AC_MSG_WARN([argument to --with-build-time-tools must be an absolute path])
3349        ;;
3350    esac],
3351   [with_build_time_tools=])
3352
3353 NCN_STRICT_CHECK_TARGET_TOOLS(CC_FOR_TARGET, cc gcc)
3354 NCN_STRICT_CHECK_TARGET_TOOLS(CXX_FOR_TARGET, c++ g++ cxx gxx)
3355 NCN_STRICT_CHECK_TARGET_TOOLS(GCC_FOR_TARGET, gcc, ${CC_FOR_TARGET})
3356 NCN_STRICT_CHECK_TARGET_TOOLS(GCJ_FOR_TARGET, gcj)
3357 NCN_STRICT_CHECK_TARGET_TOOLS(GFORTRAN_FOR_TARGET, gfortran)
3358 NCN_STRICT_CHECK_TARGET_TOOLS(GOC_FOR_TARGET, gccgo)
3359
3360 ACX_CHECK_INSTALLED_TARGET_TOOL(AR_FOR_TARGET, ar)
3361 ACX_CHECK_INSTALLED_TARGET_TOOL(AS_FOR_TARGET, as)
3362 ACX_CHECK_INSTALLED_TARGET_TOOL(DLLTOOL_FOR_TARGET, dlltool)
3363 ACX_CHECK_INSTALLED_TARGET_TOOL(LD_FOR_TARGET, ld)
3364 ACX_CHECK_INSTALLED_TARGET_TOOL(LIPO_FOR_TARGET, lipo)
3365 ACX_CHECK_INSTALLED_TARGET_TOOL(NM_FOR_TARGET, nm)
3366 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJCOPY_FOR_TARGET, objcopy)
3367 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJDUMP_FOR_TARGET, objdump)
3368 ACX_CHECK_INSTALLED_TARGET_TOOL(RANLIB_FOR_TARGET, ranlib)
3369 ACX_CHECK_INSTALLED_TARGET_TOOL(READELF_FOR_TARGET, readelf)
3370 ACX_CHECK_INSTALLED_TARGET_TOOL(STRIP_FOR_TARGET, strip)
3371 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDRES_FOR_TARGET, windres)
3372 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDMC_FOR_TARGET, windmc)
3373
3374 RAW_CXX_FOR_TARGET="$CXX_FOR_TARGET"
3375
3376 GCC_TARGET_TOOL(ar, AR_FOR_TARGET, AR, [binutils/ar])
3377 GCC_TARGET_TOOL(as, AS_FOR_TARGET, AS, [gas/as-new])
3378 GCC_TARGET_TOOL(cc, CC_FOR_TARGET, CC, [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3379 dnl see comments for CXX_FOR_TARGET_FLAG_TO_PASS
3380 GCC_TARGET_TOOL(c++, CXX_FOR_TARGET, CXX,
3381                 [gcc/xg++ -B$$r/$(HOST_SUBDIR)/gcc/ -nostdinc++ `if test -f $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags; then $(SHELL) $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags --build-includes; else echo -funconfigured-libstdc++-v3 ; fi` -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs],
3382                 c++)
3383 GCC_TARGET_TOOL(c++ for libstdc++, RAW_CXX_FOR_TARGET, CXX,
3384                 [gcc/xgcc -shared-libgcc -B$$r/$(HOST_SUBDIR)/gcc -nostdinc++ -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs],
3385                 c++)
3386 GCC_TARGET_TOOL(dlltool, DLLTOOL_FOR_TARGET, DLLTOOL, [binutils/dlltool])
3387 GCC_TARGET_TOOL(gcc, GCC_FOR_TARGET, , [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3388 GCC_TARGET_TOOL(gcj, GCJ_FOR_TARGET, GCJ,
3389                 [gcc/gcj -B$$r/$(HOST_SUBDIR)/gcc/], java)
3390 GCC_TARGET_TOOL(gfortran, GFORTRAN_FOR_TARGET, GFORTRAN,
3391                 [gcc/gfortran -B$$r/$(HOST_SUBDIR)/gcc/], fortran)
3392 GCC_TARGET_TOOL(gccgo, GOC_FOR_TARGET, GOC,
3393                 [gcc/gccgo -B$$r/$(HOST_SUBDIR)/gcc/], go)
3394 GCC_TARGET_TOOL(ld, LD_FOR_TARGET, LD, [ld/ld-new])
3395 GCC_TARGET_TOOL(lipo, LIPO_FOR_TARGET, LIPO)
3396 GCC_TARGET_TOOL(nm, NM_FOR_TARGET, NM, [binutils/nm-new])
3397 GCC_TARGET_TOOL(objcopy, OBJCOPY_FOR_TARGET, OBJCOPY, [binutils/objcopy])
3398 GCC_TARGET_TOOL(objdump, OBJDUMP_FOR_TARGET, OBJDUMP, [binutils/objdump])
3399 GCC_TARGET_TOOL(ranlib, RANLIB_FOR_TARGET, RANLIB, [binutils/ranlib])
3400 GCC_TARGET_TOOL(readelf, READELF_FOR_TARGET, READELF, [binutils/readelf])
3401 GCC_TARGET_TOOL(strip, STRIP_FOR_TARGET, STRIP, [binutils/strip-new])
3402 GCC_TARGET_TOOL(windres, WINDRES_FOR_TARGET, WINDRES, [binutils/windres])
3403 GCC_TARGET_TOOL(windmc, WINDMC_FOR_TARGET, WINDMC, [binutils/windmc])
3404
3405 AC_SUBST(FLAGS_FOR_TARGET)
3406 AC_SUBST(RAW_CXX_FOR_TARGET)
3407
3408 # Certain tools may need extra flags.
3409 AR_FOR_TARGET=${AR_FOR_TARGET}${extra_arflags_for_target}
3410 RANLIB_FOR_TARGET=${RANLIB_FOR_TARGET}${extra_ranlibflags_for_target}
3411 NM_FOR_TARGET=${NM_FOR_TARGET}${extra_nmflags_for_target}
3412
3413 # When building target libraries, except in a Canadian cross, we use
3414 # the same toolchain as the compiler we just built.
3415 COMPILER_AS_FOR_TARGET='$(AS_FOR_TARGET)'
3416 COMPILER_LD_FOR_TARGET='$(LD_FOR_TARGET)'
3417 COMPILER_NM_FOR_TARGET='$(NM_FOR_TARGET)'
3418 if test $host = $build; then
3419   case " $configdirs " in
3420     *" gcc "*)
3421       COMPILER_AS_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/as'
3422       COMPILER_LD_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/collect-ld'
3423       COMPILER_NM_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/nm'${extra_nmflags_for_target}
3424       ;;
3425   esac
3426 fi
3427
3428 AC_SUBST(COMPILER_AS_FOR_TARGET)
3429 AC_SUBST(COMPILER_LD_FOR_TARGET)
3430 AC_SUBST(COMPILER_NM_FOR_TARGET)
3431
3432 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3433 AC_ARG_ENABLE(maintainer-mode,
3434 [AS_HELP_STRING([--enable-maintainer-mode],
3435                 [enable make rules and dependencies not useful
3436                  (and sometimes confusing) to the casual installer])],
3437       USE_MAINTAINER_MODE=$enableval,
3438       USE_MAINTAINER_MODE=no)
3439 AC_MSG_RESULT($USE_MAINTAINER_MODE)
3440 AC_SUBST(MAINTAINER_MODE_TRUE)
3441 AC_SUBST(MAINTAINER_MODE_FALSE)
3442 if test "$USE_MAINTAINER_MODE" = yes; then
3443   MAINTAINER_MODE_TRUE=
3444   MAINTAINER_MODE_FALSE='#'
3445 else
3446   MAINTAINER_MODE_TRUE='#'
3447   MAINTAINER_MODE_FALSE=
3448 fi
3449 MAINT=$MAINTAINER_MODE_TRUE
3450 AC_SUBST(MAINT)dnl
3451
3452 # ---------------------
3453 # GCC bootstrap support
3454 # ---------------------
3455
3456 # Stage specific cflags for build.
3457 stage1_cflags="-g"
3458 case $build in
3459   vax-*-*)
3460     case ${GCC} in
3461       yes) stage1_cflags="-g -Wa,-J" ;;
3462       *) stage1_cflags="-g -J" ;;
3463     esac ;;
3464 esac
3465
3466 AC_SUBST(stage1_cflags)
3467
3468 # Enable --enable-checking in stage1 of the compiler.
3469 AC_ARG_ENABLE(stage1-checking,
3470 [AS_HELP_STRING([[--enable-stage1-checking[=all]]],
3471                 [choose additional checking for stage1 of the compiler])],
3472 [stage1_checking=--enable-checking=${enable_stage1_checking}],
3473 [if test "x$enable_checking" = xno || test "x$enable_checking" = x; then
3474   stage1_checking=--enable-checking=yes,types
3475 else
3476   stage1_checking=--enable-checking=$enable_checking,types
3477 fi])
3478 AC_SUBST(stage1_checking)
3479
3480 # Enable -Werror in bootstrap stage2 and later.
3481 AC_ARG_ENABLE(werror,
3482 [AS_HELP_STRING([--enable-werror],
3483                 [enable -Werror in bootstrap stage2 and later])], [],
3484 [if test -d ${srcdir}/gcc && test x"`cat $srcdir/gcc/DEV-PHASE`" = xexperimental; then
3485   enable_werror=yes
3486 else
3487   enable_werror=no
3488 fi])
3489 case ${enable_werror} in
3490   yes) stage2_werror_flag="--enable-werror-always" ;;
3491   *) stage2_werror_flag="" ;;
3492 esac
3493 AC_SUBST(stage2_werror_flag)
3494
3495 # Enable --enable-host-shared.
3496 AC_ARG_ENABLE(host-shared,
3497 [AS_HELP_STRING([--enable-host-shared],
3498                 [build host code as shared libraries])],
3499 [host_shared=$enableval], [host_shared=no])
3500 AC_SUBST(host_shared)
3501
3502 # PR jit/64780: Require the user to explicitly specify
3503 # --enable-host-shared if the jit is enabled, hinting
3504 # that they might want to do a separate configure/build of
3505 # the jit, to avoid users from slowing down the rest of the
3506 # compiler by enabling the jit.
3507 if test ${host_shared} = "no" ; then
3508   case "${enable_languages}" in
3509     *jit*)
3510       AC_MSG_ERROR([
3511 Enabling language "jit" requires --enable-host-shared.
3512
3513 --enable-host-shared typically slows the rest of the compiler down by
3514 a few %, so you must explicitly enable it.
3515
3516 If you want to build both the jit and the regular compiler, it is often
3517 best to do this via two separate configure/builds, in separate
3518 directories, to avoid imposing the performance cost of
3519 --enable-host-shared on the regular compiler.])
3520       ;;
3521     *)
3522       ;;
3523   esac
3524 fi
3525
3526 # Specify what files to not compare during bootstrap.
3527
3528 compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/*"
3529 case "$target" in
3530   hppa*64*-*-hpux*) ;;
3531   hppa*-*-hpux*) compare_exclusions="gcc/cc*-checksum\$(objext) | */libgcc/lib2funcs* | gcc/ada/*tools/*" ;;
3532   powerpc*-ibm-aix*) compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/* | *libgomp*\$(objext)" ;;
3533 esac
3534 AC_SUBST(compare_exclusions)
3535
3536 AC_CONFIG_FILES([Makefile],
3537   [sed "$extrasub_build" Makefile |
3538    sed "$extrasub_host" |
3539    sed "$extrasub_target" > mf$$
3540    mv -f mf$$ Makefile],
3541   [extrasub_build="$extrasub_build"
3542    extrasub_host="$extrasub_host"
3543    extrasub_target="$extrasub_target"])
3544 AC_OUTPUT