configure.ac

   1 AC_PREREQ([2.64])
   2 AC_INIT([weston],
   3         [1.0.0],
   4         [https://bugs.freedesktop.org/enter_bug.cgi?product=weston],
   5         [weston],
   6         [http://wayland.freedesktop.org/])
   7
   8 AC_CONFIG_HEADERS([config.h])
   9
  10 AM_INIT_AUTOMAKE([1.11 foreign no-dist-gzip dist-xz])
  11
  12 AM_SILENT_RULES([yes])
  13
  14 # Check for programs
  15 AC_PROG_CC
  16 AC_PROG_CXX
  17 AC_PROG_SED
  18
  19 # Initialize libtool
  20 LT_PREREQ([2.2])
  21 LT_INIT([disable-static])
  22
  23 PKG_PROG_PKG_CONFIG()
  24
  25 AC_CHECK_FUNC([dlopen], [],
  26               AC_CHECK_LIB([dl], [dlopen], DLOPEN_LIBS="-ldl"))
  27 AC_SUBST(DLOPEN_LIBS)
  28
  29 AC_CHECK_HEADERS([execinfo.h])
  30
  31 AC_CHECK_FUNCS([mkostemp strchrnul])
  32
  33 PKG_CHECK_MODULES(COMPOSITOR,
  34                   [wayland-server egl >= 7.10 glesv2 xkbcommon pixman-1])
  35
  36
  37 AC_ARG_ENABLE(setuid-install, [  --enable-setuid-install],,
  38               enable_setuid_install=yes)
  39 AM_CONDITIONAL(ENABLE_SETUID_INSTALL, test x$enable_setuid_install = xyes)
  40
  41
  42 AC_ARG_ENABLE(xwayland, [  --enable-xwayland],,
  43               enable_xwayland=yes)
  44 AM_CONDITIONAL(ENABLE_XWAYLAND, test x$enable_xwayland = xyes)
  45 if test x$enable_xwayland = xyes; then
  46   PKG_CHECK_MODULES([XWAYLAND], xcb xcb-xfixes xcursor cairo-xcb)
  47   AC_DEFINE([BUILD_XWAYLAND], [1], [Build the X server launcher])
  48
  49   AC_ARG_WITH(xserver-path, AS_HELP_STRING([--with-xserver-path=PATH],
  50               [Path to X server]), [XSERVER_PATH="$withval"],
  51               [XSERVER_PATH="$bindir/Xorg"])
  52   AC_SUBST([XSERVER_PATH])
  53 fi
  54
  55
  56 AC_ARG_ENABLE(x11-compositor, [  --enable-x11-compositor],,
  57               enable_x11_compositor=yes)
  58 AM_CONDITIONAL(ENABLE_X11_COMPOSITOR, test x$enable_x11_compositor = xyes)
  59 if test x$enable_x11_compositor = xyes; then
  60   PKG_CHECK_MODULES([XCB], xcb)
  61   xcb_save_LIBS=$LIBS
  62   xcb_save_CFLAGS=$CFLAGS
  63   CFLAGS=$XCB_CFLAGS
  64   LIBS=$XCB_LIBS
  65   AC_CHECK_FUNCS([xcb_poll_for_queued_event])
  66   LIBS=$xcb_save_LIBS
  67   CFLAGS=$xcb_save_CFLAGS
  68
  69   X11_COMPOSITOR_MODULES="x11 x11-xcb"
  70
  71   PKG_CHECK_MODULES(X11_COMPOSITOR_XKB, [xcb-xkb],
  72                     [have_xcb_xkb="yes"], [have_xcb_xkb="no"])
  73   if test "x$have_xcb_xkb" = xyes; then
  74         # Most versions of XCB have totally broken XKB bindings, where the
  75         # events don't work.  Make sure we can actually use them.
  76         xcb_xkb_save_CFLAGS=$CFLAGS
  77         CFLAGS=$X11_COMPOSITOR_XKB_CFLAGS
  78         AC_CHECK_MEMBER([struct xcb_xkb_state_notify_event_t.xkbType],
  79                         [], [have_xcb_xkb=no], [[#include <xcb/xkb.h>]])
  80         CFLAGS=$xcb_xkb_save_CFLAGS
  81   fi
  82   if test "x$have_xcb_xkb" = xyes; then
  83         X11_COMPOSITOR_MODULES="$X11_COMPOSITOR_MODULES xcb-xkb"
  84         AC_DEFINE([HAVE_XCB_XKB], [1], [libxcb supports XKB protocol])
  85   fi
  86
  87   PKG_CHECK_MODULES(X11_COMPOSITOR, [$X11_COMPOSITOR_MODULES])
  88   AC_DEFINE([BUILD_X11_COMPOSITOR], [1], [Build the X11 compositor])
  89 fi
  90
  91
  92 AC_ARG_ENABLE(drm-compositor, [  --enable-drm-compositor],,
  93               enable_drm_compositor=yes)
  94 AM_CONDITIONAL(ENABLE_DRM_COMPOSITOR, test x$enable_drm_compositor = xyes)
  95 if test x$enable_drm_compositor = xyes; then
  96   AC_DEFINE([BUILD_DRM_COMPOSITOR], [1], [Build the DRM compositor])
  97   PKG_CHECK_MODULES(DRM_COMPOSITOR, [libudev >= 136 libdrm >= 2.4.30 gbm mtdev >= 1.1.0])
  98 fi
  99
 100
 101 AC_ARG_ENABLE(wayland-compositor, [  --enable-wayland-compositor],,
 102               enable_wayland_compositor=yes)
 103 AM_CONDITIONAL(ENABLE_WAYLAND_COMPOSITOR,
 104                test x$enable_wayland_compositor = xyes)
 105 if test x$enable_wayland_compositor = xyes; then
 106   AC_DEFINE([BUILD_WAYLAND_COMPOSITOR], [1],
 107             [Build the Wayland (nested) compositor])
 108   PKG_CHECK_MODULES(WAYLAND_COMPOSITOR, [wayland-client wayland-egl])
 109 fi
 110
 111
 112 AC_ARG_ENABLE(android-compositor,
 113               AS_HELP_STRING([--disable-android-compositor],
 114                              [do not build-test the Android 4.0 backend]),,
 115               enable_android_compositor=yes)
 116 AM_CONDITIONAL(ENABLE_ANDROID_COMPOSITOR, test x$enable_android_compositor = xyes)
 117 if test x$enable_android_compositor = xyes; then
 118   AC_DEFINE([BUILD_ANDROID_COMPOSITOR], [1], [Build the compositor for Android 4.0])
 119   PKG_CHECK_MODULES(ANDROID_COMPOSITOR, [mtdev >= 1.1.0])
 120 fi
 121
 122 AC_ARG_WITH(cairo-glesv2,
 123             AS_HELP_STRING([--with-cairo-glesv2],
 124                            [Use GLESv2 cairo instead of full GL]))
 125 if test "x$with_cairo_glesv2" = "xyes"; then
 126   cairo_modules="cairo-glesv2"
 127   AC_DEFINE([USE_CAIRO_GLESV2], [1], [Use the GLESv2 GL cairo backend])
 128 else
 129   cairo_modules="cairo-gl"
 130 fi
 131
 132 PKG_CHECK_MODULES(PIXMAN, [pixman-1])
 133 PKG_CHECK_MODULES(PNG, [libpng])
 134 PKG_CHECK_MODULES(WEBP, [libwebp], [have_webp=yes], [have_webp=no])
 135 AS_IF([test "x$have_webp" = "xyes"],
 136       [AC_DEFINE([HAVE_WEBP], [1], [Have webp])])
 137
 138 AC_CHECK_LIB([jpeg], [jpeg_CreateDecompress], have_jpeglib=yes)
 139 if test x$have_jpeglib = xyes; then
 140   IMAGE_LIBS="$IMAGE_LIBS -ljpeg"
 141 else
 142   AC_ERROR([libjpeg not found])
 143 fi
 144
 145 PKG_CHECK_MODULES(CAIRO, [cairo])
 146 SHARED_LIBS="$CAIRO_LIBS $PIXMAN_LIBS $PNG_LIBS $WEBP_LIBS $IMAGE_LIBS"
 147 SHARED_CFLAGS="$CAIRO_CFLAGS $PIXMAN_CFLAGS $PNG_CFLAGS $WEBP_CFLAGS"
 148 AC_SUBST(SHARED_LIBS)
 149 AC_SUBST(SHARED_CFLAGS)
 150
 151 COMPOSITOR_LIBS="$COMPOSITOR_LIBS $IMAGE_LIBS"
 152 COMPOSITOR_CFLAGS="$COMPOSITOR_CFLAGS $IMAGE_CFLAGS"
 153
 154 AC_ARG_ENABLE(simple-clients,
 155               AS_HELP_STRING([--disable-simple-clients],
 156                              [do not build the simple wl_shm clients]),,
 157               enable_simple_clients=yes)
 158 AM_CONDITIONAL(BUILD_SIMPLE_CLIENTS, test "x$enable_simple_clients" = "xyes")
 159 if test x$enable_simple_clients = xyes; then
 160   PKG_CHECK_MODULES(SIMPLE_CLIENT, [wayland-client])
 161 fi
 162
 163 AC_ARG_ENABLE(simple-egl-clients,
 164               AS_HELP_STRING([--disable-simple-egl-clients],
 165                              [do not build the simple EGL clients]),,
 166               enable_simple_egl_clients=yes)
 167 AM_CONDITIONAL(BUILD_SIMPLE_EGL_CLIENTS, test "x$enable_simple_egl_clients" = "xyes")
 168 if test x$enable_simple_egl_clients = xyes; then
 169   PKG_CHECK_MODULES(SIMPLE_EGL_CLIENT,
 170                     [egl >= 7.10 glesv2 wayland-client wayland-egl])
 171 fi
 172
 173 AC_ARG_ENABLE(clients, [  --enable-clients],, enable_clients=yes)
 174 AM_CONDITIONAL(BUILD_CLIENTS, test x$enable_clients = xyes)
 175 if test x$enable_clients = xyes; then
 176   AC_DEFINE([BUILD_CLIENTS], [1], [Build the Wayland clients])
 177
 178   PKG_CHECK_MODULES(CLIENT, [wayland-client cairo >= 1.10.0 xkbcommon wayland-cursor])
 179   PKG_CHECK_MODULES(WESTON_INFO, [wayland-client])
 180
 181   CLIENT_CFLAGS="$CLIENT_CFLAGS $IMAGE_CFLAGS"
 182   CLIENT_LIBS="$CLIENT_LIBS $IMAGE_LIBS"
 183
 184   PKG_CHECK_MODULES(POPPLER, [poppler-glib glib-2.0 gobject-2.0 gio-2.0 ],
 185                              [have_poppler=yes], [have_poppler=no])
 186   PKG_CHECK_MODULES(CAIRO_EGL, [wayland-egl egl >= 7.10 cairo-egl >= 1.11.3 $cairo_modules],
 187                     [have_cairo_egl=yes], [have_cairo_egl=no])
 188   AS_IF([test "x$have_cairo_egl" = "xyes"],
 189         [AC_DEFINE([HAVE_CAIRO_EGL], [1], [Have cairo-egl])],
 190         [AC_MSG_WARN([clients will use cairo image, cairo-egl not used because $CAIRO_EGL_PKG_ERRORS])])
 191 fi
 192
 193 AC_ARG_ENABLE(weston-launch, [  --enable-weston-launch],, enable_weston_launch=yes)
 194 AM_CONDITIONAL(BUILD_WESTON_LAUNCH, test x$enable_weston_launch == xyes)
 195 if test x$enable_weston_launch == xyes; then
 196   PKG_CHECK_MODULES(WESTON_LAUNCH, [libdrm])
 197   PKG_CHECK_MODULES(SYSTEMD_LOGIN, [libsystemd-login],
 198                     [have_systemd_login=yes], [have_systemd_login=no])
 199   AS_IF([test "x$have_systemd_login" = "xyes"],
 200         [AC_DEFINE([HAVE_SYSTEMD_LOGIN], [1], [Have systemd-login])])
 201
 202   AC_CHECK_LIB([pam], [pam_open_session], [have_pam=yes], [have_pam=no])
 203   if test x$have_pam == xno; then
 204     AC_ERROR([weston-launch requires pam])
 205   fi
 206   WESTON_LAUNCH_LIBS="$WESTON_LAUNCH_LIBS -lpam"
 207 fi
 208
 209 AM_CONDITIONAL(HAVE_POPPLER, test "x$have_poppler" = "xyes")
 210
 211 AM_CONDITIONAL(BUILD_FULL_GL_CLIENTS,
 212                test x$cairo_modules = "xcairo-gl" -a "x$have_cairo_egl" = "xyes")
 213
 214 AM_CONDITIONAL(ENABLE_DESKTOP_SHELL, true)
 215
 216 AC_ARG_ENABLE(tablet-shell,
 217               AS_HELP_STRING([--disable-tablet-shell],
 218                              [do not build tablet-shell server plugin and client]),,
 219               enable_tablet_shell=yes)
 220 AM_CONDITIONAL(ENABLE_TABLET_SHELL,
 221                test "x$enable_tablet_shell" = "xyes")
 222
 223
 224 AC_ARG_ENABLE(wcap-tools, [  --disable-wcap-tools],, enable_wcap_tools=yes)
 225 AM_CONDITIONAL(BUILD_WCAP_TOOLS, test x$enable_wcap_tools = xyes)
 226 if test x$enable_wcap_tools = xyes; then
 227   AC_DEFINE([BUILD_WCAP_TOOLS], [1], [Build the wcap tools])
 228   PKG_CHECK_MODULES(WCAP, [cairo])
 229   WCAP_LIBS="$WCAP_LIBS -lm"
 230 fi
 231
 232 AC_CHECK_PROG(RSVG_CONVERT, rsvg-convert, rsvg-convert)
 233 AM_CONDITIONAL(HAVE_RSVG_CONVERT, test -n "$RSVG_CONVERT")
 234
 235 PKG_CHECK_MODULES(SETBACKLIGHT, [libudev libdrm], enable_setbacklight=yes, enable_setbacklight=no)
 236 AM_CONDITIONAL(BUILD_SETBACKLIGHT, test "x$enable_setbacklight" = "xyes")
 237
 238 if test "x$GCC" = "xyes"; then
 239         my_common_gcc_flags="-Wall -Wextra -Wno-unused-parameter \
 240                 -Wno-missing-field-initializers -g -fvisibility=hidden"
 241         GCC_CFLAGS="$my_common_gcc_flags \
 242                 -Wstrict-prototypes -Wmissing-prototypes"
 243         GCC_CXXFLAGS="$my_common_gcc_flags"
 244 fi
 245 AC_SUBST(GCC_CFLAGS)
 246 AC_SUBST(GCC_CXXFLAGS)
 247
 248 WAYLAND_SCANNER_RULES(['$(top_srcdir)/protocol'])
 249
 250 AC_CONFIG_FILES([Makefile
 251                  shared/Makefile
 252                  src/Makefile
 253                  src/xwayland/Makefile
 254                  clients/Makefile
 255                  wcap/Makefile
 256                  data/Makefile
 257                  protocol/Makefile
 258                  man/Makefile
 259                  tests/Makefile])
 260 AC_OUTPUT