configure.ac

   1 # vim:set et ts=4:
   2 #
   3 # ibus-pinyin - The Chinese PinYin engine for IBus
   4 #
   5 # Copyright (c) 2008-2010 Peng Huang <shawn.p.huang@gmail.com>
   6 #
   7 # This program is free software; you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 2, or (at your option)
  10 # any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program; if not, write to the Free Software
  19 # Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  20
  21 # if not 1, append datestamp to the version number.
  22 m4_define([ibus_released], [1])
  23 m4_define([ibus_major_version], [1])
  24 m4_define([ibus_minor_version], [4])
  25 m4_define([ibus_micro_version], [0])
  26 m4_define(ibus_maybe_datestamp,
  27     m4_esyscmd([if test x]ibus_released[ != x1; then date +.%Y%m%d | tr -d '\n\r'; fi]))
  28
  29 m4_define([ibus_version],
  30     ibus_major_version.ibus_minor_version.ibus_micro_version[]ibus_maybe_datestamp)
  31
  32 AC_INIT([ibus-pinyin], [ibus_version], [http://code.google.com/p/ibus/issues/entry],[ibus-pinyin])
  33 AM_INIT_AUTOMAKE([1.10])
  34 AC_GNU_SOURCE
  35
  36 AC_CONFIG_HEADERS([config.h])
  37 AC_CONFIG_MACRO_DIR([m4])
  38 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  39
  40 # define PACKAGE_VERSION_* variables
  41 AS_VERSION
  42 AS_NANO
  43 AM_SANITY_CHECK
  44 AM_MAINTAINER_MODE
  45 AM_DISABLE_STATIC
  46 AC_PROG_CC
  47 AC_PROG_CXX
  48 AM_PROG_CC_C_O
  49 AC_ISC_POSIX
  50 AC_HEADER_STDC
  51 IT_PROG_INTLTOOL([0.35.0])
  52 AM_PROG_LIBTOOL
  53
  54 # check ibus
  55 PKG_CHECK_MODULES(IBUS, [
  56     ibus-1.0 >= 1.3.99
  57 ])
  58
  59 # check sqlite
  60 PKG_CHECK_MODULES(SQLITE, [
  61     sqlite3
  62 ])
  63 AC_PATH_PROG(SQLITE3, sqlite3)
  64
  65 # check libpinyin
  66 PKG_CHECK_MODULES(LIBPINYIN, [
  67     libpinyin >= 0.2.0
  68 ])
  69
  70 # check uuid
  71 AC_CHECK_FUNCS([uuid_create], [], [
  72     PKG_CHECK_MODULES(LIBUUID, uuid, [
  73         # uuid.pc exist
  74         AC_DEFINE(HAVE_LIBUUID, 1, [Define if found libuuid])
  75         HAVE_LIBUUID=yes
  76     ], [
  77         # uuid.pc does not exist
  78         uuid_old_LIBS=$LIBS
  79         AC_CHECK_HEADERS(uuid/uuid.h, [
  80             AC_SEARCH_LIBS(uuid_generate, uuid, [
  81                 test x"$ac_cv_search_uuid_generate" != x"none required" && LIBUUID_LIBS=$ac_cv_search_uuid_generate
  82                 AC_DEFINE(HAVE_LIBUUID, 1, [Define if found libuuid])
  83                 HAVE_LIBUUID=yes
  84             ], [
  85                 AC_MSG_ERROR([Can not find uuid_create and uuid_generate in libc or libuuid])
  86             ])
  87         ], [
  88             AC_MSG_ERROR([Can not find uuid_create and uuid_generate in libc or libuuid])
  89         ])
  90         LIBS=$uuid_old_LIBS
  91     ])
  92 ])
  93
  94 AM_CONDITIONAL(HAVE_LIBUUID, test x"$HAVE_LIBUUID" = x"yes")
  95
  96 # check if ibus_config_get_values, which is available in ibus-1.3.99+ (git master)
  97 save_CFLAGS="$CFLAGS"
  98 save_LIBS="$LIBS"
  99 CFLAGS="$CFLAGS $IBUS_CFLAGS"
 100 LIBS="$LIBS $IBUS_LIBS"
 101 AC_CHECK_FUNCS([ibus_config_get_values])
 102 CFLAGS="$save_CFLAGS"
 103 LIBS="$save_LIBS"
 104
 105
 106 # check env
 107 AC_PATH_PROG(ENV, env)
 108 AC_SUBST(ENV)
 109
 110 # check python
 111 AM_PATH_PYTHON([2.5])
 112
 113 # --enable-boost
 114 AC_ARG_ENABLE(boost,
 115     AC_HELP_STRING([--enable-boost],
 116         [Use boost to replace stdc++0x.]),
 117         [enable_boost=$enableval],
 118         [enable_boost=no]
 119 )
 120 if test x"$enable_boost" = x"yes"; then
 121     # check boost
 122     BOOST_REQUIRE([1.39])
 123     BOOST_FIND_HEADER([boost/bind.hpp])
 124     BOOST_FIND_HEADER([boost/signals2.hpp])
 125 fi
 126 AM_CONDITIONAL(HAVE_BOOST, test x"$enable_boost" = x"yes")
 127
 128 # --enable-opencc
 129 AC_ARG_ENABLE(opencc,
 130     AC_HELP_STRING([--enable-opencc],
 131         [Use opencc for simplified and traditional Chinese conversion]),
 132         [enable_opencc=$enableval],
 133         [enable_opencc=no]
 134 )
 135 if test x"$enable_opencc" = x"yes"; then
 136     # check opencc
 137     PKG_CHECK_MODULES(OPENCC, [opencc], [
 138         AC_DEFINE(HAVE_OPENCC, 1, [Define if found opencc])
 139     ])
 140 fi
 141
 142 # define GETTEXT_* variables
 143 GETTEXT_PACKAGE=ibus-pinyin
 144 AC_SUBST(GETTEXT_PACKAGE)
 145 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE", [Gettext package])
 146
 147 AM_GLIB_GNU_GETTEXT
 148
 149 # --enable-db-android
 150 AC_ARG_ENABLE(db-android,
 151     AS_HELP_STRING([--disable-db-android],
 152         [do not build database from pinyin in android]),
 153     [enable_db_android=$enableval],
 154     [enable_db_android=yes]
 155 )
 156 AM_CONDITIONAL(IBUS_BUILD_DB_ANDROID, [test x"$enable_db_android" = x"yes" ])
 157
 158 # --enable-db-open-phrase
 159 AC_ARG_ENABLE(db-open-phrase,
 160     AS_HELP_STRING([--enable-db-open-phrase],
 161         [build open-phrase database]),
 162     [enable_db_open_phrase=$enableval],
 163     [enable_db_open_phrase=no]
 164 )
 165 AM_CONDITIONAL(IBUS_BUILD_DB_OPEN_PHRASE, [test x"$enable_db_open_phrase" = x"yes" ])
 166
 167 # --disable-lua-extension
 168 AC_ARG_ENABLE(lua-extension,
 169     AS_HELP_STRING([--disable-lua-extension],
 170          [do not build lua extension]),
 171     [enable_lua_extension=$enableval],
 172     [enable_lua_extension=yes]
 173 )
 174
 175 # check lua
 176 PKG_CHECK_MODULES(LUA, [
 177     lua >= 5.1
 178 ], [],
 179 [has_lua_extension=no]
 180 )
 181
 182 if test x"$has_lua_extension" = x"no";
 183 then
 184     PKG_CHECK_MODULES(LUA, [
 185         lua5.1
 186     ], [],
 187     [enable_lua_extension=no]
 188     );
 189 fi
 190
 191 AM_CONDITIONAL(IBUS_BUILD_LUA_EXTENSION, [test x"$enable_lua_extension" = x"yes"])
 192
 193 # --disable-english-input-mode
 194 AC_ARG_ENABLE(english-input-mode,
 195     AS_HELP_STRING([--disable-english-input-mode],
 196     [do not build english input mode]),
 197     [enable_english_input_mode=$enableval],
 198     [enable_english_input_mode=yes]
 199 )
 200
 201 AM_CONDITIONAL(IBUS_BUILD_ENGLISH_INPUT_MODE, [test x"$enable_english_input_mode" = x"yes"])
 202
 203 # OUTPUT files
 204 AC_CONFIG_FILES([ po/Makefile.in
 205 Makefile
 206 ibus-pinyin.spec
 207 lua/Makefile
 208 src/Makefile
 209 src/pinyin.xml.in
 210 setup/Makefile
 211 setup/ibus-setup-pinyin
 212 setup/version.py
 213 data/Makefile
 214 data/db/Makefile
 215 data/db/android/Makefile
 216 data/db/open-phrase/Makefile
 217 data/icons/Makefile
 218 m4/Makefile
 219 ])
 220
 221 AC_OUTPUT
 222
 223 AC_MSG_RESULT([
 224 Build options:
 225     Version                     $VERSION
 226     Install prefix              $prefix
 227     Use boost                   $enable_boost
 228     Use opencc                  $enable_opencc
 229     Build database android      $enable_db_android
 230     Build database open-phrase  $enable_db_open_phrase
 231     Build lua extension         $enable_lua_extension
 232     Build english input mode    $enable_english_input_mode
 233 ])
 234