configure.ac

   1 dnl -*- mode: m4 -*-
   2 AC_PREREQ([2.63])
   3
   4 m4_define([dbus_major_version], [1])
   5 m4_define([dbus_minor_version], [4])
   6 m4_define([dbus_micro_version], [15])
   7 m4_define([dbus_version],
   8           [dbus_major_version.dbus_minor_version.dbus_micro_version])
   9 AC_INIT([dbus],[dbus_version],[https://bugs.freedesktop.org/enter_bug.cgi?product=dbus],[dbus])
  10
  11 AC_CANONICAL_HOST
  12
  13 AC_CONFIG_HEADERS([config.h])
  14 AC_CONFIG_MACRO_DIR([m4])
  15
  16 AM_INIT_AUTOMAKE([1.10 tar-ustar -Wno-portability])
  17
  18 GETTEXT_PACKAGE=dbus-1
  19 AC_SUBST(GETTEXT_PACKAGE)
  20 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[The name of the gettext domain])
  21
  22  ## must come before we use the $USE_MAINTAINER_MODE variable later
  23 AM_MAINTAINER_MODE
  24
  25 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  26
  27 AC_DEFINE_UNQUOTED(DBUS_DAEMON_NAME,"dbus-daemon",[Name of executable])
  28
  29 # libtool versioning - this applies to libdbus
  30 #
  31 # See http://sources.redhat.com/autobook/autobook/autobook_91.html#SEC91 for details
  32 #
  33
  34 ## increment if the interface has additions, changes, removals.
  35 LT_CURRENT=8
  36
  37 ## increment any time the source changes; set to
  38 ##  0 if you increment CURRENT
  39 LT_REVISION=7
  40
  41 ## increment if any interfaces have been added; set to 0
  42 ## if any interfaces have been changed or removed. removal has
  43 ## precedence over adding, so set to 0 if both happened.
  44 LT_AGE=5
  45
  46 AC_SUBST(LT_CURRENT)
  47 AC_SUBST(LT_REVISION)
  48 AC_SUBST(LT_AGE)
  49
  50 DBUS_MAJOR_VERSION=dbus_major_version
  51 DBUS_MINOR_VERSION=dbus_minor_version
  52 DBUS_MICRO_VERSION=dbus_micro_version
  53 DBUS_VERSION=dbus_major_version.dbus_minor_version.dbus_micro_version
  54
  55 AC_SUBST(DBUS_MAJOR_VERSION)
  56 AC_SUBST(DBUS_MINOR_VERSION)
  57 AC_SUBST(DBUS_MICRO_VERSION)
  58 AC_SUBST(DBUS_VERSION)
  59
  60 AC_PROG_CC
  61 AM_PROG_CC_C_O
  62 AC_PROG_CXX
  63 AC_USE_SYSTEM_EXTENSIONS
  64 AC_ISC_POSIX
  65 AC_HEADER_STDC
  66 AC_C_INLINE
  67 AM_PROG_LIBTOOL
  68 AC_PROG_MKDIR_P
  69 COMPILER_COVERAGE
  70 COMPILER_OPTIMISATIONS
  71
  72 # Initialize libtool
  73 LT_INIT([win32-dll])
  74 LT_LANG([Windows Resource])
  75
  76 # Set some internal variables depending on the platform for later use.
  77 dbus_win=no
  78 dbus_cygwin=no
  79 dbus_unix=no
  80 case "${host}" in
  81     *-mingw32ce*)
  82         dbus_win=yes
  83         dbus_wince=yes
  84         ;;
  85     *-mingw32*)
  86         dbus_win=yes
  87         ;;
  88     *-cygwin*)
  89         dbus_cygwin=yes
  90         dbus_unix=yes
  91         ;;
  92     *)
  93         dbus_unix=yes
  94        ;;
  95 esac
  96
  97 # Special defines for certain platforms
  98 if test "$dbus_win" = yes; then
  99     AC_DEFINE(DBUS_WIN,1,[Defined if we run on a W32 API based system])
 100     BUILD_TIMESTAMP=`date --iso-8601=minutes`
 101     AC_SUBST(BUILD_TIMESTAMP)
 102     # Assume DBUS_VERSION is always three numbers
 103     BUILD_FILEVERSION=`echo "$DBUS_VERSION" | sed -e 's/\./,/g'`,0
 104     AC_SUBST(BUILD_FILEVERSION)
 105     AC_CHECK_TOOL(WINDRES, windres, no)
 106     if test "$WINDRES" = no; then
 107       AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 108     fi
 109     if test "$dbus_wince" = yes; then
 110       AC_DEFINE(DBUS_WINCE,1,[Defined if we run on a W32 CE API based system])
 111       AC_DEFINE(_WIN32_WCE, 0x0502, [Defined to get newer W32 CE APIs])
 112     fi
 113 else
 114     AC_DEFINE(DBUS_UNIX,1,[Defined if we run on a Unix-based system])
 115 fi
 116 if test "$dbus_cygwin" = yes; then
 117     AC_DEFINE(DBUS_CYGWIN,1,[Defined if we run on a cygwin API based system])
 118 fi
 119
 120 AM_CONDITIONAL(DBUS_WIN, test "$dbus_win" = yes)
 121 AM_CONDITIONAL(DBUS_WINCE, test "$dbus_wince" = yes)
 122 AM_CONDITIONAL(DBUS_UNIX, test "$dbus_unix" = yes)
 123 AM_CONDITIONAL(DBUS_CYGWIN, test "$dbus_cygwin" = yes)
 124
 125 AC_ARG_ENABLE(ansi, AS_HELP_STRING([--enable-ansi],[enable -ansi -pedantic gcc flags]),enable_ansi=$enableval,enable_ansi=no)
 126 AC_ARG_ENABLE(verbose-mode, AS_HELP_STRING([--enable-verbose-mode],[support verbose debug mode]),enable_verbose_mode=$enableval,enable_verbose_mode=$USE_MAINTAINER_MODE)
 127 AC_ARG_ENABLE(asserts, AS_HELP_STRING([--enable-asserts],[include assertion checks]),enable_asserts=$enableval,enable_asserts=$USE_MAINTAINER_MODE)
 128 AC_ARG_ENABLE(checks, AS_HELP_STRING([--enable-checks],[include sanity checks on public API]),enable_checks=$enableval,enable_checks=yes)
 129 AC_ARG_ENABLE(xml-docs, AS_HELP_STRING([--enable-xml-docs],[build XML documentation (requires xmlto)]),enable_xml_docs=$enableval,enable_xml_docs=auto)
 130 AC_ARG_ENABLE(doxygen-docs, AS_HELP_STRING([--enable-doxygen-docs],[build DOXYGEN documentation (requires Doxygen)]),enable_doxygen_docs=$enableval,enable_doxygen_docs=auto)
 131 AC_ARG_ENABLE(abstract-sockets, AS_HELP_STRING([--enable-abstract-sockets],[use abstract socket namespace (linux only)]),enable_abstract_sockets=$enableval,enable_abstract_sockets=auto)
 132 AC_ARG_ENABLE(selinux, AS_HELP_STRING([--enable-selinux],[build with SELinux support]),enable_selinux=$enableval,enable_selinux=auto)
 133 AC_ARG_ENABLE(libaudit,AS_HELP_STRING([--enable-libaudit],[build audit daemon support for SELinux]),enable_libaudit=$enableval,enable_libaudit=auto)
 134 AC_ARG_ENABLE(dnotify, AS_HELP_STRING([--enable-dnotify],[build with dnotify support (linux only)]),enable_dnotify=$enableval,enable_dnotify=auto)
 135 AC_ARG_ENABLE(inotify, AS_HELP_STRING([--enable-inotify],[build with inotify support (linux only)]),enable_inotify=$enableval,enable_inotify=auto)
 136 AC_ARG_ENABLE(kqueue, AS_HELP_STRING([--enable-kqueue],[build with kqueue support]),enable_kqueue=$enableval,enable_kqueue=auto)
 137 AC_ARG_ENABLE(console-owner-file, AS_HELP_STRING([--enable-console-owner-file],[enable console owner file]),enable_console_owner_file=$enableval,enable_console_owner_file=auto)
 138 AC_ARG_ENABLE(userdb-cache, AS_HELP_STRING([--enable-userdb-cache],[build with userdb-cache support]),enable_userdb_cache=$enableval,enable_userdb_cache=yes)
 139 AC_ARG_ENABLE(launchd, AS_HELP_STRING([--enable-launchd],[build with launchd auto-launch support]),enable_launchd=$enableval,enable_launchd=auto)
 140
 141 AC_ARG_WITH(xml, AS_HELP_STRING([--with-xml=[libxml/expat]],[XML library to use (libxml may be named libxml2 on some systems)]))
 142 AC_ARG_WITH(init-scripts, AS_HELP_STRING([--with-init-scripts=[redhat]],[Style of init scripts to install]))
 143 AC_ARG_WITH(session-socket-dir, AS_HELP_STRING([--with-session-socket-dir=[dirname]],[Where to put sockets for the per-login-session message bus]))
 144 AC_ARG_WITH(test-socket-dir, AS_HELP_STRING([--with-test-socket-dir=[dirname]],[Where to put sockets for make check]))
 145 AC_ARG_WITH(system-pid-file, AS_HELP_STRING([--with-system-pid-file=[pidfile]],[PID file for systemwide daemon]))
 146 AC_ARG_WITH(system-socket, AS_HELP_STRING([--with-system-socket=[filename]],[UNIX domain socket for systemwide daemon]))
 147 AC_ARG_WITH(console-auth-dir, AS_HELP_STRING([--with-console-auth-dir=[dirname]],[directory to check for console ownerhip]))
 148 AC_ARG_WITH(console-owner-file, AS_HELP_STRING([--with-console-owner-file=[filename]],[file whose owner determines current console owner]))
 149 AC_ARG_WITH(launchd-agent-dir, AS_HELP_STRING([--with-launchd-agent-dir=[dirname]],[directory to put the launchd agent (default: /Library/LaunchAgents)]))
 150 AC_ARG_WITH(dbus_user, AS_HELP_STRING([--with-dbus-user=<user>],[User for running the DBUS daemon (messagebus)]))
 151 AC_ARG_WITH(dbus_daemondir, AS_HELP_STRING([--with-dbus-daemondir=[dirname]],[Directory for installing the DBUS daemon]))
 152
 153 AC_ARG_ENABLE([embedded-tests],
 154   AS_HELP_STRING([--enable-embedded-tests],
 155     [enable unit test code in the library and binaries]),
 156   [], [enable_embedded_tests=$USE_MAINTAINER_MODE])
 157 AC_ARG_ENABLE([modular-tests],
 158   AS_HELP_STRING([--enable-modular-tests],
 159     [enable modular regression tests (requires GLib)]),
 160   [], [enable_modular_tests=auto])
 161 # --enable-tests overrides both --enable-embedded-tests and
 162 # --enable-modular-tests
 163 AC_ARG_ENABLE([tests],
 164   AS_HELP_STRING([--enable-tests],
 165     [enable/disable all tests, overriding embedded-tests/modular-tests]),
 166   [
 167   if test "x$enableval" = xyes; then
 168     AC_MSG_NOTICE([Full test coverage was requested with --enable-tests=yes])
 169     AC_MSG_NOTICE([This has many dependencies (GLib, dbus-glib, Python)])
 170   fi
 171   enable_embedded_tests=$enableval
 172   enable_modular_tests=$enableval
 173   ],
 174   [])
 175
 176 # DBUS_ENABLE_EMBEDDED_TESTS controls unit tests built in to .c files
 177 # and also some stuff in the test/ subdir. DBUS_BUILD_TESTS was an older
 178 # name for this.
 179 AM_CONDITIONAL([DBUS_BUILD_TESTS], [test "x$enable_embedded_tests" = xyes])
 180 AM_CONDITIONAL([DBUS_ENABLE_EMBEDDED_TESTS],
 181   [test "x$enable_embedded_tests" = xyes])
 182 if test "x$enable_embedded_tests" = xyes; then
 183     AC_DEFINE([DBUS_ENABLE_EMBEDDED_TESTS], [1],
 184       [Define to build test code into the library and binaries])
 185     AC_DEFINE([DBUS_BUILD_TESTS], [1],
 186       [Define to build test code into the library and binaries])
 187 fi
 188
 189 # DBUS_ENABLE_MODULAR_TESTS controls tests that work based on public API.
 190 # These use GTest, from GLib, because life's too short. They're enabled by
 191 # default (unless you don't have GLib), because they don't bloat the library
 192 # or binaries.
 193 if test "x$enable_modular_tests" != xno; then
 194   PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.22, gio-2.0 >= 2.22],
 195     [],
 196     [if test "x$enable_modular_tests" = xyes; then
 197       AC_MSG_NOTICE([Full test coverage (--enable-modular-tests=yes or --enable-tests=yes) requires GLib])
 198       AC_MSG_ERROR([$GLIB_ERRORS])
 199     else # assumed to be "auto"
 200       enable_modular_tests=no
 201     fi])
 202   # If dbus-gmain.[ch] returned to libdbus then we wouldn't need this
 203   PKG_CHECK_MODULES([DBUS_GLIB], [dbus-glib-1],
 204     [],
 205     [if test "x$enable_modular_tests" = xyes; then
 206       AC_MSG_NOTICE([Full test coverage (--enable-modular-tests=yes or --enable-tests=yes) requires dbus-glib])
 207       AC_MSG_ERROR([$DBUS_GLIB_ERRORS])
 208     else # assumed to be "auto"
 209       enable_modular_tests=no
 210     fi])
 211   if test "x$enable_modular_tests" != xno; then
 212     # dependencies checked, switch from auto to yes
 213     enable_modular_tests=yes
 214   fi
 215 fi
 216 if test "x$enable_modular_tests" = xyes; then
 217   AC_DEFINE([DBUS_ENABLE_MODULAR_TESTS], [1],
 218     [Define to build independent test binaries (requires GLib)])
 219 fi
 220 AM_CONDITIONAL([DBUS_ENABLE_MODULAR_TESTS],
 221   [test "x$enable_modular_tests" = xyes])
 222
 223 AC_ARG_ENABLE([installed-tests],
 224   AS_HELP_STRING([--enable-installed-tests],
 225     [enable unit test code in the library and binaries]),
 226   [], [enable_installed_tests=no])
 227 AM_CONDITIONAL([DBUS_ENABLE_INSTALLED_TESTS],
 228   [test "x$enable_installed_tests" = xyes])
 229
 230 if test "x$enable_tests" = xyes; then
 231   # full test coverage is required, Python is a hard dependency
 232   AC_MSG_NOTICE([Full test coverage (--enable-tests=yes) requires Python])
 233   AM_PATH_PYTHON([2.6])
 234 else
 235   # --enable-tests not given: do not abort if Python is missing
 236   AM_PATH_PYTHON([2.6], [], [:])
 237 fi
 238
 239 if test x$enable_verbose_mode = xyes; then
 240     AC_DEFINE(DBUS_ENABLE_VERBOSE_MODE,1,[Support a verbose mode])
 241 fi
 242
 243 if test x$enable_asserts = xno; then
 244     AC_DEFINE(DBUS_DISABLE_ASSERT,1,[Disable assertion checking])
 245     R_DYNAMIC_LDFLAG=""
 246 else
 247     # -rdynamic is needed for glibc's backtrace_symbols to work.
 248     # No clue how much overhead this adds, but it's useful
 249     # to do this on any assertion failure,
 250     # so for now it's enabled anytime asserts are (currently not
 251     # in production builds).
 252
 253     # To get -rdynamic you pass -export-dynamic to libtool.
 254     AC_DEFINE(DBUS_BUILT_R_DYNAMIC,1,[whether -export-dynamic was passed to libtool])
 255     R_DYNAMIC_LDFLAG=-export-dynamic
 256 fi
 257 AC_SUBST(R_DYNAMIC_LDFLAG)
 258
 259 if test x$enable_checks = xno; then
 260     AC_DEFINE(DBUS_DISABLE_CHECKS,1,[Disable public API sanity checking])
 261     AC_DEFINE(G_DISABLE_CHECKS,1,[Disable GLib public API sanity checking])
 262 fi
 263
 264 if test x$enable_userdb_cache = xyes; then
 265     AC_DEFINE(DBUS_ENABLE_USERDB_CACHE,1,[Build with caching of user data])
 266 fi
 267
 268 if test x$enable_compiler_coverage = xyes; then
 269      ## so that config.h changes when you toggle gcov support
 270      AC_DEFINE_UNQUOTED(DBUS_GCOV_ENABLED, 1, [Defined if gcov is enabled to force a rebuild due to config.h changing])
 271 fi
 272
 273 # glibc21.m4 serial 3
 274 dnl Copyright (C) 2000-2002, 2004 Free Software Foundation, Inc.
 275 dnl This file is free software; the Free Software Foundation
 276 dnl gives unlimited permission to copy and/or distribute it,
 277 dnl with or without modifications, as long as this notice is preserved.
 278
 279 # Test for the GNU C Library, version 2.1 or newer.
 280 # From Bruno Haible.
 281
 282 AC_CACHE_CHECK(whether we are using the GNU C Library 2.1 or newer,
 283   ac_cv_gnu_library_2_1,
 284   [AC_EGREP_CPP([Lucky GNU user],
 285     [
 286 #include <features.h>
 287 #ifdef __GNU_LIBRARY__
 288  #if (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 1) || (__GLIBC__ > 2)
 289   Lucky GNU user
 290  #endif
 291 #endif
 292     ],
 293     ac_cv_gnu_library_2_1=yes,
 294     ac_cv_gnu_library_2_1=no)
 295   ]
 296 )
 297
 298 #### Integer sizes
 299
 300 AC_CHECK_SIZEOF(char)
 301 AC_CHECK_SIZEOF(short)
 302 AC_CHECK_SIZEOF(long)
 303 AC_CHECK_SIZEOF(int)
 304 AC_CHECK_SIZEOF(void *)
 305 AC_CHECK_SIZEOF(long long)
 306 AC_CHECK_SIZEOF(__int64)
 307
 308 ### See what our 64 bit type is called
 309 AC_MSG_CHECKING([64-bit integer type])
 310
 311 case 8 in
 312 $ac_cv_sizeof_int)
 313   dbusint64=int
 314   dbusint64_constant='(val)'
 315   dbusuint64_constant='(val)'
 316   dbusint64_printf_modifier='""'
 317   ;;
 318 $ac_cv_sizeof_long)
 319   dbusint64=long
 320   dbusint64_constant='(val##L)'
 321   dbusuint64_constant='(val##UL)'
 322   dbusint64_printf_modifier='"l"'
 323   ;;
 324 $ac_cv_sizeof_long_long)
 325   dbusint64='long long'
 326   dbusint64_constant='(val##LL)'
 327   dbusuint64_constant='(val##ULL)'
 328   # Ideally we discover what the format is, but this is
 329   # only used in verbose mode, so eh...
 330   if test x"$ac_cv_gnu_library_2_1" = xyes; then
 331     dbusint64_printf_modifier='"ll"'
 332   fi
 333   ;;
 334 $ac_cv_sizeof___int64)
 335   dbusint64=__int64
 336   dbusint64_constant='(val##i64)'
 337   dbusuint64_constant='(val##ui64)'
 338   # See above case
 339   if test x"$ac_cv_gnu_library_2_1" = xyes; then
 340     dbusint64_printf_modifier='"ll"'
 341   fi
 342   ;;
 343 esac
 344
 345 if test -z "$dbusint64" ; then
 346         DBUS_INT64_TYPE="no_int64_type_detected"
 347         DBUS_HAVE_INT64=0
 348         DBUS_INT64_CONSTANT=
 349         DBUS_UINT64_CONSTANT=
 350         AC_MSG_RESULT([none found])
 351 else
 352         DBUS_INT64_TYPE="$dbusint64"
 353         DBUS_HAVE_INT64=1
 354         DBUS_INT64_CONSTANT="$dbusint64_constant"
 355         DBUS_UINT64_CONSTANT="$dbusuint64_constant"
 356         if test x"$dbusint64_printf_modifier" != x; then
 357                 AC_DEFINE_UNQUOTED(DBUS_INT64_PRINTF_MODIFIER, [$dbusint64_printf_modifier], [Define to printf modifier for 64 bit integer type])
 358         fi
 359         AC_MSG_RESULT($DBUS_INT64_TYPE)
 360 fi
 361
 362 AC_SUBST(DBUS_INT64_TYPE)
 363 AC_SUBST(DBUS_INT64_CONSTANT)
 364 AC_SUBST(DBUS_UINT64_CONSTANT)
 365 AC_SUBST(DBUS_HAVE_INT64)
 366
 367 ### see what 32-bit int is called
 368 AC_MSG_CHECKING([32-bit integer type])
 369
 370 case 4 in
 371 $ac_cv_sizeof_short)
 372   dbusint32=short
 373   ;;
 374 $ac_cv_sizeof_int)
 375   dbusint32=int
 376   ;;
 377 $ac_cv_sizeof_long)
 378   dbusint32=long
 379   ;;
 380 esac
 381
 382 if test -z "$dbusint32" ; then
 383         DBUS_INT32_TYPE="no_int32_type_detected"
 384         AC_MSG_ERROR([No 32-bit integer type found])
 385 else
 386         DBUS_INT32_TYPE="$dbusint32"
 387         AC_MSG_RESULT($DBUS_INT32_TYPE)
 388 fi
 389
 390 AC_SUBST(DBUS_INT32_TYPE)
 391
 392 ### see what 16-bit int is called
 393 AC_MSG_CHECKING([16-bit integer type])
 394
 395 case 2 in
 396 $ac_cv_sizeof_short)
 397   dbusint16=short
 398   ;;
 399 $ac_cv_sizeof_int)
 400   dbusint16=int
 401   ;;
 402 esac
 403
 404 if test -z "$dbusint16" ; then
 405         DBUS_INT16_TYPE="no_int16_type_detected"
 406         AC_MSG_ERROR([No 16-bit integer type found])
 407 else
 408         DBUS_INT16_TYPE="$dbusint16"
 409         AC_MSG_RESULT($DBUS_INT16_TYPE)
 410 fi
 411
 412 AC_SUBST(DBUS_INT16_TYPE)
 413
 414 ## byte order
 415 case $host_os in
 416         darwin*)
 417                 # check at compile-time, so that it is possible to build universal
 418                 # (with multiple architectures at once on the compile line)
 419                 AH_VERBATIM([WORDS_BIGENDIAN_DARWIN], [
 420                         /* Use the compiler-provided endianness defines to allow universal compiling. */
 421                         #if defined(__BIG_ENDIAN__)
 422                         #define WORDS_BIGENDIAN 1
 423                         #endif
 424                 ])
 425                 ;;
 426         *)
 427                 AC_C_BIGENDIAN
 428                 ;;
 429 esac
 430
 431 dnl **********************************
 432 dnl *** va_copy checks (from GLib) ***
 433 dnl **********************************
 434 dnl we currently check for all three va_copy possibilities, so we get
 435 dnl all results in config.log for bug reports.
 436 AC_CACHE_CHECK([for an implementation of va_copy()],dbus_cv_va_copy,[
 437         AC_LINK_IFELSE([AC_LANG_SOURCE([#include <stdarg.h>
 438 #include <stdlib.h>
 439         static void f (int i, ...) {
 440         va_list args1, args2;
 441         va_start (args1, i);
 442         va_copy (args2, args1);
 443         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 444           exit (1);
 445         va_end (args1); va_end (args2);
 446         }
 447         int main() {
 448           f (0, 42);
 449           return 0;
 450         }])],
 451         [dbus_cv_va_copy=yes],
 452         [dbus_cv_va_copy=no])
 453 ])
 454 AC_CACHE_CHECK([for an implementation of __va_copy()],dbus_cv___va_copy,[
 455         AC_LINK_IFELSE([AC_LANG_SOURCE([#include <stdarg.h>
 456 #include <stdlib.h>
 457         static void f (int i, ...) {
 458         va_list args1, args2;
 459         va_start (args1, i);
 460         __va_copy (args2, args1);
 461         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 462           exit (1);
 463         va_end (args1); va_end (args2);
 464         }
 465         int main() {
 466           f (0, 42);
 467           return 0;
 468         }])],
 469         [dbus_cv___va_copy=yes],
 470         [dbus_cv___va_copy=no])
 471 ])
 472
 473 if test "x$dbus_cv_va_copy" = "xyes"; then
 474   dbus_va_copy_func=va_copy
 475 else if test "x$dbus_cv___va_copy" = "xyes"; then
 476   dbus_va_copy_func=__va_copy
 477 fi
 478 fi
 479
 480 if test -n "$dbus_va_copy_func"; then
 481   AC_DEFINE_UNQUOTED(DBUS_VA_COPY,$dbus_va_copy_func,[A 'va_copy' style function])
 482 fi
 483
 484 AC_LANG_PUSH(C)
 485 AC_CACHE_CHECK([whether va_lists can be copied by value],
 486         dbus_cv_va_val_copy,
 487         [AC_RUN_IFELSE([AC_LANG_PROGRAM(
 488 [[
 489         #include <stdarg.h>
 490         #include <stdlib.h>
 491 ]],
 492 [[
 493         static void f (int i, ...) {
 494         va_list args1, args2;
 495         va_start (args1, i);
 496         args2 = args1;
 497         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 498           exit (1);
 499         va_end (args1); va_end (args2);
 500         }
 501         int main() {
 502           f (0, 42);
 503           return 0;
 504         }
 505 ]])],
 506         [dbus_cv_va_val_copy=yes],
 507         [dbus_cv_va_val_copy=no],
 508         [dbus_cv_va_val_copy=yes])
 509 ])
 510 AC_LANG_POP(C)
 511
 512 if test "x$dbus_cv_va_val_copy" = "xno"; then
 513   AC_DEFINE(DBUS_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
 514 fi
 515
 516
 517 #### Atomic integers
 518
 519 AC_CACHE_CHECK([whether $CC knows __sync_sub_and_fetch()],
 520   dbus_cv_sync_sub_and_fetch,
 521   [AC_LINK_IFELSE([
 522      AC_LANG_PROGRAM([[]], [[int a = 4; int b = __sync_sub_and_fetch(&a, 4); exit(b); ]])],
 523      [dbus_cv_sync_sub_and_fetch=yes],
 524      [dbus_cv_sync_sub_and_fetch=no])
 525   ])
 526
 527 if test "x$dbus_cv_sync_sub_and_fetch" = "xyes" ; then
 528    have_sync=1
 529 else
 530    have_sync=0
 531 fi
 532
 533 AC_DEFINE_UNQUOTED([DBUS_USE_SYNC], [$have_sync], [Use the gcc __sync extension])
 534
 535 #### Various functions
 536 AC_SEARCH_LIBS(socket,[socket network])
 537 AC_CHECK_FUNC(gethostbyname,,[AC_CHECK_LIB(nsl,gethostbyname)])
 538
 539 AC_CHECK_FUNCS(vsnprintf vasprintf nanosleep usleep setenv clearenv unsetenv socketpair getgrouplist fpathconf setrlimit poll setlocale localeconv strtoll strtoull)
 540
 541 AC_CHECK_HEADERS([syslog.h])
 542 if test "x$ac_cv_header_syslog_h" = "xyes"; then
 543   AC_CHECK_DECLS([LOG_PERROR], [], [], [[#include <syslog.h>]])
 544 fi
 545
 546 #### Check for broken poll; taken from Glib's configure
 547
 548 AC_MSG_CHECKING([for broken poll])
 549 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 550     #include <stdlib.h>
 551     #include <fcntl.h>
 552     #include <poll.h>
 553     #ifdef HAVE_SYS_POLL_H
 554     #include <sys/poll.h>
 555     #endif
 556     int main(void) {
 557       struct pollfd fds[1];
 558       int fd;
 559       fd = open("/dev/null", 1);
 560       fds[0].fd = fd;
 561       fds[0].events = POLLIN;
 562       fds[0].revents = 0;
 563       if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
 564             exit(1);  /* Does not work for devices -- fail */
 565       }
 566       exit(0);
 567     }]])],
 568   [broken_poll=no],
 569   [broken_poll=yes
 570    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
 571   [broken_poll="no (cross compiling)"])
 572 AC_MSG_RESULT($broken_poll)
 573
 574 AC_MSG_CHECKING(for dirfd)
 575 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 576 #include <sys/types.h>
 577 #include <dirent.h>
 578 ]], [[
 579 DIR *dirp;
 580 dirp = opendir(".");
 581 dirfd(dirp);
 582 closedir(dirp);
 583 ]])],
 584 [dbus_have_dirfd=yes],
 585 [dbus_have_dirfd=no])
 586 AC_MSG_RESULT($dbus_have_dirfd)
 587 if test "$dbus_have_dirfd" = yes; then
 588         AC_DEFINE(HAVE_DIRFD,1,[Have dirfd function])
 589 else
 590         AC_MSG_CHECKING(for DIR *dirp->dd_fd)
 591         AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 592 #include <sys/types.h>
 593 #include <dirent.h>
 594         ]], [[
 595 DIR *dirp;
 596 int fd;
 597 dirp = opendir(".");
 598 fd = dirp->dd_fd;
 599 closedir(dirp);
 600         ]])],
 601         [dbus_have_ddfd=yes],
 602         [dbus_have_ddfd=no])
 603         AC_MSG_RESULT($dbus_have_ddfd)
 604         if test "$dbus_have_ddfd" = yes; then
 605                 AC_DEFINE(HAVE_DDFD,1,[Have the ddfd member of DIR])
 606         fi
 607 fi
 608
 609 AC_CHECK_HEADERS(sys/resource.h)
 610
 611 AC_CHECK_HEADERS(dirent.h)
 612
 613 AC_CHECK_HEADERS(execinfo.h, [AC_CHECK_FUNCS(backtrace)])
 614
 615 AC_CHECK_HEADERS(errno.h)
 616
 617 AC_CHECK_HEADERS(signal.h)
 618
 619 AC_CHECK_HEADERS(locale.h)
 620
 621 AC_CHECK_HEADERS(byteswap.h)
 622
 623 AC_CHECK_HEADERS(unistd.h)
 624
 625 AC_CHECK_HEADERS(ws2tcpip.h)
 626
 627 AC_CHECK_HEADERS(wspiapi.h)
 628
 629 # Add -D_POSIX_PTHREAD_SEMANTICS if on Solaris
 630 #
 631 case $host_os in
 632     solaris*)
 633        CFLAGS="$CFLAGS -D_POSIX_PTHREAD_SEMANTICS" ;;
 634 esac
 635
 636 # checking for a posix version of getpwnam_r
 637 # if we are cross compiling and can not run the test
 638 # assume getpwnam_r is the posix version
 639 # it is up to the person cross compiling to change
 640 # this behavior if desired
 641 AC_LANG_PUSH(C)
 642 AC_CACHE_CHECK([for posix getpwnam_r],
 643                 ac_cv_func_posix_getpwnam_r,
 644                 [AC_RUN_IFELSE([AC_LANG_PROGRAM(
 645 [[
 646 #include <errno.h>
 647 #include <pwd.h>
 648 ]],
 649 [[
 650     char buffer[10000];
 651     struct passwd pwd, *pwptr = &pwd;
 652     int error;
 653     errno = 0;
 654     error = getpwnam_r ("", &pwd, buffer,
 655                         sizeof (buffer), &pwptr);
 656    return (error < 0 && errno == ENOSYS)
 657            || error == ENOSYS;
 658 ]])],
 659         [ac_cv_func_posix_getpwnam_r=yes],
 660         [ac_cv_func_posix_getpwnam_r=no],
 661         [ac_cv_func_posix_getpwnam_r=yes]
 662 )])
 663 AC_LANG_POP(C)
 664
 665 if test "$ac_cv_func_posix_getpwnam_r" = yes; then
 666         AC_DEFINE(HAVE_POSIX_GETPWNAM_R,1,
 667                 [Have POSIX function getpwnam_r])
 668 else
 669         AC_CACHE_CHECK([for nonposix getpwnam_r],
 670                 ac_cv_func_nonposix_getpwnam_r,
 671                 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <pwd.h>]], [[char buffer[10000];
 672                         struct passwd pwd;
 673                         getpwnam_r ("", &pwd, buffer,
 674                                         sizeof (buffer));]])],
 675                         [ac_cv_func_nonposix_getpwnam_r=yes],
 676                         [ac_cv_func_nonposix_getpwnam_r=no])])
 677                 if test "$ac_cv_func_nonposix_getpwnam_r" = yes; then
 678                 AC_DEFINE(HAVE_NONPOSIX_GETPWNAM_R,1,
 679                         [Have non-POSIX function getpwnam_r])
 680         fi
 681 fi
 682
 683 dnl check for socklen_t
 684 AC_MSG_CHECKING(whether socklen_t is defined)
 685 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 686 #include <sys/types.h>
 687 #include <sys/socket.h>
 688 #include <netdb.h>
 689 ]], [[
 690 socklen_t foo;
 691 foo = 1;
 692 ]])],
 693 [dbus_have_socklen_t=yes],
 694 [dbus_have_socklen_t=no])
 695 AC_MSG_RESULT($dbus_have_socklen_t)
 696
 697 if test "x$dbus_have_socklen_t" = "xyes"; then
 698     AC_DEFINE(HAVE_SOCKLEN_T,1,[Have socklen_t type])
 699 fi
 700
 701 dnl check for writev header and writev function so we're
 702 dnl good to go if HAVE_WRITEV gets defined.
 703 AC_CHECK_HEADERS(sys/uio.h, [AC_CHECK_FUNCS(writev)])
 704
 705 dnl needed on darwin for NAME_MAX
 706 AC_CHECK_HEADERS(sys/syslimits.h)
 707
 708 dnl Make it easy to check if we have MSG_NOSIGNAL without actually having to include sys/socket.h
 709 AC_CHECK_DECLS([MSG_NOSIGNAL], [], [], [[ #include <sys/socket.h> ]])
 710
 711 dnl check for flavours of varargs macros (test from GLib)
 712 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 713 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[
 714 int a(int p1, int p2, int p3);
 715 #define call_a(...) a(1,__VA_ARGS__)
 716 call_a(2,3);
 717 ]])],
 718 [dbus_have_iso_c_varargs=yes],
 719 [dbus_have_iso_c_varargs=no])
 720 AC_MSG_RESULT($dbus_have_iso_c_varargs)
 721
 722 AC_MSG_CHECKING(for GNUC varargs macros)
 723 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[
 724 int a(int p1, int p2, int p3);
 725 #define call_a(params...) a(1,params)
 726 call_a(2,3);
 727 ]])],
 728 [dbus_have_gnuc_varargs=yes],
 729 [dbus_have_gnuc_varargs=no])
 730 AC_MSG_RESULT($dbus_have_gnuc_varargs)
 731
 732 dnl Output varargs tests
 733 if test x$dbus_have_iso_c_varargs = xyes; then
 734     AC_DEFINE(HAVE_ISO_VARARGS,1,[Have ISO C99 varargs macros])
 735 fi
 736 if test x$dbus_have_gnuc_varargs = xyes; then
 737     AC_DEFINE(HAVE_GNUC_VARARGS,1,[Have GNU-style varargs macros])
 738 fi
 739
 740 dnl Check for various credentials.
 741 AC_MSG_CHECKING(for struct cmsgcred)
 742 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 743 #include <sys/types.h>
 744 #include <sys/socket.h>
 745 ]], [[
 746 struct cmsgcred cred;
 747
 748 cred.cmcred_pid = 0;
 749 ]])],
 750 [dbus_have_struct_cmsgcred=yes],
 751 [dbus_have_struct_cmsgcred=no])
 752 AC_MSG_RESULT($dbus_have_struct_cmsgcred)
 753
 754 if test x$dbus_have_struct_cmsgcred = xyes; then
 755     AC_DEFINE(HAVE_CMSGCRED,1,[Have cmsgcred structure])
 756 fi
 757
 758 AC_CHECK_FUNCS(getpeerucred getpeereid)
 759
 760 AC_CHECK_FUNCS(pipe2 accept4)
 761
 762 #### Abstract sockets
 763
 764 if test x$enable_abstract_sockets = xauto; then
 765 AC_LANG_PUSH(C)
 766 warn_on_xcompile=no
 767 AC_CACHE_CHECK([abstract socket namespace],
 768                 ac_cv_have_abstract_sockets,
 769                 [AC_RUN_IFELSE([AC_LANG_PROGRAM(
 770 [[
 771 #include <sys/types.h>
 772 #include <stdlib.h>
 773 #include <string.h>
 774 #include <stdio.h>
 775 #include <sys/socket.h>
 776 #include <sys/un.h>
 777 #include <errno.h>
 778 ]],
 779 [[
 780   size_t slen;
 781   int listen_fd;
 782   struct sockaddr_un addr;
 783
 784   listen_fd = socket (PF_UNIX, SOCK_STREAM, 0);
 785
 786   if (listen_fd < 0)
 787     {
 788       fprintf (stderr, "socket() failed: %s\n", strerror (errno));
 789       exit (1);
 790     }
 791
 792   memset (&addr, '\0', sizeof (addr));
 793   addr.sun_family = AF_UNIX;
 794   strcpy (addr.sun_path, "X/tmp/dbus-fake-socket-path-used-in-configure-test");
 795   /* SUN_LEN uses strlen() so need to calculate it before adding \0 at the
 796    * beginning.
 797    */
 798   slen = SUN_LEN(&addr);
 799   addr.sun_path[0] = '\0'; /* this is what makes it abstract */
 800
 801   if (bind (listen_fd, (struct sockaddr*) &addr, slen) < 0)
 802     {
 803        fprintf (stderr, "Abstract socket namespace bind() failed: %s\n",
 804                 strerror (errno));
 805        exit (1);
 806     }
 807   else
 808     exit (0);
 809 ]])],
 810               [ac_cv_have_abstract_sockets=yes],
 811               [ac_cv_have_abstract_sockets=no],
 812               [
 813                 ac_cv_have_abstract_sockets=no
 814                 warn_on_xcompile=yes
 815               ]
 816 )])
 817 if test x$warn_on_xcompile = xyes ; then
 818   AC_MSG_WARN([Cannot check for abstract sockets when cross-compiling, please use --enable-abstract-sockets])
 819 fi
 820 AC_LANG_POP(C)
 821 fi
 822
 823 if test x$enable_abstract_sockets = xyes; then
 824     if test x$ac_cv_have_abstract_sockets = xno; then
 825         AC_MSG_ERROR([Abstract sockets explicitly required, and support not detected.])
 826     fi
 827 fi
 828
 829 if test x$enable_abstract_sockets = xno; then
 830    ac_cv_have_abstract_sockets=no;
 831 fi
 832
 833 if test x$ac_cv_have_abstract_sockets = xyes ; then
 834    DBUS_PATH_OR_ABSTRACT=abstract
 835    AC_DEFINE(HAVE_ABSTRACT_SOCKETS,1,[Have abstract socket namespace])
 836 else
 837    DBUS_PATH_OR_ABSTRACT=path
 838 fi
 839
 840 # this is used in addresses to prefer abstract, e.g.
 841 # unix:path=/foo or unix:abstract=/foo
 842 AC_SUBST(DBUS_PATH_OR_ABSTRACT)
 843
 844 PKG_PROG_PKG_CONFIG
 845
 846 #### Sort out XML library
 847
 848 # see what we have
 849 AC_CHECK_LIB(expat, XML_ParserCreate_MM,
 850              [ AC_CHECK_HEADERS(expat.h, have_expat=true, have_expat=false) ],
 851              have_expat=false)
 852
 853 # see what we want to use
 854 dbus_use_libxml=false
 855 dbus_use_expat=false
 856 if test x$with_xml = xexpat; then
 857         if ! $have_expat ; then
 858            AC_MSG_ERROR([Explicitly requested expat but expat not found])
 859         fi
 860         dbus_use_expat=true
 861 elif test x$with_xml = xlibxml; then
 862         PKG_CHECK_MODULES(LIBXML, libxml-2.0 >= 2.6.0, have_libxml=true, have_libxml=false)
 863         if ! $have_libxml ; then
 864            AC_MSG_ERROR([Explicitly requested libxml but libxml not found])
 865         fi
 866         dbus_use_libxml=true
 867 else
 868         ### expat is the default because libxml can't currently survive
 869         ### our brutal OOM-handling unit test setup.
 870         ### http://bugzilla.gnome.org/show_bug.cgi?id=109368
 871         if test x$have_expat = xfalse; then
 872                 AC_MSG_ERROR([Could not find expat.h, check config.log for failed attempts])
 873         fi
 874         ### By default, only use Expat since it's tested and known to work.  If you're a
 875         ### general-purpose OS vendor, please don't enable libxml.  For embedded use
 876         ### if your OS is built around libxml, that's another case.
 877         dbus_use_expat=true
 878 fi
 879
 880 AM_CONDITIONAL(DBUS_USE_EXPAT, $dbus_use_expat)
 881 AM_CONDITIONAL(DBUS_USE_LIBXML, $dbus_use_libxml)
 882
 883 if $dbus_use_expat; then
 884    XML_LIBS=-lexpat
 885    XML_CFLAGS=
 886 fi
 887 if $dbus_use_libxml; then
 888    XML_LIBS=$LIBXML_LIBS
 889    XML_CFLAGS=$LIBXML_CFLAGS
 890 fi
 891
 892 # Thread lib detection
 893 AC_CHECK_FUNC(pthread_cond_timedwait,[AC_CHECK_LIB(pthread,pthread_cond_timedwait,
 894                                                     [THREAD_LIBS="-lpthread"])])
 895 save_libs="$LIBS"
 896 LIBS="$LIBS $THREAD_LIBS"
 897 AC_CHECK_FUNC(pthread_condattr_setclock,have_pthread_condattr_setclock=true,have_pthread_condattr_setclock=false)
 898 if test x$have_pthread_condattr_setclock = xtrue; then
 899     AC_SEARCH_LIBS([clock_getres],[rt],[THREAD_LIBS="$THREAD_LIBS -lrt"])
 900     AC_MSG_CHECKING([for CLOCK_MONOTONIC])
 901     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>
 902 #include <pthread.h>
 903 ]], [[
 904 struct timespec monotonic_timer;
 905 pthread_condattr_t attr;
 906 pthread_condattr_init (&attr);
 907 pthread_condattr_setclock (&attr, CLOCK_MONOTONIC);
 908 clock_getres (CLOCK_MONOTONIC,&monotonic_timer);
 909 ]])],
 910 [have_clock_monotonic=true],
 911 [have_clock_monotonic=false])
 912 if test x$have_clock_monotonic = xtrue; then
 913     AC_MSG_RESULT([found])
 914     AC_DEFINE(HAVE_MONOTONIC_CLOCK, 1, [Define if we have CLOCK_MONOTONIC])
 915 else
 916     AC_MSG_RESULT([not found])
 917 fi
 918 fi
 919 LIBS="$save_libs"
 920
 921 # SELinux detection
 922 if test x$enable_selinux = xno ; then
 923     have_selinux=no;
 924 else
 925     # See if we have SELinux library
 926     AC_CHECK_LIB(selinux, is_selinux_enabled,
 927                  have_selinux=yes, have_selinux=no)
 928
 929     # see if we have the SELinux header with the new D-Bus stuff in it
 930     if test x$have_selinux = xyes ; then
 931         AC_MSG_CHECKING([for DBUS Flask permissions in selinux/av_permissions.h])
 932         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <selinux/av_permissions.h>]],
 933                           [[#ifdef DBUS__ACQUIRE_SVC return 0;
 934                             #else
 935                             #error DBUS__ACQUIRE_SVC not defined
 936                             #endif]])],
 937                           [have_selinux=yes],
 938                           [have_selinux=no])
 939         AC_MSG_RESULT($have_selinux)
 940     fi
 941
 942     if test x$enable_selinux = xauto ; then
 943         if test x$have_selinux = xno ; then
 944                 AC_MSG_WARN([Sufficiently new SELinux library not found])
 945         fi
 946     else
 947         if test x$have_selinux = xno ; then
 948                 AC_MSG_ERROR([SElinux explicitly required, and SELinux library not found])
 949         fi
 950     fi
 951 fi
 952
 953 AM_CONDITIONAL(HAVE_SELINUX, test x$have_selinux = xyes)
 954
 955 if test x$have_selinux = xyes ; then
 956     # the selinux code creates threads
 957     # which requires libpthread even on linux
 958     AC_CHECK_FUNC(pthread_create,,[AC_CHECK_LIB(pthread,pthread_create,
 959                                                 [SELINUX_THREAD_LIBS="-lpthread"])])
 960
 961     SELINUX_LIBS="-lselinux $SELINUX_THREAD_LIBS"
 962     AC_DEFINE(HAVE_SELINUX,1,[SELinux support])
 963 else
 964     SELINUX_LIBS=
 965 fi
 966
 967 # inotify checks
 968 if test x$enable_inotify = xno ; then
 969     have_inotify=no;
 970 else
 971     AC_CHECK_HEADERS(sys/inotify.h, have_inotify=yes, have_inotify=no)
 972 fi
 973
 974 dnl check if inotify backend is enabled
 975 if test x$have_inotify = xyes; then
 976    AC_DEFINE(DBUS_BUS_ENABLE_INOTIFY,1,[Use inotify])
 977    AC_CHECK_FUNCS(inotify_init1)
 978 fi
 979
 980 AM_CONDITIONAL(DBUS_BUS_ENABLE_INOTIFY, test x$have_inotify = xyes)
 981
 982 # dnotify checks
 983 if test x$enable_dnotify = xno ; then
 984     have_dnotify=no;
 985 else
 986     if test x$have_inotify = xno -a x$host_os = xlinux-gnu -o x$host_os = xlinux; then
 987         have_dnotify=yes;
 988     else
 989         have_dnotify=no;
 990     fi
 991 fi
 992
 993 dnl check if dnotify backend is enabled
 994 if test x$have_dnotify = xyes; then
 995    AC_DEFINE(DBUS_BUS_ENABLE_DNOTIFY_ON_LINUX,1,[Use dnotify on Linux])
 996 fi
 997
 998 AM_CONDITIONAL(DBUS_BUS_ENABLE_DNOTIFY_ON_LINUX, test x$have_dnotify = xyes)
 999
1000 # kqueue checks
1001 if test x$enable_kqueue = xno ; then
1002     have_kqueue=no
1003 else
1004     have_kqueue=yes
1005     AC_CHECK_HEADER(sys/event.h, , have_kqueue=no)
1006     AC_CHECK_FUNC(kqueue, , have_kqueue=no)
1007
1008     if test x$enable_kqueue = xyes -a x$have_kqueue = xno; then
1009         AC_MSG_ERROR(kqueue support explicitly enabled but not available)
1010     fi
1011 fi
1012
1013 dnl check if kqueue backend is enabled
1014 if test x$have_kqueue = xyes; then
1015    AC_DEFINE(DBUS_BUS_ENABLE_KQUEUE,1,[Use kqueue])
1016 fi
1017
1018 AM_CONDITIONAL(DBUS_BUS_ENABLE_KQUEUE, test x$have_kqueue = xyes)
1019
1020 # launchd checks
1021 if test x$enable_launchd = xno ; then
1022     have_launchd=no
1023 else
1024     have_launchd=yes
1025     AC_CHECK_HEADER([launch.h], , have_launchd=no)
1026     AC_PATH_PROG([LAUNCHCTL], [launchctl])
1027     if test "x$LAUNCHCTL" = "x"; then
1028         have_launchd=no
1029     fi
1030
1031     if test x$enable_launchd = xyes && test x$have_launchd = xno ; then
1032         AC_MSG_ERROR([launchd support explicitly enabled but not available])
1033     fi
1034 fi
1035
1036 dnl check if launchd is enabled
1037 if test x$have_launchd = xyes; then
1038     AC_DEFINE(DBUS_ENABLE_LAUNCHD,1,[Use launchd autolaunch])
1039 fi
1040
1041 AM_CONDITIONAL(DBUS_ENABLE_LAUNCHD, test x$have_launchd = xyes)
1042
1043 #### Directory to place launchd agent file
1044 if test "x$with_launchd_agent_dir" = "x"; then
1045    LAUNCHD_AGENT_DIR="/Library/LaunchAgents"
1046 else
1047    LAUNCHD_AGENT_DIR="$with_launchd_agent_dir"
1048 fi
1049
1050 AC_SUBST(LAUNCHD_AGENT_DIR)
1051
1052 dnl console owner file
1053 if test x$enable_console_owner_file = xno ; then
1054     have_console_owner_file=no;
1055 else
1056     case $host_os in
1057     solaris*)
1058         have_console_owner_file=yes;
1059         AC_DEFINE(HAVE_CONSOLE_OWNER_FILE,1,[Have console owner file])
1060         ;;
1061     *)
1062         have_console_owner_file=no;;
1063     esac
1064 fi
1065
1066 AM_CONDITIONAL(HAVE_CONSOLE_OWNER_FILE, test x$have_console_owner_file = xyes)
1067
1068 # libaudit detection
1069 if test x$enable_libaudit = xno ; then
1070     have_libaudit=no;
1071 else
1072     # See if we have audit daemon & capabilities library
1073     AC_CHECK_LIB(audit, audit_log_user_avc_message,
1074                  have_libaudit=yes, have_libaudit=no)
1075     if test x$have_libaudit = xyes ; then
1076         AC_CHECK_LIB(cap-ng, capng_clear,
1077                  have_libaudit=yes, have_libaudit=no)
1078     fi
1079 fi
1080
1081 AM_CONDITIONAL(HAVE_LIBAUDIT, test x$have_libaudit = xyes)
1082
1083 if test x$have_libaudit = xyes ; then
1084     SELINUX_LIBS="$SELINUX_LIBS -laudit -lcap-ng"
1085     AC_DEFINE(HAVE_LIBAUDIT,1,[audit daemon SELinux support])
1086 fi
1087
1088 # Check for ADT API
1089 AC_MSG_CHECKING(for ADT API)
1090 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1091 #include <bsm/adt.h>
1092 adt_user_context = ADT_USER;
1093 ]], [[]])], [ check_adt_audit=yes ], [ check_adt_audit=no ])
1094
1095 if test ${check_adt_audit} = yes
1096 then
1097    AC_DEFINE([HAVE_ADT], [], [Adt audit API])
1098    ADT_LIBS="-lbsm"
1099    LIBS="-lbsm $LIBS"
1100    AC_MSG_RESULT(yes)
1101 else
1102    AC_MSG_RESULT(no)
1103 fi
1104
1105 # Check for SCM_RIGHTS
1106 AC_MSG_CHECKING([for SCM_RIGHTS])
1107 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1108 #include <sys/socket.h>
1109 #include <sys/un.h>
1110 static int x = SCM_RIGHTS;
1111 ]], [[]])],
1112 [ AC_MSG_RESULT([supported])
1113   AC_DEFINE([HAVE_UNIX_FD_PASSING], [1], [Supports sending UNIX file descriptors]) ],
1114 [ AC_MSG_RESULT([not supported]) ])
1115
1116 NETWORK_libs=
1117 if test x$dbus_win = xyes ; then
1118   if test x$dbus_wince = xyes ; then
1119     NETWORK_libs="-lws2"
1120   else
1121     NETWORK_libs="-lws2_32"
1122   fi
1123 fi
1124
1125 #### Set up final flags
1126 DBUS_CLIENT_CFLAGS=
1127 DBUS_CLIENT_LIBS="$THREAD_LIBS $NETWORK_libs"
1128 AC_SUBST(DBUS_CLIENT_CFLAGS)
1129 AC_SUBST(DBUS_CLIENT_LIBS)
1130
1131 DBUS_BUS_CFLAGS="$XML_CFLAGS"
1132 DBUS_BUS_LIBS="$XML_LIBS $SELINUX_LIBS $THREAD_LIBS $ADT_LIBS $NETWORK_libs"
1133 AC_SUBST(DBUS_BUS_CFLAGS)
1134 AC_SUBST(DBUS_BUS_LIBS)
1135
1136 DBUS_LAUNCHER_CFLAGS="$XML_CFLAGS"
1137 DBUS_LAUNCHER_LIBS="$XML_LIBS $THREAD_LIBS $NETWORK_libs"
1138 AC_SUBST(DBUS_LAUNCHER_CFLAGS)
1139 AC_SUBST(DBUS_LAUNCHER_LIBS)
1140
1141 DBUS_TEST_CFLAGS=
1142 DBUS_TEST_LIBS="$THREAD_LIBS $NETWORK_libs"
1143 AC_SUBST(DBUS_TEST_CFLAGS)
1144 AC_SUBST(DBUS_TEST_LIBS)
1145
1146 ### X11 detection
1147 DBUS_X_LIBS=
1148 DBUS_X_CFLAGS=
1149
1150 AC_ARG_ENABLE([x11-autolaunch],
1151   AS_HELP_STRING([--enable-x11-autolaunch], [build with X11 auto-launch support]),
1152   [], [enable_x11_autolaunch=auto])
1153
1154 if test "x$dbus_win" = xyes; then
1155     if test "x$enable_x11_autolaunch" = xyes; then
1156         AC_MSG_ERROR([X11 auto-launch is not supported on Windows])
1157     fi
1158
1159     enable_x11_autolaunch=no
1160     have_x11=no
1161 else
1162     AC_PATH_XTRA
1163
1164     if test "x$no_x" = xyes; then
1165         have_x11=no
1166     else
1167         have_x11=yes
1168         DBUS_X_LIBS="$X_LIBS $X_PRE_LIBS -lX11 $X_EXTRA_LIBS"
1169         DBUS_X_CFLAGS="$X_CFLAGS"
1170     fi
1171 fi
1172
1173 if test "x$enable_x11_autolaunch,$have_x11" = xyes,no; then
1174     AC_MSG_ERROR([X11 auto-launch requires X headers/libraries])
1175 else
1176     # move from "auto" to "yes" or "no" if necessary
1177     if test "x$enable_x11_autolaunch" != xno; then
1178         enable_x11_autolaunch="$have_x11"
1179     fi
1180 fi
1181
1182 if test "x$have_x11" = xyes ; then
1183    AC_DEFINE([DBUS_BUILD_X11], [1], [Define to build X11 functionality])
1184 fi
1185
1186 if test "x$enable_x11_autolaunch" = xyes ; then
1187    AC_DEFINE([DBUS_ENABLE_X11_AUTOLAUNCH], [1], [Define to enable X11 auto-launch])
1188 fi
1189
1190 AC_SUBST([DBUS_X_CFLAGS])
1191 AC_SUBST([DBUS_X_LIBS])
1192
1193 #### gcc warning flags
1194
1195 cc_supports_flag() {
1196   AC_MSG_CHECKING(whether $CC supports "$*")
1197   save_CFLAGS="$CFLAGS"
1198   CFLAGS="$*"
1199   AC_TRY_COMPILE([], [], [rc=yes], [rc=no])
1200   CFLAGS="$save_CFLAGS"
1201   AC_MSG_RESULT([$rc])
1202   test "x$rc" = xyes
1203 }
1204
1205 TP_COMPILER_WARNINGS([WARNING_CFLAGS],
1206   dnl Use -Werror by default if:
1207   dnl - we're not on Windows (too many warnings), and
1208   dnl - we're in maintainer mode (a D-Bus developer, not a distro or end-user)
1209   dnl Override with --enable-Werror or --disable-Werror
1210   [test x$dbus_win != xyes -a x$dbus_cygwin != xyes -a x$USE_MAINTAINER_MODE = xyes],
1211
1212   dnl enable these warnings if possible:
1213   [all \
1214    char-subscripts \
1215    missing-declarations \
1216    missing-prototypes \
1217    nested-externs \
1218    pointer-arith \
1219    cast-align \
1220    no-address \
1221    float-equal \
1222    declaration-after-statement \
1223   ],
1224
1225   dnl disable these warnings if possible, make them non-fatal if possible,
1226   dnl and don't enable -Werror unless we succeeded:
1227   dnl (unused is by design, sign-compare and pointer-sign are fd.o #17433)
1228   [unused \
1229    sign-compare \
1230    pointer-sign \
1231   ])
1232
1233 if test "x$GCC" = "xyes"; then
1234   # We're treating -fno-common like a warning: it makes the linker more
1235   # strict, because on some systems the linker is *always* this strict
1236   TP_ADD_COMPILER_FLAG([WARNING_CFLAGS], [-fno-common])
1237
1238   # http://bugs.freedesktop.org/show_bug.cgi?id=10599
1239   TP_ADD_COMPILER_FLAG([WARNING_CFLAGS], [-fno-strict-aliasing])
1240
1241   if test "x$enable_ansi" = "xyes"; then
1242     TP_ADD_COMPILER_FLAG([WARNING_CFLAGS],
1243       [-ansi -D_POSIX_C_SOURCE=199309L -D_BSD_SOURCE -pedantic])
1244   fi
1245 fi
1246
1247 dnl In principle we should put WARNING_CFLAGS in each Makefile.am like
1248 dnl telepathy-glib does, since CFLAGS is meant to be reserved for the user...
1249 dnl but prepending to CFLAGS (so the user can override it with later CFLAGS)
1250 dnl is the next best thing
1251 CFLAGS="$WARNING_CFLAGS $CFLAGS"
1252
1253 case $host_os in
1254     solaris*)
1255         # Solaris' C library apparently needs these runes to be threadsafe...
1256         CFLAGS="$CFLAGS -D_POSIX_PTHREAD_SEMANTICS -D_REENTRANT"
1257         # ... and this opt-in to get file descriptor passing support
1258         CFLAGS="$CFLAGS -D_XOPEN_SOURCE=500"
1259         ;;
1260 esac
1261
1262 ### Doxygen Documentation
1263
1264 AC_PATH_PROG(DOXYGEN, doxygen, no)
1265
1266 AC_MSG_CHECKING([whether to build Doxygen documentation])
1267
1268 if test x$DOXYGEN = xno ; then
1269     have_doxygen=no
1270 else
1271     have_doxygen=yes
1272 fi
1273
1274 if test x$enable_doxygen_docs = xauto ; then
1275     if test x$have_doxygen = xno ; then
1276         enable_doxygen_docs=no
1277     else
1278         enable_doxygen_docs=yes
1279     fi
1280 fi
1281
1282 if test x$enable_doxygen_docs = xyes; then
1283     if test x$have_doxygen = xno; then
1284         AC_MSG_ERROR([Building Doxygen docs explicitly required, but Doxygen not found])
1285     fi
1286 fi
1287
1288 AM_CONDITIONAL(DBUS_DOXYGEN_DOCS_ENABLED, test x$enable_doxygen_docs = xyes)
1289 AC_MSG_RESULT($enable_doxygen_docs)
1290
1291 AC_CHECK_PROGS([XSLTPROC], [xsltproc])
1292 AM_CONDITIONAL([DBUS_HAVE_XSLTPROC], [test "x$XSLTPROC" != "x"])
1293
1294 ### XML Documentation
1295
1296 AC_PATH_PROG(XMLTO, xmlto, no)
1297
1298 AC_MSG_CHECKING([whether to build XML documentation])
1299
1300 if test x$XMLTO = xno ; then
1301     have_xmlto=no
1302 else
1303     have_xmlto=yes
1304 fi
1305
1306 if test x$enable_xml_docs = xauto ; then
1307     if test x$have_xmlto = xno ; then
1308         enable_xml_docs=no
1309     else
1310         enable_xml_docs=yes
1311     fi
1312 fi
1313
1314 if test x$enable_xml_docs = xyes; then
1315     if test x$have_xmlto = xno; then
1316         AC_MSG_ERROR([Building XML docs explicitly required, but xmlto not found])
1317     fi
1318 fi
1319
1320 AM_CONDITIONAL(DBUS_XML_DOCS_ENABLED, test x$enable_xml_docs = xyes)
1321 AC_MSG_RESULT($enable_xml_docs)
1322
1323 AC_PATH_PROG([MAN2HTML], [man2html])
1324 AC_ARG_VAR([MAN2HTML], [Path to man2html (optional)])
1325 AM_CONDITIONAL(DBUS_HAVE_MAN2HTML, test x$MAN2HTML != x)
1326
1327 AM_CONDITIONAL(DBUS_CAN_UPLOAD_DOCS,
1328     test x$enable_doxygen_docs = xyes -a x$enable_xml_docs = xyes -a \
1329          x$MAN2HTML != x)
1330
1331 #### Have to go $localstatedir->$prefix/var->/usr/local/var
1332
1333 #### find the actual value for $prefix that we'll end up with
1334 ##   (I know this is broken and should be done in the Makefile, but
1335 ##    that's a major pain and almost nobody actually seems to care)
1336 AS_AC_EXPAND(EXPANDED_PREFIX, "$prefix")
1337 AS_AC_EXPAND(EXPANDED_LOCALSTATEDIR, "$localstatedir")
1338 AS_AC_EXPAND(EXPANDED_SYSCONFDIR, "$sysconfdir")
1339 AS_AC_EXPAND(EXPANDED_BINDIR, "$bindir")
1340 AS_AC_EXPAND(EXPANDED_LIBDIR, "$libdir")
1341 AS_AC_EXPAND(EXPANDED_LIBEXECDIR, "$libexecdir")
1342 AS_AC_EXPAND(EXPANDED_DATADIR, "$datadir")
1343
1344 #### Check our operating system
1345 operating_system=unknown
1346 if test -f /etc/redhat-release || test -f $EXPANDED_SYSCONFDIR/redhat-release ; then
1347    operating_system=redhat
1348 fi
1349
1350 if test -f /etc/slackware-version || test -f $EXPANDED_SYSCONFDIR/slackware-version ; then
1351    operating_system=slackware
1352 fi
1353
1354 if test -f /usr/bin/cygwin1.dll || test -f $EXPANDED_BINDIR/cygwin1.dll ; then
1355    operating_system=cygwin
1356 fi
1357
1358 #### Sort out init scripts
1359
1360 if test x$with_init_scripts = x; then
1361     case x$operating_system in
1362         xredhat)        with_init_scripts=redhat ;;
1363         xslackware)     with_init_scripts=slackware ;;
1364         xcygwin)        with_init_scripts=cygwin ;;
1365         *)                      with_init_scripts=none ;;
1366     esac
1367 fi
1368
1369 AM_CONDITIONAL(DBUS_INIT_SCRIPTS_RED_HAT, test x$with_init_scripts = xredhat)
1370 AM_CONDITIONAL(DBUS_INIT_SCRIPTS_SLACKWARE, test x$with_init_scripts = xslackware)
1371 AM_CONDITIONAL(DBUS_INIT_SCRIPTS_CYGWIN, test x$with_init_scripts = xcygwin)
1372
1373 ##### systemd unit files
1374 AC_ARG_WITH([systemdsystemunitdir],
1375 AS_HELP_STRING([--with-systemdsystemunitdir=DIR], [Directory for systemd service files]),
1376     [],
1377     [
1378     PKG_CHECK_EXISTS([systemd],
1379       [with_systemdsystemunitdir=$($PKG_CONFIG --variable=systemdsystemunitdir systemd)],
1380       [with_systemdsystemunitdir=no])
1381     ])
1382 if test "x$with_systemdsystemunitdir" != xno; then
1383    AC_SUBST([systemdsystemunitdir], [$with_systemdsystemunitdir])
1384 fi
1385 AM_CONDITIONAL(HAVE_SYSTEMD, [test -n "$with_systemdsystemunitdir" -a "x$with_systemdsystemunitdir" != xno ])
1386
1387 ##### Set up location for system bus socket
1388 if ! test -z "$with_system_socket"; then
1389    DBUS_SYSTEM_SOCKET=$with_system_socket
1390 else
1391    DBUS_SYSTEM_SOCKET=${EXPANDED_LOCALSTATEDIR}/run/dbus/system_bus_socket
1392 fi
1393
1394 AC_SUBST(DBUS_SYSTEM_SOCKET)
1395 AC_DEFINE_UNQUOTED(DBUS_SYSTEM_SOCKET,"$DBUS_SYSTEM_SOCKET",[The name of the socket the system bus listens on by default])
1396
1397 ## system bus only listens on local domain sockets, and never
1398 ## on an abstract socket (so only root can create the socket)
1399 DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="unix:path=$DBUS_SYSTEM_SOCKET"
1400 AC_SUBST(DBUS_SYSTEM_BUS_DEFAULT_ADDRESS)
1401 AC_DEFINE_UNQUOTED(DBUS_SYSTEM_BUS_DEFAULT_ADDRESS, "$DBUS_SYSTEM_BUS_DEFAULT_ADDRESS",[The default D-Bus address of the system bus])
1402
1403 #### Set up the pid file
1404 if ! test -z "$with_system_pid_file"; then
1405    DBUS_SYSTEM_PID_FILE=$with_system_pid_file
1406 elif test x$with_init_scripts = xredhat ; then
1407    DBUS_SYSTEM_PID_FILE=${EXPANDED_LOCALSTATEDIR}/run/messagebus.pid
1408 else
1409    DBUS_SYSTEM_PID_FILE=${EXPANDED_LOCALSTATEDIR}/run/dbus/pid
1410 fi
1411
1412 AC_SUBST(DBUS_SYSTEM_PID_FILE)
1413
1414 #### Directory to check for console ownership
1415 if ! test -z "$with_console_auth_dir"; then
1416    DBUS_CONSOLE_AUTH_DIR=$with_console_auth_dir
1417 else
1418    DBUS_CONSOLE_AUTH_DIR=/var/run/console/
1419 fi
1420
1421 AC_SUBST(DBUS_CONSOLE_AUTH_DIR)
1422 AC_DEFINE_UNQUOTED(DBUS_CONSOLE_AUTH_DIR, "$DBUS_CONSOLE_AUTH_DIR", [Directory to check for console ownerhip])
1423
1424 #### File to check for console ownership
1425 if test x$have_console_owner_file = xyes; then
1426    if ! test -z "$with_console_owner_file"; then
1427       DBUS_CONSOLE_OWNER_FILE=$with_console_owner_file
1428    else
1429       DBUS_CONSOLE_OWNER_FILE=/dev/console
1430    fi
1431 else
1432   DBUS_CONSOLE_OWNER_FILE=
1433 fi
1434
1435 AC_SUBST(DBUS_CONSOLE_OWNER_FILE)
1436 AC_DEFINE_UNQUOTED(DBUS_CONSOLE_OWNER_FILE, "$DBUS_CONSOLE_OWNER_FILE", [File to check for console ownerhip])
1437
1438 #### User to start the system bus as
1439 if test -z "$with_dbus_user" ; then
1440     DBUS_USER=messagebus
1441 else
1442     DBUS_USER=$with_dbus_user
1443 fi
1444 AC_SUBST(DBUS_USER)
1445 AC_DEFINE_UNQUOTED(DBUS_USER,"$DBUS_USER", [User for running the system BUS daemon])
1446
1447 #### Prefix to install into
1448 DBUS_PREFIX=$EXPANDED_PREFIX
1449 AC_SUBST(DBUS_PREFIX)
1450 AC_DEFINE_UNQUOTED(DBUS_PREFIX,"$DBUS_PREFIX", [Prefix for installing DBUS])
1451
1452 #### Direcotry to install data files into
1453 DBUS_DATADIR=$EXPANDED_DATADIR
1454 AC_SUBST(DBUS_DATADIR)
1455 AC_DEFINE_UNQUOTED(DBUS_DATADIR,"$DBUS_DATADIR", [Directory for installing DBUS data files])
1456
1457 #### Directory to install dbus-daemon
1458 if test -z "$with_dbus_daemondir" ; then
1459     DBUS_DAEMONDIR=$EXPANDED_BINDIR
1460 else
1461     DBUS_DAEMONDIR=$with_dbus_daemondir
1462 fi
1463 AC_SUBST(DBUS_DAEMONDIR)
1464 AC_DEFINE_UNQUOTED(DBUS_DAEMONDIR,"$DBUS_DAEMONDIR", [Directory for installing the DBUS daemon])
1465
1466 #### Directory to install the other binaries
1467 DBUS_BINDIR="$EXPANDED_BINDIR"
1468 AC_SUBST(DBUS_BINDIR)
1469 AC_DEFINE_UNQUOTED(DBUS_BINDIR,"$DBUS_BINDIR", [Directory for installing the binaries])
1470
1471 #### Directory to install the libexec binaries
1472 DBUS_LIBEXECDIR="$EXPANDED_LIBEXECDIR"
1473 AC_SUBST(DBUS_LIBEXECDIR)
1474 AC_DEFINE_UNQUOTED(DBUS_LIBEXECDIR,"$DBUS_LIBEXECDIR", [Directory for installing the libexec binaries])
1475
1476 #### Tell tests where to find certain stuff in builddir
1477
1478 DBUS_PWD=`pwd`
1479 # Useful in a cross-compilation environment, where the tests are run on the host system.
1480 AC_ARG_WITH(dbus-test-dir, AS_HELP_STRING([--with-dbus-test-dir=[dirname]],[path where the tests tools are available]),
1481                            DBUS_PWD=$withval)
1482 AC_DEFUN([TEST_PATH], [
1483 TEST_$1=${DBUS_PWD}/test/$2
1484 AC_DEFINE_UNQUOTED(TEST_$1, "$TEST_$1",
1485                    [Full path to test file test/$2 in builddir])
1486 AC_SUBST(TEST_$1)
1487 ])
1488 AC_DEFUN([TEST_PROG], [
1489 TEST_$1=${DBUS_PWD}/test/$2
1490 AC_DEFINE_UNQUOTED(TEST_$1, "$TEST_$1$EXEEXT",
1491                    [Full path to test file test/$2 in builddir])
1492 AC_SUBST(TEST_$1)
1493 ])
1494
1495 TEST_PATH(VALID_SERVICE_DIR, data/valid-service-files)
1496 TEST_PATH(INVALID_SERVICE_DIR, data/invalid-service-files)
1497 TEST_PATH(VALID_SERVICE_SYSTEM_DIR, data/valid-service-files-system)
1498 TEST_PATH(INVALID_SERVICE_SYSTEM_DIR, data/invalid-service-files-system)
1499 TEST_PROG(SERVICE_BINARY, test-service)
1500 TEST_PROG(SHELL_SERVICE_BINARY, test-shell-service)
1501 TEST_PROG(EXIT_BINARY, test-exit)
1502 TEST_PROG(SEGFAULT_BINARY, test-segfault)
1503 TEST_PROG(SLEEP_FOREVER_BINARY, test-sleep-forever)
1504 TEST_PROG(PRIVSERVER_BINARY, name-test/test-privserver)
1505
1506 AC_DEFINE_UNQUOTED(TEST_BUS_BINARY, "$DBUS_PWD/bus/dbus-daemon$EXEEXT",
1507                    [Full path to the daemon in the builddir])
1508 AC_SUBST(TEST_BUS_BINARY)
1509
1510 ## Export the non-setuid external helper
1511 TEST_LAUNCH_HELPER_BINARY="$DBUS_PWD/bus/dbus-daemon-launch-helper-test$EXEEXT"
1512 AC_SUBST(TEST_LAUNCH_HELPER_BINARY)
1513 AC_DEFINE_UNQUOTED(DBUS_TEST_LAUNCH_HELPER_BINARY, "$TEST_LAUNCH_HELPER_BINARY",
1514                    [Full path to the launch helper test program in the builddir])
1515
1516 #### Find socket directories
1517 if ! test -z "$TMPDIR" ; then
1518    DEFAULT_SOCKET_DIR=$TMPDIR
1519 elif ! test -z "$TEMP" ; then
1520    DEFAULT_SOCKET_DIR=$TEMP
1521 elif ! test -z "$TMP" ; then
1522    DEFAULT_SOCKET_DIR=$TMP
1523 else
1524    DEFAULT_SOCKET_DIR=/tmp
1525 fi
1526
1527 DEFAULT_SOCKET_DIR=`echo $DEFAULT_SOCKET_DIR | sed 's/+/%2B/g'`
1528
1529 if ! test -z "$with_test_socket_dir" ; then
1530    TEST_SOCKET_DIR="$with_test_socket_dir"
1531 else
1532    TEST_SOCKET_DIR=$DEFAULT_SOCKET_DIR
1533 fi
1534 AC_SUBST(TEST_SOCKET_DIR)
1535 AC_DEFINE_UNQUOTED(DBUS_TEST_SOCKET_DIR, "$TEST_SOCKET_DIR", [Where to put test sockets])
1536
1537 if ! test -z "$with_session_socket_dir" ; then
1538    DBUS_SESSION_SOCKET_DIR="$with_session_socket_dir"
1539 else
1540    DBUS_SESSION_SOCKET_DIR=$DEFAULT_SOCKET_DIR
1541 fi
1542 AC_DEFINE_UNQUOTED(DBUS_SESSION_SOCKET_DIR, "$DBUS_SESSION_SOCKET_DIR", [Where per-session bus puts its sockets])
1543 AC_SUBST(DBUS_SESSION_SOCKET_DIR)
1544
1545 if test x$dbus_win = xyes; then
1546         DBUS_SESSION_BUS_DEFAULT_ADDRESS="nonce-tcp:"
1547 elif test x$have_launchd = xyes; then
1548         DBUS_SESSION_BUS_DEFAULT_ADDRESS="launchd:env=DBUS_LAUNCHD_SESSION_BUS_SOCKET"
1549 else
1550         DBUS_SESSION_BUS_DEFAULT_ADDRESS="unix:tmpdir=$DBUS_SESSION_SOCKET_DIR"
1551 fi
1552 AC_SUBST(DBUS_SESSION_BUS_DEFAULT_ADDRESS)
1553
1554 # darwin needs this to initialize the environment
1555 AC_CHECK_HEADERS(crt_externs.h)
1556 AC_CHECK_FUNC(_NSGetEnviron, [AC_DEFINE(HAVE_NSGETENVIRON, 1, [Define if your system needs _NSGetEnviron to set up the environment])])
1557 AH_VERBATIM(_DARWIN_ENVIRON,
1558 [
1559 #if defined(HAVE_NSGETENVIRON) && defined(HAVE_CRT_EXTERNS_H)
1560 # include <sys/time.h>
1561 # include <crt_externs.h>
1562 # define environ (*_NSGetEnviron())
1563 #endif
1564 ])
1565
1566 AC_CONFIG_FILES([
1567 Doxyfile
1568 dbus/versioninfo.rc
1569 dbus/dbus-arch-deps.h
1570 bus/system.conf
1571 bus/session.conf
1572 bus/messagebus
1573 bus/messagebus-config
1574 bus/org.freedesktop.dbus-session.plist
1575 bus/rc.messagebus
1576 bus/dbus.service
1577 bus/dbus.socket
1578 Makefile
1579 dbus/Makefile
1580 bus/Makefile
1581 tools/Makefile
1582 test/Makefile
1583 test/name-test/Makefile
1584 doc/Makefile
1585 doc/dbus-daemon.1
1586 dbus-1.pc
1587 dbus-1-uninstalled.pc
1588 test/data/valid-config-files/debug-allow-all.conf
1589 test/data/valid-config-files/debug-allow-all-sha1.conf
1590 test/data/valid-config-files-system/debug-allow-all-pass.conf
1591 test/data/valid-config-files-system/debug-allow-all-fail.conf
1592 test/data/valid-service-files/org.freedesktop.DBus.TestSuite.PrivServer.service
1593 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteEchoService.service
1594 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteForkingEchoService.service
1595 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteSegfaultService.service
1596 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteShellEchoServiceSuccess.service
1597 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteShellEchoServiceFail.service
1598 test/data/valid-service-files-system/org.freedesktop.DBus.TestSuiteEchoService.service
1599 test/data/valid-service-files-system/org.freedesktop.DBus.TestSuiteSegfaultService.service
1600 test/data/valid-service-files-system/org.freedesktop.DBus.TestSuiteShellEchoServiceSuccess.service
1601 test/data/valid-service-files-system/org.freedesktop.DBus.TestSuiteShellEchoServiceFail.service
1602 test/data/invalid-service-files-system/org.freedesktop.DBus.TestSuiteNoExec.service
1603 test/data/invalid-service-files-system/org.freedesktop.DBus.TestSuiteNoUser.service
1604 test/data/invalid-service-files-system/org.freedesktop.DBus.TestSuiteNoService.service
1605 ])
1606 AC_OUTPUT
1607
1608 dnl ==========================================================================
1609 echo "
1610                     D-Bus $VERSION
1611                   ==============
1612
1613         prefix:                   ${EXPANDED_PREFIX}
1614         exec_prefix:              ${exec_prefix}
1615         libdir:                   ${EXPANDED_LIBDIR}
1616         libexecdir:               ${EXPANDED_LIBEXECDIR}
1617         bindir:                   ${EXPANDED_BINDIR}
1618         sysconfdir:               ${EXPANDED_SYSCONFDIR}
1619         localstatedir:            ${EXPANDED_LOCALSTATEDIR}
1620         datadir:                  ${EXPANDED_DATADIR}
1621         source code location:     ${srcdir}
1622         compiler:                 ${CC}
1623         cflags:                   ${CFLAGS}
1624         cppflags:                 ${CPPFLAGS}
1625         cxxflags:                 ${CXXFLAGS}
1626         64-bit int:               ${DBUS_INT64_TYPE}
1627         32-bit int:               ${DBUS_INT32_TYPE}
1628         16-bit int:               ${DBUS_INT16_TYPE}
1629         Doxygen:                  ${DOXYGEN:-not found}
1630         xmlto:                    ${XMLTO:-not found}
1631         man2html:                 ${MAN2HTML:-not found}"
1632
1633 echo "
1634         Maintainer mode:          ${USE_MAINTAINER_MODE}
1635         gcc coverage profiling:   ${enable_compiler_coverage}
1636         Building embedded tests:  ${enable_embedded_tests}
1637         Building modular tests:   ${enable_modular_tests}
1638         Building verbose mode:    ${enable_verbose_mode}
1639         Building assertions:      ${enable_asserts}
1640         Building checks:          ${enable_checks}
1641         Building SELinux support: ${have_selinux}
1642         Building inotify support: ${have_inotify}
1643         Building dnotify support: ${have_dnotify}
1644         Building kqueue support:  ${have_kqueue}
1645         Building X11 code:        ${enable_x11}
1646         Building Doxygen docs:    ${enable_doxygen_docs}
1647         Building XML docs:        ${enable_xml_docs}
1648         Building cache support:   ${enable_userdb_cache}
1649         Building launchd support: ${have_launchd}
1650         Using XML parser:         ${with_xml}
1651         Init scripts style:       ${with_init_scripts}
1652         Abstract socket names:    ${ac_cv_have_abstract_sockets}
1653         System bus socket:        ${DBUS_SYSTEM_SOCKET}
1654         System bus address:       ${DBUS_SYSTEM_BUS_DEFAULT_ADDRESS}
1655         System bus PID file:      ${DBUS_SYSTEM_PID_FILE}
1656         Session bus address:      ${DBUS_SESSION_BUS_DEFAULT_ADDRESS}
1657         Console auth dir:         ${DBUS_CONSOLE_AUTH_DIR}
1658         Console owner file:       ${have_console_owner_file}
1659         Console owner file path:  ${DBUS_CONSOLE_OWNER_FILE}
1660         System bus user:          ${DBUS_USER}
1661         Session bus services dir: ${EXPANDED_DATADIR}/dbus-1/services
1662         'make check' socket dir:  ${TEST_SOCKET_DIR}
1663 "
1664 if test x$have_launchd = xyes; then
1665         echo "        launchd agent dir:        ${LAUNCHD_AGENT_DIR}"
1666 fi
1667 echo
1668
1669 if test x$enable_embedded_tests = xyes; then
1670         echo "NOTE: building with unit tests increases the size of the installed library and renders it insecure."
1671 fi
1672 if test x$enable_embedded_tests = xyes -a x$enable_asserts = xno; then
1673         echo "NOTE: building with embedded tests but without assertions means tests may not properly report failures (this configuration is only useful when doing something like profiling the tests)"
1674 fi
1675 if test x$enable_compiler_coverage = xyes; then
1676         echo "NOTE: building with coverage profiling is definitely for developers only."
1677 fi
1678 if test x$enable_verbose_mode = xyes; then
1679         echo "NOTE: building with verbose mode increases library size, may slightly increase security risk, and decreases performance."
1680 fi
1681 if test x$enable_asserts = xyes; then
1682         echo "NOTE: building with assertions increases library size and decreases performance."
1683 fi
1684 if test x$enable_checks = xno; then
1685         echo "NOTE: building without checks for arguments passed to public API makes it harder to debug apps using D-Bus, but will slightly decrease D-Bus library size and _very_ slightly improve performance."
1686 fi
1687 if test x$dbus_use_libxml = xtrue; then
1688         echo
1689         echo "WARNING: You have chosen to use libxml as your xml parser however this code path is not maintained by the D-Bus developers and if it breaks you get to keep the pieces.  If you have selected this option in err please reconfigure with expat (e.g. --with-xml=expat)."
1690 fi