configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2
   3 # Copyright (C) 1995-2012 Free Software Foundation, Inc.
   4 #
   5 # This program is free software; you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 2, or (at your option)
   8 # any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  17
  18 AC_PREREQ([2.69])
  19 AC_INIT([GNU Automake], [1.12.0a], [bug-automake@gnu.org])
  20
  21 AC_CONFIG_SRCDIR([automake.in])
  22 AC_CONFIG_AUX_DIR([lib])
  23
  24 AM_SILENT_RULES([yes])
  25
  26 AC_CANONICAL_HOST
  27 AC_CANONICAL_BUILD
  28
  29 # Save the AUTOCONF setting before AM_INIT_AUTOMAKE overrides it; this
  30 # way we can run Autoconf tests from configure (or from the test
  31 # suite) without being bothered by 'missing'.  Likewise for autom4te,
  32 # autoreconf, autoheader, and autoupdate.
  33 AC_SUBST([am_AUTOCONF], ["${AUTOCONF-autoconf}"])
  34 AC_SUBST([am_AUTOM4TE], ["${AUTOM4TE-autom4te}"])
  35 AC_SUBST([am_AUTORECONF], ["${AUTORECONF-autoreconf}"])
  36 AC_SUBST([am_AUTOHEADER], ["${AUTOHEADER-autoheader}"])
  37 AC_SUBST([am_AUTOUPDATE], ["${AUTOUPDATE-autoupdate}"])
  38
  39 dnl We call AC_PROG_CC in an unusual way, and only for use in our
  40 dnl testsuite, so also use 'no-dependencies' and 'no-define' among
  41 dnl the automake options to avoid bloating and potential problems.
  42 AM_INIT_AUTOMAKE([dist-xz filename-length-max=99 color-tests
  43                   parallel-tests silent-rules no-define no-dependencies])
  44
  45 # The API version is the base version.  We must guarantee
  46 # compatibility for all releases with the same API version.
  47 # Our current rule is that:
  48 # * All releases, including the prereleases, in an X.Y series
  49 #   are compatible.  So 1.5.1c is compatible with 1.5.
  50 # * Prereleases on the trunk are all incompatible -- 1.5b and 1.5c
  51 #   aren't the same.
  52 APIVERSION=`echo "$VERSION" | sed -e 's/^\([[0-9]]*\.[[0-9]]*[[a-z]]*\).*$/\1/'`
  53 AC_SUBST([APIVERSION])
  54
  55 AC_SUBST([pkgvdatadir], ["\${datadir}/$PACKAGE-$APIVERSION"])
  56 AC_SUBST([scriptdir], ["\${pkgvdatadir}"])
  57 AC_SUBST([amdir], ["\${pkgvdatadir}/am"])
  58 AC_SUBST([automake_acdir], ["\${datadir}/aclocal-$APIVERSION"])
  59 AC_SUBST([system_acdir], ["\${datadir}/aclocal"])
  60
  61 # $AUTOMAKE and $ACLOCAL are always run after a "cd $top_srcdir",
  62 # hence '.' is really what we want for perllibdir, libdir, and acdir.
  63 ACLOCAL="perllibdir=\"`pwd`/lib$PATH_SEPARATOR./lib\" \"`pwd`/aclocal\" --acdir=m4 -I m4"
  64 AUTOMAKE="perllibdir=\"`pwd`/lib$PATH_SEPARATOR./lib\" \"`pwd`/automake\" --libdir=lib"
  65
  66 AC_PATH_PROG([PERL], [perl])
  67 if test -z "$PERL"; then
  68    AC_MSG_ERROR([perl not found])
  69 fi
  70 # Save details about the selected perl interpreter in config.log.
  71 AM_RUN_LOG([$PERL --version])
  72 $PERL -e 'require 5.006;' || {
  73    AC_MSG_ERROR(
  74 [perl 5.6 or better is required; perl 5.8.2 or better
  75 is recommended.  If you have several perl versions
  76 installed, select the one Automake should use using
  77   ./configure PERL=/path/to/perl])
  78 }
  79
  80 # We require ithreads support, and version 5.7.2 for CLONE.
  81 AC_CACHE_CHECK([whether $PERL supports ithreads], [am_cv_prog_PERL_ithreads],
  82 [if $PERL -e '
  83     require 5.007_002;
  84     use Config;
  85     if ($Config{useithreads})
  86       {
  87         require threads;
  88         import threads;
  89         require Thread::Queue;
  90         import Thread::Queue;
  91         exit 0;
  92       }
  93     exit 1;' >&AS_MESSAGE_LOG_FD 2>&1
  94 then
  95   am_cv_prog_PERL_ithreads=yes
  96 else
  97   am_cv_prog_PERL_ithreads=no
  98 fi])
  99 if test $am_cv_prog_PERL_ithreads = yes; then
 100   PERL_THREADS=1;
 101 else
 102   PERL_THREADS=0;
 103 fi
 104 AC_SUBST([PERL_THREADS])
 105
 106 # The test suite will skip some tests if tex is absent.
 107 AC_CHECK_PROG([TEX], [tex], [tex])
 108 # Save details about the selected TeX program in config.log.
 109 # Redirect input from /dev/null, as TeX might otherwise hang waiting
 110 # for input from the terminal.
 111 AM_RUN_LOG([$TEX --version </dev/null])
 112
 113 # The test suite will skip some tests if no lex or yacc program is
 114 # available.
 115 # We don't use AC_PROG_LEX nor AC_PROG_YACC here because:
 116 #  1. we don't want flex (resp. bison) to be preferred to system lex
 117 #     (resp. system yacc);
 118 #  2. we don't want $LEX (resp. $YACC) to be defined to ':' (resp. 'yacc')
 119 #     by default;
 120 #  3. we prefer not to have the variables YFLAGS, LEX_OUTPUT_ROOT and
 121 #     LEXLIB to be calculated and/or AC_SUBST'd;
 122 #  4. we prefer that the YACC and LEX variables are not reported in the
 123 #     configure help screen.
 124 AC_CHECK_PROGS([YACC], [yacc byacc 'bison -y'], [false])
 125 AC_CHECK_PROGS([LEX], [lex flex], [false])
 126
 127 # Test for Autoconf.  We run Autoconf in a subdirectory to ease
 128 # deletion of any files created (such as those added to
 129 # autom4te.cache).  We used to perform only the last of the three
 130 # following tests, but some users were unable to figure out that their
 131 # installation was broken since --version appeared to work.
 132
 133 required_autoconf_version=2.62
 134 AC_CACHE_CHECK([whether autoconf is installed], [am_cv_autoconf_installed],
 135 [if AM_RUN_LOG([$am_AUTOCONF --version]);
 136 then
 137   am_cv_autoconf_installed=yes
 138 else
 139   am_cv_autoconf_installed=no
 140 fi])
 141 if test "$am_cv_autoconf_installed" = no; then
 142   AC_MSG_ERROR([Autoconf $required_autoconf_version or better is required.
 143     Please make sure it is installed and in your PATH.])
 144 fi
 145
 146 AC_CACHE_CHECK([whether autoconf works], [am_cv_autoconf_works],
 147 [mkdir conftest
 148 echo 'AC''_INIT' > conftest/conftest.ac
 149 if AM_RUN_LOG([cd conftest && $am_AUTOCONF -o /dev/null conftest.ac]);
 150 then
 151   am_cv_autoconf_works=yes
 152 else
 153   am_cv_autoconf_works=no
 154 fi
 155 rm -rf conftest])
 156 if test "$am_cv_autoconf_works" = no; then
 157   AC_MSG_ERROR([The installed version of autoconf does not work.
 158     Please check config.log for error messages before this one.])
 159 fi
 160
 161 AC_CACHE_CHECK([whether autoconf is recent enough], [am_cv_autoconf_version],
 162 [mkdir conftest
 163 dnl Creative quoting required to avoid spurious expansion of AC_PREREQ macro
 164 echo 'AC'"_PREREQ([[$required_autoconf_version]])" > conftest/conftest.ac
 165 if AM_RUN_LOG([cd conftest && $am_AUTOCONF -o /dev/null conftest.ac]);
 166 then
 167   am_cv_autoconf_version=yes
 168 else
 169   am_cv_autoconf_version=no
 170 fi
 171 rm -rf conftest])
 172 if test "$am_cv_autoconf_version" = no; then
 173   AC_MSG_ERROR([Autoconf $required_autoconf_version or better is required.])
 174 fi
 175
 176 # Test for ln.  We need use it to install the versioned binaries.
 177 AC_MSG_CHECKING([whether ln works])
 178 AC_CACHE_VAL([am_cv_prog_ln], [
 179 rm -f conftest conftest.file
 180 : >conftest.file
 181 if ln conftest.file conftest 2>/dev/null; then
 182   am_cv_prog_ln=ln
 183 else
 184   am_cv_prog_ln='cp -p'
 185 fi
 186 rm -f conftest conftest.file])
 187 AC_SUBST([LN], [$am_cv_prog_ln])
 188 result=no
 189 test "x$am_cv_prog_ln" = xln && result=yes
 190 AC_MSG_RESULT([$result])
 191
 192 # The amount we should wait after modifying files depends on the platform.
 193 # On Windows '95, '98 and ME, files modifications have 2-seconds
 194 # granularity and can be up to 3 seconds in the future w.r.t. the
 195 # system clock.  When it is important to ensure one file is older
 196 # than another we wait at least 5 seconds between creations.
 197 case $build in
 198   *-pc-msdosdjgpp) MODIFICATION_DELAY=5;;
 199   *)               MODIFICATION_DELAY=2;;
 200 esac
 201 AC_SUBST([MODIFICATION_DELAY])
 202
 203 # Test for things needed by the test suite.
 204 AC_PROG_EGREP
 205 AC_PROG_FGREP
 206
 207 AC_CACHE_CHECK([whether $SHELL has working 'set -e' with exit trap],
 208 [am_cv_sh_errexit_works],
 209 [if $SHELL -ec "trap 'exit \$?' 0; (exit 77); exit 77"; test $? = 77
 210 then
 211   am_cv_sh_errexit_works=yes
 212 else
 213   am_cv_sh_errexit_works=no
 214 fi
 215 ])
 216 if test $am_cv_sh_errexit_works = no; then
 217   AC_MSG_WARN(["${MAKE-make} check" will leave leftover directories t/*.dir])
 218   AC_MSG_WARN([you can clean them up manually using "${MAKE-make} clean" or])
 219   AC_MSG_WARN(["cd t && ${MAKE-make} clean-local-check'])
 220 fi
 221 AC_SUBST([sh_errexit_works], [$am_cv_sh_errexit_works])
 222
 223
 224 ###########################################################################
 225
 226 # Look for C, C++ and fortran compilers to be used in the testsuite.
 227
 228 dnl We don't want to abort our configuration script if no C compiler is
 229 dnl available, as such a compiler is only required to run part of the
 230 dnl testsuite, not to build or install Automake.  Ditto for C++, Fortran
 231 dnl and Fortran 77 compilers.  Unfortunately, autoconf does not offer an
 232 dnl easy way to obtain this behaviour, so we'll need a few hacks.
 233
 234 dnl We want the body of this macro to expand as a single shell statement,
 235 dnl thus we wrap it into { ... } brackets.
 236 AC_DEFUN([_AM_WRAP_MSG_ERROR], [ {
 237   AC_MSG_WARN([$1])
 238   am__failed=yes
 239   break
 240 } ])
 241
 242 AC_DEFUN([_AM_COMPILER_CAN_FAIL], [
 243   m4_pushdef([AC_MSG_FAILURE], m4_defn([_AM_WRAP_MSG_ERROR]))
 244   m4_pushdef([AC_MSG_ERROR],   m4_defn([_AM_WRAP_MSG_ERROR]))
 245   am__failed=no
 246   while :; do
 247      $1
 248      break
 249   done
 250   AS_IF([test $am__failed = yes], [$2])
 251   # We have to clear these cache variables, so that future checks on
 252   # compilers for different languages won't be confused.
 253   unset ac_cv_objext ac_cv_exeext
 254   # We also need to meddle with the autoconf internals to ensure that
 255   # checks to find object and executable extensions will be run anew.
 256   # FIXME: In the long run, the better thing to do would be to fix
 257   # FIXME: autoconf instead ...
 258   m4_undefine([m4_provide(_AC_COMPILER_OBJEXT)])
 259   m4_undefine([m4_provide(_AC_COMPILER_EXEEXT)])
 260   m4_popdef([AC_MSG_FAILURE])
 261   m4_popdef([AC_MSG_ERROR])
 262 ])
 263
 264 AC_DEFUN([_AM_SKIP_COMP_TESTS],
 265   [AC_MSG_NOTICE([tests requiring the $1 compiler will be skipped])])
 266
 267 # Prefer generic compilers to GNU ones when possible.  This will ensure
 268 # more testsuite coverage "in the wild".
 269 # Note that we don't look for the MSVC C/C++ compiler here.  This is
 270 # deliberate; for more discussion and rationale, see:
 271 # <http://lists.gnu.org/archive/html/automake-patches/2012-01/msg00130.html>
 272
 273 AC_MSG_NOTICE([will now look for generic compilers])
 274
 275 # C compiler.
 276 _AM_COMPILER_CAN_FAIL(dnl
 277   [AC_PROG_CC([cc gcc])],
 278   [CC=false; _AM_SKIP_COMP_TESTS([C])])
 279
 280 AS_IF([test x"$GCC" = x"yes"], [am_CC_is_GNU=yes], [am_CC_is_GNU=no])
 281
 282 # The list of C++ compilers here has been copied, pasted and edited
 283 # from 'lib/autoconf/c.m4:AC_PROG_CXX' in the Autoconf distribution.
 284 # Keep it in sync, or better again, find out a way to avoid this code
 285 # duplication.
 286 _AM_COMPILER_CAN_FAIL([AC_PROG_CXX(dnl
 287   [aCC CC FCC KCC RCC xlC_r xlC c++ cxx cc++ gpp g++])],
 288   [CXX=false; _AM_SKIP_COMP_TESTS([C++])])
 289
 290 AS_IF([test x"$GXX" = x"yes"], [am_CXX_is_GNU=yes], [am_CXX_is_GNU=no])
 291
 292 # The lists of Fortran compilers here has been copied, pasted and edited
 293 # from file 'lib/autoconf/fortran.m4' in the Autoconf distribution.
 294 # Keep it in sync, or better again, find out a way to avoid this code
 295 # duplication.
 296
 297 _AM_COMPILER_CAN_FAIL([AC_PROG_FC(dnl
 298   [xlf95 f95 fort ifort ifc efc pgfortran pgf95 lf95 ftn nagfor] dnl
 299   [xlf90 f90 pgf90 pghpf epcf90 g95 gfortran])],
 300   [FC=false; _AM_SKIP_COMP_TESTS([Fortran])])
 301
 302 AS_IF([test x"$GFC" = x"yes"], [am_FC_is_GNU=yes], [am_FC_is_GNU=no])
 303
 304 _AM_COMPILER_CAN_FAIL([AC_PROG_F77(dnl
 305   [xlf f77 frt pgf77 cf77 fort77 fl32 af77 g77 gfortran])],
 306   [F77=false; _AM_SKIP_COMP_TESTS([Fortran 77])])
 307
 308 AS_IF([test x"$G77" = x"yes"], [am_F77_is_GNU=yes], [am_F77_is_GNU=no])
 309
 310 # Some tests will need the GNU compilers.  Searching for them here would
 311 # be overkill, since our testsuite already handles their search and setup
 312 # pretty well.  But in case the compilers already found are the GNU ones,
 313 # we want to use them in the testsuite where GNU compilers are required.
 314 # Also, in case the compilers detected above (at configure time) are not
 315 # the GNU ones, we cannot use the values of CFLAGS, CXXFLAGS, FCFLAGS and
 316 # FFLAGS detected for them with the GNU compilers too, since it's likely
 317 # they won't be compatible.  So we allow the user to define variants of
 318 # these variables for the GNU compilers separately.
 319
 320 AC_MSG_NOTICE([will now look for GNU compilers])
 321
 322 # GNU C compiler.
 323 AC_ARG_VAR([GNU_CC],     [GNU C compiler])
 324 AC_ARG_VAR([GNU_CFLAGS], [GNU C compiler flags])
 325 if test $am_CC_is_GNU = yes; then
 326   AC_MSG_NOTICE([$CC is already a GNU C compiler])
 327   GNU_CC=$CC GNU_CFLAGS=${GNU_CFLAGS-$CFLAGS}
 328 else
 329   AC_CHECK_TOOLS([GNU_CC], [gcc], [false])
 330 fi
 331 AS_IF([AM_RUN_LOG([$GNU_CC --version && $GNU_CC -v])], [],
 332       [AC_MSG_WARN([botched installation for GNU C compiler])
 333        _AM_SKIP_COMP_TESTS([GNU C])])
 334
 335 # GNU C++ compiler.
 336 AC_ARG_VAR([GNU_CXX],      [GNU C++ compiler])
 337 AC_ARG_VAR([GNU_CXXFLAGS], [GNU C++ compiler flags])
 338 if test $am_CXX_is_GNU = yes; then
 339   AC_MSG_NOTICE([$CXX is already a GNU C++ compiler])
 340   GNU_CXX=$CXX
 341   GNU_CXXFLAGS=${GNU_CXXFLAGS-$CXXFLAGS}
 342 else
 343   AC_CHECK_TOOLS([GNU_CXX], [g++ gpp], [false])
 344 fi
 345 AS_IF([AM_RUN_LOG([$GNU_CXX --version && $GNU_CXX -v])], [],
 346       [AC_MSG_WARN([botched installation for GNU C++ compiler])
 347        _AM_SKIP_COMP_TESTS([GNU C++])])
 348
 349 # GNU Fortran compiler.
 350 AC_ARG_VAR([GNU_FC],      [GNU Fortran compiler])
 351 AC_ARG_VAR([GNU_FCFLAGS], [GNU Fortran compiler flags])
 352 if test $am_FC_is_GNU = yes; then
 353   AC_MSG_NOTICE([$FC is already a GNU Fortran compiler])
 354   GNU_FC=$FC
 355   GNU_FCFLAGS=${GNU_FCFLAGS-$FCFLAGS}
 356 else
 357   AC_CHECK_TOOLS([GNU_FC], [gfortran], [false])
 358 fi
 359 AS_IF([AM_RUN_LOG([$GNU_FC --version && $GNU_FC -v])], [],
 360       [AC_MSG_WARN([botched installation for GNU Fortran compiler])
 361        _AM_SKIP_COMP_TESTS([GNU Fortran])])
 362
 363 # GNU Fortran 77 compiler.
 364 AC_ARG_VAR([GNU_F77],    [GNU Fortran 77 compiler])
 365 AC_ARG_VAR([GNU_FFLAGS], [GNU Fortran 77 compiler flags])
 366 if test $am_F77_is_GNU = yes; then
 367   AC_MSG_NOTICE([$F77 is already a GNU Fortran 77 compiler])
 368   GNU_F77=$F77
 369   GNU_FFLAGS=${GNU_FFLAGS-$FFLAGS}
 370 else
 371   AC_CHECK_TOOLS([GNU_F77], [g77 gfortran], [false])
 372 fi
 373 AS_IF([AM_RUN_LOG([$GNU_F77 --version && $GNU_F77 -v])], [],
 374       [AC_MSG_WARN([botched installation for GNU Fortran 77 compiler])
 375       _AM_SKIP_COMP_TESTS([GNU Fortran 77])])
 376
 377 # GNU Java compiler.
 378 AC_ARG_VAR([GNU_GCJ], [GNU Java compiler])
 379 AC_ARG_VAR([GNU_GCJFLAGS], [GNU Java compiler flags])
 380 AC_CHECK_TOOLS([GNU_GCJ], [gcj], [false])
 381 AS_IF([AM_RUN_LOG([$GNU_GCJ --version && $GNU_GCJ -v])], [],
 382       [AC_MSG_WARN([botched installation for GNU Java compiler])
 383       _AM_SKIP_COMP_TESTS([GNU Java])])
 384
 385 # If we have been able to find at least a working compiler above, we
 386 # know what the object and executable extensions for this platform are.
 387 OBJEXT=${ac_cv_objext-UNKNOWN}
 388 EXEEXT=${ac_cv_exeext-UNKNOWN}
 389 AC_SUBST([OBJEXT])
 390 AC_SUBST([EXEEXT])
 391
 392 ###########################################################################
 393
 394 AC_CONFIG_FILES([Makefile])
 395
 396 AC_CONFIG_LINKS([GNUmakefile:GNUmakefile])
 397 AC_CONFIG_LINKS([defs:defs])
 398
 399 AC_CONFIG_FILES([t/wrap/aclocal-${APIVERSION}:t/wrap/aclocal.in],
 400                 [chmod +x t/wrap/aclocal-${APIVERSION}],
 401                 [APIVERSION=$APIVERSION])
 402 AC_CONFIG_FILES([t/wrap/automake-${APIVERSION}:t/wrap/automake.in],
 403                 [chmod +x t/wrap/automake-${APIVERSION}],
 404                 [APIVERSION=$APIVERSION])
 405
 406 AC_OUTPUT
 407
 408 # Inform the user if this version of automake is a beta release or
 409 # a development snapshot.
 410 # According to HACKING, the version of a development snapshot should
 411 # end with an "odd" letter (a, c, ...), the version of a test release
 412 # should end wit an "even" letter (b, d, ...).
 413
 414 am_stable_version_rx='[[1-9]\.[0-9]+(\.[0-9]+)?]'
 415 am_beta_version_rx="[$am_stable_version_rx[bdfhjlnprtvxz]]"
 416
 417 am_release_type=`AS_ECHO(["$PACKAGE_VERSION"]) | LC_ALL=C awk ["
 418   /^$am_stable_version_rx$/ { print \"stable\"; exit(0); }
 419   /^$am_beta_version_rx$/ { print \"beta version\"; exit(0); }
 420   { print \"development snapshot\"; }"]`
 421
 422 test "$am_release_type" = stable || cat <<EOF
 423
 424 WARNING: You are about to use a $am_release_type of automake.
 425 WARNING: It might easily suffer from new bugs or regressions.
 426 WARNING: You are strongly advised not to use it in production code.
 427
 428 Please report bugs, problems and feedback to <AC_PACKAGE_BUGREPORT>.
 429 EOF
 430
 431 AS_EXIT([0])