configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2
   3 # Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2006,
   4 # 2004, 2006  Free Software Foundation, Inc.
   5 #
   6 # This program is free software; you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation; either version 2, or (at your option)
   9 # any later version.
  10 #
  11 # This program is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program; if not, write to the Free Software
  18 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  19 # 02110-1301, USA.
  20
  21 dnl Require Autoconf 2.60 for AC_REQUIRE_AUX_FILE.
  22 AC_PREREQ(2.60)
  23 AC_INIT([GNU Automake], [1.10a], [bug-automake@gnu.org])
  24
  25 AC_CONFIG_SRCDIR(automake.in)
  26 AC_CONFIG_AUX_DIR(lib)
  27
  28 AC_CANONICAL_BUILD
  29
  30 # Save the AUTOCONF setting before AM_INIT_AUTOMAKE overrides it; this
  31 # way we can run Autoconf tests from configure (or from the test
  32 # suite) without being bothered by `missing'.
  33 AC_SUBST([am_AUTOCONF], ["${AUTOCONF-autoconf}"])
  34
  35 AM_INIT_AUTOMAKE([1.8a dist-bzip2 filename-length-max=99])
  36
  37 # The API version is the base version.  We must guarantee
  38 # compatibility for all releases with the same API version.
  39 # Our current rule is that:
  40 # * All releases, including the prereleases, in an X.Y series
  41 #   are compatible.  So 1.5.1c is compatible with 1.5.
  42 # * Prereleases on the trunk are all incompatible -- 1.5b and 1.5c
  43 #   aren't the same.
  44 APIVERSION=`echo "$VERSION" | sed -e 's/^\([[0-9]]*\.[[0-9]]*[[a-z]]*\).*$/\1/'`
  45 AC_SUBST(APIVERSION)
  46
  47 # A versioned directory, defined here for convenience.
  48 AC_SUBST([pkgvdatadir], ["\${datadir}/$PACKAGE-$APIVERSION"])
  49
  50 # $AUTOMAKE and $ACLOCAL are always run after a `cd $top_srcdir',
  51 # hence `.' is really what we want for perllibdir, libdir, and acdir.
  52 ACLOCAL="perllibdir=`pwd`\"/lib$PATH_SEPARATOR./lib\" `pwd`/aclocal --acdir=m4 -I m4"
  53 AUTOMAKE="perllibdir=`pwd`\"/lib$PATH_SEPARATOR./lib\" `pwd`/automake --libdir=lib"
  54
  55 AC_PATH_PROG(PERL, perl)
  56 if test -z "$PERL"; then
  57    AC_MSG_ERROR([perl not found])
  58 fi
  59 $PERL -e 'require 5.006;' || {
  60    AC_MSG_ERROR(
  61 [perl 5.6 or better is required; perl 5.8.2 or better
  62 is recommended.  If you have several perl versions
  63 installed, select the one Automake should use using
  64   ./configure PERL=/path/to/perl])
  65 }
  66
  67 # The test suite will skip some tests if tex is absent.
  68 AC_CHECK_PROG([TEX], [tex], [tex])
  69
  70 # Test for Autoconf.  We run Autoconf in a subdirectory to ease
  71 # deletion of any files created (such as those added to
  72 # autom4te.cache).  We used to perform only the last of the three
  73 # following tests, but some users were unable to figure out that their
  74 # installation was broken since --version appeared to work.
  75
  76 AC_CACHE_CHECK([whether autoconf is installed], [am_cv_autoconf_installed],
  77 [if AM_RUN_LOG([eval $am_AUTOCONF --version]);
  78 then
  79   am_cv_autoconf_installed=yes
  80 else
  81   am_cv_autoconf_installed=no
  82 fi])
  83 if test "$am_cv_autoconf_installed" = no; then
  84   AC_MSG_ERROR([Autoconf 2.58 or better is required.
  85     Please make sure it is installed and in your PATH.])
  86 fi
  87
  88 AC_CACHE_CHECK([whether autoconf works], [am_cv_autoconf_works],
  89 [mkdir conftest
  90 echo 'AC''_INIT' > conftest/conftest.ac
  91 if AM_RUN_LOG([cd conftest && eval $am_AUTOCONF -o /dev/null conftest.ac]);
  92 then
  93   am_cv_autoconf_works=yes
  94 else
  95   am_cv_autoconf_works=no
  96 fi
  97 rm -rf conftest])
  98 if test "$am_cv_autoconf_works" = no; then
  99   AC_MSG_ERROR([The installed version of autoconf does not work.
 100     Please check config.log for error messages before this one.])
 101 fi
 102
 103 AC_CACHE_CHECK([whether autoconf is recent enough], [am_cv_autoconf_version],
 104 [mkdir conftest
 105 echo 'AC''_PREREQ(2.58)' > conftest/conftest.ac
 106 if AM_RUN_LOG([cd conftest && eval $am_AUTOCONF -o /dev/null conftest.ac]);
 107 then
 108   am_cv_autoconf_version=yes
 109 else
 110   am_cv_autoconf_version=no
 111 fi
 112 rm -rf conftest])
 113 if test "$am_cv_autoconf_version" = no; then
 114   AC_MSG_ERROR([Autoconf 2.58 or better is required.])
 115 fi
 116
 117 # Test for ln.  We need use it to install the versioned binaries.
 118 AC_MSG_CHECKING([whether ln works])
 119 AC_CACHE_VAL([am_cv_prog_ln], [
 120 rm -f conftest conftest.file
 121 : >conftest.file
 122 if ln conftest.file conftest 2>/dev/null; then
 123   am_cv_prog_ln=ln
 124 else
 125   am_cv_prog_ln='cp -p'
 126 fi
 127 rm -f conftest conftest.file])
 128 AC_SUBST([LN], [$am_cv_prog_ln])
 129 result=no
 130 test "x$am_cv_prog_ln" = xln && result=yes
 131 AC_MSG_RESULT([$result])
 132
 133 # The amount we should wait after modifying files depends on the platform.
 134 # On Windows '95, '98 and ME, files modifications have 2-seconds
 135 # granularity and can be up to 3 seconds in the future w.r.t. the
 136 # system clock.  When it is important to ensure one file is older
 137 # than another we wait at least 5 seconds between creations.
 138 case $build in
 139   *-pc-msdosdjgpp) MODIFICATION_DELAY=5;;
 140   *)               MODIFICATION_DELAY=2;;
 141 esac
 142 AC_SUBST([MODIFICATION_DELAY])
 143
 144 # Test for things needed by the test suite.
 145 AC_PROG_EGREP
 146 AC_PROG_FGREP
 147
 148 AC_CONFIG_FILES([
 149   Makefile
 150   doc/Makefile
 151   lib/Automake/Makefile
 152   lib/Automake/tests/Makefile
 153   lib/Makefile
 154   lib/am/Makefile
 155   m4/Makefile
 156   tests/Makefile
 157   tests/defs
 158 ])
 159 AC_CONFIG_FILES([tests/aclocal-${APIVERSION}:tests/aclocal.in],
 160                 [chmod +x tests/aclocal-${APIVERSION}],
 161                 [APIVERSION=$APIVERSION])
 162 AC_CONFIG_FILES([tests/automake-${APIVERSION}:tests/automake.in],
 163                 [chmod +x tests/automake-${APIVERSION}])
 164
 165 AC_OUTPUT