configure.ac

   1 AC_INIT([libusb], [1.0.4])
   2 AM_INIT_AUTOMAKE
   3 AC_CONFIG_SRCDIR([libusb/core.c])
   4 AC_CONFIG_MACRO_DIR([m4])
   5 AM_CONFIG_HEADER([config.h])
   6 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
   7
   8 AC_PREREQ([2.50])
   9 AC_PROG_CC
  10 AC_PROG_LIBTOOL
  11 AC_C_INLINE
  12 AM_PROG_CC_C_O
  13 AC_DEFINE([_GNU_SOURCE], [], [Use GNU extensions])
  14
  15 AC_MSG_CHECKING([operating system])
  16 case $host in
  17 *-linux*)
  18         AC_DEFINE(OS_LINUX, [], [Linux backend])
  19         AC_SUBST(OS_LINUX)
  20         AC_MSG_RESULT([Linux])
  21         backend="linux"
  22         AC_CHECK_LIB(rt, clock_gettime)
  23         AM_LDFLAGS=""
  24         ;;
  25 *-darwin*)
  26         AC_DEFINE(OS_DARWIN, [], [Darwin backend])
  27         AC_SUBST(OS_DARWIN)
  28         AC_DEFINE(USBI_OS_HANDLES_TIMEOUT, [], [Backend handles timeout])
  29         AC_MSG_RESULT([Darwin/MacOS X])
  30         backend="darwin"
  31         AM_LDFLAGS="-Wl,-framework -Wl,IOKit -Wl,-framework -Wl,CoreFoundation -Wl,-prebind -no-undefined"
  32         ;;
  33 *)
  34         AC_MSG_ERROR([unsupported operating system])
  35 esac
  36
  37 AM_CONDITIONAL([OS_LINUX], [test "x$backend" == "xlinux"])
  38 AM_CONDITIONAL([OS_DARWIN], [test "x$backend" == "xdarwin"])
  39
  40 # Library versioning
  41 lt_major="0"
  42 lt_revision="0"
  43 lt_age="0"
  44 AC_SUBST(lt_major)
  45 AC_SUBST(lt_revision)
  46 AC_SUBST(lt_age)
  47
  48 # timerfd
  49 AC_CHECK_HEADER([sys/timerfd.h], [timerfd_h=1], [timerfd_h=0])
  50 AC_ARG_ENABLE([timerfd],
  51         [AS_HELP_STRING([--enable-timerfd],
  52                 [use timerfd for timing (default auto)])],
  53         [use_timerfd=$enableval], [use_timerfd='auto'])
  54
  55 if test "x$use_timerfd" = "xyes" -a "x$timerfd_h" = "x0"; then
  56         AC_MSG_ERROR([timerfd header not available; glibc 2.8+ required])
  57 error
  58 fi
  59
  60 AC_MSG_CHECKING([whether to use timerfd for timing])
  61 if test "x$use_timerfd" = "xno"; then
  62         AC_MSG_RESULT([no (disabled by user)])
  63 else
  64         if test "x$timerfd_h" = "x1"; then
  65                 AC_MSG_RESULT([yes])
  66                 AC_DEFINE(USBI_TIMERFD_AVAILABLE, [], [timerfd headers available])
  67         else
  68                 AC_MSG_RESULT([no (header not available)])
  69         fi
  70 fi
  71
  72 # Message logging
  73 AC_ARG_ENABLE([log], [AS_HELP_STRING([--disable-log], [disable all logging])],
  74         [log_enabled=$enableval],
  75         [log_enabled='yes'])
  76 if test "x$log_enabled" != "xno"; then
  77         AC_DEFINE([ENABLE_LOGGING], 1, [Message logging])
  78 fi
  79
  80 AC_ARG_ENABLE([debug-log], [AS_HELP_STRING([--enable-debug-log],
  81         [enable debug logging (default n)])],
  82         [debug_log_enabled=$enableval],
  83         [debug_log_enabled='no'])
  84 if test "x$debug_log_enabled" != "xno"; then
  85         AC_DEFINE([ENABLE_DEBUG_LOGGING], 1, [Debug message logging])
  86 fi
  87
  88 # Examples build
  89 AC_ARG_ENABLE([examples-build], [AS_HELP_STRING([--enable-examples-build],
  90         [build example applications (default n)])],
  91         [build_examples=$enableval],
  92         [build_examples='no'])
  93 AM_CONDITIONAL([BUILD_EXAMPLES], [test "x$build_examples" != "xno"])
  94
  95 # Restore gnu89 inline semantics on gcc 4.3 and newer
  96 saved_cflags="$CFLAGS"
  97 CFLAGS="$CFLAGS -fgnu89-inline"
  98 AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]), inline_cflags="-fgnu89-inline", inline_cflags="")
  99 CFLAGS="$saved_cflags"
 100
 101 # check for -fvisibility=hidden compiler support (GCC >= 3.4)
 102 saved_cflags="$CFLAGS"
 103 CFLAGS="$CFLAGS -fvisibility=hidden"
 104 AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]),
 105         [VISIBILITY_CFLAGS="-fvisibility=hidden"
 106          AC_DEFINE([API_EXPORTED], [__attribute__((visibility("default")))], [Default visibility]) ],
 107         [ VISIBILITY_CFLAGS=""
 108          AC_DEFINE([API_EXPORTED], [], [Default visibility]) ],
 109         ])
 110 CFLAGS="$saved_cflags"
 111
 112 # check for -Wno-pointer-sign compiler support (GCC >= 4)
 113 saved_cflags="$CFLAGS"
 114 CFLAGS="$CFLAGS -Wno-pointer-sign"
 115 AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]),
 116         nopointersign_cflags="-Wno-pointer-sign", nopointersign_cflags="")
 117 CFLAGS="$saved_cflags"
 118
 119 AM_CFLAGS="-std=gnu99 $inline_cflags -Wall -Wundef -Wunused -Wstrict-prototypes -Werror-implicit-function-declaration $nopointersign_cflags -Wshadow"
 120
 121 AC_SUBST(VISIBILITY_CFLAGS)
 122 AC_SUBST(AM_CFLAGS)
 123 AC_SUBST(AM_LDFLAGS)
 124
 125 AC_CONFIG_FILES([libusb-1.0.pc] [Makefile] [libusb/Makefile] [examples/Makefile] [doc/Makefile] [doc/doxygen.cfg])
 126 AC_OUTPUT
 127