configure.ac

   1 # If not 1, append datestamp to the version number
   2 m4_define([folks_released], [0])
   3
   4 m4_define([folks_major_version], [0])
   5 m4_define([folks_minor_version], [6])
   6 m4_define([folks_micro_version], [3])
   7 m4_define([folks_nano_version], [3])
   8
   9 # If library source has changed since last release, increment revision
  10 # If interfaces have been added, removed or changed since last release,
  11 #  increment current and set revision to 0
  12 # If interfaces have been added since last release, increment age
  13 # If interfaces have been removed since last release, set age to 0
  14 m4_define([folks_lt_current], [27])
  15 m4_define([folks_lt_revision], [2])
  16 m4_define([folks_lt_age], [2])
  17
  18 # Display the nano_version only if it's not '0'
  19 m4_define([folks_base_version],
  20           folks_major_version.folks_minor_version.folks_micro_version)
  21 m4_define([folks_full_version],
  22           [m4_if(folks_nano_version, [0],
  23                  folks_base_version, folks_base_version.folks_nano_version)])
  24
  25 m4_define([folks_maybe_datestamp],
  26           m4_if(folks_released, [1],
  27                 [], [m4_esyscmd([date +.%Y%m%d | tr -d '\n\r'])]))
  28
  29 m4_define([folks_version], folks_full_version[]folks_maybe_datestamp)
  30 m4_define([folks_major_minor_version], folks_major_version.folks_minor_version)
  31 m4_define([folks_module_version], folks_lt_current)
  32
  33 AC_INIT([folks], folks_version,
  34         [https://bugzilla.gnome.org/browse.cgi?product=folks], [folks],
  35         [http://telepathy.freedesktop.org/wiki/Folks])
  36 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  37
  38 AC_PREREQ([2.65])
  39 AC_COPYRIGHT([Copyright (C) 2010 Collabora Ltd.])
  40
  41 AC_CONFIG_MACRO_DIR([m4])
  42 AC_CONFIG_SRCDIR([Makefile.am])
  43 AC_CONFIG_HEADERS(config.h)
  44 AC_CONFIG_SRCDIR([configure.ac])
  45 AM_INIT_AUTOMAKE([1.11 dist-bzip2 no-define
  46                   no-dist-gzip tar-ustar -Wno-portability])
  47 AM_MAINTAINER_MODE([enable])
  48
  49 AC_PROG_CC
  50 AM_PROG_CC_C_O
  51 AC_DISABLE_STATIC
  52 LT_INIT
  53 PKG_PROG_PKG_CONFIG([0.21])
  54
  55 AC_SUBST([CFLAGS])
  56 AC_SUBST([CPPFLAGS])
  57 AC_SUBST([LDFLAGS])
  58
  59 LT_CURRENT=folks_lt_current
  60 LT_REVISION=folks_lt_revision
  61 LT_AGE=folks_lt_age
  62 AC_SUBST([LT_CURRENT])
  63 AC_SUBST([LT_REVISION])
  64 AC_SUBST([LT_AGE])
  65
  66 FOLKS_MAJOR_MINOR_VERSION=folks_major_minor_version
  67 AC_SUBST([FOLKS_MAJOR_MINOR_VERSION])
  68
  69 API_VERSION=0.6
  70 AC_SUBST([API_VERSION])
  71
  72 AC_ARG_ENABLE(tracker-backend,
  73         AC_HELP_STRING([--enable-tracker-backend],
  74                        [ build the Tracker backend]),
  75         enable_tracker_backend=$enableval,
  76         enable_tracker_backend=no )
  77
  78 AM_CONDITIONAL([ENABLE_TRACKER], [test "x$enable_tracker_backend" = "xyes"])
  79
  80 AC_ARG_ENABLE(eds-backend,
  81         AC_HELP_STRING([--enable-eds-backend],
  82                        [ build the E-D-S backend]),
  83         enable_eds_backend=$enableval,
  84         enable_eds_backend=yes )
  85
  86 AM_CONDITIONAL([ENABLE_EDS], [test "x$enable_eds_backend" = "xyes"])
  87
  88 # Automatically check the dependencies for the libsocialweb backend
  89 SW_CLIENT_REQUIRED=0.25.15
  90 AC_ARG_ENABLE(libsocialweb-backend,
  91         AC_HELP_STRING([--enable-libsocialweb-backend=@<:@no/yes/auto@:>@],
  92                        [build the Libsocialweb backend (default: auto)]),
  93         enable_libsocialweb_backend=$enableval,
  94         enable_libsocialweb_backend=auto )
  95
  96 if test "x$enable_libsocialweb_backend" != "xno"; then
  97   PKG_CHECK_MODULES([SW_CLIENT], [libsocialweb-client >= $SW_CLIENT_REQUIRED],
  98       have_libsocialweb_backend="yes", have_libsocialweb_backend="no")
  99   if test "x$have_libsocialweb_backend" = "xyes" -a \
 100           "x$enable_vala" = "xyes"; then
 101     VALA_CHECK_PACKAGES([telepathy-glib
 102                          gio-2.0
 103                          gee-1.0
 104                          libsocialweb-client],
 105         ,
 106         have_libsocialweb_backend="no")
 107   fi
 108
 109   if test "x$have_libsocialweb_backend" = "xyes"; then
 110     AC_DEFINE(HAVE_LIBSOCIALWEB, [],
 111               [Define if you have the libsocialweb backend])
 112   fi
 113 else
 114    have_libsocialweb_backend=no
 115 fi
 116
 117 if test "x$enable_libsocialweb_backend" = "xyes" -a \
 118   "x$have_libsocialweb_backend" != "xyes"; then
 119     AC_MSG_ERROR([Cannot find libsocialweb dependencies.])
 120 fi
 121
 122 AM_CONDITIONAL([ENABLE_LIBSOCIALWEB],
 123         [test "x$have_libsocialweb_backend" = "xyes"])
 124
 125 # -----------------------------------------------------------
 126 # Dependencies
 127 # -----------------------------------------------------------
 128
 129 GLIB_REQUIRED=2.24.0
 130 TP_GLIB_REQUIRED=0.13.1
 131 VALA_REQUIRED=0.13.4
 132 VALADOC_REQUIRED=0.3.1
 133 TRACKER_SPARQL_REQUIRED=0.12
 134 TRACKER_SPARQL_NEWER_VER=0.12.0
 135 GCONF2_REQUIRED=2.31
 136 EBOOK_REQUIRED=3.1.5
 137 EDATASERVER_REQUIRED=3.1.5
 138
 139 PKG_CHECK_MODULES([GLIB],
 140                   [glib-2.0 >= $GLIB_REQUIRED
 141                    gobject-2.0 >= $GLIB_REQUIRED])
 142 PKG_CHECK_MODULES([GMODULE], [gmodule-no-export-2.0])
 143 PKG_CHECK_MODULES([GIO], [gio-2.0 >= $GLIB_REQUIRED])
 144 PKG_CHECK_MODULES([DBUS_GLIB], [dbus-glib-1])
 145 PKG_CHECK_MODULES([GCONF2], [gconf-2.0 >= $GCONF2_REQUIRED])
 146
 147 # FIXME: We depend on libgee < 0.7 because 0.7 breaks API. bgo#627746
 148 PKG_CHECK_MODULES([GEE], [gee-1.0 < 0.7])
 149 PKG_CHECK_MODULES([TP_GLIB], [telepathy-glib >= $TP_GLIB_REQUIRED])
 150
 151 if test x$enable_tracker_backend = xyes; then
 152         # Starting Tracker 0.10.6, the GLib.SpawnError is exception is thrown
 153         # when calling Tracker.Sparql.Connection.get (). So we need to test
 154         # for the installed version and catch or not the exception, accordingly.
 155         PKG_CHECK_MODULES([TRACKER_SPARQL],
 156                           [tracker-sparql-0.12 >= $TRACKER_SPARQL_NEWER_VER])
 157 fi
 158
 159 if test x$enable_eds_backend = xyes; then
 160         PKG_CHECK_MODULES([EBOOK], [libebook-1.2 >= $EBOOK_REQUIRED])
 161         PKG_CHECK_MODULES([EDATASERVER], [libedataserver-1.2 >= $EDATASERVER_REQUIRED])
 162 fi
 163
 164 #
 165 # Vala building options -- allows tarball builds without installing Vala
 166 #
 167 AC_ARG_ENABLE([vala],
 168               AS_HELP_STRING([--enable-vala],
 169                              [Enable building from the Vala sources]),
 170               [enable_vala=$enableval],
 171               [enable_vala=no])
 172
 173 # will be re-set as necessary below
 174 AM_CONDITIONAL([HAVE_INTROSPECTION], [test "x$enable_vala" = "xyes"])
 175 sd=${srcdir}/
 176
 177 # Force Vala for non-release builds
 178 m4_if(folks_released, [1], [],
 179     [
 180         enable_vala=yes
 181         echo "Vala compiler required for non-release builds; requiring Vala..."
 182     ])
 183
 184 # Force Vala if generated source is missing or outdated
 185 if test \
 186         ! -e ${sd}tools/folks_import_vala.stamp -o \
 187         ! -e ${sd}tests/folks/abstract_field_details_vala.stamp -o \
 188         ! -e ${sd}tests/folks/aggregation_vala.stamp -o \
 189         ! -e ${sd}tests/folks/backend_loading_vala.stamp -o \
 190         ! -e ${sd}tests/key-file/individual_retrieval_vala.stamp -o \
 191         ! -e ${sd}tests/lib/folks-test.vapi -o \
 192         ! -e ${sd}tests/lib/key-file/kf-test.vapi -o \
 193         ! -e ${sd}tests/lib/key-file/libkf_test_la_vala.stamp -o \
 194         ! -e ${sd}tests/lib/telepathy/contactlist/tp-test-contactlist.gir -o \
 195         ! -e ${sd}tests/lib/telepathy/contactlist/tp-test-contactlist.vapi -o \
 196         ! -e ${sd}tests/lib/libfolks_test_la_vala.stamp -o \
 197         ! -e ${sd}tests/telepathy/persona_store_capabilities_vala.stamp -o \
 198         ! -e ${sd}tests/telepathy/individual_retrieval_vala.stamp -o \
 199         ! -e ${sd}tests/telepathy/individual_properties_vala.stamp -o \
 200         ! -e ${sd}tests/folks/backend_loading_vala.stamp -o \
 201         ! -e ${sd}backends/key-file/key_file_la_vala.stamp -o \
 202         ! -e ${sd}backends/telepathy/telepathy_la_vala.stamp \
 203                 -o \
 204         ! -e ${sd}backends/telepathy/lib/folks-telepathy.vapi -o \
 205         ! -e ${sd}backends/telepathy/lib/tp-lowlevel.gir -o \
 206         ! -e ${sd}backends/telepathy/lib/tp-lowlevel.vapi -o \
 207         ! -e ${sd}backends/telepathy/lib/libfolks_telepathy_la_vala.stamp -o \
 208         ! -e ${sd}folks/folks.vapi -o \
 209         ! -e ${sd}folks/libfolks_la_vala.stamp ; then
 210         enable_vala=yes
 211         echo "Vala source needs to be re-compiled; requiring Vala..."
 212 fi
 213
 214 if test "x$enable_vala" = "xyes" ; then
 215         AM_PROG_VALAC([$VALA_REQUIRED])
 216         if test "x$VALAC" = "x"; then
 217               AC_MSG_ERROR([Vala requested but valac is not installed])
 218         fi
 219
 220         AC_PATH_PROG([VAPIGEN], [vapigen], [])
 221         if test "x$VAPIGEN" = "x"; then
 222               AC_MSG_ERROR([Vala must be built with --enable-vapigen])
 223         fi
 224
 225         # require GLib >= 2.24 so GLib.Array, etc. reffing is handled
 226         # automatically
 227         VALAFLAGS="$VALAFLAGS --target-glib=2.24"
 228         AC_SUBST([VALAFLAGS])
 229         AC_SUBST([VAPIGENFLAGS])
 230         AC_SUBST([VAPIDIR])
 231
 232         VALA_CHECK_PACKAGES([telepathy-glib
 233                              gio-2.0
 234                              gee-1.0])
 235
 236         if test x$enable_tracker_backend = xyes; then
 237           VALA_CHECK_PACKAGES([tracker-sparql-0.10])
 238         fi
 239
 240         if test x$enable_eds_backend = xyes; then
 241           VALA_CHECK_PACKAGES([libebook-1.2 libedataserver-1.2 libxml-2.0])
 242         fi
 243 fi
 244
 245 # this will set HAVE_INTROSPECTION
 246 GOBJECT_INTROSPECTION_REQUIRE([0.9.12])
 247
 248 AM_CONDITIONAL([HAVE_VALA], [test "x$enable_vala" = "xyes"])
 249
 250 # Various functions that we need (used in C code generated from Vala)
 251 AC_CHECK_FUNCS([memset])
 252 AC_CHECK_FUNCS([strstr])
 253
 254 # -----------------------------------------------------------
 255 # Backends
 256 # -----------------------------------------------------------
 257
 258 FOLKS_MODULE_VERSION=folks_module_version
 259 AC_SUBST([FOLKS_MODULE_VERSION])
 260 AC_DEFINE([MODULE_VERSION], "folks_module_version", [Module interface version])
 261
 262 BACKEND_DIR='$(libdir)/folks/$(FOLKS_MODULE_VERSION)/backends'
 263 AC_SUBST([BACKEND_DIR])
 264
 265 BACKEND_KF='$(top_builddir)/backends/key-file/.libs/key-file.so'
 266 AC_SUBST([BACKEND_KF])
 267 BACKEND_TP='$(top_builddir)/backends/telepathy/.libs/telepathy.so'
 268 AC_SUBST([BACKEND_TP])
 269
 270 if test x$have_libsocialweb_backend = xyes; then
 271   BACKEND_LIBSOCIALWEB='$(top_builddir)/backends/libsocialweb/.libs/libsocialweb.so'
 272   AC_SUBST([BACKEND_LIBSOCIALWEB])
 273 fi
 274
 275 if test x$enable_tracker_backend = xyes; then
 276   BACKEND_TRACKER='$(top_builddir)/backends/tracker/.libs/tracker.so'
 277   AC_SUBST([BACKEND_TRACKER])
 278 fi
 279
 280 if test x$enable_eds_backend = xyes; then
 281   BACKEND_EDS='$(top_builddir)/backends/eds/.libs/eds.so'
 282   AC_SUBST([BACKEND_EDS])
 283 fi
 284
 285 # All of the backend libraries in our tree; to be used by the tests
 286 BACKEND_UNINST_PATH='$(BACKEND_KF):$(BACKEND_TP)'
 287 if test x$have_libsocialweb_backend = xyes; then
 288   LIBSOCIALWEB_BACKEND_UNINST_PATH='$(BACKEND_LIBSOCIALWEB)'
 289   BACKEND_UNINST_PATH="$BACKEND_UNINST_PATH:$LIBSOCIALWEB_BACKEND_UNINST_PATH"
 290 fi
 291 if test x$enable_tracker_backend = xyes; then
 292   TRACKER_BACKEND_UNINST_PATH='$(BACKEND_TRACKER)'
 293   BACKEND_UNINST_PATH="$BACKEND_UNINST_PATH:$TRACKER_BACKEND_UNINST_PATH"
 294 fi
 295 if test x$enable_eds_backend = xyes; then
 296   EDS_BACKEND_UNINST_PATH='$(BACKEND_EDS)'
 297   BACKEND_UNINST_PATH="$BACKEND_UNINST_PATH:$EDS_BACKEND_UNINST_PATH"
 298 fi
 299 AC_SUBST([BACKEND_UNINST_PATH])
 300
 301 # -----------------------------------------------------------
 302 # Tools
 303 # -----------------------------------------------------------
 304
 305 AC_ARG_ENABLE([import-tool],
 306               AS_HELP_STRING([--enable-import-tool],
 307                              [Enable building the meta-contact import tool]),
 308               [enable_import_tool=$enableval with_import_tool=$enableval],
 309               [enable_import_tool=maybe with_import_tool=no])
 310 AS_IF([test "$enable_import_tool" != "no"],
 311       [PKG_CHECK_MODULES([LIBXML], [libxml-2.0],
 312                          [with_import_tool=yes], [with_import_tool=no])])
 313 AS_IF([test "$enable_import_tool" = "yes" -a "$with_import_tool" = "no"],
 314       [AC_MSG_ERROR([Import tool explicitly enabled, but libxml2 not found])])
 315 AM_CONDITIONAL([ENABLE_IMPORT_TOOL], [test "$with_import_tool" = "yes"])
 316
 317 # Readline's required for the folks-inspect program
 318 AC_ARG_ENABLE([inspect-tool],
 319               AS_HELP_STRING([--enable-inspect-tool],
 320                              [Enable building the data inspection tool]),
 321               [enable_inspect_tool=$enableval with_inspect_tool=$enableval],
 322               [enable_inspect_tool=maybe with_inspect_tool=no])
 323 AS_IF([test "$enable_inspect_tool" = "yes" -a "$enable_vala" != "yes"],
 324       [AC_MSG_ERROR([Inspect tool explicitly enabled, but Vala wasn't enabled \
 325                      using --enable-vala])])
 326 AS_IF([test "$enable_inspect_tool" = "maybe" -a "$enable_vala" != "yes"],
 327       [AC_MSG_NOTICE([Inspect tool disabled, as Vala wasn't enabled using \
 328                       --enable-vala])])
 329 AS_IF([test "$enable_inspect_tool" != "no" -a "x$enable_vala" = "xyes"],
 330       [AC_CHECK_LIB([readline], [main],
 331                     [with_inspect_tool=yes], [with_inspect_tool=no],
 332                     [-lncurses])])
 333 AS_IF([test "$enable_inspect_tool" != "no" -a "$with_inspect_tool" = "yes" -a \
 334        "x$enable_vala" = "xyes"],
 335       [VALA_CHECK_PACKAGES([readline])
 336        LIBREADLINE="-lreadline -lncurses"
 337        AC_DEFINE([HAVE_LIBREADLINE], [1], [Define if you have libreadline])
 338        AC_SUBST([LIBREADLINE])])
 339 AS_IF([test "$enable_inspect_tool" = "yes" -a "$with_inspect_tool" = "no"],
 340       [AC_MSG_ERROR([Inspect tool explicitly enabled, but readline not found])])
 341 AM_CONDITIONAL([ENABLE_INSPECT_TOOL], [test "$with_inspect_tool" = "yes"])
 342
 343 # -----------------------------------------------------------
 344 # Documentation
 345 # -----------------------------------------------------------
 346
 347 AC_ARG_ENABLE([docs],
 348               AS_HELP_STRING([--enable-docs],[Enable documentation generation]),
 349               [enable_docs=$enableval], [enable_docs=no])
 350 AM_CONDITIONAL([ENABLE_DOCS], [test x$enable_docs = xyes])
 351
 352 have_valadoc=no
 353 if test x$enable_docs = xyes; then
 354   # make sure the library is new enough and the program exists
 355   PKG_CHECK_MODULES([VALADOC], [valadoc-1.0 >= $VALADOC_REQUIRED])
 356   AC_PATH_PROG([VALADOC], [valadoc], [:])
 357   AS_IF([test "$VALADOC" != :], have_valadoc=yes)
 358 fi
 359 AM_CONDITIONAL([HAVE_VALADOC], [test x$have_valadoc = xyes])
 360
 361 if test "x$enable_docs" = "xyes" -a "x$have_valadoc" != "xyes"; then
 362     AC_MSG_ERROR([Doc building requested but valadoc not installed.])
 363 fi
 364
 365 # -----------------------------------------------------------
 366 # Gettext
 367 # -----------------------------------------------------------
 368
 369 GETTEXT_PACKAGE=AC_PACKAGE_NAME
 370 AC_SUBST(GETTEXT_PACKAGE)
 371 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"], [Define the gettext package to be used])
 372 IT_PROG_INTLTOOL([0.35.0])
 373
 374 # -----------------------------------------------------------
 375 # Error flags
 376 # -----------------------------------------------------------
 377
 378 AS_COMPILER_FLAG([-Wall], [ERROR_CFLAGS="-Wall"], [ERROR_CFLAGS=""])
 379 AS_COMPILER_FLAG([-Werror], [werror=yes], [werror=no])
 380
 381 AC_ARG_ENABLE([debug],
 382               AS_HELP_STRING([--disable-debug],[compile without debug code]),
 383               [enable_debug=$enableval], [enable_debug=yes])
 384
 385 AC_ARG_ENABLE([Werror],
 386               AS_HELP_STRING([--disable-Werror],
 387                              [compile without -Werror (normally enabled in
 388                               development builds)]),
 389               [werror=$enableval], [werror=yes])
 390
 391 AS_COMPILER_FLAG([-Wextra], [wextra=yes], [wextra=no])
 392 AS_COMPILER_FLAG([-Wno-missing-field-initializers],
 393                  [wno_missing_field_initializers=yes],
 394                  [wno_missing_field_initializers=no])
 395 AS_COMPILER_FLAG([-Wno-unused-parameter],
 396                  [wno_unused_parameter=yes], [wno_unused_parameter=no])
 397
 398 m4_if(folks_released, [1], [],
 399     [
 400         if test x$werror = xyes; then
 401             ERROR_CFLAGS="$ERROR_CFLAGS -Werror"
 402         fi
 403         if test x$wextra = xyes -a \
 404             x$wno_missing_field_initializers = xyes -a \
 405             x$wno_unused_parameter = xyes; then
 406             ERROR_CFLAGS="$ERROR_CFLAGS -Wextra \
 407                 -Wno-missing-field-initializers -Wno-unused-parameter"
 408         fi
 409     ])
 410
 411 AS_COMPILER_FLAG([-D_POSIX_SOURCE], [ERROR_CFLAGS="$ERROR_CFLAGS -D_POSIX_SOURCE"])
 412 AS_COMPILER_FLAG([-std=c99], [ERROR_CFLAGS="$ERROR_CFLAGS -std=c99"])
 413 AS_COMPILER_FLAG([-Wshadow], [ERROR_CFLAGS="$ERROR_CFLAGS -Wshadow"])
 414 AS_COMPILER_FLAG([-Wmissing-prototypes], [ERROR_CFLAGS="$ERROR_CFLAGS \
 415                                           -Wmissing-prototypes"])
 416 AS_COMPILER_FLAG([-Wmissing-declarations], [ERROR_CFLAGS="$ERROR_CFLAGS \
 417                                             -Wmissing-declarations"])
 418 AS_COMPILER_FLAG([-Wstrict-prototypes], [ERROR_CFLAGS="$ERROR_CFLAGS \
 419                                          -Wstrict-prototypes"])
 420
 421 AC_SUBST([ERROR_CFLAGS])
 422
 423 # Vala-related flags
 424 AS_IF([test "x$enable_vala" = "xyes"],
 425       [ERROR_INTROSPECTION_SCANNER_ARGS="\
 426                         $ERROR_INTROSPECTION_SCANNER_ARGS --warn-error"
 427        ERROR_VALAFLAGS="$ERROR_VALAFLAGS --fatal-warnings"])
 428
 429 m4_if(folks_released, [1], [],
 430     [
 431         ERROR_VALAFLAGS="$ERROR_VALAFLAGS -g"
 432     ])
 433
 434 AC_SUBST([ERROR_INTROSPECTION_SCANNER_ARGS])
 435 AC_SUBST([ERROR_VALAFLAGS])
 436
 437 # -----------------------------------------------------------
 438 # Final output
 439 # -----------------------------------------------------------
 440
 441 AC_CONFIG_FILES([
 442     backends/telepathy/lib/folks-telepathy.pc
 443     backends/telepathy/lib/folks-telepathy-uninstalled.pc
 444     backends/tracker/lib/folks-tracker.pc
 445     backends/tracker/lib/folks-tracker-uninstalled.pc
 446     backends/eds/lib/folks-eds.pc
 447     backends/eds/lib/folks-eds-uninstalled.pc
 448     folks/folks.pc
 449     folks/folks-uninstalled.pc
 450     Makefile
 451     backends/Makefile
 452     backends/key-file/Makefile
 453     backends/libsocialweb/Makefile
 454     backends/libsocialweb/lib/Makefile
 455     backends/libsocialweb/lib/folks-libsocialweb.pc
 456     backends/libsocialweb/lib/folks-libsocialweb-uninstalled.pc
 457     backends/telepathy/Makefile
 458     backends/telepathy/lib/Makefile
 459     backends/tracker/Makefile
 460     backends/tracker/lib/Makefile
 461     backends/eds/Makefile
 462     backends/eds/lib/Makefile
 463     folks/Makefile
 464     docs/Makefile
 465     po/Makefile.in
 466     tests/Makefile
 467     tests/data/Makefile
 468     tests/data/gconf.path
 469     tests/folks/Makefile
 470     tests/key-file/Makefile
 471     tests/libsocialweb/Makefile
 472     tests/telepathy/Makefile
 473     tests/tracker/Makefile
 474     tests/lib/Makefile
 475     tests/lib/folks-test-uninstalled.pc
 476     tests/lib/key-file/Makefile
 477     tests/lib/libsocialweb/Makefile
 478     tests/lib/libsocialweb/session.conf
 479     tests/eds/Makefile
 480     tests/lib/eds/Makefile
 481     tests/lib/telepathy/Makefile
 482     tests/lib/tracker/Makefile
 483     tests/lib/telepathy/contactlist/Makefile
 484     tests/lib/telepathy/contactlist/session.conf
 485     tests/tools/Makefile
 486     tools/Makefile
 487     tools/inspect/Makefile
 488 ])
 489
 490 AC_OUTPUT
 491
 492 echo "
 493 Configure summary:
 494
 495         Vala........................:  ${enable_vala}
 496         Vala Compiler...............:  ${VALAC}
 497         C Compiler Flags............:  ${CFLAGS} ${ERROR_CFLAGS}
 498         Prefix......................:  ${prefix}
 499         Bugreporting URL............:  ${PACKAGE_BUGREPORT}
 500         Documentation...............:  ${have_valadoc}
 501         Import tool.................:  ${with_import_tool}
 502         Inspector tool..............:  ${with_inspect_tool}
 503         Tracker backend.............:  ${enable_tracker_backend}
 504         Libsocialweb backend........:  ${have_libsocialweb_backend}
 505         E-D-S backend...............:  ${enable_eds_backend}
 506
 507 "