configure.ac

   1 # get rid of that stupid cache mechanism
   2 rm -f config.cache
   3
   4 AC_INIT([ecore], [0.9.9.063], [enlightenment-devel@lists.sourceforge.net])
   5 release="ver-pre-svn-05"
   6 AC_PREREQ([2.52])
   7 AC_CONFIG_SRCDIR([configure.ac])
   8 AC_CONFIG_MACRO_DIR([m4])
   9 AC_CANONICAL_BUILD
  10 AC_CANONICAL_HOST
  11 AC_ISC_POSIX
  12
  13 AM_INIT_AUTOMAKE([1.6 dist-bzip2])
  14 AM_CONFIG_HEADER([config.h])
  15 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  16
  17 AC_GNU_SOURCE
  18
  19 AC_LIBTOOL_WIN32_DLL
  20 define([AC_LIBTOOL_LANG_F77_CONFIG], [:])dnl
  21 AC_PROG_LIBTOOL
  22
  23 VMAJ=`echo $PACKAGE_VERSION | awk -F. '{printf("%s", $1);}'`
  24 VMIN=`echo $PACKAGE_VERSION | awk -F. '{printf("%s", $2);}'`
  25 VMIC=`echo $PACKAGE_VERSION | awk -F. '{printf("%s", $3);}'`
  26 SNAP=`echo $PACKAGE_VERSION | awk -F. '{printf("%s", $4);}'`
  27 version_info=`expr $VMAJ + $VMIN`":$VMIC:$VMIN"
  28 AC_SUBST(version_info)
  29
  30 AM_GNU_GETTEXT_VERSION([0.12.1])
  31 AM_GNU_GETTEXT([external])
  32
  33 case "$host_os" in
  34    mingw32ce* | cegcc*)
  35       ;;
  36    *)
  37       ecore_config_release_info="-release $release"
  38       ecore_con_release_info="-release $release"
  39       ecore_directfb_release_info="-release $release"
  40       ecore_evas_release_info="-release $release"
  41       ecore_fb_release_info="-release $release"
  42       ecore_file_release_info="-release $release"
  43       ecore_imf_evas_release_info="-release $release"
  44       ecore_imf_release_info="-release $release"
  45       ecore_input_release_info="-release $release"
  46       ecore_ipc_release_info="-release $release"
  47       ecore_job_release_info="-release $release"
  48       ecore_quartz_release_info="-release $release"
  49       ecore_release_info="-release $release"
  50       ecore_sdl_release_info="-release $release"
  51       ecore_txt_release_info="-release $release"
  52       ecore_win32_release_info="-release $release"
  53       ecore_x_release_info="-release $release"
  54       ;;
  55 esac
  56 AC_SUBST(ecore_config_release_info)
  57 AC_SUBST(ecore_con_release_info)
  58 AC_SUBST(ecore_directfb_release_info)
  59 AC_SUBST(ecore_evas_release_info)
  60 AC_SUBST(ecore_fb_release_info)
  61 AC_SUBST(ecore_file_release_info)
  62 AC_SUBST(ecore_imf_evas_release_info)
  63 AC_SUBST(ecore_imf_release_info)
  64 AC_SUBST(ecore_input_release_info)
  65 AC_SUBST(ecore_ipc_release_info)
  66 AC_SUBST(ecore_job_release_info)
  67 AC_SUBST(ecore_quartz_release_info)
  68 AC_SUBST(ecore_release_info)
  69 AC_SUBST(ecore_sdl_release_info)
  70 AC_SUBST(ecore_txt_release_info)
  71 AC_SUBST(ecore_win32_release_info)
  72 AC_SUBST(ecore_wince_release_info)
  73 AC_SUBST(ecore_x_release_info)
  74
  75 AC_DEFINE_UNQUOTED(SHARED_LIB_SUFFIX, "$shrext_cmds", [Suffix for shared objects])
  76
  77
  78 ### Default options with respect to host
  79
  80 # dependencies and options
  81 want_curl="no"
  82 want_abstract_sockets="no"
  83 want_gnutls="no"
  84 want_openssl="no"
  85 want_cares="no"
  86 want_cipher="no"
  87 want_signature="no"
  88 want_poll="yes"
  89 want_inotify="no"
  90 want_notify_win32="no"
  91 want_tslib="no"
  92 want_glib="no"
  93
  94 # core modules
  95 want_ecore_job="yes"
  96 want_ecore_txt="yes"
  97 want_ecore_con="no"
  98 want_ecore_ipc="no"
  99 want_ecore_file="yes"
 100 want_ecore_config="no"
 101 want_ecore_imf="no"
 102 want_ecore_input="yes"
 103
 104 # graphic system modules
 105 want_evas_simple_x11="no"
 106 want_ecore_x_xcb="no"
 107 want_ecore_x="no"
 108 want_ecore_win32="no"
 109 want_ecore_quartz="no"
 110 want_ecore_sdl="no"
 111 want_ecore_fb="no"
 112 want_ecore_directfb="no"
 113 want_ecore_wince="no"
 114
 115 # ecore_evas modules
 116 want_ecore_evas="yes"
 117 want_ecore_evas_software_buffer="yes"
 118 want_ecore_evas_software_x11="no"
 119 want_ecore_evas_xrender_x11="no"
 120 want_ecore_evas_opengl_x11="no"
 121 want_ecore_evas_software_16_x11="no"
 122 want_ecore_evas_software_xcb="no"
 123 want_ecore_evas_xrender_xcb="no"
 124 want_ecore_evas_software_gdi="no"
 125 want_ecore_evas_software_ddraw="no"
 126 want_ecore_evas_direct3d="no"
 127 want_ecore_evas_opengl_glew="no"
 128 want_ecore_evas_software_16_ddraw="no"
 129 want_ecore_evas_quartz="no"
 130 want_ecore_evas_software_sdl="no"
 131 want_ecore_evas_directfb="no"
 132 want_ecore_evas_fb="no"
 133 want_ecore_evas_software_16_wince="no"
 134
 135 case "$host_os" in
 136    mingw32ce* | cegcc*)
 137       want_ecore_wince="yes"
 138       want_ecore_evas_software_16_wince="yes"
 139       ;;
 140    mingw*)
 141       want_notify_win32="yes"
 142       want_curl="yes"
 143       want_glib="auto"
 144       want_ecore_imf="yes"
 145       want_ecore_win32="yes"
 146       want_ecore_evas_software_gdi="yes"
 147       want_ecore_evas_software_ddraw="yes"
 148       want_ecore_evas_direct3d="yes"
 149       want_ecore_evas_opengl_glew="yes"
 150       want_ecore_evas_software_16_ddraw="auto"
 151       want_ecore_evas_software_sdl="yes"
 152       ;;
 153    darwin*)
 154       want_curl="yes"
 155       want_glib="auto"
 156       want_gnutls="auto"
 157       want_openssl="auto"
 158       want_ecore_con="yes"
 159       want_ecore_ipc="yes"
 160       want_ecore_config="yes"
 161       want_ecore_imf="yes"
 162       want_ecore_quartz="yes"
 163       want_ecore_evas_quartz="yes"
 164       want_ecore_evas_software_sdl="yes"
 165       ;;
 166    *)
 167       want_curl="yes"
 168       want_glib="auto"
 169       want_abstract_sockets="yes"
 170       want_gnutls="auto"
 171       want_openssl="auto"
 172       want_cipher="yes"
 173       want_signature="yes"
 174       want_inotify="yes"
 175       want_tslib="yes"
 176       want_ecore_con="yes"
 177       want_ecore_ipc="yes"
 178       want_ecore_config="yes"
 179       want_ecore_imf="yes"
 180       want_ecore_x="yes"
 181       want_ecore_evas_software_x11="yes"
 182       want_ecore_evas_xrender_x11="yes"
 183       want_ecore_evas_opengl_x11="yes"
 184       want_ecore_evas_software_16_x11="yes"
 185       want_ecore_evas_software_xcb="yes"
 186       want_ecore_evas_xrender_xcb="yes"
 187       want_ecore_evas_software_sdl="yes"
 188       want_ecore_evas_directfb="yes"
 189       want_ecore_evas_fb="yes"
 190       ;;
 191 esac
 192
 193 requirements_ecore=""
 194 requirements_ecore_con=""
 195 requirements_ecore_config=""
 196 requirements_ecore_directfb=""
 197 requirements_ecore_evas=""
 198 requirements_ecore_fb=""
 199 requirements_ecore_file=""
 200 requirements_ecore_imf=""
 201 requirements_ecore_imf_evas=""
 202 requirements_ecore_input=""
 203 requirements_ecore_ipc=""
 204 requirements_ecore_job=""
 205 requirements_ecore_quartz=""
 206 requirements_ecore_sdl=""
 207 requirements_ecore_txt=""
 208 requirements_ecore_x=""
 209 requirements_ecore_win32=""
 210 requirements_ecore_wince=""
 211
 212 ### Additional options to configure
 213
 214 # abstract sockets (ecore_con.c)
 215 AC_ARG_ENABLE([abstract-sockets],
 216    [AC_HELP_STRING([--disable-abstract-sockets], [disable abstract sockets.])],
 217    [
 218     if test "x${enableval}" = "xyes" ; then
 219        want_abstract_sockets="yes"
 220     else
 221        want_abstract_sockets="no"
 222     fi
 223    ],
 224    [want_abstract_sockets="yes"])
 225
 226 if test "x${want_abstract_sockets}" = "xyes" ; then
 227    AC_DEFINE([HAVE_ABSTRACT_SOCKETS], [1], [Have abstract sockets namespace])
 228 fi
 229
 230 # Simple X11 build/link
 231
 232 AC_ARG_ENABLE(simple-x11,
 233   AC_HELP_STRING([--enable-simple-x11], [enable simple x11 linking]),
 234   [want_evas_simple_x11=$enableval])
 235
 236 # XIM
 237 AC_ARG_ENABLE([xim],
 238    [AC_HELP_STRING([--enable-xim], [enable X Input Method.])],
 239    [
 240     if test "x${enableval}" = "xyes" ; then
 241        want_xim="yes"
 242     else
 243        want_xim="no"
 244     fi
 245    ],
 246    [want_xim="no"])
 247
 248 if test "x${want_xim}" = "xyes" ; then
 249    AC_DEFINE([ENABLE_XIM], [1], [Enable X Input Method])
 250 fi
 251
 252
 253 ### Checks for programs
 254
 255 m4_ifdef([AC_PROG_OBJC],
 256    [
 257     AC_PROG_OBJC
 258     _AM_DEPENDENCIES(OBJC)
 259    ],
 260    [
 261     AC_CHECK_TOOL([OBJC], [gcc])
 262     AC_SUBST([OBJC])
 263     AC_SUBST([OBJCFLAGS])
 264    ])
 265 AC_PROG_CXX
 266 AC_PROG_CC
 267
 268 have_gnu_objc=${ac_cv_objc_compiler_gnu}
 269
 270 # doxygen program for documentation building
 271
 272 EFL_CHECK_DOXYGEN([build_doc="yes"], [build_doc="no"])
 273
 274 # The first call to PKG_CHECK_MODULES is done conditionally,
 275 # so we should include this here:
 276 PKG_PROG_PKG_CONFIG
 277
 278 # Check whether pkg-config supports Requires.private
 279 if $PKG_CONFIG --atleast-pkgconfig-version 0.22; then
 280    pkgconfig_requires_private="Requires.private"
 281 else
 282    pkgconfig_requires_private="Requires"
 283 fi
 284 AC_SUBST(pkgconfig_requires_private)
 285
 286
 287 ### Checks for libraries
 288
 289 # Evil library for compilation on Windows
 290
 291 case "$host_os" in
 292    mingw* | cegcc*)
 293       PKG_CHECK_MODULES([EVIL], [evil])
 294       AC_DEFINE(HAVE_EVIL, 1, [Set to 1 if Evil library is installed])
 295       requirements_ecore="evil ${requirements_ecore}"
 296       requirements_ecore_evas="evil ${requirements_ecore_evas}"
 297       requirements_ecore_file="evil ${requirements_ecore_file}"
 298       requirements_ecore_imf="evil ${requirements_ecore_imf}"
 299       requirements_ecore_imf_evas="evil ${requirements_ecore_imf_evas}"
 300       requirements_ecore_job="evil ${requirements_ecore_job}"
 301       requirements_ecore_txt="evil ${requirements_ecore_txt}"
 302       EFL_ECORE_BUILD="-DEFL_ECORE_BUILD"
 303       EFL_ECORE_JOB_BUILD="-DEFL_ECORE_JOB_BUILD"
 304       EFL_ECORE_TXT_BUILD="-DEFL_ECORE_TXT_BUILD"
 305       EFL_ECORE_FILE_BUILD="-DEFL_ECORE_FILE_BUILD"
 306       EFL_ECORE_EVAS_BUILD="-DEFL_ECORE_EVAS_BUILD"
 307       EFL_ECORE_IMF_BUILD="-DEFL_ECORE_IMF_BUILD"
 308       EFL_ECORE_INPUT_BUILD="-DEFL_ECORE_INPUT_BUILD"
 309       ;;
 310 esac
 311
 312 have_win32=""
 313 have_wince=""
 314 case "$host_os" in
 315    mingw32ce* | cegcc*)
 316       EFL_ECORE_WINCE_BUILD="-DEFL_ECORE_WINCE_BUILD"
 317       requirements_ecore_wince="evil ${requirements_ecore_wince}"
 318       have_wince="yes"
 319       ;;
 320    mingw*)
 321       EFL_ECORE_WIN32_BUILD="-DEFL_ECORE_WIN32_BUILD"
 322       EFL_ECORE_SDL_BUILD="-DEFL_ECORE_SDL_BUILD"
 323       requirements_ecore_win32="evil ${requirements_ecore_win32}"
 324       requirements_ecore_sdl="evil ${requirements_ecore_sdl}"
 325       have_win32="yes"
 326       ;;
 327 esac
 328
 329 AC_SUBST(EFL_ECORE_BUILD)
 330 AC_SUBST(EFL_ECORE_JOB_BUILD)
 331 AC_SUBST(EFL_ECORE_TXT_BUILD)
 332 AC_SUBST(EFL_ECORE_FILE_BUILD)
 333 AC_SUBST(EFL_ECORE_EVAS_BUILD)
 334 AC_SUBST(EFL_ECORE_IMF_BUILD)
 335 AC_SUBST(EFL_ECORE_INPUT_BUILD)
 336 AC_SUBST(EFL_ECORE_WINCE_BUILD)
 337 AC_SUBST(EFL_ECORE_WIN32_BUILD)
 338 AC_SUBST(EFL_ECORE_SDL_BUILD)
 339
 340 AM_CONDITIONAL(ECORE_HAVE_WINCE, test "x${have_wince}" = "xyes")
 341 AM_CONDITIONAL(ECORE_HAVE_WIN32, test "x${have_win32}" = "xyes")
 342
 343 WIN32_LIBS=""
 344 case "$host_os" in
 345    mingw32ce* | cegcc*)
 346       WIN32_LIBS="-lws2"
 347       dlopen_libs="-ldl"
 348       ;;
 349    mingw*)
 350       WIN32_LIBS="-lws2_32"
 351       dlopen_libs="-ldl"
 352       ;;
 353    *)
 354       AC_CHECK_LIB(dl, dlopen, dlopen_libs=-ldl)
 355       ;;
 356 esac
 357 AC_SUBST(WIN32_LIBS)
 358 AC_SUBST(dlopen_libs)
 359
 360 # Eina library
 361
 362 PKG_CHECK_MODULES(EINA, [eina-0])
 363 #FIXME check all the requirements when the eina move will be finished
 364 requirements_ecore="eina-0 ${requirements_ecore}"
 365 requirements_ecore_con="ecore eina-0 ${requirements_ecore_con}"
 366 requirements_ecore_config="ecore eina-0 ${requirements_ecore_config}"
 367 requirements_ecore_directfb="ecore eina-0 ${requirements_ecore_directfb}"
 368 requirements_ecore_evas="ecore eina-0 ${requirements_ecore_evas}"
 369 requirements_ecore_fb="ecore eina-0 ${requirements_ecore_fb}"
 370 requirements_ecore_file="ecore eina-0 ${requirements_ecore_file}"
 371 requirements_ecore_imf="ecore eina-0 ${requirements_ecore_imf}"
 372 requirements_ecore_imf_evas="ecore eina-0 ${requirements_ecore_imf_evas}"
 373 requirements_ecore_input="ecore eina-0 ${requirements_ecore_input}"
 374 requirements_ecore_ipc="ecore eina-0 ${requirements_ecore_ipc}"
 375 requirements_ecore_job="ecore eina-0 ${requirements_ecore_job}"
 376 requirements_ecore_quartz="ecore eina-0 ${requirements_ecore_quartz}"
 377 requirements_ecore_sdl="ecore eina-0 ${requirements_ecore_sdl}"
 378 requirements_ecore_win32="ecore eina-0 ${requirements_ecore_win32}"
 379 requirements_ecore_wince="ecore eina-0 ${requirements_ecore_wince}"
 380 requirements_ecore_x="ecore eina-0 ${requirements_ecore_x}"
 381
 382
 383 # glib support (main loop integration)
 384 AC_ARG_ENABLE([glib],
 385    [AC_HELP_STRING([--disable-glib], [enable glib support. @<:@default=detect@:>@])],
 386    [want_glib=$enableval], [])
 387
 388 if test "x$want_glib" != "xno"; then
 389    PKG_CHECK_MODULES([GLIB], [glib-2.0], [have_glib="yes"], [have_glib="no"])
 390 else
 391    have_glib="no"
 392 fi
 393 if test "x$want_glib" = "xyes" -a "x$have_glib" = "xno"; then
 394    AC_MSG_ERROR([GLib support requested, but no GLib found by pkg-config.])
 395 elif test "x$have_glib" = "xyes"; then
 396    AC_DEFINE(HAVE_GLIB, [1], [Have GLib])
 397    requirements_ecore="glib-2.0 ${requirements_ecore}"
 398 fi
 399
 400
 401 # iconv library (ecore_txt)
 402
 403 iconv_cflags=""
 404 iconv_libs=""
 405 have_iconv="no"
 406 AC_ARG_WITH([iconv-link],
 407    AC_HELP_STRING([--with-iconv-link=ICONV_LINK], [explicitly specify an iconv link option]),
 408    [
 409     iconv_libs=$withval
 410     have_iconv="yes"
 411    ])
 412
 413 AC_MSG_CHECKING(for explicit iconv link options)
 414 if test "x${iconv_libs}" = "x" ; then
 415    AC_MSG_RESULT([no explicit iconv link option])
 416 else
 417    AC_MSG_RESULT([$iconv_libs])
 418 fi
 419
 420 AM_ICONV
 421
 422 if test "x${have_iconv}" = "xno" && test "x${am_cv_func_iconv}" = "xyes" ; then
 423    iconv_cflags=${LIBICONV}
 424    iconv_libs=${LTLIBICONV}
 425    have_iconv="yes"
 426 fi
 427
 428 AC_SUBST(iconv_cflags)
 429 AC_SUBST(iconv_libs)
 430
 431
 432 # SDL library (ecore_sdl)
 433
 434 have_sdl="no"
 435 SDL_CONFIG="sdl-config"
 436 AC_ARG_WITH([sdl-config],
 437    [AC_HELP_STRING([--with-sdl-config=PATH], [use sdl-config specified])],
 438    [
 439     SDL_CONFIG=$withval
 440     AC_MSG_NOTICE([using ${SDL_CONFIG} for sdl-config])
 441    ])
 442
 443 AC_PATH_PROG([SDL_CONFIG], ["sdl-config"], [""], [$PATH])
 444
 445 if test -z "$SDL_CONFIG" ; then
 446    SDL_CFLAGS=`$SDL_CONFIG --cflags`
 447    SDL_LIBS=`$SDL_CONFIG --libs`
 448    AC_SUBST(SDL_CFLAGS)
 449    AC_SUBST(SDL_LIBS)
 450    have_sdl="no"
 451 else
 452    PKG_CHECK_MODULES([SDL], [sdl >= 1.2.0], [have_sdl="yes"], [have_sdl="no"])
 453 fi
 454
 455 if test "x${have_sdl}" = "xyes" ; then
 456    PKG_CHECK_EXISTS([sdl >= 1.3.0],
 457       [AC_DEFINE(BUILD_ECORE_EVAS_SDL_130, 1, [Support for SVN SDL])])
 458 fi
 459
 460
 461 # DirectFB library (ecore_directfb)
 462
 463 PKG_CHECK_MODULES([DIRECTFB],
 464    [directfb >= 0.9.16],
 465    [have_directfb="yes"],
 466    [have_directfb="no"])
 467
 468
 469 # Eet library (ecore_config)
 470
 471 PKG_CHECK_MODULES([EET],
 472    [eet >= 1.0.0],
 473    [have_eet="yes"],
 474    [have_eet="no"])
 475
 476
 477 # Xlib and XCB (ecore_x)
 478
 479 have_x="no"
 480 have_ecore_x="no"
 481 have_ecore_x_xlib="no"
 482 have_ecore_x_xcb="no"
 483
 484 x_dir="";
 485 x_includes="";
 486 x_cflags="";
 487 x_libs="";
 488
 489 ecore_x_libs_private=""
 490
 491 AC_ARG_ENABLE(ecore-x-xcb,
 492    [AC_HELP_STRING([--enable-ecore-x-xcb],
 493        [enable the ecore_x module with XCB backend. [[default=disabled]]])],
 494    [want_ecore_x_xcb=$enableval],
 495    [want_ecore_x_xcb="no"])
 496
 497 AC_MSG_CHECKING(whether ecore_x with XCB backend is to be built)
 498 AC_MSG_RESULT($want_ecore_x_xcb)
 499
 500 if test "x$want_ecore_x_xcb" = "xyes" ; then
 501   PKG_CHECK_MODULES(XCB, xcb xcb-icccm xcb-image xcb-keysyms pixman-1,
 502     [ have_ecore_x_xcb="yes"
 503       requirements_ecore_x="xcb xcb-icccm xcb-image xcb-keysyms pixman-1 ${requirements_ecore_x}" ],
 504     [ have_ecore_x_xcb="no" ])
 505
 506   if test "x$have_ecore_x_xcb" = "xyes" ; then
 507     PKG_CHECK_MODULES(XCB_COMPOSITE, xcb-composite,
 508       [ have_ecore_x_xcb_composite="yes"
 509         requirements_ecore_x="xcb-composite ${requirements_ecore_x}"
 510         AC_DEFINE(ECORE_XCB_COMPOSITE, 1, [Build support for XCB composite]) ],
 511       [ have_ecore_x_xcb_composite="no" ])
 512
 513     PKG_CHECK_MODULES(XCB_DAMAGE, xcb-damage,
 514       [ have_ecore_x_xcb_damage="yes"
 515         requirements_ecore_x="xcb-damage ${requirements_ecore_x}"
 516         AC_DEFINE(ECORE_XCB_DAMAGE, 1, [Build support for XCB damage]) ],
 517       [ have_ecore_x_xcb_damage="no" ])
 518
 519     PKG_CHECK_MODULES(XCB_DPMS, xcb-dpms,
 520       [ have_ecore_x_xcb_dpms="yes"
 521         requirements_ecore_x="xcb-dpms ${requirements_ecore_x}"
 522         AC_DEFINE(ECORE_XCB_DPMS, 1, [Build support for XCB dpms]) ],
 523       [ have_ecore_x_xcb_dpms="no" ])
 524
 525     PKG_CHECK_MODULES(XCB_RANDR, xcb-randr,
 526       [ have_ecore_x_xcb_randr="yes"
 527         requirements_ecore_x="xcb-randr ${requirements_ecore_x}"
 528         AC_DEFINE(ECORE_XCB_RANDR, 1, [Build support for XCB randr]) ],
 529       [ have_ecore_x_xcb_randr="no" ])
 530
 531     PKG_CHECK_MODULES(XCB_RENDER, xcb-render,
 532       [ have_ecore_x_xcb_render="yes"
 533         requirements_ecore_x="xcb-render ${requirements_ecore_x}"
 534         AC_DEFINE(ECORE_XCB_RENDER, 1, [Build support for XCB render]) ],
 535       [ have_ecore_x_xcb_render="no" ])
 536
 537     PKG_CHECK_MODULES(XCB_SCREENSAVER, xcb-screensaver,
 538       [ have_ecore_x_xcb_screensaver="yes"
 539         requirements_ecore_x="xcb-screensaver ${requirements_ecore_x}"
 540         AC_DEFINE(ECORE_XCB_SCREENSAVER, 1, [Build support for XCB screensaver]) ],
 541       [ have_ecore_x_xcb_screensaver="no" ])
 542
 543     PKG_CHECK_MODULES(XCB_SHAPE, xcb-shape,
 544       [ have_ecore_x_xcb_shape="yes"
 545         requirements_ecore_x="xcb-shape ${requirements_ecore_x}"
 546         AC_DEFINE(ECORE_XCB_SHAPE, 1, [Build support for XCB shape]) ],
 547       [ have_ecore_x_xcb_shape="no" ])
 548
 549     PKG_CHECK_MODULES(XCB_SYNC, xcb-sync,
 550       [ have_ecore_x_xcb_sync="yes"
 551         requirements_ecore_x="xcb-sync ${requirements_ecore_x}"
 552         AC_DEFINE(ECORE_XCB_SYNC, 1, [Build support for XCB sync]) ],
 553       [ have_ecore_x_xcb_sync="no" ])
 554
 555     PKG_CHECK_MODULES(XCB_XFIXES, xcb-xfixes,
 556       [ have_ecore_x_xcb_xfixes="yes"
 557         requirements_ecore_x="xcb-xfixes ${requirements_ecore_x}"
 558         AC_DEFINE(ECORE_XCB_FIXES, 1, [Build support for XCB xfixes]) ],
 559       [ have_ecore_x_xcb_xfixes="no" ])
 560
 561     PKG_CHECK_MODULES(XCB_XINERAMA, xcb-xinerama,
 562       [ have_ecore_x_xcb_xinerama="yes"
 563         requirements_ecore_x="xcb-xinerama ${requirements_ecore_x}"
 564         AC_DEFINE(ECORE_XCB_XINERAMA, 1, [Build support for XCB xinerama]) ],
 565       [ have_ecore_x_xcb_xinerama="no" ])
 566
 567     PKG_CHECK_MODULES(XCB_XPRINT, xcb-xprint,
 568       [ have_ecore_x_xcb_xprint="yes"
 569         requirements_ecore_x="xcb-xprint ${requirements_ecore_x}"
 570         AC_DEFINE(ECORE_XCB_XPRINT, 1, [Build support for XCB xprint]) ],
 571       [ have_ecore_x_xcb_xprint="no" ])
 572
 573     PKG_CHECK_MODULES(XCB_XTEST, xcb-xtest,
 574       [ have_ecore_x_xcb_xtest="yes"
 575         requirements_ecore_x="xcb-xtest ${requirements_ecore_x}"
 576         AC_DEFINE(ECORE_XCB_XTEST, 1, [Build support for XCB xtest]) ],
 577       [ have_ecore_x_xcb_xtest="no" ])
 578
 579     AC_DEFINE(HAVE_ECORE_X_XCB, 1, [Defined to 1 if XCB is enabled.])
 580
 581     x_cflags=$XCB_CFLAGS
 582     x_libs=$XCB_LIBS
 583     have_x="yes"
 584
 585     have_ecore_x_xcb_define="-DHAVE_ECORE_X_XCB"
 586     AC_SUBST(have_ecore_x_xcb_define)
 587   fi
 588 fi
 589
 590 if ! test "x$have_ecore_x_xcb" = "xyes" ; then
 591   AC_PATH_XTRA
 592   AC_CHECK_HEADER(X11/X.h,
 593     [
 594      if test "x$want_evas_simple_x11" = "xyes"; then
 595        x_libs="${x_libs} -lX11 -lXext"
 596      else
 597        x_dir=${x_dir:-/usr/X11R6}
 598        x_cflags=${x_cflags:--I${x_includes:-$x_dir/include}}
 599        x_libs="${x_libs:--L${x_libraries:-$x_dir/lib}} -lX11 -lXext"
 600      fi
 601      have_ecore_x_xlib="yes"
 602     ]
 603   )
 604
 605   if test "x$have_ecore_x_xlib" = "xyes"; then
 606     Xcursor_libs=""
 607     Xcursor_cflags=""
 608     use_Xcursor="no"
 609     PCFLAGS=$CFLAGS
 610     CFLAGS="$x_cflags $x_includes"
 611     AC_CHECK_HEADER(X11/Xcursor/Xcursor.h,
 612       [
 613         AC_CHECK_LIB(Xcursor, XcursorImageLoadCursor,
 614           [
 615             AC_DEFINE(ECORE_XCURSOR, 1, [Build support for Xcursor])
 616             Xcursor_cflags=""
 617             Xcursor_libs="-lXcursor"
 618             use_Xcursor="yes"
 619           ], [
 620             Xcursor_cflags=""
 621             Xcursor_libs=""
 622             use_Xcursor="no"
 623           ], [
 624             $x_libs -lXrender
 625           ]
 626         )
 627       ], [
 628         Xcursor_cflags=""
 629         Xcursor_libs=""
 630         use_Xcursor="no"
 631       ], [
 632         #include <X11/Xlib.h>
 633       ]
 634     )
 635     CFLAGS=$PCFLAGS
 636
 637     AC_SUBST(Xcursor_cflags)
 638     AC_SUBST(Xcursor_libs)
 639
 640     ECORE_CHECK_X_EXTENSION([Xkb], [XKB.h], [X11], [XkbSetDetectableAutoRepeat])
 641     ECORE_CHECK_X_EXTENSION([Xcomposite], [Xcomposite.h], [Xcomposite], [XCompositeQueryExtension])
 642     ECORE_CHECK_X_EXTENSION([Xdamage], [Xdamage.h], [Xdamage], [XDamageSubtract])
 643     ECORE_CHECK_X_EXTENSION([Xdpms], [dpms.h], [Xdpms], [DPMSQueryExtension])
 644     if test "x$use_xdpms" = "xno" ; then
 645       ECORE_CHECK_X_EXTENSION([Xdpms], [dpms.h], [Xext], [DPMSQueryExtension])
 646     fi
 647     ECORE_CHECK_X_EXTENSION([Xfixes], [Xfixes.h], [Xfixes], [XFixesExpandRegion])
 648     ECORE_CHECK_X_EXTENSION([Xinerama], [Xinerama.h], [Xinerama], [XineramaQueryScreens])
 649     ECORE_CHECK_X_EXTENSION([Xprint], [Print.h], [Xp], [XpQueryScreens])
 650     ECORE_CHECK_X_EXTENSION([Xrandr], [Xrandr.h], [Xrandr], [XRRGetScreenResourcesCurrent])
 651     ECORE_CHECK_X_EXTENSION([Xrender], [Xrender.h], [Xrender], [XRenderFindVisualFormat])
 652     ECORE_CHECK_X_EXTENSION([Xtest], [XTest.h], [Xtst], [XTestFakeKeyEvent])
 653     ECORE_CHECK_X_EXTENSION([Xss], [scrnsaver.h], [Xss], [XScreenSaverSelectInput])
 654
 655     ecore_x_libs_private="${Xcursor_libs} ${XKB_LIBS} ${XCOMPOSITE_LIBS} ${XDAMAGE_LIBS} ${XDPMS_LIBS} ${XFIXES_LIBS} ${XINERAMA_LIBS} ${XPRINT_LIBS} ${XRANDR_LIBS} ${XRENDER_LIBS} ${XTEST_LIBS} ${XSS_LIBS} "
 656
 657     AC_DEFINE(HAVE_ECORE_X_XLIB, 1, [Defined to 1 if Xlib is enabled.])
 658     have_x="yes"
 659
 660     have_ecore_x_xlib="yes"
 661   fi
 662 fi
 663
 664 AC_SUBST(x_cflags)
 665 AC_SUBST(x_includes)
 666 AC_SUBST(x_libs)
 667 AC_SUBST(ecore_x_libs_private)
 668
 669 AM_CONDITIONAL(BUILD_ECORE_X_XLIB, test $have_ecore_x_xlib = yes)
 670 AM_CONDITIONAL(BUILD_ECORE_X_XCB, test $have_ecore_x_xcb = yes)
 671
 672
 673 # Evas library (ecore_config, ecore_input, ecore_imf_evas and ecore_evas)
 674
 675 PKG_CHECK_MODULES([EVAS], [evas >= 0.9.9],
 676    [have_evas="yes"],
 677    [have_evas="no"])
 678
 679
 680 ### Checks for header files
 681
 682 AC_HEADER_SYS_WAIT
 683
 684 case "$host_os" in
 685    mingw* | cegcc*)
 686       AC_DEFINE(HAVE_DLFCN_H, 1, [Define to 1 if you have the <dlfcn.h> header file.])
 687       AC_DEFINE(HAVE_SYS_MMAN_H, 1, [Define to 1 if you have the <sys/mman.h> header file.])
 688       AC_DEFINE(HAVE_SYS_TIME_H, 1, [Define to 1 if you have the <sys/time.h> header file.])
 689       ;;
 690    *)
 691       AC_CHECK_HEADERS([dlfcn.h features.h langinfo.h locale.h netdb.h netinet/in.h sys/time.h sys/mman.h signal.h sys/resource.h])
 692       ;;
 693 esac
 694
 695 # Framebuffer (ecore_fb)
 696 have_fb="no"
 697 AC_CHECK_HEADER([linux/fb.h],
 698    [AC_CHECK_HEADER([linux/input.h], [have_fb="yes"])])
 699
 700 # Quartz header files (ecore_quartz)
 701
 702 quartz_ldflags="";
 703 have_quartz="no"
 704
 705 if test "x${have_gnu_objc}" = "xyes" ; then
 706    AC_LANG_PUSH([Objective C])
 707    AC_CHECK_HEADER([Cocoa/Cocoa.h],
 708       [
 709        have_quartz="yes"
 710        quartz_ldflags="-framework Cocoa"
 711       ],
 712       [have_quartz="no"])
 713    AC_LANG_POP([Objective C])
 714 fi
 715
 716 AC_SUBST(quartz_ldflags)
 717
 718 # basic pthread support
 719
 720 EFL_CHECK_PTHREAD([have_pthread="yes"], [have_pthread="no"])
 721
 722 ### Checks for types
 723 AC_CHECK_SIZEOF(int, 4)
 724 AC_CHECK_SIZEOF(long, 4)
 725
 726
 727 ### Checks for structures
 728
 729
 730 ### Checks for compiler characteristics
 731 AM_PROG_CC_STDC
 732 AC_C_CONST
 733 AC_C_BIGENDIAN
 734 AC_HEADER_STDC
 735 AC_C___ATTRIBUTE__
 736
 737 WIN32_CPPFLAGS=""
 738 WIN32_CFLAGS=""
 739 case "$host_os" in
 740    mingw32ce*)
 741       WIN32_CPPFLAGS="-D_WIN32_WCE=0x0420"
 742       ;;
 743    cegcc*)
 744       WIN32_CPPFLAGS="-D_WIN32_WCE=0x0420"
 745       WIN32_CFLAGS="-mwin32"
 746       ;;
 747    mingw*)
 748       WIN32_CPPFLAGS="-D_WIN32_WINNT=0x0500"
 749       ;;
 750 esac
 751 AC_SUBST(WIN32_CPPFLAGS)
 752 AC_SUBST(WIN32_CFLAGS)
 753
 754
 755 ### Checks for linker characteristics
 756
 757 # use --enable-auto-import on Windows
 758
 759 lt_enable_auto_import=""
 760 case "$host_os" in
 761    mingw* | cegcc*)
 762       lt_enable_auto_import="-Wl,--enable-auto-import"
 763       ;;
 764 esac
 765 AC_SUBST(lt_enable_auto_import)
 766
 767 ### Checks for library functions
 768 AC_FUNC_ALLOCA
 769 AC_CHECK_FUNCS(gettimeofday strlcpy)
 770
 771 have_atfile_source=auto
 772 AC_ARG_ENABLE(atfile-source,
 773         AC_HELP_STRING([--disable-atfile-source],
 774                        [disable use of atfile source functions as openat and mkdirat @<:@default=detect@:>@]),
 775         [have_atfile_source=$enableval], [have_atfile_source=auto])
 776
 777 if test "x$have_atfile_source" != "xno"; then
 778         AC_CHECK_FUNCS(mkdirat,
 779                 [
 780                 have_atfile_source=yes
 781                 AC_DEFINE(HAVE_ATFILE_SOURCE, 1, [mkdirat exists])
 782                 ],
 783                 [
 784                 if test "x$have_atfile_source" = "xyes"; then
 785                         AC_MSG_ERROR([required atfile-source but no mkdirat()])
 786                 fi
 787                 have_atfile_source=no
 788                 ])
 789 fi
 790
 791 ### Ecore modules
 792
 793 ## Core modules
 794
 795 # ecore_job
 796 ECORE_CHECK_MODULE([Job], [${want_ecore_job}])
 797
 798 # ecore_txt
 799 ECORE_CHECK_MODULE([Txt], [${want_ecore_txt}], [$have_iconv])
 800
 801 # ecore_con
 802 ECORE_CHECK_MODULE([Con], [${want_ecore_con}])
 803
 804 have_curl="no"
 805 have_gnutls="no"
 806 have_openssl="no"
 807 have_cares="no"
 808 if test "x${have_ecore_con}" = "xyes" ; then
 809
 810    ECORE_CHECK_CURL([${want_curl}],
 811       [
 812        have_curl="yes"
 813        requirements_ecore_con="libcurl ${requirements_ecore_con}"
 814       ],
 815       [have_curl="no"])
 816
 817    ECORE_CHECK_GNUTLS([${want_gnutls}],
 818       [have_gnutls="yes"],
 819       [have_gnutls="no"])
 820
 821    ECORE_CHECK_OPENSSL([${want_openssl}],
 822       [have_openssl="yes"],
 823       [have_openssl="no"])
 824
 825    if test "x${have_gnutls}" = "xyes" ; then
 826       requirements_ecore_con="gnutls ${requirements_ecore_con}"
 827       # no need to add it to req_ecore_ipc, since they
 828       # depends on ecore_con anyway.
 829    else
 830       if test "x${have_openssl}" = "xyes" ; then
 831          requirements_ecore_con="openssl ${requirements_ecore_con}"
 832          # no need to add it to req_ecore_ipc, since they
 833          # depends on ecore_con anyway.
 834       fi
 835    fi
 836
 837    ECORE_CHECK_CARES([${want_cares}],
 838       [
 839        have_cares="yes"
 840        requirements_ecore_con="libcares ${requirements_ecore_con}"
 841       ],
 842       [have_cares="no"])
 843
 844 fi
 845
 846 AM_CONDITIONAL([HAVE_CARES], [test "x${have_cares}" = "xyes"])
 847
 848 # ecore_ipc
 849 ECORE_CHECK_MODULE([Ipc], [${want_ecore_ipc}], [${have_ecore_con}],
 850    [requirements_ecore_ipc="ecore-con ${requirements_ecore_ipc}"])
 851
 852 # ecore_file
 853 ECORE_CHECK_MODULE([File], [${want_ecore_file}])
 854
 855 have_poll="no"
 856 have_inotify="no"
 857 have_notify_win32="no"
 858 if test "x${have_ecore_file}" = "xyes" ; then
 859    ECORE_CHECK_POLL([${want_poll}], [have_poll="yes"], [have_poll="no"])
 860    ECORE_CHECK_INOTIFY([${want_inotify}], [have_inotify="yes"], [have_inotify="no"])
 861    ECORE_CHECK_NOTIFY_WIN32([${want_notify_win32}], [have_notify_win32="yes"], [have_notify_win32="no"])
 862
 863    if test "x${have_ecore_con}" = "xyes" ; then
 864       requirements_ecore_file="ecore-con ${requirements_ecore_file}"
 865    fi
 866 fi
 867
 868 # ecore_config
 869 ecore_config_deps="no"
 870 if test "x${have_eet}" = "xyes" -a "x${have_evas}"  -a "x${have_ecore_ipc}" ; then
 871    ecore_config_deps="yes"
 872 fi
 873
 874 ECORE_CHECK_MODULE([Config], [${want_ecore_config}], [${ecore_config_deps}],
 875    [requirements_ecore_config="ecore-ipc evas eet ${requirements_ecore_config}"])
 876
 877 # ecore_imf
 878
 879 ECORE_CHECK_MODULE([IMF], [${want_ecore_imf}])
 880
 881 # ecore_imf_evas
 882
 883 ecore_imf_evas_deps="no"
 884 if test "x${have_ecore_imf}" = "xyes" -a "x${have_evas}" = "xyes" ; then
 885    ecore_imf_evas_deps="yes"
 886 fi
 887
 888 ECORE_CHECK_MODULE([IMF_EVAS], [${want_ecore_imf}], [${ecore_imf_evas_deps}],
 889    [requirements_ecore_imf_evas="ecore-imf evas ${requirements_ecore_imf_evas}"])
 890
 891 # ecore_input
 892 ECORE_CHECK_MODULE([Input], [${want_ecore_input}], [${have_evas}],
 893    [requirements_ecore_input="evas ${requirements_ecore_input}"])
 894
 895 ## Graphic systems
 896
 897 # ecore_x{cb}
 898
 899 ecore_x_deps="no"
 900 if test "x${have_x}" = "xyes" -a \
 901         "x${have_ecore_input}" = "xyes" -a \
 902         "x${have_ecore_txt}" = "xyes" ; then
 903    ecore_x_deps="yes"
 904 fi
 905
 906 ECORE_CHECK_MODULE([X], [${want_ecore_x}], [${ecore_x_deps}],
 907   [
 908    ecore_x_libs="$ecore_x_libs $x_libs"
 909    requirements_ecore_x="ecore-input ecore-txt ${requirements_ecore_x}"
 910   ])
 911
 912 # ecore_win32
 913
 914 ECORE_CHECK_MODULE([Win32], [${want_ecore_win32}], [${have_ecore_input}],
 915    [
 916     ecore_win32_libs="-lole32 -lgdi32"
 917     requirements_ecore_win32="ecore-input ${requirements_ecore_win32}"
 918    ])
 919 AC_SUBST(ecore_win32_libs)
 920
 921 # ecore_quartz
 922
 923 ecore_quartz_deps="no"
 924 if test "x${have_ecore_input}" = "xyes" -a "x${have_quartz}" = "xyes" ; then
 925    ecore_quartz_deps="yes"
 926 fi
 927
 928 ECORE_CHECK_MODULE([QUARTZ], [${want_ecore_quartz}], [${ecore_quartz_deps}],
 929    [requirements_ecore_quartz="ecore-input ${requirements_ecore_quartz}"])
 930
 931 # ecore_sdl
 932
 933 ecore_sdl_deps="no"
 934 if test "x${have_sdl}" = "xyes" -a "x${have_ecore_input}" = "xyes" ; then
 935    ecore_sdl_deps="yes"
 936 fi
 937
 938 ECORE_CHECK_MODULE([SDL], [${want_ecore_sdl}], [${ecore_sdl_deps}],
 939    [requirements_ecore_sdl="ecore-input ${requirements_ecore_sdl}"])
 940
 941 # ecore_fb
 942 ECORE_CHECK_MODULE([FB], [${want_ecore_fb}], [$have_fb])
 943
 944 if test "x${have_ecore_fb}" = "xyes" ; then
 945    ECORE_CHECK_TSLIB([${want_tslib}],
 946       [
 947        have_tslib="yes"
 948        requirements_ecore_fb="${_tslib_requirement} ${requirements_ecore_fb}"
 949       ],
 950       [have_tslib="no"])
 951 fi
 952
 953 # ecore_directfb
 954
 955 ECORE_CHECK_MODULE([DirectFB], [${want_ecore_directfb}], [${have_directfb}],
 956    [requirements_ecore_directfb="directfb ${requirements_ecore_directfb}"])
 957
 958 # ecore_wince
 959
 960 ECORE_CHECK_MODULE([WinCE], [${want_ecore_wince}], [${have_ecore_input}],
 961    [requirements_ecore_win32="ecore-input ${requirements_ecore_win32}"])
 962
 963 ## Ecore Evas
 964
 965 # ecore_evas
 966
 967 ecore_evas_deps="no"
 968 if test "x${have_evas}" = "xyes" -a "x${have_ecore_input}" = "xyes" ; then
 969    ecore_evas_deps="yes"
 970 fi
 971
 972 ECORE_CHECK_MODULE([Evas], [${want_ecore_evas}], [${ecore_evas_deps}],
 973   [requirements_ecore_evas="ecore-input evas ${requirements_ecore_evas}"])
 974
 975 # ecore_evas_buffer
 976
 977 ECORE_EVAS_CHECK_MODULE([software-buffer],
 978    [${want_ecore_evas_software_buffer}],
 979    [Software Buffer],
 980    [yes])
 981
 982 # ecore_evas_x11
 983
 984 # ecore_evas_software_x11
 985
 986 ECORE_EVAS_CHECK_MODULE([software-x11],
 987    [${want_ecore_evas_software_x11}],
 988    [Software X11],
 989    [${have_ecore_x}])
 990
 991 have_ecore_evas_software_xlib=no"
 992 have_ecore_evas_software_xcb=no"
 993 if test "x$have_ecore_evas_software_x11" = "xyes" ; then
 994    have_ecore_evas_software_xlib=`${PKG_CONFIG} --variable=Xlib evas-software-x11`
 995    if test "x${have_ecore_evas_software_xlib}" = "xyes" -a "x${have_ecore_x_xlib}" = "xyes" ; then
 996       AC_DEFINE(BUILD_ECORE_EVAS_SOFTWARE_XLIB, 1, [Evas Software Xlib Engine Support])
 997    fi
 998    have_ecore_evas_software_xcb=`${PKG_CONFIG} --variable=XCB evas-software-x11`
 999    if test "x$have_ecore_evas_software_xcb" = "xyes" -a "x${have_ecore_x_xcb}" = "xyes" ; then
