configure.ac

   1 # gstreamer-vaapi package version number
   2 m4_define([gst_vaapi_major_version], [0])
   3 m4_define([gst_vaapi_minor_version], [3])
   4 m4_define([gst_vaapi_micro_version], [0])
   5 m4_define([gst_vaapi_version],
   6           [gst_vaapi_major_version.gst_vaapi_minor_version.gst_vaapi_micro_version])
   7
   8 # gst version number
   9 m4_define([gst_major_version], [0])
  10 m4_define([gst_minor_version], [10])
  11 m4_define([gst_micro_version], [10])
  12 m4_define([gst_major_minor_version],
  13           [gst_major_version.gst_minor_version])
  14 m4_define([gst_version],
  15           [gst_major_version.gst_minor_version.gst_micro_version])
  16
  17 # gst plugins-base version number
  18 m4_define([gst_plugins_base_major_version], [0])
  19 m4_define([gst_plugins_base_minor_version], [10])
  20 m4_define([gst_plugins_base_micro_version], [16])
  21 m4_define([gst_plugins_base_version],
  22           [gst_plugins_base_major_version.gst_plugins_base_minor_version.gst_plugins_base_micro_version])
  23
  24 # VA-API minimum version number
  25 m4_define([va_api_x11_version], [0.31.0])
  26 m4_define([va_api_glx_version], [0.32.0])
  27
  28 # libva package version number
  29 m4_define([libva_x11_package_version], [1.0.3])
  30 m4_define([libva_glx_package_version], [1.0.9])
  31
  32 # gtk-doc version number
  33 # XXX: introspection annotations require gtk-doc >= 1.12
  34 m4_define([gtkdoc_major_version], [1])
  35 m4_define([gtkdoc_minor_version], [9])
  36 m4_define([gtkdoc_version], [gtkdoc_major_version.gtkdoc_minor_version])
  37
  38 AC_PREREQ([2.57])
  39 AC_INIT([gst_vaapi], [gst_vaapi_version],
  40     [gwenole.beauchesne@intel.com],
  41     [gstreamer-vaapi])
  42 AC_CONFIG_SRCDIR([Makefile.am])
  43 AC_CANONICAL_TARGET
  44 AM_INIT_AUTOMAKE
  45 AM_CONFIG_HEADER([config.h])
  46
  47 TODAY="`LC_ALL=C date +'%a, %d %b %Y %X %z'`"
  48 AC_SUBST(TODAY)
  49
  50 GST_VAAPI_MAJOR_VERSION=gst_vaapi_major_version
  51 AC_SUBST(GST_VAAPI_MAJOR_VERSION)
  52
  53 LIBVA_PACKAGE_VERSION=libva_x11_package_version
  54 AC_SUBST(LIBVA_PACKAGE_VERSION)
  55
  56 dnl Versions for GStreamer and plugins-base
  57 GST_MAJORMINOR=gst_major_minor_version
  58 GST_VERSION_REQUIRED=gst_version
  59 GST_PLUGINS_BASE_VERSION_REQUIRED=gst_plugins_base_version
  60 AC_SUBST(GST_MAJORMINOR)
  61 AC_SUBST(GST_VERSION_REQUIRED)
  62 AC_SUBST(GST_PLUGINS_BASE_VERSION_REQUIRED)
  63
  64 dnl Use pretty build output with automake >= 1.11
  65 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])], [
  66   AM_DEFAULT_VERBOSITY=1
  67   AC_SUBST(AM_DEFAULT_VERBOSITY)
  68 ])
  69
  70 dnl Check for tools
  71 AC_PROG_CC
  72 AM_PROG_CC_C_O
  73 AC_PROG_LIBTOOL
  74
  75 AC_ARG_ENABLE(glx,
  76     AC_HELP_STRING([--enable-glx],
  77                    [enable OpenGL/X11 @<:@default=yes@:>@]),
  78     [], [enable_glx="yes"])
  79
  80 AC_ARG_ENABLE(vaapi-glx,
  81     AC_HELP_STRING([--enable-vaapi-glx],
  82                    [enable VA/GLX extensions @<:@default=yes@:>@]),
  83     [], [enable_vaapi_glx="yes"])
  84
  85 AC_ARG_ENABLE(vaapisink-glx,
  86     AC_HELP_STRING([--enable-vaapisink-glx],
  87                    [enable OpenGL/X11 to vaapisink @<:@default=yes@:>@]),
  88     [], [enable_vaapisink_glx="no"])
  89
  90 dnl Check for __attribute__((visibility()))
  91 AC_CACHE_CHECK([whether __attribute__((visibility())) is supported],
  92   vaapi_cv_visibility_attribute,
  93   [cat > conftest.c <<EOF
  94 int foo __attribute__ ((visibility ("hidden"))) = 1;
  95 int bar __attribute__ ((visibility ("protected"))) = 1;
  96 EOF
  97   vaapi_cv_visibility_attribute=no
  98   if ${CC-cc} -Werror -S conftest.c -o conftest.s >/dev/null 2>&1; then
  99     if grep '\.hidden.*foo' conftest.s >/dev/null; then
 100       if grep '\.protected.*bar' conftest.s >/dev/null; then
 101         vaapi_cv_visibility_attribute=yes
 102       fi
 103     fi
 104   fi
 105   rm -f conftest.[cs]
 106 ])
 107 if test $vaapi_cv_visibility_attribute = yes; then
 108   vaapi_cv_visibility_attribute_hidden="__attribute__((visibility(\"hidden\")))"
 109 else
 110   vaapi_cv_visibility_attribute_hidden=""
 111 fi
 112 AC_DEFINE_UNQUOTED([attribute_hidden],
 113                    [$vaapi_cv_visibility_attribute_hidden],
 114                    [Define the "hidden" visibility attribute])
 115
 116 dnl Check for basic libraries
 117 AC_CHECK_LIB(m, tan)
 118
 119 dnl Check for Gtk doc
 120 GTKDOC_VERSION=gtkdoc_version
 121 GTK_DOC_CHECK([$GTKDOC_VERSION])
 122 AM_CONDITIONAL([BUILD_GTK_DOC], [test "x$enable_gtk_doc" = "xyes"])
 123 AC_SUBST(GTKDOC_VERSION)
 124
 125 dnl Check for GLib
 126 AC_PATH_PROG([GLIB_GENMARSHAL], [glib-genmarshal])
 127 PKG_CHECK_MODULES([GLIB], [glib-2.0])
 128 AC_SUBST(GLIB_CFLAGS)
 129 AC_SUBST(GLIB_LIBS)
 130
 131 dnl Check for GStreamer
 132 PKG_CHECK_MODULES([GST],
 133     [gstreamer-$GST_MAJORMINOR >= $GST_VERSION_REQUIRED]
 134 )
 135 AC_SUBST(GST_CFLAGS)
 136 AC_SUBST(GST_LIBS)
 137
 138 dnl Check for GStreamer plugins-base
 139 PKG_CHECK_MODULES([GST_PLUGINS_BASE],
 140     [gstreamer-plugins-base-$GST_MAJORMINOR >= $GST_PLUGINS_BASE_VERSION_REQUIRED]
 141 )
 142 AC_SUBST(GST_PLUGINS_BASE_CFLAGS)
 143 AC_SUBST(GST_PLUGINS_BASE_LIBS)
 144
 145 dnl Check for GStreamer base
 146 PKG_CHECK_MODULES([GST_BASE],
 147     [gstreamer-base-$GST_MAJORMINOR >= $GST_VERSION_REQUIRED]
 148 )
 149 AC_SUBST(GST_BASE_CFLAGS)
 150 AC_SUBST(GST_BASE_LIBS)
 151
 152 dnl Check for GStreamer video
 153 PKG_CHECK_MODULES([GST_VIDEO],
 154     [gstreamer-video-$GST_MAJORMINOR >= $GST_VERSION_REQUIRED]
 155 )
 156 AC_SUBST(GST_VIDEO_CFLAGS)
 157 AC_SUBST(GST_VIDEO_LIBS)
 158
 159 dnl Check for GStreamer interfaces
 160 PKG_CHECK_MODULES([GST_INTERFACES],
 161     [gstreamer-interfaces-$GST_MAJORMINOR >= $GST_PLUGINS_BASE_VERSION_REQUIRED]
 162 )
 163 AC_SUBST(GST_INTERFACES_CFLAGS)
 164 AC_SUBST(GST_INTERFACES_LIBS)
 165
 166 dnl GST_ALL_LDFLAGS:
 167 dnl LDFLAGS really should only contain flags, not libs - they get added before
 168 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 169 GST_ALL_LDFLAGS="-no-undefined"
 170 AC_SUBST(GST_ALL_LDFLAGS)
 171
 172 dnl GST_PLUGIN_LDFLAGS:
 173 dnl this really should only contain flags, not libs - they get added before
 174 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 175 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^([_]*gst_plugin_desc|gst_.*_get_type)\$\$' $GST_ALL_LDFLAGS"
 176 AC_SUBST(GST_PLUGIN_LDFLAGS)
 177
 178 dnl Check for the GStreamer plugins directory
 179 AC_MSG_CHECKING([for GStreamer plugins directory])
 180 GST_PLUGINS_DIR=`$PKG_CONFIG gstreamer-$GST_MAJORMINOR --variable pluginsdir`
 181 if test -z "$GST_PLUGINS_DIR"; then
 182     echo "FAIL FAIL FAIL"
 183     GST_PLUGINS_DIR="\$(libdir)/gstreamer-$GST_MAJORMINOR"
 184 fi
 185 AC_MSG_RESULT([$GST_PLUGINS_DIR])
 186 plugindir="$GST_PLUGINS_DIR"
 187 AC_SUBST(plugindir)
 188
 189 dnl Check for X11
 190 PKG_CHECK_MODULES(X11, [x11])
 191
 192 dnl Check for OpenGL
 193 USE_GLX=1
 194 if test "$enable_glx" != "yes"; then
 195     USE_GLX=0
 196 fi
 197 GLX_CFLAGS=""
 198 GLX_LIBS=""
 199 AC_CHECK_HEADERS([GL/gl.h GL/glext.h GL/glx.h], [], [USE_GLX=0], [
 200 #ifdef HAVE_GL_GL_H
 201 # include <GL/gl.h>
 202 #endif
 203 ])
 204 AC_CHECK_LIB(GL, glXCreateContext, [GLX_LIBS="-lGL"], [USE_GLX=0])
 205 AC_SUBST(GLX_CFLAGS)
 206 AC_SUBST(GLX_LIBS)
 207
 208 dnl Check for VA-API
 209 LIBVA_PKGNAME="libva"
 210 PKG_CHECK_MODULES(LIBVA, [$LIBVA_PKGNAME])
 211 AC_SUBST(LIBVA_PKGNAME)
 212
 213 dnl ... original VA-API 0.29
 214 AC_CACHE_CHECK([for old VA-API 0.29],
 215     ac_cv_have_vaapi_old, [
 216     saved_CFLAGS="$CFLAGS"
 217     CFLAGS="$CFLAGS $LIBVA_CFLAGS"
 218     saved_LIBS="$LIBS"
 219     LIBS="$LIBS $LIBVA_LIBS"
 220     AC_TRY_LINK(
 221     [#include <va_x11.h>],
 222     [vaGetDisplay(NULL)],
 223     [ac_cv_have_vaapi_old="yes"],
 224     [ac_cv_have_vaapi_old="no"])
 225     CFLAGS="$saved_CFLAGS"
 226     LIBS="$saved_LIBS"
 227 ])
 228 if test "$ac_cv_have_vaapi_old" = "yes"; then
 229     LIBVA_EXTRA_CFLAGS="$LIBVA_CFLAGS -DGST_VAAPI_USE_OLD_VAAPI_0_29"
 230 fi
 231
 232 dnl ... VA-API >= 0.31 or -sds
 233 LIBVA_X11_PKGNAME="libva-x11"
 234 PKG_CHECK_MODULES(LIBVA_X11, [$LIBVA_X11_PKGNAME],
 235     [ac_cv_have_vaapi_x11="yes"],
 236     [ac_cv_have_vaapi_x11="no"]
 237 )
 238 if test "$ac_cv_have_vaapi_x11" = "no"; then
 239     if test "$ac_cv_have_vaapi_old" = "yes"; then
 240         LIBVA_X11_PKGNAME="libva"
 241         CFLAGS="$CFLAGS $LIBVA_EXTRA_CFLAGS"
 242         LIBS="$LIBS $LIBVA_EXTRA_LIBS"
 243     else
 244         AC_MSG_ERROR([could not find VA-API])
 245     fi
 246 fi
 247 AC_SUBST(LIBVA_X11_PKGNAME)
 248
 249 dnl ... VA-API >= 0.31 or -sds (VA/GLX extensions)
 250 USE_VAAPI_GLX=0
 251 if test $USE_GLX -eq 1; then
 252     if test "$enable_vaapi_glx" = "yes"; then
 253         LIBVA_GLX_PKGNAME="libva-glx"
 254         PKG_CHECK_MODULES(LIBVA_GLX, [$LIBVA_GLX_PKGNAME],
 255             [ac_cv_have_vaapi_glx="yes" USE_VAAPI_GLX=1],
 256             [ac_cv_have_vaapi_glx="no"]
 257         )
 258     fi
 259     if test $USE_VAAPI_GLX -eq 0; then
 260         AC_MSG_WARN([VA/GLX not found or disabled. Fallbacking to TFP+FBO])
 261         LIBVA_GLX_PKGNAME="$LIBVA_X11_PKGNAME"
 262     fi
 263 fi
 264 AC_SUBST(LIBVA_GLX_PKGNAME)
 265
 266 AC_SUBST(LIBVA_EXTRA_CFLAGS)
 267 AC_SUBST(LIBVA_EXTRA_LIBS)
 268
 269 dnl Check for OpenGL support to vaapisink
 270 if test "$enable_vaapisink_glx:$USE_GLX" = "yes:1"; then
 271     USE_VAAPISINK_GLX=1
 272 else
 273     USE_VAAPISINK_GLX=0
 274 fi
 275
 276 dnl Check for FFmpeg
 277 PKG_CHECK_MODULES(LIBAVCODEC, [libavcodec])
 278 AC_CHECK_HEADERS([libavcodec/avcodec.h ffmpeg/avcodec.h])
 279 AC_CHECK_HEADERS([libavcodec/vaapi.h ffmpeg/vaapi.h], [break],
 280     AC_MSG_ERROR([The system FFmpeg headers do not support VA-API]))
 281
 282 AC_DEFINE_UNQUOTED(USE_GLX, $USE_GLX,
 283     [Defined to 1 if GLX is enabled])
 284 AM_CONDITIONAL(USE_GLX, test $USE_GLX -eq 1)
 285
 286 AC_DEFINE_UNQUOTED(USE_VAAPI_GLX, $USE_VAAPI_GLX,
 287     [Defined to 1 if VA/GLX is enabled])
 288 AM_CONDITIONAL(USE_VAAPI_GLX, test $USE_VAAPI_GLX -eq 1)
 289
 290 AC_DEFINE_UNQUOTED(USE_VAAPISINK_GLX, $USE_VAAPISINK_GLX,
 291     [Defined to 1 to enable GLX support to vaapisink])
 292 AM_CONDITIONAL(USE_VAAPISINK_GLX, test $USE_VAAPISINK_GLX -eq 1)
 293
 294 VA_VERSION=`$PKG_CONFIG --modversion libva`
 295 VA_MAJOR_VERSION=`echo "$VA_VERSION" | cut -d'.' -f1`
 296 VA_MINOR_VERSION=`echo "$VA_VERSION" | cut -d'.' -f2`
 297 VA_MICRO_VERSION=`echo "$VA_VERSION" | cut -d'.' -f3`
 298 VA_VERSION_STR="$VA_VERSION"
 299
 300 pkgconfigdir=${libdir}/pkgconfig
 301 AC_SUBST(pkgconfigdir)
 302
 303 AC_OUTPUT([
 304     Makefile
 305     debian.upstream/Makefile
 306     debian.upstream/changelog
 307     debian.upstream/control
 308     debian.upstream/gstreamer$GST_MAJORMINOR-vaapi.install:\
 309 debian.upstream/gstreamer-vaapi.install.in
 310     debian.upstream/gstreamer$GST_MAJORMINOR-vaapi-doc.install:\
 311 debian.upstream/gstreamer-vaapi-doc.install.in
 312     debian.upstream/libgstvaapi$GST_VAAPI_MAJOR_VERSION.install:\
 313 debian.upstream/libgstvaapi.install.in
 314     debian.upstream/libgstvaapi-dev.install
 315     debian.upstream/libgstvaapi-x11-$GST_VAAPI_MAJOR_VERSION.install:\
 316 debian.upstream/libgstvaapi-x11.install.in
 317     debian.upstream/libgstvaapi-glx-$GST_VAAPI_MAJOR_VERSION.install:\
 318 debian.upstream/libgstvaapi-glx.install.in
 319     docs/Makefile
 320     docs/reference/Makefile
 321     docs/reference/libs/Makefile
 322     docs/reference/libs/libs-docs.xml
 323     docs/reference/plugins/Makefile
 324     docs/reference/plugins/plugins-docs.xml
 325     gst-libs/Makefile
 326     gst-libs/gst/Makefile
 327     gst-libs/gst/vaapi/Makefile
 328     pkgconfig/Makefile
 329     pkgconfig/gstreamer-vaapi-$GST_MAJORMINOR.pc:\
 330 pkgconfig/gstreamer-vaapi.pc.in
 331     pkgconfig/gstreamer-vaapi-glx-$GST_MAJORMINOR.pc:\
 332 pkgconfig/gstreamer-vaapi-glx.pc.in
 333     pkgconfig/gstreamer-vaapi-x11-$GST_MAJORMINOR.pc:\
 334 pkgconfig/gstreamer-vaapi-x11.pc.in
 335     gst/Makefile
 336     gst/vaapi/Makefile
 337     tests/Makefile
 338 ])
 339
 340 dnl Print summary
 341 yesno() {
 342     test $1 -eq 1 && echo yes || echo no
 343 }
 344
 345 echo
 346 echo $PACKAGE configuration summary:
 347 echo
 348 echo VA-API version ................... : $VA_VERSION_STR
 349 echo GLX support ...................... : $(yesno $USE_GLX)
 350 echo VA/GLX support ................... : $(yesno $USE_VAAPI_GLX)
 351 echo VaapiSink/GL ..................... : $(yesno $USE_VAAPISINK_GLX)
 352 echo