configure.ac

   1 # Copyright (c) 2007 Intel Corporation. All Rights Reserved.
   2 #
   3 # Permission is hereby granted, free of charge, to any person obtaining a
   4 # copy of this software and associated documentation files (the
   5 # "Software"), to deal in the Software without restriction, including
   6 # without limitation the rights to use, copy, modify, merge, publish,
   7 # distribute, sub license, and/or sell copies of the Software, and to
   8 # permit persons to whom the Software is furnished to do so, subject to
   9 # the following conditions:
  10 #
  11 # The above copyright notice and this permission notice (including the
  12 # next paragraph) shall be included in all copies or substantial portions
  13 # of the Software.
  14 #
  15 # THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS
  16 # OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
  17 # MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NON-INFRINGEMENT.
  18 # IN NO EVENT SHALL PRECISION INSIGHT AND/OR ITS SUPPLIERS BE LIABLE FOR
  19 # ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT,
  20 # TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE
  21 # SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
  22
  23 # VA-API version
  24 # - increment major for any ABI change (which shall not occur!)
  25 # - increment minor for any interface change (e.g. new/modified function)
  26 # - increment micro for any other change (new flag, new codec definition, etc.)
  27 # - reset micro version to zero when minor version is incremented
  28 # - reset minor version to zero when major version is incremented
  29 m4_define([va_api_major_version], [0])
  30 m4_define([va_api_minor_version], [33])
  31 m4_define([va_api_micro_version], [0])
  32
  33 m4_define([va_api_version],
  34           [va_api_major_version.va_api_minor_version.va_api_micro_version])
  35
  36 # libva package version number, (as distinct from shared library version)
  37 # XXX: we want the package version to remain at 1.0.x for VA-API 0.32.y
  38 #
  39 # - major version is automatically generated from VA-API major version
  40 # - minor version is automatically generated from VA-API minor version
  41 # - increment micro for any library release
  42 # - reset micro version to zero when VA-API major or minor version is changed
  43 m4_define([libva_major_version], [m4_eval(va_api_major_version + 1)])
  44 m4_define([libva_minor_version], [m4_eval(va_api_minor_version - 32)])
  45 m4_define([libva_micro_version], [0])
  46 m4_define([libva_pre_version],   [1])
  47
  48 m4_define([libva_version],
  49           [libva_major_version.libva_minor_version.libva_micro_version])
  50 m4_if(libva_pre_version, [0], [], [
  51 m4_append([libva_version], libva_pre_version, [.pre])
  52 ])
  53
  54 # libva library version number (generated, do not change)
  55 # XXX: we want the SONAME to remain at libva.so.1 for VA-API major == 0
  56 #
  57 # The library name is generated libva.<x>.<y>.0 where
  58 # <x> = VA-API major version + 1
  59 # <y> = 100 * VA-API minor version + VA-API micro version
  60 #
  61 # For example:
  62 # VA-API 0.32.0 generates libva.so.1.3200.0
  63 # VA-API 0.34.1 generates libva.so.1.3401.0
  64 # VA-API 1.2.13 generates libva.so.2.213.0
  65 m4_define([libva_interface_bias], [m4_eval(va_api_major_version + 1)])
  66 m4_define([libva_interface_age],  [0])
  67 m4_define([libva_binary_age],
  68           [m4_eval(100 * va_api_minor_version + va_api_micro_version - libva_interface_age)])
  69
  70 m4_define([libva_lt_current],
  71           [m4_eval(100 * va_api_minor_version + va_api_micro_version + libva_interface_bias)])
  72 m4_define([libva_lt_revision],
  73           [m4_eval(libva_interface_age)])
  74 m4_define([libva_lt_age],
  75           [m4_eval(libva_binary_age - libva_interface_age)])
  76
  77 # libdrm minimun version requirement
  78 m4_define([libdrm_version], [2.4])
  79
  80 AC_PREREQ(2.57)
  81 AC_INIT([libva], [libva_version], [waldo.bastian@intel.com], libva)
  82 AC_CONFIG_SRCDIR([Makefile.am])
  83 AM_INIT_AUTOMAKE([dist-bzip2])
  84
  85 AM_CONFIG_HEADER([config.h])
  86 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  87
  88 VA_API_MAJOR_VERSION=va_api_major_version
  89 VA_API_MINOR_VERSION=va_api_minor_version
  90 VA_API_MICRO_VERSION=va_api_micro_version
  91 VA_API_VERSION=va_api_version
  92 AC_SUBST(VA_API_MAJOR_VERSION)
  93 AC_SUBST(VA_API_MINOR_VERSION)
  94 AC_SUBST(VA_API_MICRO_VERSION)
  95 AC_SUBST(VA_API_VERSION)
  96
  97 LIBVA_MAJOR_VERSION=libva_major_version
  98 LIBVA_MINOR_VERSION=libva_minor_version
  99 LIBVA_MICRO_VERSION=libva_micro_version
 100 LIBVA_VERSION=libva_version
 101 AC_SUBST(LIBVA_MAJOR_VERSION)
 102 AC_SUBST(LIBVA_MINOR_VERSION)
 103 AC_SUBST(LIBVA_MICRO_VERSION)
 104 AC_SUBST(LIBVA_VERSION)
 105
 106 LIBVA_LT_CURRENT=libva_lt_current
 107 LIBVA_LT_REV=libva_lt_revision
 108 LIBVA_LT_AGE=libva_lt_age
 109 LIBVA_LT_VERSION="$LIBVA_LT_CURRENT:$LIBVA_LT_REV:$LIBVA_LT_AGE"
 110 LIBVA_LT_LDFLAGS="-version-info $LIBVA_LT_VERSION"
 111 AC_SUBST(LIBVA_LT_VERSION)
 112 AC_SUBST(LIBVA_LT_LDFLAGS)
 113
 114 AC_ARG_ENABLE(docs,
 115     [AC_HELP_STRING([--enable-docs],
 116                     [build Doxygen documentation @<:@default=no@:>@])],
 117     [], [enable_docs="no"])
 118
 119 AC_ARG_ENABLE(drm,
 120     [AC_HELP_STRING([--enable-drm],
 121                     [build with VA/DRM API support @<:@default=yes@:>@])],
 122     [], [enable_drm="yes"])
 123
 124 AC_ARG_ENABLE(x11,
 125     [AC_HELP_STRING([--enable-x11],
 126                     [build with VA/X11 API support @<:@default=yes@:>@])],
 127     [], [enable_x11="yes"])
 128
 129 AC_ARG_ENABLE(glx,
 130     [AC_HELP_STRING([--enable-glx],
 131                     [build with GLX support @<:@default=yes@:>@])],
 132     [], [enable_glx="yes"])
 133
 134 AC_ARG_ENABLE(egl,
 135     [AC_HELP_STRING([--enable-egl],
 136                     [build with EGL support @<:@default=yes@:>@])],
 137     [], [enable_egl="yes"])
 138
 139 AC_ARG_ENABLE([wayland],
 140     [AC_HELP_STRING([--enable-wayland],
 141                     [build with Wayland support @<:@default=yes@:>@])],
 142     [], [enable_wayland="yes"])
 143
 144 AC_ARG_ENABLE(dummy-driver,
 145     [AC_HELP_STRING([--enable-dummy-driver],
 146                     [build dummy video driver @<:@default=yes@:>@])],
 147     [], [enable_dummy_driver="yes"])
 148 AM_CONDITIONAL(BUILD_DUMMY_DRIVER, test x$enable_dummy_driver = xyes)
 149
 150 AC_ARG_ENABLE(dummy-backend,
 151     [AC_HELP_STRING([--enable-dummy-backend],
 152                     [build dummy libva backend])],
 153     [], [enable_dummy_backend="no"])
 154
 155 AC_ARG_WITH(drivers-path,
 156     [AC_HELP_STRING([--with-drivers-path=[[path]]],
 157                     [drivers path])],
 158     [], [with_drivers_path="$libdir/dri"])
 159
 160 LIBVA_DRIVERS_PATH="$with_drivers_path"
 161 AC_SUBST(LIBVA_DRIVERS_PATH)
 162
 163 AC_DISABLE_STATIC
 164 AC_PROG_LIBTOOL
 165 AC_PROG_CC
 166 AC_PROG_CXX
 167 AM_PROG_CC_C_O
 168 PKG_PROG_PKG_CONFIG
 169
 170 AC_HEADER_STDC
 171 AC_SYS_LARGEFILE
 172
 173 # Check for Doxygen
 174 if test "$enable_docs" = "yes"; then
 175     AC_CHECK_TOOL([DOXYGEN], [doxygen], [enable_docs="no"])
 176 fi
 177 AM_CONDITIONAL(ENABLE_DOCS, test "$enable_docs" = "yes")
 178
 179 # Check for __attribute__((visibility()))
 180 AC_CACHE_CHECK([whether __attribute__((visibility())) is supported],
 181     ac_cv_have_gnuc_visibility_attribute,
 182     [cat > conftest.c <<EOF
 183 int foo __attribute__ ((visibility ("hidden"))) = 1;
 184 int bar __attribute__ ((visibility ("protected"))) = 1;
 185 EOF
 186     ac_cv_have_gnuc_visibility_attribute="no"
 187     if ${CC-cc} -Werror -S conftest.c -o conftest.s >/dev/null 2>&1; then
 188         if grep '\.hidden.*foo' conftest.s >/dev/null; then
 189             if grep '\.protected.*bar' conftest.s >/dev/null; then
 190                 ac_cv_have_gnuc_visibility_attribute="yes"
 191             fi
 192         fi
 193     fi
 194     rm -f conftest.[cs]
 195 ])
 196 if test "$ac_cv_have_gnuc_visibility_attribute" = "yes"; then
 197     AC_DEFINE([HAVE_GNUC_VISIBILITY_ATTRIBUTE], [1],
 198               [Defined to 1 if GCC visibility attribute is supported])
 199 fi
 200
 201 # Check for X11
 202 USE_X11="no"
 203 if test "$enable_x11" = "yes"; then
 204     PKG_CHECK_MODULES([X11],    [x11])
 205     PKG_CHECK_MODULES([XEXT],   [xext])
 206     PKG_CHECK_MODULES([XFIXES], [xfixes])
 207     USE_X11="yes"
 208     AC_DEFINE([HAVE_VA_X11], [1], [Defined to 1 if VA/X11 API is built])
 209 fi
 210 AM_CONDITIONAL(USE_X11, test "$USE_X11" = "yes")
 211
 212 # Check for DRM
 213 LIBDRM_VERSION=libdrm_version
 214 PKG_CHECK_MODULES([DRM], [libdrm >= $LIBDRM_VERSION])
 215 AC_SUBST(LIBDRM_VERSION)
 216
 217 if test x$enable_dummy_backend = xyes; then
 218     PKG_CHECK_MODULES([UDEV], [libudev], [libudev=yes], [libudev=no])
 219 fi
 220 if test x$libudev = xno; then
 221    enable_dummy_backend=no
 222 fi
 223 AM_CONDITIONAL(BUILD_DUMMY_BACKEND, test x$enable_dummy_backend = xyes)
 224
 225 USE_DRM="no"
 226 if test "$enable_drm" = "yes"; then
 227     USE_DRM="yes"
 228     AC_DEFINE([HAVE_VA_DRM], [1], [Defined to 1 if VA/DRM API is built])
 229 fi
 230 AM_CONDITIONAL(USE_DRM, test "$USE_DRM" = "yes")
 231
 232 # Check for GLX
 233 USE_GLX="no"
 234 GL_DEPS_CFLAGS=""
 235 GL_DEPS_LIBS=""
 236 if test "$USE_X11:$enable_glx" = "yes:yes"; then
 237     saved_CFLAGS="$CFLAGS"
 238     saved_LIBS="$LIBS"
 239     PKG_CHECK_MODULES([GL_DEPS], [gl], [], [GL_DEPS_LIBS="-lX11 -lGL"])
 240     CFLAGS="$CFLAGS $GL_DEPS_CFLAGS"
 241     LIBS="$LIBS $GL_DEPS_LIBS"
 242     AC_CHECK_HEADERS([GL/gl.h])
 243     AC_CHECK_HEADERS([GL/glx.h])
 244     AC_CHECK_LIB(GL, glXCreateContext, [USE_GLX="yes"])
 245     CFLAGS="$saved_CFLAGS"
 246     LIBS="$saved_LIBS"
 247 fi
 248 AC_SUBST(GL_DEPS_CFLAGS)
 249 AC_SUBST(GL_DEPS_LIBS)
 250 AM_CONDITIONAL(USE_GLX, test "$USE_GLX" = "yes")
 251
 252 # Check for EGL
 253 USE_EGL="no"
 254 EGL_DEPS_CFLAGS=""
 255 EGL_DEPS_LIBS=""
 256 if test "$enable_egl" = "yes"; then
 257     saved_CFLAGS="$CFLAGS"
 258     saved_LIBS="$LIBS"
 259     PKG_CHECK_MODULES([EGL_DEPS], [egl], [], [EGL_DEPS_LIBS="-lEGL"])
 260     CFLAGS="$CFLAGS $EGL_DEPS_CFLAGS"
 261     LIBS="$LIBS $EGL_DEPS_LIBS"
 262     AC_CHECK_HEADERS([EGL/egl.h], [USE_EGL="yes"], [USE_EGL="no"])
 263
 264     if test "x$USE_EGL" = "xyes"; then
 265         AC_CHECK_LIB(EGL, eglGetDisplay, [USE_EGL="yes"], [USE_EGL="no"])
 266     fi
 267
 268     CFLAGS="$saved_CFLAGS"
 269     LIBS="$saved_LIBS"
 270
 271     libglesv1_cm="no"
 272     PKG_CHECK_MODULES([GLESv1_CM], [glesv1_cm], [libglesv1_cm="yes"], [libglesv1_cm="no"])
 273 fi
 274 AC_SUBST(EGL_DEPS_CFLAGS)
 275 AC_SUBST(EGL_DEPS_LIBS)
 276 AM_CONDITIONAL(USE_EGL, test "$USE_EGL" = "yes")
 277 AM_CONDITIONAL(BUILD_EGL_TEST, [test "x$USE_EGL" = "xyes" && test "x$libglesv1_cm" = "xyes"])
 278
 279 # Check for Wayland
 280 USE_WAYLAND="no"
 281 if test "$enable_wayland" = "yes"; then
 282     PKG_CHECK_MODULES([WAYLAND], [wayland-client], [USE_WAYLAND="yes"], [:])
 283     if test "$USE_WAYLAND" = "yes"; then
 284         AC_DEFINE([HAVE_VA_WAYLAND], [1],
 285                   [Defined to 1 if VA/Wayland API is built])
 286     fi
 287 fi
 288 AM_CONDITIONAL(USE_WAYLAND, test "$USE_WAYLAND" = "yes")
 289
 290 m4_ifdef([WAYLAND_SCANNER_RULES],
 291     [WAYLAND_SCANNER_RULES(['$(top_srcdir)/va/wayland/protocol'])],
 292     [wayland_scanner_rules=""; AC_SUBST(wayland_scanner_rules)])
 293
 294 # We only need the headers, we don't link against the DRM libraries
 295 LIBVA_CFLAGS="$DRM_CFLAGS"
 296 AC_SUBST(LIBVA_CFLAGS)
 297 AC_SUBST(LIBVA_LIBS)
 298
 299 pkgconfigdir=${libdir}/pkgconfig
 300 AC_SUBST(pkgconfigdir)
 301
 302 # Check for builds without backend
 303 if test "$USE_X11:$USE_DRM" = "no:no"; then
 304     AC_MSG_ERROR([Please select at least VA/X11 or VA/DRM backend])
 305 fi
 306
 307 LIBVA_DISPLAY="drm"
 308 if test "$USE_X11" = "yes"; then
 309     LIBVA_DISPLAY="x11"
 310 fi
 311 libvacorelib=libva.la
 312 libvabackendlib=libva-$LIBVA_DISPLAY.la
 313 AC_SUBST([libvacorelib])
 314 AC_SUBST([libvabackendlib])
 315
 316 AC_OUTPUT([
 317     Makefile
 318     debian.upstream/Makefile
 319     doc/Makefile
 320     dummy_drv_video/Makefile
 321     pkgconfig/Makefile
 322     pkgconfig/libva-drm.pc
 323     pkgconfig/libva-egl.pc
 324     pkgconfig/libva-glx.pc
 325     pkgconfig/libva-tpi.pc
 326     pkgconfig/libva-wayland.pc
 327     pkgconfig/libva-x11.pc
 328     pkgconfig/libva.pc
 329     test/Makefile
 330     test/basic/Makefile
 331     test/common/Makefile
 332     test/decode/Makefile
 333     test/encode/Makefile
 334     test/putsurface/Makefile
 335     test/vainfo/Makefile
 336     test/v4l_h264/Makefile
 337     test/v4l_h264/encode/Makefile
 338     test/v4l_h264/decode/Makefile
 339     va/Makefile
 340     va/drm/Makefile
 341     va/dummy/Makefile
 342     va/egl/Makefile
 343     va/glx/Makefile
 344     va/va_version.h
 345     va/wayland/Makefile
 346     va/wayland/protocol/Makefile
 347     va/x11/Makefile
 348 ])
 349
 350 # Print a small summary
 351 AS_IF([test x$USE_DRM = xyes], [BACKENDS="drm $BACKENDS"])
 352 AS_IF([test x$USE_X11 = xyes], [BACKENDS="x11 $BACKENDS"])
 353 AS_IF([test x$USE_GLX = xyes], [BACKENDS="glx $BACKENDS"])
 354 AS_IF([test x$USE_EGL = xyes], [BACKENDS="egl $BACKENDS"])
 355 AS_IF([test x$USE_WAYLAND = xyes], [BACKENDS="wayland $BACKENDS"])
 356
 357 echo
 358 echo "libva - ${LIBVA_VERSION} (VA-API ${VA_API_VERSION})"
 359 echo
 360 echo Installation prefix .............. : $prefix
 361 echo Default driver path .............. : $LIBVA_DRIVERS_PATH
 362 echo Extra window systems ............. : $BACKENDS
 363 echo Build dummy driver ............... : $enable_dummy_driver
 364 echo Build documentation .............. : $enable_docs
 365 echo