1000       AC_DEFINE(BUILD_ECORE_EVAS_SOFTWARE_XCB, 1, [Evas Software XCB Engine Support])
1001    fi
1002 fi
1003
1004 # ecore_evas_xrender_x11
1005
1006 ECORE_EVAS_CHECK_MODULE([xrender-x11],
1007    [${want_ecore_evas_xrender_x11}],
1008    [XRender Xlib],
1009    [${have_ecore_x_xlib}])
1010
1011 # ecore_evas_opengl_x11
1012
1013 ECORE_EVAS_CHECK_MODULE([opengl-x11],
1014    [${want_ecore_evas_opengl_x11}],
1015    [OpenGL Xlib],
1016    [${have_ecore_x_xlib}])
1017
1018 # ecore_evas_software_x11 16 bits
1019
1020 ECORE_EVAS_CHECK_MODULE([software-16-x11],
1021    [${want_ecore_evas_software_16_x11}],
1022    [Software Xlib 16 bits],
1023    [${have_ecore_x_xlib}])
1024
1025 # ecore_evas_xrender_xcb
1026
1027 ECORE_EVAS_CHECK_MODULE([xrender-xcb],
1028    [${want_ecore_evas_xrender_xcb}],
1029    [XRender XCB],
1030    [${ecore_evas_xcb_deps}])
1031
1032 if test "x$have_ecore_evas_software_x11" = "xyes" -o \
1033         "x$have_ecore_evas_xrender_x11" = "xyes" -o \
1034         "x$have_ecore_evas_opengl_x11" = "xyes" -o \
1035         "x$have_ecore_evas_software_16_x11" = "xyes" -o \
1036         "x$have_ecore_evas_software_xcb" = "xyes" -o \
1037         "x$have_ecore_evas_xrender_xcb" = "xyes"; then
1038    AC_DEFINE(BUILD_ECORE_EVAS_X11, 1, [Support for X Window Engines in Ecore_Evas])
1039    requirements_ecore_evas="ecore-x ${requirements_ecore_evas}"
1040 fi
1041
1042 # ecore_evas_win32
1043
1044 ECORE_EVAS_CHECK_MODULE([software-gdi],
1045    [${want_ecore_evas_software_gdi}],
1046    [Software GDI],
1047    [${have_ecore_win32}])
1048
1049 ECORE_EVAS_CHECK_MODULE([software-ddraw],
1050    [${want_ecore_evas_software_ddraw}],
1051    [Software DirectDraw],
1052    [${have_ecore_win32}])
1053
1054 ECORE_EVAS_CHECK_MODULE([direct3d],
1055    [${want_ecore_evas_direct3d}],
1056    [Direct3d],
1057    [${have_ecore_win32}])
1058
1059 ECORE_EVAS_CHECK_MODULE([opengl-glew],
1060    [${want_ecore_evas_opengl_glew}],
1061    [Glew OpenGL],
1062    [${have_ecore_win32}])
1063
1064 ECORE_EVAS_CHECK_MODULE([software-16-ddraw],
1065    [${want_ecore_evas_software_16_ddraw}],
1066    [16 bpp Software DirectDraw],
1067    [${have_ecore_win32}])
1068
1069 if test "x${have_ecore_evas_software_gdi}" = "xyes" -o \
1070         "x${have_ecore_evas_software_ddraw}" = "xyes" -o \
1071         "x${have_ecore_evas_direct3d}" = "xyes" -o \
1072         "x${have_ecore_evas_opengl_glew}" = "xyes" -o \
1073         "x${have_ecore_evas_software_16_ddraw}" = "xyes" ; then
1074    AC_DEFINE(BUILD_ECORE_EVAS_WIN32, 1, [Support for Win32 Engine in Ecore_Evas])
1075    requirements_ecore_evas="ecore-win32 ${requirements_ecore_evas}"
1076 fi
1077
1078 # ecore_evas_quartz
1079
1080 ECORE_EVAS_CHECK_MODULE([quartz],
1081    [${want_ecore_evas_quartz}],
1082    [Quartz],
1083    [${have_ecore_quartz}],
1084    [requirements_ecore_evas="ecore-quartz ${requirements_ecore_evas}"])
1085
1086 # ecore_evas_software_sdl
1087
1088 ECORE_EVAS_CHECK_MODULE([software-sdl],
1089    [${want_ecore_evas_software_sdl}],
1090    [Software SDL],
1091    [${have_ecore_sdl}],
1092    [requirements_ecore_evas="ecore-sdl ${requirements_ecore_evas}"])
1093
1094 # ecore_evas_directfb
1095
1096 ECORE_EVAS_CHECK_MODULE([directfb],
1097    [${want_ecore_evas_directfb}],
1098    [DirectFB],
1099    [${have_ecore_directfb}],
1100    [requirements_ecore_evas="ecore-directfb ${requirements_ecore_evas}"])
1101
1102 # ecore_evas_fb
1103
1104 ECORE_EVAS_CHECK_MODULE([fb],
1105    [${want_ecore_evas_fb}],
1106    [Linux Framebuffer],
1107    [${have_ecore_fb}],
1108    [requirements_ecore_evas="ecore-fb ${requirements_ecore_evas}"])
1109
1110 # ecore_evas_wince
1111
1112 ECORE_EVAS_CHECK_MODULE([software-16-wince],
1113    [${want_ecore_evas_software_16_wince}],
1114    [16 bpp Software Windows CE],
1115    [${have_ecore_wince}],
1116    [requirements_ecore_evas="ecore-wince ${requirements_ecore_evas}"])
1117
1118
1119
1120 ### requirements
1121
1122 AC_SUBST(requirements_ecore)
1123 AC_SUBST(requirements_ecore_con)
1124 AC_SUBST(requirements_ecore_config)
1125 AC_SUBST(requirements_ecore_directfb)
1126 AC_SUBST(requirements_ecore_evas)
1127 AC_SUBST(requirements_ecore_fb)
1128 AC_SUBST(requirements_ecore_file)
1129 AC_SUBST(requirements_ecore_imf)
1130 AC_SUBST(requirements_ecore_imf_evas)
1131 AC_SUBST(requirements_ecore_input)
1132 AC_SUBST(requirements_ecore_ipc)
1133 AC_SUBST(requirements_ecore_job)
1134 AC_SUBST(requirements_ecore_quartz)
1135 AC_SUBST(requirements_ecore_sdl)
1136 AC_SUBST(requirements_ecore_txt)
1137 AC_SUBST(requirements_ecore_x)
1138 AC_SUBST(requirements_ecore_win32)
1139 AC_SUBST(requirements_ecore_wince)
1140
1141 AC_OUTPUT([
1142 Makefile
1143 ecore-con.pc
1144 ecore-config.pc
1145 ecore-directfb.pc
1146 ecore-evas.pc
1147 ecore-fb.pc
1148 ecore-file.pc
1149 ecore-imf.pc
1150 ecore-imf-evas.pc
1151 ecore-ipc.pc
1152 ecore-job.pc
1153 ecore-txt.pc
1154 ecore-x.pc
1155 ecore-input.pc
1156 ecore-win32.pc
1157 ecore-sdl.pc
1158 ecore-quartz.pc
1159 ecore-wince.pc
1160 ecore.pc
1161 doc/ecore.dox
1162 doc/Makefile
1163 src/Makefile
1164 src/bin/Makefile
1165 src/lib/Makefile
1166 src/lib/ecore/Makefile
1167 src/lib/ecore_job/Makefile
1168 src/lib/ecore_x/Makefile
1169 src/lib/ecore_x/xlib/Makefile
1170 src/lib/ecore_x/xcb/Makefile
1171 src/lib/ecore_fb/Makefile
1172 src/lib/ecore_sdl/Makefile
1173 src/lib/ecore_quartz/Makefile
1174 src/lib/ecore_evas/Makefile
1175 src/lib/ecore_con/Makefile
1176 src/lib/ecore_imf/Makefile
1177 src/lib/ecore_imf_evas/Makefile
1178 src/lib/ecore_input/Makefile
1179 src/lib/ecore_ipc/Makefile
1180 src/lib/ecore_txt/Makefile
1181 src/lib/ecore_config/Makefile
1182 src/lib/ecore_file/Makefile
1183 src/lib/ecore_directfb/Makefile
1184 src/lib/ecore_win32/Makefile
1185 src/lib/ecore_wince/Makefile
1186 README
1187 ecore.spec
1188 po/Makefile.in
1189 ])
1190
1191 echo
1192 echo "$PACKAGE $VERSION"
1193 echo
1194 echo "Optional Modules:"
1195 echo
1196 echo " Core:"
1197 echo
1198 echo "  Ecore........................: always"
1199 echo "    Thread support.............: $have_pthread"
1200 echo "    GLib support...............: $have_glib"
1201 echo "  Ecore_Job....................: $have_ecore_job"
1202 echo "  Ecore_Txt....................: $have_ecore_txt"
1203 echo "  Ecore_Con....................: $have_ecore_con"
1204 if test "x$have_ecore_con" = "xyes" ; then
1205   echo $ECHO_N "    OpenSSL....................: $have_openssl $ECHO_C"
1206 if test "x$have_gnutls" = "xyes" ; then
1207   echo " (disabled)"
1208 else
1209   echo
1210 fi
1211   echo "    GnuTLS.....................: $have_gnutls"
1212   echo "    CURL.......................: $have_curl"
1213   echo "    Abstract Sockets...........: $want_abstract_sockets"
1214   echo "    c-ares.....................: $have_cares"
1215 fi
1216 echo "  Ecore_Ipc....................: $have_ecore_ipc"
1217 if test "x$have_ecore_ipc" = "xyes" ; then
1218   echo $ECHO_N "    OpenSSL....................: $have_openssl $ECHO_C"
1219 if test "x$have_gnutls" = "xyes" ; then
1220   echo " (disabled)"
1221 else
1222   echo
1223 fi
1224   echo "    GnuTLS.....................: $have_gnutls"
1225 fi
1226 echo "  Ecore_File...................: $have_ecore_file"
1227 if test "x$have_ecore_file" = "xyes" ; then
1228   echo "    Inotify....................: $have_inotify"
1229   echo "    Windows notification.......: $have_notify_win32"
1230   echo "    Poll.......................: $have_poll"
1231   echo "    CURL.......................: $have_curl"
1232 fi
1233 echo "  Ecore_Config.................: $have_ecore_config"
1234 echo "  Ecore_IMF....................: $have_ecore_imf"
1235 echo "  Ecore_IMF_Evas...............: $have_ecore_imf_evas"
1236 echo "  Ecore_Input..................: $have_ecore_input"
1237
1238 echo
1239 echo " Graphic systems:"
1240 echo
1241
1242 if test "x$have_ecore_x" = "xyes" ; then
1243   if test "x$have_ecore_x_xcb" = "xyes" ; then
1244     echo "  Ecore_X (XCB backend)........: $have_ecore_x_xcb"
1245     echo "    Xprint.....................: $have_ecore_x_xcb_xprint"
1246     echo "    Xinerama...................: $have_ecore_x_xcb_xinerama"
1247     echo "    Xrandr.....................: $have_ecore_x_xcb_randr"
1248     echo "    Xscreensaver...............: $have_ecore_x_xcb_screensaver"
1249     echo "    Xshape.....................: $have_ecore_x_xcb_shape"
1250     echo "    Xsync......................: $have_ecore_x_xcb_sync"
1251     echo "    Xrender....................: $have_ecore_x_xcb_render"
1252     echo "    Xcomposite.................: $have_ecore_x_xcb_composite"
1253     echo "    Xfixes.....................: $have_ecore_x_xcb_xfixes"
1254     echo "    Xdamage....................: $have_ecore_x_xcb_damage"
1255     echo "    Xdpms......................: $have_ecore_x_xcb_dpms"
1256     echo "    Xtest......................: $have_ecore_x_xcb_xtest"
1257   else
1258     echo "  Ecore_X (Xlib backend).......: $have_ecore_x"
1259     echo "    Xcursor....................: $use_Xcursor"
1260     echo "    Xkb........................: $use_xkb"
1261     echo "    Xprint.....................: $use_xprint"
1262     echo "    Xinerama...................: $use_xinerama"
1263     echo "    Xrandr.....................: $use_xrandr"
1264     echo "    Xscreensaver...............: $use_xss"
1265     echo "    Xrender....................: $use_xrender"
1266     echo "    Xcomposite.................: $use_xcomposite"
1267     echo "    Xfixes.....................: $use_xfixes"
1268     echo "    Xdamage....................: $use_xdamage"
1269     echo "    Xdpms......................: $use_xdpms"
1270     echo "    Xtest......................: $use_xtest"
1271     echo "    XIM........................: $want_xim"
1272   fi
1273 else
1274   echo "  Ecore_X......................: $have_ecore_x"
1275 fi
1276 echo "  Ecore_Win32..................: $have_ecore_win32"
1277 echo "  Ecore_Quartz.................: $have_ecore_quartz"
1278 echo "  Ecore_SDL....................: $have_ecore_sdl"
1279 echo "  Ecore_FB.....................: $have_ecore_fb"
1280 if test "x${have_ecore_fb}" = "xyes" ; then
1281   echo "    Touchscreen................: $have_tslib"
1282 fi
1283 echo "  Ecore_DirectFB...............: $have_ecore_directfb"
1284 echo "  Ecore_WinCE..................: $have_ecore_wince"
1285
1286 echo
1287 echo " Ecore Evas:"
1288 echo
1289
1290 echo "  Ecore_Evas...................: $have_ecore_evas"
1291 if test "x${have_ecore_evas}" = "xyes" ; then
1292   echo "    Software Memory Buffer.....: $have_ecore_evas_software_buffer"
1293   if test "x${have_ecore_evas_software_x11}" = "xyes" ; then
1294     if test "x${have_ecore_evas_software_xlib}" = "xyes" ; then
1295       echo "    Software X11...............: $have_ecore_evas_software_x11 (Xlib)"
1296     fi
1297     if test "x${have_ecore_evas_software_xcb}" = "xyes" ; then
1298       echo "    Software X11...............: $have_ecore_evas_software_x11 (XCB)"
1299     fi
1300   else
1301     echo "    Software X11...............: $have_ecore_evas_software_x11"
1302   fi
1303   echo "    XRender X11................: $have_ecore_evas_xrender_x11"
1304   echo "    OpenGL X11.................: $have_ecore_evas_opengl_x11"
1305   echo "    XRender XCB................: $have_ecore_evas_xrender_xcb"
1306   echo "    Software GDI...............: $have_ecore_evas_software_gdi"
1307   echo "    Software DirectDraw........: $have_ecore_evas_software_ddraw"
1308   echo "    Direct3D...................: $have_ecore_evas_direct3d"
1309   echo "    OpenGL Glew................: $have_ecore_evas_opengl_glew"
1310   echo "    Quartz.....................: $have_ecore_evas_quartz"
1311   echo "    Software SDL...............: $have_ecore_evas_software_sdl"
1312   echo "    DirectFB...................: $have_ecore_evas_directfb"
1313   echo "    Software Framebuffer.......: $have_ecore_evas_fb"
1314   echo "    Software 16bit X11.........: $have_ecore_evas_software_16_x11"
1315   echo "    Software 16bit DirectDraw..: $have_ecore_evas_software_16_ddraw"
1316   echo "    Software 16bit WinCE.......: $have_ecore_evas_software_16_wince"
1317 fi
1318 echo
1319 echo " Documentation.................: ${build_doc}"
1320 echo
1321 echo " Compilation...................: make (or gmake)"
1322 if test "x${build_doc}" = "xyes" ; then
1323    echo " Build of the documentation....: make doc"
1324 fi
1325 echo
1326 echo " Installation..................: make install"
1327 echo
1328 echo "    prefix.....................: $prefix"
1329 echo
1330
1331 echo
1332 echo "Compilation............: make (or gmake)"
1333 echo "  CPPFLAGS.............: $CPPFLAGS"
1334 echo "  CFLAGS...............: $CFLAGS"
1335 echo "  CXXFLAGS.............: $CXXFLAGS"
1336 echo "  LDFLAGS..............: $LDFLAGS"
1337 echo
1338 echo "Installation...........: make install (as root if needed, with 'su' or 'sudo')"
1339 echo "  prefix...............: $prefix"
1340 echo