configure.ac

   1 AC_PREREQ([2.68])
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/prerelease
   8 AC_INIT([GStreamer Base Plug-ins],[1.3.0.1],[http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer],[gst-plugins-base])
   9
  10 AG_GST_INIT
  11
  12 dnl initialize automake
  13 AM_INIT_AUTOMAKE([-Wno-portability 1.11 no-dist-gzip dist-xz tar-ustar subdir-objects])
  14
  15 dnl define PACKAGE_VERSION_* variables
  16 AS_VERSION
  17
  18 dnl check if this is a release version
  19 AS_NANO(GST_GIT="no", GST_GIT="yes")
  20
  21 dnl can autoconf find the source ?
  22 AC_CONFIG_SRCDIR([gst/audiotestsrc/gstaudiotestsrc.c])
  23
  24 dnl define the output header for config
  25 AC_CONFIG_HEADERS([config.h])
  26
  27 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  28 AM_MAINTAINER_MODE([enable])
  29
  30 dnl sets host_* variables
  31 AC_CANONICAL_HOST
  32
  33 dnl use pretty build output with automake >= 1.11
  34 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  35   [AM_DEFAULT_VERBOSITY=1
  36    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  37
  38 dnl our libraries and install dirs use GST_API_VERSION in the filename
  39 dnl to allow side-by-side installation of different API versions
  40 GST_API_VERSION=1.0
  41 AC_SUBST(GST_API_VERSION)
  42 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION",
  43   [GStreamer API Version])
  44
  45 dnl CURRENT, REVISION, AGE
  46 dnl - library source changed -> increment REVISION
  47 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  48 dnl - interfaces added -> increment AGE
  49 dnl - interfaces removed -> AGE = 0
  50 dnl
  51 dnl Keep CURRENT as MINOR * 100 + MICRO
  52 dnl Ex : 1.0.0 => 0
  53 dnl      1.0.3 => 3
  54 dnl      1.1.0 => 100
  55 dnl      1.2.5 => 205
  56 dnl      1.10.9 (who knows) => 1009
  57 dnl
  58 dnl sets GST_LT_LDFLAGS
  59 AS_LIBTOOL(GST, 300, 0, 300)
  60
  61 dnl *** required versions of GStreamer stuff ***
  62 GST_REQ=1.3.0.1
  63
  64 dnl *** autotools stuff ****
  65
  66 dnl allow for different autotools
  67 AS_AUTOTOOLS_ALTERNATE
  68
  69 dnl Add parameters for aclocal
  70 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  71
  72 dnl set up gettext
  73 dnl the version check needs to stay here because autopoint greps for it
  74 AM_GNU_GETTEXT_VERSION([0.17])
  75 AM_GNU_GETTEXT([external])
  76 AG_GST_GETTEXT([gst-plugins-base-$GST_API_VERSION])
  77
  78 dnl *** check for arguments to configure ***
  79
  80 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  81
  82 AG_GST_ARG_DEBUG
  83 AG_GST_ARG_PROFILING
  84 AG_GST_ARG_VALGRIND
  85 AG_GST_ARG_GCOV
  86
  87 AG_GST_ARG_EXAMPLES
  88
  89 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  90 AG_GST_ARG_WITH_PACKAGE_NAME
  91 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  92
  93 AG_GST_PKG_CONFIG_PATH
  94
  95 dnl let distro override plugin install helper path
  96 AC_ARG_WITH(install-plugins-helper,
  97   AS_HELP_STRING([--with-install-plugins-helper],[specify path of helper script to call to install plugins]),
  98   [
  99     case "${withval}" in
 100       yes) AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
 101       no)  AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
 102       *)   GST_INSTALL_PLUGINS_HELPER="${withval}" ;;
 103     esac
 104   ],
 105   [
 106     dnl Default value
 107     AS_AC_EXPAND(GST_INSTALL_PLUGINS_HELPER,${libexecdir}/gst-install-plugins-helper)
 108   ]
 109 )
 110 AC_MSG_NOTICE(Using $GST_INSTALL_PLUGINS_HELPER as plugin install helper)
 111 AC_DEFINE_UNQUOTED(GST_INSTALL_PLUGINS_HELPER, "$GST_INSTALL_PLUGINS_HELPER",
 112     [plugin install helper script])
 113 AC_SUBST(GST_INSTALL_PLUGINS_HELPER)
 114
 115 AG_GST_ARG_WITH_PLUGINS
 116
 117 AG_GST_ARG_ENABLE_EXTERNAL
 118
 119 AG_GST_ARG_ENABLE_EXPERIMENTAL
 120
 121 dnl *** checks for platform ***
 122 AG_GST_PLATFORM
 123
 124 dnl * hardware/architecture *
 125
 126 dnl common/m4/gst-arch.m4
 127 dnl check CPU type
 128 AG_GST_ARCH
 129
 130 dnl check for large file support
 131 dnl affected plugins must include config.h
 132 AC_SYS_LARGEFILE
 133
 134 dnl *** checks for programs ***
 135
 136 dnl find a compiler
 137 AC_PROG_CC
 138 AC_PROG_CC_STDC
 139
 140 dnl check if the compiler supports '-c' and '-o' options
 141 AM_PROG_CC_C_O
 142
 143 dnl determine if c++ is available on this system
 144 AC_PROG_CXX
 145 dnl CXX may be set to some default even if no c++ compiler is available
 146 dnl (thanks autotools!), so just try to compile some c++ code to make sure
 147 AC_LANG_PUSH([C++])
 148 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[ class Foo { int bar; };]], [[]])],[working_cxx=yes],[working_cxx=no])
 149 AC_LANG_POP([C++])
 150 AC_MSG_NOTICE([working c++ compiler found: $working_cxx])
 151 AM_CONDITIONAL(HAVE_CXX, test "x$working_cxx" = "xyes")
 152
 153 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 154 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 155
 156 dnl check for gobject-introspection
 157 GOBJECT_INTROSPECTION_CHECK([1.31.1])
 158
 159 dnl check for documentation tools
 160 GTK_DOC_CHECK([1.12])
 161 AG_GST_PLUGIN_DOCS([1.12])
 162
 163 dnl *** checks for libraries ***
 164
 165 dnl libm, for sin() etc.
 166 LT_LIB_M
 167 AC_SUBST(LIBM)
 168
 169 dnl *** checks for header files ***
 170
 171 dnl check if we have ANSI C header files
 172 AC_HEADER_STDC
 173
 174 dnl check for GCC specific SSE headers
 175 dnl these are used by the speex resampler code
 176 AC_CHECK_HEADERS([xmmintrin.h emmintrin.h])
 177
 178 dnl used in gst/tcp
 179 AC_CHECK_HEADERS([sys/socket.h],
 180   [HAVE_SYS_SOCKET_H="yes"], [HAVE_SYS_SOCKET_H="no"], [AC_INCLUDES_DEFAULT])
 181 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 182
 183 dnl used in gst-libs/gst/pbutils and associated unit test
 184 AC_CHECK_HEADERS([process.h sys/types.h sys/wait.h sys/stat.h], [], [], [AC_INCLUDES_DEFAULT])
 185
 186 dnl checks for ARM NEON support
 187 dnl this instruction set is used by the speex resampler code
 188 AC_MSG_CHECKING(for ARM NEON support in current arch/CFLAGS)
 189 AC_LINK_IFELSE([
 190 AC_LANG_PROGRAM([[
 191   #include <arm_neon.h>
 192   int32x4_t testfunc(int16_t *a, int16_t *b) {
 193       asm volatile ("vmull.s16 q0, d0, d0" : : : "q0");
 194       return vmull_s16(vld1_s16(a), vld1_s16(b));
 195   }
 196 ]])],
 197 [
 198   AC_DEFINE(HAVE_ARM_NEON,[],[ARM NEON support is enabled])
 199   AC_MSG_RESULT(yes)
 200 ],
 201 [
 202   AC_MSG_RESULT(no)
 203 ])
 204
 205 dnl also, Windows does not have long long
 206 AX_CREATE_STDINT_H
 207
 208 dnl *** checks for functions ***
 209 AC_CHECK_FUNCS([localtime_r gmtime_r])
 210
 211 dnl *** checks for math functions ***
 212 LIBS_SAVE=$LIBS
 213 LIBS="$LIBS $LIBM"
 214 AC_CHECK_FUNCS(log2)
 215 LIBS=$LIBS_SAVE
 216
 217 dnl *** checks for types/defines ***
 218
 219 dnl *** checks for structures ***
 220
 221 dnl *** checks for compiler characteristics ***
 222
 223 dnl *** checks for library functions ***
 224
 225 dnl check for fseeko()
 226 AC_FUNC_FSEEKO
 227
 228 dnl Check for fast float to int casting as defined in C99
 229 dnl used to be used in gst-libs/gst/floatcast/floatcast.h (FIXME: still needed?)
 230 save_libs=$LIBS
 231 LIBS="$LIBS $LIBM"
 232 AC_C99_FUNC_LRINT
 233 AC_C99_FUNC_LRINTF
 234 LIBS=$save_libs
 235
 236 dnl Check for a way to display the function name in debug output
 237 AG_GST_CHECK_FUNCTION
 238
 239 dnl *** checks for dependency libraries ***
 240
 241 dnl GLib
 242 GLIB_REQ=2.32
 243 AG_GST_GLIB_CHECK([$GLIB_REQ])
 244
 245 ORC_CHECK([0.4.18])
 246
 247 dnl checks for gstreamer
 248 dnl uninstalled is selected preferentially -- see pkg-config(1)
 249 AG_GST_CHECK_GST($GST_API_VERSION, [$GST_REQ], yes)
 250 AG_GST_CHECK_GST_BASE($GST_API_VERSION, [$GST_REQ], yes)
 251 AG_GST_CHECK_GST_CONTROLLER($GST_API_VERSION, [$GST_REQ], yes)
 252 AG_GST_CHECK_GST_CHECK($GST_API_VERSION, [$GST_REQ], no)
 253 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 254
 255 dnl Check for documentation xrefs
 256 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 257 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_API_VERSION`"
 258 AC_SUBST(GLIB_PREFIX)
 259 AC_SUBST(GST_PREFIX)
 260
 261 dnl GTK is optional and only used in examples
 262 HAVE_GTK=no
 263 HAVE_GTK_X11=no
 264 GTK_REQ=3.0.0
 265 if test "x$BUILD_EXAMPLES" = "xyes"; then
 266   PKG_CHECK_MODULES(GTK, gtk+-3.0 >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 267   dnl some examples need gtk+-x11
 268   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-3.0 >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 269   PKG_CHECK_MODULES(GTK_QUARTZ, gtk+-quartz-3.0 >= $GTK_REQ, HAVE_GTK_QUARTZ=yes, HAVE_GTK_QUARTZ=no)
 270   AC_SUBST(GTK_LIBS)
 271   AC_SUBST(GTK_CFLAGS)
 272 fi
 273 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 274 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 275 AM_CONDITIONAL(HAVE_GTK_QUARTZ, test "x$HAVE_GTK_QUARTZ" = "xyes")
 276
 277 dnl QT is optional and only used in examples
 278 PKG_CHECK_MODULES(QT, QtGui >= 4.6, [
 279   HAVE_QT_GV=yes
 280   HAVE_QT=yes
 281 ], [
 282   HAVE_QT_GV=no
 283   PKG_CHECK_MODULES(QT, QtGui >= 4.0, HAVE_QT=yes, HAVE_QT=no)
 284 ])
 285 if test "x$HAVE_QT" = "xyes"; then
 286   AC_MSG_CHECKING([Qt moc])
 287   QT4_MOC=`$PKG_CONFIG --variable=moc_location QtGui`
 288   AC_MSG_RESULT($QT4_MOC)
 289   AC_SUBST(QT4_MOC)
 290 fi
 291 AM_CONDITIONAL(HAVE_QT, test "x$HAVE_QT" = "xyes")
 292 AM_CONDITIONAL(HAVE_QT_GV, test "x$HAVE_QT_GV" = "xyes")
 293
 294 dnl chck for linux headers needed by the joystick seek example
 295 AC_COMPILE_IFELSE(
 296 [
 297   AC_LANG_PROGRAM([
 298     #include <linux/input.h>
 299     #include <linux/joystick.h>
 300   ],[
 301     struct js_event js;
 302     js.type = JS_EVENT_AXIS;
 303   ])
 304 ], [
 305   HAVE_LINUX_JOYSTICK_HEADERS="yes"
 306 ], [
 307   HAVE_LINUX_JOYSTICK_HEADERS="no"
 308 ])
 309 AM_CONDITIONAL(HAVE_LINUX_JOYSTICK_HEADERS, test "x$HAVE_LINUX_JOYSTICK_HEADERS" = "xyes")
 310
 311 dnl Check for -Bsymbolic-functions linker flag used to avoid
 312 dnl intra-library PLT jumps, if available.
 313 AC_ARG_ENABLE(Bsymbolic,
 314               [AS_HELP_STRING([--disable-Bsymbolic],[avoid linking with -Bsymbolic])],,
 315               [SAVED_LDFLAGS="${LDFLAGS}"
 316                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 317                LDFLAGS=-Wl,-Bsymbolic-functions
 318                AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int main (void) { return 0; }]])],[
 319                            AC_MSG_RESULT(yes)
 320                            enable_Bsymbolic=yes],[
 321                            AC_MSG_RESULT(no)
 322                            enable_Bsymbolic=no])
 323                LDFLAGS="${SAVED_LDFLAGS}"])
 324
 325
 326 dnl *** set variables based on configure arguments ***
 327
 328 dnl set license and copyright notice
 329 GST_LICENSE="LGPL"
 330 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 331 AC_SUBST(GST_LICENSE)
 332
 333 dnl set location of plugin directory
 334 AG_GST_SET_PLUGINDIR
 335
 336 dnl set release date/time
 337 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 338   ["${srcdir}/gst-plugins-base.doap"],
 339   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 340
 341 dnl build static plugins or not
 342 AC_MSG_CHECKING([whether to build static plugins or not])
 343 AC_ARG_ENABLE(
 344   static-plugins,
 345   AC_HELP_STRING(
 346     [--enable-static-plugins],
 347     [build static plugins @<:@default=no@:>@]),
 348   [AS_CASE(
 349     [$enableval], [no], [], [yes], [],
 350     [AC_MSG_ERROR([bad value "$enableval" for --enable-static-plugins])])],
 351   [enable_static_plugins=no])
 352 AC_MSG_RESULT([$enable_static_plugins])
 353 if test "x$enable_static_plugins" = xyes; then
 354   AC_DEFINE(GST_PLUGIN_BUILD_STATIC, 1,
 355     [Define if static plugins should be built])
 356   GST_PLUGIN_LIBTOOLFLAGS=""
 357 else
 358   GST_PLUGIN_LIBTOOLFLAGS="--tag=disable-static"
 359 fi
 360 AC_SUBST(GST_PLUGIN_LIBTOOLFLAGS)
 361 AM_CONDITIONAL(GST_PLUGIN_BUILD_STATIC, test "x$enable_static_plugins" = "xyes")
 362
 363 # set by AG_GST_PARSE_SUBSYSTEM_DISABLES above
 364 dnl make sure it doesn't complain about unused variables if debugging is disabled
 365 NO_WARNINGS=""
 366 AG_GST_CHECK_GST_DEBUG_DISABLED([NO_WARNINGS="-Wno-unused"], [NO_WARNINGS=""])
 367
 368 dnl define an ERROR_CFLAGS Makefile variable
 369 dnl -Wformat-nonliteral - see ext/pango/gstclockoverlay.c and http://gcc.gnu.org/bugzilla/show_bug.cgi?id=39438
 370 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [
 371     -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef
 372     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 373     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 374     -Wno-multichar -Wnested-externs $NO_WARNINGS])
 375
 376 dnl define an ERROR_CXXFLAGS Makefile variable
 377 AG_GST_SET_ERROR_CXXFLAGS($FATAL_WARNINGS, [
 378     -Wmissing-declarations -Wredundant-decls -Wundef
 379     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 380     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 381     -Wno-multichar $NO_WARNINGS])
 382
 383 dnl define correct level for debugging messages
 384 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 385
 386 dnl used in examples
 387 AG_GST_DEFAULT_ELEMENTS
 388
 389 dnl needed for encoding-target
 390 GST_DATADIR="$GST_PREFIX/share"
 391 AC_DEFINE_UNQUOTED(GST_DATADIR, "$GST_DATADIR", [system wide data directory])
 392 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION", [major/minor version])
 393
 394 dnl behaviour of speex based audio resampler
 395 AC_MSG_CHECKING(which audio resample format to use for integer)
 396 AC_ARG_WITH([audioresample_format],
 397         AS_HELP_STRING([--with-audioresample-format],[Which implementation should be used for integer audio resampling, int/float/auto, (default is auto)]),
 398         [ac_cv_audioresample_format=$withval], [ac_cv_audioresample_format=auto])dnl
 399 AC_MSG_RESULT($ac_cv_audioresample_format)
 400 case $ac_cv_audioresample_format in
 401   int)
 402     AC_DEFINE(AUDIORESAMPLE_FORMAT_INT,1,[The int implementation should be used for integer audio resampling])
 403     AC_SUBST(AUDIORESAMPLE_FORMAT_INT)
 404   ;;
 405   float)
 406     AC_DEFINE(AUDIORESAMPLE_FORMAT_FLOAT,1,[The float implementation should be used for integer audio resampling])
 407     AC_SUBST(AUDIORESAMPLE_FORMAT_FLOAT)
 408   ;;
 409   auto)
 410     AC_DEFINE(AUDIORESAMPLE_FORMAT_AUTO,1,[The implementation that should be used for integer audio resampling witll be benchmarked at runtime])
 411     AC_SUBST(AUDIORESAMPLE_FORMAT_AUTO)
 412 esac
 413
 414 dnl Check for mmap (needed by allocators library)
 415 AC_CHECK_FUNC([mmap], [AC_DEFINE(HAVE_MMAP, 1, [Defined if mmap is supported])])
 416
 417 dnl *** plug-ins to include ***
 418
 419 dnl these are all the gst plug-ins, compilable without additional libs
 420 AG_GST_CHECK_PLUGIN(adder)
 421 AG_GST_CHECK_PLUGIN(app)
 422 AG_GST_CHECK_PLUGIN(audioconvert)
 423 AG_GST_CHECK_PLUGIN(audiorate)
 424 AG_GST_CHECK_PLUGIN(audiotestsrc)
 425 AG_GST_CHECK_PLUGIN(encoding)
 426 AG_GST_CHECK_PLUGIN(videoconvert)
 427 AG_GST_CHECK_PLUGIN(gio)
 428 AG_GST_CHECK_PLUGIN(playback)
 429 AG_GST_CHECK_PLUGIN(audioresample)
 430 AG_GST_CHECK_PLUGIN(subparse)
 431 AG_GST_CHECK_PLUGIN(tcp)
 432 AG_GST_CHECK_PLUGIN(typefind)
 433 AG_GST_CHECK_PLUGIN(videotestsrc)
 434 AG_GST_CHECK_PLUGIN(videorate)
 435 AG_GST_CHECK_PLUGIN(videoscale)
 436 AG_GST_CHECK_PLUGIN(volume)
 437
 438 dnl iso-codes is optional, used by libgsttag
 439 AC_ARG_ENABLE(iso-codes,
 440 AS_HELP_STRING([--enable-iso-codes],[use iso-codes if installed]),
 441 [case "${enableval}" in
 442   yes) enable_iso_codes=yes ;;
 443   no)  enable_iso_codes=no ;;
 444   *) AC_MSG_ERROR(bad value ${enableval} for --enable-iso-codes) ;;
 445 esac
 446 ],
 447 [enable_iso_codes=yes]) dnl Default value
 448
 449 AC_MSG_CHECKING([whether to use iso-codes if they are available])
 450 if test "x$enable_iso_codes" = "xyes"; then
 451   AC_MSG_RESULT([yes])
 452   have_iso_codes=no
 453   AC_MSG_CHECKING([whether iso-codes are available on this system])
 454   if $PKG_CONFIG iso-codes; then
 455     AC_MSG_RESULT([yes])
 456     AC_MSG_CHECKING([whether iso-codes has iso-639 domain])
 457     if $PKG_CONFIG --variable=domains iso-codes | $GREP -q 639 ; then
 458       AC_MSG_RESULT([yes])
 459       AC_MSG_CHECKING([for iso-codes prefix])
 460       ISO_CODES_PREFIX=`$PKG_CONFIG --variable=prefix iso-codes`
 461       if test -d "$ISO_CODES_PREFIX"; then
 462         AC_MSG_RESULT([yes])
 463         AC_MSG_CHECKING([ISO_CODES_PREFIX])
 464         AC_MSG_RESULT([$ISO_CODES_PREFIX])
 465         ISO_639_DOMAIN="iso_639"
 466         AC_MSG_CHECKING([ISO_639_DOMAIN])
 467         AC_MSG_RESULT([$ISO_639_DOMAIN])
 468         have_iso_codes=yes
 469         AC_DEFINE([HAVE_ISO_CODES], [1], [make use of iso-codes for ISO-639])
 470         AC_DEFINE_UNQUOTED([ISO_CODES_PREFIX], ["$ISO_CODES_PREFIX"], [prefix])
 471         ISO_CODES_VERSION=`$PKG_CONFIG --modversion iso-codes`
 472         AC_DEFINE_UNQUOTED([ISO_CODES_VERSION], ["$ISO_CODES_VERSION"], [ ])
 473       else
 474         AC_MSG_RESULT([no])
 475       fi
 476     else
 477       AC_MSG_RESULT([no])
 478     fi
 479   else
 480     AC_MSG_RESULT([no])
 481   fi
 482   AM_CONDITIONAL(USE_ISO_CODES, test "x$have_iso_codes" = "xyes")
 483 else
 484   AC_MSG_RESULT([no (disabled via --disable-iso-codes)])
 485   AM_CONDITIONAL(USE_ISO_CODES, false)
 486 fi
 487
 488 dnl *** zlib is optionally used by id3 tag parsing in libgsttag ***
 489 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 490 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for ID3 parsing in libgsttag],, [
 491   PKG_CHECK_MODULES(ZLIB, [ zlib ], [
 492       HAVE_ZLIB="yes"
 493     ], [
 494       AG_GST_CHECK_LIBHEADER(ZLIB, z, uncompress,, zlib.h, [
 495         HAVE_ZLIB="yes"
 496         ZLIB_LIBS="-lz"
 497         AC_SUBST(ZLIB_LIBS)
 498       ])
 499     ])
 500 ])
 501
 502 dnl *** sys plug-ins ***
 503
 504 echo
 505 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 506 echo
 507
 508 dnl *** X11 ***
 509 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 510 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 511                   [ximagesink], [
 512   AC_PATH_XTRA
 513   ac_cflags_save="$CFLAGS"
 514   ac_cppflags_save="$CPPFLAGS"
 515   CFLAGS="$CFLAGS $X_CFLAGS"
 516   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 517
 518   dnl now try to find the HEADER
 519   AC_CHECK_HEADER([X11/Xlib.h], [HAVE_X="yes"], [HAVE_X="no"], [AC_INCLUDES_DEFAULT])
 520
 521   if test "x$HAVE_X" = "xno"
 522   then
 523     AC_MSG_NOTICE([cannot find X11 development files])
 524   else
 525     dnl this is much more than we want
 526     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 527     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 528     dnl it does not add the libs; therefore we add them here
 529     X_LIBS="$X_LIBS -lX11"
 530     AC_SUBST(X_CFLAGS)
 531     AC_SUBST(X_LIBS)
 532   fi
 533   AC_SUBST(HAVE_X)
 534   CFLAGS="$ac_cflags_save"
 535   CPPFLAGS="$ac_cppflags_save"
 536 ])
 537
 538 dnl Check for Xv extension
 539 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 540 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 541                   [xvimagesink], [
 542   AG_GST_CHECK_XV
 543 ])
 544
 545 dnl check for X Shm
 546 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 547 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 548   if test x$HAVE_X = xyes; then
 549     AC_CHECK_LIB(Xext, XShmAttach,
 550                  HAVE_XSHM="yes", HAVE_XSHM="no",
 551                  $X_LIBS)
 552     if test "x$HAVE_XSHM" = "xyes"; then
 553       XSHM_LIBS="-lXext"
 554     else
 555       dnl On AIX, it is in XextSam instead, but we still need -lXext
 556       AC_CHECK_LIB(XextSam, XShmAttach,
 557                    HAVE_XSHM="yes", HAVE_XSHM="no",
 558                    $X_LIBS)
 559       if test "x$HAVE_XSHM" = "xyes"; then
 560         XSHM_LIBS="-lXext -lXextSam"
 561       fi
 562     fi
 563   fi
 564 ], , [
 565   AC_SUBST(HAVE_XSHM)
 566   AC_SUBST(XSHM_LIBS)
 567 ])
 568
 569 dnl *** ext plug-ins ***
 570 dnl keep this list sorted alphabetically !
 571
 572 if test "x$BUILD_EXTERNAL" = "xyes"; then
 573
 574 echo
 575 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 576 echo
 577
 578 dnl *** alsa ***
 579 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 580 AG_GST_CHECK_FEATURE(ALSA, [ALSA], alsa, [
 581   PKG_CHECK_MODULES(ALSA, alsa >= 0.9.1, [
 582     HAVE_ALSA="yes"
 583     AC_SUBST(ALSA_CFLAGS)
 584     AC_SUBST(ALSA_LIBS)
 585   ], [
 586     AM_PATH_ALSA(0.9.1, HAVE_ALSA="yes", HAVE_ALSA="no")
 587   ])
 588 ])
 589
 590 dnl *** CDParanoia ***
 591 dnl Note: upstream has a pkg-config file only in post-10.2 SVN so far
 592 translit(dnm, m, l) AM_CONDITIONAL(USE_CDPARANOIA, true)
 593 AG_GST_CHECK_FEATURE(CDPARANOIA, [CDParanoia], cdparanoia, [
 594   PKG_CHECK_MODULES(CDPARANOIA, cdparanoia-3 >= 10.2, [
 595     HAVE_CDPARANOIA="yes"
 596   ], [
 597     AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 598                         cdda_open, -lm,
 599                         cdda_interface.h,
 600                         CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 601                         HEADER_DIR="no"
 602                         FOUND_CDPARANOIA="yes")
 603     if test "x$FOUND_CDPARANOIA" != "xyes";
 604     then
 605       AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 606                           cdda_open, -lm,
 607                           cdda/cdda_interface.h,
 608                           CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 609                           HEADER_DIR="yes"
 610                           FOUND_CDPARANOIA="yes")
 611     fi
 612     if test "x$HEADER_DIR" = "xyes";
 613     then
 614       AC_DEFINE_UNQUOTED(CDPARANOIA_HEADERS_IN_DIR, ,
 615                          defined if cdda headers are in a cdda/ directory)
 616     fi
 617     if test "x$FOUND_CDPARANOIA" = "xyes";
 618     then
 619       AC_CHECK_LIB(cdda_paranoia,
 620                    paranoia_cachemodel_size,
 621                    : ,
 622                    HAVE_CDPARANOIA=no,
 623                  [-lcdda_interface])
 624     fi
 625
 626     AC_SUBST(CDPARANOIA_LIBS)
 627   ])
 628 ])
 629 dnl FIXME : add second check somehow if that is necessary
 630 dnl AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
 631 dnl AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
 632
 633 dnl *** ivorbis ***
 634 dnl AM_PATH_IVORBIS only takes two options
 635 translit(dnm, m, l) AM_CONDITIONAL(USE_IVORBIS, true)
 636 AG_GST_CHECK_FEATURE(IVORBIS, [integer vorbis plug-in], ivorbisdec, [
 637   AG_GST_PKG_CHECK_MODULES(IVORBIS, vorbisidec)
 638   if test $HAVE_IVORBIS = no
 639   then
 640     IVORBIS_LIBS=
 641     IVORBIS_CFLAGS=
 642     AC_CHECK_LIB(vorbisidec, vorbis_block_init,
 643       [IVORBIS_LIBS=-lvorbisidec
 644       HAVE_IVORBIS=yes
 645       case $host in
 646       arm-*-*)
 647         IVORBIS_CFLAGS="-D_ARM_ASSEM_ $IVORBIS_CFLAGS"
 648       esac
 649       ],
 650       HAVE_IVORBIS=no)
 651     AC_SUBST(IVORBIS_LIBS)
 652     AC_SUBST(IVORBIS_CFLAGS)
 653   else
 654     AC_CHECK_LIB(vorbisidec, vorbis_dsp_pcmout,
 655       AC_DEFINE([USE_TREMOLO],1, "Define if building for android"),
 656       USE_TREMOLO=no)
 657   fi
 658 ])
 659
 660 dnl *** libvisual ***
 661 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBVISUAL, true)
 662 AG_GST_CHECK_FEATURE(LIBVISUAL, [libvisual visualization library], libvisual, [
 663   AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual-0.4 >= 0.4.0)
 664   if test $HAVE_LIBVISUAL = no
 665   then
 666     AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual = 0.2.0)
 667     if test x$HAVE_LIBVISUAL = xyes; then
 668       LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.2`"
 669     fi
 670   else
 671     if test x$HAVE_LIBVISUAL = xyes; then
 672       LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.4`"
 673     fi
 674   fi
 675   AC_MSG_NOTICE([libvisual pluginsdir: $LIBVIS_PLUGINSDIR])
 676   if test x$LIBVIS_PLUGINSDIR != x; then
 677     AC_DEFINE_UNQUOTED(LIBVISUAL_PLUGINSBASEDIR,
 678         "$LIBVIS_PLUGINSDIR",
 679         [directory in which the detected libvisual's plugins are located])
 680   fi
 681 ])
 682
 683 dnl *** ogg ***
 684 translit(dnm, m, l) AM_CONDITIONAL(USE_OGG, true)
 685 AG_GST_CHECK_FEATURE(OGG, [Xiph Ogg library], ogg, [
 686   AG_GST_PKG_CHECK_MODULES(OGG, ogg >= 1.0)
 687 ])
 688
 689 dnl *** pango ***
 690 translit(dnm, m, l) AM_CONDITIONAL(USE_PANGO, true)
 691 AG_GST_CHECK_FEATURE(PANGO, [Pango font rendering], pango, [
 692   AG_GST_PKG_CHECK_MODULES(PANGO, pango >= 1.22.0  pangocairo >= 1.22.0)
 693 ])
 694
 695 dnl *** theora ***
 696 translit(dnm, m, l) AM_CONDITIONAL(USE_THEORA, true)
 697 AG_GST_CHECK_FEATURE(THEORA, [Xiph Theora video codec], theora, [
 698   AG_GST_PKG_CHECK_MODULES(THEORA, theoradec >= 1.1 theoraenc >= 1.1)
 699 ])
 700
 701 dnl *** vorbis ***
 702 translit(dnm, m, l) AM_CONDITIONAL(USE_VORBIS, true)
 703 AG_GST_CHECK_FEATURE(VORBIS, [Xiph Vorbis audio codec], vorbis, [
 704   AG_GST_PKG_CHECK_MODULES(VORBIS, vorbis >= 1.0 vorbisenc >= 1.0)
 705 ])
 706
 707 if test "x$HAVE_VORBIS" = "xyes"; then
 708   ac_cflags_save="$CFLAGS"
 709   AC_COMPILE_IFELSE([
 710     AC_LANG_PROGRAM([[
 711 #include <vorbis/codec.h>
 712                      ]],[[
 713 vorbis_dsp_state *v;
 714
 715 vorbis_synthesis_restart (v);
 716                      ]])], HAVE_VSR=yes, HAVE_VSR=no)
 717   if test "x$HAVE_VSR" = "xyes"; then
 718     AC_DEFINE_UNQUOTED(HAVE_VORBIS_SYNTHESIS_RESTART, 1,
 719                        [defined if vorbis_synthesis_restart is present])
 720   fi
 721   CFLAGS="$ac_cflags_save"
 722 fi
 723
 724 else
 725
 726 dnl not building plugins with external dependencies,
 727 dnl but we still need to set the conditionals
 728 AM_CONDITIONAL(USE_ALSA, false)
 729 AM_CONDITIONAL(USE_CDPARANOIA, false)
 730 AM_CONDITIONAL(USE_IVORBIS, false)
 731 AM_CONDITIONAL(USE_LIBVISUAL, false)
 732 AM_CONDITIONAL(USE_OGG, false)
 733 AM_CONDITIONAL(USE_PANGO, false)
 734 AM_CONDITIONAL(USE_THEORA, false)
 735 AM_CONDITIONAL(USE_VORBIS, false)
 736
 737 fi dnl of EXT plugins
 738
 739 dnl seeking needs freetype, so check for it here
 740 PKG_CHECK_MODULES(FT2, freetype2 >= 2.0.9, HAVE_FT2="yes", [
 741   AC_CHECK_FT2(2.0.9, HAVE_FT2="yes", HAVE_FT2="no")
 742 ])
 743 dnl make the HAVE_FT2 variable available to automake and Makefile.am
 744 AM_CONDITIONAL(HAVE_FT2, test "x$HAVE_FT2" = "xyes")
 745 AC_SUBST(FT2_CFLAGS)
 746 AC_SUBST(FT2_LIBS)
 747
 748 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 749
 750 dnl Overview:
 751 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 752 dnl GST_*:              flags shared by built objects to link against GStreamer
 753 dnl GST_PLUGINS_BASE_CFLAGS: to link internally against the plugins base libs
 754 dnl                          (compare to other modules) or for i18n
 755 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 756 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 757 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 758 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 759
 760 dnl GST_OPTION_CFLAGS
 761 if test "x$USE_DEBUG" = xyes; then
 762    PROFILE_CFLAGS="-g"
 763 fi
 764 AC_SUBST(PROFILE_CFLAGS)
 765
 766 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 767   dnl Define _only_ when compiling a git version (not pre-releases or releases)
 768   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 769 else
 770   DEPRECATED_CFLAGS=""
 771 fi
 772 AC_SUBST(DEPRECATED_CFLAGS)
 773
 774 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
 775 dnl at make time with e.g. make ERROR_CFLAGS=""
 776 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 777 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 778 AC_SUBST(GST_OPTION_CFLAGS)
 779 AC_SUBST(GST_OPTION_CXXFLAGS)
 780
 781 dnl our libraries need to be versioned correctly
 782 AC_SUBST(GST_LT_LDFLAGS)
 783
 784 dnl GST_PLUGINS_BASE_CFLAGS
 785 dnl prefer internal headers to already installed ones
 786 dnl also add builddir include for enumtypes and marshal
 787 GST_PLUGINS_BASE_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs"
 788 AC_SUBST(GST_PLUGINS_BASE_CFLAGS)
 789
 790 dnl FIXME: do we want to rename to GST_ALL_* ?
 791 dnl add GST_OPTION_CFLAGS, but overridable
 792 GST_CFLAGS="$GST_CFLAGS"
 793 GST_CXXFLAGS="$GLIB_CFLAGS $GST_CFLAGS \$(GLIB_EXTRA_CFLAGS) \$(GST_OPTION_CXXFLAGS)"
 794 GST_CFLAGS="$GLIB_CFLAGS $GST_CFLAGS \$(GLIB_EXTRA_CFLAGS) \$(GST_OPTION_CFLAGS)"
 795 AC_SUBST(GST_CFLAGS)
 796 AC_SUBST(GST_CXXFLAGS)
 797 dnl add GCOV libs because libtool strips -fprofile-arcs -ftest-coverage
 798 GST_LIBS="$GST_LIBS \$(GCOV_LIBS)"
 799 AC_SUBST(GST_LIBS)
 800
 801 dnl LDFLAGS really should only contain flags, not libs - they get added before
 802 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 803 GST_ALL_LDFLAGS="-no-undefined"
 804 if test "x${enable_Bsymbolic}" = "xyes"; then
 805   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
 806 fi
 807 AC_SUBST(GST_ALL_LDFLAGS)
 808
 809 dnl GST_LIB_LDFLAGS
 810 dnl linker flags shared by all libraries
 811 dnl LDFLAGS modifier defining exported symbols from built libraries
 812 dnl (export _gst_foo but not __gst_foo)
 813 GST_LIB_LDFLAGS="-export-symbols-regex ^_?\(gst_\|Gst\|GST_\).*"
 814 AC_SUBST(GST_LIB_LDFLAGS)
 815
 816 dnl this really should only contain flags, not libs - they get added before
 817 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 818 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_.*' $GST_ALL_LDFLAGS"
 819 AC_SUBST(GST_PLUGIN_LDFLAGS)
 820
 821 dnl *** output files ***
 822
 823 $MKDIR_P tests/check/orc
 824
 825 AC_CONFIG_FILES(
 826 Makefile
 827 gst-plugins-base.spec
 828 gst/Makefile
 829 gst/adder/Makefile
 830 gst/app/Makefile
 831 gst/audioconvert/Makefile
 832 gst/audiorate/Makefile
 833 gst/audiotestsrc/Makefile
 834 gst/encoding/Makefile
 835 gst/videoconvert/Makefile
 836 gst/gio/Makefile
 837 gst/playback/Makefile
 838 gst/audioresample/Makefile
 839 gst/subparse/Makefile
 840 gst/tcp/Makefile
 841 gst/typefind/Makefile
 842 gst/videotestsrc/Makefile
 843 gst/videorate/Makefile
 844 gst/videoscale/Makefile
 845 gst/volume/Makefile
 846 sys/Makefile
 847 sys/ximage/Makefile
 848 sys/xvimage/Makefile
 849 ext/Makefile
 850 ext/alsa/Makefile
 851 ext/cdparanoia/Makefile
 852 ext/libvisual/Makefile
 853 ext/ogg/Makefile
 854 ext/pango/Makefile
 855 ext/theora/Makefile
 856 ext/vorbis/Makefile
 857 gst-libs/Makefile
 858 gst-libs/gst/Makefile
 859 gst-libs/gst/allocators/Makefile
 860 gst-libs/gst/audio/Makefile
 861 gst-libs/gst/app/Makefile
 862 gst-libs/gst/fft/Makefile
 863 gst-libs/gst/riff/Makefile
 864 gst-libs/gst/rtp/Makefile
 865 gst-libs/gst/rtsp/Makefile
 866 gst-libs/gst/sdp/Makefile
 867 gst-libs/gst/tag/Makefile
 868 gst-libs/gst/pbutils/Makefile
 869 gst-libs/gst/pbutils/gstpluginsbaseversion.h
 870 gst-libs/gst/video/Makefile
 871 tools/Makefile
 872 pkgconfig/Makefile
 873 pkgconfig/gstreamer-allocators.pc
 874 pkgconfig/gstreamer-allocators-uninstalled.pc
 875 pkgconfig/gstreamer-audio.pc
 876 pkgconfig/gstreamer-audio-uninstalled.pc
 877 pkgconfig/gstreamer-app.pc
 878 pkgconfig/gstreamer-app-uninstalled.pc
 879 pkgconfig/gstreamer-fft.pc
 880 pkgconfig/gstreamer-fft-uninstalled.pc
 881 pkgconfig/gstreamer-pbutils.pc
 882 pkgconfig/gstreamer-pbutils-uninstalled.pc
 883 pkgconfig/gstreamer-riff.pc
 884 pkgconfig/gstreamer-riff-uninstalled.pc
 885 pkgconfig/gstreamer-rtp.pc
 886 pkgconfig/gstreamer-rtp-uninstalled.pc
 887 pkgconfig/gstreamer-rtsp.pc
 888 pkgconfig/gstreamer-rtsp-uninstalled.pc
 889 pkgconfig/gstreamer-sdp.pc
 890 pkgconfig/gstreamer-sdp-uninstalled.pc
 891 pkgconfig/gstreamer-tag.pc
 892 pkgconfig/gstreamer-tag-uninstalled.pc
 893 pkgconfig/gstreamer-video.pc
 894 pkgconfig/gstreamer-video-uninstalled.pc
 895 pkgconfig/gstreamer-plugins-base.pc
 896 pkgconfig/gstreamer-plugins-base-uninstalled.pc
 897 tests/Makefile
 898 tests/check/Makefile
 899 tests/examples/Makefile
 900 tests/examples/app/Makefile
 901 tests/examples/audio/Makefile
 902 tests/examples/dynamic/Makefile
 903 tests/examples/encoding/Makefile
 904 tests/examples/fft/Makefile
 905 tests/examples/gio/Makefile
 906 tests/examples/overlay/Makefile
 907 tests/examples/seek/Makefile
 908 tests/examples/snapshot/Makefile
 909 tests/examples/playback/Makefile
 910 tests/examples/playrec/Makefile
 911 tests/files/Makefile
 912 tests/icles/Makefile
 913 tests/icles/playback/Makefile
 914 docs/Makefile
 915 docs/design/Makefile
 916 docs/libs/Makefile
 917 docs/plugins/Makefile
 918 docs/version.entities
 919 po/Makefile.in
 920 common/Makefile
 921 common/m4/Makefile
 922 m4/Makefile
 923 )
 924
 925 dnl Create the config.h file for Visual Studio builds
 926 dnl Beware of spaces and /'s in some of the shell variable contents.
 927 sed \
 928     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"/' \
 929     -e 's/.* GST_INSTALL_PLUGINS_HELPER/#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
 930     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
 931     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
 932     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
 933     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
 934     -e 's/.* GST_API_VERSION$/#define GST_API_VERSION "'$GST_API_VERSION'"/' \
 935     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
 936     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
 937     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
 938     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
 939     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
 940     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
 941     -e 's/.* HAVE_ISO_CODES$/#undef HAVE_ISO_CODES/' \
 942     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
 943     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
 944     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
 945     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
 946     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
 947     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
 948     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
 949     -e 's/.* ISO_CODES_PREFIX$/#undef ISO_CODES_PREFIX/' \
 950     -e 's/.* ISO_CODES_VERSION$/#undef ISO_CODES_VERSION/' \
 951     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
 952     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
 953     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
 954     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
 955     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
 956     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
 957     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
 958     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
 959     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.11"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.11"\n#endif/' \
 960     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
 961     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
 962     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directsoundsink\"/" \
 963     -e "s/.* DEFAULT_VIDEOSINK$/#define DEFAULT_VIDEOSINK \"directdrawsink\"/" \
 964     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
 965     config.h.in >win32/common/config.h-new
 966
 967
 968
 969 AC_OUTPUT
 970
 971 AG_GST_OUTPUT_PLUGINS
 972 ORC_OUTPUT
 973