configure.ac

   1 # Copyright (c) 2007 Intel Corporation. All Rights Reserved.
   2 #
   3 # Permission is hereby granted, free of charge, to any person obtaining a
   4 # copy of this software and associated documentation files (the
   5 # "Software"), to deal in the Software without restriction, including
   6 # without limitation the rights to use, copy, modify, merge, publish,
   7 # distribute, sub license, and/or sell copies of the Software, and to
   8 # permit persons to whom the Software is furnished to do so, subject to
   9 # the following conditions:
  10 #
  11 # The above copyright notice and this permission notice (including the
  12 # next paragraph) shall be included in all copies or substantial portions
  13 # of the Software.
  14 #
  15 # THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS
  16 # OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
  17 # MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NON-INFRINGEMENT.
  18 # IN NO EVENT SHALL PRECISION INSIGHT AND/OR ITS SUPPLIERS BE LIABLE FOR
  19 # ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT,
  20 # TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE
  21 # SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
  22
  23 # VA-API version
  24 # - increment major for any ABI change (which shall not occur!)
  25 # - increment minor for any interface change (e.g. new/modified function)
  26 # - increment micro for any other change (new flag, new codec definition, etc.)
  27 # - reset micro version to zero when minor version is incremented
  28 # - reset minor version to zero when major version is incremented
  29 m4_define([va_api_major_version], [0])
  30 m4_define([va_api_minor_version], [33])
  31 m4_define([va_api_micro_version], [0])
  32
  33 m4_define([va_api_version],
  34           [va_api_major_version.va_api_minor_version.va_api_micro_version])
  35
  36 # libva package version number, (as distinct from shared library version)
  37 # XXX: we want the package version to remain at 1.0.x for VA-API 0.32.y
  38 #
  39 # - major version is automatically generated from VA-API major version
  40 # - minor version is automatically generated from VA-API minor version
  41 # - increment micro for any library release
  42 # - reset micro version to zero when VA-API major or minor version is changed
  43 m4_define([libva_major_version], [m4_eval(va_api_major_version + 1)])
  44 m4_define([libva_minor_version], [m4_eval(va_api_minor_version - 32)])
  45 m4_define([libva_micro_version], [0])
  46 m4_define([libva_pre_version],   [1])
  47
  48 m4_define([libva_version],
  49           [libva_major_version.libva_minor_version.libva_micro_version])
  50 m4_if(libva_pre_version, [0], [], [
  51 m4_append([libva_version], libva_pre_version, [.pre])
  52 ])
  53
  54 # libva library version number (generated, do not change)
  55 # XXX: we want the SONAME to remain at libva.so.1 for VA-API major == 0
  56 #
  57 # The library name is generated libva.<x>.<y>.0 where
  58 # <x> = VA-API major version + 1
  59 # <y> = 100 * VA-API minor version + VA-API micro version
  60 #
  61 # For example:
  62 # VA-API 0.32.0 generates libva.so.1.3200.0
  63 # VA-API 0.34.1 generates libva.so.1.3401.0
  64 # VA-API 1.2.13 generates libva.so.2.213.0
  65 m4_define([libva_interface_bias], [m4_eval(va_api_major_version + 1)])
  66 m4_define([libva_interface_age],  [0])
  67 m4_define([libva_binary_age],
  68           [m4_eval(100 * va_api_minor_version + va_api_micro_version - libva_interface_age)])
  69
  70 m4_define([libva_lt_current],
  71           [m4_eval(100 * va_api_minor_version + va_api_micro_version + libva_interface_bias)])
  72 m4_define([libva_lt_revision],
  73           [m4_eval(libva_interface_age)])
  74 m4_define([libva_lt_age],
  75           [m4_eval(libva_binary_age - libva_interface_age)])
  76
  77 # libdrm minimun version requirement
  78 m4_define([libdrm_version], [2.4])
  79
  80 AC_PREREQ(2.57)
  81 AC_INIT([libva], [libva_version], [waldo.bastian@intel.com], libva)
  82 AC_CONFIG_SRCDIR([Makefile.am])
  83 AC_CONFIG_MACRO_DIR([m4])
  84 AM_INIT_AUTOMAKE([dist-bzip2])
  85
  86 AM_CONFIG_HEADER([config.h])
  87 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  88
  89 VA_API_MAJOR_VERSION=va_api_major_version
  90 VA_API_MINOR_VERSION=va_api_minor_version
  91 VA_API_MICRO_VERSION=va_api_micro_version
  92 VA_API_VERSION=va_api_version
  93 AC_SUBST(VA_API_MAJOR_VERSION)
  94 AC_SUBST(VA_API_MINOR_VERSION)
  95 AC_SUBST(VA_API_MICRO_VERSION)
  96 AC_SUBST(VA_API_VERSION)
  97
  98 LIBVA_MAJOR_VERSION=libva_major_version
  99 LIBVA_MINOR_VERSION=libva_minor_version
 100 LIBVA_MICRO_VERSION=libva_micro_version
 101 LIBVA_VERSION=libva_version
 102 AC_SUBST(LIBVA_MAJOR_VERSION)
 103 AC_SUBST(LIBVA_MINOR_VERSION)
 104 AC_SUBST(LIBVA_MICRO_VERSION)
 105 AC_SUBST(LIBVA_VERSION)
 106
 107 LIBVA_LT_CURRENT=libva_lt_current
 108 LIBVA_LT_REV=libva_lt_revision
 109 LIBVA_LT_AGE=libva_lt_age
 110 LIBVA_LT_VERSION="$LIBVA_LT_CURRENT:$LIBVA_LT_REV:$LIBVA_LT_AGE"
 111 LIBVA_LT_LDFLAGS="-version-info $LIBVA_LT_VERSION"
 112 AC_SUBST(LIBVA_LT_VERSION)
 113 AC_SUBST(LIBVA_LT_LDFLAGS)
 114
 115 AC_ARG_ENABLE(docs,
 116     [AC_HELP_STRING([--enable-docs],
 117                     [build Doxygen documentation @<:@default=no@:>@])],
 118     [], [enable_docs="no"])
 119
 120 AC_ARG_ENABLE(drm,
 121     [AC_HELP_STRING([--enable-drm],
 122                     [build with VA/DRM API support @<:@default=yes@:>@])],
 123     [], [enable_drm="yes"])
 124
 125 AC_ARG_ENABLE(x11,
 126     [AC_HELP_STRING([--enable-x11],
 127                     [build with VA/X11 API support @<:@default=yes@:>@])],
 128     [], [enable_x11="yes"])
 129
 130 AC_ARG_ENABLE(glx,
 131     [AC_HELP_STRING([--enable-glx],
 132                     [build with VA/GLX API support @<:@default=yes@:>@])],
 133     [], [enable_glx="yes"])
 134
 135 AC_ARG_ENABLE(egl,
 136     [AC_HELP_STRING([--enable-egl],
 137                     [build with VA/EGL API support @<:@default=yes@:>@])],
 138     [], [enable_egl="yes"])
 139
 140 AC_ARG_ENABLE([wayland],
 141     [AC_HELP_STRING([--enable-wayland],
 142                     [build with VA/Wayland API support @<:@default=yes@:>@])],
 143     [], [enable_wayland="yes"])
 144
 145 AC_ARG_ENABLE(dummy-driver,
 146     [AC_HELP_STRING([--enable-dummy-driver],
 147                     [build dummy video driver @<:@default=yes@:>@])],
 148     [], [enable_dummy_driver="yes"])
 149 AM_CONDITIONAL(BUILD_DUMMY_DRIVER, test x$enable_dummy_driver = xyes)
 150
 151 AC_ARG_ENABLE(dummy-backend,
 152     [AC_HELP_STRING([--enable-dummy-backend],
 153                     [build dummy libva backend])],
 154     [], [enable_dummy_backend="no"])
 155
 156 AC_ARG_WITH(drivers-path,
 157     [AC_HELP_STRING([--with-drivers-path=[[path]]],
 158                     [drivers path])],
 159     [], [with_drivers_path="$libdir/dri"])
 160
 161 LIBVA_DRIVERS_PATH="$with_drivers_path"
 162 AC_SUBST(LIBVA_DRIVERS_PATH)
 163
 164 AC_DISABLE_STATIC
 165 AC_PROG_LIBTOOL
 166 AC_PROG_CC
 167 AC_PROG_CXX
 168 AM_PROG_CC_C_O
 169 PKG_PROG_PKG_CONFIG
 170
 171 AC_HEADER_STDC
 172 AC_SYS_LARGEFILE
 173
 174 # Check for Doxygen
 175 if test "$enable_docs" = "yes"; then
 176     AC_CHECK_TOOL([DOXYGEN], [doxygen], [enable_docs="no"])
 177 fi
 178 AM_CONDITIONAL(ENABLE_DOCS, test "$enable_docs" = "yes")
 179
 180 # Check for __attribute__((visibility()))
 181 AC_CACHE_CHECK([whether __attribute__((visibility())) is supported],
 182     ac_cv_have_gnuc_visibility_attribute,
 183     [cat > conftest.c <<EOF
 184 int foo __attribute__ ((visibility ("hidden"))) = 1;
 185 int bar __attribute__ ((visibility ("protected"))) = 1;
 186 EOF
 187     ac_cv_have_gnuc_visibility_attribute="no"
 188     if ${CC-cc} -Werror -S conftest.c -o conftest.s >/dev/null 2>&1; then
 189         if grep '\.hidden.*foo' conftest.s >/dev/null; then
 190             if grep '\.protected.*bar' conftest.s >/dev/null; then
 191                 ac_cv_have_gnuc_visibility_attribute="yes"
 192             fi
 193         fi
 194     fi
 195     rm -f conftest.[cs]
 196 ])
 197 if test "$ac_cv_have_gnuc_visibility_attribute" = "yes"; then
 198     AC_DEFINE([HAVE_GNUC_VISIBILITY_ATTRIBUTE], [1],
 199               [Defined to 1 if GCC visibility attribute is supported])
 200 fi
 201
 202 # Dummy backend
 203 if test x$enable_dummy_backend = xyes; then
 204     PKG_CHECK_MODULES([UDEV], [libudev], [libudev=yes], [libudev=no])
 205 fi
 206 if test x$libudev = xno; then
 207    enable_dummy_backend=no
 208 fi
 209 AM_CONDITIONAL(BUILD_DUMMY_BACKEND, test x$enable_dummy_backend = xyes)
 210
 211 # Check for DRM (mandatory)
 212 LIBDRM_VERSION=libdrm_version
 213 PKG_CHECK_MODULES([DRM], [libdrm >= $LIBDRM_VERSION])
 214 AC_SUBST(LIBDRM_VERSION)
 215
 216 USE_DRM="no"
 217 if test "$enable_drm" = "yes"; then
 218     USE_DRM="yes"
 219     AC_DEFINE([HAVE_VA_DRM], [1], [Defined to 1 if VA/DRM API is built])
 220 fi
 221 AM_CONDITIONAL(USE_DRM, test "$USE_DRM" = "yes")
 222
 223 # Check for X11
 224 USE_X11="no"
 225 if test "$enable_x11" = "yes"; then
 226     USE_X11="yes"
 227     PKG_CHECK_MODULES([X11],    [x11],    [:], [USE_X11="no"])
 228     PKG_CHECK_MODULES([XEXT],   [xext],   [:], [USE_X11="no"])
 229     PKG_CHECK_MODULES([XFIXES], [xfixes], [:], [USE_X11="no"])
 230     if test "$USE_X11" = "yes"; then
 231         AC_DEFINE([HAVE_VA_X11], [1], [Defined to 1 if VA/X11 API is built])
 232     fi
 233 fi
 234 AM_CONDITIONAL(USE_X11, test "$USE_X11" = "yes")
 235
 236 # Check for GLX
 237 USE_GLX="no"
 238 if test "$USE_X11:$enable_glx" = "yes:yes"; then
 239     PKG_CHECK_MODULES([GLX], [gl x11], [USE_GLX="yes"], [:])
 240     saved_CPPFLAGS="$CPPFLAGS"
 241     saved_LIBS="$LIBS"
 242     CPPFLAGS="$CPPFLAGS $GLX_CFLAGS"
 243     LIBS="$LIBS $GLX_LIBS"
 244     AC_CHECK_HEADERS([GL/gl.h GL/glx.h], [:], [USE_GLX="no"])
 245     AC_CHECK_LIB([GL], [glXCreateContext], [:] [USE_GLX="no"])
 246     CPPFLAGS="$saved_CPPFLAGS"
 247     LIBS="$saved_LIBS"
 248     if test "$USE_GLX" = "yes"; then
 249         AC_DEFINE([HAVE_VA_GLX], [1], [Defined to 1 if VA/GLX API is built])
 250     fi
 251 fi
 252 AM_CONDITIONAL(USE_GLX, test "$USE_GLX" = "yes")
 253
 254 # Check for EGL
 255 USE_EGL="no"
 256 if test "$enable_egl" = "yes"; then
 257     PKG_CHECK_MODULES([EGL], [egl], [USE_EGL="yes"], [:])
 258     saved_CPPFLAGS="$CPPFLAGS"
 259     saved_LIBS="$LIBS"
 260     CPPFLAGS="$CPPFLAGS $EGL_CFLAGS"
 261     LIBS="$LIBS $EGL_LIBS"
 262     AC_CHECK_HEADERS([EGL/egl.h], [:], [USE_EGL="no"])
 263     AC_CHECK_LIB([EGL], [eglGetDisplay], [:], [USE_EGL="no"])
 264     CPPFLAGS="$saved_CPPFLAGS"
 265     LIBS="$saved_LIBS"
 266     if test "$USE_EGL" = "yes"; then
 267         AC_DEFINE([HAVE_VA_EGL], [1], [Defined to 1 if VA/EGL API is built])
 268     fi
 269 fi
 270 AM_CONDITIONAL(USE_EGL, test "$USE_EGL" = "yes")
 271
 272 # Check for Wayland
 273 USE_WAYLAND="no"
 274 if test "$enable_wayland" = "yes"; then
 275     PKG_CHECK_MODULES([WAYLAND], [wayland-client], [USE_WAYLAND="yes"], [:])
 276     if test "$USE_WAYLAND" = "yes"; then
 277         AC_DEFINE([HAVE_VA_WAYLAND], [1],
 278                   [Defined to 1 if VA/Wayland API is built])
 279     fi
 280 fi
 281 AM_CONDITIONAL(USE_WAYLAND, test "$USE_WAYLAND" = "yes")
 282
 283 m4_ifdef([WAYLAND_SCANNER_RULES],
 284     [WAYLAND_SCANNER_RULES(['$(top_srcdir)/va/wayland/protocol'])],
 285     [wayland_scanner_rules=""; AC_SUBST(wayland_scanner_rules)])
 286
 287 pkgconfigdir=${libdir}/pkgconfig
 288 AC_SUBST(pkgconfigdir)
 289
 290 # Check for builds without backend
 291 if test "$USE_DRM:$USE_X11:$USE_WAYLAND" = "no:no:no"; then
 292     AC_MSG_ERROR([Please select at least one backend (DRM, X11, Wayland)])
 293 fi
 294
 295 AC_OUTPUT([
 296     Makefile
 297     debian.upstream/Makefile
 298     doc/Makefile
 299     dummy_drv_video/Makefile
 300     pkgconfig/Makefile
 301     pkgconfig/libva-drm.pc
 302     pkgconfig/libva-egl.pc
 303     pkgconfig/libva-glx.pc
 304     pkgconfig/libva-tpi.pc
 305     pkgconfig/libva-wayland.pc
 306     pkgconfig/libva-x11.pc
 307     pkgconfig/libva.pc
 308     test/Makefile
 309     test/basic/Makefile
 310     test/common/Makefile
 311     test/decode/Makefile
 312     test/encode/Makefile
 313     test/putsurface/Makefile
 314     test/vainfo/Makefile
 315     test/v4l_h264/Makefile
 316     test/v4l_h264/encode/Makefile
 317     test/v4l_h264/decode/Makefile
 318     va/Makefile
 319     va/drm/Makefile
 320     va/dummy/Makefile
 321     va/egl/Makefile
 322     va/glx/Makefile
 323     va/va_version.h
 324     va/wayland/Makefile
 325     va/wayland/protocol/Makefile
 326     va/x11/Makefile
 327 ])
 328
 329 # Print a small summary
 330 BACKENDS=""
 331 AS_IF([test x$USE_DRM = xyes], [BACKENDS="$BACKENDS drm"])
 332 AS_IF([test x$USE_X11 = xyes], [BACKENDS="$BACKENDS x11"])
 333 AS_IF([test x$USE_GLX = xyes], [BACKENDS="$BACKENDS glx"])
 334 AS_IF([test x$USE_EGL = xyes], [BACKENDS="$BACKENDS egl"])
 335 AS_IF([test x$USE_WAYLAND = xyes], [BACKENDS="$BACKENDS wayland"])
 336
 337 echo
 338 echo "libva - ${LIBVA_VERSION} (VA-API ${VA_API_VERSION})"
 339 echo
 340 echo Installation prefix .............. : $prefix
 341 echo Default driver path .............. : $LIBVA_DRIVERS_PATH
 342 echo Extra window systems ............. : $BACKENDS
 343 echo Build dummy driver ............... : $enable_dummy_driver
 344 echo Build documentation .............. : $enable_docs
 345 echo