configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2 AC_PREREQ([2.62])
   3
   4 dnl ***********************************
   5 dnl *** include special GLib macros ***
   6 dnl ***********************************
   7
   8 m4_define(glib_configure_ac)
   9
  10 #
  11 # The following version number definitions apply to GLib, GModule, GObject,
  12 # GThread and GIO as a whole, so if changes occurred in any of them, they are
  13 # all treated with the same interface and binary age.
  14 #
  15 # Making releases:
  16 #   glib_micro_version += 1;
  17 #   glib_interface_age += 1;
  18 #   glib_binary_age += 1;
  19 # if any functions have been added, set glib_interface_age to 0.
  20 # if backwards compatibility has been broken,
  21 # set glib_binary_age _and_ glib_interface_age to 0.
  22 #
  23 # remember to add a GLIB_VERSION_2_xx macro every time the minor version is
  24 # bumped, as well as the GLIB_DEPRECATED_IN and GLIB_AVAILABLE_IN macros
  25 # for that version - see gversion.h for further information.
  26 #
  27 # in easier to understand terms:
  28 #
  29 # <mclasen> on the stable branch, interface age == micro
  30 # <mclasen> on the unstable (ie master), interface age = 0
  31
  32 m4_define([glib_major_version], [2])
  33 m4_define([glib_minor_version], [35])
  34 m4_define([glib_micro_version], [0])
  35 m4_define([glib_interface_age], [0])
  36 m4_define([glib_binary_age],
  37           [m4_eval(100 * glib_minor_version + glib_micro_version)])
  38 m4_define([glib_version],
  39           [glib_major_version.glib_minor_version.glib_micro_version])
  40
  41 # libtool version related macros
  42 m4_define([glib_lt_release], [glib_major_version.glib_minor_version])
  43 m4_define([glib_lt_current],
  44           [m4_eval(100 * glib_minor_version + glib_micro_version - glib_interface_age)])
  45 m4_define([glib_lt_revision], [glib_interface_age])
  46 m4_define([glib_lt_age], [m4_eval(glib_binary_age - glib_interface_age)])
  47 m4_define([glib_lt_current_minus_age],
  48           [m4_eval(glib_lt_current - glib_lt_age)])
  49
  50 # if the minor version number is odd, then we want debugging.  Otherwise
  51 # we only want minimal debugging support.
  52 m4_define([glib_debug_default],
  53           [m4_if(m4_eval(glib_minor_version % 2), [1], [yes], [minimum])])dnl
  54
  55
  56 AC_INIT(glib, [glib_version],
  57         [http://bugzilla.gnome.org/enter_bug.cgi?product=glib])
  58
  59 AC_CONFIG_HEADER([config.h])
  60 AC_CONFIG_SRCDIR([glib/glib.h])
  61 AC_CONFIG_MACRO_DIR([m4macros])
  62
  63 # Save this value here, since automake will set cflags later
  64 cflags_set=${CFLAGS+set}
  65
  66 AM_INIT_AUTOMAKE([1.11 no-define no-dist-gzip dist-xz tar-ustar])
  67 AM_MAINTAINER_MODE([enable])
  68
  69 # Support silent build rules. Disable
  70 # by either passing --disable-silent-rules to configure or passing V=1
  71 # to make
  72 AM_SILENT_RULES([yes])
  73
  74 GLIB_MAJOR_VERSION=glib_major_version
  75 GLIB_MINOR_VERSION=glib_minor_version
  76 GLIB_MICRO_VERSION=glib_micro_version
  77 GLIB_INTERFACE_AGE=glib_interface_age
  78 GLIB_BINARY_AGE=glib_binary_age
  79 GLIB_VERSION=glib_version
  80
  81 AC_SUBST(GLIB_MAJOR_VERSION)
  82 AC_SUBST(GLIB_MINOR_VERSION)
  83 AC_SUBST(GLIB_MICRO_VERSION)
  84 AC_SUBST(GLIB_VERSION)
  85 AC_SUBST(GLIB_INTERFACE_AGE)
  86 AC_SUBST(GLIB_BINARY_AGE)
  87
  88 AC_DEFINE(GLIB_MAJOR_VERSION, [glib_major_version],
  89           [Define to the GLIB major version])
  90 AC_DEFINE(GLIB_MINOR_VERSION, [glib_minor_version],
  91           [Define to the GLIB minor version])
  92 AC_DEFINE(GLIB_MICRO_VERSION, [glib_micro_version],
  93           [Define to the GLIB micro version])
  94 AC_DEFINE(GLIB_INTERFACE_AGE, [glib_interface_age],
  95           [Define to the GLIB interface age])
  96 AC_DEFINE(GLIB_BINARY_AGE, [glib_binary_age],
  97           [Define to the GLIB binary age])
  98
  99 # libtool versioning
 100 LT_RELEASE=glib_lt_release
 101 LT_CURRENT=glib_lt_current
 102 LT_REVISION=glib_lt_revision
 103 LT_AGE=glib_lt_age
 104 LT_CURRENT_MINUS_AGE=glib_lt_current_minus_age
 105 AC_SUBST(LT_RELEASE)
 106 AC_SUBST(LT_CURRENT)
 107 AC_SUBST(LT_REVISION)
 108 AC_SUBST(LT_AGE)
 109 AC_SUBST(LT_CURRENT_MINUS_AGE)
 110
 111 dnl Checks for programs.
 112 AC_PROG_CC
 113 AC_PROG_CPP
 114
 115 AM_CONDITIONAL(HAVE_GCC, [test "$GCC" = "yes"])
 116
 117 AC_CANONICAL_HOST
 118
 119 AC_MSG_CHECKING([for the BeOS])
 120 case $host in
 121   *-*-beos*)
 122     glib_native_beos="yes"
 123     ;;
 124   *)
 125     glib_native_beos="no"
 126     ;;
 127 esac
 128 AC_MSG_RESULT([$glib_native_beos])
 129
 130 dnl
 131
 132 AC_MSG_CHECKING([for Win32])
 133 LIB_EXE_MACHINE_FLAG=X86
 134 case "$host" in
 135   *-*-mingw*)
 136     glib_native_win32=yes
 137     glib_pid_type='void *'
 138     glib_cv_stack_grows=no
 139     # Unfortunately the mingw implementations of C99-style snprintf and vsnprintf
 140     # don't seem to be quite good enough, at least not in mingw-runtime-3.14.
 141     # (Sorry, I don't know exactly what is the problem, but it is related to
 142     # floating point formatting and decimal point vs. comma.)
 143     # The simple tests in AC_FUNC_VSNPRINTF_C99 and AC_FUNC_SNPRINTF_C99 aren't
 144     # rigorous enough to notice, though.
 145     # So preset the autoconf cache variables.
 146     ac_cv_func_vsnprintf_c99=no
 147     ac_cv_func_snprintf_c99=no
 148     case "$host" in
 149     x86_64-*-*)
 150       LIB_EXE_MACHINE_FLAG=X64
 151       ;;
 152     esac
 153     ;;
 154   *)
 155     glib_native_win32=no
 156     glib_pid_type=int
 157     ;;
 158 esac
 159 case $host in
 160   *-*-linux*)
 161     glib_os_linux=yes
 162     ;;
 163 esac
 164
 165 AC_MSG_RESULT([$glib_native_win32])
 166
 167 AC_SUBST(LIB_EXE_MACHINE_FLAG)
 168
 169 glib_have_carbon=no
 170 AC_MSG_CHECKING([for Mac OS X Carbon support])
 171 AC_TRY_CPP([
 172 #include <Carbon/Carbon.h>
 173 #include <CoreServices/CoreServices.h>
 174 ], glib_have_carbon=yes)
 175
 176 AC_MSG_RESULT([$glib_have_carbon])
 177
 178 glib_have_cocoa=no
 179 AC_MSG_CHECKING([for Mac OS X Cocoa support])
 180 AC_TRY_CPP([
 181 #include <Cocoa/Cocoa.h>
 182 #ifdef GNUSTEP_BASE_VERSION
 183 #error "Detected GNUstep, not Cocoa"
 184 #endif
 185 ], glib_have_cocoa=yes)
 186
 187 AC_MSG_RESULT([$glib_have_cocoa])
 188
 189 AM_CONDITIONAL(OS_WIN32, [test "$glib_native_win32" = "yes"])
 190 AM_CONDITIONAL(OS_WIN32_X64, [test "$LIB_EXE_MACHINE_FLAG" = "X64"])
 191 AM_CONDITIONAL(OS_UNIX, [test "$glib_native_win32" != "yes"])
 192 AM_CONDITIONAL(OS_LINUX, [test "$glib_os_linux" = "yes"])
 193 AM_CONDITIONAL(OS_CARBON, [test "$glib_have_carbon" = "yes"])
 194 AM_CONDITIONAL(OS_COCOA, [test "$glib_have_cocoa" = "yes"])
 195
 196 AS_IF([test "$glib_native_win32" = "yes"], [
 197   AC_CHECK_TOOL(WINDRES, windres, no)
 198   if test "$WINDRES" = no; then
 199     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 200   fi
 201   AC_CHECK_TOOL(NM, nm, no)
 202   if test "$NM" = no; then
 203     AC_MSG_ERROR([*** Could not find an implementation of nm in your PATH.])
 204   fi
 205   AC_CHECK_TOOL(RANLIB, ranlib, :)
 206   AC_CHECK_PROG(ms_librarian, [lib.exe], [yes], [no])
 207 ])
 208 AM_CONDITIONAL(MS_LIB_AVAILABLE, [test x$ms_librarian = xyes])
 209
 210 if test "$glib_native_win32" != yes; then
 211     # libtool option to control which symbols are exported
 212     # right now, symbols starting with _ are not exported
 213     LIBTOOL_EXPORT_OPTIONS='-export-symbols-regex "^g.*"'
 214 else
 215     # We currently use .def files on Windows
 216     LIBTOOL_EXPORT_OPTIONS=
 217 fi
 218 AC_SUBST(LIBTOOL_EXPORT_OPTIONS)
 219
 220 AS_IF([test "x$glib_have_carbon" = "xyes"], [
 221   AC_DEFINE(HAVE_CARBON, 1, [define to 1 if Carbon is available])
 222   LDFLAGS="$LDFLAGS -Wl,-framework,Carbon"
 223 ])
 224
 225 if test "x$glib_have_cocoa" = "xyes"; then
 226   AC_DEFINE(HAVE_COCOA, 1, [define to 1 if Cocoa is available])
 227   LDFLAGS="$LDFLAGS -Wl,-framework,Foundation"
 228 fi
 229
 230 gl_GLIBC21
 231 AS_IF([test "x$GLIBC21" = "xyes"], [
 232   AC_DEFINE([_GNU_SOURCE], 1, [Make all glibc extensions visible])
 233 ])
 234
 235 dnl declare --enable-* args and collect ac_help strings
 236 AC_ARG_ENABLE(debug,
 237               AS_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 238                              [turn on debugging @<:@default=glib_debug_default@:>@]),,
 239               enable_debug=glib_debug_default)
 240
 241 AC_ARG_ENABLE(gc_friendly,
 242               [AS_HELP_STRING([--enable-gc-friendly],
 243                               [turn on garbage collector friendliness [default=no]])],,
 244               [enable_gc_friendly=no])
 245 AC_ARG_ENABLE(mem_pools,
 246               [AS_HELP_STRING([--disable-mem-pools],
 247                               [disable all glib memory pools])],,
 248               [disable_mem_pools=no])
 249 AC_ARG_ENABLE(rebuilds,
 250               [AS_HELP_STRING([--disable-rebuilds],
 251                               [disable all source autogeneration rules])],,
 252               [enable_rebuilds=yes])
 253 AC_ARG_ENABLE(modular_tests,
 254               AS_HELP_STRING([--disable-modular-tests],
 255                              [Disable build of test programs (default: no)]),,
 256               [enable_modular_tests=yes])
 257 AM_CONDITIONAL(BUILD_MODULAR_TESTS, test x$enable_modular_tests = xyes)
 258
 259 AC_MSG_CHECKING([whether to enable garbage collector friendliness])
 260 AS_IF([test "x$enable_gc_friendly" = "xyes"], [
 261   AC_DEFINE(ENABLE_GC_FRIENDLY_DEFAULT, 1, [Whether to enable GC friendliness by default])
 262   AC_MSG_RESULT([yes])
 263 ], [ AC_MSG_RESULT([no]) ])
 264
 265 AC_MSG_CHECKING([whether to disable memory pools])
 266 AS_IF([test "x$disable_mem_pools" = "xno"], [
 267   AC_MSG_RESULT([no])
 268 ], [
 269   AC_DEFINE(DISABLE_MEM_POOLS, [1], [Whether to disable memory pools])
 270   AC_MSG_RESULT([yes])
 271 ])
 272
 273 dnl location to install runtime libraries, e.g. ../../lib to install
 274 dnl to /lib if libdir is /usr/lib
 275 AC_ARG_WITH(runtime-libdir,
 276            [AS_HELP_STRING([--with-runtime-libdir=RELPATH],
 277                            [install runtime libraries relative to libdir])],
 278            [],
 279            [with_runtime_libdir=""])
 280 GLIB_RUNTIME_LIBDIR="$with_runtime_libdir"
 281 ABS_GLIB_RUNTIME_LIBDIR="`readlink -f $libdir/$with_runtime_libdir`"
 282 AC_SUBST(GLIB_RUNTIME_LIBDIR)
 283 AC_SUBST(ABS_GLIB_RUNTIME_LIBDIR)
 284 AM_CONDITIONAL(HAVE_GLIB_RUNTIME_LIBDIR, [test "x$with_runtime_libdir" != "x"])
 285
 286 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 287 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], [gcc])
 288 AC_LANG_SAVE
 289 AC_LANG_CPLUSPLUS
 290 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
 291 AM_CONDITIONAL(HAVE_CXX, [test "$CXX" != ""])
 292 AC_LANG_RESTORE
 293
 294 AM_PROG_CC_STDC
 295 AM_PROG_CC_C_O
 296 AC_PROG_INSTALL
 297
 298 AC_SYS_LARGEFILE
 299
 300 PKG_PROG_PKG_CONFIG(0.16)
 301
 302 if test "x$enable_debug" = "xyes"; then
 303   if test x$cflags_set != xset ; then
 304       case " $CFLAGS " in
 305       *[[\ \    ]]-g[[\ \       ]]*) ;;
 306       *) CFLAGS="$CFLAGS -g" ;;
 307       esac
 308   fi
 309   GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 310 else
 311   GLIB_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 312
 313   if test "x$enable_debug" = "xno"; then
 314     GLIB_DEBUG_FLAGS="$GLIB_DEBUG_FLAGS -DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
 315   fi
 316 fi
 317
 318 # Ensure MSVC-compatible struct packing convention is used when
 319 # compiling for Win32 with gcc.
 320 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 321 # gcc2 uses "-fnative-struct".
 322 if test x"$glib_native_win32" = xyes; then
 323   if test x"$GCC" = xyes; then
 324     msnative_struct=''
 325     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 326     if test -z "$ac_cv_prog_CC"; then
 327       our_gcc="$CC"
 328     else
 329       our_gcc="$ac_cv_prog_CC"
 330     fi
 331     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 332       2.)
 333         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 334           msnative_struct='-fnative-struct'
 335         fi
 336         ;;
 337       *)
 338         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 339           msnative_struct='-mms-bitfields'
 340         fi
 341         ;;
 342     esac
 343     if test x"$msnative_struct" = x ; then
 344       AC_MSG_RESULT([no way])
 345       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 346     else
 347       CFLAGS="$CFLAGS $msnative_struct"
 348       AC_MSG_RESULT([${msnative_struct}])
 349     fi
 350   fi
 351 fi
 352 GLIB_EXTRA_CFLAGS="${msnative_struct}"
 353 AC_SUBST(GLIB_EXTRA_CFLAGS)
 354
 355 AC_EXEEXT
 356
 357 # define a MAINT-like variable REBUILD which is set if Perl
 358 # and awk are found, so autogenerated sources can be rebuilt
 359 AC_PROG_AWK
 360 AC_CHECK_PROGS(PERL, [perl5 perl])
 361 # We would like indent, but don't require it.
 362 AC_CHECK_PROG(INDENT, indent, indent)
 363 REBUILD=\#
 364 if test "x$enable_rebuilds" = "xyes" && \
 365      test -n "$PERL" && \
 366      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 && \
 367      test -n "$AWK" ; then
 368   REBUILD=
 369 fi
 370 AC_SUBST(REBUILD)
 371
 372 # Need full path to Perl for glib-mkenums
 373 #
 374 if test "x$PERL" != x ; then
 375   AC_PATH_PROG(PERL_PATH, [$PERL])
 376 fi
 377 if test "x$PERL_PATH" = x ; then
 378   PERL_PATH="/usr/bin/env perl"
 379 fi
 380 AC_SUBST(PERL_PATH)
 381
 382 # Need suitable python path for greport
 383 AM_PATH_PYTHON(2.5,,PYTHON="/usr/bin/env python2.5")
 384
 385
 386 dnl ***********************
 387 dnl *** Tests for iconv ***
 388 dnl ***********************
 389 dnl
 390 dnl We do this before the gettext checks, to avoid distortion
 391
 392 dnl On Windows we use a native implementation
 393
 394 AS_IF([ test x"$glib_native_win32" = xyes], [
 395   with_libiconv=native
 396 ], [
 397   AC_ARG_WITH(libiconv,
 398               [AS_HELP_STRING([--with-libiconv=@<:@no/gnu/native@:>@],
 399                               [use the libiconv library])],,
 400               [with_libiconv=maybe])
 401
 402   found_iconv=no
 403   case $with_libiconv in
 404     maybe)
 405       # Check in the C library first
 406       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 407       # Check if we have GNU libiconv
 408       if test $found_iconv = "no"; then
 409         AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 410       fi
 411       # Check if we have a iconv in -liconv, possibly from vendor
 412       if test $found_iconv = "no"; then
 413         AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 414       fi
 415       ;;
 416     no)
 417       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 418       ;;
 419     gnu|yes)
 420       AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 421       ;;
 422     native)
 423       AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 424       ;;
 425   esac
 426
 427   if test "x$found_iconv" = "xno" ; then
 428      AC_MSG_ERROR([*** No iconv() implementation found in C library or libiconv])
 429   fi
 430 ])
 431
 432 AC_ARG_ENABLE(iconv-cache,
 433               [AS_HELP_STRING([--enable-iconv-cache=@<:@yes/no/auto@:>@],
 434                               [cache iconv descriptors [default=auto]])],,
 435               [enable_iconv_cache=auto])
 436
 437 AC_MSG_CHECKING([whether to cache iconv descriptors])
 438 case $enable_iconv_cache in
 439   auto)
 440     if test $ac_cv_gnu_library_2_1 = yes; then
 441       enable_iconv_cache=no
 442     else
 443       enable_iconv_cache=yes
 444     fi
 445   ;;
 446   yes|no)
 447   ;;
 448   *) AC_MSG_ERROR([Value given to --enable-iconv-cache must be one of yes, no or auto])
 449   ;;
 450 esac
 451
 452 if test $enable_iconv_cache = yes; then
 453    AC_DEFINE(NEED_ICONV_CACHE,1,[Do we cache iconv descriptors])
 454 fi
 455
 456 AC_MSG_RESULT($enable_iconv_cache)
 457
 458
 459 dnl
 460 dnl zlib support
 461 dnl
 462 PKG_CHECK_MODULES([ZLIB], [zlib], [found_zlib=yes], [found_zlib=no])
 463 AS_IF([test "x$found_zlib" = "xno"], [
 464   AC_CHECK_LIB(z, inflate, [AC_CHECK_HEADER(zlib.h, found_zlib=yes)])
 465   if test "x$found_zlib" = "xno" ; then
 466     AC_MSG_ERROR([*** Working zlib library and headers not found ***])
 467   fi
 468   ZLIB_LIBS='-lz'
 469   AC_SUBST(ZLIB_LIBS)
 470 ])
 471
 472 PKG_CHECK_MODULES(LIBFFI, [libffi >= 3.0.0])
 473 AC_SUBST(LIBFFI_CFLAGS)
 474 AC_SUBST(LIBFFI_LIBS)
 475
 476 dnl
 477 dnl gettext support
 478 dnl
 479
 480 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 481 AC_SUBST([CONFIG_STATUS_DEPENDENCIES],['$(top_srcdir)/po/LINGUAS'])
 482 GLIB_GNU_GETTEXT
 483
 484 if test "$gt_cv_have_gettext" != "yes" ; then
 485   AC_MSG_ERROR([
 486 *** You must have either have gettext support in your C library, or use the
 487 *** GNU gettext library. (http://www.gnu.org/software/gettext/gettext.html
 488 ])
 489 fi
 490
 491 LIBS="$INTLLIBS $LIBS"
 492
 493 GETTEXT_PACKAGE=glib20
 494 AC_SUBST(GETTEXT_PACKAGE)
 495 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
 496   [Define the gettext package to be used])
 497
 498 GLIB_DEFINE_LOCALEDIR(GLIB_LOCALE_DIR)
 499
 500 dnl
 501 dnl Now we are done with gettext checks, figure out ICONV_LIBS
 502 dnl
 503
 504 AS_IF([test x"$glib_native_win32" != xyes], [
 505   if test x$with_libiconv != xno ; then
 506     case " $INTLLIBS " in
 507     *[[\ \      ]]-liconv[[\ \  ]]*) ;;
 508     *) ICONV_LIBS="-liconv" ;;
 509     esac
 510   fi
 511 ])
 512 AC_SUBST(ICONV_LIBS)
 513
 514 case $with_libiconv in
 515   gnu)
 516     AC_DEFINE(USE_LIBICONV_GNU, 1, [Using GNU libiconv])
 517     ;;
 518   native)
 519     AC_DEFINE(USE_LIBICONV_NATIVE, 1, [Using a native implementation of iconv in a separate library])
 520     ;;
 521 esac
 522
 523 dnl Initialize libtool
 524 LT_PREREQ([2.2])
 525 LT_INIT([disable-static win32-dll])
 526 dnl when using libtool 2.x create libtool early, because it's used in configure
 527 m4_ifdef([LT_OUTPUT], [LT_OUTPUT])
 528
 529
 530 if test "x$GCC" = "xyes"; then
 531   case " $CFLAGS " in
 532   *[[\ \        ]]-Wall[[\ \    ]]*) ;;
 533   *) CFLAGS="$CFLAGS -Wall" ;;
 534   esac
 535 fi
 536
 537 AS_IF([test "$glib_native_win32" = "yes"], [
 538   if test x$enable_static = xyes -a x$enable_shared = xyes; then
 539     AC_MSG_ERROR([Can not build both shared and static at the same time on Windows.])
 540   fi
 541   if test x$enable_static = xyes; then
 542     glib_win32_static_compilation=yes
 543     GLIB_WIN32_STATIC_COMPILATION_DEFINE="#define GLIB_STATIC_COMPILATION 1
 544 #define GOBJECT_STATIC_COMPILATION 1"
 545     AC_SUBST(GLIB_WIN32_STATIC_COMPILATION_DEFINE)
 546   fi
 547 ])
 548 AM_CONDITIONAL(OS_WIN32_AND_DLL_COMPILATION, [test x$glib_native_win32 = xyes -a x$glib_win32_static_compilation != xyes])
 549
 550 dnl
 551 dnl DU4 native cc currently needs -std1 for ANSI mode (instead of K&R)
 552 dnl
 553 AS_IF([test $cross_compiling != yes], [
 554     AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 555     glib_save_LIBS=$LIBS
 556     LIBS="$LIBS -lm"
 557     AC_TRY_RUN([#include <math.h>
 558                  int main (void) { return (log(1) != log(1.)); }],
 559          AC_MSG_RESULT(none needed),
 560          glib_save_CFLAGS=$CFLAGS
 561          CFLAGS="$CFLAGS -std1"
 562          AC_TRY_RUN([#include <math.h>
 563                      int main (void) { return (log(1) != log(1.)); }],
 564              AC_MSG_RESULT(-std1),
 565              AC_MSG_RESULT()
 566              CFLAGS=$glib_save_CFLAGS
 567              AC_MSG_WARN(
 568                     [No ANSI prototypes found in library. (-std1 didn't work.)])
 569          )
 570     )
 571     LIBS=$glib_save_LIBS
 572 ])
 573
 574 dnl NeXTStep cc seems to need this
 575 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 576 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 577   AC_MSG_RESULT(none needed),
 578   glib_save_CFLAGS=$CFLAGS
 579   CFLAGS="$CFLAGS -posix"
 580   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 581     AC_MSG_RESULT(-posix),
 582     AC_MSG_RESULT()
 583     CFLAGS=$glib_save_CFLAGS
 584     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 585
 586 # Checks for library functions.
 587 AC_FUNC_VPRINTF
 588 AC_FUNC_ALLOCA
 589 AC_CHECK_FUNCS(mmap posix_memalign memalign valloc fsync pipe2 issetugid)
 590 AC_CHECK_FUNCS(atexit on_exit timegm gmtime_r)
 591
 592 AC_CACHE_CHECK([for __libc_enable_secure], glib_cv_have_libc_enable_secure,
 593   [AC_TRY_LINK([#include <unistd.h>
 594     extern int __libc_enable_secure;],
 595     [return __libc_enable_secure;],
 596    glib_cv_have_libc_enable_secure=yes,
 597    glib_cv_have_libc_enable_secure=no)])
 598 AS_IF([test x$glib_cv_have_libc_enable_secure = xyes], [
 599    AC_DEFINE(HAVE_LIBC_ENABLE_SECURE, 1,
 600      [Define if you have the __libc_enable_secure variable (GNU libc, eglibc)])
 601 ])
 602
 603 AC_CHECK_SIZEOF(char)
 604 AC_CHECK_SIZEOF(short)
 605 AC_CHECK_SIZEOF(long)
 606 AC_CHECK_SIZEOF(int)
 607 AC_CHECK_SIZEOF(void *)
 608 AC_CHECK_SIZEOF(long long)
 609 AC_CHECK_SIZEOF(__int64)
 610
 611 AC_CACHE_CHECK([for sig_atomic_t], ac_cv_type_sig_atomic_t,
 612   [AC_TRY_LINK([#include <signal.h>
 613      #include <sys/types.h>
 614      sig_atomic_t val = 42;],
 615     [return val == 42 ? 0 : 1],
 616    ac_cv_type_sig_atomic_t=yes,
 617    ac_cv_type_sig_atomic_t=no)])
 618 if test x$ac_cv_type_sig_atomic_t = xyes; then
 619    AC_DEFINE(HAVE_SIG_ATOMIC_T, 1,
 620      [Define if you have the 'sig_atomic_t' type.])
 621 fi
 622
 623 if test x$ac_cv_sizeof_long = x8 || test x$ac_cv_sizeof_long_long = x8 || test x$ac_cv_sizeof___int64 = x8 ; then
 624   :
 625 else
 626   AC_MSG_ERROR([
 627 *** GLib requires a 64 bit type. You might want to consider
 628 *** using the GNU C compiler.
 629 ])
 630 fi
 631
 632 AS_IF([test x$glib_native_win32 != xyes && test x$ac_cv_sizeof_long_long = x8], [
 633         # long long is a 64 bit integer.
 634         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 635         AC_CACHE_VAL(glib_cv_long_long_format,[
 636                 for format in ll q I64; do
 637                   AC_TRY_RUN([#include <stdio.h>
 638                         int main()
 639                         {
 640                           long long b, a = -0x3AFAFAFAFAFAFAFALL;
 641                           char buffer[1000];
 642                           sprintf (buffer, "%${format}u", a);
 643                           sscanf (buffer, "%${format}u", &b);
 644                           exit (b!=a);
 645                         }
 646                         ],
 647                         [glib_cv_long_long_format=${format}
 648                         break],
 649                         [],[:])
 650                 done])
 651         AS_IF([ test -n "$glib_cv_long_long_format"], [
 652           AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 653           AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 654           if test x"$glib_cv_long_long_format" = xI64; then
 655             AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 656           fi
 657         ], [AC_MSG_RESULT(none)])
 658 ],[ test x$ac_cv_sizeof___int64 = x8], [
 659         # __int64 is a 64 bit integer.
 660         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 661         # We know this is MSVCRT.DLL, and what the formats are
 662         glib_cv_long_long_format=I64
 663         AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 664         AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 665         AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 666 ])
 667
 668 AC_C_CONST
 669
 670 dnl ok, here we try to check whether the systems prototypes for
 671 dnl malloc and friends actually match the prototypes provided
 672 dnl by gmem.h (keep in sync). i currently only know how to check
 673 dnl this reliably with gcc (-Werror), improvements for other
 674 dnl compilers are apprechiated.
 675 SANE_MALLOC_PROTOS=no
 676 AC_MSG_CHECKING([if malloc() and friends prototypes are gmem.h compatible])
 677 glib_save_CFLAGS=$CFLAGS
 678 AS_IF([test "x$GCC" = "xyes"], [
 679   CFLAGS="$CFLAGS -Werror"
 680   AC_TRY_COMPILE([#include <stdlib.h>], [
 681     void* (*my_calloc_p)  (size_t, size_t) = calloc;
 682     void* (*my_malloc_p)  (size_t)         = malloc;
 683     void  (*my_free_p)    (void*)          = free;
 684     void* (*my_realloc_p) (void*, size_t)  = realloc;
 685     my_calloc_p = 0;
 686     my_malloc_p = 0;
 687     my_free_p = 0;
 688     my_realloc_p = 0;
 689   ],
 690     AC_DEFINE(SANE_MALLOC_PROTOS, 1,
 691       [Define if you have correct malloc prototypes])
 692     SANE_MALLOC_PROTOS=yes)
 693 ])
 694 AC_MSG_RESULT($SANE_MALLOC_PROTOS)
 695 CFLAGS=$glib_save_CFLAGS
 696
 697 dnl
 698 dnl check in which direction the stack grows
 699 dnl
 700 AC_CACHE_CHECK([for growing stack pointer],glib_cv_stack_grows,[
 701         AC_TRY_RUN([
 702         volatile int *a = 0, *b = 0;
 703         void foo (void);
 704         int main () { volatile int y = 7; a = &y; foo (); return b > a; }
 705         void foo (void) { volatile int x = 5; b = &x; }
 706         ],
 707         glib_cv_stack_grows=no
 708         ,
 709         glib_cv_stack_grows=yes
 710         ,)
 711 ])
 712
 713 dnl AC_C_INLINE is useless to us since it bails out too early, we need to
 714 dnl truely know which ones of `inline', `__inline' and `__inline__' are
 715 dnl actually supported.
 716 AC_CACHE_CHECK([for __inline],glib_cv_has__inline,[
 717         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 718         __inline int foo () { return 0; }
 719         int main () { return foo (); }
 720         ]])],
 721         glib_cv_has__inline=yes
 722         ,
 723         glib_cv_has__inline=no
 724         ,)
 725 ])
 726 case x$glib_cv_has__inline in
 727 xyes) AC_DEFINE(G_HAVE___INLINE,1,[Have __inline keyword])
 728 esac
 729 AC_CACHE_CHECK([for __inline__],glib_cv_has__inline__,[
 730         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 731         __inline__ int foo () { return 0; }
 732         int main () { return foo (); }
 733         ]])],
 734         glib_cv_has__inline__=yes
 735         ,
 736         glib_cv_has__inline__=no
 737         ,)
 738 ])
 739 case x$glib_cv_has__inline__ in
 740 xyes) AC_DEFINE(G_HAVE___INLINE__,1,[Have __inline__ keyword])
 741 esac
 742 AC_CACHE_CHECK([for inline], glib_cv_hasinline,[
 743         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 744         #undef inline
 745         inline int foo () { return 0; }
 746         int main () { return foo (); }
 747         ]])],
 748         glib_cv_hasinline=yes
 749         ,
 750         glib_cv_hasinline=no
 751         ,)
 752 ])
 753 case x$glib_cv_hasinline in
 754 xyes) AC_DEFINE(G_HAVE_INLINE,1,[Have inline keyword])
 755 esac
 756
 757 # if we can use inline functions in headers
 758 AC_MSG_CHECKING(if inline functions in headers work)
 759 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 760 #if defined (G_HAVE_INLINE) && defined (__GNUC__) && defined (__STRICT_ANSI__)
 761 #  undef inline
 762 #  define inline __inline__
 763 #elif !defined (G_HAVE_INLINE)
 764 #  undef inline
 765 #  if defined (G_HAVE___INLINE__)
 766 #    define inline __inline__
 767 #  elif defined (G_HAVE___INLINE)
 768 #    define inline __inline
 769 #  endif
 770 #endif
 771
 772 int glib_test_func2 (int);
 773
 774 static inline int
 775 glib_test_func1 (void) {
 776   return glib_test_func2 (1);
 777 }
 778
 779 int
 780 main (void) {
 781   int i = 1;
 782 }]])],[g_can_inline=yes],[g_can_inline=no])
 783 AC_MSG_RESULT($g_can_inline)
 784
 785 dnl *** check for working do while(0) macros ***
 786 AC_CACHE_CHECK([for working do while(0) macros], g_cv_support_dowhile_macros, [
 787         AC_TRY_COMPILE([],[
 788         #define STMT_START do
 789         #define STMT_END while(0)
 790         #define STMT_TEST STMT_START { i = 0; } STMT_END
 791         int main(void) { int i = 1; STMT_TEST; return i; }],
 792         [g_cv_support_dowhile_macros=yes],
 793         [g_cv_support_dowhile_macros=no],
 794         [g_cv_support_dowhile_macros=yes])
 795 ])
 796 if test x$g_cv_support_dowhile_macros = xyes; then
 797   AC_DEFINE(HAVE_DOWHILE_MACROS, 1, [define for working do while(0) macros])
 798 fi
 799
 800 # check for flavours of varargs macros
 801 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 802 AC_TRY_COMPILE([],[
 803 int a(int p1, int p2, int p3);
 804 #define call_a(...) a(1,__VA_ARGS__)
 805 call_a(2,3);
 806 ],g_have_iso_c_varargs=yes,g_have_iso_c_varargs=no)
 807 AC_MSG_RESULT($g_have_iso_c_varargs)
 808
 809 AC_MSG_CHECKING(for ISO C99 varargs macros in C++)
 810 AS_IF([test "$CXX" = ""], [
 811 dnl No C++ compiler
 812   g_have_iso_cxx_varargs=no
 813 else
 814   AC_LANG_CPLUSPLUS
 815   AC_TRY_COMPILE([],[
 816 int a(int p1, int p2, int p3);
 817 #define call_a(...) a(1,__VA_ARGS__)
 818 call_a(2,3);
 819 ],g_have_iso_cxx_varargs=yes,g_have_iso_cxx_varargs=no)
 820   AC_LANG_C
 821 ])
 822 AC_MSG_RESULT($g_have_iso_cxx_varargs)
 823
 824 AC_MSG_CHECKING(for GNUC varargs macros)
 825 AC_TRY_COMPILE([],[
 826 int a(int p1, int p2, int p3);
 827 #define call_a(params...) a(1,params)
 828 call_a(2,3);
 829 ],g_have_gnuc_varargs=yes,g_have_gnuc_varargs=no)
 830 AC_MSG_RESULT($g_have_gnuc_varargs)
 831
 832 # check for GNUC visibility support
 833 AC_MSG_CHECKING(for GNUC visibility attribute)
 834 GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 835 void
 836 __attribute__ ((visibility ("hidden")))
 837      f_hidden (void)
 838 {
 839 }
 840 void
 841 __attribute__ ((visibility ("internal")))
 842      f_internal (void)
 843 {
 844 }
 845 void
 846 __attribute__ ((visibility ("protected")))
 847      f_protected (void)
 848 {
 849 }
 850 void
 851 __attribute__ ((visibility ("default")))
 852      f_default (void)
 853 {
 854 }
 855 int main (int argc, char **argv)
 856 {
 857         f_hidden();
 858         f_internal();
 859         f_protected();
 860         f_default();
 861         return 0;
 862 }
 863 ]])],g_have_gnuc_visibility=yes,g_have_gnuc_visibility=no)
 864 AC_MSG_RESULT($g_have_gnuc_visibility)
 865 AM_CONDITIONAL(HAVE_GNUC_VISIBILITY, [test x$g_have_gnuc_visibility = xyes])
 866
 867 AC_MSG_CHECKING([whether using Sun Studio C compiler])
 868 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#if defined(__SUNPRO_C) || (__SUNPRO_C >= 0x550)
 869 #else
 870 # include "error: this is not Sun Studio."
 871 #endif
 872 ]], [[]])], [ g_have_sunstudio_visibility=yes ], [ g_have_sunstudio_visibility=no ])
 873 AC_MSG_RESULT($g_have_sunstudio_visibility)
 874 AM_CONDITIONAL(HAVE_SUNSTUDIO_VISIBILITY, [test x$g_have_sunstudio_visibility = xyes])
 875
 876 # check for bytesex stuff
 877 AC_C_BIGENDIAN
 878 if test x$ac_cv_c_bigendian = xuniversal ; then
 879 AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __BIG_ENDIAN
 880 #else
 881 #error Not a big endian.
 882 #endif],
 883     ac_cv_c_bigendian=yes
 884     ,AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __LITTLE_ENDIAN
 885 #else
 886 #error Not a little endian.
 887 #endif],
 888     ac_cv_c_bigendian=no
 889     ,AC_MSG_WARN([Could not determine endianness.])))
 890 fi
 891
 892
 893 # check for header files
 894 AC_CHECK_HEADERS([dirent.h float.h limits.h pwd.h grp.h sys/param.h sys/poll.h sys/resource.h])
 895 AC_CHECK_HEADERS([sys/time.h sys/times.h sys/wait.h unistd.h values.h])
 896 AC_CHECK_HEADERS([sys/select.h sys/types.h stdint.h inttypes.h sched.h malloc.h])
 897 AC_CHECK_HEADERS([sys/vfs.h sys/vmount.h sys/statfs.h sys/statvfs.h sys/filio.h])
 898 AC_CHECK_HEADERS([mntent.h sys/mnttab.h sys/vfstab.h sys/mntctl.h fstab.h])
 899 AC_CHECK_HEADERS([sys/uio.h sys/mkdev.h])
 900 AC_CHECK_HEADERS([linux/magic.h])
 901 AC_CHECK_HEADERS([sys/prctl.h])
 902
 903 AC_CHECK_HEADERS([sys/mount.h sys/sysctl.h], [], [],
 904 [#if HAVE_SYS_PARAM_H
 905  #include <sys/param.h>
 906  #endif
 907 ])
 908
 909 AC_CHECK_HEADERS([xlocale.h])
 910
 911 # check for structure fields
 912 AC_CHECK_MEMBERS([struct stat.st_mtimensec, struct stat.st_mtim.tv_nsec, struct stat.st_atimensec, struct stat.st_atim.tv_nsec, struct stat.st_ctimensec, struct stat.st_ctim.tv_nsec])
 913 AC_CHECK_MEMBERS([struct stat.st_blksize, struct stat.st_blocks, struct statfs.f_fstypename, struct statfs.f_bavail],,, [#include <sys/types.h>
 914 #include <sys/stat.h>
 915 #include <unistd.h>
 916 #ifdef HAVE_SYS_STATFS_H
 917 #include <sys/statfs.h>
 918 #endif
 919 #ifdef HAVE_SYS_PARAM_H
 920 #include <sys/param.h>
 921 #endif
 922 #ifdef HAVE_SYS_MOUNT_H
 923 #include <sys/mount.h>
 924 #endif])
 925 # struct statvfs.f_basetype is available on Solaris but not for Linux.
 926 AC_CHECK_MEMBERS([struct statvfs.f_basetype],,, [#include <sys/statvfs.h>])
 927 AC_CHECK_MEMBERS([struct statvfs.f_fstypename],,, [#include <sys/statvfs.h>])
 928 AC_CHECK_MEMBERS([struct tm.tm_gmtoff, struct tm.__tm_gmtoff],,,[#include <time.h>])
 929
 930 AC_STRUCT_DIRENT_D_TYPE
 931
 932 # Checks for libcharset
 933 AM_LANGINFO_CODESET
 934 AC_CHECK_HEADERS([stddef.h stdlib.h string.h])
 935 AC_CHECK_FUNCS(setlocale)
 936
 937 # check additional type sizes
 938 AC_CHECK_SIZEOF(size_t)
 939
 940 dnl Try to figure out whether gsize, gssize should be long or int
 941 AC_MSG_CHECKING([for the appropriate definition for size_t])
 942
 943 case $ac_cv_sizeof_size_t in
 944   $ac_cv_sizeof_short)
 945       glib_size_type=short
 946       ;;
 947   $ac_cv_sizeof_int)
 948       glib_size_type=int
 949       ;;
 950   $ac_cv_sizeof_long)
 951       glib_size_type=long
 952       ;;
 953   $ac_cv_sizeof_long_long)
 954       glib_size_type='long long'
 955       ;;
 956   $ac_cv_sizeof__int64)
 957       glib_size_type='__int64'
 958       ;;
 959   *)  AC_MSG_ERROR([No type matching size_t in size])
 960       ;;
 961 esac
 962
 963 dnl If int/long are the same size, we see which one produces
 964 dnl warnings when used in the location as size_t. (This matters
 965 dnl on AIX with xlc)
 966 dnl
 967 AS_IF([test $ac_cv_sizeof_size_t = $ac_cv_sizeof_int &&
 968        test $ac_cv_sizeof_size_t = $ac_cv_sizeof_long], [
 969   GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 970 #if defined(_AIX) && !defined(__GNUC__)
 971 #pragma options langlvl=stdc89
 972 #endif
 973 #include <stddef.h>
 974 int main ()
 975 {
 976   size_t s = 1;
 977   unsigned int *size_int = &s;
 978   return (int)*size_int;
 979 }
 980     ]])],glib_size_type=int,
 981       [GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 982 #if defined(_AIX) && !defined(__GNUC__)
 983 #pragma options langlvl=stdc89
 984 #endif
 985 #include <stddef.h>
 986 int main ()
 987 {
 988    size_t s = 1;
 989    unsigned long *size_long = &s;
 990    return (int)*size_long;
 991 }
 992         ]])],glib_size_type=long)])
 993 ])
 994
 995 AC_MSG_RESULT(unsigned $glib_size_type)
 996
 997 # Check for some functions
 998 AC_CHECK_FUNCS(lstat strerror strsignal memmove vsnprintf stpcpy strcasecmp strncasecmp poll getcwd vasprintf setenv unsetenv getc_unlocked readlink symlink fdwalk memmem)
 999 AC_CHECK_FUNCS(chown lchmod lchown fchmod fchown link utimes getgrgid getpwuid getresuid)
