configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Configure input file for elfutils.                     -*-autoconf-*-
   3 dnl
   4 dnl Copyright (C) 1996-2016 Red Hat, Inc.
   5 dnl
   6 dnl This file is part of elfutils.
   7 dnl
   8 dnl  This file is free software; you can redistribute it and/or modify
   9 dnl  it under the terms of the GNU General Public License as published by
  10 dnl  the Free Software Foundation; either version 3 of the License, or
  11 dnl  (at your option) any later version.
  12 dnl
  13 dnl  elfutils is distributed in the hope that it will be useful, but
  14 dnl  WITHOUT ANY WARRANTY; without even the implied warranty of
  15 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 dnl  GNU General Public License for more details.
  17 dnl
  18 dnl  You should have received a copy of the GNU General Public License
  19 dnl  along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20 AC_INIT([elfutils],[0.168],[https://sourceware.org/bugzilla],[elfutils],[http://elfutils.org/])
  21
  22 # We want eu- as default program prefix if none was given by the user.
  23 # But if the user explicitly provided --program-prefix="" then pretend
  24 # it wasn't set at all (NONE). We want to test this really early before
  25 # configure has a chance to use the value.
  26
  27 if test "x$program_prefix" = "xNONE"; then
  28   AC_MSG_NOTICE([No --program-prefix given, using "eu-"])
  29   program_prefix="eu-"
  30 elif test "x$program_prefix" = "x"; then
  31   AC_MSG_NOTICE([Using no program-prefix])
  32   program_prefix=NONE
  33 fi
  34
  35 AC_CONFIG_AUX_DIR([config])
  36 AC_CONFIG_FILES([config/Makefile])
  37
  38 AC_COPYRIGHT([Copyright (C) 1996-2016 The elfutils developers.])
  39 AC_PREREQ(2.63)                 dnl Minimum Autoconf version required.
  40
  41 dnl We use GNU make extensions; automake 1.10 defaults to -Wportability.
  42 AM_INIT_AUTOMAKE([gnits 1.11 -Wno-portability dist-bzip2 no-dist-gzip parallel-tests])
  43 AM_MAINTAINER_MODE
  44
  45 AM_SILENT_RULES([yes])
  46
  47 AC_CONFIG_SRCDIR([libelf/libelf.h])
  48 AC_CONFIG_FILES([Makefile])
  49 AC_CONFIG_HEADERS([config.h])
  50
  51 AC_CONFIG_MACRO_DIR([m4])
  52 AC_CONFIG_FILES([m4/Makefile])
  53
  54 dnl The RPM spec file.  We substitute a few values in the file.
  55 AC_CONFIG_FILES([elfutils.spec:config/elfutils.spec.in])
  56
  57
  58 AC_CANONICAL_HOST
  59
  60 AC_ARG_ENABLE(deterministic-archives,
  61 [AS_HELP_STRING([--enable-deterministic-archives],
  62                 [ar and ranlib default to -D behavior])], [
  63 if test "${enableval}" = no; then
  64   default_ar_deterministic=false
  65 else
  66   default_ar_deterministic=true
  67 fi], [default_ar_deterministic=false])
  68 AC_DEFINE_UNQUOTED(DEFAULT_AR_DETERMINISTIC, $default_ar_deterministic,
  69                    [Should ar and ranlib use -D behavior by default?])
  70
  71 AC_ARG_ENABLE([thread-safety],
  72 AS_HELP_STRING([--enable-thread-safety],
  73                [enable thread safety of libraries EXPERIMENTAL]),
  74                use_locks=$enableval, use_locks=no)
  75 AM_CONDITIONAL(USE_LOCKS, test "$use_locks" = yes)
  76 AS_IF([test "$use_locks" = yes], [AC_DEFINE(USE_LOCKS)])
  77 AS_IF([test "$use_locks" = yes],
  78       [AC_MSG_WARN([thread-safety is EXPERIMENTAL tests might fail.])])
  79
  80 AH_TEMPLATE([USE_LOCKS], [Defined if libraries should be thread-safe.])
  81
  82 AC_PROG_CC
  83 AC_PROG_RANLIB
  84 AC_PROG_YACC
  85 AM_PROG_LEX
  86 # Only available since automake 1.12
  87 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  88 AC_CHECK_TOOL([READELF], [readelf])
  89 AC_CHECK_TOOL([NM], [nm])
  90
  91 # We use -std=gnu99 but have explicit checks for some language constructs
  92 # and GNU extensions since some compilers claim GNU99 support, but don't
  93 # really support all language extensions. In particular we need
  94 # Mixed Declarations and Code
  95 # https://gcc.gnu.org/onlinedocs/gcc/Mixed-Declarations.html
  96 # Nested Functions
  97 # https://gcc.gnu.org/onlinedocs/gcc/Nested-Functions.html
  98 # Arrays of Variable Length
  99 # https://gcc.gnu.org/onlinedocs/gcc/Variable-Length.html
 100 AC_CACHE_CHECK([for gcc with GNU99 support], ac_cv_c99, [dnl
 101 old_CFLAGS="$CFLAGS"
 102 CFLAGS="$CFLAGS -std=gnu99"
 103 AC_COMPILE_IFELSE([AC_LANG_SOURCE([dnl
 104 int foo (int a)
 105 {
 106   for (int i = 0; i < a; ++i) if (i % 4) break; int s = a; return s;
 107 }
 108
 109 double bar (double a, double b)
 110 {
 111   double square (double z) { return z * z; }
 112   return square (a) + square (b);
 113 }
 114
 115 void baz (int n)
 116 {
 117   struct S { int x[[n]]; };
 118 }])],
 119                   ac_cv_c99=yes, ac_cv_c99=no)
 120 CFLAGS="$old_CFLAGS"])
 121 AS_IF([test "x$ac_cv_c99" != xyes],
 122       AC_MSG_ERROR([gcc with GNU99 support required]))
 123
 124 AC_CACHE_CHECK([for __thread support], ac_cv_tls, [dnl
 125 # Use the same flags that we use for our DSOs, so the test is representative.
 126 # Some old compiler/linker/libc combinations fail some ways and not others.
 127 save_CFLAGS="$CFLAGS"
 128 save_LDFLAGS="$LDFLAGS"
 129 CFLAGS="-fPIC $CFLAGS"
 130 LDFLAGS="-shared -Wl,-z,defs,-z,relro $LDFLAGS"
 131 AC_LINK_IFELSE([dnl
 132 AC_LANG_PROGRAM([[#include <stdlib.h>
 133 #undef __thread
 134 static __thread int a; int foo (int b) { return a + b; }]],
 135                 [[exit (foo (0));]])],
 136                ac_cv_tls=yes, ac_cv_tls=no)
 137 CFLAGS="$save_CFLAGS"
 138 LDFLAGS="$save_LDFLAGS"])
 139 AS_IF([test "x$ac_cv_tls" != xyes],
 140       AC_MSG_ERROR([__thread support required]))
 141
 142 dnl This test must come as early as possible after the compiler configuration
 143 dnl tests, because the choice of the file model can (in principle) affect
 144 dnl whether functions and headers are available, whether they work, etc.
 145 AC_SYS_LARGEFILE
 146
 147 dnl Older glibc had a broken fts that didn't work with Large File Systems.
 148 dnl We want the version that can handler LFS, but include workaround if we
 149 dnl get a bad one. Add define to CFLAGS (not AC_DEFINE it) since we need to
 150 dnl check it before including config.h (which might define _FILE_OFFSET_BITS).
 151 AC_CACHE_CHECK([whether fts.h is bad when included (with LFS)], ac_cv_bad_fts,
 152   [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[#include <fts.h>]])],
 153                      ac_cv_bad_fts=no, ac_cv_bad_fts=yes)])
 154 AS_IF([test "x$ac_cv_bad_fts" = "xyes"], [CFLAGS="$CFLAGS -DBAD_FTS=1"])
 155
 156 dnl enable debugging of branch prediction.
 157 AC_ARG_ENABLE([debugpred],
 158 AS_HELP_STRING([--enable-debugpred],[build binaries with support to debug branch prediction]),
 159 [use_debugpred=$enableval], [use_debugpred=no])
 160 case $use_debugpred in
 161  yes) use_debugpred_val=1 ;;
 162  *)   use_debugpred_val=0 ;;
 163 esac
 164 AC_SUBST([DEBUGPRED], $use_debugpred_val)
 165
 166 dnl Enable gprof suport.
 167 AC_ARG_ENABLE([gprof],
 168 AS_HELP_STRING([--enable-gprof],[build binaries with gprof support]), [use_gprof=$enableval], [use_gprof=no])
 169 if test "$use_gprof" = yes; then
 170   CFLAGS="$CFLAGS -pg"
 171   LDFLAGS="$LDFLAGS -pg"
 172 fi
 173 AM_CONDITIONAL(GPROF, test "$use_gprof" = yes)
 174
 175 # Enable gcov suport.
 176 AC_ARG_ENABLE([gcov],
 177 AS_HELP_STRING([--enable-gcov],[build binaries with gcov support]), [use_gcov=$enableval], [use_gcov=no])
 178 if test "$use_gcov" = yes; then
 179   CFLAGS="$CFLAGS -fprofile-arcs -ftest-coverage"
 180   LDFLAGS="$LDFLAGS -fprofile-arcs"
 181 fi
 182 AM_CONDITIONAL(GCOV, test "$use_gcov" = yes)
 183
 184 AC_ARG_ENABLE([sanitize-undefined],
 185               AS_HELP_STRING([--enable-sanitize-undefined],
 186                              [Use gcc undefined behaviour sanitizer]),
 187                              [use_undefined=$enableval], [use_undefined=no])
 188 if test "$use_undefined" = yes; then
 189   old_CFLAGS="$CFLAGS"
 190   old_CXXFLAGS="$CXXFLAGS"
 191   # We explicitly use unaligned access when possible (see ALLOW_UNALIGNED)
 192   # We want to fail immediately on first error, don't try to recover.
 193   CFLAGS="$CFLAGS -fsanitize=undefined -fno-sanitize-recover"
 194   CXXFLAGS="$CXXFLAGS -fsanitize=undefined -fno-sanitize-recover"
 195   AC_LINK_IFELSE([AC_LANG_SOURCE([int main (int argc, char **argv) { return 0; }])], use_undefined=yes, use_undefined=no)
 196   AS_IF([test "x$use_undefined" != xyes],
 197         AC_MSG_WARN([gcc undefined behaviour sanitizer not available])
 198         CFLAGS="$old_CFLAGS" CXXFLAGS="$old_CXXFLAGS")
 199 fi
 200 case $use_undefined in
 201  yes) check_undefined_val=1 ;;
 202  *)   check_undefined_val=0 ;;
 203 esac
 204 AC_DEFINE_UNQUOTED(CHECK_UNDEFINED, $check_undefined_val,
 205                    [Building with -fsanitize=undefined or not])
 206
 207 AC_ARG_ENABLE([valgrind],
 208 AS_HELP_STRING([--enable-valgrind],[run all tests under valgrind]),
 209 [use_valgrind=$enableval], [use_valgrind=no])
 210 if test "$use_valgrind" = yes; then
 211   AC_CHECK_PROG(HAVE_VALGRIND, valgrind, yes, no)
 212   if test "$HAVE_VALGRIND" = "no"; then
 213     AC_MSG_ERROR([valgrind not found])
 214   fi
 215 fi
 216 AM_CONDITIONAL(USE_VALGRIND, test "$use_valgrind" = yes)
 217
 218 AM_CONDITIONAL(BUILD_STATIC, [dnl
 219 test "$use_gprof" = yes -o "$use_gcov" = yes])
 220
 221 AC_ARG_ENABLE([tests-rpath],
 222 AS_HELP_STRING([--enable-tests-rpath],[build $ORIGIN-using rpath into tests]),
 223                [tests_use_rpath=$enableval], [tests_use_rpath=no])
 224 AM_CONDITIONAL(TESTS_RPATH, test "$tests_use_rpath" = yes)
 225
 226 LIBEBL_SUBDIR="$PACKAGE"
 227 AC_ARG_ENABLE([libebl-subdir],
 228 AS_HELP_STRING([--enable-libebl-subdir=DIR],
 229 [install libebl_CPU modules in $(libdir)/DIR]), [dnl
 230 LIBEBL_SUBDIR="$enable_libebl_subdir"])
 231 AC_SUBST([LIBEBL_SUBDIR])
 232 AC_DEFINE_UNQUOTED(LIBEBL_SUBDIR, "$LIBEBL_SUBDIR")
 233 AH_TEMPLATE([LIBEBL_SUBDIR], [$libdir subdirectory containing libebl modules.])
 234
 235 dnl zlib is mandatory.
 236 save_LIBS="$LIBS"
 237 LIBS=
 238 eu_ZIPLIB(zlib,ZLIB,z,gzdirect,gzip)
 239 AS_IF([test "x$with_zlib" = xno], [AC_MSG_ERROR([zlib not found but is required])])
 240 LIBS="$save_LIBS"
 241
 242 dnl Test for bzlib and xz/lzma, gives BZLIB/LZMALIB .am
 243 dnl conditional and config.h USE_BZLIB/USE_LZMALIB #define.
 244 save_LIBS="$LIBS"
 245 LIBS=
 246 eu_ZIPLIB(bzlib,BZLIB,bz2,BZ2_bzdopen,bzip2)
 247 # We need this since bzip2 doesn't have a pkgconfig file.
 248 BZ2_LIB="$LIBS"
 249 AC_SUBST([BZ2_LIB])
 250 eu_ZIPLIB(lzma,LZMA,lzma,lzma_auto_decoder,[LZMA (xz)])
 251 AS_IF([test "x$with_lzma" = xyes], [LIBLZMA="liblzma"], [LIBLZMA=""])
 252 AC_SUBST([LIBLZMA])
 253 zip_LIBS="$LIBS"
 254 LIBS="$save_LIBS"
 255 AC_SUBST([zip_LIBS])
 256
 257 AC_CHECK_DECLS([memrchr, rawmemchr],[],[],
 258                [#define _GNU_SOURCE
 259                 #include <string.h>])
 260 AC_CHECK_DECLS([powerof2],[],[],[#include <sys/param.h>])
 261
 262 AC_CHECK_LIB([stdc++], [__cxa_demangle], [dnl
 263 AC_DEFINE([USE_DEMANGLE], [1], [Defined if demangling is enabled])])
 264 AM_CONDITIONAL(DEMANGLE, test "x$ac_cv_lib_stdcpp___cxa_demangle" = "xyes")
 265 AS_IF([test "x$ac_cv_lib_stdcpp___cxa_demangle" = "xyes"],
 266       [enable_demangler=yes],[enable_demangler=no])
 267
 268 AC_ARG_ENABLE([textrelcheck],
 269 AS_HELP_STRING([--disable-textrelcheck],
 270                [Disable textrelcheck being a fatal error]))
 271 AM_CONDITIONAL(FATAL_TEXTREL, [test "x$enable_textrelcheck" != "xno"])
 272 AS_IF([test "x$enable_textrelcheck" != "xno"],
 273       [enable_textrelcheck=yes],[enable_textrelcheck=no])
 274
 275 AC_ARG_ENABLE([symbol-versioning],
 276 AS_HELP_STRING([--disable-symbol-versioning],
 277                [Disable symbol versioning in shared objects]))
 278 AM_CONDITIONAL(SYMBOL_VERSIONING, [test "x$enable_symbol_versioning" != "xno"])
 279 AS_IF([test "x$enable_symbol_versioning" = "xno"],
 280       [AC_MSG_WARN([Disabling symbol versioning breaks ABI compatibility.])
 281        enable_symbol_versioning=no],[enable_symbol_versioning=yes])
 282
 283 AC_CACHE_CHECK([whether gcc accepts -Wstack-usage], ac_cv_stack_usage, [dnl
 284 old_CFLAGS="$CFLAGS"
 285 CFLAGS="$CFLAGS -Wstack-usage=262144 -Werror"
 286 AC_COMPILE_IFELSE([AC_LANG_SOURCE([])],
 287                   ac_cv_stack_usage=yes, ac_cv_stack_usage=no)
 288 CFLAGS="$old_CFLAGS"])
 289 AM_CONDITIONAL(ADD_STACK_USAGE_WARNING, [test "x$ac_cv_stack_usage" != "xno"])
 290
 291 # -Wlogical-op was too fragile in the past, make sure we get a sane one.
 292 AC_CACHE_CHECK([whether gcc has a sane -Wlogical-op], ac_cv_logical_op, [dnl
 293 old_CFLAGS="$CFLAGS"
 294 CFLAGS="$CFLAGS -Wlogical-op -Werror"
 295 AC_COMPILE_IFELSE([AC_LANG_SOURCE(
 296         [#define FLAG 1
 297         int f (int r, int f) { return (r && (FLAG || (FLAG & f))); }])],
 298                   ac_cv_logical_op=yes, ac_cv_logical_op=no)
 299 CFLAGS="$old_CFLAGS"])
 300 AM_CONDITIONAL(SANE_LOGICAL_OP_WARNING,
 301                [test "x$ac_cv_logical_op" != "xno"])
 302
 303 # -Wduplicated-cond was added by GCC6
 304 AC_CACHE_CHECK([whether gcc accepts -Wduplicated-cond], ac_cv_duplicated_cond, [dnl
 305 old_CFLAGS="$CFLAGS"
 306 CFLAGS="$CFLAGS -Wduplicated-cond -Werror"
 307 AC_COMPILE_IFELSE([AC_LANG_SOURCE([])],
 308                   ac_cv_duplicated_cond=yes, ac_cv_duplicated_cond=no)
 309 CFLAGS="$old_CFLAGS"])
 310 AM_CONDITIONAL(HAVE_DUPLICATED_COND_WARNING,
 311                [test "x$ac_cv_duplicated_cond" != "xno"])
 312
 313 # -Wnull-dereference was added by GCC6
 314 AC_CACHE_CHECK([whether gcc accepts -Wnull-dereference], ac_cv_null_dereference, [dnl
 315 old_CFLAGS="$CFLAGS"
 316 CFLAGS="$CFLAGS -Wnull-dereference -Werror"
 317 AC_COMPILE_IFELSE([AC_LANG_SOURCE([])],
 318                   ac_cv_null_dereference=yes, ac_cv_null_dereference=no)
 319 CFLAGS="$old_CFLAGS"])
 320 AM_CONDITIONAL(HAVE_NULL_DEREFERENCE_WARNING,
 321                [test "x$ac_cv_null_dereference" != "xno"])
 322
 323 # -Wimplicit-fallthrough was added by GCC7
 324 AC_CACHE_CHECK([whether gcc accepts -Wimplicit-fallthrough], ac_cv_implicit_fallthrough, [dnl
 325 old_CFLAGS="$CFLAGS"
 326 CFLAGS="$CFLAGS -Wimplicit-fallthrough -Werror"
 327 AC_COMPILE_IFELSE([AC_LANG_SOURCE([])],
 328                   ac_cv_implicit_fallthrough=yes, ac_cv_implicit_fallthrough=no)
 329 CFLAGS="$old_CFLAGS"])
 330 AM_CONDITIONAL(HAVE_IMPLICIT_FALLTHROUGH_WARNING,
 331                [test "x$ac_cv_implicit_fallthrough" != "xno"])
 332
 333 dnl Check if we have argp available from our libc
 334 AC_LINK_IFELSE(
 335         [AC_LANG_PROGRAM(
 336                 [#include <argp.h>],
 337                 [int argc=1; char *argv[]={"test"}; argp_parse(0,argc,&argv,0,0,0); return 0;]
 338                 )],
 339         [libc_has_argp="true"],
 340         [libc_has_argp="false"]
 341 )
 342
 343 dnl If our libc doesn't provide argp, then test for libargp
 344 if test "$libc_has_argp" = "false" ; then
 345         AC_MSG_WARN("libc does not have argp")
 346         AC_CHECK_LIB([argp], [argp_parse], [have_argp="true"], [have_argp="false"])
 347
 348         if test "$have_argp" = "false"; then
 349                 AC_MSG_ERROR("no libargp found")
 350         else
 351                 argp_LDADD="-largp"
 352         fi
 353 else
 354         argp_LDADD=""
 355 fi
 356 AC_SUBST([argp_LDADD])
 357
 358 dnl Check if we have <linux/bpf.h> for EM_BPF disassembly.
 359 AC_CHECK_HEADERS(linux/bpf.h)
 360 AM_CONDITIONAL(HAVE_LINUX_BPF_H, [test "x$ac_cv_header_linux_bpf_h" = "xyes"])
 361
 362 dnl The directories with content.
 363
 364 dnl Documentation.
 365 dnl Commented out for now.
 366 dnl AC_CONFIG_FILES([doc/Makefile])
 367
 368 dnl Support library.
 369 AC_CONFIG_FILES([lib/Makefile])
 370
 371 dnl ELF library.
 372 AC_CONFIG_FILES([libelf/Makefile])
 373
 374 dnl Higher-level ELF support library.
 375 AC_CONFIG_FILES([libebl/Makefile])
 376
 377 dnl DWARF-ELF Lower-level Functions support library.
 378 AC_CONFIG_FILES([libdwelf/Makefile])
 379
 380 dnl DWARF library.
 381 AC_CONFIG_FILES([libdw/Makefile])
 382
 383 dnl Higher-level DWARF support library.
 384 AC_CONFIG_FILES([libdwfl/Makefile])
 385
 386 dnl CPU handling library.
 387 AC_CONFIG_FILES([libcpu/Makefile])
 388
 389 dnl Assembler library.
 390 AM_CONDITIONAL(HAVE_LIBASM, true)dnl Used in tests/Makefile.am, which see.
 391 AC_CONFIG_FILES([libasm/Makefile])
 392
 393 dnl CPU-specific backend libraries.
 394 AC_CONFIG_FILES([backends/Makefile])
 395
 396 dnl Tools.
 397 AC_CONFIG_FILES([src/Makefile po/Makefile.in])
 398
 399 dnl Test suite.
 400 AM_CONDITIONAL(STANDALONE, false)dnl Used in tests/Makefile.am, which see.
 401 AC_CONFIG_FILES([tests/Makefile])
 402
 403 dnl pkgconfig files
 404 AC_CONFIG_FILES([config/libelf.pc config/libdw.pc])
 405
 406 # Get the definitions necessary to create the Makefiles in the po
 407 # subdirectories.  This is a small subset of the gettext rules.
 408 AC_SUBST(USE_NLS, yes)
 409 AM_PO_SUBDIRS
 410
 411 dnl Appended to the config.h file.
 412 dnl We hide all kinds of configuration magic in lib/eu-config.h.
 413 AH_BOTTOM([#include <eu-config.h>])
 414
 415 dnl Version compatibility header.
 416 AC_CONFIG_FILES([version.h:config/version.h.in])
 417 AC_SUBST([eu_version])
 418
 419 # 1.234<whatever> -> 1234<whatever>
 420 case "$PACKAGE_VERSION" in
 421 [[0-9]].*) eu_version=`echo "$PACKAGE_VERSION" | sed 's@\.@@'` ;;
 422 *)         AC_MSG_ERROR([confused by version number '$PACKAGE_VERSION']) ;;
 423 esac
 424 case "$eu_version" in
 425 *.*)
 426   # 1234.567 -> "1234", "567"
 427   eu_extra_version="${eu_version#*.}"
 428   eu_version="${eu_version%%.*}"
 429   case "$eu_extra_version" in
 430   [[0-9]][[0-9]][[0-9]]) ;;
 431   [[0-9]][[0-9]])       eu_extra_version="${eu_extra_version}0" ;;
 432   [[0-9]])              eu_extra_version="${eu_extra_version}00" ;;
 433   *) AC_MSG_ERROR([confused by version number '$PACKAGE_VERSION']) ;;
 434   esac
 435   ;;
 436 *)
 437   eu_extra_version=000
 438   ;;
 439 esac
 440
 441 case "$eu_version" in
 442       0[[0-9]][[0-9]][[0-9]]) eu_version="${eu_version#0}$eu_extra_version" ;;
 443 [[0-9]][[0-9]][[0-9]][[0-9]]) eu_version="${eu_version}$eu_extra_version" ;;
 444 [[0-9]][[0-9]][[0-9]])        eu_version="${eu_version}0$eu_extra_version" ;;
 445 [[0-9]][[0-9]])               eu_version="${eu_version}00$eu_extra_version";;
 446 *) AC_MSG_ERROR([confused by version number '$PACKAGE_VERSION']) ;;
 447 esac
 448
 449 # Round up to the next release API (x.y) version.
 450 eu_version=$(( (eu_version + 999) / 1000 ))
 451
 452 dnl Unique ID for this build.
 453 MODVERSION="Build for ${LIBEBL_SUBDIR} ${eu_version} ${ac_cv_build}"
 454 AC_SUBST([MODVERSION])
 455 AC_DEFINE_UNQUOTED(MODVERSION, "$MODVERSION")
 456 AH_TEMPLATE([MODVERSION], [Identifier for modules in the build.])
 457
 458 AC_CHECK_SIZEOF(long)
 459
 460 # On aarch64 before glibc 2.20 we would get the kernel user_pt_regs instead
 461 # of the user_regs_struct from sys/user.h. They are structurally the same
 462 # but we get either one or the other.
 463 AC_CHECK_TYPE([struct user_regs_struct],
 464               [sys_user_has_user_regs=yes], [sys_user_has_user_regs=no],
 465               [[#include <sys/ptrace.h>]
 466                [#include <sys/time.h>]
 467                [#include <sys/user.h>]])
 468 if test "$sys_user_has_user_regs" = "yes"; then
 469   AC_DEFINE(HAVE_SYS_USER_REGS, 1,
 470             [Define to 1 if <sys/user.h> defines struct user_regs_struct])
 471 fi
 472
 473 # On a 64-bit host where can can use $CC -m32, we'll run two sets of tests.
 474 # Likewise in a 32-bit build on a host where $CC -m64 works.
 475 utrace_BIARCH
 476 # `$utrace_biarch' will be `-m64' even on an uniarch i386 machine.
 477 CC_BIARCH="$CC $utrace_biarch"
 478 AC_SUBST([CC_BIARCH])
 479
 480 # In maintainer mode we really need flex and bison.
 481 # Otherwise we really need a release dir with maintainer files generated.
 482 if test "x$enable_maintainer_mode" = xyes; then
 483   AC_CHECK_PROG(HAVE_FLEX, flex, yes, no)
 484   if test "$HAVE_FLEX" = "no"; then
 485     AC_MSG_ERROR([flex needed in maintainer mode])
 486   fi
 487   AC_CHECK_PROG(HAVE_BISON, bison, yes, no)
 488   if test "$HAVE_BISON" = "no"; then
 489     AC_MSG_ERROR([bison needed in maintainer mode])
 490   fi
 491 else
 492   if test ! -f ${srcdir}/libdw/known-dwarf.h; then
 493     AC_MSG_ERROR([No libdw/known-dwarf.h. configure --enable-maintainer-mode])
 494   fi
 495 fi
 496
 497 # The testfiles are all compressed, we need bunzip2 when running make check
 498 AC_CHECK_PROG(HAVE_BUNZIP2, bunzip2, yes, no)
 499 if test "$HAVE_BUNZIP2" = "no"; then
 500   AC_MSG_WARN([No bunzip2, needed to run make check])
 501 fi
 502
 503 AC_OUTPUT
 504
 505 AC_MSG_NOTICE([
 506 =====================================================================
 507         elfutils: ${PACKAGE_VERSION} (eu_version: ${eu_version})
 508 =====================================================================
 509
 510     Prefix                             : ${prefix}
 511     Program prefix ("eu-" recommended) : ${program_prefix}
 512     Source code location               : ${srcdir}
 513     Maintainer mode                    : ${enable_maintainer_mode}
 514     libebl modules subdirectory        : ${LIBEBL_SUBDIR}
 515     build arch                         : ${ac_cv_build}
 516
 517   RECOMMENDED FEATURES (should all be yes)
 518     gzip support                       : ${with_zlib}
 519     bzip2 support                      : ${with_bzlib}
 520     lzma/xz support                    : ${with_lzma}
 521     libstdc++ demangle support         : ${enable_demangler}
 522     File textrel check                 : ${enable_textrelcheck}
 523     Symbol versioning                  : ${enable_symbol_versioning}
 524
 525   NOT RECOMMENDED FEATURES (should all be no)
 526     Experimental thread safety         : ${use_locks}
 527
 528   OTHER FEATURES
 529     Deterministic archives by default  : ${default_ar_deterministic}
 530     Native language support            : ${USE_NLS}
 531
 532   EXTRA TEST FEATURES (used with make check)
 533     have bunzip2 installed (required)  : ${HAVE_BUNZIP2}
 534     debug branch prediction            : ${use_debugpred}
 535     gprof support                      : ${use_gprof}
 536     gcov support                       : ${use_gcov}
 537     run all tests under valgrind       : ${use_valgrind}
 538     gcc undefined behaviour sanitizer  : ${use_undefined}
 539     use rpath in tests                 : ${tests_use_rpath}
 540     test biarch                        : ${utrace_cv_cc_biarch}
 541 ])