configure.ac

   1 dnl *******************************************
   2 dnl *** Initialize automake and set version ***
   3 dnl *******************************************
   4
   5 m4_define([soup_major_version], [2])
   6 m4_define([soup_minor_version], [41])
   7 m4_define([soup_micro_version], [2])
   8
   9 AC_PREREQ(2.63)
  10 AC_INIT([libsoup],[soup_major_version.soup_minor_version.soup_micro_version],[http://bugzilla.gnome.org/enter_bug.cgi?product=libsoup])
  11 AC_CONFIG_SRCDIR([libsoup-2.4.pc.in])
  12 AC_CONFIG_MACRO_DIR([m4])
  13
  14 AM_INIT_AUTOMAKE([1.11 foreign no-dist-gzip dist-xz -Wno-portability])
  15 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],)
  16
  17 AC_PROG_MAKE_SET
  18
  19 SOUP_MAJOR_VERSION=soup_major_version
  20 SOUP_MINOR_VERSION=soup_minor_version
  21 SOUP_MICRO_VERSION=soup_micro_version
  22 AC_SUBST(SOUP_MAJOR_VERSION)
  23 AC_SUBST(SOUP_MINOR_VERSION)
  24 AC_SUBST(SOUP_MICRO_VERSION)
  25
  26 SOUP_API_VERSION=2.4
  27 AC_SUBST(SOUP_API_VERSION)
  28
  29 # Increment on interface addition. Reset on removal.
  30 SOUP_AGE=5
  31
  32 # Increment on interface add, remove, or change.
  33 SOUP_CURRENT=6
  34
  35 # Increment on source change. Reset when CURRENT changes.
  36 SOUP_REVISION=0
  37
  38 AC_SUBST(SOUP_CURRENT)
  39 AC_SUBST(SOUP_REVISION)
  40 AC_SUBST(SOUP_AGE)
  41
  42 dnl ***************************
  43 dnl *** Set debugging flags ***
  44 dnl ***************************
  45
  46 debug_default=minimum
  47
  48 # Declare --enable-* args and collect ac_help strings
  49 AC_ARG_ENABLE(debug,
  50               AS_HELP_STRING([--enable-debug=[no/minimum/yes]],
  51                              [turn on debugging (default=$debug_default)]),,
  52               enable_debug=$debug_default)
  53
  54 # Set the debug flags
  55 if test "x$enable_debug" = "xyes"; then
  56         test "$cflags_set" = set || CFLAGS="$CFLAGS -g"
  57         SOUP_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
  58 else
  59         if test "x$enable_debug" = "xno"; then
  60                 SOUP_DEBUG_FLAGS="-DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
  61         fi
  62 fi
  63
  64 AC_SUBST(SOUP_DEBUG_FLAGS)
  65
  66 # Set the maintainer flags
  67 #if test -d .git; then
  68 #       SOUP_MAINTAINER_FLAGS="-DG_DISABLE_DEPRECATED"
  69 #fi
  70 AC_SUBST(SOUP_MAINTAINER_FLAGS)
  71
  72 dnl ***************************
  73 dnl *** Checks for programs ***
  74 dnl ***************************
  75
  76 AC_PROG_CC
  77 AC_PROG_INSTALL
  78
  79 # Initialize libtool
  80 LT_INIT([win32-dll])
  81
  82 dnl ***********************
  83 dnl *** Checks for glib ***
  84 dnl ***********************
  85
  86 GLIB_REQUIRED=2.35.0
  87 AM_PATH_GLIB_2_0($GLIB_REQUIRED,,,gobject gio)
  88 if test "$GLIB_LIBS" = ""; then
  89    AC_MSG_ERROR(GLIB $GLIB_REQUIRED or later is required to build libsoup)
  90 fi
  91 GLIB_CFLAGS="$GLIB_CFLAGS -DGLIB_VERSION_MIN_REQUIRED=GLIB_VERSION_2_36"
  92
  93 GLIB_MAKEFILE='$(top_srcdir)/Makefile.glib'
  94 AC_SUBST(GLIB_MAKEFILE)
  95
  96 PKG_CHECK_MODULES(XML, libxml-2.0)
  97 AC_SUBST(XML_CFLAGS)
  98 AC_SUBST(XML_LIBS)
  99
 100 dnl ***********************
 101 dnl *** Check for Win32 ***
 102 dnl ***********************
 103
 104 AC_MSG_CHECKING([for Win32])
 105 case "$host" in
 106   *-*-mingw*)
 107     os_win32=yes
 108     CFLAGS="$CFLAGS -D_REENTRANT"
 109     ;;
 110   *)
 111     os_win32=no
 112     ;;
 113 esac
 114 AC_MSG_RESULT([$os_win32])
 115 AM_CONDITIONAL(OS_WIN32, [test $os_win32 = yes])
 116
 117 dnl ************************
 118 dnl *** gettext/intltool ***
 119 dnl ************************
 120 IT_PROG_INTLTOOL([0.35.0])
 121 GETTEXT_PACKAGE=libsoup
 122 AC_SUBST([GETTEXT_PACKAGE])
 123 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["$GETTEXT_PACKAGE"],[The gettext domain name])
 124 AM_GLIB_GNU_GETTEXT
 125
 126 dnl *******************
 127 dnl *** Misc checks ***
 128 dnl *******************
 129 AC_CHECK_FUNCS(gmtime_r)
 130 AC_CHECK_FUNC(socket, , AC_CHECK_LIB(socket, socket))
 131
 132 dnl *********************
 133 dnl *** GNOME support ***
 134 dnl *********************
 135 AC_MSG_CHECKING(whether to build libsoup-gnome)
 136 AC_ARG_WITH(gnome,
 137             AS_HELP_STRING([--without-gnome], [Do not build libsoup-gnome]),
 138             :, [if test $os_win32 = yes; then with_gnome=no; else with_gnome=yes; fi])
 139 AC_MSG_RESULT($with_gnome)
 140
 141 if test $with_gnome != no -a $os_win32 != yes; then
 142         PKG_CHECK_MODULES(GNOME_KEYRING, gnome-keyring-1, :,
 143                           AC_MSG_ERROR(
 144 [Could not find gnome-keyring devel files.
 145 Configure with --without-gnome if you wish to build only libsoup
 146 without GNOME-specific features.]))
 147 fi
 148 AC_SUBST(GNOME_KEYRING_CFLAGS)
 149 AC_SUBST(GNOME_KEYRING_LIBS)
 150
 151 AM_CONDITIONAL(BUILD_LIBSOUP_GNOME, test $with_gnome != no)
 152
 153 if test $with_gnome != no; then
 154         AC_DEFINE(HAVE_GNOME, 1, [Defined if GNOME support is enabled])
 155
 156         PKG_CHECK_MODULES(SQLITE, sqlite3, :, [AC_MSG_ERROR(dnl
 157 [Could not find sqlite3 devel files:
 158
 159 $SQLITE_PKG_ERRORS
 160
 161 Pass "--without-gnome" to configure if you want to build libsoup
 162 without GNOME support.])])
 163 fi
 164 AC_SUBST(HAVE_GNOME)
 165 AC_SUBST(SQLITE_CFLAGS)
 166 AC_SUBST(SQLITE_LIBS)
 167
 168
 169 dnl ***************
 170 dnl *** gtk-doc ***
 171 dnl ***************
 172 GTK_DOC_CHECK([1.10])
 173
 174 dnl *****************************
 175 dnl *** gobject-introspection ***
 176 dnl *****************************
 177 GOBJECT_INTROSPECTION_CHECK([0.9.5])
 178
 179 AC_MSG_CHECKING([for glib-networking (glib TLS implementation)])
 180 save_CFLAGS="$CFLAGS"
 181 save_LIBS="$LIBS"
 182 CFLAGS="$CFLAGS $GLIB_CFLAGS"
 183 LIBS="$LIBS $GLIB_LIBS"
 184 AC_RUN_IFELSE([AC_LANG_PROGRAM([#include <gio/gio.h>],
 185                                [g_type_init (); return !g_tls_backend_supports_tls (g_tls_backend_get_default ());])],
 186               [have_glib_networking=yes],
 187               [have_glib_networking=no],
 188               [have_glib_networking="unknown (cross-compiling)"])
 189 CFLAGS="$save_CFLAGS"
 190 LIBS="$save_LIBS"
 191 AC_MSG_RESULT($have_glib_networking)
 192
 193 AC_ARG_ENABLE(tls-check,
 194               AS_HELP_STRING([--disable-tls-check], [Don't error out if glib-networking is unavailable]))
 195 if test "$enable_tls_check" != "no" -a "$have_glib_networking" = "no"; then
 196         AC_MSG_ERROR([libsoup requires glib-networking for TLS support.
 197
 198 If you are building a package, you can pass --disable-tls-check to
 199 allow building libsoup anyway (since glib-networking is not actually
 200 required at compile time), but you should be sure to add a runtime
 201 dependency on it.])
 202 fi
 203
 204 dnl ******************************
 205 dnl *** Stuff for regression tests
 206 dnl ******************************
 207 AC_MSG_NOTICE([checking for programs needed for regression tests])
 208 MISSING_REGRESSION_TEST_PACKAGES=""
 209
 210 if test "$have_glib_networking" = "no"; then
 211         MISSING_REGRESSION_TEST_PACKAGES="$MISSING_REGRESSION_TEST_PACKAGES glib-networking"
 212 fi
 213
 214 AC_ARG_WITH(apache-httpd,
 215             AS_HELP_STRING([--with-apache-httpd], [Path to apache httpd (for tests)]),
 216             APACHE_HTTPD="$withval",
 217             [AC_PATH_PROGS(APACHE_HTTPD, httpd2 httpd apache2 apache, no, ${PATH}:/usr/sbin)])
 218 if test "$APACHE_HTTPD" != "no"; then
 219     AC_MSG_CHECKING([Apache version])
 220     apache_version=`$APACHE_HTTPD -v 2>/dev/null | sed -ne 's/Server version: Apache\///p'`
 221     case $apache_version in
 222     2.2.*)
 223         AC_MSG_RESULT([$apache_version (ok)])
 224         apache_version=2.2
 225         ;;
 226     2.4.*)
 227         AC_MSG_RESULT([$apache_version (ok)])
 228         apache_version=2.4
 229         ;;
 230     *)
 231         AC_MSG_RESULT([$apache_version (ignoring)])
 232         APACHE_HTTPD="no"
 233         ;;
 234     esac
 235 fi
 236 AC_SUBST(APACHE_HTTPD)
 237 AC_DEFINE_UNQUOTED(APACHE_HTTPD, "$APACHE_HTTPD", [Apache httpd])
 238
 239 if test "$APACHE_HTTPD" != "no"; then
 240     AC_MSG_CHECKING([for Apache module directory])
 241     AC_ARG_WITH(apache-module-dir,
 242                 AS_HELP_STRING([--with-apache-module-dir], [Apache modules dirs (for tests)]),
 243                 apache_module_dirs="$withval",
 244                 [apache_prefix=`dirname \`dirname $APACHE_HTTPD\``
 245                 mpm=`$APACHE_HTTPD -V -C "ServerName localhost" | sed -ne 's/^Server MPM: */-/p' | tr 'A-Z' 'a-z'`
 246                 # This only works with bash, but should fail harmlessly in sh
 247                 apache_module_dirs=`echo $apache_prefix/lib{64,}/{apache,apache2,http,http2,httpd}{$mpm,}{/modules,}`])
 248     for dir in $apache_module_dirs; do
 249         if test -f $dir/mod_auth_digest.so; then
 250             APACHE_MODULE_DIR="$dir"
 251         fi
 252         if test -f $dir/mod_ssl.so; then
 253             APACHE_SSL_MODULE_DIR="$dir"
 254             IF_HAVE_APACHE_SSL=""
 255         fi
 256         if test -f $dir/mod_php5.so; then
 257             APACHE_PHP_MODULE_DIR="$dir"
 258             APACHE_PHP_MODULE=mod_php5.so
 259         fi
 260         if test -f $dir/libphp5.so; then
 261             APACHE_PHP_MODULE_DIR="$dir"
 262             APACHE_PHP_MODULE=libphp5.so
 263         fi
 264     done
 265     AC_MSG_RESULT($APACHE_MODULE_DIR)
 266     AC_SUBST(APACHE_MODULE_DIR)
 267     AC_SUBST(APACHE_SSL_MODULE_DIR)
 268     AC_SUBST(APACHE_PHP_MODULE_DIR)
 269     AC_SUBST(APACHE_PHP_MODULE)
 270 fi
 271
 272 if test "$APACHE_HTTPD" != "no" -a -n "$APACHE_MODULE_DIR" -a -n "$APACHE_SSL_MODULE_DIR"; then
 273     AC_DEFINE(HAVE_APACHE, 1, [Whether or not apache can be used for tests])
 274     if test $apache_version = 2.2; then
 275         AC_DEFINE(HAVE_APACHE_2_2, 1, [Apache is 2.2.x])
 276     else
 277         AC_DEFINE(HAVE_APACHE_2_4, 1, [Apache is 2.4.x])
 278     fi
 279     have_apache=1
 280     if test -z "$APACHE_PHP_MODULE_DIR"; then
 281         MISSING_REGRESSION_TEST_PACKAGES="$MISSING_REGRESSION_TEST_PACKAGES mod_php5"
 282     fi
 283 else
 284     have_apache=0
 285     if test "$APACHE_HTTPD" = "no" -o -z "$APACHE_MODULE_DIR"; then
 286         MISSING_REGRESSION_TEST_PACKAGES="$MISSING_REGRESSION_TEST_PACKAGES apache"
 287     else
 288         MISSING_REGRESSION_TEST_PACKAGES="$MISSING_REGRESSION_TEST_PACKAGES mod_ssl"
 289     fi
 290 fi
 291 AM_CONDITIONAL(HAVE_APACHE, test "$have_apache" = 1)
 292 AM_CONDITIONAL(HAVE_APACHE_2_2, test "$apache_version" = 2.2)
 293 AM_CONDITIONAL(HAVE_APACHE_2_4, test "$apache_version" = 2.4)
 294
 295 if test "$have_apache" = 1; then
 296     AC_CHECK_PROGS(PHP, php php5)
 297
 298     AC_MSG_CHECKING([for Apache PHP module])
 299     if test -f $APACHE_PHP_MODULE_DIR/$APACHE_PHP_MODULE; then
 300         have_php=yes
 301         IF_HAVE_PHP=""
 302     else
 303         have_php=no
 304         IF_HAVE_PHP="#"
 305         MISSING_REGRESSION_TEST_PACKAGES="$MISSING_REGRESSION_TEST_PACKAGES php5"
 306     fi
 307     AC_MSG_RESULT($have_php)
 308
 309     if test "$have_php" = yes; then
 310         AC_MSG_CHECKING([for xmlrpc-php])
 311         if $PHP --rf xmlrpc_server_create | grep -q "does not exist"; then
 312             have_xmlrpc_php=no
 313             MISSING_REGRESSION_TEST_PACKAGES="$MISSING_REGRESSION_TEST_PACKAGES php-xmlrpc"
 314         else
 315             have_xmlrpc_php=yes
 316         fi
 317         AC_MSG_RESULT($have_xmlrpc_php)
 318     fi
 319 fi
 320
 321 AC_SUBST(IF_HAVE_PHP)
 322 AM_CONDITIONAL(HAVE_XMLRPC_PHP, test "$have_xmlrpc_php" = yes)
 323
 324 AC_PATH_PROG(CURL, curl, no)
 325 if test "$CURL" != no; then
 326     AC_DEFINE(HAVE_CURL, 1, [Whether or not curl can be used for tests])
 327 else
 328     MISSING_REGRESSION_TEST_PACKAGES="$MISSING_REGRESSION_TEST_PACKAGES curl"
 329 fi
 330 AM_CONDITIONAL(HAVE_CURL, test "$CURL" != no)
 331
 332 GLIB_COMPILE_RESOURCES=`$PKG_CONFIG --variable glib_compile_resources gio-2.0`
 333 AC_SUBST(GLIB_COMPILE_RESOURCES)
 334
 335 AC_SUBST(MISSING_REGRESSION_TEST_PACKAGES)
 336 AM_CONDITIONAL(MISSING_REGRESSION_TEST_PACKAGES, test -n "$MISSING_REGRESSION_TEST_PACKAGES")
 337
 338 dnl **********************************************************
 339 dnl *** path of NTLM single-sign-on helper ntlm_auth
 340 dnl **********************************************************
 341 AC_ARG_WITH(ntlm-auth,
 342             AC_HELP_STRING([--with-ntlm-auth=PATH],[Where to look for ntlm_auth, path points to ntlm_auth installation (default: /usr/bin/ntlm_auth)]),
 343             ntlm_auth="$withval",
 344             [if test $os_win32 = yes; then ntlm_auth="no"; else ntlm_auth="/usr/bin/ntlm_auth"; fi])
 345 if test "$ntlm_auth" != "no"; then
 346     AC_DEFINE(USE_NTLM_AUTH, 1, [Whether or not use Samba's 'winbind' daemon helper 'ntlm_auth' for NTLM single-sign-on])
 347     if test "$ntlm_auth" = "yes"; then
 348         dnl --with-ntlm-auth (without path) used, use default path
 349         ntlm_auth="/usr/bin/ntlm_auth"
 350     fi
 351 fi
 352 AC_SUBST(ntlm_auth)
 353 AC_DEFINE_UNQUOTED(NTLM_AUTH, "$ntlm_auth", [Samba's 'winbind' daemon helper 'ntlm_auth' which can be used for NTLM single-sign-on])
 354
 355 dnl ****************************************************
 356 dnl *** Warnings to show if using GCC                ***
 357 dnl *** (do this last so -Werror won't mess up tests ***
 358 dnl ****************************************************
 359
 360 AC_ARG_ENABLE(more-warnings,
 361               AS_HELP_STRING([--disable-more-warnings], [Inhibit compiler warnings]),
 362               set_more_warnings=no)
 363
 364 if test "$GCC" = "yes" -a "$set_more_warnings" != "no"; then
 365         CFLAGS="$CFLAGS \
 366                 -Wall -Wstrict-prototypes -Werror=missing-prototypes \
 367                 -Werror=implicit-function-declaration \
 368                 -Werror=pointer-arith -Werror=init-self -Werror=format=2 \
 369                 -Werror=missing-include-dirs -Werror=aggregate-return \
 370                 -Werror=declaration-after-statement"
 371 fi
 372
 373 dnl *************************
 374 dnl *** Output Everything ***
 375 dnl *************************
 376
 377 AC_CONFIG_HEADERS([config.h])
 378 AC_CONFIG_FILES([
 379         libsoup-2.4.pc
 380         libsoup-gnome-2.4.pc
 381         Makefile
 382         libsoup-zip
 383         libsoup/Makefile
 384         po/Makefile.in
 385         po/Makefile
 386         tests/Makefile
 387         docs/Makefile
 388         docs/reference/Makefile
 389         libsoup/soup-version.h
 390         ])
 391 AC_OUTPUT
 392
 393 if test -n "$MISSING_REGRESSION_TEST_PACKAGES"; then
 394     echo ""
 395     echo Some regression tests will not be run due to missing packages:
 396     echo $MISSING_REGRESSION_TEST_PACKAGES
 397     echo ""
 398 fi