configure.ac

   1 # gstreamer-vaapi package version number
   2 m4_define([gst_vaapi_major_version], [0])
   3 m4_define([gst_vaapi_minor_version], [3])
   4 m4_define([gst_vaapi_micro_version], [8])
   5 m4_define([gst_vaapi_pre_version],   [1])
   6 m4_define([gst_vaapi_version],
   7           [gst_vaapi_major_version.gst_vaapi_minor_version.gst_vaapi_micro_version])
   8 m4_if(gst_vaapi_pre_version, [0], [], [
   9 m4_append([gst_vaapi_version], gst_vaapi_pre_version, [.pre])
  10 ])
  11
  12 # glib version number
  13 m4_define([glib_major_version], [2])
  14 m4_define([glib_minor_version], [4])
  15 m4_define([glib_micro_version], [0])
  16 m4_define([glib_major_minor_version],
  17           [glib_major_version.glib_minor_version])
  18 m4_define([glib_version],
  19           [glib_major_version.glib_minor_version.glib_micro_version])
  20
  21 # gst version number
  22 m4_define([gst_major_version], [0])
  23 m4_define([gst_minor_version], [10])
  24 m4_define([gst_micro_version], [14])
  25 m4_define([gst_major_minor_version],
  26           [gst_major_version.gst_minor_version])
  27 m4_define([gst_version],
  28           [gst_major_version.gst_minor_version.gst_micro_version])
  29
  30 # gst plugins-base version number
  31 m4_define([gst_plugins_base_major_version], [0])
  32 m4_define([gst_plugins_base_minor_version], [10])
  33 m4_define([gst_plugins_base_micro_version], [31])
  34 m4_define([gst_plugins_base_version],
  35           [gst_plugins_base_major_version.gst_plugins_base_minor_version.gst_plugins_base_micro_version])
  36
  37 # VA-API minimum version number
  38 m4_define([va_api_x11_version], [0.31.0])
  39 m4_define([va_api_glx_version], [0.32.0])
  40
  41 # gst plugins-bad version number
  42 m4_define([gst_plugins_bad_major_version], [0])
  43 m4_define([gst_plugins_bad_minor_version], [10])
  44 m4_define([gst_plugins_bad_micro_version], [22])
  45 m4_define([gst_plugins_bad_version],
  46           [gst_plugins_bad_major_version.gst_plugins_bad_minor_version.gst_plugins_bad_micro_version])
  47
  48 # libva package version number
  49 m4_define([libva_x11_package_version], [1.0.3])
  50 m4_define([libva_glx_package_version], [1.0.9])
  51
  52 # gtk-doc version number
  53 # XXX: introspection annotations require gtk-doc >= 1.12
  54 m4_define([gtkdoc_major_version], [1])
  55 m4_define([gtkdoc_minor_version], [9])
  56 m4_define([gtkdoc_version], [gtkdoc_major_version.gtkdoc_minor_version])
  57
  58 AC_PREREQ([2.57])
  59 AC_INIT([gst_vaapi], [gst_vaapi_version],
  60     [gwenole.beauchesne@intel.com],
  61     [gstreamer-vaapi])
  62 AC_CONFIG_SRCDIR([Makefile.am])
  63 AC_CANONICAL_TARGET
  64 AM_INIT_AUTOMAKE
  65 AM_CONFIG_HEADER([config.h])
  66
  67 TODAY="`LC_ALL=C date +'%a, %d %b %Y %X %z'`"
  68 AC_SUBST(TODAY)
  69
  70 GST_VAAPI_MAJOR_VERSION=gst_vaapi_major_version
  71 AC_SUBST(GST_VAAPI_MAJOR_VERSION)
  72
  73 LIBVA_PACKAGE_VERSION=libva_x11_package_version
  74 AC_SUBST(LIBVA_PACKAGE_VERSION)
  75
  76 dnl Versions for GStreamer and plugins-base
  77 GST_MAJORMINOR=gst_major_minor_version
  78 GST_VERSION_REQUIRED=gst_version
  79 GST_PLUGINS_BASE_VERSION_REQUIRED=gst_plugins_base_version
  80 GST_PLUGINS_BAD_VERSION_REQUIRED=gst_plugins_bad_version
  81 AC_SUBST(GST_MAJORMINOR)
  82 AC_SUBST(GST_VERSION_REQUIRED)
  83 AC_SUBST(GST_PLUGINS_BASE_VERSION_REQUIRED)
  84
  85 dnl Use pretty build output with automake >= 1.11
  86 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])], [
  87   AM_DEFAULT_VERBOSITY=1
  88   AC_SUBST(AM_DEFAULT_VERBOSITY)
  89 ])
  90
  91 dnl Check for tools
  92 AC_PROG_CC
  93 AM_PROG_CC_C_O
  94 AC_PROG_LIBTOOL
  95
  96 AC_ARG_ENABLE(glx,
  97     AC_HELP_STRING([--enable-glx],
  98                    [enable OpenGL/X11 @<:@default=yes@:>@]),
  99     [], [enable_glx="yes"])
 100
 101 AC_ARG_ENABLE(vaapi-glx,
 102     AC_HELP_STRING([--enable-vaapi-glx],
 103                    [enable VA/GLX extensions @<:@default=yes@:>@]),
 104     [], [enable_vaapi_glx="yes"])
 105
 106 AC_ARG_ENABLE(vaapisink-glx,
 107     AC_HELP_STRING([--enable-vaapisink-glx],
 108                    [enable OpenGL/X11 to vaapisink @<:@default=yes@:>@]),
 109     [], [enable_vaapisink_glx="no"])
 110
 111 AC_ARG_ENABLE(ffmpeg,
 112     AC_HELP_STRING([--enable-ffmpeg],
 113                    [enable bitstream parsing from FFmpeg @<:@default=no@:>@]),
 114     [], [enable_ffmpeg="no"])
 115
 116 AC_ARG_ENABLE(codecparsers,
 117     AC_HELP_STRING([--enable-codecparsers],
 118                    [enable adhoc bitstream parsers from GStreamer @<:@default=yes@:>@]),
 119     [], [enable_codecparsers="yes"])
 120
 121 dnl Check for __attribute__((visibility()))
 122 AC_CACHE_CHECK([whether __attribute__((visibility())) is supported],
 123   vaapi_cv_visibility_attribute,
 124   [cat > conftest.c <<EOF
 125 int foo __attribute__ ((visibility ("hidden"))) = 1;
 126 int bar __attribute__ ((visibility ("protected"))) = 1;
 127 EOF
 128   vaapi_cv_visibility_attribute=no
 129   if ${CC-cc} -Werror -S conftest.c -o conftest.s >/dev/null 2>&1; then
 130     if grep '\.hidden.*foo' conftest.s >/dev/null; then
 131       if grep '\.protected.*bar' conftest.s >/dev/null; then
 132         vaapi_cv_visibility_attribute=yes
 133       fi
 134     fi
 135   fi
 136   rm -f conftest.[cs]
 137 ])
 138 if test $vaapi_cv_visibility_attribute = yes; then
 139   vaapi_cv_visibility_attribute_hidden="__attribute__((visibility(\"hidden\")))"
 140 else
 141   vaapi_cv_visibility_attribute_hidden=""
 142 fi
 143 AC_DEFINE_UNQUOTED([attribute_hidden],
 144                    [$vaapi_cv_visibility_attribute_hidden],
 145                    [Define the "hidden" visibility attribute])
 146
 147 dnl Check for basic libraries
 148 AC_CHECK_LIB(m, tan)
 149
 150 dnl Check for Gtk doc
 151 GTKDOC_VERSION=gtkdoc_version
 152 GTK_DOC_CHECK([$GTKDOC_VERSION])
 153 AM_CONDITIONAL([BUILD_GTK_DOC], [test "x$enable_gtk_doc" = "xyes"])
 154 AC_SUBST(GTKDOC_VERSION)
 155
 156 dnl Check for GLib
 157 AC_PATH_PROG([GLIB_GENMARSHAL], [glib-genmarshal])
 158 PKG_CHECK_MODULES([GLIB], [glib-2.0 >= glib_version])
 159 AC_CHECK_LIB([glib-2.0], [g_list_free_full], [
 160     AC_DEFINE([HAVE_G_LIST_FREE_FULL], [1],
 161               [Define to 1 if g_list_free_full() is available.])])
 162
 163 dnl Check for GStreamer
 164 PKG_CHECK_MODULES([GST],
 165     [gstreamer-$GST_MAJORMINOR >= $GST_VERSION_REQUIRED]
 166 )
 167
 168 AC_CACHE_CHECK([for GstBaseSink::query hook], ac_cv_have_gst_base_sink_query, [
 169     saved_CFLAGS="$CFLAGS"
 170     CFLAGS="$CFLAGS $GST_CFLAGS"
 171     saved_LIBS="$LIBS"
 172     LIBS="$LIBS $GST_LIBS"
 173     AC_TRY_COMPILE(
 174         [#include <gst/base/gstbasesink.h>],
 175         [GstBaseSinkClass klass; klass.query = NULL;],
 176         [ac_cv_have_gst_base_sink_query="yes"],
 177         [ac_cv_have_gst_base_sink_query="no"]
 178     )
 179     CFLAGS="$saved_CFLAGS"
 180     LIBS="$saved_LIBS"
 181 ])
 182 if test "$ac_cv_have_gst_base_sink_query" != "yes"; then
 183     AC_MSG_ERROR([GstBaseSink does not contain the 'query' vfunc])
 184 fi
 185
 186 dnl Check for GStreamer plugins-base
 187 PKG_CHECK_MODULES([GST_PLUGINS_BASE],
 188     [gstreamer-plugins-base-$GST_MAJORMINOR >= $GST_PLUGINS_BASE_VERSION_REQUIRED]
 189 )
 190
 191 V=`$PKG_CONFIG --modversion gstreamer-plugins-base-$GST_MAJORMINOR`
 192 GST_PLUGINS_BASE_MAJOR_VERSION=`echo "$V" | cut -d'.' -f1`
 193 GST_PLUGINS_BASE_MINOR_VERSION=`echo "$V" | cut -d'.' -f2`
 194 GST_PLUGINS_BASE_MICRO_VERSION=`echo "$V" | cut -d'.' -f3`
 195 AC_SUBST(GST_PLUGINS_BASE_MAJOR_VERSION)
 196 AC_SUBST(GST_PLUGINS_BASE_MINOR_VERSION)
 197 AC_SUBST(GST_PLUGINS_BASE_MICRO_VERSION)
 198
 199 dnl Check for GStreamer base
 200 PKG_CHECK_MODULES([GST_BASE],
 201     [gstreamer-base-$GST_MAJORMINOR >= $GST_VERSION_REQUIRED]
 202 )
 203
 204 dnl Check for GStreamer video
 205 PKG_CHECK_MODULES([GST_VIDEO],
 206     [gstreamer-video-$GST_MAJORMINOR >= $GST_VERSION_REQUIRED]
 207 )
 208
 209 AC_CACHE_CHECK([for GstVideoOverlayComposition],
 210     ac_cv_have_gst_video_overlay_composition, [
 211     saved_CFLAGS="$CFLAGS"
 212     CFLAGS="$CFLAGS $GST_CFLAGS"
 213     saved_LIBS="$LIBS"
 214     LIBS="$LIBS $GST_LIBS"
 215     AC_TRY_COMPILE(
 216         [#include <gst/video/video-overlay-composition.h>],
 217         [GstVideoOverlayComposition *c = gst_video_overlay_composition_new(0);],
 218         [ac_cv_have_gst_video_overlay_composition="yes"],
 219         [ac_cv_have_gst_video_overlay_composition="no"]
 220     )
 221     CFLAGS="$saved_CFLAGS"
 222     LIBS="$saved_LIBS"
 223 ])
 224 if test "$ac_cv_have_gst_video_overlay_composition" != "yes"; then
 225     AC_MSG_ERROR([GstVideoOverlayComposition is not available])
 226 fi
 227
 228 dnl Check for GStreamer basevideo
 229 PKG_CHECK_MODULES([GST_BASEVIDEO],
 230     [gstreamer-basevideo-$GST_MAJORMINOR >= $GST_PLUGINS_BAD_VERSION_REQUIRED]
 231 )
 232
 233 dnl Check for GStreamer codec parsers
 234 USE_CODEC_PARSERS=0
 235 if test "$enable_codecparsers" = "yes"; then
 236 PKG_CHECK_MODULES([GST_CODEC_PARSERS],
 237     [gstreamer-codecparsers-$GST_MAJORMINOR >= $GST_VERSION_REQUIRED],
 238     [enable_codecparsers="yes" USE_CODEC_PARSERS=1],
 239     [enable_codecparsers="no"  USE_CODEC_PARSERS=0]
 240 )
 241 fi
 242
 243 AC_DEFINE_UNQUOTED(USE_CODEC_PARSERS, $USE_CODEC_PARSERS,
 244     [Defined to 1 if GStreamer codec parsers are used])
 245 AM_CONDITIONAL(USE_CODEC_PARSERS, test $USE_CODEC_PARSERS -eq 1)
 246
 247 USE_LOCAL_CODEC_PARSERS=0
 248 if test "$enable_codecparsers" = "yes"; then
 249 AC_CACHE_CHECK([for GstH264SliceHdr::n_emulation_prevention_bytes],
 250     ac_cv_have_gst_h264_slice_hdr_epb_count, [
 251     saved_CFLAGS="$CFLAGS"
 252     CFLAGS="$CFLAGS $GST_CFLAGS $GST_CODEC_PARSERS_CFLAGS"
 253     saved_LIBS="$LIBS"
 254     LIBS="$LIBS $GST_LIBS $GST_CODEC_PARSERS_LIBS"
 255     AC_TRY_COMPILE(
 256         [#include <gst/codecparsers/gsth264parser.h>],
 257         [GstH264SliceHdr slice_hdr;
 258          slice_hdr.n_emulation_prevention_bytes = 0;],
 259         [ac_cv_have_gst_h264_slice_hdr_epb_count="yes"],
 260         [ac_cv_have_gst_h264_slice_hdr_epb_count="no"]
 261     )
 262     CFLAGS="$saved_CFLAGS"
 263     LIBS="$saved_LIBS"
 264 ])
 265
 266 AC_CACHE_CHECK([for JPEG parser],
 267     ac_cv_have_gst_jpeg_parser, [
 268     saved_CFLAGS="$CFLAGS"
 269     CFLAGS="$CFLAGS $GST_CFLAGS $GST_CODEC_PARSERS_CFLAGS"
 270     saved_LIBS="$LIBS"
 271     LIBS="$LIBS $GST_LIBS $GST_CODEC_PARSERS_LIBS"
 272     AC_TRY_COMPILE(
 273         [#include <gst/codecparsers/gstjpegparser.h>],
 274         [GstJpegImage jpeg_image;],
 275         [ac_cv_have_gst_jpeg_parser="yes"],
 276         [ac_cv_have_gst_jpeg_parser="no" USE_LOCAL_CODEC_PARSERS=1]
 277     )
 278     CFLAGS="$saved_CFLAGS"
 279     LIBS="$saved_LIBS"
 280 ])
 281 fi
 282
 283 if test "$ac_cv_have_gst_h264_slice_hdr_epb_count" = "yes"; then
 284     AC_DEFINE_UNQUOTED(HAVE_GST_H264_SLICE_HDR_EPB_COUNT, 1,
 285         [Defined to 1 if GstH264SliceHdr::n_emulation_prevention_bytes exists.])
 286 fi
 287
 288 if test "$ac_cv_have_gst_jpeg_parser" = "yes"; then
 289     AC_DEFINE_UNQUOTED(HAVE_GST_JPEG_PARSER, 1,
 290         [Defined to 1 if JPEG parser exists.])
 291 fi
 292 AM_CONDITIONAL(USE_LOCAL_CODEC_PARSERS, test $USE_LOCAL_CODEC_PARSERS -eq 1)
 293
 294 dnl Check for GStreamer interfaces
 295 PKG_CHECK_MODULES([GST_INTERFACES],
 296     [gstreamer-interfaces-$GST_MAJORMINOR >= $GST_PLUGINS_BASE_VERSION_REQUIRED]
 297 )
 298
 299 dnl GST_ALL_LDFLAGS:
 300 dnl LDFLAGS really should only contain flags, not libs - they get added before
 301 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 302 GST_ALL_LDFLAGS="-no-undefined"
 303 AC_SUBST(GST_ALL_LDFLAGS)
 304
 305 dnl GST_PLUGIN_LDFLAGS:
 306 dnl this really should only contain flags, not libs - they get added before
 307 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 308 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^([_]*gst_plugin_desc|gst_.*_get_type)\$\$' $GST_ALL_LDFLAGS"
 309 AC_SUBST(GST_PLUGIN_LDFLAGS)
 310
 311 dnl Check for the GStreamer plugins directory
 312 AC_MSG_CHECKING([for GStreamer plugins directory])
 313 GST_PLUGINS_DIR=`$PKG_CONFIG gstreamer-$GST_MAJORMINOR --variable pluginsdir`
 314 if test -z "$GST_PLUGINS_DIR"; then
 315     echo "FAIL FAIL FAIL"
 316     GST_PLUGINS_DIR="\$(libdir)/gstreamer-$GST_MAJORMINOR"
 317 fi
 318 AC_MSG_RESULT([$GST_PLUGINS_DIR])
 319 plugindir="$GST_PLUGINS_DIR"
 320 AC_SUBST(plugindir)
 321
 322 dnl Check for X11
 323 PKG_CHECK_MODULES(X11, [x11])
 324
 325 dnl Check for OpenGL
 326 USE_GLX=1
 327 if test "$enable_glx" != "yes"; then
 328     USE_GLX=0
 329 fi
 330 GLX_CFLAGS=""
 331 GLX_LIBS=""
 332 AC_CHECK_HEADERS([GL/gl.h GL/glext.h GL/glx.h], [], [USE_GLX=0], [
 333 #ifdef HAVE_GL_GL_H
 334 # include <GL/gl.h>
 335 #endif
 336 ])
 337 AC_CHECK_LIB(GL, glXCreateContext, [GLX_LIBS="-lGL"], [USE_GLX=0])
 338 AC_SUBST(GLX_CFLAGS)
 339 AC_SUBST(GLX_LIBS)
 340
 341 dnl Check for VA-API
 342 LIBVA_PKGNAME="libva"
 343 PKG_CHECK_MODULES(LIBVA, [$LIBVA_PKGNAME])
 344 AC_SUBST(LIBVA_PKGNAME)
 345
 346 dnl ... original VA-API 0.29
 347 AC_CACHE_CHECK([for old VA-API 0.29],
 348     ac_cv_have_vaapi_old, [
 349     saved_CFLAGS="$CFLAGS"
 350     CFLAGS="$CFLAGS $LIBVA_CFLAGS"
 351     saved_LIBS="$LIBS"
 352     LIBS="$LIBS $LIBVA_LIBS"
 353     AC_TRY_LINK(
 354     [#include <va_x11.h>],
 355     [vaGetDisplay(NULL)],
 356     [ac_cv_have_vaapi_old="yes"],
 357     [ac_cv_have_vaapi_old="no"])
 358     CFLAGS="$saved_CFLAGS"
 359     LIBS="$saved_LIBS"
 360 ])
 361 if test "$ac_cv_have_vaapi_old" = "yes"; then
 362     LIBVA_EXTRA_CFLAGS="$LIBVA_CFLAGS -DGST_VAAPI_USE_OLD_VAAPI_0_29"
 363 fi
 364
 365 dnl ... VA-API >= 0.31 or -sds
 366 LIBVA_X11_PKGNAME="libva-x11"
 367 PKG_CHECK_MODULES(LIBVA_X11, [$LIBVA_X11_PKGNAME],
 368     [ac_cv_have_vaapi_x11="yes"],
 369     [ac_cv_have_vaapi_x11="no"]
 370 )
 371 if test "$ac_cv_have_vaapi_x11" = "no"; then
 372     if test "$ac_cv_have_vaapi_old" = "yes"; then
 373         LIBVA_X11_PKGNAME="libva"
 374         CFLAGS="$CFLAGS $LIBVA_EXTRA_CFLAGS"
 375         LIBS="$LIBS $LIBVA_EXTRA_LIBS"
 376     else
 377         AC_MSG_ERROR([could not find VA-API])
 378     fi
 379 fi
 380 AC_SUBST(LIBVA_X11_PKGNAME)
 381
 382 dnl ... VA-API >= 0.31 or -sds (VA/GLX extensions)
 383 USE_VAAPI_GLX=0
 384 if test $USE_GLX -eq 1; then
 385     if test "$enable_vaapi_glx" = "yes"; then
 386         LIBVA_GLX_PKGNAME="libva-glx"
 387         PKG_CHECK_MODULES(LIBVA_GLX, [$LIBVA_GLX_PKGNAME],
 388             [ac_cv_have_vaapi_glx="yes" USE_VAAPI_GLX=1],
 389             [ac_cv_have_vaapi_glx="no"]
 390         )
 391     fi
 392     if test $USE_VAAPI_GLX -eq 0; then
 393         AC_MSG_WARN([VA/GLX not found or disabled. Fallbacking to TFP+FBO])
 394         LIBVA_GLX_PKGNAME="$LIBVA_X11_PKGNAME"
 395     fi
 396 fi
 397 AC_SUBST(LIBVA_GLX_PKGNAME)
 398
 399 AC_SUBST(LIBVA_EXTRA_CFLAGS)
 400 AC_SUBST(LIBVA_EXTRA_LIBS)
 401
 402 dnl Check for JPEG decoding API (0.33+)
 403 USE_JPEG_DECODER=0
 404 if test "$enable_codecparsers" = "yes"; then
 405 AC_CACHE_CHECK([for JPEG decoding API],
 406     ac_cv_have_jpeg_decoding_api, [
 407     saved_CFLAGS="$CFLAGS"
 408     CFLAGS="$CFLAGS $LIBVA_CFLAGS"
 409     saved_LIBS="$LIBS"
 410     LIBS="$CFLAGS $LIBVA_LIBS"
 411     AC_TRY_COMPILE(
 412         [#include <va/va.h>
 413          #include <va/va_dec_jpeg.h>],
 414         [VAPictureParameterBufferJPEG pic_param;
 415          VASliceParameterBufferJPEG slice_param;
 416          VAHuffmanTableBufferJPEG huffman_table;
 417          VAIQMatrixBufferJPEG iq_matrix;],
 418         [ac_cv_have_jpeg_decoding_api="yes" USE_JPEG_DECODER=1],
 419         [ac_cv_have_jpeg_decoding_api="no"]
 420     )
 421     CFLAGS="$saved_CFLAGS"
 422     LIBS="$saved_LIBS"
 423 ])
 424 fi
 425
 426 AC_DEFINE_UNQUOTED(USE_JPEG_DECODER, $USE_JPEG_DECODER,
 427     [Defined to 1 if JPEG decoder is used])
 428 AM_CONDITIONAL(USE_JPEG_DECODER, test $USE_JPEG_DECODER -eq 1)
 429
 430 dnl Check for OpenGL support to vaapisink
 431 if test "$enable_vaapisink_glx:$USE_GLX" = "yes:1"; then
 432     USE_VAAPISINK_GLX=1
 433 else
 434     USE_VAAPISINK_GLX=0
 435 fi
 436
 437 dnl Check for FFmpeg
 438 USE_FFMPEG=0
 439 if test "$enable_ffmpeg" = "yes"; then
 440 PKG_CHECK_MODULES(LIBAVCODEC, [libavcodec],
 441     [enable_ffmpeg="yes" USE_FFMPEG=1],
 442     [enable_ffmpeg="no"  USE_FFMPEG=0]
 443 )
 444 fi
 445 if test "$enable_ffmpeg" = "yes"; then
 446 AC_CHECK_HEADERS([libavcodec/avcodec.h ffmpeg/avcodec.h])
 447 AC_CHECK_HEADERS([libavcodec/vaapi.h ffmpeg/vaapi.h],
 448     [break],
 449     [enable_ffmpeg="no"  USE_FFMPEG=0]
 450 )
 451 fi
 452
 453 if test "$enable_ffmpeg:$enable_codecparsers" = "no:no"; then
 454     AC_MSG_ERROR([Found neither suitable FFmpeg with VA-API support nor GStreamer bitstream parsers])
 455 fi
 456
 457 AC_DEFINE_UNQUOTED(USE_FFMPEG, $USE_FFMPEG,
 458     [Defined to 1 if FFmpeg is used])
 459 AM_CONDITIONAL(USE_FFMPEG, test $USE_FFMPEG -eq 1)
 460
 461 AC_DEFINE_UNQUOTED(USE_GLX, $USE_GLX,
 462     [Defined to 1 if GLX is enabled])
 463 AM_CONDITIONAL(USE_GLX, test $USE_GLX -eq 1)
 464
 465 AC_DEFINE_UNQUOTED(USE_VAAPI_GLX, $USE_VAAPI_GLX,
 466     [Defined to 1 if VA/GLX is enabled])
 467 AM_CONDITIONAL(USE_VAAPI_GLX, test $USE_VAAPI_GLX -eq 1)
 468
 469 AC_DEFINE_UNQUOTED(USE_VAAPISINK_GLX, $USE_VAAPISINK_GLX,
 470     [Defined to 1 to enable GLX support to vaapisink])
 471 AM_CONDITIONAL(USE_VAAPISINK_GLX, test $USE_VAAPISINK_GLX -eq 1)
 472
 473 VA_VERSION=`$PKG_CONFIG --modversion libva`
 474 VA_MAJOR_VERSION=`echo "$VA_VERSION" | cut -d'.' -f1`
 475 VA_MINOR_VERSION=`echo "$VA_VERSION" | cut -d'.' -f2`
 476 VA_MICRO_VERSION=`echo "$VA_VERSION" | cut -d'.' -f3`
 477 VA_VERSION_STR="$VA_VERSION"
 478
 479 pkgconfigdir=${libdir}/pkgconfig
 480 AC_SUBST(pkgconfigdir)
 481
 482 AC_OUTPUT([
 483     Makefile
 484     debian.upstream/Makefile
 485     debian.upstream/changelog
 486     debian.upstream/control
 487     debian.upstream/gstreamer$GST_MAJORMINOR-vaapi.install:\
 488 debian.upstream/gstreamer-vaapi.install.in
 489     debian.upstream/gstreamer$GST_MAJORMINOR-vaapi-doc.install:\
 490 debian.upstream/gstreamer-vaapi-doc.install.in
 491     debian.upstream/libgstvaapi$GST_VAAPI_MAJOR_VERSION.install:\
 492 debian.upstream/libgstvaapi.install.in
 493     debian.upstream/libgstvaapi-dev.install
 494     debian.upstream/libgstvaapi-x11-$GST_VAAPI_MAJOR_VERSION.install:\
 495 debian.upstream/libgstvaapi-x11.install.in
 496     debian.upstream/libgstvaapi-glx-$GST_VAAPI_MAJOR_VERSION.install:\
 497 debian.upstream/libgstvaapi-glx.install.in
 498     docs/Makefile
 499     docs/reference/Makefile
 500     docs/reference/libs/Makefile
 501     docs/reference/libs/libs-docs.xml
 502     docs/reference/plugins/Makefile
 503     docs/reference/plugins/plugins-docs.xml
 504     gst-libs/Makefile
 505     gst-libs/gst/Makefile
 506     gst-libs/gst/gstutils_version.h
 507     gst-libs/gst/codecparsers/Makefile
 508     gst-libs/gst/vaapi/Makefile
 509     pkgconfig/Makefile
 510     pkgconfig/gstreamer-vaapi-$GST_MAJORMINOR.pc:\
 511 pkgconfig/gstreamer-vaapi.pc.in
 512     pkgconfig/gstreamer-vaapi-glx-$GST_MAJORMINOR.pc:\
 513 pkgconfig/gstreamer-vaapi-glx.pc.in
 514     pkgconfig/gstreamer-vaapi-x11-$GST_MAJORMINOR.pc:\
 515 pkgconfig/gstreamer-vaapi-x11.pc.in
 516     gst/Makefile
 517     gst/vaapi/Makefile
 518     tests/Makefile
 519 ])
 520
 521 dnl Print summary
 522 yesno() {
 523     test $1 -eq 1 && echo yes || echo no
 524 }
 525
 526 echo
 527 echo $PACKAGE configuration summary:
 528 echo
 529 echo VA-API version ................... : $VA_VERSION_STR
 530 echo GLX support ...................... : $(yesno $USE_GLX)
 531 echo VA/GLX support ................... : $(yesno $USE_VAAPI_GLX)
 532 echo VaapiSink/GL ..................... : $(yesno $USE_VAAPISINK_GLX)
 533 echo FFmpeg bitstream parsers ......... : $(yesno $USE_FFMPEG)
 534 echo GStreamer bitstream parsers ...... : $(yesno $USE_CODEC_PARSERS)
 535 echo