configure.ac

   1 AC_PREREQ(2.65)
   2 AC_CONFIG_MACRO_DIR([m4])
   3
   4 AC_INIT([gsecret],[0.1],[http://bugzilla.gnome.org/enter_bug.cgi?product=gsecret])
   5
   6 AC_CONFIG_SRCDIR([library/gsecret-data.c])
   7 AC_CONFIG_HEADERS([config.h])
   8
   9 dnl Other initialization
  10 AM_INIT_AUTOMAKE
  11 AM_MAINTAINER_MODE([enable])
  12 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],)
  13 LT_INIT
  14
  15 dnl Checks for programs.
  16 AC_PROG_CC
  17 AC_PROG_CPP
  18 AM_PROG_CC_C_O
  19
  20 dnl Checks for libraries.
  21
  22 dnl ****************************
  23 dnl *** Checks for intltool
  24
  25 IT_PROG_INTLTOOL([0.35.0])
  26 GETTEXT_PACKAGE=gsecret
  27
  28 AC_SUBST([GETTEXT_PACKAGE])
  29 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["$GETTEXT_PACKAGE"],[The gettext domain name])
  30 AM_GLIB_GNU_GETTEXT
  31
  32 dnl *****************************
  33 dnl *** Check GLib
  34
  35 PKG_CHECK_MODULES(GLIB, glib-2.0 >= 2.16.0 gio-2.0 >= 2.16.0 gthread-2.0 >= 2.16.0)
  36 LIBS="$LIBS $GLIB_LIBS"
  37 CFLAGS="$CFLAGS $GLIB_CFLAGS"
  38
  39 AC_CHECK_FUNCS(mlock)
  40
  41 dnl *************************************
  42 dnl *** Warnings to show if using GCC ***
  43 dnl *************************************
  44
  45 AC_ARG_ENABLE(more-warnings,
  46               AS_HELP_STRING([--disable-more-warnings], [Inhibit compiler warnings]),
  47               set_more_warnings=no)
  48
  49 if test "$GCC" = "yes" -a "$set_more_warnings" != "no"; then
  50         CFLAGS="$CFLAGS \
  51                 -Wall -Wstrict-prototypes -Wmissing-declarations \
  52                 -Wmissing-prototypes -Wnested-externs -Wpointer-arith \
  53                 -Wdeclaration-after-statement -Wformat=2 -Winit-self \
  54                 -Waggregate-return -Wmissing-format-attribute"
  55
  56         for option in -Wmissing-include-dirs -Wundef; do
  57                 SAVE_CFLAGS="$CFLAGS"
  58                 CFLAGS="$CFLAGS $option"
  59                 AC_MSG_CHECKING([whether gcc understands $option])
  60                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [])],
  61                                   [has_option=yes],
  62                                   [has_option=no])
  63                 AC_MSG_RESULT($has_option)
  64                 if test $has_option = no; then
  65                         CFLAGS="$SAVE_CFLAGS"
  66                 fi
  67         done
  68 fi
  69
  70 dnl *****************************
  71 dnl *** done                  ***
  72 dnl *****************************
  73 AC_CONFIG_FILES([Makefile
  74                  egg/Makefile
  75                  po/Makefile.in
  76                  po/Makefile
  77                  library/Makefile
  78                 ])
  79 AC_OUTPUT