configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.59])
   4
   5 dnl Versioning - scrape the version from configs/default
   6 m4_define([mesa_version],
   7     [m4_esyscmd([${MAKE-make} -s -f bin/version.mk version | tr -d '\n' | tr -d '\r'])])
   8 m4_ifval(mesa_version,,
   9     [m4_fatal([Failed to get the Mesa version from `make -f bin/version.mk version`])])
  10
  11 dnl Tell the user about autoconf.html in the --help output
  12 m4_divert_once([HELP_END], [
  13 See docs/autoconf.html for more details on the options for Mesa.])
  14
  15 AC_INIT([Mesa],[mesa_version],
  16     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  17 AC_CONFIG_AUX_DIR([bin])
  18 AC_CANONICAL_HOST
  19
  20 dnl Versions for external dependencies
  21 LIBDRM_REQUIRED=2.4.15
  22 LIBDRM_RADEON_REQUIRED=2.4.17
  23 DRI2PROTO_REQUIRED=2.1
  24 GLPROTO_REQUIRED=1.4.11
  25 LIBDRM_XORG_REQUIRED=2.4.17
  26 LIBKMS_XORG_REQUIRED=1.0.0
  27
  28 dnl Check for progs
  29 AC_PROG_CPP
  30 AC_PROG_CC
  31 AC_PROG_CXX
  32 AC_CHECK_PROGS([MAKE], [gmake make])
  33 AC_PATH_PROG([MKDEP], [makedepend])
  34 AC_PATH_PROG([SED], [sed])
  35
  36 dnl Our fallback install-sh is a symlink to minstall. Use the existing
  37 dnl configuration in that case.
  38 AC_PROG_INSTALL
  39 test "x$INSTALL" = "x$ac_install_sh" && INSTALL='$(MINSTALL)'
  40
  41 dnl We need a POSIX shell for parts of the build. Assume we have one
  42 dnl in most cases.
  43 case "$host_os" in
  44 solaris*)
  45     # Solaris /bin/sh is too old/non-POSIX compliant
  46     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  47     SHELL="$POSIX_SHELL"
  48     ;;
  49 esac
  50
  51 dnl If we're using GCC, make sure that it is at least version 3.3.0.  Older
  52 dnl versions are explictly not supported.
  53 if test "x$GCC" = xyes; then
  54     AC_MSG_CHECKING([whether gcc version is sufficient])
  55     major=0
  56     minor=0
  57
  58     GCC_VERSION=`$CC -dumpversion`
  59     if test $? -eq 0; then
  60         major=`echo $GCC_VERSION | cut -d. -f1`
  61         minor=`echo $GCC_VERSION | cut -d. -f1`
  62     fi
  63
  64     if test $major -lt 3 -o $major -eq 3 -a $minor -lt 3 ; then
  65         AC_MSG_RESULT([no])
  66         AC_MSG_ERROR([If using GCC, version 3.3.0 or later is required.])
  67     else
  68         AC_MSG_RESULT([yes])
  69     fi
  70 fi
  71
  72
  73 MKDEP_OPTIONS=-fdepend
  74 dnl Ask gcc where it's keeping its secret headers
  75 if test "x$GCC" = xyes; then
  76     for dir in include include-fixed; do
  77         GCC_INCLUDES=`$CC -print-file-name=$dir`
  78         if test "x$GCC_INCLUDES" != x && \
  79            test "$GCC_INCLUDES" != "$dir" && \
  80            test -d "$GCC_INCLUDES"; then
  81             MKDEP_OPTIONS="$MKDEP_OPTIONS -I$GCC_INCLUDES"
  82         fi
  83     done
  84 fi
  85 AC_SUBST([MKDEP_OPTIONS])
  86
  87 dnl Make sure the pkg-config macros are defined
  88 m4_ifndef([PKG_PROG_PKG_CONFIG],
  89     [m4_fatal([Could not locate the pkg-config autoconf macros.
  90   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
  91   are in a different location, try setting the environment variable
  92   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
  93 PKG_PROG_PKG_CONFIG()
  94
  95 dnl LIB_DIR - library basename
  96 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
  97 AC_SUBST([LIB_DIR])
  98
  99 dnl Cache LDFLAGS so we can add EXTRA_LIB_PATH and restore it later
 100 _SAVE_LDFLAGS="$LDFLAGS"
 101 AC_ARG_VAR([EXTRA_LIB_PATH],[Extra -L paths for the linker])
 102 AC_SUBST([EXTRA_LIB_PATH])
 103
 104 dnl Cache CPPFLAGS so we can add *_INCLUDES and restore it later
 105 _SAVE_CPPFLAGS="$CPPFLAGS"
 106 AC_ARG_VAR([X11_INCLUDES],[Extra -I paths for X11 headers])
 107 AC_SUBST([X11_INCLUDES])
 108
 109 dnl Compiler macros
 110 DEFINES=""
 111 AC_SUBST([DEFINES])
 112 case "$host_os" in
 113 linux*|*-gnu*|gnu*)
 114     DEFINES="$DEFINES -D_GNU_SOURCE -DPTHREADS"
 115     ;;
 116 solaris*)
 117     DEFINES="$DEFINES -DPTHREADS -DSVR4"
 118     ;;
 119 cygwin*)
 120     DEFINES="$DEFINES -DPTHREADS"
 121     ;;
 122 esac
 123
 124 dnl Add flags for gcc and g++
 125 if test "x$GCC" = xyes; then
 126     CFLAGS="$CFLAGS -Wall -Wmissing-prototypes -std=c99 -ffast-math"
 127
 128     # Enable -fvisibility=hidden if using a gcc that supports it
 129     save_CFLAGS="$CFLAGS"
 130     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 131     CFLAGS="$CFLAGS -fvisibility=hidden"
 132     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 133                    [CFLAGS="$save_CFLAGS" ; AC_MSG_RESULT([no])]);
 134
 135     # Work around aliasing bugs - developers should comment this out
 136     CFLAGS="$CFLAGS -fno-strict-aliasing"
 137 fi
 138 if test "x$GXX" = xyes; then
 139     CXXFLAGS="$CXXFLAGS -Wall"
 140
 141     # Work around aliasing bugs - developers should comment this out
 142     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 143 fi
 144
 145 dnl These should be unnecessary, but let the user set them if they want
 146 AC_ARG_VAR([OPT_FLAGS], [Additional optimization flags for the compiler.
 147     Default is to use CFLAGS.])
 148 AC_ARG_VAR([ARCH_FLAGS], [Additional architecture specific flags for the
 149     compiler. Default is to use CFLAGS.])
 150 AC_SUBST([OPT_FLAGS])
 151 AC_SUBST([ARCH_FLAGS])
 152
 153 dnl
 154 dnl Hacks to enable 32 or 64 bit build
 155 dnl
 156 AC_ARG_ENABLE([32-bit],
 157     [AS_HELP_STRING([--enable-32-bit],
 158         [build 32-bit libraries @<:@default=auto@:>@])],
 159     [enable_32bit="$enableval"],
 160     [enable_32bit=auto]
 161 )
 162 if test "x$enable_32bit" = xyes; then
 163     if test "x$GCC" = xyes; then
 164         CFLAGS="$CFLAGS -m32"
 165         ARCH_FLAGS="$ARCH_FLAGS -m32"
 166     fi
 167     if test "x$GXX" = xyes; then
 168         CXXFLAGS="$CXXFLAGS -m32"
 169     fi
 170 fi
 171 AC_ARG_ENABLE([64-bit],
 172     [AS_HELP_STRING([--enable-64-bit],
 173         [build 64-bit libraries @<:@default=auto@:>@])],
 174     [enable_64bit="$enableval"],
 175     [enable_64bit=auto]
 176 )
 177 if test "x$enable_64bit" = xyes; then
 178     if test "x$GCC" = xyes; then
 179         CFLAGS="$CFLAGS -m64"
 180     fi
 181     if test "x$GXX" = xyes; then
 182         CXXFLAGS="$CXXFLAGS -m64"
 183     fi
 184 fi
 185
 186 dnl
 187 dnl shared/static libraries, mimic libtool options
 188 dnl
 189 AC_ARG_ENABLE([static],
 190     [AS_HELP_STRING([--enable-static],
 191         [build static libraries @<:@default=disabled@:>@])],
 192     [enable_static="$enableval"],
 193     [enable_static=no]
 194 )
 195 case "x$enable_static" in
 196 xyes|xno ) ;;
 197 x ) enable_static=no ;;
 198 * )
 199     AC_MSG_ERROR([Static library option '$enable_static' is not a valid])
 200     ;;
 201 esac
 202 AC_ARG_ENABLE([shared],
 203     [AS_HELP_STRING([--disable-shared],
 204         [build shared libraries @<:@default=enabled@:>@])],
 205     [enable_shared="$enableval"],
 206     [enable_shared=yes]
 207 )
 208 case "x$enable_shared" in
 209 xyes|xno ) ;;
 210 x ) enable_shared=yes ;;
 211 * )
 212     AC_MSG_ERROR([Shared library option '$enable_shared' is not a valid])
 213     ;;
 214 esac
 215
 216 dnl Can't have static and shared libraries, default to static if user
 217 dnl explicitly requested. If both disabled, set to static since shared
 218 dnl was explicitly requirested.
 219 case "x$enable_static$enable_shared" in
 220 xyesyes )
 221     AC_MSG_WARN([Can't build static and shared libraries, disabling shared])
 222     enable_shared=no
 223     ;;
 224 xnono )
 225     AC_MSG_WARN([Can't disable both static and shared libraries, enabling static])
 226     enable_static=yes
 227     ;;
 228 esac
 229
 230 dnl
 231 dnl mklib options
 232 dnl
 233 AC_ARG_VAR([MKLIB_OPTIONS],[Options for the Mesa library script, mklib])
 234 if test "$enable_static" = yes; then
 235     MKLIB_OPTIONS="$MKLIB_OPTIONS -static"
 236 fi
 237 AC_SUBST([MKLIB_OPTIONS])
 238
 239 dnl
 240 dnl other compiler options
 241 dnl
 242 AC_ARG_ENABLE([debug],
 243     [AS_HELP_STRING([--enable-debug],
 244         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 245     [enable_debug="$enableval"],
 246     [enable_debug=no]
 247 )
 248 if test "x$enable_debug" = xyes; then
 249     DEFINES="$DEFINES -DDEBUG"
 250     if test "x$GCC" = xyes; then
 251         CFLAGS="$CFLAGS -g"
 252     fi
 253     if test "x$GXX" = xyes; then
 254         CXXFLAGS="$CXXFLAGS -g"
 255     fi
 256 fi
 257
 258 dnl
 259 dnl library names
 260 dnl
 261 if test "$enable_static" = yes; then
 262     LIB_EXTENSION='a'
 263 else
 264     case "$host_os" in
 265     darwin* )
 266         LIB_EXTENSION='dylib' ;;
 267     cygwin* )
 268         LIB_EXTENSION='dll.a' ;;
 269     aix* )
 270         LIB_EXTENSION='a' ;;
 271     * )
 272         LIB_EXTENSION='so' ;;
 273     esac
 274 fi
 275
 276 GL_LIB_NAME='lib$(GL_LIB).'${LIB_EXTENSION}
 277 GLU_LIB_NAME='lib$(GLU_LIB).'${LIB_EXTENSION}
 278 GLUT_LIB_NAME='lib$(GLUT_LIB).'${LIB_EXTENSION}
 279 GLW_LIB_NAME='lib$(GLW_LIB).'${LIB_EXTENSION}
 280 OSMESA_LIB_NAME='lib$(OSMESA_LIB).'${LIB_EXTENSION}
 281 EGL_LIB_NAME='lib$(EGL_LIB).'${LIB_EXTENSION}
 282 GLESv1_CM_LIB_NAME='lib$(GLESv1_CM_LIB).'${LIB_EXTENSION}
 283 GLESv2_LIB_NAME='lib$(GLESv2_LIB).'${LIB_EXTENSION}
 284 VG_LIB_NAME='lib$(VG_LIB).'${LIB_EXTENSION}
 285
 286 GL_LIB_GLOB='lib$(GL_LIB).*'${LIB_EXTENSION}'*'
 287 GLU_LIB_GLOB='lib$(GLU_LIB).*'${LIB_EXTENSION}'*'
 288 GLUT_LIB_GLOB='lib$(GLUT_LIB).*'${LIB_EXTENSION}'*'
 289 GLW_LIB_GLOB='lib$(GLW_LIB).*'${LIB_EXTENSION}'*'
 290 OSMESA_LIB_GLOB='lib$(OSMESA_LIB).*'${LIB_EXTENSION}'*'
 291 EGL_LIB_GLOB='lib$(EGL_LIB).*'${LIB_EXTENSION}'*'
 292 GLESv1_CM_LIB_GLOB='lib$(GLESv1_CM_LIB).*'${LIB_EXTENSION}'*'
 293 GLESv2_LIB_GLOB='lib$(GLESv2_LIB).*'${LIB_EXTENSION}'*'
 294 VG_LIB_GLOB='lib$(VG_LIB).*'${LIB_EXTENSION}'*'
 295
 296 AC_SUBST([GL_LIB_NAME])
 297 AC_SUBST([GLU_LIB_NAME])
 298 AC_SUBST([GLUT_LIB_NAME])
 299 AC_SUBST([GLW_LIB_NAME])
 300 AC_SUBST([OSMESA_LIB_NAME])
 301 AC_SUBST([EGL_LIB_NAME])
 302 AC_SUBST([GLESv1_CM_LIB_NAME])
 303 AC_SUBST([GLESv2_LIB_NAME])
 304 AC_SUBST([VG_LIB_NAME])
 305
 306 AC_SUBST([GL_LIB_GLOB])
 307 AC_SUBST([GLU_LIB_GLOB])
 308 AC_SUBST([GLUT_LIB_GLOB])
 309 AC_SUBST([GLW_LIB_GLOB])
 310 AC_SUBST([OSMESA_LIB_GLOB])
 311 AC_SUBST([EGL_LIB_GLOB])
 312 AC_SUBST([GLESv1_CM_LIB_GLOB])
 313 AC_SUBST([GLESv2_LIB_GLOB])
 314 AC_SUBST([VG_LIB_GLOB])
 315
 316 dnl
 317 dnl Arch/platform-specific settings
 318 dnl
 319 AC_ARG_ENABLE([asm],
 320     [AS_HELP_STRING([--disable-asm],
 321         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 322     [enable_asm="$enableval"],
 323     [enable_asm=yes]
 324 )
 325 asm_arch=""
 326 ASM_FLAGS=""
 327 MESA_ASM_SOURCES=""
 328 GLAPI_ASM_SOURCES=""
 329 AC_MSG_CHECKING([whether to enable assembly])
 330 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 331 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 332 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 333     case "$host_cpu" in
 334     i?86 | x86_64)
 335         enable_asm=no
 336         AC_MSG_RESULT([no, cross compiling])
 337         ;;
 338     esac
 339 fi
 340 # check for supported arches
 341 if test "x$enable_asm" = xyes; then
 342     case "$host_cpu" in
 343     i?86)
 344         case "$host_os" in
 345         linux* | *freebsd* | dragonfly*)
 346             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 347             ;;
 348         esac
 349         ;;
 350     x86_64)
 351         case "$host_os" in
 352         linux* | *freebsd* | dragonfly*)
 353             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 354             ;;
 355         esac
 356         ;;
 357     powerpc)
 358         case "$host_os" in
 359         linux*)
 360             asm_arch=ppc
 361             ;;
 362         esac
 363         ;;
 364     sparc*)
 365         case "$host_os" in
 366         linux*)
 367             asm_arch=sparc
 368             ;;
 369         esac
 370         ;;
 371     esac
 372
 373     case "$asm_arch" in
 374     x86)
 375         ASM_FLAGS="-DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 376         MESA_ASM_SOURCES='$(X86_SOURCES)'
 377         GLAPI_ASM_SOURCES='$(X86_API)'
 378         AC_MSG_RESULT([yes, x86])
 379         ;;
 380     x86_64)
 381         ASM_FLAGS="-DUSE_X86_64_ASM"
 382         MESA_ASM_SOURCES='$(X86-64_SOURCES)'
 383         GLAPI_ASM_SOURCES='$(X86-64_API)'
 384         AC_MSG_RESULT([yes, x86_64])
 385         ;;
 386     ppc)
 387         ASM_FLAGS="-DUSE_PPC_ASM -DUSE_VMX_ASM"
 388         MESA_ASM_SOURCES='$(PPC_SOURCES)'
 389         AC_MSG_RESULT([yes, ppc])
 390         ;;
 391     sparc)
 392         ASM_FLAGS="-DUSE_SPARC_ASM"
 393         MESA_ASM_SOURCES='$(SPARC_SOURCES)'
 394         GLAPI_ASM_SOURCES='$(SPARC_API)'
 395         AC_MSG_RESULT([yes, sparc])
 396         ;;
 397     *)
 398         AC_MSG_RESULT([no, platform not supported])
 399         ;;
 400     esac
 401 fi
 402 AC_SUBST([ASM_FLAGS])
 403 AC_SUBST([MESA_ASM_SOURCES])
 404 AC_SUBST([GLAPI_ASM_SOURCES])
 405
 406 dnl PIC code macro
 407 MESA_PIC_FLAGS
 408
 409 dnl Check to see if dlopen is in default libraries (like Solaris, which
 410 dnl has it in libc), or if libdl is needed to get it.
 411 AC_CHECK_FUNC([dlopen], [],
 412     [AC_CHECK_LIB([dl], [dlopen], [DLOPEN_LIBS="-ldl"])])
 413 AC_SUBST([DLOPEN_LIBS])
 414
 415 dnl See if posix_memalign is available
 416 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 417
 418 dnl SELinux awareness.
 419 AC_ARG_ENABLE([selinux],
 420     [AS_HELP_STRING([--enable-selinux],
 421         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 422     [MESA_SELINUX="$enableval"],
 423     [MESA_SELINUX=no])
 424 if test "x$enable_selinux" = "xyes"; then
 425     AC_CHECK_HEADER([selinux/selinux.h],[],
 426                     [AC_MSG_ERROR([SELinux headers not found])])
 427     AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 428                  [AC_MSG_ERROR([SELinux library not found])])
 429     SELINUX_LIBS="-lselinux"
 430     DEFINES="$DEFINES -DMESA_SELINUX"
 431 fi
 432
 433 dnl
 434 dnl Driver configuration. Options are xlib, dri and osmesa right now.
 435 dnl More later: fbdev, ...
 436 dnl
 437 default_driver="xlib"
 438
 439 case "$host_os" in
 440 linux*)
 441     case "$host_cpu" in
 442     i*86|x86_64|powerpc*|sparc*) default_driver="dri";;
 443     esac
 444     ;;
 445 *freebsd* | dragonfly*)
 446     case "$host_cpu" in
 447     i*86|x86_64|powerpc*|sparc*) default_driver="dri";;
 448     esac
 449     ;;
 450 esac
 451
 452 AC_ARG_WITH([driver],
 453     [AS_HELP_STRING([--with-driver=DRIVER],
 454         [driver for Mesa: xlib,dri,osmesa @<:@default=dri when available, or xlib@:>@])],
 455     [mesa_driver="$withval"],
 456     [mesa_driver="$default_driver"])
 457 dnl Check for valid option
 458 case "x$mesa_driver" in
 459 xxlib|xdri|xosmesa)
 460     ;;
 461 *)
 462     AC_MSG_ERROR([Driver '$mesa_driver' is not a valid option])
 463     ;;
 464 esac
 465
 466 PKG_CHECK_MODULES([TALLOC], [talloc])
 467
 468 dnl
 469 dnl Driver specific build directories
 470 dnl
 471
 472 dnl this variable will be prepended to SRC_DIRS and is not exported
 473 CORE_DIRS="mapi/glapi glsl mesa"
 474
 475 SRC_DIRS=""
 476 GLU_DIRS="sgi"
 477 GALLIUM_DIRS="auxiliary drivers state_trackers"
 478 GALLIUM_TARGET_DIRS=""
 479 GALLIUM_WINSYS_DIRS="sw"
 480 GALLIUM_DRIVERS_DIRS="softpipe failover galahad trace rbug identity"
 481 GALLIUM_STATE_TRACKERS_DIRS=""
 482
 483 case "$mesa_driver" in
 484 xlib)
 485     DRIVER_DIRS="x11"
 486     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
 487     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS libgl-xlib"
 488     ;;
 489 dri)
 490     SRC_DIRS="$SRC_DIRS glx"
 491     DRIVER_DIRS="dri"
 492     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib sw/dri"
 493     ;;
 494 osmesa)
 495     DRIVER_DIRS="osmesa"
 496     ;;
 497 esac
 498 AC_SUBST([SRC_DIRS])
 499 AC_SUBST([GLU_DIRS])
 500 AC_SUBST([DRIVER_DIRS])
 501 AC_SUBST([GALLIUM_DIRS])
 502 AC_SUBST([GALLIUM_TARGET_DIRS])
 503 AC_SUBST([GALLIUM_WINSYS_DIRS])
 504 AC_SUBST([GALLIUM_DRIVERS_DIRS])
 505 AC_SUBST([GALLIUM_STATE_TRACKERS_DIRS])
 506 AC_SUBST([MESA_LLVM])
 507
 508 dnl
 509 dnl Find out if X is available. The variable have_x is set if libX11 is
 510 dnl found to mimic AC_PATH_XTRA.
 511 dnl
 512 if test -n "$PKG_CONFIG"; then
 513     AC_MSG_CHECKING([pkg-config files for X11 are available])
 514     PKG_CHECK_EXISTS([x11],[
 515         x11_pkgconfig=yes
 516         have_x=yes
 517         ],[
 518         x11_pkgconfig=no
 519     ])
 520     AC_MSG_RESULT([$x11_pkgconfig])
 521 else
 522     x11_pkgconfig=no
 523 fi
 524 dnl Use the autoconf macro if no pkg-config files
 525 if test "$x11_pkgconfig" = yes; then
 526     PKG_CHECK_MODULES([X11], [x11])
 527 else
 528     AC_PATH_XTRA
 529     test -z "$X11_CFLAGS" && X11_CFLAGS="$X_CFLAGS"
 530     test -z "$X11_LIBS" && X11_LIBS="$X_LIBS -lX11"
 531     AC_SUBST([X11_CFLAGS])
 532     AC_SUBST([X11_LIBS])
 533 fi
 534
 535 dnl Try to tell the user that the --x-* options are only used when
 536 dnl pkg-config is not available. This must be right after AC_PATH_XTRA.
 537 m4_divert_once([HELP_BEGIN],
 538 [These options are only used when the X libraries cannot be found by the
 539 pkg-config utility.])
 540
 541 dnl We need X for xlib and dri, so bomb now if it's not found
 542 case "$mesa_driver" in
 543 xlib|dri)
 544     if test "$no_x" = yes; then
 545         AC_MSG_ERROR([X11 development libraries needed for $mesa_driver driver])
 546     fi
 547     ;;
 548 esac
 549
 550 dnl XCB - this is only used for GLX right now
 551 AC_ARG_ENABLE([xcb],
 552     [AS_HELP_STRING([--enable-xcb],
 553         [use XCB for GLX @<:@default=disabled@:>@])],
 554     [enable_xcb="$enableval"],
 555     [enable_xcb=no])
 556 if test "x$enable_xcb" = xyes; then
 557     DEFINES="$DEFINES -DUSE_XCB"
 558 else
 559     enable_xcb=no
 560 fi
 561
 562 dnl
 563 dnl libGL configuration per driver
 564 dnl
 565 case "$mesa_driver" in
 566 xlib)
 567     if test "$x11_pkgconfig" = yes; then
 568         PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 569         GL_PC_REQ_PRIV="x11 xext"
 570         X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 571         GL_LIB_DEPS="$XLIBGL_LIBS"
 572     else
 573         # should check these...
 574         X11_INCLUDES="$X11_INCLUDES $X_CFLAGS"
 575         GL_LIB_DEPS="$X_LIBS -lX11 -lXext"
 576         GL_PC_LIB_PRIV="$GL_LIB_DEPS"
 577         GL_PC_CFLAGS="$X11_INCLUDES"
 578     fi
 579     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm -lpthread"
 580     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm -lpthread"
 581
 582     # if static, move the external libraries to the programs
 583     # and empty the libraries for libGL
 584     if test "$enable_static" = yes; then
 585         APP_LIB_DEPS="$APP_LIB_DEPS $GL_LIB_DEPS"
 586         GL_LIB_DEPS=""
 587     fi
 588     ;;
 589 dri)
 590     # DRI must be shared, I think
 591     if test "$enable_static" = yes; then
 592         AC_MSG_ERROR([Can't use static libraries for DRI drivers])
 593     fi
 594
 595     # Check for libdrm
 596     PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED])
 597     PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 598     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 599     GL_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED dri2proto >= $DRI2PROTO_REQUIRED glproto >= $GLPROTO_REQUIRED"
 600     DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 601
 602     # find the DRI deps for libGL
 603     if test "$x11_pkgconfig" = yes; then
 604         # add xcb modules if necessary
 605         dri_modules="x11 xext xxf86vm xdamage xfixes"
 606         if test "$enable_xcb" = yes; then
 607             dri_modules="$dri_modules x11-xcb xcb-glx"
 608         fi
 609
 610         PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 611         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 612         X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 613         GL_LIB_DEPS="$DRIGL_LIBS"
 614     else
 615         # should check these...
 616         X11_INCLUDES="$X11_INCLUDES $X_CFLAGS"
 617         GL_LIB_DEPS="$X_LIBS -lX11 -lXext -lXxf86vm -lXdamage -lXfixes"
 618         GL_PC_LIB_PRIV="$GL_LIB_DEPS"
 619         GL_PC_CFLAGS="$X11_INCLUDES"
 620
 621         # XCB can only be used from pkg-config
 622         if test "$enable_xcb" = yes; then
 623             PKG_CHECK_MODULES([XCB],[x11-xcb xcb-glx])
 624             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV x11-xcb xcb-glx"
 625             X11_INCLUDES="$X11_INCLUDES $XCB_CFLAGS"
 626             GL_LIB_DEPS="$GL_LIB_DEPS $XCB_LIBS"
 627         fi
 628     fi
 629
 630     # need DRM libs, -lpthread, etc.
 631     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
 632     GL_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
 633     GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
 634     GLESv1_CM_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
 635     GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
 636     GLESv2_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
 637     ;;
 638 osmesa)
 639     # No libGL for osmesa
 640     GL_LIB_DEPS=""
 641     ;;
 642 esac
 643 AC_SUBST([GL_LIB_DEPS])
 644 AC_SUBST([GL_PC_REQ_PRIV])
 645 AC_SUBST([GL_PC_LIB_PRIV])
 646 AC_SUBST([GL_PC_CFLAGS])
 647 AC_SUBST([DRI_PC_REQ_PRIV])
 648 AC_SUBST([GLESv1_CM_LIB_DEPS])
 649 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
 650 AC_SUBST([GLESv2_LIB_DEPS])
 651 AC_SUBST([GLESv2_PC_LIB_PRIV])
 652
 653
 654 dnl
 655 dnl More X11 setup
 656 dnl
 657 if test "$mesa_driver" = xlib; then
 658     DEFINES="$DEFINES -DUSE_XSHM"
 659 fi
 660
 661 dnl
 662 dnl More DRI setup
 663 dnl
 664 AC_ARG_ENABLE([glx-tls],
 665     [AS_HELP_STRING([--enable-glx-tls],
 666         [enable TLS support in GLX @<:@default=disabled@:>@])],
 667     [GLX_USE_TLS="$enableval"],
 668     [GLX_USE_TLS=no])
 669 dnl Directory for DRI drivers
 670 AC_ARG_WITH([dri-driverdir],
 671     [AS_HELP_STRING([--with-dri-driverdir=DIR],
 672         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
 673     [DRI_DRIVER_INSTALL_DIR="$withval"],
 674     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
 675 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
 676 dnl Extra search path for DRI drivers
 677 AC_ARG_WITH([dri-searchpath],
 678     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
 679         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
 680     [DRI_DRIVER_SEARCH_DIR="$withval"],
 681     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
 682 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
 683 dnl Direct rendering or just indirect rendering
 684 AC_ARG_ENABLE([driglx-direct],
 685     [AS_HELP_STRING([--disable-driglx-direct],
 686         [enable direct rendering in GLX and EGL for DRI @<:@default=enabled@:>@])],
 687     [driglx_direct="$enableval"],
 688     [driglx_direct="yes"])
 689 dnl Which drivers to build - default is chosen by platform
 690 AC_ARG_WITH([dri-drivers],
 691     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
 692         [comma delimited DRI drivers list, e.g.
 693         "swrast,i965,radeon" @<:@default=auto@:>@])],
 694     [with_dri_drivers="$withval"],
 695     [with_dri_drivers=yes])
 696 if test "x$with_dri_drivers" = x; then
 697     with_dri_drivers=no
 698 fi
 699
 700 dnl Determine which APIs to support
 701 AC_ARG_ENABLE([opengl],
 702     [AS_HELP_STRING([--disable-opengl],
 703         [disable support for standard OpenGL API @<:@default=no@:>@])],
 704     [enable_opengl="$enableval"],
 705     [enable_opengl=yes])
 706 AC_ARG_ENABLE([gles1],
 707     [AS_HELP_STRING([--enable-gles1],
 708         [enable support for OpenGL ES 1.x API @<:@default=no@:>@])],
 709     [enable_gles1="$enableval"],
 710     [enable_gles1=no])
 711 AC_ARG_ENABLE([gles2],
 712     [AS_HELP_STRING([--enable-gles2],
 713         [enable support for OpenGL ES 2.x API @<:@default=no@:>@])],
 714     [enable_gles2="$enableval"],
 715     [enable_gles2=no])
 716 AC_ARG_ENABLE([gles-overlay],
 717     [AS_HELP_STRING([--enable-gles-overlay],
 718         [build separate OpenGL ES only libraries @<:@default=no@:>@])],
 719     [enable_gles_overlay="$enableval"],
 720     [enable_gles_overlay=no])
 721
 722 API_DEFINES=""
 723 GLES_OVERLAY=0
 724 if test "x$enable_opengl" = xno; then
 725     API_DEFINES="$API_DEFINES -DFEATURE_GL=0"
 726 else
 727     API_DEFINES="$API_DEFINES -DFEATURE_GL=1"
 728 fi
 729 if test "x$enable_gles1" = xyes; then
 730     API_DEFINES="$API_DEFINES -DFEATURE_ES1=1"
 731 fi
 732 if test "x$enable_gles2" = xyes; then
 733     API_DEFINES="$API_DEFINES -DFEATURE_ES2=1"
 734 fi
 735 if test "x$enable_gles_overlay" = xyes -o \
 736     "x$enable_gles1" = xyes -o "x$enable_gles2" = xyes; then
 737     CORE_DIRS="mapi/es1api mapi/es2api $CORE_DIRS"
 738     if test "x$enable_gles_overlay" = xyes; then
 739         GLES_OVERLAY=1
 740     fi
 741 fi
 742 AC_SUBST([API_DEFINES])
 743 AC_SUBST([GLES_OVERLAY])
 744
 745 dnl If $with_dri_drivers is yes, directories will be added through
 746 dnl platform checks
 747 DRI_DIRS=""
 748 case "$with_dri_drivers" in
 749 no) ;;
 750 yes)
 751     DRI_DIRS="yes"
 752     ;;
 753 *)
 754     # verify the requested driver directories exist
 755     dri_drivers=`IFS=', '; echo $with_dri_drivers`
 756     for driver in $dri_drivers; do
 757         test -d "$srcdir/src/mesa/drivers/dri/$driver" || \
 758             AC_MSG_ERROR([DRI driver directory '$driver' doesn't exist])
 759     done
 760     DRI_DIRS="$dri_drivers"
 761     ;;
 762 esac
 763
 764 dnl Set DRI_DIRS, DEFINES and LIB_DEPS
 765 if test "$mesa_driver" = dri; then
 766     # Use TLS in GLX?
 767     if test "x$GLX_USE_TLS" = xyes; then
 768         DEFINES="$DEFINES -DGLX_USE_TLS -DPTHREADS"
 769     fi
 770
 771     # Platform specific settings and drivers to build
 772     case "$host_os" in
 773     linux*)
 774         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
 775         if test "x$driglx_direct" = xyes; then
 776             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 777         fi
 778         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING -DHAVE_ALIAS"
 779
 780         case "$host_cpu" in
 781         x86_64)
 782             # sis is missing because they have not be converted to use
 783             # the new interface.  i810 are missing because there is no
 784             # x86-64 system where they could *ever* be used.
 785             if test "x$DRI_DIRS" = "xyes"; then
 786                 DRI_DIRS="i915 i965 mach64 mga r128 r200 r300 r600 radeon \
 787                     savage tdfx unichrome swrast"
 788             fi
 789             ;;
 790         powerpc*)
 791             # Build only the drivers for cards that exist on PowerPC.
 792             # At some point MGA will be added, but not yet.
 793             if test "x$DRI_DIRS" = "xyes"; then
 794                 DRI_DIRS="mach64 r128 r200 r300 r600 radeon tdfx swrast"
 795             fi
 796             ;;
 797         sparc*)
 798             # Build only the drivers for cards that exist on sparc`
 799             if test "x$DRI_DIRS" = "xyes"; then
 800                 DRI_DIRS="mach64 r128 r200 r300 r600 radeon swrast"
 801             fi
 802             ;;
 803         esac
 804         ;;
 805     freebsd* | dragonfly*)
 806         DEFINES="$DEFINES -DPTHREADS -DUSE_EXTERNAL_DXTN_LIB=1"
 807         DEFINES="$DEFINES -DIN_DRI_DRIVER -DHAVE_ALIAS"
 808         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 809         if test "x$driglx_direct" = xyes; then
 810             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 811         fi
 812         if test "x$GXX" = xyes; then
 813             CXXFLAGS="$CXXFLAGS -ansi -pedantic"
 814         fi
 815
 816         if test "x$DRI_DIRS" = "xyes"; then
 817             DRI_DIRS="i810 i915 i965 mach64 mga r128 r200 r300 r600 radeon tdfx \
 818                 unichrome savage sis swrast"
 819         fi
 820         ;;
 821     gnu*)
 822         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
 823         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING -DHAVE_ALIAS"
 824         ;;
 825     solaris*)
 826         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
 827         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 828         if test "x$driglx_direct" = xyes; then
 829             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 830         fi
 831         ;;
 832     esac
 833
 834     # default drivers
 835     if test "x$DRI_DIRS" = "xyes"; then
 836         DRI_DIRS="i810 i915 i965 mach64 mga r128 r200 r300 r600 radeon \
 837             savage sis tdfx unichrome swrast"
 838     fi
 839
 840     DRI_DIRS=`echo "$DRI_DIRS" | $SED 's/  */ /g'`
 841
 842     # Check for expat
 843     EXPAT_INCLUDES=""
 844     EXPAT_LIB=-lexpat
 845     AC_ARG_WITH([expat],
 846         [AS_HELP_STRING([--with-expat=DIR],
 847             [expat install directory])],[
 848         EXPAT_INCLUDES="-I$withval/include"
 849         CPPFLAGS="$CPPFLAGS $EXPAT_INCLUDES"
 850         LDFLAGS="$LDFLAGS -L$withval/$LIB_DIR"
 851         EXPAT_LIB="-L$withval/$LIB_DIR -lexpat"
 852         ])
 853     AC_CHECK_HEADER([expat.h],[],[AC_MSG_ERROR([Expat required for DRI.])])
 854     AC_CHECK_LIB([expat],[XML_ParserCreate],[],
 855         [AC_MSG_ERROR([Expat required for DRI.])])
 856
 857     # put all the necessary libs together
 858     DRI_LIB_DEPS="$SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm -lpthread $DLOPEN_LIBS $TALLOC_LIBS"
 859 fi
 860 AC_SUBST([DRI_DIRS])
 861 AC_SUBST([EXPAT_INCLUDES])
 862 AC_SUBST([DRI_LIB_DEPS])
 863
 864 case $DRI_DIRS in
 865 *i915*|*i965*)
 866     PKG_CHECK_MODULES([INTEL], [libdrm_intel >= 2.4.21])
 867     ;;
 868 esac
 869
 870 case $DRI_DIRS in
 871 *radeon*|*r200*|*r300*|*r600*)
 872     PKG_CHECK_MODULES([LIBDRM_RADEON],
 873                       [libdrm_radeon libdrm >= $LIBDRM_RADEON_REQUIRED],
 874                       HAVE_LIBDRM_RADEON=yes,
 875                       HAVE_LIBDRM_RADEON=no)
 876
 877     if test "$HAVE_LIBDRM_RADEON" = yes; then
 878         RADEON_CFLAGS="-DHAVE_LIBDRM_RADEON=1 $LIBDRM_RADEON_CFLAGS"
 879         RADEON_LDFLAGS=$LIBDRM_RADEON_LIBS
 880     fi
 881     ;;
 882 esac
 883 AC_SUBST([RADEON_CFLAGS])
 884 AC_SUBST([RADEON_LDFLAGS])
 885
 886
 887 dnl
 888 dnl OSMesa configuration
 889 dnl
 890 if test "$mesa_driver" = xlib; then
 891     default_gl_osmesa=yes
 892 else
 893     default_gl_osmesa=no
 894 fi
 895 AC_ARG_ENABLE([gl-osmesa],
 896     [AS_HELP_STRING([--enable-gl-osmesa],
 897         [enable OSMesa with libGL @<:@default=enabled for xlib driver@:>@])],
 898     [gl_osmesa="$enableval"],
 899     [gl_osmesa="$default_gl_osmesa"])
 900 if test "x$gl_osmesa" = xyes; then
 901     if test "$mesa_driver" = osmesa; then
 902         AC_MSG_ERROR([libGL is not available for OSMesa driver])
 903     else
 904         DRIVER_DIRS="$DRIVER_DIRS osmesa"
 905     fi
 906 fi
 907
 908 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
 909 AC_ARG_WITH([osmesa-bits],
 910     [AS_HELP_STRING([--with-osmesa-bits=BITS],
 911         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
 912     [osmesa_bits="$withval"],
 913     [osmesa_bits=8])
 914 if test "$mesa_driver" != osmesa && test "x$osmesa_bits" != x8; then
 915     AC_MSG_WARN([Ignoring OSMesa channel bits for non-OSMesa driver])
 916     osmesa_bits=8
 917 fi
 918 case "x$osmesa_bits" in
 919 x8)
 920     OSMESA_LIB=OSMesa
 921     ;;
 922 x16|x32)
 923     OSMESA_LIB="OSMesa$osmesa_bits"
 924     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
 925     ;;
 926 *)
 927     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
 928     ;;
 929 esac
 930 AC_SUBST([OSMESA_LIB])
 931
 932 case "$DRIVER_DIRS" in
 933 *osmesa*)
 934     # only link libraries with osmesa if shared
 935     if test "$enable_static" = no; then
 936         OSMESA_LIB_DEPS="-lm -lpthread $SELINUX_LIBS $DLOPEN_LIBS"
 937     else
 938         OSMESA_LIB_DEPS=""
 939     fi
 940     OSMESA_MESA_DEPS=""
 941     OSMESA_PC_LIB_PRIV="-lm -lpthread $SELINUX_LIBS $DLOPEN_LIBS"
 942     ;;
 943 esac
 944 AC_SUBST([OSMESA_LIB_DEPS])
 945 AC_SUBST([OSMESA_MESA_DEPS])
 946 AC_SUBST([OSMESA_PC_REQ])
 947 AC_SUBST([OSMESA_PC_LIB_PRIV])
 948
 949 dnl
 950 dnl EGL configuration
 951 dnl
 952 AC_ARG_ENABLE([egl],
 953     [AS_HELP_STRING([--disable-egl],
 954         [disable EGL library @<:@default=enabled@:>@])],
 955     [enable_egl="$enableval"],
 956     [enable_egl=yes])
 957 if test "x$enable_egl" = xyes; then
 958     SRC_DIRS="$SRC_DIRS egl"
 959     EGL_LIB_DEPS="$DLOPEN_LIBS -lpthread"
 960     EGL_DRIVERS_DIRS=""
 961     if test "$enable_static" != yes; then
 962         # build egl_glx when libGL is built
 963         if test "$mesa_driver" != osmesa; then
 964             EGL_DRIVERS_DIRS="glx"
 965         fi
 966
 967         if test "$mesa_driver" = dri; then
 968             # build egl_dri2 when xcb-dri2 is available
 969             PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb-dri2 xcb-xfixes],
 970                           [have_xcb_dri2=yes],[have_xcb_dri2=no])
 971             PKG_CHECK_MODULES([LIBUDEV], [libudev > 150],
 972                           [have_libudev=yes],[have_libudev=no])
 973
 974             if test "$have_xcb_dri2" = yes; then
 975                 EGL_DRIVER_DRI2=dri2
 976                 DEFINES="$DEFINES -DHAVE_XCB_DRI2"
 977                 if test "$have_libudev" = yes; then
 978                     DEFINES="$DEFINES -DHAVE_LIBUDEV"
 979                 fi
 980             fi
 981         fi
 982
 983         EGL_DRIVERS_DIRS="$EGL_DRIVERS_DIRS $EGL_DRIVER_DRI2"
 984     fi
 985 fi
 986 AC_SUBST([EGL_LIB_DEPS])
 987 AC_SUBST([EGL_DRIVERS_DIRS])
 988
 989 dnl
 990 dnl GLU configuration
 991 dnl
 992 AC_ARG_ENABLE([glu],
 993     [AS_HELP_STRING([--disable-glu],
 994         [enable OpenGL Utility library @<:@default=enabled@:>@])],
 995     [enable_glu="$enableval"],
 996     [enable_glu=yes])
 997 if test "x$enable_glu" = xyes; then
 998     SRC_DIRS="$SRC_DIRS glu"
 999
