configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 m4_pattern_forbid([^MAN_])
   3
   4 # Initialise and check we're in the correct directory.
   5 AC_INIT([man-db], [2.6.4], [cjwatson@debian.org])
   6 AC_CONFIG_AUX_DIR([tools])
   7 AM_INIT_AUTOMAKE([1.11 -Wall -Wno-override -Werror foreign dist-xz no-dist-gzip parallel-tests])
   8 AM_MAINTAINER_MODE
   9 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  10 AC_PREREQ([2.59])
  11 AC_CONFIG_SRCDIR([src/man.c])
  12 AC_GNU_SOURCE
  13 AM_PROG_AR
  14 LT_INIT([disable-static])
  15
  16 if test ! -f "$srcdir/gnulib/po/Makefile.in.in"; then
  17         AC_MSG_ERROR([you must run ./autogen.sh before ./configure when building from revision control])
  18 fi
  19
  20 AC_CONFIG_HEADER([config.h])
  21 AC_CANONICAL_HOST
  22
  23 # Define below date and version information to be put into man pages etc.
  24 date=2013-06-23
  25 AC_SUBST([date])dnl
  26 roff_version=`echo AC_PACKAGE_VERSION | sed 's/-/\\-/g'`
  27 AC_SUBST([roff_version])dnl
  28
  29 # We have to be a bit naughty here and supply options.
  30 # The autoconf literature states that only features that can be separately
  31 # 'built' should use --enable and friends. Oh well...
  32 AC_ARG_ENABLE([setuid],
  33 [AS_HELP_STRING([--enable-setuid[=ARG]], [install man setuid to user ARG [ARG=man]])
  34 AS_HELP_STRING([--disable-setuid], [don't install man setuid])],
  35           [if test "$enableval" = "yes"
  36            then
  37                 enableval=man
  38            fi
  39            if test "$enableval" = "no"
  40            then
  41                 man_owner=
  42                 man_mode="755"
  43                 AC_MSG_NOTICE([Man will not be installed setuid])
  44            else
  45                 man_owner=$enableval
  46                 man_mode="4755"
  47                 AC_MSG_NOTICE([Man will be installed setuid $enableval])
  48                 AC_DEFINE_UNQUOTED([SECURE_MAN_UID], ["$man_owner"],
  49                                    [Define as the setuid owner of man or undefine if not installing setuid.])
  50            fi],
  51           [man_owner=man
  52            man_mode="4755"
  53            AC_DEFINE_UNQUOTED([SECURE_MAN_UID], ["$man_owner"])])
  54 AC_ARG_ENABLE([undoc],
  55 [AS_HELP_STRING([--enable-undoc=COMMAND], [suggest COMMAND for missing manual pages])],
  56         [if test "$enableval" = "yes" || test "$enableval" = "no"
  57          then
  58                 AC_MSG_ERROR([--enable-undoc requires an argument])
  59          else
  60                 AC_MSG_NOTICE([Suggesting '$enableval' for missing manual pages])
  61                 AC_DEFINE_UNQUOTED([UNDOC_COMMAND], ["$enableval"],
  62                                    [Define as the name of a command you want to suggest when a non-existent page is requested.])
  63          fi])
  64 AC_ARG_WITH([device],
  65 [AS_HELP_STRING([--with-device=DEVICE], [use nroff with the output device DEVICE])],
  66         [if test "$withval" = "yes" || test "$withval" = "no"
  67          then
  68                 AC_MSG_ERROR([--with-device requires an argument])
  69          else
  70                 nroff_device=" -T$withval"
  71          fi])
  72 AC_ARG_WITH([db],
  73 [AS_HELP_STRING([--with-db=LIBRARY], [use database library LIBRARY (db5, db4, db3, db2, db1, db, gdbm, ndbm)])],
  74         [if test "$withval" = "yes" || test "$withval" = "no"
  75          then
  76                 AC_MSG_ERROR([--with-db requires an argument])
  77          else
  78                 db=$withval
  79          fi],
  80         [: ${db=no}])
  81 AC_ARG_WITH([config-file],
  82 [AS_HELP_STRING([--with-config-file=CF], [use config file CF [CF=SYSCONFDIR/man_db.conf]])],
  83         [if test "$withval" = "yes" || test "$withval" = "no"
  84          then
  85                 AC_MSG_ERROR([--with-config-file requires an argument])
  86          else
  87                 config_file=$withval
  88          fi],
  89         [: ${config_file=\$\{sysconfdir\}/man_db.conf}])
  90 config_file_basename=${withval##*/}
  91 config_file_dirname=`AS_DIRNAME(["$config_file"])`
  92 AC_ARG_WITH([sections],
  93 [AS_HELP_STRING([--with-sections=SECTIONS], [use manual page sections SECTIONS @<:@1 n l 8 3 0 2 5 4 9 6 7@:>@])],
  94         [if test "$withval" = "yes" || test "$withval" = "no"
  95          then
  96                 AC_MSG_ERROR([--with-sections requires an argument])
  97          else
  98                 sections="$withval"
  99          fi],
 100         [: ${sections=1 n l 8 3 2 5 4 9 6 7}])
 101 AC_ARG_ENABLE([automatic-create],
 102 [AS_HELP_STRING([--enable-automatic-create], [allow man to create user databases on the fly])],
 103         [if test "$enableval" = "yes"
 104          then
 105                 AC_DEFINE([MAN_DB_CREATES], [1], [Allow man to create user databases on the fly.])
 106          fi])
 107 AC_ARG_ENABLE([automatic-update],
 108 [AS_HELP_STRING([--disable-automatic-update], [don't allow man to update databases on the fly])],
 109         [if test "$enableval" = "yes"
 110          then
 111                 AC_DEFINE([MAN_DB_UPDATES], [1], [Allow man to update databases on the fly.])
 112          fi],
 113         [AC_DEFINE([MAN_DB_UPDATES], [1], [Allow man to update databases on the fly.])])
 114 AC_ARG_ENABLE([cats],
 115 [AS_HELP_STRING([--disable-cats], [don't allow man to create/update cat files])],
 116         [if test "$enableval" = "yes"
 117          then
 118                 AC_DEFINE([MAN_CATS], [1], [Allow man to create/update cat files.])
 119          fi],
 120         [AC_DEFINE([MAN_CATS], [1], [Allow man to create/update cat files.])])
 121
 122 # Finish the argument parsing.
 123 AC_SUBST([man_owner])dnl
 124 AC_SUBST([man_mode])dnl
 125 AC_SUBST([config_file])dnl
 126 AC_SUBST([config_file_basename])dnl
 127 AC_SUBST([config_file_dirname])dnl
 128 AC_SUBST([sections])dnl
 129
 130 # Check $PATH for the following programs and append suitable options.
 131 AC_PROG_CC
 132 gl_EARLY
 133 AC_PROG_CPP
 134 CFLAGS="$CFLAGS -Wall"
 135 case $host_os in
 136         ultrix4.3*)
 137                 dnl When compiled for BSD environment, each running `man'
 138                 dnl increases the system load as reported by uptime(1) by
 139                 dnl one.  The reason for this behaviour is currently
 140                 dnl unknown, but the load increase does *not* reflect actual
 141                 dnl resource usage.  To avoid it, compile for POSIX
 142                 dnl environment:
 143                 CFLAGS="$CFLAGS -YPOSIX"
 144                 ;;
 145 esac
 146 if test "$GCC" = yes
 147 then
 148         gl_WARN_ADD([-W])
 149         gl_WARN_ADD([-Wpointer-arith])
 150         gl_WARN_ADD([-Wwrite-strings])
 151         gl_WARN_ADD([-Wstrict-prototypes])
 152         gl_WARN_ADD([-Wshadow])
 153         gl_WARN_ADD([-Wformat-security])
 154         gl_WARN_ADD([-Wredundant-decls])
 155         gl_WARN_ADD([-Wno-missing-field-initializers])
 156 fi
 157 AC_PROG_INSTALL
 158 AC_PROG_LN_S
 159 AC_CHECK_PROGS([cat], [cat])
 160 MAN_CHECK_PROGS([browser], [BROWSER], [use BROWSER as default web browser], [www-browser lynx elinks w3m])
 161 test -n "$browser" && browser="exec $browser"
 162 AC_CHECK_PROGS([tr], [tr])
 163 AC_CHECK_PROGS([grep], [grep])
 164 MAN_CHECK_PROGS([pager], [PAGER], [use PAGER as default pager], [pager less more])
 165 test -n "$pager" && pager="$pager -s"
 166
 167 # Define below (in list of preference) *roff macros to check for.
 168 macros="andoc an doc"
 169
 170 # We have problems here, as different systems have different *roff
 171 # formatters and they accept different options and do different things :(
 172 MAN_CHECK_PROGS([nroff], [NROFF], [use NROFF as roff formatter for character devices], [nroff gnroff groff])
 173 if test -n "$nroff"
 174 then
 175         MAN_PROG_GNU_NROFF([$nroff])
 176         if test "$man_cv_prog_gnu_nroff" != "yes"
 177         then
 178                 MAN_PROG_HEIRLOOM_NROFF([$nroff])
 179         fi
 180         if test -n "$nroff_device"
 181         then
 182                 AC_MSG_CHECKING([that nroff works with argument$nroff_device])
 183                 # We cannot cache this result as it can change between runs
 184                 # of configure.
 185                 if $nroff $nroff_device </dev/null >/dev/null 2>&1 3>&1
 186                 then
 187                         AC_MSG_RESULT([yes])
 188                 else
 189                         AC_MSG_RESULT([no])
 190                         AC_MSG_ERROR([nroff does not work with argument$nroff_device])
 191                 fi
 192         fi
 193         AC_MSG_CHECKING([for appropriate nroff macro])
 194         AC_CACHE_VAL([man_cv_prog_nroff_macro], [
 195
 196         for macro in $macros
 197         do
 198                 if $nroff -m$macro $nroff_device </dev/null >/dev/null 2>&1 3>&1
 199                 then
 200                         man_cv_prog_nroff_macro=-m$macro
 201                         break
 202                 fi
 203         done])
 204
 205         if test -n "$man_cv_prog_nroff_macro"
 206         then
 207                 if test "$man_cv_prog_heirloom_nroff" = "yes"
 208                 then
 209                         # Heirloom works best with some extra options:
 210                         #   -mg: groff compatibility
 211                         #   -msafe: disable privileged operations
 212                         #   -mpadj: clean up line breaking
 213                         man_cv_prog_nroff_macro="-mg -msafe -mpadj ${man_cv_prog_nroff_macro}"
 214                 fi
 215                 nroff="$nroff ${man_cv_prog_nroff_macro}"
 216 dnl             nroff="$nroff ${man_cv_prog_nroff_macro}${nroff_device}"
 217                 AC_MSG_RESULT([$man_cv_prog_nroff_macro])
 218         else
 219                 AC_MSG_RESULT([ambiguous])
 220                 AC_MSG_WARN([please edit include/manconfig.h and add nroff definition])
 221         fi
 222
 223         AC_CACHE_CHECK([whether nroff supports warning control],
 224                        [man_cv_prog_nroff_warnings], [
 225                 if test "x$troff_is_groff" = xyes && \
 226                    nroff -wmac </dev/null >/dev/null 2>&1
 227                 then
 228                         man_cv_prog_nroff_warnings=yes
 229                 else
 230                         man_cv_prog_nroff_warnings=no
 231                 fi])
 232         if test "x$man_cv_prog_nroff_warnings" = xyes; then
 233                 AC_DEFINE([NROFF_WARNINGS], [1],
 234                           [Define if nroff supports warning control.])
 235         fi
 236 else
 237         AC_MSG_WARN([Cannot find an nroff-like program, formatting of manual page source will not be supported.])
 238         nroff="(nroff not installed)"
 239         AC_DEFINE([NROFF_MISSING], [1], [Define if you don't have nroff.])
 240 fi
 241
 242 dnl It would be nice to use MAN_CHECK_PROGS here, but how do we determine
 243 dnl TROFF_IS_GROFF?
 244 AC_CHECK_PROGS([troff], [groff])
 245 if test -n "$troff"
 246 then
 247         troff_is_groff=yes
 248         AC_DEFINE([TROFF_IS_GROFF], [1], [Define if you are using groff as troff.])
 249         TROFF=groff
 250 else
 251         troff_is_groff=no
 252         AC_CHECK_PROGS([troff], [troff gtroff])
 253         TROFF=troff
 254 fi
 255 AC_SUBST([TROFF])
 256 if test -n "$troff"
 257 then
 258         AC_DEFINE([HAS_TROFF], [1], [Define if you have troff.])
 259         AC_MSG_CHECKING([for appropriate $TROFF options])
 260         AC_CACHE_VAL([man_cv_prog_troff_options], [
 261         # Do a quick test to see if -t works [AIX needs this], groff doesn't
 262         # as it indicates pre-process with tbl.
 263         test "$TROFF" = "troff" && $troff -t </dev/null >/dev/null 2>&1 3>&1 \
 264                                 && troff_filter="-t "
 265         for macro in $macros
 266         do
 267                 if $troff $troff_filter -m$macro </dev/null >/dev/null 2>&1 3>&1
 268                 then
 269                         man_cv_prog_troff_options="${troff_filter}-m${macro}"
 270                         break
 271                 fi
 272         done])
 273         if test -n "$man_cv_prog_troff_options"
 274         then
 275                 if test "$man_cv_prog_heirloom_nroff" = "yes"
 276                 then
 277                         # Heirloom works best with some extra options:
 278                         #   -mg: groff compatibility
 279                         #   -msafe: disable privileged operations
 280                         #   -mpadj: clean up line breaking
 281                         man_cv_prog_troff_options="-mg -msafe -mpadj ${man_cv_prog_troff_options}"
 282                 fi
 283                 troff="$troff $man_cv_prog_troff_options"
 284                 AC_MSG_RESULT([$man_cv_prog_troff_options])
 285         else
 286                 AC_MSG_RESULT([ambiguous])
 287                 AC_MSG_WARN([please edit include/manconfig.h and add troff definition])
 288         fi
 289 else
 290         troff="(troff not installed)"
 291 fi
 292
 293 AC_CHECK_PROGS([preconv], [gpreconv preconv])
 294
 295 AC_MSG_CHECKING([for groff with Debian multibyte patch or real Unicode support])
 296 man_mb_groff=no
 297 AC_ARG_ENABLE([mb-groff],
 298 [AS_HELP_STRING([--enable-mb-groff], [expect groff with Debian multibyte patch or real Unicode support])],
 299         [if test "$enableval" = "yes"
 300          then
 301                 man_mb_groff=yes
 302          fi],
 303         [if test -n "$preconv"
 304          then
 305                 man_mb_groff=yes
 306          elif test -n "$troff" && test "$troff_is_groff" = "yes"
 307          then
 308                 if $troff -Tnippon </dev/null >/dev/null 2>&1
 309                 then
 310                         man_mb_groff=yes
 311                 fi
 312          fi])
 313 AC_MSG_RESULT([$man_mb_groff])
 314 if test "$man_mb_groff" = "yes"
 315 then
 316         AC_DEFINE([MULTIBYTE_GROFF], 1,
 317                   [Define if your groff installation has the Debian multibyte patch.])
 318 fi
 319
 320 MAN_CHECK_PROGS([eqn], [EQN], [use EQN to preprocess equations], [eqn geqn])
 321 MAN_CHECK_PROGS([neqn], [NEQN], [use NEQN to preprocess equations for character devices], [neqn gneqn])
 322 # If we fail to find an neqn, use eqn and try to force it to output for an
 323 # ascii device. As this is only relevant for equations (?), not using latin1
 324 # should be acceptable. -Tlatin1 is ignored by some eqn implementations.
 325 if test -z "$neqn"
 326 then
 327         test -n "$eqn" &&
 328         (test -n "$nroff_device" && neqn="$eqn -T$nroff_device" || neqn="$eqn -Tascii")
 329 fi
 330 MAN_CHECK_PROGS([tbl], [TBL], [use TBL to preprocess tables], [tbl gtbl])
 331 TBL_X_FORMAT=
 332 if test -n "$tbl"
 333 then
 334         AC_CACHE_CHECK([whether tbl supports the 'x' format character],
 335                        [man_cv_tbl_x_format], [
 336                 if (echo .TS; echo ';'; echo lx.; echo SENTINEL; echo .TE) | \
 337                    $tbl 2>/dev/null | grep SENTINEL >/dev/null 2>&1
 338                 then
 339                         man_cv_tbl_x_format=yes
 340                 else
 341                         man_cv_tbl_x_format=no
 342                 fi])
 343         if test "x$man_cv_tbl_x_format" = xyes
 344         then
 345                 TBL_X_FORMAT=x
 346         fi
 347 fi
 348 AC_SUBST([TBL_X_FORMAT])
 349 MAN_CHECK_PROGS([col], [COL], [use COL to filter formatting characters from output], [col gcol])
 350 MAN_CHECK_PROGS([vgrind], [VGRIND], [use VGRIND to preprocess program sources], [vgrind gvgrind])
 351 MAN_CHECK_PROGS([refer], [REFER], [use REFER to preprocess bibliographic references], [refer grefer])
 352 MAN_CHECK_PROGS([grap], [GRAP], [use GRAP to preprocess graphs], [grap])
 353 MAN_CHECK_PROGS([pic], [PIC], [use PIC to preprocess pictures], [pic gpic])
 354 test -n "$pic" && pic="$pic -S"
 355
 356 MAN_CHECK_PROGS([gzip], [GZIP], [use GZIP as GNU compression utility], [gzip])
 357 if test -n "$gzip"
 358 then
 359         gunzip="$gzip -dc"
 360         compressor="$gzip -c7"
 361         compress_ext="gz"
 362 fi
 363 MAN_CHECK_PROGS([compress], [COMPRESS], [use COMPRESS as UNIX compression utility], [compress])
 364 if test -n "$compress"
 365 then
 366         uncompress="$compress -dc"
 367         if test -z "$gzip"
 368         then
 369                 compressor="$compress -c"
 370                 compress_ext="Z"
 371         fi
 372 fi
 373 MAN_CHECK_PROGS([bzip2], [BZIP2], [use BZIP2 as block-sorting compression utility], [bzip2])
 374 if test -n "$bzip2"
 375 then
 376         bunzip2="$bzip2 -dc"
 377 fi
 378 MAN_CHECK_PROGS([xz], [XZ], [use XZ as Lempel-Ziv-Markov chain-Algorithm compression utility], [xz])
 379 if test -n "$xz"
 380 then
 381         unxz="$xz -dc"
 382         unlzma=
 383 else
 384         dnl lzma not used/needed if we have xz
 385         MAN_CHECK_PROGS([lzma], [LZMA], [use LZMA as Lempel-Ziv-Markov chain-Algorithm compression utility], [lzma])
 386         if test -n "$lzma"
 387         then
 388                 unlzma="$lzma -dc"
 389         fi
 390 fi
 391 MAN_CHECK_PROGS([lzip], [LZIP], [use LZIP as Lempel-Ziv-Markov chain-Algorithm compression utility], [lzip])
 392 if test -n "$lzip"
 393 then
 394         unlzip="$lzip -dc"
 395 fi
 396 if test -n "$gzip" || test -n "$compress" || test -n "$bzip2" || test -n "$xz" || test -n "$lzip" || test -n "$lzma"
 397 then
 398         AC_DEFINE([COMP_CAT], [1], [Define if you have compressors and want to support compressed cat files.])
 399         AC_DEFINE([COMP_SRC], [1], [Define if you have compressors and want to support compressed manual source.])
 400 fi
 401 AC_SUBST([compressor])
 402 AC_SUBST([compress_ext])
 403 AC_SUBST([gunzip])
 404 AC_SUBST([uncompress])
 405 AC_SUBST([bunzip2])
 406 AC_SUBST([unlzma])
 407 AC_SUBST([unxz])
 408 AC_SUBST([unlzip])
 409 MAN_COMPRESS_LIB([z], [gzopen])
 410 dnl To add more decompressors just follow the scheme above.
 411
 412 # Work out which manual page hierarchy scheme might be in use.
 413 AC_ARG_ENABLE([mandirs],
 414 [AS_HELP_STRING([--enable-mandirs=OS], [select manual page hierarchy organization (GNU, HPUX, IRIX, Solaris, BSD)])],
 415         [AC_MSG_NOTICE([Using $enableval hierarchy organization(s)])
 416          AC_DEFINE_UNQUOTED([MANDIR_LAYOUT], ["$enableval"],
 417                             [Define to the manual page hierarchy organization(s) in use.])
 418          MANDIR_LAYOUT="$enableval"],
 419         [case $host in
 420                 *-gnu)          mandirs=GNU;;
 421                 *-hpux*)        mandirs=HPUX;;
 422                 *-irix*)        mandirs=IRIX;;
 423                 *-solaris*)     mandirs=Solaris;;
 424                 *-*bsd*)        mandirs=BSD;;
 425                 *)              mandirs=;;
 426          esac
 427          if test -n "$mandirs"; then
 428                 AC_MSG_NOTICE([Using $mandirs hierarchy organization])
 429                 AC_DEFINE_UNQUOTED([MANDIR_LAYOUT], ["$mandirs"])
 430                 MANDIR_LAYOUT="$mandirs"
 431          else
 432                 AC_MSG_NOTICE([Allowing any hierarchy organization])
 433                 AC_DEFINE([MANDIR_LAYOUT], [""])
 434                 MANDIR_LAYOUT=
 435          fi])
 436 AC_SUBST([MANDIR_LAYOUT])
 437
 438 # Check for various header files and associated libraries.
 439 AC_ISC_POSIX
 440 dnl AC_PROG_LEX calls AC_TRY_LINK: must come after above 3
 441 AC_PROG_LEX
 442 gl_INIT
 443 AC_HEADER_DIRENT
 444 AC_CHECK_HEADERS([fcntl.h sys/file.h])
 445
 446 # Internationalization support.
 447 AM_GNU_GETTEXT([external])
 448 AM_GNU_GETTEXT_VERSION([0.18.1])
 449 AC_SUBST([LINGUAS])
 450 AM_ICONV
 451 MAN_PO4A
 452 MAN_LINGUAS
 453
 454 # Checks for structures and compiler characteristics.
 455 AC_C_CONST
 456 AC_C_INLINE
 457 AC_TYPE_PID_T
 458 AC_TYPE_UID_T
 459 AC_TYPE_SIZE_T
 460
 461 # Check for pipeline library.
 462 PKG_CHECK_MODULES([libpipeline], [libpipeline >= 1.1.0])
 463
 464 # Find a suitable database interface header and library.
 465 #
 466 # Check for GNU dbm routines.
 467 if test "$db" = "no" || test "$db" = "gdbm"
 468 then
 469   AC_CHECK_HEADER([gdbm.h], [
 470     for lib in gdbm c dbm
 471     do
 472       AC_CHECK_LIB([$lib], [gdbm_fetch],
 473                    test "$lib" = "c" || DBLIBS="-l$lib"
 474                    [AC_DEFINE([GDBM], [1], [Define if you have, and want to use, gdbm interface routines.])
 475                     AC_SUBST([DBTYPE], [gdbm])]
 476                    db=yes, db=no)
 477       if test "$db" = "yes"
 478       then
 479         man_save_LIBS="$LIBS"
 480         LIBS="$LIBS $DBLIBS"
 481         AC_CHECK_FUNCS([gdbm_exists])
 482         LIBS="$man_save_LIBS"
 483         break
 484       fi
 485     done], db=no)
 486 fi
 487
 488 # Check for Berkeley db routines (first version API).
 489 MAN_CHECK_BDB([db5 db], [db5/db_185.h db_185.h], [db5 db-5])
 490 MAN_CHECK_BDB([db4 db], [db4/db_185.h db_185.h], [db4 db-4])
 491 MAN_CHECK_BDB([db3 db], [db3/db_185.h db_185.h], [db3])
 492 MAN_CHECK_BDB([db2 db], [db_185.h db2/db_185.h db2_185.h], [db2 db])
 493 MAN_CHECK_BDB([db1 db], [db/db.h db.h db1/db.h], [db db1 c])
 494
 495 dnl MAN_CHECK_BDB([db2], [db2_185.h], [db2 db c], [AC_DEFINE(DB_ON_LIBC)])
 496 dnl MAN_CHECK_BDB([db2], [db2/db_185.h], [db2 db c])
 497
 498 # Check for UNIX ndbm routines.
 499 if test "$db" = "no" || test "$db" = "ndbm"
 500 then
 501   AC_CHECK_HEADER([ndbm.h], [
 502     for lib in ndbm c dbm
 503     do
 504       AC_CHECK_LIB([$lib], [dbm_fetch],
 505                    test "$lib" = "c" || DBLIBS="-l$lib"
 506                    [AC_DEFINE([NDBM], [1], [Define if you have, and want to use, ndbm interface routines.])
 507                     AC_SUBST([DBTYPE], [ndbm])]
 508                    db=yes, db=no)
 509       test "$db" = "yes" && break
 510       done], db=no)
 511 fi
 512
 513 if test "$db" != "yes"
 514 then
 515     if test "$db" = "no"
 516     then
 517       AC_MSG_ERROR([Fatal: no supported database library/header found])
 518     else
 519       AC_MSG_ERROR([Fatal: $db: unsupported database library])
 520     fi
 521 fi
 522 AC_SUBST([DBLIBS])
 523
 524 dnl MAN_ECHO_VAR(ENV-VARIABLE)
 525 define([MAN_ECHO_VAR], [AC_MSG_NOTICE([default $1 = "$$1"])])dnl
 526 dnl
 527 MAN_ECHO_VAR([CC])
 528 MAN_ECHO_VAR([CPP])
 529 MAN_ECHO_VAR([CPPFLAGS])
 530 MAN_ECHO_VAR([CFLAGS])
 531 MAN_ECHO_VAR([LDFLAGS])
 532 MAN_ECHO_VAR([LIBS])
 533 MAN_ECHO_VAR([DBLIBS])
 534
 535 # Transformed versions of program names for use in Automake variables.
 536 MAN_TRANS_SUBST([apropos])
 537 MAN_TRANS_SUBST([catman])
 538 MAN_TRANS_SUBST([lexgrog])
 539 MAN_TRANS_SUBST([man])
 540 MAN_TRANS_SUBST([manconv])
 541 MAN_TRANS_SUBST([mandb])
 542 MAN_TRANS_SUBST([manpath])
 543 MAN_TRANS_SUBST([whatis])
 544 MAN_TRANS_SUBST([zsoelim])
 545
 546 # If we're cross-compiling, tests won't work.
 547 AM_CONDITIONAL([CROSS_COMPILING], [test "x$cross_compiling" = xyes])
 548
 549 AC_CONFIG_FILES([Makefile
 550         gnulib/lib/Makefile
 551         gnulib/po/Makefile.in
 552         lib/Makefile
 553         src/Makefile
 554         src/man_db.conf
 555         src/tests/Makefile
 556         man/Makefile
 557         man/replace.sin
 558         man/po4a/Makefile
 559         man/da/Makefile
 560         man/de/Makefile
 561         man/es/Makefile
 562         man/fr/Makefile
 563         man/id/Makefile
 564         man/it/Makefile
 565         man/ja/Makefile
 566         man/nl/Makefile
 567         man/pl/Makefile
 568         man/ru/Makefile
 569         man/zh_CN/Makefile
 570         manual/Makefile
 571         libdb/Makefile
 572         docs/Makefile
 573         tools/Makefile
 574         include/comp_src.h
 575         include/manconfig.h
 576         po/Makefile.in])
 577 AC_OUTPUT