1000 AC_CHECK_FUNCS(getmntent_r setmntent endmntent hasmntopt getfsstat getvfsstat)
1001 # Check for high-resolution sleep functions
1002 AC_CHECK_FUNCS(splice)
1003 AC_CHECK_FUNCS(prlimit)
1004
1005 # To avoid finding a compatibility unusable statfs, which typically
1006 # successfully compiles, but warns to use the newer statvfs interface:
1007 AS_IF([test $ac_cv_header_sys_statvfs_h = yes], [AC_CHECK_FUNCS([statvfs])])
1008 AS_IF([test $ac_cv_header_sys_statfs_h  = yes -o $ac_cv_header_sys_mount_h = yes], [AC_CHECK_FUNCS([statfs])])
1009
1010 AC_MSG_CHECKING([whether to use statfs or statvfs])
1011 # Some systems have both statfs and statvfs, pick the most "native" for these
1012 AS_IF([test x$ac_cv_func_statfs = xyes && test x$ac_cv_func_statvfs = xyes],
1013    [
1014    # on solaris and irix, statfs doesn't even have the f_bavail field
1015    AS_IF([test x$ac_cv_member_struct_statfs_f_bavail = xno],
1016       [ac_cv_func_statfs=no],
1017    # else, at least on linux, statfs is the actual syscall
1018       [ac_cv_func_statvfs=no])
1019    ])
1020
1021 AS_IF([test x$ac_cv_func_statfs = xyes],
1022       [
1023          AC_DEFINE([USE_STATFS], [1], [Define to use statfs()])
1024          AC_MSG_RESULT([statfs])
1025       ],
1026       [test x$ac_cv_func_statvfs = xyes],
1027       [
1028          AC_DEFINE([USE_STATVFS], [1], [Define to use statvfs()])
1029          AC_MSG_RESULT([statvfs])
1030       ],
1031       [  AC_MSG_RESULT([neither])])
1032
1033 AC_CHECK_HEADERS(crt_externs.h)
1034 AC_CHECK_FUNCS(_NSGetEnviron)
1035
1036 AC_CHECK_FUNCS(newlocale uselocale strtod_l strtoll_l strtoull_l)
1037
1038 AC_FUNC_VSNPRINTF_C99
1039 AC_FUNC_PRINTF_UNIX98
1040
1041 # Internet address families
1042 if test $glib_native_win32 = yes; then
1043   glib_inet_includes=["
1044 #include <winsock2.h>
1045   "]
1046 else
1047   glib_inet_includes=["
1048 #include <sys/types.h>
1049 #include <sys/socket.h>
1050   "]
1051 fi
1052
1053 glib_failed=false
1054 GLIB_CHECK_VALUE(AF_INET, $glib_inet_includes, glib_failed=true)
1055 GLIB_CHECK_VALUE(AF_INET6, $glib_inet_includes, glib_failed=true)
1056 # winsock defines this even though it doesn't support it
1057 GLIB_CHECK_VALUE(AF_UNIX, $glib_inet_includes, glib_failed=true)
1058 if $glib_failed ; then
1059   AC_MSG_ERROR([Could not determine values for AF_INET* constants])
1060 fi
1061
1062 glib_failed=false
1063 GLIB_CHECK_VALUE(MSG_PEEK, $glib_inet_includes, glib_failed=true)
1064 GLIB_CHECK_VALUE(MSG_OOB, $glib_inet_includes, glib_failed=true)
1065 GLIB_CHECK_VALUE(MSG_DONTROUTE, $glib_inet_includes, glib_failed=true)
1066 if $glib_failed ; then
1067   AC_MSG_ERROR([Could not determine values for MSG_* constants])
1068 fi
1069
1070 AC_CHECK_FUNCS(getprotobyname_r endservent if_nametoindex)
1071 AC_CHECK_HEADERS([netdb.h wspiapi.h arpa/nameser_compat.h])
1072
1073 AS_IF([test $glib_native_win32 = no], [
1074   # We can't just use AC_CHECK_FUNC/AC_CHECK_LIB here. Bug 586150
1075   NETWORK_LIBS=""
1076   AC_MSG_CHECKING([for res_query])
1077   AC_TRY_LINK([#include <sys/types.h>
1078                #include <netinet/in.h>
1079                #include <arpa/nameser.h>
1080                #include <resolv.h>
1081               ],[
1082                res_query("test", 0, 0, (void *)0, 0);
1083               ],[AC_MSG_RESULT([yes])],
1084               [save_libs="$LIBS"
1085                LIBS="-lresolv $LIBS"
1086                AC_TRY_LINK([#include <sys/types.h>
1087                             #include <netinet/in.h>
1088                             #include <arpa/nameser.h>
1089                             #include <resolv.h>
1090                            ],[
1091                             res_query("test", 0, 0, (void *)0, 0);
1092                            ],[AC_MSG_RESULT([in -lresolv])
1093                               NETWORK_LIBS="-lresolv $NETWORK_LIBS"],
1094                            [LIBS="-lbind $save_libs"
1095                             AC_TRY_LINK([#include <resolv.h>],
1096                                         [res_query("test", 0, 0, (void *)0, 0);],
1097                                         [AC_MSG_RESULT([in -lbind])
1098                                          NETWORK_LIBS="-lbind $NETWORK_LIBS"],
1099                                         [AC_MSG_ERROR(not found)])])
1100                LIBS="$save_libs"])
1101   AC_CHECK_FUNC(socket, :, AC_CHECK_LIB(socket, socket,
1102                                         [NETWORK_LIBS="-lsocket $NETWORK_LIBS"],
1103                                         [AC_MSG_ERROR(Could not find socket())]))
1104 ])
1105 AC_SUBST(NETWORK_LIBS)
1106
1107 AC_CHECK_HEADER([linux/netlink.h],
1108                 [AC_DEFINE(HAVE_NETLINK, 1, [We have AF_NETLINK sockets])],,
1109                 [#include <sys/socket.h>])
1110 AM_CONDITIONAL(HAVE_NETLINK, [test "$ac_cv_header_linux_netlink_h" = "yes"])
1111
1112 AC_CHECK_TYPE([struct ip_mreqn], [
1113               AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
1114               [#include <netinet/in.h>])
1115
1116 case $host in
1117   *-*-solaris* )
1118      AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1119      AC_DEFINE(_XOPEN_SOURCE,          2, Needed to get declarations for msg_control and msg_controllen on Solaris)
1120      AC_DEFINE(__EXTENSIONS__,         1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1121      ;;
1122 esac
1123
1124 dnl
1125 dnl if statfs() takes 2 arguments (Posix) or 4 (Solaris)
1126 dnl
1127 AS_IF([test "$ac_cv_func_statfs" = yes], [
1128   AC_MSG_CHECKING([number of arguments to statfs()])
1129   AC_TRY_COMPILE([#include <unistd.h>
1130   #ifdef HAVE_SYS_PARAM_H
1131   #include <sys/param.h>
1132   #endif
1133   #ifdef HAVE_SYS_VFS_H
1134   #include <sys/vfs.h>
1135   #endif
1136   #ifdef HAVE_SYS_MOUNT_H
1137   #include <sys/mount.h>
1138   #endif
1139   #ifdef HAVE_SYS_STATFS_H
1140   #include <sys/statfs.h>
1141   #endif], [struct statfs st;
1142   statfs(NULL, &st);],[
1143     AC_MSG_RESULT([2])
1144     AC_DEFINE(STATFS_ARGS, 2, [Number of arguments to statfs()])],[
1145     AC_TRY_COMPILE([#include <unistd.h>
1146   #ifdef HAVE_SYS_PARAM_H
1147   #include <sys/param.h>
1148   #endif
1149   #ifdef HAVE_SYS_VFS_H
1150   #include <sys/vfs.h>
1151   #endif
1152   #ifdef HAVE_SYS_MOUNT_H
1153   #include <sys/mount.h>
1154   #endif
1155   #ifdef HAVE_SYS_STATFS_H
1156   #include <sys/statfs.h>
1157   #endif], [struct statfs st;
1158   statfs(NULL, &st, sizeof (st), 0);],[
1159       AC_MSG_RESULT([4])
1160       AC_DEFINE(STATFS_ARGS, 4, [Number of arguments to statfs()])],[
1161       AC_MSG_RESULT(unknown)
1162       AC_MSG_ERROR([unable to determine number of arguments to statfs()])])])
1163 ])
1164
1165 #
1166 # Check whether to use an included printf
1167 #
1168
1169 AC_ARG_ENABLE(included-printf,
1170               [AS_HELP_STRING([--enable-included-printf],
1171                               [use included printf [default=auto]])],
1172               enable_included_printf="$enableval")
1173
1174 need_included_printf=no
1175 if test "x$enable_included_printf" = "xyes" ; then
1176   need_included_printf=yes
1177 fi
1178 if test "$ac_cv_func_vsnprintf_c99" != "yes" ; then
1179   need_included_printf=yes
1180 fi
1181 if test "$ac_cv_func_printf_unix98" != "yes" ; then
1182   need_included_printf=yes
1183 fi
1184 if test "x$ac_cv_sizeof_long_long" = "x8" &&
1185    test -z "$glib_cv_long_long_format" ; then
1186   need_included_printf=yes
1187 fi
1188
1189 if test "x$enable_included_printf" = "xno" &&
1190    test "x$need_included_printf" = "xyes" ; then
1191   AC_MSG_ERROR([
1192 *** Your C library's printf doesn't appear to have the features that
1193 *** GLib needs, but you specified --enable-included-printf=no.])
1194 fi
1195
1196 enable_included_printf=$need_included_printf
1197
1198 AM_CONDITIONAL(HAVE_GOOD_PRINTF, test "$enable_included_printf" != "yes")
1199 AS_IF([test "$enable_included_printf" != "yes"], [
1200   AC_DEFINE(HAVE_GOOD_PRINTF,1,[define to use system printf])
1201 ], [
1202   if test -z "$glib_cv_long_long_format" ; then
1203     glib_cv_long_long_format="ll"
1204   fi
1205   AC_DEFINE(HAVE_VASPRINTF,1)
1206 ])
1207
1208 # Checks needed for gnulib vasnprintf
1209 bh_C_SIGNED
1210 jm_AC_TYPE_LONG_LONG
1211 gt_TYPE_LONGDOUBLE
1212 gt_TYPE_WCHAR_T
1213 gt_TYPE_WINT_T
1214 AC_TYPE_SIZE_T
1215 AC_CHECK_TYPES(ptrdiff_t)
1216 jm_AC_TYPE_INTMAX_T
1217 AC_CHECK_FUNCS([snprintf wcslen])
1218 AC_FUNC_SNPRINTF_C99
1219
1220 # Check if bcopy can be used for overlapping copies, if memmove isn't found.
1221 # The check is borrowed from the PERL Configure script.
1222 AS_IF([test "$ac_cv_func_memmove" != "yes"],
1223   AC_CACHE_CHECK(whether bcopy can handle overlapping copies,
1224     glib_cv_working_bcopy,[AC_TRY_RUN([
1225       int main() {
1226         char buf[128], abc[128], *b;
1227         int len, off, align;
1228         bcopy("abcdefghijklmnopqrstuvwxyz0123456789", abc, 36);
1229         for (align = 7; align >= 0; align--) {
1230           for (len = 36; len; len--) {
1231             b = buf+align; bcopy(abc, b, len);
1232             for (off = 1; off <= len; off++) {
1233               bcopy(b, b+off, len); bcopy(b+off, b, len);
1234                 if (bcmp(b, abc, len)) return(1);
1235             }
1236           }
1237         }
1238         return(0);
1239       }],glib_cv_working_bcopy=yes,glib_cv_working_bcopy=no)])
1240
1241   GLIB_ASSERT_SET(glib_cv_working_bcopy)
1242   if test "$glib_cv_working_bcopy" = "yes"; then
1243     AC_DEFINE(HAVE_WORKING_BCOPY,1,[Have a working bcopy])
1244   fi
1245 ])
1246
1247 # Check if <sys/select.h> needs to be included for fd_set
1248 AC_MSG_CHECKING([for fd_set])
1249 AC_TRY_COMPILE([#include <sys/types.h>],
1250         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
1251 AS_IF([test "$gtk_ok" = "yes"], [
1252     AC_MSG_RESULT([yes, found in sys/types.h])
1253 ], [
1254     AC_EGREP_HEADER(fd_set, sys/select.h, gtk_ok=yes)
1255     if test "$gtk_ok" = "yes"; then
1256         # *** FIXME: give it a different name
1257         AC_DEFINE(HAVE_SYS_SELECT_H,1,[found fd_set in sys/select.h])
1258         AC_MSG_RESULT([yes, found in sys/select.h])
1259     else
1260         AC_DEFINE(NO_FD_SET,1,[didn't find fd_set])
1261         AC_MSG_RESULT(no)
1262     fi
1263 ])
1264
1265 dnl *** check for sane realloc() ***
1266 AC_CACHE_CHECK([whether realloc (NULL,) will work],glib_cv_sane_realloc,[
1267         AC_TRY_RUN([#include <stdlib.h>
1268         int main() {
1269           return realloc (0, sizeof (int)) == 0;
1270         }],
1271         [glib_cv_sane_realloc=yes],
1272         [glib_cv_sane_realloc=no],
1273         [glib_cv_sane_realloc=yes])
1274 ])
1275 AS_IF([test x$glib_cv_sane_realloc = xyes], [
1276   AC_DEFINE(REALLOC_0_WORKS,1,[whether realloc (NULL,) works])
1277 ])
1278
1279 dnl Check for nl_langinfo and CODESET
1280 AC_CACHE_CHECK([for nl_langinfo (CODESET)],glib_cv_langinfo_codeset,[
1281         AC_TRY_COMPILE([#include <langinfo.h>],
1282                 [char *codeset = nl_langinfo (CODESET);],
1283                 [glib_cv_langinfo_codeset=yes],
1284                 [glib_cv_langinfo_codeset=no])])
1285 if test x$glib_cv_langinfo_codeset = xyes; then
1286   AC_DEFINE(HAVE_CODESET,1,[Have nl_langinfo (CODESET)])
1287 fi
1288
1289 dnl Check for nl_langinfo and LC_TIME parts that are needed in gdatetime.c
1290 AC_CACHE_CHECK([for nl_langinfo (PM_STR)],glib_cv_langinfo_time,[
1291         AC_TRY_COMPILE([#include <langinfo.h>],
1292                 [char *str;
1293                  str = nl_langinfo (PM_STR);
1294                  str = nl_langinfo (D_T_FMT);
1295                  str = nl_langinfo (D_FMT);
1296                  str = nl_langinfo (T_FMT);
1297                  str = nl_langinfo (T_FMT_AMPM);
1298                  str = nl_langinfo (MON_1);
1299                  str = nl_langinfo (ABMON_12);
1300                  str = nl_langinfo (DAY_1);
1301                  str = nl_langinfo (ABDAY_7);],
1302                 [glib_cv_langinfo_time=yes],
1303                 [glib_cv_langinfo_time=no])])
1304 if test x$glib_cv_langinfo_time = xyes; then
1305   AC_DEFINE(HAVE_LANGINFO_TIME,1,[Have nl_langinfo (PM_STR)])
1306 fi
1307
1308 dnl Check for nl_langinfo and _NL_CTYPE_OUTDIGITn_MB
1309 AC_CACHE_CHECK([for nl_langinfo (_NL_CTYPE_OUTDIGITn_MB)], glib_cv_langinfo_outdigit,[
1310         AC_TRY_COMPILE([#include <langinfo.h>],
1311                 [char *str;
1312                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT0_MB);
1313                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT1_MB);
1314                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT2_MB);
1315                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT3_MB);
1316                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT4_MB);
1317                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT5_MB);
1318                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT6_MB);
1319                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT7_MB);
1320                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT8_MB);
1321                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT9_MB);],
1322                 [glib_cv_langinfo_outdigit=yes],
1323                 [glib_cv_langinfo_outdigit=no])])
1324 if test x$glib_cv_langinfo_outdigit = xyes; then
1325   AC_DEFINE(HAVE_LANGINFO_OUTDIGIT,1,[Have nl_langinfo (_NL_CTYPE_OUTDIGITn_MB)])
1326 fi
1327
1328 dnl ****************************************
1329 dnl *** posix_memalign                   ***
1330 dnl ****************************************
1331 AC_MSG_CHECKING(for a compliant posix_memalign() implementation)
1332 AC_CACHE_VAL(glib_cv_compliant_posix_memalign,[
1333     glib_cv_compliant_posix_memalign=0
1334     if test "$ac_cv_func_posix_memalign" = "yes" ; then
1335         AC_TRY_RUN([
1336                 #define _XOPEN_SOURCE 600
1337                 #include <stdlib.h> /* posix_memalign() should be defined here */
1338                 /* some systems break if #include <malloc.h> used */
1339                 static void test_memalign (size_t boundary, size_t size) {
1340                     void *mem = 0;
1341                     if (posix_memalign (&mem, boundary, size) != 0 || !mem)
1342                         exit (1);
1343                     else
1344                       free (mem);
1345                 }
1346                 int main() {
1347                     test_memalign (  128,   128 - 2 * sizeof (void*));
1348                     test_memalign (  256,   256 - 2 * sizeof (void*));
1349                     test_memalign (  512,   512 - 2 * sizeof (void*));
1350                     test_memalign ( 1024,  1024 - 2 * sizeof (void*));
1351                     test_memalign ( 2048,  2048 - 2 * sizeof (void*));
1352                     test_memalign ( 4096,  4096 - 2 * sizeof (void*));
1353                     test_memalign ( 8192,  8192 - 2 * sizeof (void*));
1354                     test_memalign (16384, 16384 - 2 * sizeof (void*));
1355                     test_memalign (32768, 32768 - 2 * sizeof (void*));
1356                     exit (0); /* success */
1357                 }
1358                 ],
1359             [glib_cv_compliant_posix_memalign=1], [], [:])
1360       :
1361     fi
1362     ])
1363 AS_IF([test "$glib_cv_compliant_posix_memalign" = "1"], [
1364     AC_MSG_RESULT(yes)
1365     AC_DEFINE(POSIX_MEMALIGN_WITH_COMPLIANT_ALLOCS, 1, [define if posix_memalign() can allocate any size])
1366 ], [
1367     AC_MSG_RESULT(no)
1368 ])
1369
1370
1371 dnl ****************************************
1372 dnl *** strlcpy/strlcat                  ***
1373 dnl ****************************************
1374 # Check for strlcpy
1375 AC_CACHE_CHECK([for OpenBSD strlcpy/strlcat],glib_cv_have_strlcpy,[
1376 AC_TRY_RUN([#include <stdlib.h>
1377 #include <string.h>
1378 int main() {
1379   char p[10];
1380   (void) strlcpy (p, "hi", 10);
1381   if (strlcat (p, "bye", 0) != 3)
1382     return 1;
1383   return 0;
1384 }], glib_cv_have_strlcpy=yes,
1385     glib_cv_have_strlcpy=no,
1386     glib_cv_have_strlcpy=no)])
1387 if test "$glib_cv_have_strlcpy" = "yes"; then
1388     AC_DEFINE(HAVE_STRLCPY,1,[Have functions strlcpy and strlcat])
1389 fi
1390
1391
1392 dnl **********************
1393 dnl *** va_copy checks ***
1394 dnl **********************
1395 dnl we currently check for all three va_copy possibilities, so we get
1396 dnl all results in config.log for bug reports.
1397 AC_CACHE_CHECK([for an implementation of va_copy()],glib_cv_va_copy,[
1398         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1399 #include <stdlib.h>
1400         void f (int i, ...) {
1401         va_list args1, args2;
1402         va_start (args1, i);
1403         va_copy (args2, args1);
1404         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1405           exit (1);
1406         va_end (args1); va_end (args2);
1407         }
1408         int main() {
1409           f (0, 42);
1410           return 0;
1411         }]])],
1412         [glib_cv_va_copy=yes],
1413         [glib_cv_va_copy=no])
1414 ])
1415 AC_CACHE_CHECK([for an implementation of __va_copy()],glib_cv___va_copy,[
1416         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1417 #include <stdlib.h>
1418         void f (int i, ...) {
1419         va_list args1, args2;
1420         va_start (args1, i);
1421         __va_copy (args2, args1);
1422         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1423           exit (1);
1424         va_end (args1); va_end (args2);
1425         }
1426         int main() {
1427           f (0, 42);
1428           return 0;
1429         }]])],
1430         [glib_cv___va_copy=yes],
1431         [glib_cv___va_copy=no])
1432 ])
1433
1434 if test "x$glib_cv_va_copy" = "xyes"; then
1435   g_va_copy_func=va_copy
1436 else if test "x$glib_cv___va_copy" = "xyes"; then
1437   g_va_copy_func=__va_copy
1438 fi
1439 fi
1440
1441 if test -n "$g_va_copy_func"; then
1442   AC_DEFINE_UNQUOTED(G_VA_COPY,$g_va_copy_func,[A 'va_copy' style function])
1443 fi
1444
1445 AC_CACHE_CHECK([whether va_lists can be copied by value],glib_cv_va_val_copy,[
1446         AC_TRY_RUN([#include <stdarg.h>
1447 #include <stdlib.h>
1448         void f (int i, ...) {
1449         va_list args1, args2;
1450         va_start (args1, i);
1451         args2 = args1;
1452         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1453           exit (1);
1454         va_end (args1); va_end (args2);
1455         }
1456         int main() {
1457           f (0, 42);
1458           return 0;
1459         }],
1460         [glib_cv_va_val_copy=yes],
1461         [glib_cv_va_val_copy=no],
1462         [glib_cv_va_val_copy=yes])
1463 ])
1464
1465 AS_IF([ test "x$glib_cv_va_val_copy" = "xno"], [
1466   AC_DEFINE(G_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
1467 ])
1468
1469 dnl ***********************
1470 dnl *** g_module checks ***
1471 dnl ***********************
1472 G_MODULE_LIBS=
1473 G_MODULE_LIBS_EXTRA=
1474 G_MODULE_PLUGIN_LIBS=
1475 if test x"$glib_native_win32" = xyes; then
1476   dnl No use for this on Win32
1477   G_MODULE_LDFLAGS=
1478 else
1479   export SED
1480   G_MODULE_LDFLAGS=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1481 fi
1482 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
1483 G_MODULE_NEED_USCORE=0
1484 G_MODULE_BROKEN_RTLD_GLOBAL=0
1485 G_MODULE_HAVE_DLERROR=0
1486 dnl *** force native WIN32 shared lib loader
1487 if test -z "$G_MODULE_IMPL"; then
1488   case "$host" in
1489   *-*-mingw*|*-*-cygwin*) G_MODULE_IMPL=G_MODULE_IMPL_WIN32 ;;
1490   esac
1491 fi
1492 dnl *** force native AIX library loader
1493 dnl *** dlopen() filepath must be of the form /path/libname.a(libname.so)
1494 if test -z "$G_MODULE_IMPL"; then
1495   case "$host" in
1496   *-*-aix*) G_MODULE_IMPL=G_MODULE_IMPL_AR ;;
1497   esac
1498 fi
1499 dnl *** dlopen() and dlsym() in system libraries
1500 AS_IF([ test -z "$G_MODULE_IMPL"], [
1501         AC_CHECK_FUNC(dlopen,
1502                       [AC_CHECK_FUNC(dlsym,
1503                                      [G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1504                       [])
1505 ])
1506 dnl *** load_image (BeOS)
1507 AS_IF([test -z "$G_MODULE_IMPL" && test "x$glib_native_beos" = "xyes"], [
1508   AC_CHECK_LIB(root, load_image,
1509       [G_MODULE_LIBS="-lbe -lroot -lglib-2.0 "
1510       G_MODULE_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
1511       G_MODULE_PLUGIN_LIBS="-L\$(top_builddir_full)/gmodule/.libs -lgmodule"
1512       G_MODULE_IMPL=G_MODULE_IMPL_BEOS],
1513       [])
1514 ])
1515 dnl *** NSLinkModule (dyld) in system libraries (Darwin)
1516 AS_IF([ test -z "$G_MODULE_IMPL" ], [
1517         AC_CHECK_FUNC(NSLinkModule,
1518                       [G_MODULE_IMPL=G_MODULE_IMPL_DYLD
1519                        G_MODULE_NEED_USCORE=1],
1520                       [])
1521 ])
1522 dnl *** dlopen() and dlsym() in libdl
1523 AS_IF([ test -z "$G_MODULE_IMPL"], [
1524         AC_CHECK_LIB(dl, dlopen,
1525                      [AC_CHECK_LIB(dl, dlsym,
1526                                    [G_MODULE_LIBS=-ldl
1527                                    G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1528                      [])
1529 ])
1530 dnl *** shl_load() in libdld (HP-UX)
1531 AS_IF([ test -z "$G_MODULE_IMPL"], [
1532         AC_CHECK_LIB(dld, shl_load,
1533                 [G_MODULE_LIBS=-ldld
1534                 G_MODULE_IMPL=G_MODULE_IMPL_DLD],
1535                 [])
1536 ])
1537 dnl *** additional checks for G_MODULE_IMPL_DL
1538 AS_IF([ test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL" ], [
1539         LIBS_orig="$LIBS"
1540         LDFLAGS_orig="$LDFLAGS"
1541         LIBS="$G_MODULE_LIBS $LIBS"
1542         LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
1543 dnl *** check for OSF1/5.0 RTLD_GLOBAL brokenness
1544         echo "void glib_plugin_test(void) { }" > plugin.c
1545         ${SHELL} ./libtool --mode=compile --tag=CC ${CC} ${CFLAGS} \
1546                 ${CPPFLAGS} -c -o plugin.lo plugin.c >/dev/null 2>&1
1547         ${SHELL} ./libtool --mode=link --tag=CC ${CC} ${CFLAGS} \
1548                 ${LDFLAGS} -module -o plugin.la -export-dynamic \
1549                 -shrext ".o" -avoid-version plugin.lo \
1550                 -rpath /dont/care >/dev/null 2>&1
1551         eval `./libtool --config | grep ^objdir`
1552         AC_CACHE_CHECK([for RTLD_GLOBAL brokenness],
1553                 glib_cv_rtldglobal_broken,[
1554                 AC_TRY_RUN([
1555 #include <dlfcn.h>
1556 #ifndef RTLD_GLOBAL
1557 #  define RTLD_GLOBAL 0
1558 #endif
1559 #ifndef RTLD_LAZY
1560 #  define RTLD_LAZY 0
1561 #endif
1562 int glib_plugin_test;
1563 int main () {
1564     void *handle, *global, *local;
1565     global = &glib_plugin_test;
1566     handle = dlopen ("./$objdir/plugin.o", RTLD_GLOBAL | RTLD_LAZY);
1567     if (!handle) return 0;
1568     local = dlsym (handle, "glib_plugin_test");
1569     return global == local;
1570 }                       ],
1571                         [glib_cv_rtldglobal_broken=no],
1572                         [glib_cv_rtldglobal_broken=yes],
1573                         [glib_cv_rtldglobal_broken=no])
1574                 rm -f plugin.c plugin.o plugin.lo plugin.la ${objdir}/plugin.*
1575                 rmdir ${objdir} 2>/dev/null
1576         ])
1577         if test "x$glib_cv_rtldglobal_broken" = "xyes"; then
1578                 G_MODULE_BROKEN_RTLD_GLOBAL=1
1579         else
1580                 G_MODULE_BROKEN_RTLD_GLOBAL=0
1581         fi
1582 dnl *** check whether we need preceeding underscores
1583         AC_CACHE_CHECK([for preceeding underscore in symbols],
1584                 glib_cv_uscore,[
1585                 AC_TRY_RUN([#include <dlfcn.h>
1586                 int glib_underscore_test (void) { return 42; }
1587                 int main() {
1588                   void *f1 = (void*)0, *f2 = (void*)0, *handle;
1589                   handle = dlopen ((void*)0, 0);
1590                   if (handle) {
1591                     f1 = dlsym (handle, "glib_underscore_test");
1592                     f2 = dlsym (handle, "_glib_underscore_test");
1593                   } return (!f2 || f1);
1594                 }],
1595                         [glib_cv_uscore=yes],
1596                         [glib_cv_uscore=no],
1597                         [])
1598                 rm -f plugin.c plugin.$ac_objext plugin.lo
1599         ])
1600         GLIB_ASSERT_SET(glib_cv_uscore)
1601         if test "x$glib_cv_uscore" = "xyes"; then
1602                 G_MODULE_NEED_USCORE=1
1603         else
1604                 G_MODULE_NEED_USCORE=0
1605         fi
1606
1607         LDFLAGS="$LDFLAGS_orig"
1608 dnl *** check for having dlerror()
1609         AC_CHECK_FUNC(dlerror,
1610                 [G_MODULE_HAVE_DLERROR=1],
1611                 [G_MODULE_HAVE_DLERROR=0])
1612         LIBS="$LIBS_orig"
1613 ])
1614 dnl *** done, have we got an implementation?
1615 if test -z "$G_MODULE_IMPL"; then
1616         G_MODULE_IMPL=0
1617         G_MODULE_SUPPORTED=false
1618 else
1619         G_MODULE_SUPPORTED=true
1620 fi
1621
1622 AC_MSG_CHECKING(for the suffix of module shared libraries)
1623 export SED
1624 shrext_cmds=`./libtool --config | grep '^shrext_cmds='`
1625 eval $shrext_cmds
1626 module=yes eval std_shrext=$shrext_cmds
1627 # chop the initial dot
1628 glib_gmodule_suffix=`echo $std_shrext | sed 's/^\.//'`
1629 AC_MSG_RESULT(.$glib_gmodule_suffix)
1630 # any reason it may fail?
1631 if test "x$glib_gmodule_suffix" = x; then
1632         AC_MSG_ERROR(Cannot determine shared library suffix from libtool)
1633 fi
1634
1635 AC_SUBST(G_MODULE_SUPPORTED)
1636 AC_SUBST(G_MODULE_IMPL)
1637 AC_SUBST(G_MODULE_LIBS)
1638 AC_SUBST(G_MODULE_LIBS_EXTRA)
1639 AC_SUBST(G_MODULE_PLUGIN_LIBS)
1640 AC_SUBST(G_MODULE_LDFLAGS)
1641 AC_SUBST(G_MODULE_HAVE_DLERROR)
1642 AC_SUBST(G_MODULE_BROKEN_RTLD_GLOBAL)
1643 AC_SUBST(G_MODULE_NEED_USCORE)
1644 AC_SUBST(GLIB_DEBUG_FLAGS)
1645
1646 dnl **********************
1647 dnl *** g_spawn checks ***
1648 dnl **********************
1649
1650 AC_MSG_CHECKING(for gspawn implementation)
1651 case "$host" in
1652   *-*-mingw*)
1653     GSPAWN=gspawn-win32.lo
1654     ;;
1655   *)
1656     GSPAWN=gspawn.lo
1657     ;;
1658 esac
1659 AC_MSG_RESULT($GSPAWN)
1660 AC_SUBST(GSPAWN)
1661
1662 dnl *************************
1663 dnl *** GIOChannel checks ***
1664 dnl *************************
1665
1666 AC_MSG_CHECKING(for GIOChannel implementation)
1667 case "$host" in
1668   *-*-mingw*)
1669     GIO=giowin32.lo
1670     ;;
1671   *)
1672     GIO=giounix.lo
1673     ;;
1674 esac
1675 AC_MSG_RESULT($GIO)
1676 AC_SUBST(GIO)
1677
1678 dnl *********************************
1679 dnl *** Directory for GIO modules ***
1680 dnl *********************************
1681
1682 AC_ARG_WITH(gio-module-dir,
1683            [AS_HELP_STRING([--with-gio-module-dir=DIR],
1684                            [load gio modules from this directory [LIBDIR/gio/modules]])],
1685            [],
1686            [with_gio_module_dir='${libdir}/gio/modules'])
1687 GIO_MODULE_DIR=$with_gio_module_dir
1688 AC_SUBST(GIO_MODULE_DIR)
1689
1690 dnl **********************************
1691 dnl *** Check for libselinux (GIO) ***
1692 dnl **********************************
1693 AC_ARG_ENABLE(selinux,
1694               AS_HELP_STRING([--disable-selinux],
1695                              [build without selinux support]))
1696 msg_selinux=no
1697 SELINUX_LIBS=
1698 AS_IF([ test "x$enable_selinux" != "xno"], [
1699
1700  AC_CHECK_LIB(selinux, is_selinux_enabled,
1701    [AC_CHECK_HEADERS(selinux/selinux.h,
1702      [AC_CHECK_LIB(selinux, lgetfilecon_raw,
1703        [AC_DEFINE(HAVE_SELINUX, 1, [Define to 1 if libselinux is available])
1704         SELINUX_LIBS="-lselinux"
1705         msg_selinux=yes])
1706      ])
1707    ])
1708 ])
1709 AC_SUBST(SELINUX_LIBS)
1710
1711 dnl *****************************
1712 dnl ** Check for inotify (GIO) **
1713 dnl *****************************
1714 inotify_support=no
1715 AC_CHECK_HEADERS([sys/inotify.h],
1716 [
1717         inotify_support=yes
1718         AC_CHECK_FUNCS(inotify_init1)
1719 ])
1720
1721 AM_CONDITIONAL(HAVE_INOTIFY, [test "$inotify_support" = "yes"])
1722
1723 dnl *********************************
1724 dnl ** Check for Solaris FEN (GIO) **
1725 dnl *********************************
1726 fen_support=no
1727 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
1728 #include <port.h>
1729 #ifndef PORT_SOURCE_FILE
1730 #error "Please upgrade to Nevada 72 or above to suppoert FEN"
1731 #endif
1732 int main() { return 0; } ]])],
1733 [
1734         fen_support=yes
1735 ],)
1736
1737 AM_CONDITIONAL(HAVE_FEN, [test "$fen_support" = "yes"])
1738
1739 dnl ****************************
1740 dnl *** Checks for FAM (GIO) ***
1741 dnl ****************************
1742
1743 should_disable_fam=no
1744
1745 AC_ARG_ENABLE(fam,
1746               AS_HELP_STRING([--disable-fam],
1747                              [don't use fam for file system monitoring]),
1748                          [
1749                                 if test "x$enable_fam" = "xno"; then
1750                                         should_disable_fam=yes
1751                                 fi
1752                          ]
1753                          )
1754 fam_support=no
1755 FAM_LIBS=
1756 if test "x$should_disable_fam" = "xno"; then
1757 AC_CHECK_LIB(fam, FAMOpen,
1758   [AC_CHECK_HEADERS(fam.h,
1759     [AC_DEFINE(HAVE_FAM, [], [Define if we have FAM])
1760      AC_CHECK_LIB(fam, FAMNoExists,
1761                   AC_DEFINE(HAVE_FAM_NO_EXISTS, [], [Define if we have FAMNoExists in fam]))
1762      FAM_LIBS="-lfam"]
1763      fam_support=yes,
1764     AC_MSG_WARN(*** FAM support will not be built (header files not found) ***))],
1765   AC_MSG_WARN(*** FAM support will not be built (FAM library not found) ***))
1766 AC_SUBST(FAM_LIBS)
1767 fi
1768 AM_CONDITIONAL(HAVE_FAM, [test "$fam_support" = "yes"])
1769
1770
1771 dnl *****************************
1772 dnl *** Check for xattr (GIO) ***
1773 dnl *****************************
1774 AC_ARG_ENABLE(xattr,
1775               AS_HELP_STRING([--disable-xattr], [build without xattr support]))
1776 msg_xattr=no
1777 XATTR_LIBS=
1778 AS_IF([ test "x$enable_xattr" != "xno"], [
1779
1780 dnl either glibc or libattr can provide xattr support
1781
1782 dnl for both of them, we check for getxattr being in
1783 dnl the library and a valid xattr header.
1784
1785 dnl try glibc
1786  AC_CHECK_LIB(c, getxattr,
1787    [AC_CHECK_HEADERS(sys/xattr.h,
1788      [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1789       msg_xattr=yes])
1790    ])
1791
1792   AS_IF([ test "x$msg_xattr" != "xyes"], [
1793 dnl   failure. try libattr
1794    AC_CHECK_LIB(attr, getxattr,
1795       [AC_CHECK_HEADERS(attr/xattr.h,
1796        [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1797         XATTR_LIBS="-lattr"
1798         msg_xattr=yes])
1799       ])
1800   ])
1801
1802   AS_IF([ test "x$msg_xattr" = "xyes"], [
1803     AC_MSG_CHECKING([for XATTR_NOFOLLOW])
1804     AC_TRY_COMPILE([
1805       #include <stdio.h>
1806       #ifdef HAVE_SYS_TYPES_H
1807       #include <sys/types.h>
1808       #endif
1809       #ifdef HAVE_SYS_XATTR_H
1810       #include <sys/xattr.h>
1811       #elif HAVE_ATTR_XATTR_H
1812       #include <attr/xattr.h>
1813       #endif
1814     ],
1815     [ssize_t len = getxattr("", "", NULL, 0, 0, XATTR_NOFOLLOW);],
1816     [
1817       AC_DEFINE([HAVE_XATTR_NOFOLLOW], [1], [Define to 1 if xattr API uses XATTR_NOFOLLOW])
1818       AC_MSG_RESULT([yes])
1819     ],
1820     [AC_MSG_RESULT([no])]
1821     )
1822   ])
1823 ])
1824 AC_SUBST(XATTR_LIBS)
1825
1826 dnl ************************
1827 dnl *** check for libelf ***
1828 dnl ************************
1829 AC_ARG_ENABLE(libelf,
1830               AS_HELP_STRING([--disable-libelf], [build without libelf support]))
1831 AS_IF([ test "x$enable_libelf" != "xno"],[
1832 PKG_CHECK_MODULES([LIBELF], [libelf >= 0.8.12], [have_libelf=yes], [have_libelf=maybe])
1833 AS_IF([ test $have_libelf = maybe ], [
1834   glib_save_LIBS=$LIBS
1835   AC_CHECK_LIB([elf], [elf_begin], [:], [have_libelf=no])
1836   AC_CHECK_LIB([elf], [elf_getshdrstrndx], [:], [have_libelf=no])
1837   AC_CHECK_LIB([elf], [elf_getshdrnum], [:], [have_libelf=no])
1838   AC_CHECK_HEADER([libelf.h], [:], [have_libelf=no])
1839   LIBS=$glib_save_LIBS
1840
1841   if test $have_libelf != no; then
1842     LIBELF_LIBS=-lelf
1843     have_libelf=yes
1844   fi
1845 ])
1846 ])
1847
1848 if test x$have_libelf = xyes; then
1849   AC_DEFINE(HAVE_LIBELF, 1, [Define if libelf is available])
1850 fi
1851
1852 dnl ****************************************
1853 dnl *** platform dependent source checks ***
1854 dnl ****************************************
1855
1856 AC_MSG_CHECKING(for platform-dependent source)
1857 case "$host" in
1858   *-*-cygwin*|*-*-mingw*)
1859     PLATFORMDEP=gwin32.lo
1860     ;;
1861   *)
1862     PLATFORMDEP=
1863     ;;
1864 esac
1865 AC_MSG_RESULT($PLATFORMDEP)
1866 AC_SUBST(PLATFORMDEP)
1867
1868 AC_MSG_CHECKING([whether to compile timeloop])
1869 case "$host" in
1870   *-*-cygwin*|*-*-mingw*|*-*-minix)
1871     enable_timeloop=no
1872     ;;
1873   *)
1874     enable_timeloop=yes
1875     ;;
1876 esac
1877 AC_MSG_RESULT($enable_timeloop)
1878 AM_CONDITIONAL(ENABLE_TIMELOOP, test x$enable_timeloop = xyes)
1879
1880 AC_MSG_CHECKING([if building for some Win32 platform])
1881 case "$host" in
1882   *-*-mingw*|*-*-cygwin*)
1883     platform_win32=yes
1884     ;;
1885   *)
1886     platform_win32=no
1887     ;;
1888 esac
1889 AC_MSG_RESULT($platform_win32)
1890 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
1891
1892 dnl ***********************
1893 dnl *** g_thread checks ***
1894 dnl ***********************
1895
1896 AC_ARG_WITH(threads,
1897            [AS_HELP_STRING([--with-threads=@<:@posix/win32@:>@],
1898                            [specify a thread implementation to use])],
1899            [],
1900            [with_threads=yes])
1901
1902 dnl error and warning message
1903 dnl *************************
1904
1905 THREAD_NO_IMPLEMENTATION="No thread implementation found."
1906
1907 FLAG_DOES_NOT_WORK="I can't find the MACRO to enable thread safety on your
1908                 platform (normally it's "_REENTRANT"). I'll not use any flag on
1909                 compilation now, but then your programs might not work.
1910                 Please provide information on how it is done on your system."
1911
1912 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
1913                  "
1914
1915 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
1916                   provide information on your thread implementation."
1917
1918 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
1919                 functions will not be MT-safe during their first call because
1920                 there is no working 'getpwuid_r' on your system."
1921
1922 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
1923                 because there is no 'localtime_r' on your system."
1924
1925 AIX_COMPILE_INFO="AIX's C compiler needs to be called by a different name, when
1926                 linking threaded applications. As GLib cannot do that
1927                 automatically, you will get an linkg error everytime you are
1928                 not using the right compiler. In that case you have to relink
1929                 with the right compiler. Ususally just '_r' is appended
1930                 to the compiler name."
1931
1932 dnl determination of thread implementation
1933 dnl ***************************************
1934
1935 AC_MSG_CHECKING(for thread implementation)
1936
1937 have_threads=no
1938 AS_IF([ test "x$with_threads" = xyes || test "x$with_threads" = xposix], [
1939         # -D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE is for DG/UX
1940         # -U_OSF_SOURCE is for Digital UNIX 4.0d
1941         GTHREAD_COMPILE_IMPL_DEFINES="-D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE -U_OSF_SOURCE"
1942         glib_save_CPPFLAGS="$CPPFLAGS"
1943         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1944         AS_IF([ test "x$have_threads" = xno], [
1945                 AC_TRY_COMPILE([#include <pthread.h>],
1946                         [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1947                         have_threads=posix)
1948         ])
1949         # Tru64Unix requires -pthread to find pthread.h. See #103020
1950         CPPFLAGS="$CPPFLAGS -pthread"
1951         if test "x$have_threads" = xno; then
1952         AC_TRY_COMPILE([#include <pthread.h>],
1953                        [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1954                        have_threads=posix)
1955         fi
1956         CPPFLAGS="$glib_save_CPPFLAGS"
1957 ])
1958 if test "x$with_threads" = xyes || test "x$with_threads" = xwin32; then
1959         case $host in
1960                 *-*-mingw*)
1961                 have_threads=win32
1962                 ;;
1963         esac
1964 fi
1965
1966 if test "x$have_threads" = xno; then
1967         AC_MSG_RESULT(none available)
1968         AC_MSG_ERROR($THREAD_NO_IMPLEMENTATION)
1969 else
1970         AC_MSG_RESULT($have_threads)
1971 fi
1972
1973
1974 dnl determination of G_THREAD_CFLAGS
1975 dnl ********************************
1976
1977 G_THREAD_LIBS=
1978 G_THREAD_LIBS_EXTRA=
1979 G_THREAD_CFLAGS=
1980
1981 dnl
1982 dnl Test program for basic POSIX threads functionality
1983 dnl
1984 m4_define([glib_thread_test],[
1985 #include <pthread.h>
1986 int check_me = 0;
1987 void* func(void* data) {check_me = 42; return &check_me;}
1988 int main()
1989  { pthread_t t;
1990    void *ret;
1991    pthread_create (&t, $1, func, 0);
1992    pthread_join (t, &ret);
1993    return (check_me != 42 || ret != &check_me);
1994 }])
1995
1996 AS_IF([ test x"$have_threads" = xposix], [
1997   # First we test for posix, whether -pthread or -pthreads do the trick as
1998   # both CPPFLAG and LIBS.
1999   # One of them does for most gcc versions and some other platforms/compilers
2000   # too and could be considered as the canonical way to go.
2001   case $host in
2002     *-*-cygwin*|*-*-darwin*)
2003        # skip cygwin and darwin -pthread or -pthreads test
2004        ;;
2005     *-solaris*)
2006       # These compiler/linker flags work with both Sun Studio and gcc
2007       # Sun Studio expands -mt to -D_REENTRANT and -lthread
2008       # gcc expands -pthreads to -D_REENTRANT -D_PTHREADS -lpthread
2009       G_THREAD_CFLAGS="-D_REENTRANT -D_PTHREADS"
2010       G_THREAD_LIBS="-lpthread -lthread"
2011       ;;
2012     *)
2013       for flag in pthread pthreads mt; do
2014         glib_save_CFLAGS="$CFLAGS"
2015         CFLAGS="$CFLAGS -$flag"
2016         AC_TRY_RUN(glib_thread_test(0),
2017                    glib_flag_works=yes,
2018                    glib_flag_works=no,
2019                    [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test(0))],
2020                                    glib_flag_works=yes,
2021                                    glib_flag_works=no)])
2022         CFLAGS="$glib_save_CFLAGS"
2023         if test $glib_flag_works = yes ; then
2024            G_THREAD_CFLAGS=-$flag
2025         G_THREAD_LIBS=-$flag
2026         break;
2027         fi
2028       done
2029        ;;
2030   esac
2031 ])
2032
2033 AS_IF([ test x"$G_THREAD_CFLAGS" = x], [
2034
2035   # The canonical -pthread[s] does not work. Try something different.
2036
2037   case $host in
2038         *-aix*)
2039                 if test x"$GCC" = xyes; then
2040                         # GCC 3.0 and above needs -pthread.
2041                         # Should be coverd by the case above.
2042                         # GCC 2.x and below needs -mthreads
2043                         G_THREAD_CFLAGS="-mthreads"
2044                         G_THREAD_LIBS=$G_THREAD_CFLAGS
2045                 else
2046                         # We are probably using the aix compiler. Normaly a
2047                         # program would have to be compiled with the _r variant
2048                         # of the corresponding compiler, but we as GLib cannot
2049                         # do that: but the good news is that for compiling the
2050                         # only difference is the added -D_THREAD_SAFE compile
2051                         # option. This is according to the "C for AIX User's
2052                         # Guide".
2053                         G_THREAD_CFLAGS="-D_THREAD_SAFE"
2054                 fi
2055                 ;;
2056         *-dg-dgux*)  # DG/UX
2057                 G_THREAD_CFLAGS="-D_REENTRANT -D_POSIX4A_DRAFT10_SOURCE"
2058                 ;;
2059         *-sysv5uw7*) # UnixWare 7
2060                 # We are not using gcc with -pthread. Catched above.
2061                 G_THREAD_CFLAGS="-Kthread"
2062                 G_THREAD_LIBS=$G_THREAD_CFLAGS
2063                 ;;
2064         *-mingw*)
2065                 # No flag needed when using MSVCRT.DLL
2066                 G_THREAD_CFLAGS=""
2067                 ;;
2068         *)
2069                 G_THREAD_CFLAGS="-D_REENTRANT" # good default guess otherwise
2070                 ;;
2071   esac
2072 ])
2073
2074 # if we are not finding the localtime_r function, then we probably are
2075 # not using the proper multithread flag
2076
2077 glib_save_CPPFLAGS="$CPPFLAGS"
2078 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2079
2080 # First we test, whether localtime_r is declared in time.h
2081 # directly. Then we test whether a macro localtime_r exists, in
2082 # which case localtime_r in the test program is replaced and thus
2083 # if we still find localtime_r in the output, it is not defined as
2084 # a macro.
2085
2086 AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>], ,
2087   [AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>
2088                                                            localtime_r(a,b)],
2089                    AC_MSG_WARN($FLAG_DOES_NOT_WORK))])
2090
2091 CPPFLAGS="$glib_save_CPPFLAGS"
2092
2093 AC_MSG_CHECKING(thread related cflags)
2094 AC_MSG_RESULT($G_THREAD_CFLAGS)
2095 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2096
2097 dnl determination of G_THREAD_LIBS
2098 dnl ******************************
2099
2100 AS_IF([test x$have_threads = xposix], [
2101           glib_save_CPPFLAGS="$CPPFLAGS"
2102           CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2103           AS_IF([ test x"$G_THREAD_LIBS" = x ], [
2104             case $host in
2105               *-aix*)
2106                 # We are not using gcc (would have set G_THREAD_LIBS) and thus
2107                 # probably using the aix compiler.
2108                 AC_MSG_WARN($AIX_COMPILE_INFO)
2109                 ;;
2110               *)
2111                 G_THREAD_LIBS=error
2112                 glib_save_LIBS="$LIBS"
2113                 for thread_lib in "" pthread pthread32 pthreads thread; do
2114                         if test x"$thread_lib" = x; then
2115                                 add_thread_lib=""
2116                                 IN=""
2117                         else
2118                                 add_thread_lib="-l$thread_lib"
2119                                 IN=" in -l$thread_lib"
2120                         fi
2121                         if test x"$have_threads" = xposix; then
2122                                 defattr=0
2123                         else
2124                                 defattr=pthread_attr_default
2125                         fi
2126
2127                         LIBS="$add_thread_lib $glib_save_LIBS"
2128
2129                         AC_MSG_CHECKING(for pthread_create/pthread_join$IN)
2130                         AC_TRY_RUN(glib_thread_test($defattr),
2131                                    glib_result=yes,
2132                                    glib_result=no,
2133                                    [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test($defattr))],
2134                                                    glib_result=yes,
2135                                                    glib_result=no)])
2136                         AC_MSG_RESULT($glib_result)
2137
2138                         if test "$glib_result" = "yes" ; then
2139                           G_THREAD_LIBS="$add_thread_lib"
2140                           break
2141                         fi
2142                 done
2143                 if test "x$G_THREAD_LIBS" = xerror; then
2144                   AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2145                 fi
2146                 LIBS="$glib_save_LIBS"
2147                 ;;
2148             esac
2149           ])
2150
2151           g_threads_impl="POSIX"
2152           AC_SUBST(GTHREAD_COMPILE_IMPL_DEFINES)
2153           CPPFLAGS="$glib_save_CPPFLAGS"
2154 ], [test x$have_threads = xwin32], [
2155            g_threads_impl="WIN32"
2156 ], [
2157            g_threads_impl="NONE"
2158            G_THREAD_LIBS=error
2159 ])
2160
2161 if test "x$G_THREAD_LIBS" = xerror; then
2162         AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2163 fi
2164
2165 case $host in
2166   *-*-beos*)
2167     G_THREAD_LIBS="-lbe -lroot -lglib-2.0 "
2168     G_THREAD_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
2169     ;;
2170   *)
2171     ;;
2172 esac
2173
2174 AC_MSG_CHECKING(thread related libraries)
2175 AC_MSG_RESULT($G_THREAD_LIBS)
2176
2177 dnl check for mt safe function variants and some posix functions
2178 dnl ************************************************************
2179
2180 glib_save_LIBS="$LIBS"
2181 # we are not doing the following for now, as this might require glib
2182 # to always be linked with the thread libs on some platforms.
2183 # LIBS="$LIBS $G_THREAD_LIBS"
2184 AC_CHECK_FUNCS(localtime_r gmtime_r)
2185 AS_IF([ test "$ac_cv_header_pwd_h" = "yes"], [
2186         AC_CACHE_CHECK([for posix getpwuid_r],
2187                 ac_cv_func_posix_getpwuid_r,
2188                 [AC_TRY_RUN([
2189 #include <errno.h>
2190 #include <pwd.h>
2191 int main () {
2192     char buffer[10000];
2193     struct passwd pwd, *pwptr = &pwd;
2194     int error;
2195     errno = 0;
2196     error = getpwuid_r (0, &pwd, buffer,
2197                         sizeof (buffer), &pwptr);
2198    return (error < 0 && errno == ENOSYS)
2199            || error == ENOSYS;
2200 }                               ],
2201                         [ac_cv_func_posix_getpwuid_r=yes],
2202                         [ac_cv_func_posix_getpwuid_r=no])])
2203         GLIB_ASSERT_SET(ac_cv_func_posix_getpwuid_r)
2204         if test "$ac_cv_func_posix_getpwuid_r" = yes; then
2205                 AC_DEFINE(HAVE_POSIX_GETPWUID_R,1,
2206                         [Have POSIX function getpwuid_r])
2207         else
2208                 AC_CACHE_CHECK([for nonposix getpwuid_r],
2209                         ac_cv_func_nonposix_getpwuid_r,
2210                         [AC_TRY_LINK([#include <pwd.h>],
2211                                 [char buffer[10000];
2212                                 struct passwd pwd;
2213                                 getpwuid_r (0, &pwd, buffer,
2214                                                 sizeof (buffer));],
2215                                 [ac_cv_func_nonposix_getpwuid_r=yes],
2216                                 [ac_cv_func_nonposix_getpwuid_r=no])])
2217                 GLIB_ASSERT_SET(ac_cv_func_nonposix_getpwuid_r)
2218                 if test "$ac_cv_func_nonposix_getpwuid_r" = yes; then
2219                         AC_DEFINE(HAVE_NONPOSIX_GETPWUID_R,1,
2220                                 [Have non-POSIX function getpwuid_r])
2221                 fi
2222         fi
2223 ])
2224 AS_IF([ test "$ac_cv_header_grp_h" = "yes"], [
2225         AC_CACHE_CHECK([for posix getgrgid_r],
2226                 ac_cv_func_posix_getgrgid_r,
2227                 [AC_TRY_RUN([
2228 #include <errno.h>
2229 #include <grp.h>
2230 int main () {
2231     char buffer[10000];
2232     struct group grp, *grpptr = &grp;
2233     int error;
2234     errno = 0;
2235     error = getgrgid_r (0, &grp, buffer,
2236                         sizeof (buffer), &grpptr);
2237    return (error < 0 && errno == ENOSYS)
2238            || error == ENOSYS;
2239 }                              ],
2240                        [ac_cv_func_posix_getgrgid_r=yes],
2241                        [ac_cv_func_posix_getgrgid_r=no])])
2242         GLIB_ASSERT_SET(ac_cv_func_posix_getgrgid_r)
2243         AS_IF([ test "$ac_cv_func_posix_getgrgid_r" = yes ], [
2244                 AC_DEFINE(HAVE_POSIX_GETGRGID_R,1,
2245                         [Have POSIX function getgrgid_r])
2246         ], [
2247                 AC_CACHE_CHECK([for nonposix getgrgid_r],
2248                         ac_cv_func_nonposix_getgrgid_r,
2249                         [AC_TRY_LINK([#include <grp.h>],
2250                                 [char buffer[10000];
2251                                 struct group grp;
2252                                 getgrgid_r (0, &grp, buffer,
2253                                 sizeof (buffer));],
2254                         [ac_cv_func_nonposix_getgrgid_r=yes],
2255                         [ac_cv_func_nonposix_getgrgid_r=no])])
2256                 GLIB_ASSERT_SET(ac_cv_func_nonposix_getgrgid_r)
2257                 if test "$ac_cv_func_nonposix_getgrgid_r" = yes; then
2258                         AC_DEFINE(HAVE_NONPOSIX_GETGRGID_R,1,
2259                                 [Have non-POSIX function getgrgid_r])
2260                 fi
2261         ])
2262 ])
2263 LIBS="$G_THREAD_LIBS $LIBS"
2264 AS_IF([ test x"$have_threads" = xposix], [
2265         glib_save_CPPFLAGS="$CPPFLAGS"
2266         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2267         # This is not AC_CHECK_FUNC to also work with function
2268         # name mangling in header files.
2269         AC_MSG_CHECKING(for pthread_attr_setstacksize)
2270         AC_LINK_IFELSE(
2271             [AC_LANG_PROGRAM(
2272                 [#include <pthread.h>],
2273                 [pthread_attr_t t; pthread_attr_setstacksize(&t,0)])],
2274             [AC_MSG_RESULT(yes)
2275              AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE,1,
2276                 [Have function pthread_attr_setstacksize])],
2277             [AC_MSG_RESULT(no)])
2278         AC_MSG_CHECKING(for pthread_condattr_setclock)
2279         AC_LINK_IFELSE(
2280             [AC_LANG_PROGRAM(
2281                 [#include <pthread.h>],
2282                 [pthread_condattr_t a; pthread_condattr_setclock(&a,0)])],
2283             [AC_MSG_RESULT(yes)
2284              AC_DEFINE(HAVE_PTHREAD_CONDATTR_SETCLOCK,1,
2285                 [Have function pthread_condattr_setclock])],
2286             [AC_MSG_RESULT(no)])
2287         CPPFLAGS="$glib_save_CPPFLAGS"
2288 ])
2289
2290 LIBS="$glib_save_LIBS"
2291
2292 # now spit out all the warnings.
2293 if test "$ac_cv_func_posix_getpwuid_r" != "yes" &&
2294    test "$ac_cv_func_nonposix_getpwuid_r" != "yes"; then
2295         AC_MSG_WARN($FUNC_NO_GETPWUID_R)
2296 fi
2297 if test "$ac_cv_func_localtime_r" != "yes"; then
2298         AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
2299 fi
2300
2301 #
2302 # Hack to deal with:
2303 #
2304 #  a) GCC < 3.3 for Linux doesn't include -lpthread when
2305 #     building shared libraries with linux.
2306 #  b) FreeBSD doesn't do this either.
2307 #
2308 case $host in
2309   *-*-freebsd*|*-*-linux*)
2310     G_THREAD_LIBS_FOR_GTHREAD="`echo $G_THREAD_LIBS | sed s/-pthread/-lpthread/`"
2311     ;;
2312   *-*-openbsd*)
2313     LDFLAGS="$LDFLAGS -pthread"
2314     ;;
2315   *)
2316     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
2317     ;;
2318 esac
2319
2320 AC_SUBST(G_THREAD_CFLAGS)
2321 AC_SUBST(G_THREAD_LIBS)
2322 AC_SUBST(G_THREAD_LIBS_FOR_GTHREAD)
2323 AC_SUBST(G_THREAD_LIBS_EXTRA)
2324
2325 AC_CHECK_FUNCS(clock_gettime, [], [
2326   AC_CHECK_LIB(rt, clock_gettime, [
2327     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
2328     G_THREAD_LIBS="$G_THREAD_LIBS -lrt"
2329     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS_FOR_GTHREAD -lrt"
2330   ])
2331 ])
2332
2333
2334 dnl ************************
2335 dnl *** g_atomic_* tests ***
2336 dnl ************************
2337
2338 dnl We need to decide at configure time if GLib will use real atomic
2339 dnl operations ("lock free") or emulated ones with a mutex.  This is
2340 dnl because we must put this information in glibconfig.h so we know if
2341 dnl it is safe or not to inline using compiler intrinsics directly from
2342 dnl the header.
2343 dnl
2344 dnl We also publish the information via G_ATOMIC_LOCK_FREE in case the
2345 dnl user is interested in knowing if they can use the atomic ops across
2346 dnl processes.
2347 dnl
2348 dnl We can currently support the atomic ops natively when building GLib
2349 dnl with recent versions of GCC or MSVC.  MSVC doesn't run ./configure,
2350 dnl so we skip that case here and define G_ATOMIC_LOCK_FREE exactly when
2351 dnl we are using GCC.
2352 dnl
2353 dnl Note that the atomic ops are only available with GCC on x86 when
2354 dnl using -march=i486 or higher.  If we detect that the atomic ops are
2355 dnl not available but would be available given the right flags, we want
2356 dnl to abort and advise the user to fix their CFLAGS.  It's better to do
2357 dnl that then to silently fall back on emulated atomic ops just because
2358 dnl the user had the wrong build environment.
2359
2360 dnl We may add other compilers here in the future...
2361
2362 AC_CACHE_CHECK([for lock-free atomic intrinsics], glib_cv_g_atomic_lock_free, [
2363   AC_TRY_COMPILE([],
2364                  [__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4;],
2365                  [glib_cv_g_atomic_lock_free=yes],
2366                  [glib_cv_g_atomic_lock_free=no])])
2367
2368 if test "$glib_cv_g_atomic_lock_free" = "no"; then
2369   SAVE_CFLAGS="${CFLAGS}"
2370   CFLAGS="-march=i486"
2371   AC_TRY_COMPILE([],
2372                  [__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4;],
2373                  [AC_MSG_ERROR([GLib must be build with -march=i486 or later.])],
2374                  [])
2375   CFLAGS="${SAVE_CFLAGS}"
2376 fi
2377
2378 dnl We need a more robust approach here...
2379 case $host_cpu in
2380   i?86|x86_64|s390|s390x|arm*|crisv32*|etrax*)
2381     glib_memory_barrier_needed=no
2382     ;;
2383   sparc*|alpha*|powerpc*|ia64)
2384     glib_memory_barrier_needed=yes
2385     ;;
2386   *)
2387     glib_memory_barrier_needed=yes
2388     ;;
2389 esac
2390
2391 dnl ************************
2392 dnl ** Check for futex(2) **
2393 dnl ************************
2394 AC_CACHE_CHECK(for futex(2) system call,
2395     glib_cv_futex,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2396 #include <linux/futex.h>
2397 #include <sys/syscall.h>
2398 #include <unistd.h>
2399 ],[
2400 int
2401 main (void)
2402 {
2403   /* it is not like this actually runs or anything... */
2404   syscall (__NR_futex, NULL, FUTEX_WAKE, FUTEX_WAIT);
2405   return 0;
2406 }
2407 ])],glib_cv_futex=yes,glib_cv_futex=no))
2408 if test x"$glib_cv_futex" = xyes; then
2409   AC_DEFINE(HAVE_FUTEX, 1, [we have the futex(2) system call])
2410 fi
2411
2412 AC_CACHE_CHECK(for eventfd(2) system call,
2413     glib_cv_eventfd,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2414 #include <sys/eventfd.h>
2415 #include <unistd.h>
2416 ],[
2417 int
2418 main (void)
2419 {
2420   eventfd (0, EFD_CLOEXEC);
2421   return 0;
2422 }
2423 ])],glib_cv_eventfd=yes,glib_cv_eventfd=no))
2424 if test x"$glib_cv_eventfd" = x"yes"; then
2425   AC_DEFINE(HAVE_EVENTFD, 1, [we have the eventfd(2) system call])
2426 fi
2427 AM_CONDITIONAL(HAVE_EVENTFD, [test "$glib_cv_eventfd" = "yes"])
2428
2429 dnl ****************************************
2430 dnl *** GLib POLL* compatibility defines ***
2431 dnl ****************************************
2432
2433 glib_poll_includes=["
2434 #include <sys/types.h>
2435 #include <sys/poll.h>
2436 "]
2437
2438 AS_IF([ test $ac_cv_header_sys_types_h = yes &&
2439    test $ac_cv_header_sys_poll_h = yes ], [
2440   glib_failed=false
2441   GLIB_CHECK_VALUE(POLLIN, $glib_poll_includes, glib_failed=true)
2442   GLIB_CHECK_VALUE(POLLOUT, $glib_poll_includes, glib_failed=true)
2443   GLIB_CHECK_VALUE(POLLPRI, $glib_poll_includes, glib_failed=true)
2444   GLIB_CHECK_VALUE(POLLERR, $glib_poll_includes, glib_failed=true)
2445   GLIB_CHECK_VALUE(POLLHUP, $glib_poll_includes, glib_failed=true)
2446   GLIB_CHECK_VALUE(POLLNVAL, $glib_poll_includes, glib_failed=true)
2447   if $glib_failed ; then
2448     AC_MSG_ERROR([Could not determine values for POLL* constants])
2449   fi
2450 ], [
2451   glib_cv_value_POLLIN=1
2452   glib_cv_value_POLLOUT=4
2453   glib_cv_value_POLLPRI=2
2454   glib_cv_value_POLLERR=8
2455   glib_cv_value_POLLHUP=16
2456   glib_cv_value_POLLNVAL=32
2457 ])
2458
2459 AC_MSG_CHECKING([for broken poll])
2460 AC_RUN_IFELSE([AC_LANG_SOURCE([[
2461         #include <stdlib.h>
2462         #include <fcntl.h>
2463         #include <poll.h>
2464         #ifdef HAVE_SYS_POLL_H
2465         #include <sys/poll.h>
2466         #endif
2467         int main(void) {
2468           struct pollfd fds[1];
2469           int fd;
2470           fd = open("/dev/null", 1);
2471           fds[0].fd = fd;
2472           fds[0].events = POLLIN;
2473           fds[0].revents = 0;
2474           if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
2475                 exit(1);  /* Does not work for devices -- fail */
2476           }
2477           exit(0);
2478         }]])],
2479   [broken_poll=no],
2480   [broken_poll=yes
2481    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
2482   [broken_poll="no (cross compiling)"])
2483 AC_MSG_RESULT($broken_poll)
2484
2485 dnl *********************
2486 dnl *** GRegex checks ***
2487 dnl *********************
2488
2489 PCRE_REQUIRED_VERSION=8.13
2490
2491 # Check if we should use the internal or the system-supplied pcre
2492 AC_ARG_WITH(pcre,
2493             [AS_HELP_STRING([--with-pcre=@<:@internal/system@:>@],
2494                             [whether to use system PCRE [default=internal]])])
2495
2496 AM_CONDITIONAL(USE_SYSTEM_PCRE, [test "x$with_pcre" = xsystem])
2497
2498 AS_IF([ test "x$with_pcre" = xsystem], [
2499   PKG_CHECK_MODULES(PCRE,
2500                     libpcre >= $PCRE_REQUIRED_VERSION)
2501   AC_CACHE_CHECK([for Unicode support in PCRE],glib_cv_pcre_has_unicode,[
2502                   glib_save_CFLAGS="$CFLAGS"
2503                   glib_save_LIBS="$LIBS"
2504                   CFLAGS="$CFLAGS $PCRE_CFLAGS" LIBS="$PCRE_LIBS"
2505                   AC_TRY_RUN([#include <pcre.h>
2506                               int main () {
2507                                 int support;
2508                                 pcre_config (PCRE_CONFIG_UTF8, &support);
2509                                 if (!support)
2510                                   return 1;
2511                                 pcre_config (PCRE_CONFIG_UNICODE_PROPERTIES, &support);
2512                                 if (!support)
2513                                   return 1;
2514                                 return 0;
2515                               }],
2516                   glib_cv_pcre_has_unicode=yes,
2517                   glib_cv_pcre_has_unicode=no,
2518                   glib_cv_pcre_has_unicode=yes)
2519                   CFLAGS="$glib_save_CFLAGS"
2520                   LIBS="$glib_save_LIBS"
2521       ])
2522   if test "$glib_cv_pcre_has_unicode" = "no"; then
2523     AC_MSG_ERROR([*** The system-supplied PCRE does not support Unicode properties or UTF-8.])
2524   fi
2525   AC_SUBST(PCRE_CFLAGS)
2526   AC_SUBST(PCRE_LIBS)
2527   AC_DEFINE(USE_SYSTEM_PCRE, [], [using the system-supplied PCRE library])
2528   PCRE_REQUIRES=libpcre
2529   AC_SUBST(PCRE_REQUIRES)
2530 ], [
2531   # If using gcc 4 pass -Wno-pointer-sign when compiling the internal PCRE
2532   AS_IF([ test x"$GCC" = xyes], [
2533     AC_MSG_CHECKING([whether compiler understands -Wno-pointer-sign])
2534     save_CFLAGS="$CFLAGS"
2535     CFLAGS="$CFLAGS -Wno-pointer-sign"
2536     AC_TRY_COMPILE([],[],[PCRE_WARN_CFLAGS="$PCRE_WARN_CFLAGS -Wno-pointer-sign"
2537                           AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
2538     CFLAGS="$save_CFLAGS"
2539   ])
2540 ])
2541 AC_SUBST(PCRE_WARN_CFLAGS)
2542
2543 dnl **********************
2544 dnl *** Win32 API libs ***
2545 dnl **********************
2546
2547 case $host in
2548   *-*-cygwin*)
2549         G_LIBS_EXTRA="-luser32 -lkernel32"
2550     ;;
2551   *-*-mingw*)
2552         G_LIBS_EXTRA="-lws2_32 -lole32 -lwinmm -lshlwapi"
2553     ;;
2554   *)
2555         G_LIBS_EXTRA=""
2556     ;;
2557 esac
2558 AC_SUBST(G_LIBS_EXTRA)
2559
2560 dnl If the system doesn't define EILSEQ, we should define EILSEQ ourselves
2561 dnl since we need it for g_iconv()
2562
2563 AC_MSG_CHECKING([for EILSEQ])
2564 AC_TRY_COMPILE([
2565 #include <errno.h>
2566 ],
2567 [
2568 int error = EILSEQ;
2569 ], have_eilseq=yes, have_eilseq=no);
2570 AC_MSG_RESULT($have_eilseq)
2571
2572 dnl ******************************************************************
2573 dnl *** If we are cross-compiling, look for glib-genmarshal and    ***
2574 dnl *** glib-compile-schemas in PATH                               ***
2575 dnl ******************************************************************
2576
2577 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
2578
2579 AS_IF([ test $cross_compiling = yes && test x$enable_modular_tests = xyes], [
2580   AC_PATH_PROG(GLIB_GENMARSHAL, glib-genmarshal, no)
2581   if test x$GLIB_GENMARSHAL = xno; then
2582     AC_MSG_ERROR(Could not find a glib-genmarshal in your PATH)
2583   fi
2584
2585   AC_PATH_PROG(GLIB_COMPILE_SCHEMAS, glib-compile-schemas, no)
2586   if test x$GLIB_COMPILE_SCHEMAS = xno; then
2587     AC_MSG_ERROR(Could not find a glib-compile-schemas in your PATH)
2588   fi
2589
2590   AC_PATH_PROG(GLIB_COMPILE_RESOURCES, glib-compile-resources, no)
2591   if test x$GLIB_COMPILE_RESOURCES = xno; then
2592     AC_MSG_ERROR(Could not find a glib-compile-resources in your PATH)
2593   fi
2594 ])
2595
2596 dnl **************************
2597 dnl *** Checks for gtk-doc ***
2598 dnl **************************
2599 # gtkdocize greps for ^GTK_DOC_CHECK and parses it, so you need to have
2600 # it on it's own line.
2601 m4_ifdef([GTK_DOC_CHECK], [
2602 GTK_DOC_CHECK([1.15], [--flavour no-tmpl])
2603 ],[
2604 AM_CONDITIONAL([ENABLE_GTK_DOC],[false])
2605 ])
2606
2607 AC_ARG_ENABLE(man,
2608               [AS_HELP_STRING([--enable-man],
2609                               [generate man pages [default=auto]])],,
2610               enable_man=maybe)
2611
2612 AS_IF([test "$enable_man" != no], [
2613   AC_PATH_PROG([XSLTPROC], [xsltproc])
2614   AS_IF([test -z "$XSLTPROC"], [
2615     AS_IF([test "$enable_man" = yes], [
2616       AC_MSG_ERROR([xsltproc is required for --enable-man])
2617     ])
2618     enable_man=no
2619   ])
2620 ])
2621
2622 AS_IF([ test "$enable_man" != no ], [
2623   dnl check for DocBook DTD in the local catalog
2624   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
2625      [DocBook XML DTD V4.1.2], [have_docbook_dtd=yes], [have_docbook_dtd=no])
2626   AS_IF([test "$have_docbook_dtd" != yes], [
2627     AS_IF([test "$enable_man" = yes ], [
2628       AC_MSG_ERROR([DocBook DTD is required for --enable-man])
2629     ])
2630     enable_man=no
2631   ])
2632 ])
2633
2634 AS_IF([test "$enable_man" != no], [
2635   dnl check for DocBook XSL stylesheets in the local catalog
2636   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
2637      [DocBook XSL Stylesheets], [have_docbook_style=yes],[have_docbook_style=no])
2638   AS_IF([ test "$have_docbook_dtd" != yes ], [
2639     AS_IF([ test "$enable_man" = yes ], [
2640       AC_MSG_ERROR([DocBook XSL Stylesheets are required for --enable-man])
2641     ])
2642     enable_man=no
2643   ])
2644 ])
2645
2646 AM_CONDITIONAL(ENABLE_MAN, test "$enable_man" != no)
2647
2648 AC_MSG_CHECKING([whether to generate man pages])
2649 AS_IF([ test "$enable_man" != no ], [
2650   AC_MSG_RESULT([yes])
2651 ], [
2652   AC_MSG_RESULT([no])
2653 ])
2654
2655 dnl
2656 dnl Tracing
2657 dnl
2658
2659 AC_ARG_ENABLE([dtrace],
2660              [AS_HELP_STRING([--enable-dtrace],
2661                               [include tracing support for dtrace])])
2662 have_dtrace=no
2663 AC_MSG_CHECKING([whether to include dtrace tracing support])
2664 AS_IF([ test "x$enable_dtrace" != xno], [
2665   if test x$glib_have_carbon = xyes; then
2666     AC_MSG_RESULT([no (not yet compatible with MacOS dtrace)])
2667   else
2668     AC_MSG_RESULT([yes])
2669     AC_CHECK_PROGS(DTRACE, dtrace)
2670     if test -z "$DTRACE"; then
2671       if test "x$enable_dtrace" = xyes; then
2672         AC_MSG_ERROR([dtrace not found])
2673       fi
2674     else
2675       AC_CHECK_HEADER([sys/sdt.h],have_dtrace=yes,
2676                       [if test "x$enable_dtrace" = xyes; then
2677                         AC_MSG_ERROR([dtrace support needs sys/sdt.h header])
2678                        fi])
2679     fi
2680   fi
2681 ], [
2682   AC_MSG_RESULT([no])
2683 ])
2684 if test "x$have_dtrace" = xyes; then
2685   AC_DEFINE([HAVE_DTRACE], [1], [Define to 1 if using dtrace probes.])
2686 fi
2687 AM_CONDITIONAL([ENABLE_DTRACE], [test x$have_dtrace = xyes ])
2688
2689 AC_MSG_CHECKING([whether to include systemtap tracing support])
2690 AC_ARG_ENABLE([systemtap],
2691              [AS_HELP_STRING([--enable-systemtap],
2692                               [include tracing support for systemtap])])
2693 have_systemtap=no
2694 if test "x$enable_systemtap" != xno -a "x$have_dtrace" = xyes; then
2695   have_systemtap=yes
2696 fi
2697 AC_MSG_RESULT(${have_systemtap})
2698
2699 AM_CONDITIONAL([ENABLE_SYSTEMTAP], [test x$have_systemtap = xyes])
2700
2701 AC_ARG_WITH([tapset-install-dir],
2702             AS_HELP_STRING([--with-tapset-install-dir=DIR],
2703                             [path where systemtap tapsets are installed [DATADIR/systemtap/tapset]]),
2704             [if test "x${withval}" = x; then
2705                ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"
2706              else
2707                ABS_TAPSET_DIR="${withval}"
2708               fi],
2709             [ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"])
2710 AC_SUBST(ABS_TAPSET_DIR)
2711
2712 dnl ************************************
2713 dnl *** Enable lcov coverage reports ***
2714 dnl ************************************
2715
2716 AC_ARG_ENABLE(gcov,
2717   AS_HELP_STRING([--enable-gcov],
2718                  [enable coverage testing with gcov]),
2719   [use_gcov=$enableval], [use_gcov=no])
2720
2721 AS_IF([ test "x$use_gcov" = "xyes"], [
2722   dnl we need gcc:
2723   if test "$GCC" != "yes"; then
2724     AC_MSG_ERROR([GCC is required for --enable-gcov])
2725   fi
2726
2727   dnl Check if ccache is being used
2728   AC_CHECK_PROG(SHTOOL, shtool, shtool)
2729   case `$SHTOOL path $CC` in
2730     *ccache*[)] gcc_ccache=yes;;
2731     *[)] gcc_ccache=no;;
2732   esac
2733
2734   if test "$gcc_ccache" = "yes" && (test -z "$CCACHE_DISABLE" || test "$CCACHE_DISABLE" != "1"); then
2735     AC_MSG_ERROR([ccache must be disabled when --enable-gcov option is used. You can disable ccache by setting environment variable CCACHE_DISABLE=1.])
2736   fi
2737
2738   ltp_version_list="1.6 1.7 1.8 1.9"
2739   AC_CHECK_PROG(LTP, lcov, lcov)
2740   AC_CHECK_PROG(LTP_GENHTML, genhtml, genhtml)
2741
2742   AS_IF([ test "$LTP" ], [
2743     AC_CACHE_CHECK([for ltp version], glib_cv_ltp_version, [
2744       glib_cv_ltp_version=invalid
2745       ltp_version=`$LTP -v 2>/dev/null | $SED -e 's/^.* //'`
2746       for ltp_check_version in $ltp_version_list; do
2747         if test "$ltp_version" = "$ltp_check_version"; then
2748           glib_cv_ltp_version="$ltp_check_version (ok)"
2749         fi
2750       done
2751     ])
2752   ], [
2753     ltp_msg="To enable code coverage reporting you must have one of the following LTP versions installed: $ltp_version_list"
2754     AC_MSG_ERROR([$ltp_msg])
2755   ])
2756
2757   case $glib_cv_ltp_version in
2758     ""|invalid[)]
2759       ltp_msg="You must have one of the following versions of LTP: $ltp_version_list (found: $ltp_version)."
2760       AC_MSG_ERROR([$ltp_msg])
2761       LTP="exit 0;"
2762       ;;
2763   esac
2764
2765   if test -z "$LTP_GENHTML"; then
2766     AC_MSG_ERROR([Could not find genhtml from the LTP package])
2767   fi
2768
2769   dnl Remove all optimization flags from CFLAGS
2770   changequote({,})
2771   CFLAGS=`echo "$CFLAGS" | $SED -e 's/-O[0-9]*//g'`
2772   changequote([,])
2773
2774   dnl Add the special gcc flags
2775   CFLAGS="$CFLAGS -O0 -fprofile-arcs -ftest-coverage"
2776   LDFLAGS="$LDFLAGS -lgcov"
2777 ])
2778
2779 dnl ******************************
2780 dnl *** output the whole stuff ***
2781 dnl ******************************
2782
2783 dnl this section will only be run if config.status is invoked with no
2784 dnl arguments, or with "glib/glibconfig.h" as an argument.
2785 AC_CONFIG_COMMANDS([glib/glibconfig.h],
2786 [
2787         outfile=glib/glibconfig.h-tmp
2788         cat > $outfile <<\_______EOF
2789 /* glibconfig.h
2790  *
2791  * This is a generated file.  Please modify 'configure.ac'
2792  */
2793
2794 #ifndef __GLIBCONFIG_H__
2795 #define __GLIBCONFIG_H__
2796
2797 #include <glib/gmacros.h>
2798
2799 _______EOF
2800
2801         if test x$glib_limits_h = xyes; then
2802           echo '#include <limits.h>' >> $outfile
2803         fi
2804         if test x$glib_float_h = xyes; then
2805           echo '#include <float.h>' >> $outfile
2806         fi
2807         if test x$glib_values_h = xyes; then
2808           echo '#include <values.h>' >> $outfile
2809         fi
2810         if test "$glib_header_alloca_h" = "yes"; then
2811           echo '#define GLIB_HAVE_ALLOCA_H' >> $outfile
2812         fi
2813         if test x$glib_sys_poll_h = xyes; then
2814           echo '#define GLIB_HAVE_SYS_POLL_H' >> $outfile
2815         fi
2816         if test x$glib_included_printf != xyes; then
2817           echo "
2818 /* Specifies that GLib's g_print*() functions wrap the
2819  * system printf functions.  This is useful to know, for example,
2820  * when using glibc's register_printf_function().
2821  */" >> $outfile
2822           echo '#define GLIB_USING_SYSTEM_PRINTF' >> $outfile
2823         fi
2824
2825         cat >> $outfile <<_______EOF
2826
2827 G_BEGIN_DECLS
2828
2829 #define G_MINFLOAT      $glib_mf
2830 #define G_MAXFLOAT      $glib_Mf
2831 #define G_MINDOUBLE     $glib_md
2832 #define G_MAXDOUBLE     $glib_Md
2833 #define G_MINSHORT      $glib_ms
2834 #define G_MAXSHORT      $glib_Ms
2835 #define G_MAXUSHORT     $glib_Mus
2836 #define G_MININT        $glib_mi
2837 #define G_MAXINT        $glib_Mi
2838 #define G_MAXUINT       $glib_Mui
2839 #define G_MINLONG       $glib_ml
2840 #define G_MAXLONG       $glib_Ml
2841 #define G_MAXULONG      $glib_Mul
2842
2843 _______EOF
2844
2845
2846         ### this should always be true in a modern C/C++ compiler
2847         cat >>$outfile <<_______EOF
2848 typedef signed char gint8;
2849 typedef unsigned char guint8;
2850 _______EOF
2851
2852
2853         if test -n "$gint16"; then
2854           cat >>$outfile <<_______EOF
2855 typedef signed $gint16 gint16;
2856 typedef unsigned $gint16 guint16;
2857 #define G_GINT16_MODIFIER $gint16_modifier
2858 #define G_GINT16_FORMAT $gint16_format
2859 #define G_GUINT16_FORMAT $guint16_format
2860 _______EOF
2861         fi
2862
2863
2864         if test -n "$gint32"; then
2865           cat >>$outfile <<_______EOF
2866 typedef signed $gint32 gint32;
2867 typedef unsigned $gint32 guint32;
2868 #define G_GINT32_MODIFIER $gint32_modifier
2869 #define G_GINT32_FORMAT $gint32_format
2870 #define G_GUINT32_FORMAT $guint32_format
2871 _______EOF
2872         fi
2873
2874         cat >>$outfile <<_______EOF
2875 #define G_HAVE_GINT64 1          /* deprecated, always true */
2876
2877 ${glib_extension}typedef signed $gint64 gint64;
2878 ${glib_extension}typedef unsigned $gint64 guint64;
2879
2880 #define G_GINT64_CONSTANT(val)  $gint64_constant
2881 #define G_GUINT64_CONSTANT(val) $guint64_constant
2882 _______EOF
2883
2884         if test x$gint64_format != x ; then
2885           cat >>$outfile <<_______EOF
2886 #define G_GINT64_MODIFIER $gint64_modifier
2887 #define G_GINT64_FORMAT $gint64_format
2888 #define G_GUINT64_FORMAT $guint64_format
2889 _______EOF
2890         else
2891           cat >>$outfile <<_______EOF
2892 #undef G_GINT64_MODIFIER
2893 #undef G_GINT64_FORMAT
2894 #undef G_GUINT64_FORMAT
2895 _______EOF
2896         fi
2897
2898         cat >>$outfile <<_______EOF
2899
2900 #define GLIB_SIZEOF_VOID_P $glib_void_p
2901 #define GLIB_SIZEOF_LONG   $glib_long
2902 #define GLIB_SIZEOF_SIZE_T $glib_size_t
2903
2904 _______EOF
2905
2906         cat >>$outfile <<_______EOF
2907 typedef signed $glib_size_type_define gssize;
2908 typedef unsigned $glib_size_type_define gsize;
2909 #define G_GSIZE_MODIFIER $gsize_modifier
2910 #define G_GSSIZE_FORMAT $gssize_format
2911 #define G_GSIZE_FORMAT $gsize_format
2912
2913 #define G_MAXSIZE       G_MAXU$glib_msize_type
2914 #define G_MINSSIZE      G_MIN$glib_msize_type
2915 #define G_MAXSSIZE      G_MAX$glib_msize_type
2916
2917 typedef gint64 goffset;
2918 #define G_MINOFFSET     G_MININT64
2919 #define G_MAXOFFSET     G_MAXINT64
2920
2921 #define G_GOFFSET_MODIFIER      G_GINT64_MODIFIER
2922 #define G_GOFFSET_FORMAT        G_GINT64_FORMAT
2923 #define G_GOFFSET_CONSTANT(val) G_GINT64_CONSTANT(val)
2924
2925 _______EOF
2926
2927         if test -z "$glib_unknown_void_p"; then
2928           cat >>$outfile <<_______EOF
2929
2930 #define GPOINTER_TO_INT(p)      ((gint)  ${glib_gpi_cast} (p))
2931 #define GPOINTER_TO_UINT(p)     ((guint) ${glib_gpui_cast} (p))
2932
2933 #define GINT_TO_POINTER(i)      ((gpointer) ${glib_gpi_cast} (i))
2934 #define GUINT_TO_POINTER(u)     ((gpointer) ${glib_gpui_cast} (u))
2935
2936 typedef signed $glib_intptr_type_define gintptr;
2937 typedef unsigned $glib_intptr_type_define guintptr;
2938
2939 #define G_GINTPTR_MODIFIER      $gintptr_modifier
2940 #define G_GINTPTR_FORMAT        $gintptr_format
2941 #define G_GUINTPTR_FORMAT       $guintptr_format
2942 _______EOF
2943         else
2944           echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
2945         fi
2946
2947
2948
2949         cat >>$outfile <<_______EOF
2950 $glib_atexit
2951 $glib_memmove
2952 $glib_defines
2953 $glib_os
2954 $glib_static_compilation
2955
2956 $glib_vacopy
2957
2958 #ifdef  __cplusplus
2959 #define G_HAVE_INLINE   1
2960 #else   /* !__cplusplus */
2961 $glib_inline
2962 #endif  /* !__cplusplus */
2963
2964 #ifdef  __cplusplus
2965 #define G_CAN_INLINE    1
2966 _______EOF
2967
2968         if test x$g_can_inline = xyes ; then
2969                 cat >>$outfile <<_______EOF
2970 #else   /* !__cplusplus */
2971 #define G_CAN_INLINE    1
2972 _______EOF
2973         fi
2974
2975         cat >>$outfile <<_______EOF
2976 #endif
2977
2978 _______EOF
2979
2980         if test x$g_have_iso_c_varargs = xyes ; then
2981                 cat >>$outfile <<_______EOF
2982 #ifndef __cplusplus
2983 # define G_HAVE_ISO_VARARGS 1
2984 #endif
2985 _______EOF
2986         fi
2987         if test x$g_have_iso_cxx_varargs = xyes ; then
2988                 cat >>$outfile <<_______EOF
2989 #ifdef __cplusplus
2990 # define G_HAVE_ISO_VARARGS 1
2991 #endif
2992 _______EOF
2993         fi
2994         if test x$g_have_gnuc_varargs = xyes ; then
2995                 cat >>$outfile <<_______EOF
2996
2997 /* gcc-2.95.x supports both gnu style and ISO varargs, but if -ansi
2998  * is passed ISO vararg support is turned off, and there is no work
2999  * around to turn it on, so we unconditionally turn it off.
3000  */
3001 #if __GNUC__ == 2 && __GNUC_MINOR__ == 95
3002 #  undef G_HAVE_ISO_VARARGS
3003 #endif
3004
3005 #define G_HAVE_GNUC_VARARGS 1
3006 _______EOF
3007         fi
3008
3009         case x$g_stack_grows in
3010         xyes) echo "#define G_HAVE_GROWING_STACK 1" >>$outfile ;;
3011         *)    echo "#define G_HAVE_GROWING_STACK 0" >>$outfile ;;
3012         esac
3013
3014
3015         echo >>$outfile
3016         if test x$g_have_eilseq = xno; then
3017                 cat >>$outfile <<_______EOF
3018 #ifndef EILSEQ
3019 /* On some systems, like SunOS and NetBSD, EILSEQ is not defined.
3020  * The correspondence between this and the corresponding definition
3021  * in libiconv is essential.
3022  */
3023 #  define EILSEQ ENOENT
3024 #endif
3025 _______EOF
3026
3027         fi
3028
3029         if test x$g_have_gnuc_visibility = xyes; then
3030                 cat >>$outfile <<_______EOF
3031 #define G_HAVE_GNUC_VISIBILITY 1
3032 _______EOF
3033         fi
3034                 cat >>$outfile <<_______EOF
3035 #if defined(__SUNPRO_C) && (__SUNPRO_C >= 0x590)
3036 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
3037 #elif defined(__SUNPRO_C) && (__SUNPRO_C >= 0x550)
3038 #define G_GNUC_INTERNAL __hidden
3039 #elif defined (__GNUC__) && defined (G_HAVE_GNUC_VISIBILITY)
3040 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
3041 #else
3042 #define G_GNUC_INTERNAL
3043 #endif
3044 _______EOF
3045
3046         echo >>$outfile
3047         cat >>$outfile <<_______EOF
3048 #define G_THREADS_ENABLED
3049 #define G_THREADS_IMPL_$g_threads_impl_def
3050 _______EOF
3051
3052         if test x"$g_memory_barrier_needed" != xno; then
3053           echo >>$outfile
3054           echo "#define G_ATOMIC_OP_MEMORY_BARRIER_NEEDED 1" >>$outfile
3055         fi
3056         if test x"$g_atomic_lock_free" = xyes; then
3057           echo >>$outfile
3058           echo "#define G_ATOMIC_LOCK_FREE" >>$outfile
3059         fi
3060         echo >>$outfile
3061         g_bit_sizes="16 32 64"
3062         for bits in $g_bit_sizes; do
3063           cat >>$outfile <<_______EOF
3064 #define GINT${bits}_TO_${g_bs_native}(val)      ((gint${bits}) (val))
3065 #define GUINT${bits}_TO_${g_bs_native}(val)     ((guint${bits}) (val))
3066 #define GINT${bits}_TO_${g_bs_alien}(val)       ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
3067 #define GUINT${bits}_TO_${g_bs_alien}(val)      (GUINT${bits}_SWAP_LE_BE (val))
3068 _______EOF
3069         done
3070
3071         cat >>$outfile <<_______EOF
3072 #define GLONG_TO_LE(val)        ((glong) GINT${glongbits}_TO_LE (val))
3073 #define GULONG_TO_LE(val)       ((gulong) GUINT${glongbits}_TO_LE (val))
3074 #define GLONG_TO_BE(val)        ((glong) GINT${glongbits}_TO_BE (val))
3075 #define GULONG_TO_BE(val)       ((gulong) GUINT${glongbits}_TO_BE (val))
3076 #define GINT_TO_LE(val)         ((gint) GINT${gintbits}_TO_LE (val))
3077 #define GUINT_TO_LE(val)        ((guint) GUINT${gintbits}_TO_LE (val))
3078 #define GINT_TO_BE(val)         ((gint) GINT${gintbits}_TO_BE (val))
3079 #define GUINT_TO_BE(val)        ((guint) GUINT${gintbits}_TO_BE (val))
3080 #define GSIZE_TO_LE(val)        ((gsize) GUINT${gsizebits}_TO_LE (val))
3081 #define GSSIZE_TO_LE(val)       ((gssize) GINT${gsizebits}_TO_LE (val))
3082 #define GSIZE_TO_BE(val)        ((gsize) GUINT${gsizebits}_TO_BE (val))
3083 #define GSSIZE_TO_BE(val)       ((gssize) GINT${gsizebits}_TO_BE (val))
3084 #define G_BYTE_ORDER $g_byte_order
3085
3086 #define GLIB_SYSDEF_POLLIN =$g_pollin
3087 #define GLIB_SYSDEF_POLLOUT =$g_pollout
3088 #define GLIB_SYSDEF_POLLPRI =$g_pollpri
3089 #define GLIB_SYSDEF_POLLHUP =$g_pollhup
3090 #define GLIB_SYSDEF_POLLERR =$g_pollerr
3091 #define GLIB_SYSDEF_POLLNVAL =$g_pollnval
3092
3093 #define G_MODULE_SUFFIX "$g_module_suffix"
3094
3095 typedef $g_pid_type GPid;
3096
3097 #define GLIB_SYSDEF_AF_UNIX $g_af_unix
3098 #define GLIB_SYSDEF_AF_INET $g_af_inet
3099 #define GLIB_SYSDEF_AF_INET6 $g_af_inet6
3100
3101 #define GLIB_SYSDEF_MSG_OOB $g_msg_oob
3102 #define GLIB_SYSDEF_MSG_PEEK $g_msg_peek
3103 #define GLIB_SYSDEF_MSG_DONTROUTE $g_msg_dontroute
3104
3105 G_END_DECLS
3106
3107 #endif /* __GLIBCONFIG_H__ */
3108 _______EOF
3109
3110
3111         if cmp -s $outfile glib/glibconfig.h; then
3112           AC_MSG_NOTICE([glib/glibconfig.h is unchanged])
3113           rm -f $outfile
3114         else
3115           mv $outfile glib/glibconfig.h
3116         fi
3117 ],[
3118
3119 # Note that if two cases are the same, case goes with the first one.
3120 # Note also that this is inside an AC_OUTPUT_COMMAND.  We do not depend
3121 # on variable expansion in case labels.  Look at the generated config.status
3122 # for a hint.
3123
3124 if test "x${ac_cv_working_alloca_h+set}" = xset ; then
3125   glib_header_alloca_h="$ac_cv_working_alloca_h"
3126 else
3127   glib_header_alloca_h="$ac_cv_header_alloca_h"
3128 fi
3129
3130 case xyes in
3131 x$ac_cv_header_float_h)
3132   glib_float_h=yes
3133   glib_mf=FLT_MIN glib_Mf=FLT_MAX
3134   glib_md=DBL_MIN glib_Md=DBL_MAX
3135   ;;
3136 x$ac_cv_header_values_h)
3137   glib_values_h=yes
3138   glib_mf=MINFLOAT  glib_Mf=MAXFLOAT
3139   glib_md=MINDOUBLE glib_Md=MAXDOUBLE
3140   ;;
3141 esac
3142
3143 case xyes in
3144 x$ac_cv_header_limits_h)
3145   glib_limits_h=yes
3146   glib_ms=SHRT_MIN glib_Ms=SHRT_MAX glib_Mus=USHRT_MAX
3147   glib_mi=INT_MIN  glib_Mi=INT_MAX  glib_Mui=UINT_MAX
3148   glib_ml=LONG_MIN glib_Ml=LONG_MAX glib_Mul=ULONG_MAX
3149   ;;
3150 x$ac_cv_header_values_h)
3151   glib_values_h=yes
3152   glib_ms=MINSHORT glib_Ms=MAXSHORT glib_Mus="(((gushort)G_MAXSHORT)*2+1)"
3153   glib_mi=MININT   glib_Mi=MAXINT   glib_Mui="(((guint)G_MAXINT)*2+1)"
3154   glib_ml=MINLONG  glib_Ml=MAXLONG  glib_Mul="(((gulong)G_MAXLONG)*2+1)"
3155   ;;
3156 esac
3157
3158 if test x$ac_cv_header_sys_poll_h = xyes ; then
3159   glib_sys_poll_h=yes
3160 fi
3161
3162 if test x$enable_included_printf = xyes ; then
3163   glib_included_printf=yes
3164 fi
3165
3166 case 2 in
3167 $ac_cv_sizeof_short)
3168   gint16=short
3169   gint16_modifier='"h"'
3170   gint16_format='"hi"'
3171   guint16_format='"hu"'
3172   ;;
3173 $ac_cv_sizeof_int)
3174   gint16=int
3175   gint16_modifier='""'
3176   gint16_format='"i"'
3177   guint16_format='"u"'
3178   ;;
3179 esac
3180 case 4 in
3181 $ac_cv_sizeof_short)
3182   gint32=short
3183   gint32_modifier='"h"'
3184   gint32_format='"hi"'
3185   guint32_format='"hu"'
3186   ;;
3187 $ac_cv_sizeof_int)
3188   gint32=int
3189   gint32_modifier='""'
3190   gint32_format='"i"'
3191   guint32_format='"u"'
3192   ;;
3193 $ac_cv_sizeof_long)
3194   gint32=long
3195   gint32_modifier='"l"'
3196   gint32_format='"li"'
3197   guint32_format='"lu"'
3198   ;;
3199 esac
3200 case 8 in
3201 $ac_cv_sizeof_int)
3202   gint64=int
3203   gint64_modifier='""'
3204   gint64_format='"i"'
3205   guint64_format='"u"'
3206   glib_extension=
3207   gint64_constant='(val)'
3208   guint64_constant='(val)'
3209   ;;
3210 $ac_cv_sizeof_long)
3211   gint64=long
3212   gint64_modifier='"l"'
3213   gint64_format='"li"'
3214   guint64_format='"lu"'
3215   glib_extension=
3216   gint64_constant='(val##L)'
3217   guint64_constant='(val##UL)'
3218   ;;
3219 $ac_cv_sizeof_long_long)
3220   gint64='long long'
3221   if test -n "$glib_cv_long_long_format"; then
3222     gint64_modifier='"'$glib_cv_long_long_format'"'
3223     gint64_format='"'$glib_cv_long_long_format'i"'
3224     guint64_format='"'$glib_cv_long_long_format'u"'
3225   fi
3226   glib_extension='G_GNUC_EXTENSION '
3227   gint64_constant='(G_GNUC_EXTENSION (val##LL))'
3228   guint64_constant='(G_GNUC_EXTENSION (val##ULL))'
3229   ;;
3230 $ac_cv_sizeof___int64)
3231   gint64='__int64'
3232   if test -n "$glib_cv_long_long_format"; then
3233     gint64_modifier='"'$glib_cv_long_long_format'"'
3234     gint64_format='"'$glib_cv_long_long_format'i"'
3235     guint64_format='"'$glib_cv_long_long_format'u"'
3236   fi
3237   glib_extension=
3238   gint64_constant='(val##i64)'
3239   guint64_constant='(val##ui64)'
3240   ;;
3241 esac
3242 glib_size_t=$ac_cv_sizeof_size_t
3243 glib_size_type_define="$glib_size_type"
3244 glib_void_p=$ac_cv_sizeof_void_p
3245 glib_long=$ac_cv_sizeof_long
3246
3247 case "$glib_size_type" in
3248 short)
3249   gsize_modifier='"h"'
3250   gsize_format='"hu"'
3251   gssize_format='"hi"'
3252   glib_msize_type='SHRT'
3253   ;;
3254 int)
3255   gsize_modifier='""'
3256   gsize_format='"u"'
3257   gssize_format='"i"'
3258   glib_msize_type='INT'
3259   ;;
3260 long)
3261   gsize_modifier='"l"'
3262   gsize_format='"lu"'
3263   gssize_format='"li"'
3264   glib_msize_type='LONG'
3265   ;;
3266 "long long"|__int64)
3267   gsize_modifier='"I64"'
3268   gsize_format='"I64u"'
3269   gssize_format='"I64i"'
3270   glib_msize_type='INT64'
3271   ;;
3272 esac
3273
3274 gintbits=`expr $ac_cv_sizeof_int \* 8`
3275 glongbits=`expr $ac_cv_sizeof_long \* 8`
3276 gsizebits=`expr $ac_cv_sizeof_size_t \* 8`
3277
3278 case $ac_cv_sizeof_void_p in
3279 $ac_cv_sizeof_int)
3280   glib_intptr_type_define=int
3281   gintptr_modifier='""'
3282   gintptr_format='"i"'
3283   guintptr_format='"u"'
3284   glib_gpi_cast='(gint)'
3285   glib_gpui_cast='(guint)'
3286   ;;
3287 $ac_cv_sizeof_long)
3288   glib_intptr_type_define=long
3289   gintptr_modifier='"l"'
3290   gintptr_format='"li"'
3291   guintptr_format='"lu"'
3292   glib_gpi_cast='(glong)'
3293   glib_gpui_cast='(gulong)'
3294   ;;
3295 $ac_cv_sizeof_long_long)
3296   glib_intptr_type_define='long long'
3297   gintptr_modifier='"I64"'
3298   gintptr_format='"I64i"'
3299   guintptr_format='"I64u"'
3300   glib_gpi_cast='(gint64)'
3301   glib_gpui_cast='(guint64)'
3302   ;;
3303 $ac_cv_sizeof___int64)
3304   glib_intptr_type_define=__int64
3305   gintptr_modifier='"I64"'
3306   gintptr_format='"I64i"'
3307   guintptr_format='"I64u"'
3308   glib_gpi_cast='(gint64)'
3309   glib_gpui_cast='(guint64)'
3310   ;;
3311 *)
3312   glib_unknown_void_p=yes
3313   ;;
3314 esac
3315
3316
3317 case xyes in
3318 x$ac_cv_func_atexit)
3319   glib_atexit="
3320 #ifdef NeXT /* @#%@! NeXTStep */
3321 # define g_ATEXIT(proc) (!atexit (proc))
3322 #else
3323 # define g_ATEXIT(proc) (atexit (proc))
3324 #endif"
3325   ;;
3326 x$ac_cv_func_on_exit)
3327   glib_atexit="
3328 #define g_ATEXIT(proc)  (on_exit ((void (*)(int, void*))(proc), NULL))"
3329   ;;
3330 esac
3331
3332 case xyes in
3333 x$ac_cv_func_memmove)
3334   glib_memmove='
3335 #define g_memmove(dest,src,len) G_STMT_START { memmove ((dest), (src), (len)); } G_STMT_END'
3336   ;;
3337 x$glib_cv_working_bcopy)
3338   glib_memmove="
3339 /* memmove isn't available, but bcopy can copy overlapping memory regions */
3340 #define g_memmove(d,s,n) G_STMT_START { bcopy ((s), (d), (n)); } G_STMT_END"
3341   ;;
3342 *)
3343   glib_memmove="
3344 /* memmove isn't found and bcopy can't copy overlapping memory regions,
3345  * so we have to roll our own copy routine. */
3346 void g_memmove (void* dest, const void * src, unsigned long len);"
3347   ;;
3348 esac
3349
3350 glib_defines="
3351 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
3352 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
3353 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
3354 "
3355
3356 case xyes in
3357 x$glib_cv_va_copy)      glib_vacopy='#define G_VA_COPY  va_copy' ;;
3358 x$glib_cv___va_copy)    glib_vacopy='#define G_VA_COPY  __va_copy' ;;
3359 *)                      glib_vacopy=''
3360 esac
3361
3362 if test x$glib_cv_va_val_copy = xno; then
3363   glib_vacopy="\$glib_vacopy
3364 #define G_VA_COPY_AS_ARRAY 1"
3365 fi
3366
3367 if test x$glib_cv_hasinline = xyes; then
3368     glib_inline='#define G_HAVE_INLINE 1'
3369 fi
3370 if test x$glib_cv_has__inline = xyes; then
3371     glib_inline="\$glib_inline
3372 #define G_HAVE___INLINE 1"
3373 fi
3374 if test x$glib_cv_has__inline__ = xyes; then
3375     glib_inline="\$glib_inline
3376 #define G_HAVE___INLINE__ 1"
3377 fi
3378
3379 g_have_gnuc_varargs=$g_have_gnuc_varargs
3380 g_have_iso_c_varargs=$g_have_iso_c_varargs
3381 g_have_iso_cxx_varargs=$g_have_iso_cxx_varargs
3382
3383 g_can_inline=$g_can_inline
3384 g_have_gnuc_visibility=$g_have_gnuc_visibility
3385 g_have_sunstudio_visibility=$g_have_sunstudio_visibility
3386
3387 if test x$ac_cv_c_bigendian = xyes; then
3388   g_byte_order=G_BIG_ENDIAN
3389   g_bs_native=BE
3390   g_bs_alien=LE
3391 else
3392   g_byte_order=G_LITTLE_ENDIAN
3393   g_bs_native=LE
3394   g_bs_alien=BE
3395 fi
3396
3397 g_pollin=$glib_cv_value_POLLIN
3398 g_pollout=$glib_cv_value_POLLOUT
3399 g_pollpri=$glib_cv_value_POLLPRI
3400 g_pollhup=$glib_cv_value_POLLHUP
3401 g_pollerr=$glib_cv_value_POLLERR
3402 g_pollnval=$glib_cv_value_POLLNVAL
3403
3404 # If a family is not found on the system, define that family to
3405 # a negative value, picking a different one for each undefined
3406 # family (-1 for AF_UNIX, -2 for the next one, -3 ...)
3407 # This is needed because glib-mkenums doesn't handle optional
3408 # values in enums, and thus we have to have all existing values
3409 # defined in the enum.
3410 if test "x$glib_cv_value_AF_UNIX" != "x"; then
3411   g_af_unix=$glib_cv_value_AF_UNIX
3412 else
3413   g_af_unix=-1
3414 fi
3415 g_af_inet=$glib_cv_value_AF_INET
3416 g_af_inet6=$glib_cv_value_AF_INET6
3417
3418 g_msg_peek=$glib_cv_value_MSG_PEEK
3419 g_msg_oob=$glib_cv_value_MSG_OOB
3420 g_msg_dontroute=$glib_cv_value_MSG_DONTROUTE
3421
3422 g_stack_grows=$glib_cv_stack_grows
3423
3424 g_have_eilseq=$have_eilseq
3425
3426 g_threads_impl_def=$g_threads_impl
3427
3428 g_atomic_lock_free="$glib_cv_g_atomic_lock_free"
3429 g_memory_barrier_needed="$glib_memory_barrier_needed"
3430 g_gcc_atomic_ops="$glib_cv_gcc_has_builtin_atomic_operations"
3431
3432 g_module_suffix="$glib_gmodule_suffix"
3433
3434 g_pid_type="$glib_pid_type"
3435 case $host in
3436   *-*-beos*)
3437     glib_os="#define G_OS_BEOS"
3438     ;;
3439   *-*-cygwin*)
3440     glib_os="#define G_OS_UNIX
3441 #define G_PLATFORM_WIN32
3442 #define G_WITH_CYGWIN"
3443     ;;
3444   *-*-mingw*)
3445     glib_os="#define G_OS_WIN32
3446 #define G_PLATFORM_WIN32"
3447     ;;
3448   *)
3449     glib_os="#define G_OS_UNIX"
3450     ;;
3451 esac
3452 glib_static_compilation=""
3453 if test x$glib_win32_static_compilation = xyes; then
3454   glib_static_compilation="#define GLIB_STATIC_COMPILATION 1
3455 #define GOBJECT_STATIC_COMPILATION 1"
3456 fi
3457 ])
3458
3459 # Redo enough to get guint32 and guint64 for the alignment checks below
3460 case 4 in
3461 $ac_cv_sizeof_short)
3462   gint32=short
3463   ;;
3464 $ac_cv_sizeof_int)
3465   gint32=int
3466   ;;
3467 $ac_cv_sizeof_long)
3468   gint32=long
3469   ;;
3470 esac
3471 case 8 in
3472 $ac_cv_sizeof_int)
3473   gint64=int
3474   ;;
3475 $ac_cv_sizeof_long)
3476   gint64=long
3477   ;;
3478 $ac_cv_sizeof_long_long)
3479   gint64='long long'
3480   ;;
3481 $ac_cv_sizeof___int64)
3482   gint64='__int64'
3483   ;;
3484 esac
3485
3486 AC_CHECK_TYPE([guint32],,,[typedef unsigned $gint32 guint32;])
3487 AC_CHECK_ALIGNOF([guint32], [AC_INCLUDES_DEFAULT
3488 typedef unsigned $gint32 guint32;])
3489 AC_CHECK_TYPE([guint64],,,[typedef unsigned $gint64 guint64;])
3490 AC_CHECK_ALIGNOF([guint64], [AC_INCLUDES_DEFAULT
3491 typedef unsigned $gint64 guint64;])
3492 AC_CHECK_TYPE([unsigned long])
3493 AC_CHECK_ALIGNOF([unsigned long])
3494
3495 # Check for libdbus1 - Optional - is only used in the GDBus test cases
3496 #
3497 # 1.2.14 required for dbus_message_set_serial
3498 AS_IF([ test x$enable_modular_tests = xyes], [
3499    PKG_CHECK_MODULES(DBUS1,
3500                      dbus-1 >= 1.2.14,
3501                      [AC_DEFINE(HAVE_DBUS1, 1, [Define if dbus-1 is available]) have_dbus1=yes],
3502                      have_dbus1=no)
3503    AC_SUBST(DBUS1_CFLAGS)
3504    AC_SUBST(DBUS1_LIBS)
3505 ])
3506 AM_CONDITIONAL(HAVE_DBUS1, [test "x$have_dbus1" = "xyes"])
3507
3508 AC_CHECK_PROGS([DBUS_DAEMON], [dbus-daemon])
3509 AM_CONDITIONAL([HAVE_DBUS_DAEMON], [test x$DBUS_DAEMON = xdbus-daemon ])
3510
3511 dnl
3512 dnl Check for -Bsymbolic-functions linker flag used to avoid
3513 dnl intra-library PLT jumps, if available.
3514 dnl
3515
3516 AC_ARG_ENABLE(Bsymbolic,
3517               [AS_HELP_STRING([--disable-Bsymbolic],
3518                               [avoid linking with -Bsymbolic])],,
3519               [SAVED_LDFLAGS="${LDFLAGS}"
3520                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
3521                LDFLAGS=-Wl,-Bsymbolic-functions
3522                AC_TRY_LINK([], [int main (void) { return 0; }],
3523                            AC_MSG_RESULT(yes)
3524                            enable_Bsymbolic=yes,
3525                            AC_MSG_RESULT(no)
3526                            enable_Bsymbolic=no)
3527                LDFLAGS="${SAVED_LDFLAGS}"])
3528
3529 if test "x${enable_Bsymbolic}" = "xyes"; then
3530   GLIB_LINK_FLAGS=-Wl,-Bsymbolic-functions
3531 fi
3532
3533 AC_SUBST(GLIB_LINK_FLAGS)
3534
3535 #
3536 # Define variables corresponding to the correct include paths to use for
3537 # in-tree building.
3538 #
3539
3540 # for config.h:
3541 config_h_INCLUDES='-I$(top_builddir)'
3542 AC_SUBST(config_h_INCLUDES)
3543
3544 # glib:
3545 #   config.h
3546 #   $(top_builddir)/glib: for glibconfig.h
3547 #   $(top_srcdir)/glib:   for glib.h
3548 #   $(top_srcdir):        for everything
3549 glib_INCLUDES='$(config_h_INCLUDES) -I$(top_builddir)/glib -I$(top_srcdir)/glib -I$(top_srcdir)'
3550 AC_SUBST(glib_INCLUDES)
3551
3552 # gthread:
3553 #   same as glib
3554 gthread_INCLUDES='$(glib_INCLUDES)'
3555 AC_SUBST(gthread_INCLUDES)
3556
3557 # gobject:
3558 #   same as gthread
3559 gobject_INCLUDES='$(gthread_INCLUDES)'
3560 AC_SUBST(gobject_INCLUDES)
3561
3562 # gmodule:
3563 #   glib includes
3564 #   $(top_srcdir)/gmodule: for gmodule.h
3565 gmodule_INCLUDES='$(glib_INCLUDES) -I$(top_srcdir)/gmodule'
3566 AC_SUBST(gmodule_INCLUDES)
3567
3568 # gio:
3569 #   same as gmodule
3570 gio_INCLUDES='$(gmodule_INCLUDES)'
3571 AC_SUBST(gio_INCLUDES)
3572
3573
3574 AC_CONFIG_FILES([
3575 glib-2.0.pc
3576 gmodule-2.0.pc
3577 gmodule-export-2.0.pc
3578 gmodule-no-export-2.0.pc
3579 gthread-2.0.pc
3580 gobject-2.0.pc
3581 gio-2.0.pc
3582 gio-unix-2.0.pc
3583 gio-windows-2.0.pc
3584 glib-zip
3585 glib-gettextize
3586 Makefile
3587 build/Makefile
3588 build/win32/Makefile
3589 build/win32/dirent/Makefile
3590 build/win32/vs9/Makefile
3591 build/win32/vs10/Makefile
3592 glib/Makefile
3593 glib/glib.stp
3594 glib/libcharset/Makefile
3595 glib/gnulib/Makefile
3596 glib/pcre/Makefile
3597 glib/update-pcre/Makefile
3598 glib/tests/Makefile
3599 gmodule/Makefile
3600 gmodule/gmoduleconf.h
3601 gobject/Makefile
3602 gobject/gobject.stp
3603 gobject/glib-mkenums
3604 gobject/tests/Makefile
3605 gthread/Makefile
3606 gio/Makefile
3607 gio/gdbus-2.0/codegen/Makefile
3608 gio/gdbus-2.0/codegen/config.py
3609 gio/xdgmime/Makefile
3610 gio/inotify/Makefile
3611 gio/fen/Makefile
3612 gio/fam/Makefile
3613 gio/win32/Makefile
3614 gio/tests/Makefile
3615 gio/tests/gdbus-object-manager-example/Makefile
3616 po/Makefile.in
3617 docs/Makefile
3618 docs/reference/Makefile
3619 docs/reference/glib/Makefile
3620 docs/reference/glib/version.xml
3621 docs/reference/gobject/Makefile
3622 docs/reference/gobject/version.xml
3623 docs/reference/gio/Makefile
3624 docs/reference/gio/gdbus-object-manager-example/Makefile
3625 docs/reference/gio/version.xml
3626 tests/Makefile
3627 tests/gobject/Makefile
3628 tests/refcount/Makefile
3629 m4macros/Makefile
3630 ])
3631
3632 AC_CONFIG_COMMANDS([chmod-scripts],
3633 [chmod 0755 glib-zip
3634 chmod 0755 glib-gettextize
3635 chmod 0755 gobject/glib-mkenums])
3636
3637 # we want to invoke this macro solely so that the config.status script
3638 # and automake generated makefiles know about these generated files.
3639 # They are only needed to distcheck the package
3640 if false; then
3641   AC_CONFIG_FILES([
3642     INSTALL
3643     README
3644     config.h.win32
3645     glib/glibconfig.h.win32
3646     glib/makefile.msc
3647     glib/glib.rc
3648     gmodule/makefile.msc
3649     gmodule/gmodule.rc
3650     gobject/makefile.msc
3651     gobject/gobject.rc
3652     gthread/makefile.msc
3653     gthread/gthread.rc
3654     gio/gio.rc
3655     tests/makefile.msc
3656   ])
3657 fi
3658
3659 AC_OUTPUT