configure.ac

   1 AC_PREREQ(2.60)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/pre
   8 AC_INIT(GStreamer Good Plug-ins, 0.10.27,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-good)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE([-Wno-portability 1.10])
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_GIT="no", GST_GIT="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/law/alaw.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl use pretty build output with automake >= 1.11
  36 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  37   [AM_DEFAULT_VERBOSITY=1
  38    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  39
  40 dnl our libraries and install dirs use major.minor as a version
  41 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  42 dnl we override it here if we need to for the release candidate of new series
  43 GST_MAJORMINOR=0.10
  44 AC_SUBST(GST_MAJORMINOR)
  45
  46 dnl FIXME: this macro doesn't actually work;
  47 dnl the generated libtool script has no support for the listed tags.
  48 dnl So this needs to be fixed first if we want to use this
  49 dnl AS_LIBTOOL_TAGS
  50
  51 AC_LIBTOOL_WIN32_DLL
  52 AM_PROG_LIBTOOL
  53
  54 dnl *** required versions of GStreamer stuff ***
  55 GST_REQ=0.10.32
  56 GSTPB_REQ=0.10.32
  57
  58 dnl *** autotools stuff ****
  59
  60 dnl allow for different autotools
  61 AS_AUTOTOOLS_ALTERNATE
  62
  63 dnl Add parameters for aclocal
  64 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  65
  66 dnl set up gettext
  67 dnl the version check needs to stay here because autopoint greps for it
  68 AM_GNU_GETTEXT_VERSION([0.17])
  69 AM_GNU_GETTEXT([external])
  70 AG_GST_GETTEXT([gst-plugins-good-$GST_MAJORMINOR])
  71
  72 dnl *** check for arguments to configure ***
  73
  74 AG_GST_ARG_DEBUG
  75 AG_GST_ARG_PROFILING
  76 AG_GST_ARG_VALGRIND
  77 AG_GST_ARG_GCOV
  78
  79 AG_GST_ARG_EXAMPLES
  80
  81 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  82 AG_GST_ARG_WITH_PACKAGE_NAME
  83 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  84
  85 AG_GST_ARG_WITH_PLUGINS
  86
  87 AG_GST_ARG_ENABLE_EXTERNAL
  88
  89 AG_GST_ARG_ENABLE_EXPERIMENTAL
  90
  91 dnl *** checks for platform ***
  92
  93 dnl * hardware/architecture *
  94
  95 dnl common/m4/gst-arch.m4
  96 dnl check CPU type
  97 AG_GST_ARCH
  98
  99 dnl Determine endianness
 100 AC_C_BIGENDIAN
 101
 102 dnl *** checks for programs ***
 103
 104 dnl find a compiler
 105 AC_PROG_CC
 106 AC_PROG_CC_STDC
 107
 108 dnl determine c++ compiler
 109 AC_PROG_CXX
 110 dnl determine if c++ is available on this system
 111 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 112
 113 dnl determine c++ preprocessor
 114 dnl FIXME: do we need this ?
 115 AC_PROG_CXXCPP
 116
 117 AS_PROG_OBJC
 118
 119 dnl check if the compiler supports '-c' and '-o' options
 120 AM_PROG_CC_C_O
 121
 122 dnl find an assembler
 123 AM_PROG_AS
 124
 125 dnl check if the compiler supports do while(0) macros
 126 AG_GST_CHECK_DOWHILE_MACROS
 127
 128 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 129 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 130
 131 dnl check for gconftool-2
 132 dnl this macro defines an am conditional, so it needs to be run always
 133 AM_GCONF_SOURCE_2
 134
 135 dnl check for documentation tools
 136 GTK_DOC_CHECK([1.3])
 137 AS_PATH_PYTHON([2.1])
 138 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 139
 140 dnl *** checks for libraries ***
 141
 142 dnl check for libm, for sin()
 143 AC_CHECK_LIBM
 144 AC_SUBST(LIBM)
 145
 146 dnl *** checks for header files ***
 147
 148 dnl check if we have ANSI C header files
 149 AC_HEADER_STDC
 150
 151 dnl used by ext/wavpack
 152 AX_CREATE_STDINT_H
 153
 154 dnl used in gst/rtp/gstasteriskh263.c
 155 AC_CHECK_HEADERS([netinet/in.h])
 156 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 157 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 158
 159 dnl used in gst/udp
 160 AC_CHECK_HEADERS([sys/time.h])
 161
 162 dnl *** checks for types/defines ***
 163
 164 dnl Check for FIONREAD ioctl declaration.  This check is needed
 165 dnl for the UDP plugin to build on Solaris
 166 GST_CHECK_FIONREAD
 167
 168 dnl *** checks for structures ***
 169
 170 dnl *** checks for compiler characteristics ***
 171
 172 dnl check if we have GCC inline-asm
 173 AS_GCC_INLINE_ASSEMBLY([HAVE_GCC_ASM=yes], [HAVE_GCC_ASM=no])
 174 if test x$HAVE_GCC_ASM = xyes ; then
 175   AC_DEFINE(HAVE_GCC_ASM, 1,
 176     [Define if compiler supports gcc inline assembly])
 177 fi
 178 AM_CONDITIONAL(HAVE_GCC_ASM, test "x$HAVE_GCC_ASM" = "xyes")
 179
 180 dnl *** checks for library functions ***
 181
 182 LIBS_SAVE=$LIBS
 183 LIBS="$LIBS $LIBM"
 184 AC_CHECK_FUNCS(rint sinh cosh asinh fpclass)
 185 LIBS=$LIBS_SAVE
 186
 187 dnl Check whether isinf() is defined by math.h
 188 AC_CACHE_CHECK([for isinf], ac_cv_have_isinf,
 189     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; int i=isinf(f)]])],[ac_cv_have_isinf="yes"],[ac_cv_have_isinf="no"]))
 190 if test "$ac_cv_have_isinf" = "yes"
 191 then
 192     AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have the `isinf' function.])
 193 fi
 194
 195 dnl Check for mmap (needed by electricfence plugin)
 196 AC_FUNC_MMAP
 197 AM_CONDITIONAL(GST_HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 198
 199 dnl Check for mmap (needed by electricfence plugin)
 200
 201 AC_CHECK_TYPE([struct ip_mreqn], [
 202               AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
 203               [#include <netinet/in.h>])
 204
 205 dnl *** checks for dependency libraries ***
 206
 207 dnl GLib is required
 208 AG_GST_GLIB_CHECK([2.20])
 209
 210 dnl Orc
 211 ORC_CHECK([0.4.11])
 212
 213 dnl checks for gstreamer
 214 dnl uninstalled is selected preferentially -- see pkg-config(1)
 215 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ], yes)
 216 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ], yes)
 217 AG_GST_CHECK_GST_GDP($GST_MAJORMINOR, [$GST_REQ], yes)
 218 AG_GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ], yes)
 219 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 220 AG_GST_CHECK_GST_PLUGINS_BASE($GST_MAJORMINOR, [$GSTPB_REQ], yes)
 221
 222 GST_TOOLS_DIR=`$PKG_CONFIG --variable=toolsdir gstreamer-$GST_MAJORMINOR`
 223 if test -z $GST_TOOLS_DIR; then
 224   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 225 fi
 226 AC_SUBST(GST_TOOLS_DIR)
 227
 228 AC_MSG_NOTICE(Using GStreamer Core Plugins in $GST_PLUGINS_DIR)
 229 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 230
 231 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 232
 233 dnl Check for documentation xrefs
 234 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 235 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 236 GSTPB_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-plugins-base-$GST_MAJORMINOR`"
 237 AC_SUBST(GLIB_PREFIX)
 238 AC_SUBST(GST_PREFIX)
 239 AC_SUBST(GSTPB_PREFIX)
 240
 241 dnl GTK is optional and used in examples
 242 HAVE_GTK=no
 243 GTK2_REQ=2.14.0
 244 GTK3_REQ=2.91.3
 245 if test "x$BUILD_EXAMPLES" = "xyes"; then
 246   AC_MSG_CHECKING([which gtk+ version to compile examples against (optional)])
 247   AC_ARG_WITH([gtk],
 248     AC_HELP_STRING([--with-gtk=3.0|2.0],
 249                    [which gtk+ version to compile against (default: 2.0)]),
 250     [case "$with_gtk" in
 251         2.0) GTK_REQ=$GTK2_REQ ;;
 252         3.0) GTK_REQ=$GTK3_REQ ;;
 253         *) AC_MSG_ERROR([invalid gtk+ version specified]);;
 254     esac],
 255     [with_gtk=2.0
 256      GTK_REQ=$GTK2_REQ])
 257   AC_MSG_RESULT([$with_gtk (>= $GTK_REQ)])
 258   PKG_CHECK_MODULES(GTK, gtk+-$with_gtk >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 259   AC_SUBST(GTK_LIBS)
 260   AC_SUBST(GTK_CFLAGS)
 261 fi
 262 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 263
 264 dnl should we install schemas ?
 265 translit(dnm, m, l) AM_CONDITIONAL(USE_GCONFTOOL, true)
 266 AG_GST_CHECK_FEATURE(GCONFTOOL, [GConf schemas], , [
 267   AC_PATH_PROG(GCONFTOOL, gconftool-2, no)
 268   if test x$GCONFTOOL = xno; then
 269     AC_MSG_WARN(Not installing GConf schemas)
 270     HAVE_GCONFTOOL="no"
 271   else
 272     HAVE_GCONFTOOL="yes"
 273   fi
 274   AC_SUBST(HAVE_GCONFTOOL)
 275 ])
 276
 277 dnl *** set variables based on configure arguments ***
 278
 279 dnl set license and copyright notice
 280 GST_LICENSE="LGPL"
 281 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 282 AC_SUBST(GST_LICENSE)
 283
 284 dnl set location of plugin directory
 285 AG_GST_SET_PLUGINDIR
 286
 287 dnl set release date/time
 288 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 289   ["${srcdir}/gst-plugins-good.doap"],
 290   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 291
 292 dnl define an ERROR_CFLAGS Makefile variable
 293 dnl -Wundef: too many broken headers
 294 dnl -Waggregate-return: causes problems with ObjC code like in osxvideosink
 295 AG_GST_SET_ERROR_CFLAGS($GST_GIT, [
 296         -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 297         -Wwrite-strings -Wold-style-definition
 298         -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar
 299         -Wnested-externs ])
 300
 301 dnl define an ERROR_CXXFLAGS Makefile variable
 302 AG_GST_SET_ERROR_CXXFLAGS($GST_GIT, [
 303         -Wmissing-declarations -Wredundant-decls
 304         -Wwrite-strings
 305         -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar ])
 306
 307 dnl define correct level for debugging messages
 308 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 309
 310 dnl used in examples
 311 AG_GST_DEFAULT_ELEMENTS
 312
 313 dnl *** plug-ins to include ***
 314
 315 dnl these are all the gst plug-ins, compilable without additional libs
 316 dnl videofilter is at the top because others depend on it
 317 AG_GST_CHECK_PLUGIN(videofilter)
 318 AG_GST_CHECK_PLUGIN(alpha)
 319 AG_GST_CHECK_PLUGIN(apetag)
 320 AG_GST_CHECK_PLUGIN(audiofx)
 321 AG_GST_CHECK_PLUGIN(auparse)
 322 AG_GST_CHECK_PLUGIN(autodetect)
 323 AG_GST_CHECK_PLUGIN(avi)
 324 AG_GST_CHECK_PLUGIN(cutter)
 325 AG_GST_CHECK_PLUGIN(debugutils)
 326 AG_GST_CHECK_PLUGIN(deinterlace)
 327 AG_GST_CHECK_PLUGIN(effectv)
 328 AG_GST_CHECK_PLUGIN(equalizer)
 329 AG_GST_CHECK_PLUGIN(flv)
 330 AG_GST_CHECK_PLUGIN(id3demux)
 331 AG_GST_CHECK_PLUGIN(icydemux)
 332 AG_GST_CHECK_PLUGIN(interleave)
 333 AG_GST_CHECK_PLUGIN(flx)
 334 AG_GST_CHECK_PLUGIN(goom)
 335 AG_GST_CHECK_PLUGIN(goom2k1)
 336 AG_GST_CHECK_PLUGIN(imagefreeze)
 337 AG_GST_CHECK_PLUGIN(law)
 338 AG_GST_CHECK_PLUGIN(level)
 339 AG_GST_CHECK_PLUGIN(matroska)
 340 AG_GST_CHECK_PLUGIN(monoscope)
 341 AG_GST_CHECK_PLUGIN(multifile)
 342 AG_GST_CHECK_PLUGIN(multipart)
 343 AG_GST_CHECK_PLUGIN(qtdemux)
 344 AG_GST_CHECK_PLUGIN(replaygain)
 345 AG_GST_CHECK_PLUGIN(rtp)
 346 AG_GST_CHECK_PLUGIN(rtpmanager)
 347 AG_GST_CHECK_PLUGIN(rtsp)
 348 AG_GST_CHECK_PLUGIN(shapewipe)
 349 AG_GST_CHECK_PLUGIN(smpte)
 350 AG_GST_CHECK_PLUGIN(spectrum)
 351 AG_GST_CHECK_PLUGIN(udp)
 352 AG_GST_CHECK_PLUGIN(videobox)
 353 AG_GST_CHECK_PLUGIN(videocrop)
 354 AG_GST_CHECK_PLUGIN(videomixer)
 355 AG_GST_CHECK_PLUGIN(wavenc)
 356 AG_GST_CHECK_PLUGIN(wavparse)
 357 AG_GST_CHECK_PLUGIN(y4m)
 358
 359 dnl *** checks for socket and nsl libraries ***
 360 AC_CHECK_FUNC(socket,,[AC_CHECK_LIB(socket,socket)])
 361
 362 dnl disable gst plugins we might not be able to build on this
 363 dnl platform: udp and rtsp (ugly but minimally invasive)
 364 dnl FIXME: maybe move to sys
 365 AC_CHECK_HEADERS([sys/socket.h], HAVE_SYS_SOCKET_H=yes)
 366 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 367
 368 if test "x$HAVE_SYS_SOCKET_H" != "xyes" -a "x$HAVE_WINSOCK2_H" != "xyes"; then
 369   AG_GST_DISABLE_PLUGIN(udp)
 370   AG_GST_DISABLE_PLUGIN(rtsp)
 371 fi
 372
 373 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 374   WIN32_LIBS="-lws2_32"
 375   AC_SUBST(WIN32_LIBS)
 376 fi
 377
 378 dnl disable experimental plug-ins
 379 if test "x$BUILD_EXPERIMENTAL" != "xyes"; then
 380   AG_GST_DISABLE_PLUGIN(monoscope)
 381 fi
 382
 383 dnl *** sys plug-ins ***
 384
 385 echo
 386 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 387 echo
 388
 389 dnl DirectSound
 390 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECTSOUND, true)
 391 AG_GST_CHECK_FEATURE(DIRECTSOUND, [DirectSound plug-in], directsoundsink, [
 392   HAVE_DIRECTSOUND="no"
 393   save_CFLAGS="$CFLAGS"
 394   save_LDFLAGS="$LDFLAGS"
 395   save_LIBS="$LIBS"
 396   CFLAGS="$CFLAGS $DIRECTSOUND_CFLAGS"
 397   LDFLAGS="$LDFLAGS $DIRECTSOUND_LDFLAGS"
 398   LIBS="$LIBS -ldsound -ldxerr9 -luser32"
 399   AC_MSG_CHECKING(for DirectSound LDFLAGS)
 400   AC_LINK_IFELSE([
 401 #include <windows.h>
 402 #include <dxerr9.h>
 403 #include <dsound.h>
 404
 405 int main ()
 406 {
 407   DXGetErrorString9 (0);
 408   DirectSoundCreate(NULL, NULL, NULL);
 409
 410   return 0;
 411 }
 412 ],
 413     [HAVE_DIRECTSOUND="yes"],
 414     [HAVE_DIRECTSOUND="no"])
 415   AC_MSG_RESULT($HAVE_DIRECTSOUND)
 416   CFLAGS=$save_CFLAGS
 417   LDFLAGS=$save_LDFLAGS
 418   LIBS=$save_LIBS
 419
 420   if test "x$HAVE_DIRECTSOUND" = "xyes";  then
 421     dnl this is much more than we want
 422     DIRECTSOUND_LIBS="-ldsound -ldxerr9 -luser32"
 423     AC_SUBST(DIRECTSOUND_CFLAGS)
 424     AC_SUBST(DIRECTSOUND_LDFLAGS)
 425     AC_SUBST(DIRECTSOUND_LIBS)
 426   fi
 427   AC_SUBST(HAVE_DIRECTSOUND)
 428 ])
 429
 430 dnl *** OSS audio *** (Linux, *BSD)
 431 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS, true)
 432 AG_GST_CHECK_FEATURE(OSS, [OSS audio], ossaudio, [
 433  HAVE_OSS="yes"
 434 dnl Linux and newer BSD versions :
 435  AC_CHECK_HEADER(sys/soundcard.h, [
 436    AC_DEFINE(HAVE_OSS_INCLUDE_IN_SYS,, [Define if OSS includes are in /sys/])
 437    ] , [
 438 dnl Some old BSD versions and also newer OpenBSD versions :
 439    AC_CHECK_HEADER(soundcard.h, [
 440      AC_DEFINE(HAVE_OSS_INCLUDE_IN_ROOT,, [Define if OSS includes are in /])
 441      ], [
 442   dnl Some old BSD versions :
 443      AC_CHECK_HEADER(machine/soundcard.h, [
 444        AC_DEFINE(HAVE_OSS_INCLUDE_IN_MACHINE,,
 445          [Define if OSS includes are in /machine/])
 446        ], [
 447        HAVE_OSS="no"
 448      ])
 449    ])
 450  ])
 451 ])
 452
 453 dnl *** oss4 ***
 454 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS4, true)
 455 AG_GST_CHECK_FEATURE(OSS4, [Open Sound System 4], oss4, [
 456   AC_MSG_CHECKING([Checking if we can build the OSS4 elements])
 457   AC_CHECK_HEADERS([fcntl.h sys/ioctl.h sys/stat.h sys/types.h],
 458       [test -z "$OSS4_MISSING_HEADER" && HAVE_OSS4="yes"],
 459       [OSS4_MISSING_HEADER="yes";HAVE_OSS4="no"])
 460 ])
 461
 462 dnl *** Sun Audio ***
 463 translit(dnm, m, l) AM_CONDITIONAL(USE_SUNAUDIO, true)
 464 AG_GST_CHECK_FEATURE(SUNAUDIO, [Sun Audio], sunaudio, [
 465   AC_CHECK_HEADER(sys/audioio.h, HAVE_SUNAUDIO="yes", HAVE_SUNAUDIO="no")
 466 ])
 467
 468 dnl *** OSX Audio ***
 469 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_AUDIO, true)
 470 AG_GST_CHECK_FEATURE(OSX_AUDIO, [OSX audio], osxaudio, [
 471   AC_CHECK_HEADER(CoreAudio/CoreAudio.h, HAVE_OSX_AUDIO="yes", HAVE_OSX_AUDIO="no")
 472 ])
 473
 474 dnl *** OS X video ***
 475 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_VIDEO, true)
 476 HAVE_OSX_VIDEO="no"
 477 AG_GST_CHECK_FEATURE(OSX_VIDEO, [OSX video], osxvideosink, [
 478   AC_CHECK_HEADER(OpenGL/gl.h, HAVE_OSX_VIDEO="yes", HAVE_OSX_VIDEO="no")
 479 ])
 480 dnl in case header OpenGL/gl.h is found on other platforms
 481 case "$host" in
 482   *-*darwin*)
 483     dnl do nothing
 484     ;;
 485   *)
 486     HAVE_OSX_VIDEO="no"
 487     ;;
 488 esac
 489
 490
 491 dnl *** Video 4 Linux 2 ***
 492 dnl for information about the header/define, see sys/v4l2/gstv4l2element.h
 493 dnl renamed to GST_V4L2 because of some conflict with kernel headers
 494 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L2, true)
 495 AG_GST_CHECK_FEATURE(GST_V4L2, [Video 4 Linux 2], v4l2src, [
 496   AC_MSG_CHECKING([Checking for up to date v4l2 installation])
 497   AC_TRY_COMPILE([
 498 #include <sys/types.h>
 499 #ifdef __sun /* Solaris */
 500 #include <sys/types.h>
 501 #include <sys/videodev2.h>
 502 #else /* Linux */
 503 #include <linux/types.h>
 504 #define _LINUX_TIME_H
 505 #define __user
 506 #include <linux/videodev2.h>
 507 #endif
 508 #if defined(V4L2_MAJOR_VERSION) || defined(V4L2_MINOR_VERSION)
 509 #error too early v4l2 version or no v4l2 at all
 510 #endif
 511     ], [
 512 return 0;
 513     ], [
 514       HAVE_GST_V4L2="yes"
 515       AC_MSG_RESULT(yes)
 516     ], [
 517       HAVE_GST_V4L2="no"
 518       AC_MSG_RESULT(no)
 519
 520       HAVE_VIDEODEV=no
 521       AC_CHECK_HEADER(linux/videodev2.h, [ HAVE_VIDEODEV=yes ],
 522       [
 523         AC_CHECK_HEADER(sys/videodev2.h, [ HAVE_VIDEODEV=yes ])
 524       ])
 525
 526       if test "x$HAVE_VIDEODEV" = "xyes"; then
 527         AC_MSG_WARN([video4linux2 headers were found, but they're old.])
 528         AC_MSG_WARN([Please update v4l2 to compile the v4l2 plugins])
 529       else
 530         AC_MSG_WARN([video4linux2 was not found])
 531       fi
 532     ])
 533
 534   if [ test x$HAVE_GST_V4L2 = xyes ]; then
 535     dnl check for missing v4l2_buffer declaration (see #135919)
 536     MISSING_DECL=0
 537     AC_MSG_CHECKING(struct v4l2_buffer declaration)
 538     AC_TRY_COMPILE([
 539 #include <sys/types.h>
 540 #ifdef __sun /* Solaris */
 541 #include <sys/types.h>
 542 #include <sys/videodev2.h>
 543 #else /* Linux */
 544 #include <linux/types.h>
 545 #define _LINUX_TIME_H
 546 #define __user
 547 #include <linux/videodev2.h>
 548 #endif
 549     ],[
 550 struct v4l2_buffer buf;
 551 buf.index = 0;
 552 return 0;
 553     ], [ AC_MSG_RESULT(yes) ], [ MISSING_DECL=1 && AC_MSG_RESULT(no) ])
 554     if [ test x$MISSING_DECL = x1 ]; then
 555       AC_DEFINE(GST_V4L2_MISSING_BUFDECL, 1, [struct v4l2_buffer missing])
 556     fi
 557
 558     dnl check for XOverlay libraries
 559     AG_GST_CHECK_XV
 560   fi
 561 ])
 562
 563 # Optional gudev for device probing
 564 AC_ARG_WITH([gudev],
 565   AC_HELP_STRING([--with-gudev],
 566     [device detection with gudev]),
 567   [],
 568   [with_gudev=check])
 569 if test x$HAVE_GST_V4L2 = xyes; then
 570   if test x$with_gudev != xno; then
 571       PKG_CHECK_MODULES(GUDEV, [ gudev-1.0 >= 143 ],
 572           [ have_gudev=yes
 573             AC_DEFINE(HAVE_GUDEV, 1,
 574                [Whether gudev is available for device detection])
 575             AC_DEFINE([G_UDEV_API_IS_SUBJECT_TO_CHANGE], 1, [I know the API is subject to change.])
 576           ], [
 577           have_gudev=no
 578           ])
 579   else
 580     have_gudev=no
 581   fi
 582 fi
 583 AC_SUBST(GUDEV_CFLAGS)
 584 AC_SUBST(GUDEV_LIBS)
 585
 586 # Make libv4l2 non-automagic
 587 AC_ARG_WITH([libv4l2],
 588   AC_HELP_STRING([--with-libv4l2],
 589     [support video buffer conversion using libv4l2]),
 590   [],
 591   [with_libv4l2=check])
 592 if test x$HAVE_GST_V4L2 = xyes; then
 593   if test x$with_libv4l2 != xno; then
 594       PKG_CHECK_MODULES(LIBV4L2, libv4l2,
 595           [ have_libv4l2=yes
 596             AC_DEFINE(HAVE_LIBV4L2, 1,
 597                 [Whether libv4l2 is available for video buffer conversion])
 598           ], [
 599           have_libv4l2=no
 600           ])
 601   else
 602     have_libv4l2=no
 603   fi
 604 fi
 605
 606 dnl Check for X11
 607 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 608 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 609                   [ximagesrc], [
 610   AC_PATH_XTRA
 611
 612   dnl now try to find the HEADER
 613   ac_cflags_save="$CFLAGS"
 614   ac_cppflags_save="$CPPFLAGS"
 615   CFLAGS="$CFLAGS $X_CFLAGS"
 616   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 617   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 618
 619   if test "x$HAVE_X" = "xno"
 620   then
 621     AC_MSG_NOTICE([cannot find X11 development files])
 622   else
 623     dnl this is much more than we want
 624     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 625     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 626     dnl it does not add the libs; therefore we add them here
 627     X_LIBS="$X_LIBS -lX11"
 628     AC_SUBST(X_CFLAGS)
 629     AC_SUBST(X_LIBS)
 630
 631     dnl check for Xfixes
 632     PKG_CHECK_MODULES(XFIXES, xfixes, HAVE_XFIXES="yes", HAVE_XFIXES="no")
 633     if test "x$HAVE_XFIXES" = "xyes"
 634     then
 635         XFIXES_CFLAGS="-DHAVE_XFIXES $XFIXES_CFLAGS"
 636     fi
 637     AC_SUBST(XFIXES_LIBS)
 638     AC_SUBST(XFIXES_CFLAGS)
 639
 640     dnl check for Xdamage
 641     PKG_CHECK_MODULES(XDAMAGE, xdamage, HAVE_XDAMAGE="yes", HAVE_XDAMAGE="no")
 642     if test "x$HAVE_XDAMAGE" = "xyes"
 643     then
 644         XDAMAGE_CFLAGS="-DHAVE_XDAMAGE $XDAMAGE_CFLAGS"
 645     fi
 646     AC_SUBST(XDAMAGE_LIBS)
 647     AC_SUBST(XDAMAGE_CFLAGS)
 648   fi
 649   AC_SUBST(HAVE_X)
 650   CFLAGS="$ac_cflags_save"
 651   CPPFLAGS="$ac_cppflags_save"
 652 ])
 653
 654 dnl FIXME: this should be rolled into the test above, it's just an additional
 655 dnl feature of the ximagesrc plug-in
 656 dnl This is the same as in gst-plugins-base
 657 dnl check for X Shm
 658 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 659 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 660   if test x$HAVE_X = xyes; then
 661     AC_CHECK_LIB(Xext, XShmAttach,
 662                  HAVE_XSHM="yes", HAVE_XSHM="no",
 663                  $X_LIBS)
 664     if test "x$HAVE_XSHM" = "xyes"; then
 665       XSHM_LIBS="-lXext"
 666     else
 667       dnl On AIX, it is in XextSam instead, but we still need -lXext
 668       AC_CHECK_LIB(XextSam, XShmAttach,
 669                    HAVE_XSHM="yes", HAVE_XSHM="no",
 670                    $X_LIBS)
 671       if test "x$HAVE_XSHM" = "xyes"; then
 672         XSHM_LIBS="-lXext -lXextSam"
 673       fi
 674     fi
 675   fi
 676 ], ,[
 677   AC_SUBST(HAVE_XSHM)
 678   AC_SUBST(XSHM_LIBS)
 679 ])
 680
 681 dnl for V4L2, we also need to know if we have XVIDEO
 682 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 683 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 684                   [], [
 685   AG_GST_CHECK_XV
 686 ])
 687
 688 dnl *** ext plug-ins ***
 689 dnl keep this list sorted alphabetically !
 690
 691 if test "x$BUILD_EXTERNAL" = "xyes"; then
 692
 693 echo
 694 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 695 echo
 696
 697 dnl *** aalib ***
 698 translit(dnm, m, l) AM_CONDITIONAL(USE_AALIB, true)
 699 AG_GST_CHECK_FEATURE(AALIB, [aalib ASCII Art library], aasink, [
 700   AM_PATH_AALIB(, HAVE_AALIB=yes, HAVE_AALIB=no)
 701   AS_SCRUB_INCLUDE(AALIB_CFLAGS)
 702 ])
 703
 704 dnl *** annodex ***
 705 translit(dnm, m, l) AM_CONDITIONAL(USE_ANNODEX, true)
 706 AG_GST_CHECK_FEATURE(ANNODEX, [XML library], annodex, [
 707   AG_GST_PKG_CHECK_MODULES(ANNODEX, libxml-2.0 >= 2.4.9)
 708 ])
 709
 710 dnl *** cairo ***
 711 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO, true)
 712 AG_GST_CHECK_FEATURE(CAIRO, [Cairo graphics rendering], cairo, [
 713   AG_GST_PKG_CHECK_MODULES(CAIRO, cairo >= 1.0.0)
 714 ])
 715
 716 dnl **** ESound ****
 717 translit(dnm, m, l) AM_CONDITIONAL(USE_ESD, true)
 718 AG_GST_CHECK_FEATURE(ESD, [ESounD sound daemon], esdsink, [
 719   AG_GST_PKG_CHECK_MODULES(ESD, esound >= 0.2.12)
 720   if test $HAVE_ESD = no
 721   then
 722     AM_PATH_ESD(0.2.12, HAVE_ESD="yes")
 723     AS_SCRUB_INCLUDE(ESD_CFLAGS)
 724   fi
 725 ])
 726
 727 dnl *** FLAC ***
 728 translit(dnm, m, l) AM_CONDITIONAL(USE_FLAC, true)
 729 AG_GST_CHECK_FEATURE(FLAC, [FLAC lossless audio], flac, [
 730   AG_GST_PKG_CHECK_MODULES(FLAC, flac >= 1.1.4)
 731 ])
 732
 733 dnl *** GConf ***
 734 translit(dnm, m, l) AM_CONDITIONAL(USE_GCONF, true)
 735 AG_GST_CHECK_FEATURE(GCONF, [GConf libraries], gconfelements, [
 736   AG_GST_PKG_CHECK_MODULES(GCONF, gconf-2.0)
 737 ])
 738
 739 dnl *** GDK pixbuf ***
 740 translit(dnm, m, l) AM_CONDITIONAL(USE_GDK_PIXBUF, true)
 741 AG_GST_CHECK_FEATURE(GDK_PIXBUF, [GDK pixbuf], gdkpixbuf, [
 742   AG_GST_PKG_CHECK_MODULES(GDK_PIXBUF, gdk-pixbuf-2.0 >= 2.8.0)
 743 ])
 744
 745 dnl *** HAL ***
 746 translit(dnm, m, l) AM_CONDITIONAL(USE_HAL, true)
 747 AG_GST_CHECK_FEATURE(HAL, [HAL libraries], halelements, [
 748   AG_GST_PKG_CHECK_MODULES(HAL, [hal >= 0.5.6, dbus-1 >= 0.32])
 749 ])
 750
 751 dnl *** Jack ***
 752 translit(dnm, m, l) AM_CONDITIONAL(USE_JACK, true)
 753 AG_GST_CHECK_FEATURE(JACK, Jack, jack, [
 754   PKG_CHECK_MODULES(JACK, jack >= 0.99.10, HAVE_JACK="yes", HAVE_JACK="no")
 755   AC_SUBST(JACK_CFLAGS)
 756   AC_SUBST(JACK_LIBS)
 757 ])
 758
 759 dnl *** jpeg ***
 760 dnl FIXME: we could use header checks here as well IMO
 761 translit(dnm, m, l) AM_CONDITIONAL(USE_JPEG, true)
 762 AG_GST_CHECK_FEATURE(JPEG, [jpeg library], jpeg, [
 763   AC_ARG_WITH(jpeg-mmx,
 764     [  --with-jpeg-mmx, path to MMX'ified JPEG library])
 765   OLD_LIBS="$LIBS"
 766   if test x$with_jpeg_mmx != x; then
 767     LIBS="$LIBS -L$with_jpeg_mmx"
 768   fi
 769   AC_CHECK_LIB(jpeg-mmx, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 770   JPEG_LIBS="$LIBS -ljpeg-mmx"
 771   LIBS="$OLD_LIBS"
 772   if test x$HAVE_JPEG != xyes; then
 773     AC_CHECK_LIB(jpeg, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 774     JPEG_LIBS="-ljpeg"
 775   fi
 776   AC_SUBST(JPEG_LIBS)
 777 ])
 778
 779 dnl *** libcaca ***
 780 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBCACA, true)
 781 AG_GST_CHECK_FEATURE(LIBCACA, [libcaca coloured ASCII art], cacasink, [
 782   AG_GST_PKG_CHECK_MODULES(LIBCACA, caca)
 783   dnl only newer versions of libcaca ship caca.pc, so try caca-config as well
 784   if test "x$HAVE_LIBCACA" != "xyes"; then
 785     AG_GST_CHECK_CONFIGPROG(LIBCACA, caca-config)
 786     dnl see if it compilation works too, might not if we are cross-compiling
 787     if test "x$HAVE_LIBCACA" = "xyes"; then
 788       AC_CHECK_LIB([caca], [caca_init], [HAVE_LIBCACA=yes],
 789                    [HAVE_LIBCACA=no], [$LIBCACA_LIBS])
 790     fi
 791   fi
 792 ])
 793
 794 dnl *** libdv ***
 795 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBDV, true)
 796 AG_GST_CHECK_FEATURE(LIBDV, [libdv DV demuxer/decoder], dv, [
 797   AG_GST_PKG_CHECK_MODULES(LIBDV, libdv >= 0.100)
 798 ])
 799
 800 dnl *** libpng ***
 801 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBPNG, true)
 802 AG_GST_CHECK_FEATURE(LIBPNG, [Portable Network Graphics library], png, [
 803   AG_GST_PKG_CHECK_MODULES(LIBPNG, libpng >= 1.2)
 804 ])
 805
 806 dnl *** pulseaudio ***
 807 translit(dnm, m, l) AM_CONDITIONAL(USE_PULSE, true)
 808 AG_GST_CHECK_FEATURE(PULSE, [pulseaudio plug-in], pulseaudio, [
 809
 810   dnl used in ext/pulse/pulseutil.c
 811   AC_CHECK_HEADERS([process.h])
 812
 813   AG_GST_PKG_CHECK_MODULES(PULSE, libpulse >= 0.9.10)
 814   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_11, libpulse >= 0.9.11)
 815   if test x$HAVE_PULSE_0_9_11 = xyes; then
 816     AC_DEFINE(HAVE_PULSE_0_9_11, 1, [defined if pulseaudio >= 0.9.11 is available])
 817   fi
 818   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_12, libpulse >= 0.9.12)
 819   if test x$HAVE_PULSE_0_9_12 = xyes; then
 820     AC_DEFINE(HAVE_PULSE_0_9_12, 1, [defined if pulseaudio >= 0.9.12 is available])
 821   fi
 822   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_13, libpulse >= 0.9.13)
 823   if test x$HAVE_PULSE_0_9_13 = xyes; then
 824     AC_DEFINE(HAVE_PULSE_0_9_13, 1, [defined if pulseaudio >= 0.9.13 is available])
 825   fi
 826   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_15, libpulse >= 0.9.15)
 827   if test x$HAVE_PULSE_0_9_15 = xyes; then
 828     AC_DEFINE(HAVE_PULSE_0_9_15, 1, [defined if pulseaudio >= 0.9.15 is available])
 829   fi
 830   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_16, libpulse >= 0.9.16)
 831   if test x$HAVE_PULSE_0_9_16 = xyes; then
 832     AC_DEFINE(HAVE_PULSE_0_9_16, 1, [defined if pulseaudio >= 0.9.16 is available])
 833   fi
 834   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_20, libpulse >= 0.9.20)
 835   if test x$HAVE_PULSE_0_9_20 = xyes; then
 836     AC_DEFINE(HAVE_PULSE_0_9_20, 1, [defined if pulseaudio >= 0.9.20 is available])
 837   fi
 838 ])
 839
 840 dnl *** dv1394 ***
 841 translit(dnm, m, l) AM_CONDITIONAL(USE_DV1394, true)
 842 AG_GST_CHECK_FEATURE(DV1394, [raw1394 and avc1394 library], 1394, [
 843   dnl first test for libraw1394 >= 2.0.0
 844   AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 2.0.0)
 845   AG_GST_PKG_CHECK_MODULES(LIBIEC61883, libiec61883 >= 1.0.0)
 846   dnl now see how far we got
 847   if test x$HAVE_RAW1394 = xyes && \
 848      test x$HAVE_LIBIEC61883 = xyes; then
 849        AG_GST_CHECK_LIBHEADER(AVC1394,
 850         avc1394, avc1394_send_command, $RAW1394_LIBS,
 851         libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 852        AG_GST_CHECK_LIBHEADER(ROM1394,
 853         rom1394, rom1394_free_directory, $RAW1394_LIBS,
 854         libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 855        if test x$HAVE_AVC1394 = xyes && \
 856           test x$HAVE_AVC1394 = xyes && \
 857           test x$HAVE_ROM1394 = xyes; then
 858           HAVE_DV1394=yes
 859           DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS $LIBIEC61883_LIBS"
 860           DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 861           AC_SUBST(DV1394_CFLAGS)
 862           AC_SUBST(DV1394_LIBS)
 863         fi
 864   else
 865        if test x$HAVE_RAW1394 = xno; then
 866           AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.1.0)
 867           AG_GST_CHECK_LIBHEADER(AVC1394,
 868            avc1394, avc1394_send_command, $RAW1394_LIBS,
 869            libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 870           AG_GST_CHECK_LIBHEADER(ROM1394,
 871            rom1394, rom1394_free_directory, $RAW1394_LIBS,
 872            libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 873           if test x$HAVE_RAW1394 = xyes && \
 874              test x$HAVE_AVC1394 = xyes && \
 875              test x$HAVE_ROM1394 = xyes; then
 876              HAVE_DV1394=yes
 877              DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS"
 878              DV1394_CFLAGS="$RAW1394_CFLAGS"
 879              if test x$HAVE_LIBIEC61883 = xyes; then
 880                DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 881                DV1394_LIBS="$DV1394_LIBS $LIBIEC61883_LIBS"
 882              fi
 883              AC_SUBST(DV1394_CFLAGS)
 884              AC_SUBST(DV1394_LIBS)
 885            fi
 886          fi
 887   fi
 888 ])
 889 AM_CONDITIONAL(USE_LIBIEC61883, [ test "x${HAVE_LIBIEC61883}" = xyes ] )
 890
 891 dnl *** shout2 ***
 892 translit(dnm, m, l) AM_CONDITIONAL(USE_SHOUT2, true)
 893 AG_GST_CHECK_FEATURE(SHOUT2, [Shoutcast/Icecast client library], shout2, [
 894   AG_GST_PKG_CHECK_MODULES(SHOUT2, shout >= 2.0)
 895   if test $HAVE_SHOUT2 = no
 896   then
 897     AM_PATH_SHOUT2(HAVE_SHOUT2="yes")
 898     AC_SUBST(SHOUT2_CFLAGS)
 899     AC_SUBST(SHOUT2_LIBS)
 900   fi
 901 ])
 902
 903 dnl *** soup ***
 904 translit(dnm, m, l) AM_CONDITIONAL(USE_SOUP, true)
 905 AG_GST_CHECK_FEATURE(SOUP, [soup http client plugin (2.4)], souphttpsrc, [
 906   PKG_CHECK_MODULES(SOUP, libsoup-gnome-2.4 >= 2.3.2, [
 907     HAVE_SOUP="yes"
 908     AC_DEFINE(HAVE_LIBSOUP_GNOME, 1, [soup gnome integration])
 909   ],[
 910     PKG_CHECK_MODULES(SOUP, libsoup-2.4 >= 2.26, HAVE_SOUP="yes", [
 911       HAVE_SOUP="no"
 912       AC_MSG_RESULT(no)
 913     ])
 914   ])
 915   AC_SUBST(SOUP_CFLAGS)
 916   AC_SUBST(SOUP_LIBS)
 917 ])
 918
 919 dnl *** speex >= 1.0.4 or >= 1.1.5 ***
 920 dnl   1.1.4 and earlier were not API/ABI compatible with 1.0
 921 dnl   1.1.6 is the first to use a .pc/pkg-config file ***
 922 dnl   speex_jitter.h is 1.1.x only
 923 translit(dnm, m, l) AM_CONDITIONAL(USE_SPEEX, true)
 924 AG_GST_CHECK_FEATURE(SPEEX, [speex speech codec], speex, [
 925   AG_GST_PKG_CHECK_MODULES(SPEEX, speex >= 1.1.6)
 926   if test $HAVE_SPEEX = no
 927   then
 928     AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_bits_init, , speex/speex.h, [
 929       AC_CHECK_HEADER(speex/speex_jitter.h, [
 930         dnl speex 1.1.x :
 931         AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_encode_int, , speex/speex.h, [
 932           dnl speex 1.1.5 or + :
 933           HAVE_SPEEX="yes"
 934           SPEEX_LIBS="-lspeex"
 935           AC_SUBST(SPEEX_CFLAGS)
 936           AC_SUBST(SPEEX_LIBS)
 937         ],[
 938           HAVE_SPEEX="no"
 939         ])
 940       ],[
 941         dnl speex 1.0.x :
 942           AC_CHECK_DECL(SPEEX_GET_LOOKAHEAD, [
 943             dnl speex 1.0.4
 944             HAVE_SPEEX="yes"
 945             SPEEX_LIBS="-lspeex"
 946             AC_SUBST(SPEEX_CFLAGS)
 947             AC_SUBST(SPEEX_LIBS)
 948
 949             AC_DEFINE_UNQUOTED(SPEEX_1_0, 1,
 950               [defined if speex 1.0.x API detected])
 951         ],[
 952             HAVE_SPEEX="no"
 953             AC_MSG_NOTICE(You need at least 1.0.4 to compile the speex plugin)
 954         ], [
 955 #include <speex/speex.h>
 956         ])
 957       ])
 958     ])
 959   fi
 960 ])
 961
 962 dnl *** taglib ***
 963 translit(dnm, m, l) AM_CONDITIONAL(USE_TAGLIB, true)
 964 AG_GST_CHECK_FEATURE(TAGLIB, [taglib tagging library], taglib, [
 965   AG_GST_PKG_CHECK_MODULES(TAGLIB, taglib >= 1.5)
 966   if test "x$HAVE_CXX" != "xyes"; then
 967     USE_TAGLIB=false
 968     AC_MSG_NOTICE([Not building taglib plugin: no C++ compiler found])
 969   else
 970     dnl work around bug in taglib 1.5 headers, remove once there is a 1.6
 971     AS_CXX_COMPILER_FLAG([-Wno-attributes], [
 972         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS -Wno-attributes"
 973       ], [
 974         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS"
 975     ])
 976     AC_SUBST(TAGLIB_CXXFLAGS)
 977   fi
 978 ])
 979
 980 dnl *** wavpack ***
 981 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVPACK, true)
 982 AG_GST_CHECK_FEATURE(WAVPACK, [wavpack plug-in], wavpack, [
 983   PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.40.0, HAVE_WAVPACK=yes, [
 984     PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.20, [
 985       HAVE_WAVPACK=yes
 986       AC_DEFINE(WAVPACK_OLD_API, 1, [old wavpack API])
 987     ],[
 988       HAVE_WAVPACK=no
 989       AC_MSG_RESULT(no)
 990     ])
 991   ])
 992   AC_SUBST(WAVPACK_CFLAGS)
 993   AC_SUBST(WAVPACK_LIBS)
 994 ])
 995
 996 dnl *** qtdemux & id3demux & matroska prefer to have zlib ***
 997 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 998 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for id3demux/qtdemux/matroska],, [
 999   AG_GST_CHECK_LIBHEADER(ZLIB,
1000     z, uncompress,, zlib.h, [
1001     HAVE_ZLIB="yes"
1002     ZLIB_LIBS="-lz"
1003     AC_SUBST(ZLIB_LIBS)
1004   ])
1005 ])
1006
1007 dnl *** matroska prefers to have bz2 ***
1008 translit(dnm, m, l) AM_CONDITIONAL(USE_BZ2, true)
1009 AG_GST_CHECK_FEATURE(BZ2, [bz2 library for matroska ],, [
1010   AG_GST_CHECK_LIBHEADER(BZ2, bz2, BZ2_bzCompress, ,bzlib.h, BZ2_LIBS="-lbz2")
1011   AC_SUBST(BZ2_LIBS)
1012 ])
1013
1014 else
1015
1016 dnl not building plugins with external dependencies,
1017 dnl but we still need to set the conditionals
1018 AM_CONDITIONAL(USE_AALIB, false)
1019 AM_CONDITIONAL(USE_ANNODEX, false)
1020 AM_CONDITIONAL(USE_BZ2, false)
1021 AM_CONDITIONAL(USE_CAIRO, false)
1022 AM_CONDITIONAL(USE_DIRECTSOUND, false)
1023 AM_CONDITIONAL(USE_DV1394, false)
1024 AM_CONDITIONAL(USE_ESD, false)
1025 AM_CONDITIONAL(USE_FLAC, false)
1026 AM_CONDITIONAL(USE_GCONF, false)
1027 AM_CONDITIONAL(USE_GCONFTOOL, false)
1028 AM_CONDITIONAL(USE_GDK_PIXBUF, false)
1029 AM_CONDITIONAL(USE_GST_V4L2, false)
1030 AM_CONDITIONAL(USE_HAL, false)
1031 AM_CONDITIONAL(USE_JACK, false)
1032 AM_CONDITIONAL(USE_JPEG, false)
1033 AM_CONDITIONAL(USE_LIBCACA, false)
1034 AM_CONDITIONAL(USE_LIBDV, false)
1035 AM_CONDITIONAL(USE_LIBIEC61883, false)
1036 AM_CONDITIONAL(USE_LIBPNG, false)
1037 AM_CONDITIONAL(USE_OSS, false)
1038 AM_CONDITIONAL(USE_OSS4, false)
1039 AM_CONDITIONAL(USE_OSX_AUDIO, false)
1040 AM_CONDITIONAL(USE_OSX_VIDEO, false)
1041 AM_CONDITIONAL(USE_PULSE, false)
1042 AM_CONDITIONAL(USE_SHOUT2, false)
1043 AM_CONDITIONAL(USE_SOUP, false)
1044 AM_CONDITIONAL(USE_SPEEX, false)
1045 AM_CONDITIONAL(USE_SUNAUDIO, false)
1046 AM_CONDITIONAL(USE_TAGLIB, false)
1047 AM_CONDITIONAL(USE_WAVPACK, false)
1048 AM_CONDITIONAL(USE_X, false)
1049 AM_CONDITIONAL(USE_XSHM, false)
1050 AM_CONDITIONAL(USE_XVIDEO, false)
1051 AM_CONDITIONAL(USE_ZLIB, false)
1052
1053 fi dnl of EXT plugins
1054
1055 dnl *** finalize CFLAGS, LDFLAGS, LIBS
1056
1057 dnl Overview:
1058 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
1059 dnl GST_*:              flags shared by all built objects
1060 dnl GST_ALL_LDFLAGS:    linker flags shared by all
1061 dnl GST_LIB_LDFLAGS:    not needed, we don't install libraries
1062 dnl GST_LT_LDFLAGS:     library versioning of our libraries
1063 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
1064
1065 dnl GST_OPTION_CFLAGS
1066 if test "x$USE_DEBUG" = xyes; then
1067    PROFILE_CFLAGS="-g"
1068 fi
1069 AC_SUBST(PROFILE_CFLAGS)
1070
1071 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
1072   dnl Define _only_ for git (not pre-releases or releases)
1073   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
1074 else
1075   DEPRECATED_CFLAGS=""
1076 fi
1077 AC_SUBST(DEPRECATED_CFLAGS)
1078
1079 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
1080 dnl at make time with e.g. make ERROR_CFLAGS=""
1081 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1082 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1083 AC_SUBST(GST_OPTION_CFLAGS)
1084 AC_SUBST(GST_OPTION_CXXFLAGS)
1085
1086 dnl our libraries need to be versioned correctly
1087 AC_SUBST(GST_LT_LDFLAGS)
1088
1089 dnl FIXME: do we want to rename to GST_ALL_* ?
1090 dnl prefer internal headers to already installed ones
1091 dnl also add builddir include for enumtypes and marshal
1092 dnl add ERROR_CFLAGS, but overridable
1093 GST_CXXFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CXXFLAGS)"
1094 GST_CFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CFLAGS)"
1095 AC_SUBST(GST_CFLAGS)
1096 AC_SUBST(GST_CXXFLAGS)
1097 AC_SUBST(GST_LIBS)
1098
1099 dnl LDFLAGS really should only contain flags, not libs - they get added before
1100 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1101 GST_ALL_LDFLAGS="-no-undefined"
1102 AC_SUBST(GST_ALL_LDFLAGS)
1103
1104 dnl this really should only contain flags, not libs - they get added before
1105 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1106 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
1107 AC_SUBST(GST_PLUGIN_LDFLAGS)
1108
1109 dnl *** output files ***
1110
1111 dnl keep this alphabetic per directory, please
1112 AC_CONFIG_FILES(
1113 Makefile
1114 gst/Makefile
1115 gst/alpha/Makefile
1116 gst/apetag/Makefile
1117 gst/audiofx/Makefile
1118 gst/auparse/Makefile
1119 gst/autodetect/Makefile
1120 gst/avi/Makefile
1121 gst/cutter/Makefile
1122 gst/deinterlace/Makefile
1123 gst/debugutils/Makefile
1124 gst/effectv/Makefile
1125 gst/equalizer/Makefile
1126 gst/flv/Makefile
1127 gst/id3demux/Makefile
1128 gst/icydemux/Makefile
1129 gst/imagefreeze/Makefile
1130 gst/interleave/Makefile
1131 gst/goom/Makefile
1132 gst/goom2k1/Makefile
1133 gst/law/Makefile
1134 gst/level/Makefile
1135 gst/matroska/Makefile
1136 gst/monoscope/Makefile
1137 gst/multifile/Makefile
1138 gst/multipart/Makefile
1139 gst/qtdemux/Makefile
1140 gst/replaygain/Makefile
1141 gst/rtp/Makefile
1142 gst/rtpmanager/Makefile
1143 gst/rtsp/Makefile
1144 gst/shapewipe/Makefile
1145 gst/smpte/Makefile
1146 gst/spectrum/Makefile
1147 gst/udp/Makefile
1148 gst/videobox/Makefile
1149 gst/videocrop/Makefile
1150 gst/videofilter/Makefile
1151 gst/videomixer/Makefile
1152 gst/wavenc/Makefile
1153 gst/wavparse/Makefile
1154 gst/flx/Makefile
1155 gst/y4m/Makefile
1156 ext/Makefile
1157 ext/aalib/Makefile
1158 ext/annodex/Makefile
1159 ext/cairo/Makefile
1160 ext/dv/Makefile
1161 ext/esd/Makefile
1162 ext/flac/Makefile
1163 ext/gconf/Makefile
1164 ext/gdk_pixbuf/Makefile
1165 ext/hal/Makefile
1166 ext/jack/Makefile
1167 ext/jpeg/Makefile
1168 ext/libcaca/Makefile
1169 ext/libpng/Makefile
1170 ext/pulse/Makefile
1171 ext/raw1394/Makefile
1172 ext/shout2/Makefile
1173 ext/soup/Makefile
1174 ext/speex/Makefile
1175 ext/taglib/Makefile
1176 ext/wavpack/Makefile
1177 sys/Makefile
1178 sys/directsound/Makefile
1179 sys/oss/Makefile
1180 sys/oss4/Makefile
1181 sys/osxaudio/Makefile
1182 sys/osxvideo/Makefile
1183 sys/sunaudio/Makefile
1184 sys/v4l2/Makefile
1185 sys/waveform/Makefile
1186 sys/ximage/Makefile
1187 po/Makefile.in
1188 tests/Makefile
1189 tests/check/Makefile
1190 tests/examples/Makefile
1191 tests/examples/audiofx/Makefile
1192 tests/examples/equalizer/Makefile
1193 tests/examples/jack/Makefile
1194 tests/examples/level/Makefile
1195 tests/examples/pulse/Makefile
1196 tests/examples/rtp/Makefile
1197 tests/examples/shapewipe/Makefile
1198 tests/examples/spectrum/Makefile
1199 tests/examples/v4l2/Makefile
1200 tests/files/Makefile
1201 tests/icles/Makefile
1202 gconf/Makefile
1203 gconf/gstreamer.schemas
1204 common/Makefile
1205 common/m4/Makefile
1206 m4/Makefile
1207 docs/Makefile
1208 docs/plugins/Makefile
1209 docs/version.entities
1210 pkgconfig/Makefile
1211 pkgconfig/gstreamer-plugins-good-uninstalled.pc
1212 gst-plugins-good.spec
1213 )
1214
1215 dnl Create the config.h file for Visual Studio builds
1216 dnl Beware of spaces and /'s in some of the shell variable contents.
1217 sed \
1218     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"\n\n#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
1219     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
1220     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
1221     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
1222     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
1223     -e 's/.* GST_MAJORMINOR$/#define GST_MAJORMINOR "'$GST_MAJORMINOR'"/' \
1224     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
1225     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
1226     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
1227     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
1228     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
1229     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
1230     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
1231     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
1232     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
1233     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
1234     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
1235     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
1236     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
1237     -e 's/.* HAVE_WINSOCK2_H$/#define HAVE_WINSOCK2_H 1/' \
1238     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
1239     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
1240     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
1241     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
1242     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
1243     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
1244     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
1245     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
1246     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
1247     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.10"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.10"\n#endif/' \
1248     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
1249     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
1250     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directaudiosink\"/" \
1251     -e "s/.* DEFAULT_AUDIOSRC$/#define DEFAULT_AUDIOSRC \"audiotestsrc\"/" \
1252     -e "s/.* DEFAULT_VIDEOSRC$/#define DEFAULT_VIDEOSRC \"videotestsrc\"/" \
1253     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
1254     config.h.in >win32/common/config.h-new
1255
1256 AC_OUTPUT
1257
1258 AG_GST_OUTPUT_PLUGINS
1259 ORC_OUTPUT
1260