configure.ac

   1 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
   2 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
   3 m4_define([v_maj], [1])
   4 m4_define([v_min], [0])
   5 m4_define([v_mic], [999])
   6 m4_define([v_rev], m4_esyscmd([(svnversion "${SVN_REPO_PATH:-.}" | grep -v export || echo 0) | awk -F : '{printf("%s\n", $1);}' | tr -d ' :MSP\n']))
   7 m4_if(v_rev, [0], [m4_define([v_rev], m4_esyscmd([git log 2> /dev/null | (grep -m1 git-svn-id || echo 0) | sed -e 's/.*@\([0-9]*\).*/\1/' | tr -d '\n']))])
   8 ##--   When released, remove the dnl on the below line
   9 dnl m4_undefine([v_rev])
  10 ##--   When doing snapshots - change soname. remove dnl on below line
  11 dnl m4_define([relname], [ver-pre-svn-07])
  12 dnl m4_define([v_rel], [-release relname])
  13 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  14 m4_ifdef([v_rev], [m4_define([v_ver], [v_maj.v_min.v_mic.v_rev])], [m4_define([v_ver], [v_maj.v_min.v_mic])])
  15 m4_define([lt_cur], m4_eval(v_maj + v_min))
  16 m4_define([lt_rev], v_mic)
  17 m4_define([lt_age], v_min)
  18 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  19 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  20
  21 AC_INIT([eina], [v_ver], [enlightenment-devel@lists.sourceforge.net])
  22 AC_PREREQ([2.59])
  23 AC_CONFIG_SRCDIR([configure.ac])
  24 AC_CONFIG_MACRO_DIR([m4])
  25
  26 AC_CONFIG_HEADERS([config.h])
  27 AH_TOP([
  28 #ifndef EFL_CONFIG_H__
  29 #define EFL_CONFIG_H__
  30 ])
  31 AH_BOTTOM([
  32 #endif /* EFL_CONFIG_H__ */
  33 ])
  34
  35 AM_INIT_AUTOMAKE([1.6 dist-bzip2])
  36 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  37
  38 AC_GNU_SOURCE
  39 AC_SYS_LARGEFILE
  40
  41 AC_LIBTOOL_WIN32_DLL
  42 define([AC_LIBTOOL_LANG_CXX_CONFIG], [:])dnl
  43 define([AC_LIBTOOL_LANG_F77_CONFIG], [:])dnl
  44 AC_PROG_LIBTOOL
  45
  46 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  47 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  48 m4_ifdef([v_rev], , [m4_define([v_rev], [0])])
  49 m4_ifdef([v_rel], , [m4_define([v_rel], [])])
  50 AC_DEFINE_UNQUOTED(VMAJ, [v_maj], [Major version])
  51 AC_DEFINE_UNQUOTED(VMIN, [v_min], [Minor version])
  52 AC_DEFINE_UNQUOTED(VMIC, [v_mic], [Micro version])
  53 AC_DEFINE_UNQUOTED(VREV, [v_rev], [Revison])
  54 version_info="lt_cur:lt_rev:lt_age"
  55 release_info="v_rel"
  56 AC_SUBST(version_info)
  57 AC_SUBST(release_info)
  58 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  59 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  60 VMAJ=v_maj
  61 AC_SUBST(VMAJ)
  62
  63
  64 ### Needed information
  65
  66 AC_CANONICAL_BUILD
  67 AC_CANONICAL_HOST
  68
  69 requirement_eina=""
  70
  71 case "$host_os" in
  72    mingw32ce*)
  73       MODULE_ARCH="$host_os-$host_cpu"
  74       ;;
  75    *)
  76       MODULE_ARCH="$host_os-$host_cpu-v_maj.v_min.v_mic"
  77       ;;
  78 esac
  79 AC_SUBST(MODULE_ARCH)
  80 AC_DEFINE_UNQUOTED(MODULE_ARCH, "${MODULE_ARCH}", "Module architecture")
  81
  82 case "$host_os" in
  83    mingw*)
  84       MODULE_EXT=".dll"
  85       ;;
  86    *)
  87       MODULE_EXT=".so"
  88       ;;
  89 esac
  90
  91 AC_DEFINE_UNQUOTED(SHARED_LIB_SUFFIX, "${MODULE_EXT}", [Suffix for shared objects])
  92
  93 EFL_CHECK_CPU_MMX([have_mmx="yes"], [have_mmx="no"])
  94 EFL_CHECK_CPU_SSE([have_sse="yes"], [have_sse="no"])
  95 EFL_CHECK_CPU_SSE2([have_sse2="yes"], [have_sse2="no"])
  96 EFL_CHECK_CPU_ALTIVEC([have_altivec="yes"], [have_altivec="no"])
  97
  98 EFL_CHECK_THREADS(
  99    [
 100     if test "x${_efl_have_posix_threads}" = "xyes" ; then
 101        have_threads="POSIX"
 102     else
 103        if test "x${_efl_have_win32_threads}" = "xyes" ; then
 104           have_threads="Win32"
 105        else
 106           have_threads="no"
 107        fi
 108     fi
 109    ],
 110    [have_threads="no"])
 111 EFL_CHECK_SPINLOCK([have_posix_threads_spinlock="yes"], [have_posix_threads_spinlock="no"])
 112
 113 ### Additional options to configure
 114
 115 # Magic debug
 116 AC_ARG_ENABLE([magic-debug],
 117    [AC_HELP_STRING([--disable-magic-debug], [disable magic debug of eina structure @<:@default=enabled@:>@])],
 118    [
 119     if test "x${enableval}" = "xyes" ; then
 120        have_magic_debug="yes"
 121     else
 122        have_magic_debug="no"
 123     fi
 124    ],
 125    [have_magic_debug="yes"])
 126
 127 AC_MSG_CHECKING([whether magic debug is enable])
 128 AC_MSG_RESULT([${have_magic_debug}])
 129
 130 if test "x${have_magic_debug}" = "xyes" ; then
 131    EINA_CONFIGURE_MAGIC_DEBUG="#define EINA_MAGIC_DEBUG"
 132 fi
 133 AC_SUBST(EINA_CONFIGURE_MAGIC_DEBUG)
 134
 135 # Valgrind
 136 want_valgrind="auto"
 137 have_valgrind="no"
 138
 139 AC_MSG_CHECKING(whether to enable build with valgrind)
 140 AC_ARG_ENABLE(valgrind,
 141   AC_HELP_STRING([--enable-valgrind], [improve valgrind support by hinting it of our memory usages, having it to report proper mempool leaks.]),
 142   [want_valgrind=$enableval]
 143 )
 144 AC_MSG_RESULT($want_valgrind)
 145
 146 if test "x${want_valgrind}" = "xyes" -o "x${want_valgrind}" = "xauto"; then
 147     PKG_CHECK_MODULES(VALGRIND, valgrind >= 2.4.0,
 148         [
 149          requirement_eina="valgrind ${requirement_eina}"
 150          have_valgrind="yes"
 151         ],
 152         [
 153          AC_DEFINE(NVALGRIND, 1, [Valgrind support disabled])
 154          if test "x$want_valgrind" = "xyes"; then
 155             AC_MSG_ERROR([Valgrind >= 2.4.0 is required)])
 156          fi
 157         ]
 158     )
 159 else
 160     AC_DEFINE(NVALGRIND, 1, [Valgrind support disabled])
 161 fi
 162
 163 # Safety checks (avoid crashes on wrong api usage)
 164 AC_ARG_ENABLE(safety-checks,
 165    [AC_HELP_STRING([--disable-safety-checks], [disable safety checks for NULL pointers and like. @<:@default=enabled@:>@])],
 166    [
 167     if test "x${enableval}" = "xyes" ; then
 168        have_safety_checks="yes"
 169     else
 170        have_safety_checks="no"
 171     fi
 172    ],
 173    [have_safety_checks="yes"])
 174
 175 AC_MSG_CHECKING(whether to do safety checking on api parameters)
 176 AC_MSG_RESULT($have_safety_checks)
 177
 178 AM_CONDITIONAL(SAFETY_CHECKS, test "x$have_safety_checks" = "xyes")
 179 if test "x$have_safety_checks" = "xyes"; then
 180   AC_DEFINE(EINA_SAFETY_CHECKS, 1, [disable safety checks for NULL pointers and like.])
 181   EINA_CONFIGURE_SAFETY_CHECKS="#define EINA_SAFETY_CHECKS"
 182 fi
 183 AC_SUBST(EINA_CONFIGURE_SAFETY_CHECKS)
 184
 185 with_max_log_level="<unset>"
 186 AC_ARG_WITH(internal-maximum-log-level,
 187    [AC_HELP_STRING([--with-internal-maximum-log-level=NUMBER],
 188                    [limit eina internal log level to the given number, any call to EINA_LOG() with values greater than this will be compiled out, ignoring runtime settings, but saving function calls.])],
 189    [
 190     if test "x${withval}" != "xno"; then
 191        if echo "${withval}" | grep '^[[0-9]]\+$' >/dev/null 2>/dev/null; then
 192           AC_MSG_NOTICE([ignoring any EINA_LOG() with level greater than ${withval}])
 193           AC_DEFINE_UNQUOTED(EINA_LOG_LEVEL_MAXIMUM, ${withval}, [if set, logging is limited to this amount.])
 194           with_max_log_level="${withval}"
 195        else
 196           AC_MSG_ERROR([--with-internal-maximum-log-level takes a decimal number, got "${withval}" instead.])
 197        fi
 198     fi
 199     ], [:])
 200
 201 AC_ARG_ENABLE([amalgamation],
 202    [AC_HELP_STRING([--enable-amalgamation], [enable generation of one single file with all source code in it, helps compiler optimizations.])],
 203    [if test "x${enableval}" = "xyes"; then
 204        do_amalgamation="yes"
 205     else
 206        do_amalgamation="no"
 207     fi
 208    ],
 209    [do_amalgamation="no"]
 210 )
 211 AM_CONDITIONAL(EINA_AMALGAMATION, test "x${do_amalgamation}" = "xyes")
 212
 213 # Choose best memory pool
 214 AC_ARG_ENABLE([default-mempool],
 215    [AC_HELP_STRING([--enable-default-mempool], [Default memory allocator could be faster for some computer. @<:@default=disabled@:>@])],
 216    [
 217     if test "x${enableval}" = "xyes"; then
 218        have_default_mempool="yes"
 219     else
 220        have_default_mempool="no"
 221     fi
 222    ],
 223    [have_default_mempool="no"]
 224 )
 225 AC_MSG_CHECKING([whether to use default mempool allocator])
 226 AC_MSG_RESULT([${have_default_mempool}])
 227
 228 if test "x${have_default_mempool}" = "xyes" ; then
 229    EINA_CONFIGURE_DEFAULT_MEMPOOL="#define EINA_DEFAULT_MEMPOOL"
 230 fi
 231 AC_SUBST(EINA_CONFIGURE_DEFAULT_MEMPOOL)
 232
 233 # Report stringshare usage
 234 AC_ARG_ENABLE([stringshare-usage],
 235    [AC_HELP_STRING([--enable-stringshare-usage], [Report stringshare usage on stringshare shutdown. @<:@default=disabled@:>@])],
 236    [
 237     if test "x${enableval}" = "xyes"; then
 238        have_stringshare_usage="yes"
 239     else
 240        have_stringshare_usage="no"
 241     fi
 242    ],
 243    [have_stringshare_usage="no"]
 244 )
 245 AC_MSG_CHECKING([whether to report stringshare usage])
 246 AC_MSG_RESULT([${have_stringshare_usage}])
 247
 248 if test "x${have_stringshare_usage}" = "xyes"; then
 249    AC_DEFINE(EINA_STRINGSHARE_USAGE, 1, [Report Eina stringshare usage pattern])
 250 fi
 251
 252 # Check if we want to benchmark on real data
 253 enable_benchmark_e17="no"
 254 AC_ARG_ENABLE([e17],
 255    [AC_HELP_STRING([--enable-e17], [enable heavy benchmark @<:@default=no@:>@])],
 256    [
 257     if test "x${enableval}" = "xyes" ; then
 258        enable_benchmark_e17="yes"
 259     else
 260        enable_benchmark_e17="no"
 261     fi
 262    ],
 263    [enable_benchmark_e17="no"])
 264
 265 AC_MSG_CHECKING([whether e17 real data benchmark are built])
 266 AC_MSG_RESULT([${enable_benchmark_e17}])
 267
 268 AM_CONDITIONAL(EINA_ENABLE_BENCHMARK_E17, test "x${enable_benchmark_e17}" = "xyes")
 269
 270
 271 ### Checks for programs
 272 AC_PROG_CC
 273
 274 # pkg-config
 275 PKG_PROG_PKG_CONFIG
 276
 277 # Check whether pkg-config supports Requires.private
 278 if $PKG_CONFIG --atleast-pkgconfig-version 0.22; then
 279    pkgconfig_requires_private="Requires.private"
 280 else
 281    pkgconfig_requires_private="Requires"
 282 fi
 283 AC_SUBST(pkgconfig_requires_private)
 284
 285 # doxygen program for documentation building
 286
 287 EFL_CHECK_DOXYGEN([build_doc="yes"], [build_doc="no"])
 288
 289
 290 ### Checks for libraries
 291
 292 # Evil library for compilation on Windows CE
 293
 294 EFL_EINA_BUILD=""
 295 case "$host_os" in
 296    mingw*)
 297       PKG_CHECK_MODULES([EVIL], [evil])
 298       AC_DEFINE(HAVE_EVIL, 1, [Set to 1 if evil package is installed])
 299       requirement_eina="evil"
 300       EFL_EINA_BUILD="-DEFL_EINA_BUILD"
 301    ;;
 302 esac
 303 AC_SUBST(EFL_EINA_BUILD)
 304
 305 # Check ememoa memory pool library
 306
 307 AC_ARG_ENABLE([ememoa],
 308    [AC_HELP_STRING([--enable-ememoa], [build ememoa memory pool module @<:@default=yes@:>@])],
 309    [
 310     if test "x${enableval}" = "xyes" ; then
 311        enable_ememoa="yes"
 312     else
 313        enable_ememoa="no"
 314     fi
 315    ],
 316    [enable_ememoa="yes"]
 317 )
 318 AC_MSG_CHECKING([whether to use ememoa for memory pool])
 319 AC_MSG_RESULT([$enable_ememoa])
 320
 321 if test "x${enable_ememoa}" = "xyes" ; then
 322    PKG_CHECK_MODULES([EMEMOA],
 323       [ememoa >= 0.0.26 ],
 324       [enable_ememoa="yes"],
 325       [enable_ememoa="no"]
 326    )
 327 fi
 328
 329
 330 ### Checks for header files
 331 AC_HEADER_ASSERT
 332 AC_HEADER_DIRENT
 333 AC_HEADER_TIME
 334 AC_CHECK_HEADERS([unistd.h libgen.h])
 335 EFL_CHECK_PATH_MAX
 336
 337 ### Checks for types
 338 AC_CHECK_HEADER([inttypes.h],
 339    [
 340     EINA_CONFIGURE_HAVE_INTTYPES_H="#define EINA_HAVE_INTTYPES_H"
 341     AC_DEFINE(HAVE_INTTYPES_H, 1, [Define to 1 if you have the <inttypes.h> header file.])
 342    ])
 343 AC_SUBST(EINA_CONFIGURE_HAVE_INTTYPES_H)
 344
 345 AC_CHECK_HEADER([stdint.h],
 346    [
 347     EINA_CONFIGURE_HAVE_STDINT_H="#define EINA_HAVE_STDINT_H"
 348     AC_DEFINE(HAVE_STDINT_H, 1, [Define to 1 if you have the <stdint.h> header file.])
 349    ])
 350 AC_SUBST(EINA_CONFIGURE_HAVE_STDINT_H)
 351
 352 AC_CHECK_SIZEOF(wchar_t)
 353 EINA_SIZEOF_WCHAR_T=$ac_cv_sizeof_wchar_t
 354 AC_SUBST(EINA_SIZEOF_WCHAR_T)
 355
 356 ### Checks for structures
 357
 358
 359 ### Checks for compiler characteristics
 360 AC_C_CONST
 361 AC_C_BIGENDIAN
 362 AC_C_INLINE
 363 AC_C___ATTRIBUTE__
 364 AC_PROG_CC_STDC
 365
 366 have_win32="no"
 367 EINA_CPPFLAGS=""
 368 EINA_CFLAGS=""
 369 case "$host_os" in
 370    mingw32ce*)
 371       EINA_CPPFLAGS="-D_WIN32_WCE=0x0420"
 372       EINA_CFLAGS="${EVIL_CFLAGS}"
 373       have_win32="yes"
 374       ;;
 375    mingw*)
 376       EINA_CPPFLAGS="-D_WIN32_WINNT=0x0501"
 377       EINA_CFLAGS="${EVIL_CFLAGS}"
 378       have_win32="yes"
 379       ;;
 380 esac
 381 AM_CONDITIONAL([EINA_HAVE_WIN32], [test "x$have_win32" = "xyes"])
 382
 383 m4_ifdef([v_mic],
 384    [
 385     EFL_COMPILER_FLAG([-Wall])
 386     EFL_COMPILER_FLAG([-W])
 387    ])
 388
 389 EFL_COMPILER_FLAG([-Wshadow])
 390
 391 AC_SUBST(EINA_CPPFLAGS)
 392 AC_SUBST(EINA_CFLAGS)
 393
 394
 395 ### Checks for linker characteristics
 396 EINA_LIBS=
 397 lt_enable_auto_import=""
 398 case "${host_os}" in
 399    mingw*)
 400       EINA_LIBS="-ldl ${EVIL_LIBS} -lm"
 401       lt_enable_auto_import="-Wl,--enable-auto-import"
 402    ;;
 403    dragonfly*|openbsd*)
 404       EINA_LIBS="-lm"
 405    ;;
 406    freebsd*|netbsd*)
 407       EINA_LIBS="-lrt -lm"
 408    ;;
 409    darwin*)
 410       EINA_LIBS="-lm"
 411    ;;
 412    cygwin*)
 413       EINA_LIBS="-ldl -lm"
 414    ;;
 415    *)
 416       EINA_LIBS="-ldl -lrt -lm"
 417    ;;
 418 esac
 419 AC_SUBST(EINA_LIBS)
 420 AC_SUBST(lt_enable_auto_import)
 421
 422 EFL_LINKER_FLAG([-fno-strict-aliasing])
 423
 424
 425 ### Checks for library functions
 426 AC_ISC_POSIX
 427 AC_FUNC_ALLOCA
 428 AC_CHECK_FUNCS(strlcpy)
 429
 430 #dlopen and dladdr
 431 dlopen_libs=""
 432 case "$host_os" in
 433    mingw*)
 434 # managed by evil
 435       AC_DEFINE(HAVE_DLADDR)
 436       ;;
 437    *)
 438       AC_CHECK_FUNCS([dlopen], [res="yes"], [res="no"])
 439       if test "x${res}" = "xyes" ; then
 440          AC_CHECK_FUNCS([dladdr], [AC_DEFINE(HAVE_DLADDR)])
 441       else
 442          AC_CHECK_LIB([dl], [dlopen], [res="yes"], [res="no"])
 443          if test "x${res}" = "xyes" ; then
 444             AC_CHECK_LIB([dl], [dladdr], [AC_DEFINE(HAVE_DLADDR)])
 445             dlopen_libs="-ldl"
 446          else
 447             AC_MSG_ERROR([Cannot find dlopen])
 448          fi
 449       fi
 450       ;;
 451 esac
 452 AC_SUBST(dlopen_libs)
 453
 454 EFL_CHECK_FNMATCH([], [AC_MSG_ERROR([Cannot find fnmatch()])])
 455
 456 # iconv library
 457 have_iconv="no"
 458 AC_ARG_WITH([iconv-link],
 459    AC_HELP_STRING([--with-iconv-link=ICONV_LINK], [explicitly specify an iconv link option]),
 460    [
 461     LIBS="$withval $LIBS"
 462     have_iconv="yes"
 463    ])
 464
 465 AC_MSG_CHECKING(for explicit iconv link options)
 466 if test "x${iconv_libs}" = "x" ; then
 467    AC_MSG_RESULT([no explicit iconv link option])
 468 else
 469    AC_MSG_RESULT([$iconv_libs])
 470 fi
 471
 472 if test "x${have_iconv}" = "xno" ; then
 473    AC_CHECK_HEADERS([iconv.h], [have_iconv="yes"])
 474
 475    if test "x${have_iconv}" = "xyes" ; then
 476       AC_MSG_CHECKING([whether iconv() is in libc])
 477
 478       AC_LINK_IFELSE(
 479          [AC_LANG_PROGRAM(
 480              [[
 481 #include <stdlib.h>
 482 #include <iconv.h>
 483              ]],
 484              [[
 485 iconv_t ic;
 486 size_t count = iconv(ic, NULL, NULL, NULL, NULL);
 487              ]])],
 488          [have_iconv="yes"],
 489          [have_iconv="no"])
 490
 491       AC_MSG_RESULT([${have_iconv}])
 492    fi
 493
 494    if test "x${have_iconv}" = "xno" ; then
 495       AC_MSG_CHECKING([whether iconv() is in libiconv.a])
 496
 497       LIBS_save="${LIBS}"
 498       LIBS="-liconv $LIBS"
 499       AC_LINK_IFELSE(
 500          [AC_LANG_PROGRAM(
 501              [[
 502 #include <stdlib.h>
 503 #include <iconv.h>
 504              ]],
 505              [[
 506 iconv_t ic;
 507 size_t count;
 508 count = iconv(ic, NULL, NULL, NULL, NULL);
 509              ]])],
 510          [have_iconv="yes"],
 511          [
 512           have_iconv="no"
 513           LIBS=${LIBS_save}
 514          ])
 515
 516       AC_MSG_RESULT([${have_iconv}])
 517    fi
 518
 519    if test "x${have_iconv}" = "xno" ; then
 520       AC_MSG_CHECKING([whether iconv() is in libiconv_plug.a])
 521
 522       LIBS_save="${LIBS}"
 523       LIBS="-liconv_plug $LIBS"
 524       AC_LINK_IFELSE(
 525          [AC_LANG_PROGRAM(
 526              [[
 527 #include <stdlib.h>
 528 #include <iconv.h>
 529              ]],
 530              [[
 531 iconv_t ic;
 532 size_t count = iconv(ic, NULL, NULL, NULL, NULL);
 533              ]])],
 534          [have_iconv="yes"],
 535          [
 536           have_iconv="no"
 537           LIBS=${LIBS_save}
 538          ])
 539
 540       AC_MSG_RESULT([${have_iconv}])
 541    fi
 542 fi
 543
 544 if test "x${have_iconv}" = "xyes" ; then
 545    AC_DEFINE([HAVE_ICONV], [1], [Set to 1 if iconv library is installed])
 546 fi
 547
 548 #check for dirfd API presence
 549 have_dirfd="no"
 550 AC_CHECK_FUNCS([dirfd], [have_dirfd="yes"], [])
 551 if test "x${dirfd}" = "xyes"; then
 552    AC_DEFINE(HAVE_DIRFD)
 553 fi
 554 AC_CHECK_FUNCS([openat], [AC_DEFINE(HAVE_OPENAT)], [])
 555 AC_CHECK_FUNCS([statat], [AC_DEFINE(HAVE_STATAT)], [])
 556 AC_CHECK_FUNCS([fpathconf], [AC_DEFINE(HAVE_FPATHCONF)], [])
 557
 558 ### Modules
 559
 560 if test "x${have_default_mempool}" = "xyes" ; then
 561    enable_chained_pool="no"
 562    enable_pass_through="static"
 563 else
 564    enable_chained_pool="static"
 565    enable_pass_through="no"
 566 fi
 567
 568 enable_one_big="static"
 569
 570 EINA_CHECK_MODULE([chained-pool],   [${enable_chained_pool}], [chained pool])
 571 EINA_CHECK_MODULE([ememoa-fixed],   [${enable_ememoa}],       [ememoa fixed])
 572 EINA_CHECK_MODULE([ememoa-unknown], [${enable_ememoa}],       [ememoa unknown])
 573 EINA_CHECK_MODULE([fixed-bitmap],   [no],                     [fixed bitmap])
 574 EINA_CHECK_MODULE([pass-through],   [${enable_pass_through}], [pass through])
 575 EINA_CHECK_MODULE([buddy],          [no],                     [buddy])
 576 EINA_CHECK_MODULE([one-big],        [${enable_one_big}],      [one big])
 577
 578 ### Make the debug preprocessor configurable
 579
 580 ### Unit tests, coverage and benchmarking
 581
 582 EFL_CHECK_TESTS([enable_tests="yes"], [enable_tests="no"])
 583
 584 EFL_CHECK_COVERAGE([${enable_tests}], [enable_coverage="yes"], [enable_coverage="no"])
 585 EINA_CFLAGS="${EINA_CFLAGS} ${EFL_COVERAGE_CFLAGS}"
 586 EINA_LIBS="${EINA_LIBS} ${EFL_COVERAGE_LIBS}"
 587 if test "x$enable_coverage" = "xyes" ; then
 588    EINA_CFLAGS="${EINA_CFLAGS} ${EFL_DEBUG_CFLAGS}"
 589 fi
 590
 591 EFL_CHECK_BENCHMARK([enable_benchmark="yes"], [enable_benchmark="no"])
 592 EINA_BENCH_MODULE([glib], [${enable_benchmark}], [glib-2.0], [enable_benchmark_glib="yes"], [enable_benchmark_glib="no"])
 593
 594 AC_SUBST(requirement_eina)
 595
 596 ### Create the .pc.in file according to the major version
 597 #cat > ${srcdir}/eina-${VMAJ}.pc.in << EOF
 598 #prefix=@prefix@
 599 #exec_prefix=@exec_prefix@
 600 #libdir=@libdir@
 601 #includedir=@includedir@
 602 #
 603 #Name: Eina
 604 #Description: A Library that implements fast data types and miscellaneous tools
 605 #Requires:
 606 #Version: @VERSION@
 607 #Libs: -L${libdir} -leina
 608 #Libs.private: -ldl
 609 #Cflags: -I${includedir}/eina-@VMAJ@ -I${includedir}/eina-@VMAJ@/eina
 610 #EOF
 611
 612 AC_CONFIG_FILES([
 613 Makefile
 614 eina.pc
 615 eina.spec
 616 doc/Makefile
 617 src/Makefile
 618 src/include/Makefile
 619 src/include/eina_config.h
 620 src/lib/Makefile
 621 src/modules/Makefile
 622 src/modules/mp/Makefile
 623 src/modules/mp/chained_pool/Makefile
 624 src/modules/mp/ememoa_fixed/Makefile
 625 src/modules/mp/ememoa_unknown/Makefile
 626 src/modules/mp/pass_through/Makefile
 627 src/modules/mp/fixed_bitmap/Makefile
 628 src/modules/mp/buddy/Makefile
 629 src/modules/mp/one_big/Makefile
 630 src/tests/Makefile
 631 ])
 632
 633 AC_OUTPUT
 634
 635 #####################################################################
 636 ## Info
 637
 638 echo
 639 echo
 640 echo
 641 echo "------------------------------------------------------------------------"
 642 echo "$PACKAGE $VERSION"
 643 echo "------------------------------------------------------------------------"
 644 echo
 645 echo
 646 echo "Configuration Options Summary:"
 647 echo
 648 echo "  Magic debug..........: ${have_magic_debug}"
 649 echo "  Safety checks........: ${have_safety_checks}"
 650 echo "  Maximum log level....: ${with_max_log_level}"
 651 echo "  Report string usage..: ${have_stringshare_usage}"
 652 echo "  Valgrind support.....: ${have_valgrind}"
 653 echo "  Default mempool......: ${have_default_mempool}"
 654 echo "  Thread Support.......: ${have_threads}"
 655 if test "${have_threads}" = "POSIX" ; then
 656 echo "    spinlock...........: ${have_posix_threads_spinlock}"
 657 echo "    debug usage........: ${have_debug_threads}"
 658 fi
 659 echo "  Amalgamation.........: ${do_amalgamation}"
 660 echo "  Iconv support........: ${have_iconv}"
 661 echo "  File dirfd...........: ${have_dirfd}"
 662 echo
 663 echo "  Documentation........: ${build_doc}"
 664 echo "  Tests................: ${enable_tests}"
 665 echo "  Coverage.............: ${enable_coverage}"
 666 echo "  Benchmark............: ${enable_benchmark}"
 667 if test "x${enable_benchmark}" = "xyes" ; then
 668 echo "    Glib...............: ${enable_benchmark_glib}"
 669 echo "    E17 real data......: ${enable_benchmark_e17}"
 670 fi
 671 echo
 672 echo "  CPU Specific Extensions:"
 673 echo "    MMX................: ${have_mmx}"
 674 echo "    SSE................: ${have_sse}"
 675 echo "    SSE2...............: ${have_sse2}"
 676 echo "    ALTIVEC............: ${have_altivec}"
 677 echo
 678 echo "  Memory pools:"
 679 echo "    Chained pool.......: ${enable_chained_pool}"
 680 echo "    Ememoa fixed.......: ${enable_ememoa_fixed}"
 681 echo "    Ememoa unknown.....: ${enable_ememoa_unknown}"
 682 echo "    Fixed bitmap.......: ${enable_fixed_bitmap}"
 683 echo "    Pass through.......: ${enable_pass_through}"
 684 echo "    Buddy..............: ${enable_buddy}"
 685 echo "    One big............: ${enable_one_big}"
 686 echo
 687 echo "Compilation............: make (or gmake)"
 688 echo "  CPPFLAGS.............: $CPPFLAGS"
 689 echo "  CFLAGS...............: $CFLAGS"
 690 echo "  LDFLAGS..............: $LDFLAGS"
 691 echo
 692 echo "Installation...........: make install (as root if needed, with 'su' or 'sudo')"
 693 echo "  prefix...............: $prefix"
 694 echo
 695 EFL_FORM_VOLTRON