1000     case "$mesa_driver" in
1001     osmesa)
1002         # Link libGLU to libOSMesa instead of libGL
1003         GLU_LIB_DEPS=""
1004         GLU_PC_REQ="osmesa"
1005         if test "$enable_static" = no; then
1006             GLU_MESA_DEPS='-l$(OSMESA_LIB)'
1007         else
1008             GLU_MESA_DEPS=""
1009         fi
1010         ;;
1011     *)
1012         # If static, empty GLU_LIB_DEPS and add libs for programs to link
1013         GLU_PC_REQ="gl"
1014         GLU_PC_LIB_PRIV="-lm"
1015         if test "$enable_static" = no; then
1016             GLU_LIB_DEPS="-lm"
1017             GLU_MESA_DEPS='-l$(GL_LIB)'
1018         else
1019             GLU_LIB_DEPS=""
1020             GLU_MESA_DEPS=""
1021             APP_LIB_DEPS="$APP_LIB_DEPS -lstdc++"
1022         fi
1023         ;;
1024     esac
1025 fi
1026 if test "$enable_static" = no; then
1027     GLU_LIB_DEPS="$GLU_LIB_DEPS $OS_CPLUSPLUS_LIBS"
1028 fi
1029 GLU_PC_LIB_PRIV="$GLU_PC_LIB_PRIV $OS_CPLUSPLUS_LIBS"
1030 AC_SUBST([GLU_LIB_DEPS])
1031 AC_SUBST([GLU_MESA_DEPS])
1032 AC_SUBST([GLU_PC_REQ])
1033 AC_SUBST([GLU_PC_REQ_PRIV])
1034 AC_SUBST([GLU_PC_LIB_PRIV])
1035 AC_SUBST([GLU_PC_CFLAGS])
1036
1037 dnl
1038 dnl GLw configuration
1039 dnl
1040 AC_ARG_ENABLE([glw],
1041     [AS_HELP_STRING([--disable-glw],
1042         [enable Xt/Motif widget library @<:@default=enabled@:>@])],
1043     [enable_glw="$enableval"],
1044     [enable_glw=yes])
1045 dnl Don't build GLw on osmesa
1046 if test "x$enable_glw" = xyes && test "$mesa_driver" = osmesa; then
1047     AC_MSG_WARN([Disabling GLw since the driver is OSMesa])
1048     enable_glw=no
1049 fi
1050 AC_ARG_ENABLE([motif],
1051     [AS_HELP_STRING([--enable-motif],
1052         [use Motif widgets in GLw @<:@default=disabled@:>@])],
1053     [enable_motif="$enableval"],
1054     [enable_motif=no])
1055
1056 if test "x$enable_glw" = xyes; then
1057     SRC_DIRS="$SRC_DIRS glw"
1058     if test "$x11_pkgconfig" = yes; then
1059         PKG_CHECK_MODULES([GLW],[x11 xt])
1060         GLW_PC_REQ_PRIV="x11 xt"
1061         GLW_LIB_DEPS="$GLW_LIBS"
1062     else
1063         # should check these...
1064         GLW_LIB_DEPS="$X_LIBS -lXt -lX11"
1065         GLW_PC_LIB_PRIV="$GLW_LIB_DEPS"
1066         GLW_PC_CFLAGS="$X11_INCLUDES"
1067     fi
1068
1069     GLW_SOURCES="GLwDrawA.c"
1070     MOTIF_CFLAGS=
1071     if test "x$enable_motif" = xyes; then
1072         GLW_SOURCES="$GLW_SOURCES GLwMDrawA.c"
1073         AC_PATH_PROG([MOTIF_CONFIG], [motif-config], [no])
1074         if test "x$MOTIF_CONFIG" != xno; then
1075             MOTIF_CFLAGS=`$MOTIF_CONFIG --cflags`
1076             MOTIF_LIBS=`$MOTIF_CONFIG --libs`
1077         else
1078             AC_CHECK_HEADER([Xm/PrimitiveP.h], [],
1079                 [AC_MSG_ERROR([Can't locate Motif headers])])
1080             AC_CHECK_LIB([Xm], [XmGetPixmap], [MOTIF_LIBS="-lXm"],
1081                 [AC_MSG_ERROR([Can't locate Motif Xm library])])
1082         fi
1083         # MOTIF_LIBS is prepended to GLW_LIB_DEPS since Xm needs Xt/X11
1084         GLW_LIB_DEPS="$MOTIF_LIBS $GLW_LIB_DEPS"
1085         GLW_PC_LIB_PRIV="$MOTIF_LIBS $GLW_PC_LIB_PRIV"
1086         GLW_PC_CFLAGS="$MOTIF_CFLAGS $GLW_PC_CFLAGS"
1087     fi
1088
1089     # If static, empty GLW_LIB_DEPS and add libs for programs to link
1090     GLW_PC_LIB_PRIV="$GLW_PC_LIB_PRIV"
1091     if test "$enable_static" = no; then
1092         GLW_MESA_DEPS='-l$(GL_LIB)'
1093         GLW_LIB_DEPS="$GLW_LIB_DEPS"
1094     else
1095         APP_LIB_DEPS="$APP_LIB_DEPS $GLW_LIB_DEPS"
1096         GLW_LIB_DEPS=""
1097         GLW_MESA_DEPS=""
1098     fi
1099 fi
1100 AC_SUBST([GLW_LIB_DEPS])
1101 AC_SUBST([GLW_MESA_DEPS])
1102 AC_SUBST([GLW_SOURCES])
1103 AC_SUBST([MOTIF_CFLAGS])
1104 AC_SUBST([GLW_PC_REQ_PRIV])
1105 AC_SUBST([GLW_PC_LIB_PRIV])
1106 AC_SUBST([GLW_PC_CFLAGS])
1107
1108 dnl
1109 dnl GLUT configuration
1110 dnl
1111 if test -f "$srcdir/include/GL/glut.h"; then
1112     default_glut=yes
1113 else
1114     default_glut=no
1115 fi
1116 AC_ARG_ENABLE([glut],
1117     [AS_HELP_STRING([--disable-glut],
1118         [enable GLUT library @<:@default=enabled if source available@:>@])],
1119     [enable_glut="$enableval"],
1120     [enable_glut="$default_glut"])
1121
1122 dnl Can't build glut if GLU not available
1123 if test "x$enable_glu$enable_glut" = xnoyes; then
1124     AC_MSG_WARN([Disabling glut since GLU is disabled])
1125     enable_glut=no
1126 fi
1127 dnl Don't build glut on osmesa
1128 if test "x$enable_glut" = xyes && test "$mesa_driver" = osmesa; then
1129     AC_MSG_WARN([Disabling glut since the driver is OSMesa])
1130     enable_glut=no
1131 fi
1132
1133 if test "x$enable_glut" = xyes; then
1134     SRC_DIRS="$SRC_DIRS glut/glx"
1135     if test "$x11_pkgconfig" = yes; then
1136         PKG_CHECK_MODULES([GLUT],[x11 xmu xi])
1137         GLUT_PC_REQ_PRIV="x11 xmu xi"
1138         GLUT_LIB_DEPS="$GLUT_LIBS"
1139     else
1140         # should check these...
1141         GLUT_LIB_DEPS="$X_LIBS -lX11 -lXmu -lXi"
1142         GLUT_PC_LIB_PRIV="$GLUT_LIB_DEPS"
1143         GLUT_PC_CFLAGS="$X11_INCLUDES"
1144     fi
1145     if test "x$GCC" = xyes; then
1146         GLUT_CFLAGS="$GLUT_CFLAGS -fexceptions"
1147     fi
1148     GLUT_LIB_DEPS="$GLUT_LIB_DEPS -lm"
1149     GLUT_PC_LIB_PRIV="$GLUT_PC_LIB_PRIV -lm"
1150
1151     # If static, empty GLUT_LIB_DEPS and add libs for programs to link
1152     if test "$enable_static" = no; then
1153         GLUT_MESA_DEPS='-l$(GLU_LIB) -l$(GL_LIB)'
1154     else
1155         APP_LIB_DEPS="$APP_LIB_DEPS $GLUT_LIB_DEPS"
1156         GLUT_LIB_DEPS=""
1157         GLUT_MESA_DEPS=""
1158     fi
1159 fi
1160 AC_SUBST([GLUT_LIB_DEPS])
1161 AC_SUBST([GLUT_MESA_DEPS])
1162 AC_SUBST([GLUT_CFLAGS])
1163 AC_SUBST([GLUT_PC_REQ_PRIV])
1164 AC_SUBST([GLUT_PC_LIB_PRIV])
1165 AC_SUBST([GLUT_PC_CFLAGS])
1166
1167 dnl
1168 dnl Program library dependencies
1169 dnl    Only libm is added here if necessary as the libraries should
1170 dnl    be pulled in by the linker
1171 dnl
1172 if test "x$APP_LIB_DEPS" = x; then
1173     case "$host_os" in
1174     solaris*)
1175         APP_LIB_DEPS="-lX11 -lsocket -lnsl -lm"
1176         ;;
1177     cygwin*)
1178         APP_LIB_DEPS="-lX11"
1179         ;;
1180     *)
1181         APP_LIB_DEPS="-lm"
1182         ;;
1183     esac
1184 fi
1185 AC_SUBST([APP_LIB_DEPS])
1186 AC_SUBST([PROGRAM_DIRS])
1187
1188 dnl
1189 dnl Gallium configuration
1190 dnl
1191 AC_ARG_ENABLE([gallium],
1192     [AS_HELP_STRING([--disable-gallium],
1193         [build gallium @<:@default=enabled@:>@])],
1194     [enable_gallium="$enableval"],
1195     [enable_gallium=yes])
1196 if test "x$enable_gallium" = xyes; then
1197     SRC_DIRS="$SRC_DIRS gallium gallium/winsys gallium/targets"
1198     AC_CHECK_HEADER([udis86.h], [HAS_UDIS86="yes"],
1199                 [HAS_UDIS86="no"])
1200     AC_PATH_PROG([LLVM_CONFIG], [llvm-config], [no])
1201 fi
1202
1203 AC_SUBST([LLVM_CFLAGS])
1204 AC_SUBST([LLVM_LIBS])
1205 AC_SUBST([LLVM_LDFLAGS])
1206 AC_SUBST([LLVM_VERSION])
1207
1208 VG_LIB_DEPS=""
1209 EGL_CLIENT_APIS='$(GL_LIB)'
1210 if test "x$enable_gles_overlay" = xyes; then
1211     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GLESv1_CM_LIB) $(GLESv2_LIB)'
1212 fi
1213
1214 dnl
1215 dnl Gallium state trackers configuration
1216 dnl
1217 AC_ARG_WITH([state-trackers],
1218     [AS_HELP_STRING([--with-state-trackers@<:@=DIRS...@:>@],
1219         [comma delimited state_trackers list, e.g.
1220         "egl,glx" @<:@default=auto@:>@])],
1221     [with_state_trackers="$withval"],
1222     [with_state_trackers=yes])
1223
1224 case "$with_state_trackers" in
1225 no)
1226     GALLIUM_STATE_TRACKERS_DIRS=""
1227     ;;
1228 yes)
1229     # look at what else is built
1230     case "$mesa_driver" in
1231     xlib)
1232         GALLIUM_STATE_TRACKERS_DIRS=glx
1233         ;;
1234     dri)
1235         GALLIUM_STATE_TRACKERS_DIRS="dri"
1236         HAVE_ST_DRI="yes"
1237         if test "x$enable_egl" = xyes; then
1238             GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS egl"
1239             HAVE_ST_EGL="yes"
1240         fi
1241         # Have only tested st/xorg on 1.6.0 servers
1242         PKG_CHECK_MODULES(XORG, [xorg-server >= 1.6.0 libdrm >= $LIBDRM_XORG_REQUIRED libkms >= $LIBKMS_XORG_REQUIRED],
1243             HAVE_ST_XORG="yes"; GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS xorg",
1244             HAVE_ST_XORG="no")
1245         ;;
1246     esac
1247     ;;
1248 *)
1249     # verify the requested state tracker exist
1250     state_trackers=""
1251     _state_trackers=`IFS=', '; echo $with_state_trackers`
1252     for tracker in $_state_trackers; do
1253         case "$tracker" in
1254         dri)
1255             if test "x$mesa_driver" != xdri; then
1256                 AC_MSG_ERROR([cannot build dri state tracker without mesa driver set to dri])
1257             fi
1258             HAVE_ST_DRI="yes"
1259             ;;
1260         egl)
1261             if test "x$enable_egl" != xyes; then
1262                 AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1263             fi
1264             HAVE_ST_EGL="yes"
1265             ;;
1266         xorg)
1267             PKG_CHECK_MODULES([XORG], [xorg-server >= 1.6.0])
1268             PKG_CHECK_MODULES([LIBDRM_XORG], [libdrm >= $LIBDRM_XORG_REQUIRED])
1269             PKG_CHECK_MODULES([LIBKMS_XORG], [libkms >= $LIBKMS_XORG_REQUIRED])
1270             HAVE_ST_XORG="yes"
1271             ;;
1272         es)
1273             AC_MSG_WARN([state tracker 'es' has been replaced by --enable-gles-overlay])
1274
1275             if test "x$enable_gles_overlay" != xyes; then
1276                 if test "x$enable_gles1" != xyes -a "x$enable_gles2" != xyes; then
1277                     CORE_DIRS="mapi/es1api mapi/es2api $CORE_DIRS"
1278                 fi
1279                 GLES_OVERLAY=1
1280                 EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GLESv1_CM_LIB) $(GLESv2_LIB)'
1281             fi
1282             tracker=""
1283             ;;
1284         vega)
1285             CORE_DIRS="$CORE_DIRS mapi/vgapi"
1286             VG_LIB_DEPS="$VG_LIB_DEPS -lpthread"
1287             EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(VG_LIB)'
1288             ;;
1289         esac
1290
1291         if test -n "$tracker"; then
1292             test -d "$srcdir/src/gallium/state_trackers/$tracker" || \
1293                 AC_MSG_ERROR([state tracker '$tracker' doesn't exist])
1294             if test -n "$state_trackers"; then
1295                 state_trackers="$state_trackers $tracker"
1296             else
1297                 state_trackers="$tracker"
1298             fi
1299         fi
1300     done
1301     GALLIUM_STATE_TRACKERS_DIRS="$state_trackers"
1302     ;;
1303 esac
1304
1305 AC_SUBST([VG_LIB_DEPS])
1306 AC_SUBST([EGL_CLIENT_APIS])
1307
1308 if test "x$HAVE_ST_EGL" = xyes; then
1309         GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS egl"
1310         # define GLX_DIRECT_RENDERING even when the driver is not dri
1311         if test "x$mesa_driver" != xdri -a "x$driglx_direct" = xyes; then
1312             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1313         fi
1314 fi
1315
1316 if test "x$HAVE_ST_XORG" = xyes; then
1317     PKG_CHECK_MODULES(XEXT, [xextproto >= 7.0.99.1],
1318         HAVE_XEXTPROTO_71="yes"; DEFINES="$DEFINES -DHAVE_XEXTPROTO_71",
1319         HAVE_XEXTPROTO_71="no")
1320 fi
1321
1322 AC_ARG_WITH([egl-platforms],
1323     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1324         [comma delimited native platforms libEGL supports, e.g.
1325         "x11,kms" @<:@default=auto@:>@])],
1326     [with_egl_platforms="$withval"],
1327     [with_egl_platforms=yes])
1328 AC_ARG_WITH([egl-displays],
1329     [AS_HELP_STRING([--with-egl-displays@<:@=DIRS...@:>@],
1330         [DEPRECATED.  Use --with-egl-platforms instead])],
1331     [with_egl_platforms="$withval"])
1332
1333 EGL_PLATFORMS=""
1334 case "$with_egl_platforms" in
1335 yes)
1336     if test "x$enable_egl" = xyes && test "x$mesa_driver" != xosmesa; then
1337         EGL_PLATFORMS="x11"
1338     fi
1339     ;;
1340 *)
1341     if test "x$enable_egl" != xyes; then
1342         AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1343     fi
1344     # verify the requested driver directories exist
1345     egl_platforms=`IFS=', '; echo $with_egl_platforms`
1346     for plat in $egl_platforms; do
1347         test -d "$srcdir/src/gallium/state_trackers/egl/$plat" || \
1348             AC_MSG_ERROR([EGL platform '$plat' does't exist])
1349         if test "$plat" = "fbdev"; then
1350                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/fbdev"
1351         fi
1352     done
1353     EGL_PLATFORMS="$egl_platforms"
1354     ;;
1355 esac
1356 AC_SUBST([EGL_PLATFORMS])
1357
1358 AC_ARG_WITH([egl-driver-dir],
1359     [AS_HELP_STRING([--with-egl-driver-dir=DIR],
1360                     [directory for EGL drivers [[default=${libdir}/egl]]])],
1361     [EGL_DRIVER_INSTALL_DIR="$withval"],
1362     [EGL_DRIVER_INSTALL_DIR='${libdir}/egl'])
1363 AC_SUBST([EGL_DRIVER_INSTALL_DIR])
1364
1365 AC_ARG_WITH([xorg-driver-dir],
1366     [AS_HELP_STRING([--with-xorg-driver-dir=DIR],
1367                     [Default xorg driver directory[[default=${libdir}/xorg/modules/drivers]]])],
1368     [XORG_DRIVER_INSTALL_DIR="$withval"],
1369     [XORG_DRIVER_INSTALL_DIR="${libdir}/xorg/modules/drivers"])
1370 AC_SUBST([XORG_DRIVER_INSTALL_DIR])
1371
1372 AC_ARG_WITH([max-width],
1373     [AS_HELP_STRING([--with-max-width=N],
1374                     [Maximum framebuffer width (4096)])],
1375     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1376      AS_IF([test "${withval}" -gt "4096"],
1377            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1378 )
1379 AC_ARG_WITH([max-height],
1380     [AS_HELP_STRING([--with-max-height=N],
1381                     [Maximum framebuffer height (4096)])],
1382     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1383      AS_IF([test "${withval}" -gt "4096"],
1384            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1385 )
1386
1387 dnl
1388 dnl Gallium LLVM
1389 dnl
1390 AC_ARG_ENABLE([gallium-llvm],
1391     [AS_HELP_STRING([--enable-gallium-llvm],
1392         [build gallium LLVM support @<:@default=disabled@:>@])],
1393     [enable_gallium_llvm="$enableval"],
1394     [enable_gallium_llvm=auto])
1395 if test "x$enable_gallium_llvm" = xyes; then
1396     if test "x$LLVM_CONFIG" != xno; then
1397         LLVM_VERSION=`$LLVM_CONFIG --version`
1398         LLVM_CFLAGS=`$LLVM_CONFIG --cflags`
1399         LLVM_LIBS="`$LLVM_CONFIG --libs jit interpreter nativecodegen bitwriter` -lstdc++"
1400
1401         if test "x$HAS_UDIS86" != xno; then
1402             LLVM_LIBS="$LLVM_LIBS -ludis86"
1403             DEFINES="$DEFINES -DHAVE_UDIS86"
1404         fi
1405         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1406         GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1407         DEFINES="$DEFINES -DGALLIUM_LLVMPIPE -D__STDC_CONSTANT_MACROS"
1408         MESA_LLVM=1
1409     else
1410         MESA_LLVM=0
1411     fi
1412 else
1413     MESA_LLVM=0
1414 fi
1415
1416 dnl
1417 dnl Gallium helper functions
1418 dnl
1419 gallium_check_st() {
1420     if test "x$HAVE_ST_DRI" = xyes || test "x$HAVE_ST_XORG" = xyes; then
1421          GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS $1"
1422     fi
1423     if test "x$HAVE_ST_DRI" = xyes && test "x$2" != x; then
1424          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $2"
1425     fi
1426     if test "x$HAVE_ST_XORG" = xyes && test "x$3" != x; then
1427          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $3"
1428     fi
1429 }
1430
1431
1432 dnl
1433 dnl Gallium SVGA configuration
1434 dnl
1435 AC_ARG_ENABLE([gallium-svga],
1436     [AS_HELP_STRING([--enable-gallium-svga],
1437         [build gallium SVGA @<:@default=disabled@:>@])],
1438     [enable_gallium_svga="$enableval"],
1439     [enable_gallium_svga=auto])
1440 if test "x$enable_gallium_svga" = xyes; then
1441     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga"
1442     gallium_check_st "svga/drm" "dri-vmwgfx" "xorg-vmwgfx"
1443 elif test "x$enable_gallium_svga" = xauto; then
1444     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga"
1445 fi
1446
1447 dnl
1448 dnl Gallium i915 configuration
1449 dnl
1450 AC_ARG_ENABLE([gallium-i915],
1451     [AS_HELP_STRING([--enable-gallium-i915],
1452         [build gallium i915 @<:@default=disabled@:>@])],
1453     [enable_gallium_i915="$enableval"],
1454     [enable_gallium_i915=auto])
1455 if test "x$enable_gallium_i915" = xyes; then
1456     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
1457     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915"
1458     gallium_check_st "i915/drm" "dri-i915" "xorg-i915"
1459 elif test "x$enable_gallium_i915" = xauto; then
1460     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
1461     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915"
1462 fi
1463
1464 dnl
1465 dnl Gallium i965 configuration
1466 dnl
1467 AC_ARG_ENABLE([gallium-i965],
1468     [AS_HELP_STRING([--enable-gallium-i965],
1469         [build gallium i965 @<:@default=disabled@:>@])],
1470     [enable_gallium_i965="$enableval"],
1471     [enable_gallium_i965=auto])
1472 if test "x$enable_gallium_i965" = xyes; then
1473     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i965"
1474     gallium_check_st "i965/drm" "dri-i965" "xorg-i965"
1475 elif test "x$enable_gallium_i965" = xauto; then
1476     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i965"
1477 fi
1478
1479 dnl
1480 dnl Gallium Radeon configuration
1481 dnl
1482 AC_ARG_ENABLE([gallium-radeon],
1483     [AS_HELP_STRING([--enable-gallium-radeon],
1484         [build gallium radeon @<:@default=disabled@:>@])],
1485     [enable_gallium_radeon="$enableval"],
1486     [enable_gallium_radeon=auto])
1487 if test "x$enable_gallium_radeon" = xyes; then
1488     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1489     gallium_check_st "radeon/drm" "dri-radeong" "xorg-radeon"
1490 elif test "x$enable_gallium_radeon" = xauto; then
1491     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1492 fi
1493
1494 dnl
1495 dnl Gallium Radeon r600g configuration
1496 dnl
1497 AC_ARG_ENABLE([gallium-r600],
1498     [AS_HELP_STRING([--enable-gallium-r600],
1499         [build gallium radeon @<:@default=disabled@:>@])],
1500     [enable_gallium_r600="$enableval"],
1501     [enable_gallium_r600=auto])
1502 if test "x$enable_gallium_r600" = xyes; then
1503     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r600"
1504     gallium_check_st "r600/drm" "dri-r600"
1505 fi
1506
1507 dnl
1508 dnl Gallium Nouveau configuration
1509 dnl
1510 AC_ARG_ENABLE([gallium-nouveau],
1511     [AS_HELP_STRING([--enable-gallium-nouveau],
1512         [build gallium nouveau @<:@default=disabled@:>@])],
1513     [enable_gallium_nouveau="$enableval"],
1514     [enable_gallium_nouveau=no])
1515 if test "x$enable_gallium_nouveau" = xyes; then
1516     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau nvfx nv50"
1517     gallium_check_st "nouveau/drm" "dri-nouveau" "xorg-nouveau"
1518 fi
1519
1520 dnl
1521 dnl Gallium swrast configuration
1522 dnl
1523 AC_ARG_ENABLE([gallium-swrast],
1524     [AS_HELP_STRING([--enable-gallium-swrast],
1525         [build gallium swrast @<:@default=auto@:>@])],
1526     [enable_gallium_swrast="$enableval"],
1527     [enable_gallium_swrast=auto])
1528 if test "x$enable_gallium_swrast" = xyes || test "x$enable_gallium_swrast" = xauto; then
1529     if test "x$HAVE_ST_DRI" = xyes; then
1530         GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri-swrast"
1531     fi
1532 fi
1533
1534 dnl prepend CORE_DIRS to SRC_DIRS
1535 SRC_DIRS="$CORE_DIRS $SRC_DIRS"
1536
1537 dnl Restore LDFLAGS and CPPFLAGS
1538 LDFLAGS="$_SAVE_LDFLAGS"
1539 CPPFLAGS="$_SAVE_CPPFLAGS"
1540
1541 dnl Substitute the config
1542 AC_CONFIG_FILES([configs/autoconf])
1543
1544 dnl Replace the configs/current symlink
1545 AC_CONFIG_COMMANDS([configs],[
1546 if test -f configs/current || test -L configs/current; then
1547     rm -f configs/current
1548 fi
1549 ln -s autoconf configs/current
1550 ])
1551
1552 AC_OUTPUT
1553
1554 dnl
1555 dnl Output some configuration info for the user
1556 dnl
1557 echo ""
1558 echo "        prefix:          $prefix"
1559 echo "        exec_prefix:     $exec_prefix"
1560 echo "        libdir:          $libdir"
1561 echo "        includedir:      $includedir"
1562
1563 dnl Driver info
1564 echo ""
1565 echo "        Driver:          $mesa_driver"
1566 if echo "$DRIVER_DIRS" | grep 'osmesa' >/dev/null 2>&1; then
1567     echo "        OSMesa:          lib$OSMESA_LIB"
1568 else
1569     echo "        OSMesa:          no"
1570 fi
1571 if test "$mesa_driver" = dri; then
1572     # cleanup the drivers var
1573     dri_dirs=`echo $DRI_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
1574 if test "x$DRI_DIRS" = x; then
1575     echo "        DRI drivers:     no"
1576 else
1577     echo "        DRI drivers:     $dri_dirs"
1578 fi
1579     echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
1580 fi
1581 echo "        Use XCB:         $enable_xcb"
1582
1583 echo ""
1584 if test "x$MESA_LLVM" = x1; then
1585     echo "        llvm:            yes"
1586     echo "        llvm-config:     $LLVM_CONFIG"
1587     echo "        llvm-version:    $LLVM_VERSION"
1588 else
1589     echo "        llvm:            no"
1590 fi
1591
1592 echo ""
1593 if echo "$SRC_DIRS" | grep 'gallium' >/dev/null 2>&1; then
1594     echo "        Gallium:         yes"
1595     echo "        Gallium dirs:    $GALLIUM_DIRS"
1596     echo "        Target dirs:     $GALLIUM_TARGET_DIRS"
1597     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
1598     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
1599     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
1600     if test "x$HAVE_ST_EGL" = xyes; then
1601         echo "        EGL client APIs: $EGL_CLIENT_APIS"
1602     fi
1603 else
1604     echo "        Gallium:         no"
1605 fi
1606
1607 dnl Libraries
1608 echo ""
1609 echo "        Shared libs:     $enable_shared"
1610 echo "        Static libs:     $enable_static"
1611 if test "$enable_egl" = yes; then
1612     echo "        EGL:             $EGL_DRIVERS_DIRS"
1613     echo "        EGL platforms:   $EGL_PLATFORMS"
1614 else
1615     echo "        EGL:             no"
1616 fi
1617 echo "        GLU:             $enable_glu"
1618 echo "        GLw:             $enable_glw (Motif: $enable_motif)"
1619 echo "        glut:            $enable_glut"
1620
1621 dnl Compiler options
1622 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
1623 cflags=`echo $CFLAGS $OPT_FLAGS $PIC_FLAGS $ARCH_FLAGS | \
1624     $SED 's/^ *//;s/  */ /;s/ *$//'`
1625 cxxflags=`echo $CXXFLAGS $OPT_FLAGS $PIC_FLAGS $ARCH_FLAGS | \
1626     $SED 's/^ *//;s/  */ /;s/ *$//'`
1627 defines=`echo $DEFINES $ASM_FLAGS | $SED 's/^ *//;s/  */ /;s/ *$//'`
1628 echo ""
1629 echo "        CFLAGS:          $cflags"
1630 echo "        CXXFLAGS:        $cxxflags"
1631 echo "        Macros:          $defines"
1632
1633 echo ""
1634 echo "        Run '${MAKE-make}' to build Mesa"
1635 echo ""