configure.ac

   1 AC_PREREQ([2.69])
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/pre
   8 AC_INIT([GStreamer Good Plug-ins],[1.9.90],[http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer],[gst-plugins-good])
   9
  10 AG_GST_INIT
  11
  12 dnl initialize automake
  13 AM_INIT_AUTOMAKE([-Wno-portability 1.14 no-dist-gzip dist-xz tar-ustar subdir-objects])
  14
  15 dnl define PACKAGE_VERSION_* variables
  16 AS_VERSION
  17
  18 dnl check if this is a release version
  19 AS_NANO(GST_GIT="no", GST_GIT="yes")
  20
  21 dnl can autoconf find the source ?
  22 AC_CONFIG_SRCDIR([gst/law/alaw.c])
  23
  24 dnl define the output header for config
  25 AC_CONFIG_HEADERS([config.h])
  26
  27 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  28 AM_MAINTAINER_MODE([enable])
  29
  30 dnl sets host_* variables
  31 AC_CANONICAL_HOST
  32
  33 dnl use pretty build output with automake >= 1.11
  34 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  35   [AM_DEFAULT_VERBOSITY=1
  36    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  37
  38 dnl our libraries and install dirs use GST_API_VERSION in the filename
  39 dnl to allow side-by-side installation of different API versions
  40 GST_API_VERSION=1.0
  41 AC_SUBST(GST_API_VERSION)
  42 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION",
  43   [GStreamer API Version])
  44
  45 AG_GST_LIBTOOL_PREPARE
  46 AS_LIBTOOL(GST, 990, 0, 990)
  47
  48 dnl *** required versions of GStreamer stuff ***
  49 GST_REQ=1.9.90
  50 GSTPB_REQ=1.9.90
  51
  52 dnl *** autotools stuff ****
  53
  54 dnl allow for different autotools
  55 AS_AUTOTOOLS_ALTERNATE
  56
  57 dnl Add parameters for aclocal
  58 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  59
  60 dnl set up gettext
  61 dnl the version check needs to stay here because autopoint greps for it
  62 AM_GNU_GETTEXT_VERSION([0.17])
  63 AM_GNU_GETTEXT([external])
  64 AG_GST_GETTEXT([gst-plugins-good-$GST_API_VERSION])
  65
  66 dnl *** check for arguments to configure ***
  67
  68 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  69 AG_GST_ARG_ENABLE_EXTRA_CHECKS
  70
  71 AG_GST_ARG_DEBUG
  72 AG_GST_ARG_PROFILING
  73 AG_GST_ARG_VALGRIND
  74 AG_GST_ARG_GCOV
  75
  76 AG_GST_ARG_EXAMPLES
  77
  78 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  79 AG_GST_ARG_WITH_PACKAGE_NAME
  80 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  81
  82 AG_GST_ARG_WITH_PLUGINS
  83
  84 AG_GST_ARG_ENABLE_EXTERNAL
  85
  86 AG_GST_ARG_ENABLE_EXPERIMENTAL
  87
  88 AG_GST_PKG_CONFIG_PATH
  89
  90 dnl *** checks for platform ***
  91
  92 dnl * hardware/architecture *
  93
  94 dnl common/m4/gst-arch.m4
  95 dnl check CPU type
  96 AG_GST_ARCH
  97
  98 dnl Determine endianness
  99 AC_C_BIGENDIAN
 100
 101 dnl *** checks for programs ***
 102
 103 dnl find a compiler
 104 AC_PROG_CC
 105 AC_PROG_CC_STDC
 106
 107 dnl determine c++ compiler
 108 AC_PROG_CXX
 109 dnl determine if c++ is available on this system
 110 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 111
 112 dnl determine c++ preprocessor
 113 dnl FIXME: do we need this ?
 114 AC_PROG_CXXCPP
 115
 116 AC_PROG_OBJC
 117
 118 dnl check if the compiler supports '-c' and '-o' options
 119 AM_PROG_CC_C_O
 120
 121 dnl find an assembler
 122 AM_PROG_AS
 123
 124 dnl check if the compiler supports do while(0) macros
 125 AG_GST_CHECK_DOWHILE_MACROS
 126
 127 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 128 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 129
 130 dnl check for documentation tools
 131 GTK_DOC_CHECK([1.12])
 132 AG_GST_PLUGIN_DOCS([1.12])
 133
 134 dnl *** checks for libraries ***
 135
 136 dnl check for libm, for sin()
 137 LT_LIB_M
 138 AC_SUBST(LIBM)
 139
 140 AC_CHECK_FUNCS(clock_gettime, [], [
 141   AC_CHECK_LIB(rt, clock_gettime, [
 142     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
 143     LIBRT="-lrt"
 144     AC_SUBST([LIBRT])
 145   ])
 146 ])
 147
 148 dnl check for pthreads
 149 AX_PTHREAD
 150
 151 dnl *** checks for header files ***
 152
 153 dnl check if we have ANSI C header files
 154 AC_HEADER_STDC
 155
 156 dnl used by ext/wavpack
 157 AX_CREATE_STDINT_H
 158
 159 dnl used in gst/udp
 160 AC_CHECK_HEADERS([sys/time.h])
 161
 162 dnl used in gst/udp
 163 AC_CHECK_HEADERS([sys/socket.h])
 164
 165 dnl *** checks for types/defines ***
 166
 167 dnl Check for FIONREAD ioctl declaration.  This check is needed
 168 dnl for the UDP plugin to build on Solaris
 169 GST_CHECK_FIONREAD
 170
 171 dnl *** checks for structures ***
 172
 173 dnl *** checks for compiler characteristics ***
 174
 175 dnl check if we have GCC inline-asm
 176 AS_GCC_INLINE_ASSEMBLY([HAVE_GCC_ASM=yes], [HAVE_GCC_ASM=no])
 177 if test x$HAVE_GCC_ASM = xyes ; then
 178   AC_DEFINE(HAVE_GCC_ASM, 1,
 179     [Define if compiler supports gcc inline assembly])
 180 fi
 181 AM_CONDITIONAL(HAVE_GCC_ASM, test "x$HAVE_GCC_ASM" = "xyes")
 182
 183 dnl *** checks for library functions ***
 184
 185 LIBS_SAVE=$LIBS
 186 LIBS="$LIBS $LIBM"
 187 AC_CHECK_FUNCS(rint sinh cosh asinh fpclass)
 188 LIBS=$LIBS_SAVE
 189
 190 dnl Check whether isinf() is defined by math.h
 191 AC_CACHE_CHECK([for isinf], ac_cv_have_isinf,
 192     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; int i=isinf(f)]])],[ac_cv_have_isinf="yes"],[ac_cv_have_isinf="no"]))
 193 if test "$ac_cv_have_isinf" = "yes"
 194 then
 195     AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have the `isinf' function.])
 196 fi
 197
 198 dnl Check for mmap (needed by electricfence plugin)
 199 AC_FUNC_MMAP
 200 AM_CONDITIONAL(GST_HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 201
 202 dnl Check for mmap (needed by electricfence plugin)
 203
 204 AC_CHECK_TYPE([struct ip_mreqn], [
 205               AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
 206               [#include <netinet/in.h>])
 207
 208 dnl *** checks for dependency libraries ***
 209
 210
 211 dnl GLib
 212 GLIB_REQ=2.40.0
 213 AG_GST_GLIB_CHECK([$GLIB_REQ])
 214
 215 dnl Orc
 216 ORC_CHECK([0.4.17])
 217
 218 dnl checks for gstreamer
 219 dnl uninstalled is selected preferentially -- see pkg-config(1)
 220 AG_GST_CHECK_GST($GST_API_VERSION, [$GST_REQ], yes)
 221 AG_GST_CHECK_GST_BASE($GST_API_VERSION, [$GST_REQ], yes)
 222 AG_GST_CHECK_GST_CONTROLLER($GST_API_VERSION, [$GST_REQ], yes)
 223 AG_GST_CHECK_GST_NET($GST_API_VERSION, [$GST_REQ], yes)
 224 AG_GST_CHECK_GST_CHECK($GST_API_VERSION, [$GST_REQ], no)
 225 AG_GST_CHECK_GST_PLUGINS_BASE($GST_API_VERSION, [$GSTPB_REQ], yes)
 226
 227 GST_TOOLS_DIR=`$PKG_CONFIG --variable=toolsdir gstreamer-$GST_API_VERSION`
 228 if test -z $GST_TOOLS_DIR; then
 229   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 230 fi
 231 AC_SUBST(GST_TOOLS_DIR)
 232
 233 AC_MSG_NOTICE(Using GStreamer Core Plugins in $GST_PLUGINS_DIR)
 234 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 235
 236 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 237
 238 dnl Check for documentation xrefs
 239 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 240 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_API_VERSION`"
 241 GSTPB_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-plugins-base-$GST_API_VERSION`"
 242 AC_SUBST(GLIB_PREFIX)
 243 AC_SUBST(GST_PREFIX)
 244 AC_SUBST(GSTPB_PREFIX)
 245
 246 dnl GTK is optional and used in examples
 247 HAVE_GTK=no
 248 GTK_REQ=3.0.0
 249 if test "x$BUILD_EXAMPLES" = "xyes"; then
 250   PKG_CHECK_MODULES(GTK, gtk+-3.0 >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 251   dnl some examples need gtk+-x11
 252   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-3.0 >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 253   AC_SUBST(GTK_LIBS)
 254   AC_SUBST(GTK_CFLAGS)
 255 fi
 256 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 257 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 258
 259 dnl Check for -Bsymbolic-functions linker flag used to avoid
 260 dnl intra-library PLT jumps, if available.
 261 AC_ARG_ENABLE(Bsymbolic,
 262               [AS_HELP_STRING([--disable-Bsymbolic],[avoid linking with -Bsymbolic])],,
 263               [SAVED_LDFLAGS="${LDFLAGS}" SAVED_LIBS="${LIBS}"
 264                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 265                LDFLAGS=-Wl,-Bsymbolic-functions
 266                LIBS=
 267                AC_TRY_LINK([], [return 0],
 268                            AC_MSG_RESULT(yes)
 269                            enable_Bsymbolic=yes,
 270                            AC_MSG_RESULT(no)
 271                            enable_Bsymbolic=no)
 272                LDFLAGS="${SAVED_LDFLAGS}" LIBS="${SAVED_LIBS}"])
 273
 274 dnl *** set variables based on configure arguments ***
 275
 276 dnl set license and copyright notice
 277 GST_LICENSE="LGPL"
 278 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 279 AC_SUBST(GST_LICENSE)
 280
 281 dnl set location of plugin directory
 282 AG_GST_SET_PLUGINDIR
 283
 284 dnl set release date/time
 285 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 286   ["${srcdir}/gst-plugins-good.doap"],
 287   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 288
 289 dnl build static plugins or not
 290 AC_MSG_CHECKING([whether to build static plugins or not])
 291 AC_ARG_ENABLE(
 292   static-plugins,
 293   AC_HELP_STRING(
 294     [--enable-static-plugins],
 295     [build static plugins @<:@default=no@:>@]),
 296   [AS_CASE(
 297     [$enableval], [no], [], [yes], [],
 298     [AC_MSG_ERROR([bad value "$enableval" for --enable-static-plugins])])],
 299   [enable_static_plugins=no])
 300 AC_MSG_RESULT([$enable_static_plugins])
 301 if test "x$enable_static_plugins" = xyes; then
 302   AC_DEFINE(GST_PLUGIN_BUILD_STATIC, 1,
 303     [Define if static plugins should be built])
 304   GST_PLUGIN_LIBTOOLFLAGS=""
 305 else
 306   GST_PLUGIN_LIBTOOLFLAGS="--tag=disable-static"
 307 fi
 308 AC_SUBST(GST_PLUGIN_LIBTOOLFLAGS)
 309 AM_CONDITIONAL(GST_PLUGIN_BUILD_STATIC, test "x$enable_static_plugins" = "xyes")
 310
 311 # set by AG_GST_PARSE_SUBSYSTEM_DISABLES above
 312 dnl make sure it doesn't complain about unused variables if debugging is disabled
 313 NO_WARNINGS=""
 314 AG_GST_CHECK_GST_DEBUG_DISABLED([NO_WARNINGS="-Wno-unused"], [NO_WARNINGS=""])
 315
 316 dnl define an ERROR_CFLAGS Makefile variable
 317 dnl -Wundef: too many broken headers
 318 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [
 319       -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 320       -Wwrite-strings -Wold-style-definition -Waggregate-return
 321       -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar
 322       -Wnested-externs $NO_WARNINGS])
 323
 324 dnl define an ERROR_CXXFLAGS Makefile variable
 325 AG_GST_SET_ERROR_CXXFLAGS($FATAL_WARNINGS, [
 326         -Wmissing-declarations -Wredundant-decls
 327         -Wwrite-strings
 328         -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar
 329         $NO_WARNINGS])
 330
 331 dnl define an ERROR_OBJCFLAGS Makefile variable
 332 AG_GST_SET_ERROR_OBJCFLAGS($FATAL_WARNINGS, [
 333       -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 334       -Wwrite-strings -Wold-style-definition
 335       -Winit-self -Wmissing-include-dirs -Wno-multichar
 336       -Wnested-externs $NO_WARNINGS])
 337
 338 dnl define correct level for debugging messages
 339 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 340
 341 dnl used in examples
 342 AG_GST_DEFAULT_ELEMENTS
 343
 344 dnl *** plug-ins to include ***
 345
 346 dnl these are all the gst plug-ins, compilable without additional libs
 347 dnl videofilter is at the top because others depend on it
 348 AG_GST_CHECK_PLUGIN(alpha)
 349 AG_GST_CHECK_PLUGIN(apetag)
 350 AG_GST_CHECK_PLUGIN(audiofx)
 351 AG_GST_CHECK_PLUGIN(audioparsers)
 352 AG_GST_CHECK_PLUGIN(auparse)
 353 AG_GST_CHECK_PLUGIN(autodetect)
 354 AG_GST_CHECK_PLUGIN(avi)
 355 AG_GST_CHECK_PLUGIN(cutter)
 356 AG_GST_CHECK_PLUGIN(debugutils)
 357 AG_GST_CHECK_PLUGIN(deinterlace)
 358 AG_GST_CHECK_PLUGIN(dtmf)
 359 AG_GST_CHECK_PLUGIN(effectv)
 360 AG_GST_CHECK_PLUGIN(equalizer)
 361 AG_GST_CHECK_PLUGIN(flv)
 362 AG_GST_CHECK_PLUGIN(flx)
 363 AG_GST_CHECK_PLUGIN(goom)
 364 AG_GST_CHECK_PLUGIN(goom2k1)
 365 AG_GST_CHECK_PLUGIN(icydemux)
 366 AG_GST_CHECK_PLUGIN(id3demux)
 367 AG_GST_CHECK_PLUGIN(imagefreeze)
 368 AG_GST_CHECK_PLUGIN(interleave)
 369 AG_GST_CHECK_PLUGIN(isomp4)
 370 AG_GST_CHECK_PLUGIN(law)
 371 AG_GST_CHECK_PLUGIN(level)
 372 AG_GST_CHECK_PLUGIN(matroska)
 373 AG_GST_CHECK_PLUGIN(monoscope)
 374 AG_GST_CHECK_PLUGIN(multifile)
 375 AG_GST_CHECK_PLUGIN(multipart)
 376 AG_GST_CHECK_PLUGIN(replaygain)
 377 AG_GST_CHECK_PLUGIN(rtp)
 378 AG_GST_CHECK_PLUGIN(rtpmanager)
 379 AG_GST_CHECK_PLUGIN(rtsp)
 380 AG_GST_CHECK_PLUGIN(shapewipe)
 381 AG_GST_CHECK_PLUGIN(smpte)
 382 AG_GST_CHECK_PLUGIN(spectrum)
 383 AG_GST_CHECK_PLUGIN(udp)
 384 AG_GST_CHECK_PLUGIN(videobox)
 385 AG_GST_CHECK_PLUGIN(videocrop)
 386 AG_GST_CHECK_PLUGIN(videofilter)
 387 AG_GST_CHECK_PLUGIN(videomixer)
 388 AG_GST_CHECK_PLUGIN(wavenc)
 389 AG_GST_CHECK_PLUGIN(wavparse)
 390 AG_GST_CHECK_PLUGIN(y4m)
 391
 392 dnl disable experimental plug-ins
 393 if test "x$BUILD_EXPERIMENTAL" != "xyes"; then
 394   AG_GST_DISABLE_PLUGIN(monoscope)
 395 fi
 396
 397 dnl *** sys plug-ins ***
 398
 399 echo
 400 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 401 echo
 402
 403 dnl DirectSound
 404 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECTSOUND, true)
 405 AG_GST_CHECK_FEATURE(DIRECTSOUND, [DirectSound plug-in], directsoundsink, [
 406   HAVE_DIRECTSOUND="no"
 407   save_CFLAGS="$CFLAGS"
 408   save_LDFLAGS="$LDFLAGS"
 409   save_LIBS="$LIBS"
 410   CFLAGS="$CFLAGS $DIRECTSOUND_CFLAGS"
 411   LDFLAGS="$LDFLAGS $DIRECTSOUND_LDFLAGS"
 412   LIBS="$LIBS -ldsound -ldxerr9 -luser32 -lole32"
 413   AC_MSG_CHECKING(for DirectSound LDFLAGS)
 414   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 415 #include <windows.h>
 416 #include <dxerr9.h>
 417 #include <dsound.h>
 418 ]], [[
 419   DXGetErrorString9 (0);
 420   DirectSoundCreate(NULL, NULL, NULL);
 421   CLSIDFromString(NULL, NULL);
 422 ]])
 423 ],
 424     [HAVE_DIRECTSOUND="yes"],
 425     [HAVE_DIRECTSOUND="no"])
 426   AC_MSG_RESULT($HAVE_DIRECTSOUND)
 427   CFLAGS=$save_CFLAGS
 428   LDFLAGS=$save_LDFLAGS
 429   LIBS=$save_LIBS
 430
 431   if test "x$HAVE_DIRECTSOUND" = "xyes";  then
 432     dnl this is much more than we want
 433     DIRECTSOUND_LIBS="-ldsound -ldxerr9 -luser32 -lole32"
 434     AC_SUBST(DIRECTSOUND_CFLAGS)
 435     AC_SUBST(DIRECTSOUND_LDFLAGS)
 436     AC_SUBST(DIRECTSOUND_LIBS)
 437   fi
 438   AC_SUBST(HAVE_DIRECTSOUND)
 439 ])
 440
 441 dnl *** Win32 WaveOut ***
 442 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVEFORM, true)
 443 AG_GST_CHECK_FEATURE(WAVEFORM, [Win32 WaveForm], waveformsink, [
 444   AC_CHECK_HEADER(mmsystem.h, HAVE_WAVEFORM="yes", HAVE_WAVEFORM="no", [#include <windows.h>])
 445 ])
 446
 447 dnl *** OSS audio *** (Linux, *BSD)
 448 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS, true)
 449 AG_GST_CHECK_FEATURE(OSS, [OSS audio], ossaudio, [
 450  HAVE_OSS="yes"
 451 dnl Linux and newer BSD versions :
 452  AC_CHECK_HEADER(sys/soundcard.h, [
 453    AC_DEFINE(HAVE_OSS_INCLUDE_IN_SYS,, [Define if OSS includes are in /sys/])
 454    ] , [
 455 dnl Some old BSD versions and also newer OpenBSD versions :
 456    AC_CHECK_HEADER(soundcard.h, [
 457      AC_DEFINE(HAVE_OSS_INCLUDE_IN_ROOT,, [Define if OSS includes are in /])
 458      ], [
 459   dnl Some old BSD versions :
 460      AC_CHECK_HEADER(machine/soundcard.h, [
 461        AC_DEFINE(HAVE_OSS_INCLUDE_IN_MACHINE,,
 462          [Define if OSS includes are in /machine/])
 463        ], [
 464        HAVE_OSS="no"
 465      ])
 466    ])
 467  ])
 468 ])
 469
 470 dnl *** oss4 ***
 471 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS4, true)
 472 AG_GST_CHECK_FEATURE(OSS4, [Open Sound System 4], oss4, [
 473   AC_MSG_CHECKING([Checking if we can build the OSS4 elements])
 474   AC_CHECK_HEADERS([fcntl.h sys/ioctl.h sys/stat.h sys/types.h],
 475       [test -z "$OSS4_MISSING_HEADER" && HAVE_OSS4="yes"],
 476       [OSS4_MISSING_HEADER="yes";HAVE_OSS4="no"])
 477 ])
 478
 479 dnl *** Sun Audio ***
 480 translit(dnm, m, l) AM_CONDITIONAL(USE_SUNAUDIO, true)
 481 AG_GST_CHECK_FEATURE(SUNAUDIO, [Sun Audio], sunaudio, [
 482   AC_CHECK_HEADER(sys/audioio.h, HAVE_SUNAUDIO="yes", HAVE_SUNAUDIO="no")
 483 ])
 484
 485 dnl *** OSX Audio ***
 486 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_AUDIO, true)
 487 HAVE_IOS="no"
 488 AG_GST_CHECK_FEATURE(OSX_AUDIO, [OSX audio], osxaudio, [
 489   AC_CHECK_HEADER(CoreAudio/CoreAudio.h,
 490     [HAVE_OSX_AUDIO="yes"],
 491     [AC_CHECK_HEADER(CoreAudio/CoreAudioTypes.h,
 492     [
 493       HAVE_OSX_AUDIO="yes"
 494       HAVE_IOS="yes"
 495     ], [
 496       HAVE_OSX_AUDIO="no"
 497       HAVE_IOS="no"
 498     ])]
 499   )
 500 ])
 501 if test "x$HAVE_IOS" = "xyes"; then
 502   AC_DEFINE(HAVE_IOS, 1, [building for iOS platofrm])
 503 fi
 504 AM_CONDITIONAL(HAVE_IOS, test "x$HAVE_IOS" = "xyes")
 505
 506 dnl *** OS X video ***
 507 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_VIDEO, true)
 508 HAVE_OSX_VIDEO="no"
 509 AG_GST_CHECK_FEATURE(OSX_VIDEO, [OSX video], osxvideosink, [
 510   AC_CHECK_HEADER(OpenGL/gl.h, HAVE_OSX_VIDEO="yes", HAVE_OSX_VIDEO="no")
 511
 512   dnl in case header OpenGL/gl.h is found on other platforms (or older, unsupported OS X)
 513   dnl also require Snow Leopard or newer
 514
 515   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 516         #include <AvailabilityMacros.h>
 517         #if MAC_OS_X_VERSION_MIN_REQUIRED < 1060
 518         #error Too old OSX version
 519         #endif
 520       ]], [[return 0;]])],[HAVE_OSX_VIDEO="yes"],[HAVE_OSX_VIDEO="no"])
 521 ])
 522
 523 dnl *** Video 4 Linux 2 ***
 524 dnl renamed to GST_V4L2 because of some conflict with kernel headers
 525 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L2, true)
 526 HAVE_GST_V4L2=no
 527 AG_GST_CHECK_FEATURE(GST_V4L2, [Video 4 Linux 2], video4linux2, [
 528   AC_MSG_CHECKING([Checking for video4linux2 header ...])
 529   AC_CHECK_HEADER(linux/videodev2.h, [ HAVE_GST_V4L2=yes ],
 530   [
 531     AC_CHECK_HEADER(sys/videodev2.h, [ HAVE_GST_V4L2=yes ],
 532     [
 533       AC_CHECK_HEADER(sys/videoio.h, [ HAVE_GST_V4L2=yes ])
 534     ])
 535   ])
 536   if test "x$HAVE_VIDEODEV" = "xno"; then
 537      AC_MSG_WARN([video4linux2 was not found])
 538   fi
 539 ])
 540
 541 # Optional gudev for device probing
 542 AC_ARG_WITH([gudev],
 543   AS_HELP_STRING([--with-gudev],[device detection with gudev]),
 544   [],
 545   [with_gudev=check])
 546 if test x$HAVE_GST_V4L2 = xyes; then
 547   if test x$with_gudev != xno; then
 548     PKG_CHECK_MODULES(GUDEV, [ gudev-1.0 >= 147 ],
 549       [ AC_DEFINE(HAVE_GUDEV, 1,
 550           [Whether gudev is available for device detection])
 551       ],
 552       [true])
 553   fi
 554 fi
 555
 556 AC_SUBST(GUDEV_CFLAGS)
 557 AC_SUBST(GUDEV_LIBS)
 558
 559 # Make libv4l2 non-automagic
 560 AC_ARG_WITH([libv4l2],
 561   AS_HELP_STRING([--with-libv4l2],[support video buffer conversion using libv4l2]),
 562   [],
 563   [with_libv4l2=check])
 564 if test x$HAVE_GST_V4L2 = xyes; then
 565   if test x$with_libv4l2 != xno; then
 566       PKG_CHECK_MODULES(LIBV4L2, libv4l2,
 567           [ have_libv4l2=yes
 568             AC_DEFINE(HAVE_LIBV4L2, 1,
 569                 [Whether libv4l2 is available for video buffer conversion])
 570           ], [
 571           have_libv4l2=no
 572           ])
 573   else
 574     have_libv4l2=no
 575   fi
 576 fi
 577
 578 dnl Allow enabling v4l2 device probing
 579 AS_CASE([$host],
 580     [*-*linux*],
 581       [AS_CASE([$host_cpu],
 582         [arm*], [
 583           enable_v4l2_probe="yes"],
 584         [aarch64*], [
 585           enable_v4l2_probe="yes"])])
 586 AC_ARG_ENABLE(
 587   v4l2-probe,
 588   AC_HELP_STRING(
 589     [--enable-v4l2-probe],
 590     [enable V4L2 plugin to probe devices @<:@default=no@:>@]))
 591 if test "x$enable_v4l2_probe" = "xyes"; then
 592   AC_DEFINE(GST_V4L2_ENABLE_PROBE, 1,
 593     [Define if Video4Linux probe shall be run at plugin load])
 594 fi
 595
 596 dnl Check for X11
 597 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 598 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 599                   [ximagesrc], [
 600   PKG_CHECK_MODULES([X], [x11], [
 601     HAVE_X="yes"
 602     dnl check for Xfixes
 603     PKG_CHECK_MODULES([XFIXES], [ xfixes ], [
 604       AC_DEFINE(HAVE_XFIXES, 1, [Defined if Xfixes is available])
 605     ], [ HAVE_XFIXES="no" ])
 606
 607     dnl check for Xdamage
 608     PKG_CHECK_MODULES([XDAMAGE], [ xdamage ], [
 609       AC_DEFINE(HAVE_XDAMAGE, 1, [Defined if Xdamage is available])
 610     ], [ HAVE_XDAMAGE="no" ])
 611
 612     dnl check for X Shm
 613     PKG_CHECK_MODULES([XEXT], [ xext ], [
 614       AC_CHECK_LIB([Xext], [ XShmAttach ], [
 615         AC_DEFINE(HAVE_XSHM, 1, [Defined if XShm is available])
 616         XSHM_LIBS="$XEXT_LIBS"
 617         XSHM_CFLAGS="$XEXT_CFLAGS"
 618       ], [ HAVE_XEXT="no" ] , [ $X_LIBS ])
 619     ])
 620     AC_SUBST(XSHM_LIBS)
 621     AC_SUBST(XSHM_CFLAGS)
 622   ], [ HAVE_X="no" ])
 623 ])
 624
 625 dnl *** ext plug-ins ***
 626 dnl keep this list sorted alphabetically !
 627
 628 if test "x$BUILD_EXTERNAL" = "xyes"; then
 629
 630 echo
 631 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 632 echo
 633
 634 dnl *** aalib ***
 635 translit(dnm, m, l) AM_CONDITIONAL(USE_AALIB, true)
 636 AG_GST_CHECK_FEATURE(AALIB, [aalib ASCII Art library], aasink, [
 637   AM_PATH_AALIB(, HAVE_AALIB=yes, HAVE_AALIB=no)
 638 ])
 639
 640 dnl *** cairo ***
 641 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO, true)
 642 AG_GST_CHECK_FEATURE(CAIRO, [Cairo graphics rendering and gobject bindings], cairo, [
 643   AG_GST_PKG_CHECK_MODULES(CAIRO, cairo >= 1.10.0 cairo-gobject >= 1.10.0)
 644 ])
 645
 646 dnl *** FLAC ***
 647 translit(dnm, m, l) AM_CONDITIONAL(USE_FLAC, true)
 648 AG_GST_CHECK_FEATURE(FLAC, [FLAC lossless audio], flac, [
 649   AG_GST_PKG_CHECK_MODULES(FLAC, flac >= 1.1.4)
 650 ])
 651
 652 dnl *** GDK pixbuf ***
 653 translit(dnm, m, l) AM_CONDITIONAL(USE_GDK_PIXBUF, true)
 654 AG_GST_CHECK_FEATURE(GDK_PIXBUF, [GDK pixbuf], gdkpixbuf, [
 655   AG_GST_PKG_CHECK_MODULES(GDK_PIXBUF, gdk-pixbuf-2.0 >= 2.8.0)
 656 ])
 657
 658 dnl *** Jack ***
 659 translit(dnm, m, l) AM_CONDITIONAL(USE_JACK, true)
 660 AG_GST_CHECK_FEATURE(JACK, Jack, jack, [
 661   PKG_CHECK_MODULES(JACK, jack >= 0.99.10, HAVE_JACK="yes", HAVE_JACK="no")
 662   AC_SUBST(JACK_CFLAGS)
 663   AC_SUBST(JACK_LIBS)
 664
 665   AG_GST_PKG_CHECK_MODULES(JACK_0_120_1, jack >= 0.120.1 jack < 1.0)
 666   if test x$HAVE_JACK_0_120_1 = xyes; then
 667     AC_DEFINE(HAVE_JACK_0_120_1, 1, [defined if jack >= 0.120.1 is available])
 668   fi
 669   AG_GST_PKG_CHECK_MODULES(JACK_1_9_7, jack >= 1.9.7)
 670   if test x$HAVE_JACK_1_9_7 = xyes; then
 671     AC_DEFINE(HAVE_JACK_1_9_7, 1, [defined if jack >= 1.9.7 is available])
 672   fi
 673
 674 ])
 675
 676 dnl *** jpeg ***
 677 dnl FIXME: we could use header checks here as well IMO
 678 translit(dnm, m, l) AM_CONDITIONAL(USE_JPEG, true)
 679 AG_GST_CHECK_FEATURE(JPEG, [jpeg library], jpeg, [
 680   AC_ARG_WITH(jpeg-mmx,
 681     [  --with-jpeg-mmx, path to MMX'ified JPEG library])
 682   OLD_LIBS="$LIBS"
 683   if test x$with_jpeg_mmx != x; then
 684     LIBS="$LIBS -L$with_jpeg_mmx"
 685   fi
 686   AC_CHECK_LIB(jpeg-mmx, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 687   JPEG_LIBS="$LIBS -ljpeg-mmx"
 688   LIBS="$OLD_LIBS"
 689   if test x$HAVE_JPEG != xyes; then
 690     AC_CHECK_LIB(jpeg, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 691     JPEG_LIBS="-ljpeg"
 692   fi
 693   AC_SUBST(JPEG_LIBS)
 694 ])
 695
 696 dnl *** libcaca ***
 697 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBCACA, true)
 698 AG_GST_CHECK_FEATURE(LIBCACA, [libcaca coloured ASCII art], cacasink, [
 699   AG_GST_PKG_CHECK_MODULES(LIBCACA, caca)
 700 ])
 701
 702 dnl *** libdv ***
 703 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBDV, true)
 704 AG_GST_CHECK_FEATURE(LIBDV, [libdv DV demuxer/decoder], dv, [
 705   AG_GST_PKG_CHECK_MODULES(LIBDV, libdv >= 0.100)
 706 ])
 707
 708 dnl *** libpng ***
 709 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBPNG, true)
 710 AG_GST_CHECK_FEATURE(LIBPNG, [Portable Network Graphics library], png, [
 711   AG_GST_PKG_CHECK_MODULES(LIBPNG, libpng >= 1.2)
 712 ])
 713
 714 dnl *** pulseaudio ***
 715 translit(dnm, m, l) AM_CONDITIONAL(USE_PULSE, true)
 716 AG_GST_CHECK_FEATURE(PULSE, [pulseaudio plug-in], pulseaudio, [
 717
 718   dnl used in ext/pulse/pulseutil.c
 719   AC_CHECK_HEADERS([process.h])
 720
 721   AG_GST_PKG_CHECK_MODULES(PULSE, libpulse >= 2.0)
 722 ])
 723
 724 dnl *** dv1394 ***
 725 translit(dnm, m, l) AM_CONDITIONAL(USE_DV1394, true)
 726 AG_GST_CHECK_FEATURE(DV1394, [raw1394 and avc1394 library], 1394, [
 727   dnl first test for libraw1394 >= 2.0.0
 728   AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 2.0.0)
 729   AG_GST_PKG_CHECK_MODULES(LIBIEC61883, libiec61883 >= 1.0.0)
 730   dnl now see how far we got
 731   if test x$HAVE_RAW1394 = xyes && \
 732      test x$HAVE_LIBIEC61883 = xyes; then
 733        AG_GST_CHECK_LIBHEADER(AVC1394,
 734         avc1394, avc1394_send_command, $RAW1394_LIBS,
 735         libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 736        AG_GST_CHECK_LIBHEADER(ROM1394,
 737         rom1394, rom1394_free_directory, $RAW1394_LIBS,
 738         libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 739        if test x$HAVE_AVC1394 = xyes && \
 740           test x$HAVE_AVC1394 = xyes && \
 741           test x$HAVE_ROM1394 = xyes; then
 742           HAVE_DV1394=yes
 743           DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS $LIBIEC61883_LIBS"
 744           DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 745           AC_SUBST(DV1394_CFLAGS)
 746           AC_SUBST(DV1394_LIBS)
 747         fi
 748   else
 749        if test x$HAVE_RAW1394 = xno; then
 750           AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.1.0)
 751           AG_GST_CHECK_LIBHEADER(AVC1394,
 752            avc1394, avc1394_send_command, $RAW1394_LIBS,
 753            libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 754           AG_GST_CHECK_LIBHEADER(ROM1394,
 755            rom1394, rom1394_free_directory, $RAW1394_LIBS,
 756            libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 757           if test x$HAVE_RAW1394 = xyes && \
 758              test x$HAVE_AVC1394 = xyes && \
 759              test x$HAVE_ROM1394 = xyes; then
 760              HAVE_DV1394=yes
 761              DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS"
 762              DV1394_CFLAGS="$RAW1394_CFLAGS"
 763              if test x$HAVE_LIBIEC61883 = xyes; then
 764                DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 765                DV1394_LIBS="$DV1394_LIBS $LIBIEC61883_LIBS"
 766              fi
 767              AC_SUBST(DV1394_CFLAGS)
 768              AC_SUBST(DV1394_LIBS)
 769            fi
 770          fi
 771   fi
 772 ])
 773 AM_CONDITIONAL(USE_LIBIEC61883, [ test "x${HAVE_LIBIEC61883}" = xyes ] )
 774
 775 dnl *** shout2 ***
 776 translit(dnm, m, l) AM_CONDITIONAL(USE_SHOUT2, true)
 777 AG_GST_CHECK_FEATURE(SHOUT2, [Shoutcast/Icecast client library], shout2, [
 778   AG_GST_PKG_CHECK_MODULES(SHOUT2, shout >= 2.0)
 779 ])
 780
 781 dnl *** soup ***
 782 translit(dnm, m, l) AM_CONDITIONAL(USE_SOUP, true)
 783 AG_GST_CHECK_FEATURE(SOUP, [soup http client plugin (2.4)], souphttpsrc, [
 784   PKG_CHECK_MODULES(SOUP, libsoup-2.4 >= 2.48, [HAVE_SOUP="yes"], [HAVE_SOUP="no"])
 785   AC_SUBST(SOUP_CFLAGS)
 786   AC_SUBST(SOUP_LIBS)
 787 ])
 788
 789 dnl *** speex ***
 790 translit(dnm, m, l) AM_CONDITIONAL(USE_SPEEX, true)
 791 AG_GST_CHECK_FEATURE(SPEEX, [speex speech codec], speex, [
 792   AG_GST_PKG_CHECK_MODULES(SPEEX, speex >= 1.1.6)
 793 ])
 794
 795 dnl *** taglib ***
 796 translit(dnm, m, l) AM_CONDITIONAL(USE_TAGLIB, true)
 797 AG_GST_CHECK_FEATURE(TAGLIB, [taglib tagging library], taglib, [
 798   AG_GST_PKG_CHECK_MODULES(TAGLIB, taglib >= 1.5)
 799   if test "x$HAVE_CXX" != "xyes"; then
 800     USE_TAGLIB=false
 801     AC_MSG_NOTICE([Not building taglib plugin: no C++ compiler found])
 802   else
 803     dnl work around bug in taglib 1.5 headers, remove once there is a 1.6
 804     AS_CXX_COMPILER_FLAG([-Wno-attributes], [
 805         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS -Wno-attributes"
 806       ], [
 807         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS"
 808     ])
 809     AC_SUBST(TAGLIB_CXXFLAGS)
 810   fi
 811 ])
 812
 813 dnl *** vpx ***
 814 translit(dnm, m, l) AM_CONDITIONAL(USE_VPX, vpx)
 815 AG_GST_CHECK_FEATURE(VPX, [VPX decoder], vpx, [
 816   PKG_CHECK_MODULES(VPX, vpx >= 1.1.0, [HAVE_VPX="yes"], [HAVE_VPX="no"])
 817   HAVE_VP8=no
 818   HAVE_VP9=no
 819
 820   if test $HAVE_VPX = "yes"; then
 821     OLD_LIBS="$LIBS"
 822     OLD_CFLAGS="$CFLAGS"
 823     CFLAGS="$CFLAGS $VPX_CFLAGS"
 824     LIBS="$LIBS $VPX_LIBS"
 825     AC_CHECK_LIB(vpx, vpx_codec_vp8_cx_algo, [
 826       HAVE_VP8=yes
 827       AC_DEFINE(HAVE_VP8_ENCODER, 1, [Defined if the VP8 encoder is available])
 828     ])
 829     AC_CHECK_LIB(vpx, vpx_codec_vp8_dx_algo, [
 830       HAVE_VP8=yes
 831       AC_DEFINE(HAVE_VP8_DECODER, 1, [Defined if the VP8 decoder is available])
 832     ])
 833
 834     PKG_CHECK_MODULES(VPX_130, vpx >= 1.3.0, [
 835       AC_CHECK_LIB(vpx, vpx_codec_vp9_cx_algo, [
 836         HAVE_VP9=yes
 837         AC_DEFINE(HAVE_VP9_ENCODER, 1, [Defined if the VP9 encoder is available])
 838       ])
 839       AC_CHECK_LIB(vpx, vpx_codec_vp9_dx_algo, [
 840         HAVE_VP9=yes
 841         AC_DEFINE(HAVE_VP9_DECODER, 1, [Defined if the VP9 decoder is available])
 842       ])
 843     ], [true])
 844
 845     PKG_CHECK_MODULES(VPX_140, vpx >= 1.4.0, [
 846       AC_DEFINE(HAVE_VPX_1_4, 1, [Defined if the VPX library version is 1.4 or bigger])
 847     ], [true])
 848
 849     LIBS="$OLD_LIBS"
 850     CFLAGS="$OLD_CFLAGS"
 851   fi
 852   AC_SUBST(VPX_LIBS)
 853   AC_SUBST(VPX_CFLAGS)
 854 ])
 855
 856 dnl *** wavpack ***
 857 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVPACK, true)
 858 AG_GST_CHECK_FEATURE(WAVPACK, [wavpack plug-in], wavpack, [
 859   AG_GST_PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.60.0)
 860 ])
 861
 862 dnl *** qtdemux & matroska prefer to have zlib ***
 863 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 864 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for qtdemux/matroska],, [
 865   AG_GST_CHECK_LIBHEADER(ZLIB,
 866     z, uncompress,, zlib.h, [
 867     HAVE_ZLIB="yes"
 868     ZLIB_LIBS="-lz"
 869     AC_SUBST(ZLIB_LIBS)
 870   ])
 871 ])
 872
 873 dnl *** matroska prefers to have bz2 ***
 874 translit(dnm, m, l) AM_CONDITIONAL(USE_BZ2, true)
 875 AG_GST_CHECK_FEATURE(BZ2, [bz2 library for matroska ],, [
 876   save_LIBS=$LIBS
 877   LIBS="$LIBS -lbz2"
 878   AC_MSG_CHECKING([for BZ2_bzlibVersion in -lbz2])
 879   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <bzlib.h>]], [[const char *version = BZ2_bzlibVersion ();]])],[HAVE_BZ2=yes],[HAVE_BZ2=no])
 880   AC_MSG_RESULT($HAVE_BZ2)
 881   LIBS=$save_LIBS
 882   if test "x$HAVE_BZ2" = "xyes"; then
 883     BZ2_LIBS="-lbz2"
 884   fi
 885   AC_SUBST(BZ2_LIBS)
 886 ])
 887
 888 else
 889
 890 dnl not building plugins with external dependencies,
 891 dnl but we still need to set the conditionals
 892 AM_CONDITIONAL(USE_AALIB, false)
 893 AM_CONDITIONAL(USE_BZ2, false)
 894 AM_CONDITIONAL(USE_CAIRO, false)
 895 AM_CONDITIONAL(USE_DIRECTSOUND, false)
 896 AM_CONDITIONAL(USE_DV1394, false)
 897 AM_CONDITIONAL(USE_FLAC, false)
 898 AM_CONDITIONAL(USE_GDK_PIXBUF, false)
 899 AM_CONDITIONAL(USE_JACK, false)
 900 AM_CONDITIONAL(USE_JPEG, false)
 901 AM_CONDITIONAL(USE_LIBCACA, false)
 902 AM_CONDITIONAL(USE_LIBDV, false)
 903 AM_CONDITIONAL(USE_LIBIEC61883, false)
 904 AM_CONDITIONAL(USE_LIBPNG, false)
 905 AM_CONDITIONAL(USE_OSS, false)
 906 AM_CONDITIONAL(USE_OSS4, false)
 907 AM_CONDITIONAL(USE_OSX_AUDIO, false)
 908 AM_CONDITIONAL(USE_OSX_VIDEO, false)
 909 AM_CONDITIONAL(USE_PULSE, false)
 910 AM_CONDITIONAL(USE_SHOUT2, false)
 911 AM_CONDITIONAL(USE_SOUP, false)
 912 AM_CONDITIONAL(USE_SPEEX, false)
 913 AM_CONDITIONAL(USE_SUNAUDIO, false)
 914 AM_CONDITIONAL(USE_TAGLIB, false)
 915 AM_CONDITIONAL(USE_VPX, false)
 916 AM_CONDITIONAL(USE_WAVEFORM, false)
 917 AM_CONDITIONAL(USE_WAVPACK, false)
 918 AM_CONDITIONAL(USE_X, false)
 919 AM_CONDITIONAL(USE_ZLIB, false)
 920
 921 fi dnl of EXT plugins
 922
 923 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 924
 925 dnl Overview:
 926 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 927 dnl GST_*:              flags shared by all built objects
 928 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 929 dnl GST_LIB_LDFLAGS:    not needed, we don't install libraries
 930 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 931 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 932
 933 dnl GST_OPTION_CFLAGS
 934 if test "x$USE_DEBUG" = xyes; then
 935    PROFILE_CFLAGS="-g"
 936 fi
 937 AC_SUBST(PROFILE_CFLAGS)
 938
 939 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 940   dnl Define _only_ for git (not pre-releases or releases)
 941   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 942 else
 943   DEPRECATED_CFLAGS=""
 944 fi
 945 AC_SUBST(DEPRECATED_CFLAGS)
 946
 947 dnl every flag in GST_OPTION_CFLAGS, GST_OPTION_CXXFLAGS and GST_OPTION_OBJCFLAGS can be overridden
 948 dnl at make time with e.g. make ERROR_CFLAGS=""
 949 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 950 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 951 GST_OPTION_OBJCFLAGS="\$(WARNING_OBJCFLAGS) \$(ERROR_OBJCFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 952 AC_SUBST(GST_OPTION_CFLAGS)
 953 AC_SUBST(GST_OPTION_CXXFLAGS)
 954 AC_SUBST(GST_OPTION_OBJCFLAGS)
 955
 956 dnl our libraries need to be versioned correctly
 957 AC_SUBST(GST_LT_LDFLAGS)
 958
 959 dnl FIXME: do we want to rename to GST_ALL_* ?
 960 dnl prefer internal headers to already installed ones
 961 dnl also add builddir include for enumtypes and marshal
 962 dnl add ERROR_CFLAGS, but overridable
 963 GST_CFLAGS="$GST_CFLAGS -DGST_USE_UNSTABLE_API"
 964 GST_CXXFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CXXFLAGS)"
 965 GST_OBJCFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_OBJCFLAGS)"
 966 GST_CFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CFLAGS)"
 967 AC_SUBST(GST_CFLAGS)
 968 AC_SUBST(GST_CXXFLAGS)
 969 AC_SUBST(GST_OBJCFLAGS)
 970 AC_SUBST(GST_LIBS)
 971
 972 dnl LDFLAGS really should only contain flags, not libs - they get added before
 973 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 974 GST_ALL_LDFLAGS="-no-undefined"
 975 if test "x${enable_Bsymbolic}" = "xyes"; then
 976   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
 977 fi
 978 AC_SUBST(GST_ALL_LDFLAGS)
 979
 980 dnl this really should only contain flags, not libs - they get added before
 981 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 982 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_.*' $GST_ALL_LDFLAGS"
 983 AC_SUBST(GST_PLUGIN_LDFLAGS)
 984
 985 dnl *** output files ***
 986
 987 $MKDIR_P tests/check/orc
 988
 989 dnl keep this alphabetic per directory, please
 990 AC_CONFIG_FILES(
 991 Makefile
 992 gst/Makefile
 993 gst/alpha/Makefile
 994 gst/apetag/Makefile
 995 gst/audiofx/Makefile
 996 gst/audioparsers/Makefile
 997 gst/auparse/Makefile
 998 gst/autodetect/Makefile
 999 gst/avi/Makefile
1000 gst/cutter/Makefile
1001 gst/deinterlace/Makefile
1002 gst/dtmf/Makefile
1003 gst/debugutils/Makefile
1004 gst/effectv/Makefile
1005 gst/equalizer/Makefile
1006 gst/flv/Makefile
1007 gst/goom/Makefile
1008 gst/goom2k1/Makefile
1009 gst/id3demux/Makefile
1010 gst/icydemux/Makefile
1011 gst/imagefreeze/Makefile
1012 gst/interleave/Makefile
1013 gst/isomp4/Makefile
1014 gst/law/Makefile
1015 gst/level/Makefile
1016 gst/matroska/Makefile
1017 gst/monoscope/Makefile
1018 gst/multifile/Makefile
1019 gst/multipart/Makefile
1020 gst/replaygain/Makefile
1021 gst/rtp/Makefile
1022 gst/rtpmanager/Makefile
1023 gst/rtsp/Makefile
1024 gst/shapewipe/Makefile
1025 gst/smpte/Makefile
1026 gst/spectrum/Makefile
1027 gst/udp/Makefile
1028 gst/videobox/Makefile
1029 gst/videocrop/Makefile
1030 gst/videofilter/Makefile
1031 gst/videomixer/Makefile
1032 gst/wavenc/Makefile
1033 gst/wavparse/Makefile
1034 gst/flx/Makefile
1035 gst/y4m/Makefile
1036 ext/Makefile
1037 ext/aalib/Makefile
1038 ext/cairo/Makefile
1039 ext/dv/Makefile
1040 ext/flac/Makefile
1041 ext/gdk_pixbuf/Makefile
1042 ext/jack/Makefile
1043 ext/jpeg/Makefile
1044 ext/libcaca/Makefile
1045 ext/libpng/Makefile
1046 ext/pulse/Makefile
1047 ext/raw1394/Makefile
1048 ext/shout2/Makefile
1049 ext/soup/Makefile
1050 ext/speex/Makefile
1051 ext/taglib/Makefile
1052 ext/vpx/Makefile
1053 ext/wavpack/Makefile
1054 sys/Makefile
1055 sys/directsound/Makefile
1056 sys/oss/Makefile
1057 sys/oss4/Makefile
1058 sys/osxaudio/Makefile
1059 sys/osxvideo/Makefile
1060 sys/sunaudio/Makefile
1061 sys/v4l2/Makefile
1062 sys/waveform/Makefile
1063 sys/ximage/Makefile
1064 po/Makefile.in
1065 tests/Makefile
1066 tests/check/Makefile
1067 tests/examples/Makefile
1068 tests/examples/audiofx/Makefile
1069 tests/examples/cairo/Makefile
1070 tests/examples/equalizer/Makefile
1071 tests/examples/jack/Makefile
1072 tests/examples/level/Makefile
1073 tests/examples/pulse/Makefile
1074 tests/examples/rtp/Makefile
1075 tests/examples/shapewipe/Makefile
1076 tests/examples/spectrum/Makefile
1077 tests/examples/v4l2/Makefile
1078 tests/files/Makefile
1079 tests/icles/Makefile
1080 common/Makefile
1081 common/m4/Makefile
1082 m4/Makefile
1083 docs/Makefile
1084 docs/plugins/Makefile
1085 docs/version.entities
1086 pkgconfig/Makefile
1087 pkgconfig/gstreamer-plugins-good-uninstalled.pc
1088 gst-plugins-good.spec
1089 )
1090
1091 dnl Create the config.h file for Visual Studio builds
1092 dnl Beware of spaces and /'s in some of the shell variable contents.
1093 sed \
1094     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"\n\n#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
1095     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
1096     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
1097     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
1098     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
1099     -e 's/.* GST_API_VERSION$/#define GST_API_VERSION "'$GST_API_VERSION'"/' \
1100     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
1101     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
1102     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
1103     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
1104     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
1105     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
1106     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
1107     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
1108     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
1109     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
1110     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
1111     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
1112     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
1113     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
1114     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
1115     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
1116     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
1117     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
1118     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
1119     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
1120     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
1121     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
1122     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.11"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.11"\n#endif/' \
1123     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
1124     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
1125     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directsoundsink\"/" \
1126     -e "s/.* DEFAULT_AUDIOSRC$/#define DEFAULT_AUDIOSRC \"audiotestsrc\"/" \
1127     -e "s/.* DEFAULT_VIDEOSRC$/#define DEFAULT_VIDEOSRC \"videotestsrc\"/" \
1128     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
1129     config.h.in >win32/common/config.h-new
1130
1131 AC_OUTPUT
1132
1133 AG_GST_OUTPUT_PLUGINS
1134 ORC_OUTPUT
1135