configure.ac

   1 #  Copyright 2005 Adam Jackson.
   2 #
   3 #  Permission is hereby granted, free of charge, to any person obtaining a
   4 #  copy of this software and associated documentation files (the "Software"),
   5 #  to deal in the Software without restriction, including without limitation
   6 #  on the rights to use, copy, modify, merge, publish, distribute, sub
   7 #  license, and/or sell copies of the Software, and to permit persons to whom
   8 #  the Software is furnished to do so, subject to the following conditions:
   9 #
  10 #  The above copyright notice and this permission notice (including the next
  11 #  paragraph) shall be included in all copies or substantial portions of the
  12 #  Software.
  13 #
  14 #  THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  15 #  IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  16 #  FITNESS FOR A PARTICULAR PURPOSE AND NON-INFRINGEMENT.  IN NO EVENT SHALL
  17 #  ADAM JACKSON BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER
  18 #  IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
  19 #  CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
  20
  21 AC_PREREQ([2.63])
  22 AC_INIT([libdrm],
  23         [2.4.66],
  24         [https://bugs.freedesktop.org/enter_bug.cgi?product=DRI],
  25         [libdrm])
  26
  27 AC_CONFIG_HEADERS([config.h])
  28 AC_CONFIG_SRCDIR([Makefile.am])
  29 AC_CONFIG_MACRO_DIR([m4])
  30 AC_CONFIG_AUX_DIR([build-aux])
  31
  32 # Require xorg-macros minimum of 1.12 for XORG_WITH_XSLTPROC
  33 m4_ifndef([XORG_MACROS_VERSION],
  34           [m4_fatal([must install xorg-macros 1.12 or later before running autoconf/autogen])])
  35 XORG_MACROS_VERSION(1.12)
  36 XORG_WITH_XSLTPROC
  37 XORG_MANPAGE_SECTIONS
  38
  39 AM_INIT_AUTOMAKE([1.10 foreign dist-bzip2])
  40
  41 # Enable quiet compiles on automake 1.11.
  42 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  43
  44 # Check for programs
  45 AC_PROG_CC
  46 AC_PROG_CC_C99
  47
  48 if test "x$ac_cv_prog_cc_c99" = xno; then
  49         AC_MSG_ERROR([Building libdrm requires C99 enabled compiler])
  50 fi
  51
  52 AC_USE_SYSTEM_EXTENSIONS
  53 AC_SYS_LARGEFILE
  54 AC_FUNC_ALLOCA
  55
  56 AC_CHECK_HEADERS([sys/mkdev.h sys/sysctl.h])
  57
  58 # Initialize libtool
  59 LT_PREREQ([2.2])
  60 LT_INIT([disable-static])
  61
  62
  63 PKG_CHECK_MODULES(PTHREADSTUBS, pthread-stubs)
  64 AC_SUBST(PTHREADSTUBS_CFLAGS)
  65 AC_SUBST(PTHREADSTUBS_LIBS)
  66
  67 pkgconfigdir=${libdir}/pkgconfig
  68 AC_SUBST(pkgconfigdir)
  69 AC_ARG_ENABLE([udev],
  70               [AS_HELP_STRING([--enable-udev],
  71                               [Enable support for using udev instead of mknod (default: disabled)])],
  72               [UDEV=$enableval], [UDEV=no])
  73
  74 AC_ARG_ENABLE(libkms,
  75               AS_HELP_STRING([--disable-libkms],
  76               [Disable KMS mm abstraction library (default: auto, enabled on supported platforms)]),
  77               [LIBKMS=$enableval], [LIBKMS=auto])
  78
  79 AC_ARG_ENABLE(intel,
  80               AS_HELP_STRING([--disable-intel],
  81               [Enable support for intel's KMS API (default: auto, enabled on x86)]),
  82               [INTEL=$enableval], [INTEL=auto])
  83
  84 AC_ARG_ENABLE(radeon,
  85               AS_HELP_STRING([--disable-radeon],
  86               [Enable support for radeon's KMS API (default: auto)]),
  87               [RADEON=$enableval], [RADEON=auto])
  88
  89 AC_ARG_ENABLE(amdgpu,
  90               AS_HELP_STRING([--disable-amdgpu],
  91               [Enable support for amdgpu's KMS API (default: auto)]),
  92               [AMDGPU=$enableval], [AMDGPU=auto])
  93
  94 AC_ARG_ENABLE(nouveau,
  95               AS_HELP_STRING([--disable-nouveau],
  96               [Enable support for nouveau's KMS API (default: auto)]),
  97               [NOUVEAU=$enableval], [NOUVEAU=auto])
  98
  99 AC_ARG_ENABLE(vmwgfx,
 100               AS_HELP_STRING([--disable-vmwgfx],
 101               [Enable support for vmwgfx's KMS API (default: yes)]),
 102               [VMWGFX=$enableval], [VMWGFX=yes])
 103
 104 AC_ARG_ENABLE(omap-experimental-api,
 105               AS_HELP_STRING([--enable-omap-experimental-api],
 106               [Enable support for OMAP's experimental API (default: disabled)]),
 107               [OMAP=$enableval], [OMAP=no])
 108
 109 AC_ARG_ENABLE(exynos-experimental-api,
 110               AS_HELP_STRING([--enable-exynos-experimental-api],
 111               [Enable support for EXYNOS's experimental API (default: disabled)]),
 112               [EXYNOS=$enableval], [EXYNOS=no])
 113
 114 AC_ARG_ENABLE(freedreno,
 115               AS_HELP_STRING([--disable-freedreno],
 116               [Enable support for freedreno's KMS API (default: auto, enabled on arm)]),
 117               [FREEDRENO=$enableval], [FREEDRENO=auto])
 118
 119 AC_ARG_ENABLE(freedreno-kgsl,
 120               AS_HELP_STRING([--enable-freedreno-kgsl],
 121               [Enable support for freedreno's to use downstream android kernel API (default: disabled)]),
 122               [FREEDRENO_KGSL=$enableval], [FREEDRENO_KGSL=no])
 123
 124 AC_ARG_ENABLE(tegra-experimental-api,
 125               AS_HELP_STRING([--enable-tegra-experimental-api],
 126               [Enable support for Tegra's experimental API (default: disabled)]),
 127               [TEGRA=$enableval], [TEGRA=no])
 128
 129 AC_ARG_ENABLE(install-test-programs,
 130                   AS_HELP_STRING([--enable-install-test-programs],
 131                   [Install test programs (default: no)]),
 132                   [INSTALL_TESTS=$enableval], [INSTALL_TESTS=no])
 133
 134 dnl ===========================================================================
 135 dnl check compiler flags
 136 AC_DEFUN([LIBDRM_CC_TRY_FLAG], [
 137   AC_MSG_CHECKING([whether $CC supports $1])
 138
 139   libdrm_save_CFLAGS="$CFLAGS"
 140   CFLAGS="$CFLAGS $1"
 141
 142   AC_COMPILE_IFELSE([AC_LANG_SOURCE([ ])], [libdrm_cc_flag=yes], [libdrm_cc_flag=no])
 143   CFLAGS="$libdrm_save_CFLAGS"
 144
 145   if test "x$libdrm_cc_flag" = "xyes"; then
 146     ifelse([$2], , :, [$2])
 147   else
 148     ifelse([$3], , :, [$3])
 149   fi
 150   AC_MSG_RESULT([$libdrm_cc_flag])
 151 ])
 152
 153 dnl We use clock_gettime to check for timeouts in drmWaitVBlank
 154
 155 AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 156                [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 157                              [AC_MSG_ERROR([Couldn't find clock_gettime])])])
 158 AC_SUBST([CLOCK_LIB])
 159
 160 AC_CHECK_FUNCS([open_memstream], [HAVE_OPEN_MEMSTREAM=yes])
 161
 162 dnl Use lots of warning flags with with gcc and compatible compilers
 163
 164 dnl Note: if you change the following variable, the cache is automatically
 165 dnl skipped and all flags rechecked.  So there's no need to do anything
 166 dnl else.  If for any reason you need to force a recheck, just change
 167 dnl MAYBE_WARN in an ignorable way (like adding whitespace)
 168
 169 MAYBE_WARN="-Wall -Wextra \
 170 -Wsign-compare -Werror-implicit-function-declaration \
 171 -Wpointer-arith -Wwrite-strings -Wstrict-prototypes \
 172 -Wmissing-prototypes -Wmissing-declarations -Wnested-externs \
 173 -Wpacked -Wswitch-enum -Wmissing-format-attribute \
 174 -Wstrict-aliasing=2 -Winit-self \
 175 -Wdeclaration-after-statement -Wold-style-definition \
 176 -Wno-unused-parameter \
 177 -Wno-attributes -Wno-long-long -Winline -Wshadow \
 178 -Wno-missing-field-initializers"
 179
 180 # invalidate cached value if MAYBE_WARN has changed
 181 if test "x$libdrm_cv_warn_maybe" != "x$MAYBE_WARN"; then
 182         unset libdrm_cv_warn_cflags
 183 fi
 184 AC_CACHE_CHECK([for supported warning flags], libdrm_cv_warn_cflags, [
 185         echo
 186         WARN_CFLAGS=""
 187
 188         # Some warning options are not supported by all versions of
 189         # gcc, so test all desired options against the current
 190         # compiler.
 191         #
 192         # Note that there are some order dependencies
 193         # here. Specifically, an option that disables a warning will
 194         # have no net effect if a later option then enables that
 195         # warnings, (perhaps implicitly). So we put some grouped
 196         # options (-Wall and -Wextra) up front and the -Wno options
 197         # last.
 198
 199         for W in $MAYBE_WARN; do
 200                 LIBDRM_CC_TRY_FLAG([$W], [WARN_CFLAGS="$WARN_CFLAGS $W"])
 201         done
 202
 203         libdrm_cv_warn_cflags=$WARN_CFLAGS
 204         libdrm_cv_warn_maybe=$MAYBE_WARN
 205
 206         AC_MSG_CHECKING([which warning flags were supported])])
 207 WARN_CFLAGS="$libdrm_cv_warn_cflags"
 208
 209 # Check for atomic intrinsics
 210 AC_CACHE_CHECK([for native atomic primitives], drm_cv_atomic_primitives, [
 211         drm_cv_atomic_primitives="none"
 212
 213         AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 214         int atomic_add(int *i) { return __sync_add_and_fetch (i, 1); }
 215         int atomic_cmpxchg(int *i, int j, int k) { return __sync_val_compare_and_swap (i, j, k); }
 216                                           ]],[[]])], [drm_cv_atomic_primitives="Intel"],[])
 217
 218         if test "x$drm_cv_atomic_primitives" = "xnone"; then
 219                 AC_CHECK_HEADER([atomic_ops.h], drm_cv_atomic_primitives="libatomic-ops")
 220         fi
 221
 222         # atomic functions defined in <atomic.h> & libc on Solaris
 223         if test "x$drm_cv_atomic_primitives" = "xnone"; then
 224                 AC_CHECK_FUNC([atomic_cas_uint], drm_cv_atomic_primitives="Solaris")
 225         fi
 226 ])
 227
 228 if test "x$drm_cv_atomic_primitives" = xIntel; then
 229         AC_DEFINE(HAVE_LIBDRM_ATOMIC_PRIMITIVES, 1,
 230                 [Enable if your compiler supports the Intel __sync_* atomic primitives])
 231 fi
 232 if test "x$drm_cv_atomic_primitives" = "xlibatomic-ops"; then
 233         AC_DEFINE(HAVE_LIB_ATOMIC_OPS, 1, [Enable if you have libatomic-ops-dev installed])
 234 fi
 235
 236 dnl Print out the approapriate message considering the value set be the
 237 dnl respective in $1.
 238 dnl $1 - value to be evaluated. Eg. $INTEL, $NOUVEAU, ...
 239 dnl $2 - libdrm shortname. Eg. intel, freedreno, ...
 240 dnl $3 - GPU name/brand. Eg. Intel, NVIDIA Tegra, ...
 241 dnl $4 - Configure switch. Eg. intel, omap-experimental-api, ...
 242 AC_DEFUN([LIBDRM_ATOMICS_NOT_FOUND_MSG], [
 243         case "x$1" in
 244                 xyes)   AC_MSG_ERROR([libdrm_$2 depends upon atomic operations, which were not found for your compiler/cpu. Try compiling with -march=native, or install the libatomics-op-dev package, or, failing both of those, disable support for $3 GPUs by passing --disable-$4 to ./configure]) ;;
 245                 xauto)  AC_MSG_WARN([Disabling $2. It depends on atomic operations, which were not found for your compiler/cpu. Try compiling with -march=native, or install the libatomics-op-dev package.]) ;;
 246                 *)      ;;
 247         esac
 248 ])
 249
 250 if test "x$drm_cv_atomic_primitives" = "xnone"; then
 251         LIBDRM_ATOMICS_NOT_FOUND_MSG($INTEL, intel, Intel, intel)
 252         INTEL=no
 253
 254         LIBDRM_ATOMICS_NOT_FOUND_MSG($RADEON, radeon, Radeon, radeon)
 255         RADEON=no
 256
 257         LIBDRM_ATOMICS_NOT_FOUND_MSG($AMDGPU, amdgpu, AMD, amdgpu)
 258         AMDGPU=no
 259
 260         LIBDRM_ATOMICS_NOT_FOUND_MSG($NOUVEAU, nouveau, NVIDIA, nouveau)
 261         NOUVEAU=no
 262
 263         LIBDRM_ATOMICS_NOT_FOUND_MSG($OMAP, omap, OMAP, omap-experimental-api)
 264         OMAP=no
 265
 266         LIBDRM_ATOMICS_NOT_FOUND_MSG($FREEDRENO, freedreno, Qualcomm Adreno, freedreno)
 267         FREEDRENO=no
 268
 269         LIBDRM_ATOMICS_NOT_FOUND_MSG($TEGRA, tegra, NVIDIA Tegra, tegra-experimental-api)
 270         TEGRA=no
 271 else
 272         if test "x$INTEL" = xauto; then
 273                 case $host_cpu in
 274                         i?86|x86_64)    INTEL=yes ;;
 275                         *)              INTEL=no ;;
 276                 esac
 277         fi
 278         if test "x$RADEON" = xauto; then
 279                 RADEON=yes
 280         fi
 281         if test "x$AMDGPU" = xauto; then
 282                 AMDGPU=yes
 283         fi
 284         if test "x$NOUVEAU" = xauto; then
 285                 NOUVEAU=yes
 286         fi
 287         if test "x$FREEDRENO" = xauto; then
 288                 case $host_cpu in
 289                         arm*|aarch64)   FREEDRENO=yes ;;
 290                         *)              FREEDRENO=no ;;
 291                 esac
 292         fi
 293 fi
 294
 295 if test "x$INTEL" != "xno"; then
 296         PKG_CHECK_MODULES(PCIACCESS, [pciaccess >= 0.10])
 297 fi
 298 AC_SUBST(PCIACCESS_CFLAGS)
 299 AC_SUBST(PCIACCESS_LIBS)
 300
 301 if test "x$UDEV" = xyes; then
 302         AC_DEFINE(UDEV, 1, [Have UDEV support])
 303 fi
 304
 305 AC_CANONICAL_HOST
 306 if test "x$LIBKMS" = xauto ; then
 307         case $host_os in
 308                 linux*)         LIBKMS="yes" ;;
 309                 freebsd* | kfreebsd*-gnu)
 310                                 LIBKMS="yes" ;;
 311                 dragonfly*)     LIBKMS="yes" ;;
 312                 *)              LIBKMS="no" ;;
 313         esac
 314 fi
 315
 316 AM_CONDITIONAL(HAVE_LIBKMS, [test "x$LIBKMS" = xyes])
 317
 318 AM_CONDITIONAL(HAVE_INTEL, [test "x$INTEL" = xyes])
 319 if test "x$INTEL" = xyes; then
 320         AC_DEFINE(HAVE_INTEL, 1, [Have intel support])
 321 fi
 322
 323 AM_CONDITIONAL(HAVE_VMWGFX, [test "x$VMWGFX" = xyes])
 324 if test "x$VMWGFX" = xyes; then
 325         AC_DEFINE(HAVE_VMWGFX, 1, [Have vmwgfx kernel headers])
 326 fi
 327
 328 AM_CONDITIONAL(HAVE_NOUVEAU, [test "x$NOUVEAU" = xyes])
 329 if test "x$NOUVEAU" = xyes; then
 330         AC_DEFINE(HAVE_NOUVEAU, 1, [Have nouveau (nvidia) support])
 331 fi
 332
 333 AM_CONDITIONAL(HAVE_OMAP, [test "x$OMAP" = xyes])
 334 if test "x$OMAP" = xyes; then
 335         AC_DEFINE(HAVE_OMAP, 1, [Have OMAP support])
 336 fi
 337
 338 AM_CONDITIONAL(HAVE_EXYNOS, [test "x$EXYNOS" = xyes])
 339 if test "x$EXYNOS" = xyes; then
 340         AC_DEFINE(HAVE_EXYNOS, 1, [Have EXYNOS support])
 341 fi
 342
 343 AM_CONDITIONAL(HAVE_FREEDRENO, [test "x$FREEDRENO" = xyes])
 344 if test "x$FREEDRENO" = xyes; then
 345         AC_DEFINE(HAVE_FREEDRENO, 1, [Have freedreno support])
 346 fi
 347
 348 if test "x$FREEDRENO_KGSL" = xyes; then
 349         if test "x$FREEDRENO" != xyes; then
 350                 AC_MSG_ERROR([Cannot enable freedreno KGSL interface if freedreno is disabled])
 351         fi
 352 fi
 353 AM_CONDITIONAL(HAVE_FREEDRENO_KGSL, [test "x$FREEDRENO_KGSL" = xyes])
 354 if test "x$FREEDRENO_KGSL" = xyes; then
 355         AC_DEFINE(HAVE_FREEDRENO_KGSL, 1, [Have freedreno support for KGSL kernel interface])
 356 fi
 357
 358 AM_CONDITIONAL(HAVE_RADEON, [test "x$RADEON" = xyes])
 359 if test "x$RADEON" = xyes; then
 360         AC_DEFINE(HAVE_RADEON, 1, [Have radeon support])
 361 fi
 362
 363 # Detect cunit library
 364 PKG_CHECK_MODULES([CUNIT], [cunit >= 2.1], [have_cunit=yes], [have_cunit=no])
 365 # If pkg-config does not find cunit, check it using AC_CHECK_LIB.  We
 366 # do this because Debian (Ubuntu) lacks pkg-config file for cunit.
 367 # fixed in 2.1-2.dfsg-3: http://anonscm.debian.org/cgit/collab-maint/cunit.git/commit/?h=debian
 368 if test "x${have_cunit}" = "xno"; then
 369         AC_CHECK_LIB([cunit], [CU_initialize_registry], [have_cunit=yes], [have_cunit=no])
 370         if test "x${have_cunit}" = "xyes"; then
 371                 CUNIT_LIBS="-lcunit"
 372                 CUNIT_CFLAGS=""
 373                 AC_SUBST([CUNIT_LIBS])
 374                 AC_SUBST([CUNIT_CFLAGS])
 375         fi
 376 fi
 377 AM_CONDITIONAL(HAVE_CUNIT, [test "x$have_cunit" != "xno"])
 378
 379 AM_CONDITIONAL(HAVE_AMDGPU, [test "x$AMDGPU" = xyes])
 380 if test "x$AMDGPU" = xyes; then
 381         AC_DEFINE(HAVE_AMDGPU, 1, [Have amdgpu support])
 382
 383         AC_DEFINE(HAVE_CUNIT, [test "x$have_cunit" != "xno"], [Enable CUNIT Have amdgpu support])
 384
 385         if test "x$have_cunit" = "xno"; then
 386                 AC_MSG_WARN([Could not find cunit library. Disabling amdgpu tests])
 387         fi
 388 fi
 389
 390 AM_CONDITIONAL(HAVE_TEGRA, [test "x$TEGRA" = xyes])
 391 if test "x$TEGRA" = xyes; then
 392         AC_DEFINE(HAVE_TEGRA, 1, [Have Tegra support])
 393 fi
 394
 395 AM_CONDITIONAL(HAVE_INSTALL_TESTS, [test "x$INSTALL_TESTS" = xyes])
 396 if test "x$INSTALL_TESTS" = xyes; then
 397         AC_DEFINE(HAVE_INSTALL_TESTS, 1, [Install test programs])
 398 fi
 399
 400 AC_ARG_ENABLE([cairo-tests],
 401               [AS_HELP_STRING([--enable-cairo-tests],
 402                               [Enable support for Cairo rendering in tests (default: auto)])],
 403               [CAIRO=$enableval], [CAIRO=auto])
 404 PKG_CHECK_MODULES(CAIRO, cairo, [HAVE_CAIRO=yes], [HAVE_CAIRO=no])
 405 AC_MSG_CHECKING([whether to enable Cairo tests])
 406 if test "x$CAIRO" = xauto; then
 407         CAIRO="$HAVE_CAIRO"
 408 fi
 409 if test "x$CAIRO" = xyes; then
 410         if ! test "x$HAVE_CAIRO" = xyes; then
 411                 AC_MSG_ERROR([Cairo support required but not present])
 412         fi
 413         AC_DEFINE(HAVE_CAIRO, 1, [Have Cairo support])
 414 fi
 415 AC_MSG_RESULT([$CAIRO])
 416 AM_CONDITIONAL(HAVE_CAIRO, [test "x$CAIRO" = xyes])
 417
 418 # For enumerating devices in test case
 419 PKG_CHECK_MODULES(LIBUDEV, libudev, [HAVE_LIBUDEV=yes], [HAVE_LIBUDEV=no])
 420 if test "x$HAVE_LIBUDEV" = xyes; then
 421         AC_DEFINE(HAVE_LIBUDEV, 1, [Have libudev support])
 422 fi
 423 AM_CONDITIONAL(HAVE_LIBUDEV, [test "x$HAVE_LIBUDEV" = xyes])
 424
 425 # xsltproc for docbook manpages
 426 AC_ARG_ENABLE([manpages],
 427               AS_HELP_STRING([--enable-manpages], [enable manpages @<:@default=auto@:>@]),
 428               [MANS=$enableval], [MANS=auto])
 429 AM_CONDITIONAL([BUILD_MANPAGES], [test "x$XSLTPROC" != "x" -a "x$MANS" != "xno"])
 430
 431 # check for offline man-pages stylesheet
 432 AC_MSG_CHECKING([for docbook manpages stylesheet])
 433 MANPAGES_STYLESHEET="http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl"
 434 AC_PATH_PROGS_FEATURE_CHECK([XSLTPROC_TMP], [xsltproc],
 435                             AS_IF([`"$ac_path_XSLTPROC_TMP" --nonet "$MANPAGES_STYLESHEET" > /dev/null 2>&1`],
 436                                   [HAVE_MANPAGES_STYLESHEET=yes]))
 437 if test "x$HAVE_MANPAGES_STYLESHEET" = "xyes"; then
 438         AC_SUBST(MANPAGES_STYLESHEET)
 439         AC_MSG_RESULT([yes])
 440 else
 441         AC_MSG_RESULT([no])
 442 fi
 443 AM_CONDITIONAL([HAVE_MANPAGES_STYLESHEET], [test "x$HAVE_MANPAGES_STYLESHEET" = "xyes"])
 444
 445 AC_ARG_ENABLE(valgrind,
 446               [AS_HELP_STRING([--enable-valgrind],
 447                              [Build libdrm with  valgrind support (default: auto)])],
 448                              [VALGRIND=$enableval], [VALGRIND=auto])
 449 PKG_CHECK_MODULES(VALGRIND, [valgrind], [have_valgrind=yes], [have_valgrind=no])
 450 AC_MSG_CHECKING([whether to enable Valgrind support])
 451 if test "x$VALGRIND" = xauto; then
 452         VALGRIND="$have_valgrind"
 453 fi
 454
 455 if test "x$VALGRIND" = "xyes"; then
 456         if ! test "x$have_valgrind" = xyes; then
 457                 AC_MSG_ERROR([Valgrind support required but not present])
 458         fi
 459         AC_DEFINE([HAVE_VALGRIND], 1, [Use valgrind intrinsics to suppress false warnings])
 460 fi
 461
 462 AC_MSG_RESULT([$VALGRIND])
 463
 464 AC_ARG_WITH([kernel-source],
 465             [AS_HELP_STRING([--with-kernel-source],
 466               [specify path to linux kernel source])],
 467             [kernel_source="$with_kernel_source"])
 468 AC_SUBST(kernel_source)
 469
 470 AC_MSG_CHECKING([whether $CC supports __attribute__(("hidden"))])
 471 AC_LINK_IFELSE([AC_LANG_PROGRAM([
 472     int foo_hidden( void ) __attribute__((visibility("hidden")));
 473 ])], HAVE_ATTRIBUTE_VISIBILITY="yes"; AC_MSG_RESULT([yes]), AC_MSG_RESULT([no]));
 474
 475 if test "x$HAVE_ATTRIBUTE_VISIBILITY" = xyes; then
 476     AC_DEFINE(HAVE_VISIBILITY, 1, [Compiler supports __attribute__(("hidden"))])
 477 fi
 478
 479 AC_SUBST(WARN_CFLAGS)
 480 AC_CONFIG_FILES([
 481         Makefile
 482         libkms/Makefile
 483         libkms/libkms.pc
 484         intel/Makefile
 485         intel/libdrm_intel.pc
 486         radeon/Makefile
 487         radeon/libdrm_radeon.pc
 488         amdgpu/Makefile
 489         amdgpu/libdrm_amdgpu.pc
 490         nouveau/Makefile
 491         nouveau/libdrm_nouveau.pc
 492         omap/Makefile
 493         omap/libdrm_omap.pc
 494         exynos/Makefile
 495         exynos/libdrm_exynos.pc
 496         freedreno/Makefile
 497         freedreno/libdrm_freedreno.pc
 498         tegra/Makefile
 499         tegra/libdrm_tegra.pc
 500         tests/Makefile
 501         tests/modeprint/Makefile
 502         tests/modetest/Makefile
 503         tests/kms/Makefile
 504         tests/kmstest/Makefile
 505         tests/proptest/Makefile
 506         tests/radeon/Makefile
 507         tests/amdgpu/Makefile
 508         tests/vbltest/Makefile
 509         tests/exynos/Makefile
 510         tests/tegra/Makefile
 511         tests/nouveau/Makefile
 512         tests/util/Makefile
 513         man/Makefile
 514         libdrm.pc])
 515 AC_OUTPUT
 516
 517 echo ""
 518 echo "$PACKAGE_STRING will be compiled with:"
 519 echo ""
 520 echo "  libkms         $LIBKMS"
 521 echo "  Intel API      $INTEL"
 522 echo "  vmwgfx API     $VMWGFX"
 523 echo "  Radeon API     $RADEON"
 524 echo "  AMDGPU API     $AMDGPU"
 525 echo "  Nouveau API    $NOUVEAU"
 526 echo "  OMAP API       $OMAP"
 527 echo "  EXYNOS API     $EXYNOS"
 528 echo "  Freedreno API  $FREEDRENO (kgsl: $FREEDRENO_KGSL)"
 529 echo "  Tegra API      $TEGRA"
 530 echo ""