configure.ac

   1 dnl These m4 macros are whitespace sensitive and break if moved around much.
   2 m4_define([LU_VERSION_H], m4_include([libusb/version.h]))
   3 m4_define([LU_DEFINE_VERSION_ATOM],
   4         [m4_define([$1], m4_bregexp(LU_VERSION_H,
   5         [^#define\s*$1\s*\([0-9]*\).*], [\1]))])
   6 m4_define([LU_DEFINE_VERSION_RC_ATOM],
   7         [m4_define([$1], m4_bregexp(LU_VERSION_H,
   8         [^#define\s*$1\s*"\(-rc[0-9]*\)".*], [\1]))])
   9 dnl The m4_bregexp() returns (only) the numbers following the #define named
  10 dnl in the first macro parameter. m4_define() then defines the name for use
  11 dnl in AC_INIT.
  12
  13 LU_DEFINE_VERSION_ATOM([LIBUSB_MAJOR])
  14 LU_DEFINE_VERSION_ATOM([LIBUSB_MINOR])
  15 LU_DEFINE_VERSION_ATOM([LIBUSB_MICRO])
  16 LU_DEFINE_VERSION_RC_ATOM([LIBUSB_RC])
  17
  18 AC_INIT([libusb],[LIBUSB_MAJOR[.]LIBUSB_MINOR[.]LIBUSB_MICRO[]LIBUSB_RC],[libusb-devel@lists.sourceforge.net],[libusb],[http://libusb.info])
  19
  20 # Library versioning
  21 # These numbers should be tweaked on every release. Read carefully:
  22 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
  23 # http://sourceware.org/autobook/autobook/autobook_91.html
  24 lt_current="1"
  25 lt_revision="0"
  26 lt_age="1"
  27 LTLDFLAGS="-version-info ${lt_current}:${lt_revision}:${lt_age}"
  28
  29 AM_INIT_AUTOMAKE
  30 AM_MAINTAINER_MODE
  31
  32 AC_CONFIG_SRCDIR([libusb/core.c])
  33 AC_CONFIG_MACRO_DIR([m4])
  34 AC_CONFIG_HEADERS([config.h])
  35 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  36
  37 AC_PREREQ([2.50])
  38 AC_PROG_CC
  39 LT_INIT
  40 LT_LANG([Windows Resource])
  41 AC_C_INLINE
  42 AM_PROG_CC_C_O
  43 AC_DEFINE([_GNU_SOURCE], 1, [Use GNU extensions])
  44
  45 LTLDFLAGS="${LTLDFLAGS} -no-undefined"
  46
  47 AC_MSG_CHECKING([operating system])
  48
  49 dnl on linux-android platform, some functions are in different places
  50 case $host in
  51 *-linux-android*)
  52         AC_MSG_RESULT([This is a Linux-Android system])
  53         is_backend_android="yes"
  54         ;;
  55 *)
  56         is_backend_android="no"
  57 esac
  58
  59 case $host in
  60 *-linux* | *-uclinux*)
  61         AC_MSG_RESULT([Linux])
  62         backend="linux"
  63         threads="posix"
  64         ;;
  65 *-darwin*)
  66         AC_MSG_RESULT([Darwin/Mac OS X])
  67         backend="darwin"
  68         threads="posix"
  69         ;;
  70 *-openbsd*)
  71         AC_MSG_RESULT([OpenBSD])
  72         backend="openbsd"
  73         threads="posix"
  74         ;;
  75 *-netbsd*)
  76         AC_MSG_RESULT([NetBSD])
  77         backend="netbsd"
  78         threads="posix"
  79         ;;
  80 *-mingw*)
  81         AC_MSG_RESULT([Windows])
  82         backend="windows"
  83         threads="windows"
  84         create_import_lib="yes"
  85         AM_CFLAGS="${AM_CFLAGS} -fno-omit-frame-pointer"
  86         ;;
  87 *-cygwin*)
  88         AC_MSG_RESULT([Cygwin (using Windows backend)])
  89         backend="windows"
  90         threads="posix"
  91         ;;
  92 *)
  93         AC_MSG_ERROR([unsupported operating system])
  94 esac
  95
  96 case $backend in
  97 linux)
  98         AC_DEFINE(OS_LINUX, 1, [Linux backend])
  99         AC_SUBST(OS_LINUX)
 100         AC_SEARCH_LIBS(clock_gettime, rt, [], [], -pthread)
 101         AC_ARG_ENABLE([udev],
 102                 [AC_HELP_STRING([--enable-udev], [use udev for device enumeration and hotplug support (recommended) [default=yes]])],
 103                 [], [enable_udev="yes"])
 104                 if test "x$enable_udev" = "xyes" ; then
 105                         # system has udev. use it or fail!
 106                         AC_CHECK_HEADERS([libudev.h],[],[AC_ERROR(["udev support requested but libudev not installed"])])
 107                         AC_CHECK_LIB([udev], [udev_new], [], [AC_ERROR(["udev support requested but libudev not installed"])])
 108                         AC_DEFINE(USE_UDEV, 1, [Use udev for device enumeration/hotplug])
 109                 else
 110                         AC_CHECK_HEADERS([asm/types.h sys/socket.h], [], [])
 111                         AC_CHECK_HEADERS([linux/netlink.h linux/filter.h], [], [AC_ERROR(["Linux netlink headers not found"])], [
 112 #ifdef HAVE_ASM_TYPES_H
 113 #include <asm/types.h>
 114 #endif
 115 #ifdef HAVE_SYS_SOCKET_H
 116 #include <sys/socket.h>
 117 #endif
 118 ])
 119                 fi
 120                 AC_SUBST(USE_UDEV)
 121
 122 case $is_backend_android in
 123 yes)
 124         dnl some pthread functions is in libc
 125         THREAD_CFLAGS="-c"
 126         LIBS="${LIBS} -c"
 127         dnl there are gettimeofday function but configure doesn't seem to be able to find it.
 128         AC_DEFINE([HAVE_GETTIMEOFDAY], [1], [Define if you have gettimeofday])
 129         ;;
 130 *)
 131         THREAD_CFLAGS="-pthread"
 132         LIBS="${LIBS} -pthread"
 133 esac
 134
 135         AC_CHECK_HEADERS([poll.h])
 136         AC_DEFINE([POLL_NFDS_TYPE],[nfds_t],[type of second poll() argument])
 137         ;;
 138 darwin)
 139         AC_DEFINE(OS_DARWIN, 1, [Darwin backend])
 140         AC_SUBST(OS_DARWIN)
 141         LIBS="-lobjc -Wl,-framework,IOKit -Wl,-framework,CoreFoundation"
 142         LTLDFLAGS="${LTLDFLAGS} -Wl,-prebind"
 143         AC_CHECK_HEADERS([poll.h])
 144         AC_CHECK_TYPE([nfds_t],
 145                 [AC_DEFINE([POLL_NFDS_TYPE],[nfds_t],[type of second poll() argument])],
 146                 [AC_DEFINE([POLL_NFDS_TYPE],[unsigned int],[type of second poll() argument])],
 147                 [#include <poll.h>])
 148         ;;
 149 openbsd)
 150         AC_DEFINE(OS_OPENBSD, 1, [OpenBSD backend])
 151         AC_SUBST(OS_OPENBSD)
 152         THREAD_CFLAGS="-pthread"
 153         LIBS="-pthread"
 154         AC_CHECK_HEADERS([poll.h])
 155         AC_DEFINE([POLL_NFDS_TYPE],[nfds_t],[type of second poll() argument])
 156         ;;
 157 netbsd)
 158         AC_DEFINE(OS_NETBSD, 1, [NetBSD backend])
 159         AC_SUBST(OS_NETBSD)
 160         THREAD_CFLAGS="-pthread"
 161         LIBS="-pthread"
 162         AC_CHECK_HEADERS([poll.h])
 163         AC_DEFINE([POLL_NFDS_TYPE],[nfds_t],[type of second poll() argument])
 164         ;;
 165 windows)
 166         AC_DEFINE(OS_WINDOWS, 1, [Windows backend])
 167         AC_SUBST(OS_WINDOWS)
 168         LIBS=""
 169         LTLDFLAGS="${LTLDFLAGS} -avoid-version -Wl,--add-stdcall-alias"
 170         AC_DEFINE([POLL_NFDS_TYPE],[unsigned int],[type of second poll() argument])
 171         AC_DEFINE([WINVER], 0x0501, [Oldest Windows version supported])
 172         ;;
 173 esac
 174
 175 AC_SUBST(LIBS)
 176
 177 AM_CONDITIONAL(OS_LINUX, test "x$backend" = xlinux)
 178 AM_CONDITIONAL(OS_DARWIN, test "x$backend" = xdarwin)
 179 AM_CONDITIONAL(OS_OPENBSD, test "x$backend" = xopenbsd)
 180 AM_CONDITIONAL(OS_NETBSD, test "x$backend" = xnetbsd)
 181 AM_CONDITIONAL(OS_WINDOWS, test "x$backend" = xwindows)
 182 AM_CONDITIONAL(THREADS_POSIX, test "x$threads" = xposix)
 183 AM_CONDITIONAL(CREATE_IMPORT_LIB, test "x$create_import_lib" = "xyes")
 184 AM_CONDITIONAL(USE_UDEV, test "x$enable_udev" = xyes)
 185 if test "$threads" = posix; then
 186         AC_DEFINE(THREADS_POSIX, 1, [Use POSIX Threads])
 187 fi
 188
 189 # timerfd
 190 AC_CHECK_HEADER([sys/timerfd.h], [timerfd_h=1], [timerfd_h=0])
 191 AC_ARG_ENABLE([timerfd],
 192         [AS_HELP_STRING([--enable-timerfd],
 193                 [use timerfd for timing [default=auto]])],
 194         [use_timerfd=$enableval], [use_timerfd='auto'])
 195
 196 if test "x$use_timerfd" = "xyes" -a "x$timerfd_h" = "x0"; then
 197         AC_MSG_ERROR([timerfd header not available; glibc 2.9+ required])
 198 fi
 199
 200 AC_CHECK_DECL([TFD_NONBLOCK], [tfd_hdr_ok=yes], [tfd_hdr_ok=no], [#include <sys/timerfd.h>])
 201 if test "x$use_timerfd" = "xyes" -a "x$tfd_hdr_ok" = "xno"; then
 202         AC_MSG_ERROR([timerfd header not usable; glibc 2.9+ required])
 203 fi
 204
 205 AC_MSG_CHECKING([whether to use timerfd for timing])
 206 if test "x$use_timerfd" = "xno"; then
 207         AC_MSG_RESULT([no (disabled by user)])
 208 else
 209         if test "x$timerfd_h" = "x1" -a "x$tfd_hdr_ok" = "xyes"; then
 210                 AC_MSG_RESULT([yes])
 211                 AC_DEFINE(USBI_TIMERFD_AVAILABLE, 1, [timerfd headers available])
 212         else
 213                 AC_MSG_RESULT([no (header not available)])
 214         fi
 215 fi
 216
 217 AC_CHECK_TYPES(struct timespec)
 218
 219 # Message logging
 220 AC_ARG_ENABLE([log], [AS_HELP_STRING([--disable-log], [disable all logging])],
 221         [log_enabled=$enableval],
 222         [log_enabled='yes'])
 223 if test "x$log_enabled" != "xno"; then
 224         AC_DEFINE([ENABLE_LOGGING], 1, [Message logging])
 225 fi
 226
 227 AC_ARG_ENABLE([debug-log], [AS_HELP_STRING([--enable-debug-log],
 228         [start with debug message logging enabled [default=no]])],
 229         [debug_log_enabled=$enableval],
 230         [debug_log_enabled='no'])
 231 if test "x$debug_log_enabled" != "xno"; then
 232         AC_DEFINE([ENABLE_DEBUG_LOGGING], 1, [Start with debug message logging enabled])
 233 fi
 234
 235 AC_ARG_ENABLE([system-log], [AS_HELP_STRING([--enable-system-log],
 236         [output logging messages to system wide log, if supported by the OS [default=no]])],
 237         [system_log_enabled=$enableval],
 238         [system_log_enabled='no'])
 239 if test "x$system_log_enabled" != "xno"; then
 240         AC_DEFINE([USE_SYSTEM_LOGGING_FACILITY], 1, [Enable output to system log])
 241 fi
 242
 243 # Check if syslog is available in standard C library
 244 AC_CHECK_HEADERS(syslog.h)
 245 AC_CHECK_FUNC([syslog], [have_syslog=yes], [have_syslog=no])
 246 if test "x$have_syslog" != "xno"; then
 247         AC_DEFINE([HAVE_SYSLOG_FUNC], 1, [syslog() function available])
 248 fi
 249
 250 # Examples build
 251 AC_ARG_ENABLE([examples-build], [AS_HELP_STRING([--enable-examples-build],
 252         [build example applications [default=no]])],
 253         [build_examples=$enableval],
 254         [build_examples='no'])
 255 AM_CONDITIONAL([BUILD_EXAMPLES], [test "x$build_examples" != "xno"])
 256
 257 # Tests build
 258 AC_ARG_ENABLE([tests-build], [AS_HELP_STRING([--enable-tests-build],
 259         [build test applications [default=no]])],
 260         [build_tests=$enableval],
 261         [build_tests='no'])
 262 AM_CONDITIONAL([BUILD_TESTS], [test "x$build_tests" != "xno"])
 263
 264 # check for -fvisibility=hidden compiler support (GCC >= 3.4)
 265 saved_cflags="$CFLAGS"
 266 # -Werror required for cygwin
 267 CFLAGS="$CFLAGS -Werror -fvisibility=hidden"
 268 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([])],
 269         [VISIBILITY_CFLAGS="-fvisibility=hidden"
 270          AC_DEFINE([DEFAULT_VISIBILITY], [__attribute__((visibility("default")))], [Default visibility]) ],
 271         [ VISIBILITY_CFLAGS=""
 272          AC_DEFINE([DEFAULT_VISIBILITY], [], [Default visibility]) ],
 273         ])
 274 CFLAGS="$saved_cflags"
 275
 276 # check for -Wno-pointer-sign compiler support (GCC >= 4)
 277 saved_cflags="$CFLAGS"
 278 CFLAGS="$CFLAGS -Wno-pointer-sign"
 279 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([])],
 280         nopointersign_cflags="-Wno-pointer-sign", nopointersign_cflags="")
 281 CFLAGS="$saved_cflags"
 282
 283 # sigaction not available on MinGW
 284 AC_CHECK_FUNC([sigaction], [have_sigaction=yes], [have_sigaction=no])
 285 AM_CONDITIONAL([HAVE_SIGACTION], [test "x$have_sigaction" = "xyes"])
 286
 287 # headers not available on all platforms but required on others
 288 AC_CHECK_HEADERS([sys/time.h])
 289 AC_CHECK_FUNCS(gettimeofday)
 290 AC_CHECK_HEADERS([signal.h])
 291
 292 AM_CFLAGS="${AM_CFLAGS} -std=gnu99 -Wall -Wundef -Wunused -Wstrict-prototypes -Werror-implicit-function-declaration $nopointersign_cflags -Wshadow ${THREAD_CFLAGS} ${VISIBILITY_CFLAGS}"
 293
 294 AC_SUBST(AM_CFLAGS)
 295 AC_SUBST(LTLDFLAGS)
 296
 297 AC_CONFIG_FILES([libusb-1.0.pc])
 298 AC_CONFIG_FILES([Makefile])
 299 AC_CONFIG_FILES([libusb/Makefile])
 300 AC_CONFIG_FILES([examples/Makefile])
 301 AC_CONFIG_FILES([tests/Makefile])
 302 AC_CONFIG_FILES([doc/Makefile])
 303 AC_CONFIG_FILES([doc/doxygen.cfg])
 304 AC_OUTPUT