configure.ac

   1 AC_PREREQ([2.69])
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/pre
   8 AC_INIT([GStreamer Good Plug-ins],[1.7.0.1],[http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer],[gst-plugins-good])
   9
  10 AG_GST_INIT
  11
  12 dnl initialize automake
  13 AM_INIT_AUTOMAKE([-Wno-portability 1.14 no-dist-gzip dist-xz tar-ustar subdir-objects])
  14
  15 dnl define PACKAGE_VERSION_* variables
  16 AS_VERSION
  17
  18 dnl check if this is a release version
  19 AS_NANO(GST_GIT="no", GST_GIT="yes")
  20
  21 dnl can autoconf find the source ?
  22 AC_CONFIG_SRCDIR([gst/law/alaw.c])
  23
  24 dnl define the output header for config
  25 AC_CONFIG_HEADERS([config.h])
  26
  27 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  28 AM_MAINTAINER_MODE([enable])
  29
  30 dnl sets host_* variables
  31 AC_CANONICAL_HOST
  32
  33 dnl use pretty build output with automake >= 1.11
  34 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  35   [AM_DEFAULT_VERBOSITY=1
  36    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  37
  38 dnl our libraries and install dirs use GST_API_VERSION in the filename
  39 dnl to allow side-by-side installation of different API versions
  40 GST_API_VERSION=1.0
  41 AC_SUBST(GST_API_VERSION)
  42 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION",
  43   [GStreamer API Version])
  44
  45 AG_GST_LIBTOOL_PREPARE
  46 AS_LIBTOOL(GST, 700, 0, 700)
  47
  48 dnl *** required versions of GStreamer stuff ***
  49 GST_REQ=1.7.0.1
  50 GSTPB_REQ=1.7.0.1
  51
  52 dnl *** autotools stuff ****
  53
  54 dnl allow for different autotools
  55 AS_AUTOTOOLS_ALTERNATE
  56
  57 dnl Add parameters for aclocal
  58 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  59
  60 dnl set up gettext
  61 dnl the version check needs to stay here because autopoint greps for it
  62 AM_GNU_GETTEXT_VERSION([0.17])
  63 AM_GNU_GETTEXT([external])
  64 AG_GST_GETTEXT([gst-plugins-good-$GST_API_VERSION])
  65
  66 dnl *** check for arguments to configure ***
  67
  68 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  69 AG_GST_ARG_ENABLE_EXTRA_CHECKS
  70
  71 AG_GST_ARG_DEBUG
  72 AG_GST_ARG_PROFILING
  73 AG_GST_ARG_VALGRIND
  74 AG_GST_ARG_GCOV
  75
  76 AG_GST_ARG_EXAMPLES
  77
  78 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  79 AG_GST_ARG_WITH_PACKAGE_NAME
  80 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  81
  82 AG_GST_ARG_WITH_PLUGINS
  83
  84 AG_GST_ARG_ENABLE_EXTERNAL
  85
  86 AG_GST_ARG_ENABLE_EXPERIMENTAL
  87
  88 dnl *** checks for platform ***
  89
  90 dnl * hardware/architecture *
  91
  92 dnl common/m4/gst-arch.m4
  93 dnl check CPU type
  94 AG_GST_ARCH
  95
  96 dnl Determine endianness
  97 AC_C_BIGENDIAN
  98
  99 dnl *** checks for programs ***
 100
 101 dnl find a compiler
 102 AC_PROG_CC
 103 AC_PROG_CC_STDC
 104
 105 dnl determine c++ compiler
 106 AC_PROG_CXX
 107 dnl determine if c++ is available on this system
 108 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 109
 110 dnl determine c++ preprocessor
 111 dnl FIXME: do we need this ?
 112 AC_PROG_CXXCPP
 113
 114 AC_PROG_OBJC
 115
 116 dnl check if the compiler supports '-c' and '-o' options
 117 AM_PROG_CC_C_O
 118
 119 dnl find an assembler
 120 AM_PROG_AS
 121
 122 dnl check if the compiler supports do while(0) macros
 123 AG_GST_CHECK_DOWHILE_MACROS
 124
 125 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 126 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 127
 128 dnl check for documentation tools
 129 GTK_DOC_CHECK([1.12])
 130 AG_GST_PLUGIN_DOCS([1.12])
 131
 132 dnl *** checks for libraries ***
 133
 134 dnl check for libm, for sin()
 135 LT_LIB_M
 136 AC_SUBST(LIBM)
 137
 138 AC_CHECK_FUNCS(clock_gettime, [], [
 139   AC_CHECK_LIB(rt, clock_gettime, [
 140     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
 141     LIBRT="-lrt"
 142     AC_SUBST([LIBRT])
 143   ])
 144 ])
 145
 146 dnl *** checks for header files ***
 147
 148 dnl check if we have ANSI C header files
 149 AC_HEADER_STDC
 150
 151 dnl used by ext/wavpack
 152 AX_CREATE_STDINT_H
 153
 154 dnl used in gst/udp
 155 AC_CHECK_HEADERS([sys/time.h])
 156
 157 dnl used in gst/udp
 158 AC_CHECK_HEADERS([sys/socket.h])
 159
 160 dnl *** checks for types/defines ***
 161
 162 dnl Check for FIONREAD ioctl declaration.  This check is needed
 163 dnl for the UDP plugin to build on Solaris
 164 GST_CHECK_FIONREAD
 165
 166 dnl *** checks for structures ***
 167
 168 dnl *** checks for compiler characteristics ***
 169
 170 dnl check if we have GCC inline-asm
 171 AS_GCC_INLINE_ASSEMBLY([HAVE_GCC_ASM=yes], [HAVE_GCC_ASM=no])
 172 if test x$HAVE_GCC_ASM = xyes ; then
 173   AC_DEFINE(HAVE_GCC_ASM, 1,
 174     [Define if compiler supports gcc inline assembly])
 175 fi
 176 AM_CONDITIONAL(HAVE_GCC_ASM, test "x$HAVE_GCC_ASM" = "xyes")
 177
 178 dnl *** checks for library functions ***
 179
 180 LIBS_SAVE=$LIBS
 181 LIBS="$LIBS $LIBM"
 182 AC_CHECK_FUNCS(rint sinh cosh asinh fpclass)
 183 LIBS=$LIBS_SAVE
 184
 185 dnl Check whether isinf() is defined by math.h
 186 AC_CACHE_CHECK([for isinf], ac_cv_have_isinf,
 187     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; int i=isinf(f)]])],[ac_cv_have_isinf="yes"],[ac_cv_have_isinf="no"]))
 188 if test "$ac_cv_have_isinf" = "yes"
 189 then
 190     AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have the `isinf' function.])
 191 fi
 192
 193 dnl Check for mmap (needed by electricfence plugin)
 194 AC_FUNC_MMAP
 195 AM_CONDITIONAL(GST_HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 196
 197 dnl Check for mmap (needed by electricfence plugin)
 198
 199 AC_CHECK_TYPE([struct ip_mreqn], [
 200               AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
 201               [#include <netinet/in.h>])
 202
 203 dnl *** checks for dependency libraries ***
 204
 205
 206 dnl GLib
 207 GLIB_REQ=2.40.0
 208 AG_GST_GLIB_CHECK([$GLIB_REQ])
 209
 210 dnl Orc
 211 ORC_CHECK([0.4.17])
 212
 213 dnl checks for gstreamer
 214 dnl uninstalled is selected preferentially -- see pkg-config(1)
 215 AG_GST_CHECK_GST($GST_API_VERSION, [$GST_REQ], yes)
 216 AG_GST_CHECK_GST_BASE($GST_API_VERSION, [$GST_REQ], yes)
 217 AG_GST_CHECK_GST_CONTROLLER($GST_API_VERSION, [$GST_REQ], yes)
 218 AG_GST_CHECK_GST_NET($GST_API_VERSION, [$GST_REQ], yes)
 219 AG_GST_CHECK_GST_CHECK($GST_API_VERSION, [$GST_REQ], no)
 220 AG_GST_CHECK_GST_PLUGINS_BASE($GST_API_VERSION, [$GSTPB_REQ], yes)
 221
 222 GST_TOOLS_DIR=`$PKG_CONFIG --variable=toolsdir gstreamer-$GST_API_VERSION`
 223 if test -z $GST_TOOLS_DIR; then
 224   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 225 fi
 226 AC_SUBST(GST_TOOLS_DIR)
 227
 228 AC_MSG_NOTICE(Using GStreamer Core Plugins in $GST_PLUGINS_DIR)
 229 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 230
 231 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 232
 233 dnl Check for documentation xrefs
 234 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 235 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_API_VERSION`"
 236 GSTPB_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-plugins-base-$GST_API_VERSION`"
 237 AC_SUBST(GLIB_PREFIX)
 238 AC_SUBST(GST_PREFIX)
 239 AC_SUBST(GSTPB_PREFIX)
 240
 241 dnl GTK is optional and used in examples
 242 HAVE_GTK=no
 243 GTK_REQ=3.0.0
 244 if test "x$BUILD_EXAMPLES" = "xyes"; then
 245   PKG_CHECK_MODULES(GTK, gtk+-3.0 >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 246   dnl some examples need gtk+-x11
 247   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-3.0 >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 248   AC_SUBST(GTK_LIBS)
 249   AC_SUBST(GTK_CFLAGS)
 250 fi
 251 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 252 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 253
 254 dnl *** set variables based on configure arguments ***
 255
 256 dnl set license and copyright notice
 257 GST_LICENSE="LGPL"
 258 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 259 AC_SUBST(GST_LICENSE)
 260
 261 dnl set location of plugin directory
 262 AG_GST_SET_PLUGINDIR
 263
 264 dnl set release date/time
 265 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 266   ["${srcdir}/gst-plugins-good.doap"],
 267   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 268
 269 dnl build static plugins or not
 270 AC_MSG_CHECKING([whether to build static plugins or not])
 271 AC_ARG_ENABLE(
 272   static-plugins,
 273   AC_HELP_STRING(
 274     [--enable-static-plugins],
 275     [build static plugins @<:@default=no@:>@]),
 276   [AS_CASE(
 277     [$enableval], [no], [], [yes], [],
 278     [AC_MSG_ERROR([bad value "$enableval" for --enable-static-plugins])])],
 279   [enable_static_plugins=no])
 280 AC_MSG_RESULT([$enable_static_plugins])
 281 if test "x$enable_static_plugins" = xyes; then
 282   AC_DEFINE(GST_PLUGIN_BUILD_STATIC, 1,
 283     [Define if static plugins should be built])
 284   GST_PLUGIN_LIBTOOLFLAGS=""
 285 else
 286   GST_PLUGIN_LIBTOOLFLAGS="--tag=disable-static"
 287 fi
 288 AC_SUBST(GST_PLUGIN_LIBTOOLFLAGS)
 289 AM_CONDITIONAL(GST_PLUGIN_BUILD_STATIC, test "x$enable_static_plugins" = "xyes")
 290
 291 # set by AG_GST_PARSE_SUBSYSTEM_DISABLES above
 292 dnl make sure it doesn't complain about unused variables if debugging is disabled
 293 NO_WARNINGS=""
 294 AG_GST_CHECK_GST_DEBUG_DISABLED([NO_WARNINGS="-Wno-unused"], [NO_WARNINGS=""])
 295
 296 dnl define an ERROR_CFLAGS Makefile variable
 297 dnl -Wundef: too many broken headers
 298 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [
 299       -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 300       -Wwrite-strings -Wold-style-definition -Waggregate-return
 301       -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar
 302       -Wnested-externs $NO_WARNINGS])
 303
 304 dnl define an ERROR_CXXFLAGS Makefile variable
 305 AG_GST_SET_ERROR_CXXFLAGS($FATAL_WARNINGS, [
 306         -Wmissing-declarations -Wredundant-decls
 307         -Wwrite-strings
 308         -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar
 309         $NO_WARNINGS])
 310
 311 dnl define an ERROR_OBJCFLAGS Makefile variable
 312 AG_GST_SET_ERROR_OBJCFLAGS($FATAL_WARNINGS, [
 313       -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 314       -Wwrite-strings -Wold-style-definition
 315       -Winit-self -Wmissing-include-dirs -Wno-multichar
 316       -Wnested-externs $NO_WARNINGS])
 317
 318 dnl define correct level for debugging messages
 319 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 320
 321 dnl used in examples
 322 AG_GST_DEFAULT_ELEMENTS
 323
 324 dnl *** plug-ins to include ***
 325
 326 dnl these are all the gst plug-ins, compilable without additional libs
 327 dnl videofilter is at the top because others depend on it
 328 AG_GST_CHECK_PLUGIN(alpha)
 329 AG_GST_CHECK_PLUGIN(apetag)
 330 AG_GST_CHECK_PLUGIN(audiofx)
 331 AG_GST_CHECK_PLUGIN(audioparsers)
 332 AG_GST_CHECK_PLUGIN(auparse)
 333 AG_GST_CHECK_PLUGIN(autodetect)
 334 AG_GST_CHECK_PLUGIN(avi)
 335 AG_GST_CHECK_PLUGIN(cutter)
 336 AG_GST_CHECK_PLUGIN(debugutils)
 337 AG_GST_CHECK_PLUGIN(deinterlace)
 338 AG_GST_CHECK_PLUGIN(dtmf)
 339 AG_GST_CHECK_PLUGIN(effectv)
 340 AG_GST_CHECK_PLUGIN(equalizer)
 341 AG_GST_CHECK_PLUGIN(flv)
 342 AG_GST_CHECK_PLUGIN(flx)
 343 AG_GST_CHECK_PLUGIN(goom)
 344 AG_GST_CHECK_PLUGIN(goom2k1)
 345 AG_GST_CHECK_PLUGIN(icydemux)
 346 AG_GST_CHECK_PLUGIN(id3demux)
 347 AG_GST_CHECK_PLUGIN(imagefreeze)
 348 AG_GST_CHECK_PLUGIN(interleave)
 349 AG_GST_CHECK_PLUGIN(isomp4)
 350 AG_GST_CHECK_PLUGIN(law)
 351 AG_GST_CHECK_PLUGIN(level)
 352 AG_GST_CHECK_PLUGIN(matroska)
 353 AG_GST_CHECK_PLUGIN(monoscope)
 354 AG_GST_CHECK_PLUGIN(multifile)
 355 AG_GST_CHECK_PLUGIN(multipart)
 356 AG_GST_CHECK_PLUGIN(replaygain)
 357 AG_GST_CHECK_PLUGIN(rtp)
 358 AG_GST_CHECK_PLUGIN(rtpmanager)
 359 AG_GST_CHECK_PLUGIN(rtsp)
 360 AG_GST_CHECK_PLUGIN(shapewipe)
 361 AG_GST_CHECK_PLUGIN(smpte)
 362 AG_GST_CHECK_PLUGIN(spectrum)
 363 AG_GST_CHECK_PLUGIN(udp)
 364 AG_GST_CHECK_PLUGIN(videobox)
 365 AG_GST_CHECK_PLUGIN(videocrop)
 366 AG_GST_CHECK_PLUGIN(videofilter)
 367 AG_GST_CHECK_PLUGIN(videomixer)
 368 AG_GST_CHECK_PLUGIN(wavenc)
 369 AG_GST_CHECK_PLUGIN(wavparse)
 370 AG_GST_CHECK_PLUGIN(y4m)
 371
 372 dnl disable experimental plug-ins
 373 if test "x$BUILD_EXPERIMENTAL" != "xyes"; then
 374   AG_GST_DISABLE_PLUGIN(monoscope)
 375 fi
 376
 377 dnl *** sys plug-ins ***
 378
 379 echo
 380 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 381 echo
 382
 383 dnl DirectSound
 384 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECTSOUND, true)
 385 AG_GST_CHECK_FEATURE(DIRECTSOUND, [DirectSound plug-in], directsoundsink, [
 386   HAVE_DIRECTSOUND="no"
 387   save_CFLAGS="$CFLAGS"
 388   save_LDFLAGS="$LDFLAGS"
 389   save_LIBS="$LIBS"
 390   CFLAGS="$CFLAGS $DIRECTSOUND_CFLAGS"
 391   LDFLAGS="$LDFLAGS $DIRECTSOUND_LDFLAGS"
 392   LIBS="$LIBS -ldsound -ldxerr9 -luser32 -lole32"
 393   AC_MSG_CHECKING(for DirectSound LDFLAGS)
 394   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 395 #include <windows.h>
 396 #include <dxerr9.h>
 397 #include <dsound.h>
 398 ]], [[
 399   DXGetErrorString9 (0);
 400   DirectSoundCreate(NULL, NULL, NULL);
 401   CLSIDFromString(NULL, NULL);
 402 ]])
 403 ],
 404     [HAVE_DIRECTSOUND="yes"],
 405     [HAVE_DIRECTSOUND="no"])
 406   AC_MSG_RESULT($HAVE_DIRECTSOUND)
 407   CFLAGS=$save_CFLAGS
 408   LDFLAGS=$save_LDFLAGS
 409   LIBS=$save_LIBS
 410
 411   if test "x$HAVE_DIRECTSOUND" = "xyes";  then
 412     dnl this is much more than we want
 413     DIRECTSOUND_LIBS="-ldsound -ldxerr9 -luser32 -lole32"
 414     AC_SUBST(DIRECTSOUND_CFLAGS)
 415     AC_SUBST(DIRECTSOUND_LDFLAGS)
 416     AC_SUBST(DIRECTSOUND_LIBS)
 417   fi
 418   AC_SUBST(HAVE_DIRECTSOUND)
 419 ])
 420
 421 dnl *** Win32 WaveOut ***
 422 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVEFORM, true)
 423 AG_GST_CHECK_FEATURE(WAVEFORM, [Win32 WaveForm], waveformsink, [
 424   AC_CHECK_HEADER(mmsystem.h, HAVE_WAVEFORM="yes", HAVE_WAVEFORM="no", [#include <windows.h>])
 425 ])
 426
 427 dnl *** OSS audio *** (Linux, *BSD)
 428 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS, true)
 429 AG_GST_CHECK_FEATURE(OSS, [OSS audio], ossaudio, [
 430  HAVE_OSS="yes"
 431 dnl Linux and newer BSD versions :
 432  AC_CHECK_HEADER(sys/soundcard.h, [
 433    AC_DEFINE(HAVE_OSS_INCLUDE_IN_SYS,, [Define if OSS includes are in /sys/])
 434    ] , [
 435 dnl Some old BSD versions and also newer OpenBSD versions :
 436    AC_CHECK_HEADER(soundcard.h, [
 437      AC_DEFINE(HAVE_OSS_INCLUDE_IN_ROOT,, [Define if OSS includes are in /])
 438      ], [
 439   dnl Some old BSD versions :
 440      AC_CHECK_HEADER(machine/soundcard.h, [
 441        AC_DEFINE(HAVE_OSS_INCLUDE_IN_MACHINE,,
 442          [Define if OSS includes are in /machine/])
 443        ], [
 444        HAVE_OSS="no"
 445      ])
 446    ])
 447  ])
 448 ])
 449
 450 dnl *** oss4 ***
 451 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS4, true)
 452 AG_GST_CHECK_FEATURE(OSS4, [Open Sound System 4], oss4, [
 453   AC_MSG_CHECKING([Checking if we can build the OSS4 elements])
 454   AC_CHECK_HEADERS([fcntl.h sys/ioctl.h sys/stat.h sys/types.h],
 455       [test -z "$OSS4_MISSING_HEADER" && HAVE_OSS4="yes"],
 456       [OSS4_MISSING_HEADER="yes";HAVE_OSS4="no"])
 457 ])
 458
 459 dnl *** Sun Audio ***
 460 translit(dnm, m, l) AM_CONDITIONAL(USE_SUNAUDIO, true)
 461 AG_GST_CHECK_FEATURE(SUNAUDIO, [Sun Audio], sunaudio, [
 462   AC_CHECK_HEADER(sys/audioio.h, HAVE_SUNAUDIO="yes", HAVE_SUNAUDIO="no")
 463 ])
 464
 465 dnl *** OSX Audio ***
 466 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_AUDIO, true)
 467 HAVE_IOS="no"
 468 AG_GST_CHECK_FEATURE(OSX_AUDIO, [OSX audio], osxaudio, [
 469   AC_CHECK_HEADER(CoreAudio/CoreAudio.h,
 470     [HAVE_OSX_AUDIO="yes"],
 471     [AC_CHECK_HEADER(CoreAudio/CoreAudioTypes.h,
 472     [
 473       HAVE_OSX_AUDIO="yes"
 474       HAVE_IOS="yes"
 475     ], [
 476       HAVE_OSX_AUDIO="no"
 477       HAVE_IOS="no"
 478     ])]
 479   )
 480 ])
 481 if test "x$HAVE_IOS" = "xyes"; then
 482   AC_DEFINE(HAVE_IOS, 1, [building for iOS platofrm])
 483 fi
 484 AM_CONDITIONAL(HAVE_IOS, test "x$HAVE_IOS" = "xyes")
 485
 486 dnl *** OS X video ***
 487 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_VIDEO, true)
 488 HAVE_OSX_VIDEO="no"
 489 AG_GST_CHECK_FEATURE(OSX_VIDEO, [OSX video], osxvideosink, [
 490   AC_CHECK_HEADER(OpenGL/gl.h, HAVE_OSX_VIDEO="yes", HAVE_OSX_VIDEO="no")
 491
 492   dnl in case header OpenGL/gl.h is found on other platforms (or older, unsupported OS X)
 493   dnl also require Snow Leopard or newer
 494
 495   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 496         #include <AvailabilityMacros.h>
 497         #if MAC_OS_X_VERSION_MIN_REQUIRED < 1060
 498         #error Too old OSX version
 499         #endif
 500       ]], [[return 0;]])],[HAVE_OSX_VIDEO="yes"],[HAVE_OSX_VIDEO="no"])
 501 ])
 502
 503 dnl *** Video 4 Linux 2 ***
 504 dnl renamed to GST_V4L2 because of some conflict with kernel headers
 505 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L2, true)
 506 HAVE_GST_V4L2=no
 507 AG_GST_CHECK_FEATURE(GST_V4L2, [Video 4 Linux 2], video4linux2, [
 508   AC_MSG_CHECKING([Checking for video4linux2 header ...])
 509   AC_CHECK_HEADER(linux/videodev2.h, [ HAVE_GST_V4L2=yes ],
 510   [
 511     AC_CHECK_HEADER(sys/videodev2.h, [ HAVE_GST_V4L2=yes ],
 512     [
 513       AC_CHECK_HEADER(sys/videoio.h, [ HAVE_GST_V4L2=yes ])
 514     ])
 515   ])
 516   if test "x$HAVE_VIDEODEV" = "xno"; then
 517      AC_MSG_WARN([video4linux2 was not found])
 518   fi
 519 ])
 520
 521 # Optional gudev for device probing
 522 AC_ARG_WITH([gudev],
 523   AS_HELP_STRING([--with-gudev],[device detection with gudev]),
 524   [],
 525   [with_gudev=check])
 526 if test x$HAVE_GST_V4L2 = xyes; then
 527   if test x$with_gudev != xno; then
 528     PKG_CHECK_MODULES(GUDEV, [ gudev-1.0 >= 147 ],
 529       [ AC_DEFINE(HAVE_GUDEV, 1,
 530           [Whether gudev is available for device detection])
 531       ],
 532       [true])
 533   fi
 534 fi
 535
 536 AC_SUBST(GUDEV_CFLAGS)
 537 AC_SUBST(GUDEV_LIBS)
 538
 539 # Make libv4l2 non-automagic
 540 AC_ARG_WITH([libv4l2],
 541   AS_HELP_STRING([--with-libv4l2],[support video buffer conversion using libv4l2]),
 542   [],
 543   [with_libv4l2=check])
 544 if test x$HAVE_GST_V4L2 = xyes; then
 545   if test x$with_libv4l2 != xno; then
 546       PKG_CHECK_MODULES(LIBV4L2, libv4l2,
 547           [ have_libv4l2=yes
 548             AC_DEFINE(HAVE_LIBV4L2, 1,
 549                 [Whether libv4l2 is available for video buffer conversion])
 550           ], [
 551           have_libv4l2=no
 552           ])
 553   else
 554     have_libv4l2=no
 555   fi
 556 fi
 557
 558 dnl Allow enabling v4l2 device probing
 559 AC_ARG_ENABLE(
 560   v4l2-probe,
 561   AC_HELP_STRING(
 562     [--enable-v4l2-probe],
 563     [enable V4L2 plugin to probe devices @<:@default=no@:>@]))
 564 if test "x$enable_v4l2_probe" = xyes; then
 565   AC_DEFINE(GST_V4L2_ENABLE_PROBE, 1,
 566     [Define if Video4Linux probe shall be run at plugin load])
 567 fi
 568
 569 dnl Check for X11
 570 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 571 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 572                   [ximagesrc], [
 573   PKG_CHECK_MODULES([X], [x11], [
 574     HAVE_X="yes"
 575     dnl check for Xfixes
 576     PKG_CHECK_MODULES([XFIXES], [ xfixes ], [
 577       AC_DEFINE(HAVE_XFIXES, 1, [Defined if Xfixes is available])
 578     ], [ HAVE_XFIXES="no" ])
 579
 580     dnl check for Xdamage
 581     PKG_CHECK_MODULES([XDAMAGE], [ xdamage ], [
 582       AC_DEFINE(HAVE_XDAMAGE, 1, [Defined if Xdamage is available])
 583     ], [ HAVE_XDAMAGE="no" ])
 584
 585     dnl check for X Shm
 586     PKG_CHECK_MODULES([XEXT], [ xext ], [
 587       AC_CHECK_LIB([Xext], [ XShmAttach ], [
 588         AC_DEFINE(HAVE_XSHM, 1, [Defined if XShm is available])
 589         XSHM_LIBS="$XEXT_LIBS"
 590         XSHM_CFLAGS="$XEXT_CFLAGS"
 591       ], [ HAVE_XEXT="no" ] , [ $X_LIBS ])
 592     ])
 593     AC_SUBST(XSHM_LIBS)
 594     AC_SUBST(XSHM_CFLAGS)
 595   ], [ HAVE_X="no" ])
 596 ])
 597
 598 dnl *** ext plug-ins ***
 599 dnl keep this list sorted alphabetically !
 600
 601 if test "x$BUILD_EXTERNAL" = "xyes"; then
 602
 603 echo
 604 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 605 echo
 606
 607 dnl *** aalib ***
 608 translit(dnm, m, l) AM_CONDITIONAL(USE_AALIB, true)
 609 AG_GST_CHECK_FEATURE(AALIB, [aalib ASCII Art library], aasink, [
 610   AM_PATH_AALIB(, HAVE_AALIB=yes, HAVE_AALIB=no)
 611 ])
 612
 613 dnl *** cairo ***
 614 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO, true)
 615 AG_GST_CHECK_FEATURE(CAIRO, [Cairo graphics rendering and gobject bindings], cairo, [
 616   AG_GST_PKG_CHECK_MODULES(CAIRO, cairo >= 1.10.0 cairo-gobject >= 1.10.0)
 617 ])
 618
 619 dnl *** FLAC ***
 620 translit(dnm, m, l) AM_CONDITIONAL(USE_FLAC, true)
 621 AG_GST_CHECK_FEATURE(FLAC, [FLAC lossless audio], flac, [
 622   AG_GST_PKG_CHECK_MODULES(FLAC, flac >= 1.1.4)
 623 ])
 624
 625 dnl *** GDK pixbuf ***
 626 translit(dnm, m, l) AM_CONDITIONAL(USE_GDK_PIXBUF, true)
 627 AG_GST_CHECK_FEATURE(GDK_PIXBUF, [GDK pixbuf], gdkpixbuf, [
 628   AG_GST_PKG_CHECK_MODULES(GDK_PIXBUF, gdk-pixbuf-2.0 >= 2.8.0)
 629 ])
 630
 631 dnl *** Jack ***
 632 translit(dnm, m, l) AM_CONDITIONAL(USE_JACK, true)
 633 AG_GST_CHECK_FEATURE(JACK, Jack, jack, [
 634   PKG_CHECK_MODULES(JACK, jack >= 0.99.10, HAVE_JACK="yes", HAVE_JACK="no")
 635   AC_SUBST(JACK_CFLAGS)
 636   AC_SUBST(JACK_LIBS)
 637
 638   AG_GST_PKG_CHECK_MODULES(JACK_0_120_1, jack >= 0.120.1 jack < 1.0)
 639   if test x$HAVE_JACK_0_120_1 = xyes; then
 640     AC_DEFINE(HAVE_JACK_0_120_1, 1, [defined if jack >= 0.120.1 is available])
 641   fi
 642   AG_GST_PKG_CHECK_MODULES(JACK_1_9_7, jack >= 1.9.7)
 643   if test x$HAVE_JACK_1_9_7 = xyes; then
 644     AC_DEFINE(HAVE_JACK_1_9_7, 1, [defined if jack >= 1.9.7 is available])
 645   fi
 646
 647 ])
 648
 649 dnl *** jpeg ***
 650 dnl FIXME: we could use header checks here as well IMO
 651 translit(dnm, m, l) AM_CONDITIONAL(USE_JPEG, true)
 652 AG_GST_CHECK_FEATURE(JPEG, [jpeg library], jpeg, [
 653   AC_ARG_WITH(jpeg-mmx,
 654     [  --with-jpeg-mmx, path to MMX'ified JPEG library])
 655   OLD_LIBS="$LIBS"
 656   if test x$with_jpeg_mmx != x; then
 657     LIBS="$LIBS -L$with_jpeg_mmx"
 658   fi
 659   AC_CHECK_LIB(jpeg-mmx, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 660   JPEG_LIBS="$LIBS -ljpeg-mmx"
 661   LIBS="$OLD_LIBS"
 662   if test x$HAVE_JPEG != xyes; then
 663     AC_CHECK_LIB(jpeg, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 664     JPEG_LIBS="-ljpeg"
 665   fi
 666   AC_SUBST(JPEG_LIBS)
 667 ])
 668
 669 dnl *** libcaca ***
 670 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBCACA, true)
 671 AG_GST_CHECK_FEATURE(LIBCACA, [libcaca coloured ASCII art], cacasink, [
 672   AG_GST_PKG_CHECK_MODULES(LIBCACA, caca)
 673 ])
 674
 675 dnl *** libdv ***
 676 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBDV, true)
 677 AG_GST_CHECK_FEATURE(LIBDV, [libdv DV demuxer/decoder], dv, [
 678   AG_GST_PKG_CHECK_MODULES(LIBDV, libdv >= 0.100)
 679 ])
 680
 681 dnl *** libpng ***
 682 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBPNG, true)
 683 AG_GST_CHECK_FEATURE(LIBPNG, [Portable Network Graphics library], png, [
 684   AG_GST_PKG_CHECK_MODULES(LIBPNG, libpng >= 1.2)
 685 ])
 686
 687 dnl *** pulseaudio ***
 688 translit(dnm, m, l) AM_CONDITIONAL(USE_PULSE, true)
 689 AG_GST_CHECK_FEATURE(PULSE, [pulseaudio plug-in], pulseaudio, [
 690
 691   dnl used in ext/pulse/pulseutil.c
 692   AC_CHECK_HEADERS([process.h])
 693
 694   AG_GST_PKG_CHECK_MODULES(PULSE, libpulse >= 2.0)
 695 ])
 696
 697 dnl *** dv1394 ***
 698 translit(dnm, m, l) AM_CONDITIONAL(USE_DV1394, true)
 699 AG_GST_CHECK_FEATURE(DV1394, [raw1394 and avc1394 library], 1394, [
 700   dnl first test for libraw1394 >= 2.0.0
 701   AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 2.0.0)
 702   AG_GST_PKG_CHECK_MODULES(LIBIEC61883, libiec61883 >= 1.0.0)
 703   dnl now see how far we got
 704   if test x$HAVE_RAW1394 = xyes && \
 705      test x$HAVE_LIBIEC61883 = xyes; then
 706        AG_GST_CHECK_LIBHEADER(AVC1394,
 707         avc1394, avc1394_send_command, $RAW1394_LIBS,
 708         libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 709        AG_GST_CHECK_LIBHEADER(ROM1394,
 710         rom1394, rom1394_free_directory, $RAW1394_LIBS,
 711         libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 712        if test x$HAVE_AVC1394 = xyes && \
 713           test x$HAVE_AVC1394 = xyes && \
 714           test x$HAVE_ROM1394 = xyes; then
 715           HAVE_DV1394=yes
 716           DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS $LIBIEC61883_LIBS"
 717           DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 718           AC_SUBST(DV1394_CFLAGS)
 719           AC_SUBST(DV1394_LIBS)
 720         fi
 721   else
 722        if test x$HAVE_RAW1394 = xno; then
 723           AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.1.0)
 724           AG_GST_CHECK_LIBHEADER(AVC1394,
 725            avc1394, avc1394_send_command, $RAW1394_LIBS,
 726            libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 727           AG_GST_CHECK_LIBHEADER(ROM1394,
 728            rom1394, rom1394_free_directory, $RAW1394_LIBS,
 729            libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 730           if test x$HAVE_RAW1394 = xyes && \
 731              test x$HAVE_AVC1394 = xyes && \
 732              test x$HAVE_ROM1394 = xyes; then
 733              HAVE_DV1394=yes
 734              DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS"
 735              DV1394_CFLAGS="$RAW1394_CFLAGS"
 736              if test x$HAVE_LIBIEC61883 = xyes; then
 737                DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 738                DV1394_LIBS="$DV1394_LIBS $LIBIEC61883_LIBS"
 739              fi
 740              AC_SUBST(DV1394_CFLAGS)
 741              AC_SUBST(DV1394_LIBS)
 742            fi
 743          fi
 744   fi
 745 ])
 746 AM_CONDITIONAL(USE_LIBIEC61883, [ test "x${HAVE_LIBIEC61883}" = xyes ] )
 747
 748 dnl *** shout2 ***
 749 translit(dnm, m, l) AM_CONDITIONAL(USE_SHOUT2, true)
 750 AG_GST_CHECK_FEATURE(SHOUT2, [Shoutcast/Icecast client library], shout2, [
 751   AG_GST_PKG_CHECK_MODULES(SHOUT2, shout >= 2.0)
 752 ])
 753
 754 dnl *** soup ***
 755 translit(dnm, m, l) AM_CONDITIONAL(USE_SOUP, true)
 756 AG_GST_CHECK_FEATURE(SOUP, [soup http client plugin (2.4)], souphttpsrc, [
 757   PKG_CHECK_MODULES(SOUP, libsoup-2.4 >= 2.40, [HAVE_SOUP="yes"], [HAVE_SOUP="no"])
 758   AC_SUBST(SOUP_CFLAGS)
 759   AC_SUBST(SOUP_LIBS)
 760 ])
 761
 762 dnl *** speex ***
 763 translit(dnm, m, l) AM_CONDITIONAL(USE_SPEEX, true)
 764 AG_GST_CHECK_FEATURE(SPEEX, [speex speech codec], speex, [
 765   AG_GST_PKG_CHECK_MODULES(SPEEX, speex >= 1.1.6)
 766 ])
 767
 768 dnl *** taglib ***
 769 translit(dnm, m, l) AM_CONDITIONAL(USE_TAGLIB, true)
 770 AG_GST_CHECK_FEATURE(TAGLIB, [taglib tagging library], taglib, [
 771   AG_GST_PKG_CHECK_MODULES(TAGLIB, taglib >= 1.5)
 772   if test "x$HAVE_CXX" != "xyes"; then
 773     USE_TAGLIB=false
 774     AC_MSG_NOTICE([Not building taglib plugin: no C++ compiler found])
 775   else
 776     dnl work around bug in taglib 1.5 headers, remove once there is a 1.6
 777     AS_CXX_COMPILER_FLAG([-Wno-attributes], [
 778         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS -Wno-attributes"
 779       ], [
 780         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS"
 781     ])
 782     AC_SUBST(TAGLIB_CXXFLAGS)
 783   fi
 784 ])
 785
 786 dnl *** vpx ***
 787 translit(dnm, m, l) AM_CONDITIONAL(USE_VPX, vpx)
 788 AG_GST_CHECK_FEATURE(VPX, [VPX decoder], vpx, [
 789   PKG_CHECK_MODULES(VPX, vpx >= 1.1.0, [HAVE_VPX="yes"], [HAVE_VPX="no"])
 790   HAVE_VP8=no
 791   HAVE_VP9=no
 792
 793   if test $HAVE_VPX = "yes"; then
 794     OLD_LIBS="$LIBS"
 795     OLD_CFLAGS="$CFLAGS"
 796     CFLAGS="$CFLAGS $VPX_CFLAGS"
 797     LIBS="$LIBS $VPX_LIBS"
 798     AC_CHECK_LIB(vpx, vpx_codec_vp8_cx_algo, [
 799       HAVE_VP8=yes
 800       AC_DEFINE(HAVE_VP8_ENCODER, 1, [Defined if the VP8 encoder is available])
 801     ])
 802     AC_CHECK_LIB(vpx, vpx_codec_vp8_dx_algo, [
 803       HAVE_VP8=yes
 804       AC_DEFINE(HAVE_VP8_DECODER, 1, [Defined if the VP8 decoder is available])
 805     ])
 806
 807     PKG_CHECK_MODULES(VPX_130, vpx >= 1.3.0, [
 808       AC_CHECK_LIB(vpx, vpx_codec_vp9_cx_algo, [
 809         HAVE_VP9=yes
 810         AC_DEFINE(HAVE_VP9_ENCODER, 1, [Defined if the VP9 encoder is available])
 811       ])
 812       AC_CHECK_LIB(vpx, vpx_codec_vp9_dx_algo, [
 813         HAVE_VP9=yes
 814         AC_DEFINE(HAVE_VP9_DECODER, 1, [Defined if the VP9 decoder is available])
 815       ])
 816     ], [true])
 817     LIBS="$OLD_LIBS"
 818     CFLAGS="$OLD_CFLAGS"
 819   fi
 820   AC_SUBST(VPX_LIBS)
 821   AC_SUBST(VPX_CFLAGS)
 822 ])
 823
 824 dnl *** wavpack ***
 825 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVPACK, true)
 826 AG_GST_CHECK_FEATURE(WAVPACK, [wavpack plug-in], wavpack, [
 827   AG_GST_PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.60.0)
 828 ])
 829
 830 dnl *** qtdemux & matroska prefer to have zlib ***
 831 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 832 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for qtdemux/matroska],, [
 833   AG_GST_CHECK_LIBHEADER(ZLIB,
 834     z, uncompress,, zlib.h, [
 835     HAVE_ZLIB="yes"
 836     ZLIB_LIBS="-lz"
 837     AC_SUBST(ZLIB_LIBS)
 838   ])
 839 ])
 840
 841 dnl *** matroska prefers to have bz2 ***
 842 translit(dnm, m, l) AM_CONDITIONAL(USE_BZ2, true)
 843 AG_GST_CHECK_FEATURE(BZ2, [bz2 library for matroska ],, [
 844   save_LIBS=$LIBS
 845   LIBS="$LIBS -lbz2"
 846   AC_MSG_CHECKING([for BZ2_bzlibVersion in -lbz2])
 847   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <bzlib.h>]], [[const char *version = BZ2_bzlibVersion ();]])],[HAVE_BZ2=yes],[HAVE_BZ2=no])
 848   AC_MSG_RESULT($HAVE_BZ2)
 849   LIBS=$save_LIBS
 850   if test "x$HAVE_BZ2" = "xyes"; then
 851     BZ2_LIBS="-lbz2"
 852   fi
 853   AC_SUBST(BZ2_LIBS)
 854 ])
 855
 856 else
 857
 858 dnl not building plugins with external dependencies,
 859 dnl but we still need to set the conditionals
 860 AM_CONDITIONAL(USE_AALIB, false)
 861 AM_CONDITIONAL(USE_BZ2, false)
 862 AM_CONDITIONAL(USE_CAIRO, false)
 863 AM_CONDITIONAL(USE_DIRECTSOUND, false)
 864 AM_CONDITIONAL(USE_DV1394, false)
 865 AM_CONDITIONAL(USE_FLAC, false)
 866 AM_CONDITIONAL(USE_GDK_PIXBUF, false)
 867 AM_CONDITIONAL(USE_JACK, false)
 868 AM_CONDITIONAL(USE_JPEG, false)
 869 AM_CONDITIONAL(USE_LIBCACA, false)
 870 AM_CONDITIONAL(USE_LIBDV, false)
 871 AM_CONDITIONAL(USE_LIBIEC61883, false)
 872 AM_CONDITIONAL(USE_LIBPNG, false)
 873 AM_CONDITIONAL(USE_OSS, false)
 874 AM_CONDITIONAL(USE_OSS4, false)
 875 AM_CONDITIONAL(USE_OSX_AUDIO, false)
 876 AM_CONDITIONAL(USE_OSX_VIDEO, false)
 877 AM_CONDITIONAL(USE_PULSE, false)
 878 AM_CONDITIONAL(USE_SHOUT2, false)
 879 AM_CONDITIONAL(USE_SOUP, false)
 880 AM_CONDITIONAL(USE_SPEEX, false)
 881 AM_CONDITIONAL(USE_SUNAUDIO, false)
 882 AM_CONDITIONAL(USE_TAGLIB, false)
 883 AM_CONDITIONAL(USE_VPX, false)
 884 AM_CONDITIONAL(USE_WAVEFORM, false)
 885 AM_CONDITIONAL(USE_WAVPACK, false)
 886 AM_CONDITIONAL(USE_X, false)
 887 AM_CONDITIONAL(USE_ZLIB, false)
 888
 889 fi dnl of EXT plugins
 890
 891 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 892
 893 dnl Overview:
 894 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 895 dnl GST_*:              flags shared by all built objects
 896 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 897 dnl GST_LIB_LDFLAGS:    not needed, we don't install libraries
 898 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 899 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 900
 901 dnl GST_OPTION_CFLAGS
 902 if test "x$USE_DEBUG" = xyes; then
 903    PROFILE_CFLAGS="-g"
 904 fi
 905 AC_SUBST(PROFILE_CFLAGS)
 906
 907 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 908   dnl Define _only_ for git (not pre-releases or releases)
 909   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 910 else
 911   DEPRECATED_CFLAGS=""
 912 fi
 913 AC_SUBST(DEPRECATED_CFLAGS)
 914
 915 dnl every flag in GST_OPTION_CFLAGS, GST_OPTION_CXXFLAGS and GST_OPTION_OBJCFLAGS can be overridden
 916 dnl at make time with e.g. make ERROR_CFLAGS=""
 917 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 918 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 919 GST_OPTION_OBJCFLAGS="\$(WARNING_OBJCFLAGS) \$(ERROR_OBJCFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 920 AC_SUBST(GST_OPTION_CFLAGS)
 921 AC_SUBST(GST_OPTION_CXXFLAGS)
 922 AC_SUBST(GST_OPTION_OBJCFLAGS)
 923
 924 dnl our libraries need to be versioned correctly
 925 AC_SUBST(GST_LT_LDFLAGS)
 926
 927 dnl FIXME: do we want to rename to GST_ALL_* ?
 928 dnl prefer internal headers to already installed ones
 929 dnl also add builddir include for enumtypes and marshal
 930 dnl add ERROR_CFLAGS, but overridable
 931 GST_CFLAGS="$GST_CFLAGS -DGST_USE_UNSTABLE_API"
 932 GST_CXXFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CXXFLAGS)"
 933 GST_OBJCFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_OBJCFLAGS)"
 934 GST_CFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CFLAGS)"
 935 AC_SUBST(GST_CFLAGS)
 936 AC_SUBST(GST_CXXFLAGS)
 937 AC_SUBST(GST_OBJCFLAGS)
 938 AC_SUBST(GST_LIBS)
 939
 940 dnl LDFLAGS really should only contain flags, not libs - they get added before
 941 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 942 GST_ALL_LDFLAGS="-no-undefined"
 943 AC_SUBST(GST_ALL_LDFLAGS)
 944
 945 dnl this really should only contain flags, not libs - they get added before
 946 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 947 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_.*' $GST_ALL_LDFLAGS"
 948 AC_SUBST(GST_PLUGIN_LDFLAGS)
 949
 950 dnl *** output files ***
 951
 952 $MKDIR_P tests/check/orc
 953
 954 dnl keep this alphabetic per directory, please
 955 AC_CONFIG_FILES(
 956 Makefile
 957 gst/Makefile
 958 gst/alpha/Makefile
 959 gst/apetag/Makefile
 960 gst/audiofx/Makefile
 961 gst/audioparsers/Makefile
 962 gst/auparse/Makefile
 963 gst/autodetect/Makefile
 964 gst/avi/Makefile
 965 gst/cutter/Makefile
 966 gst/deinterlace/Makefile
 967 gst/dtmf/Makefile
 968 gst/debugutils/Makefile
 969 gst/effectv/Makefile
 970 gst/equalizer/Makefile
 971 gst/flv/Makefile
 972 gst/goom/Makefile
 973 gst/goom2k1/Makefile
 974 gst/id3demux/Makefile
 975 gst/icydemux/Makefile
 976 gst/imagefreeze/Makefile
 977 gst/interleave/Makefile
 978 gst/isomp4/Makefile
 979 gst/law/Makefile
 980 gst/level/Makefile
 981 gst/matroska/Makefile
 982 gst/monoscope/Makefile
 983 gst/multifile/Makefile
 984 gst/multipart/Makefile
 985 gst/replaygain/Makefile
 986 gst/rtp/Makefile
 987 gst/rtpmanager/Makefile
 988 gst/rtsp/Makefile
 989 gst/shapewipe/Makefile
 990 gst/smpte/Makefile
 991 gst/spectrum/Makefile
 992 gst/udp/Makefile
 993 gst/videobox/Makefile
 994 gst/videocrop/Makefile
 995 gst/videofilter/Makefile
 996 gst/videomixer/Makefile
 997 gst/wavenc/Makefile
 998 gst/wavparse/Makefile
 999 gst/flx/Makefile
1000 gst/y4m/Makefile
1001 ext/Makefile
1002 ext/aalib/Makefile
1003 ext/cairo/Makefile
1004 ext/dv/Makefile
1005 ext/flac/Makefile
1006 ext/gdk_pixbuf/Makefile
1007 ext/jack/Makefile
1008 ext/jpeg/Makefile
1009 ext/libcaca/Makefile
1010 ext/libpng/Makefile
1011 ext/pulse/Makefile
1012 ext/raw1394/Makefile
1013 ext/shout2/Makefile
1014 ext/soup/Makefile
1015 ext/speex/Makefile
1016 ext/taglib/Makefile
1017 ext/vpx/Makefile
1018 ext/wavpack/Makefile
1019 sys/Makefile
1020 sys/directsound/Makefile
1021 sys/oss/Makefile
1022 sys/oss4/Makefile
1023 sys/osxaudio/Makefile
1024 sys/osxvideo/Makefile
1025 sys/sunaudio/Makefile
1026 sys/v4l2/Makefile
1027 sys/waveform/Makefile
1028 sys/ximage/Makefile
1029 po/Makefile.in
1030 tests/Makefile
1031 tests/check/Makefile
1032 tests/examples/Makefile
1033 tests/examples/audiofx/Makefile
1034 tests/examples/cairo/Makefile
1035 tests/examples/equalizer/Makefile
1036 tests/examples/jack/Makefile
1037 tests/examples/level/Makefile
1038 tests/examples/pulse/Makefile
1039 tests/examples/rtp/Makefile
1040 tests/examples/shapewipe/Makefile
1041 tests/examples/spectrum/Makefile
1042 tests/examples/v4l2/Makefile
1043 tests/files/Makefile
1044 tests/icles/Makefile
1045 common/Makefile
1046 common/m4/Makefile
1047 m4/Makefile
1048 docs/Makefile
1049 docs/plugins/Makefile
1050 docs/version.entities
1051 pkgconfig/Makefile
1052 pkgconfig/gstreamer-plugins-good-uninstalled.pc
1053 gst-plugins-good.spec
1054 )
1055
1056 dnl Create the config.h file for Visual Studio builds
1057 dnl Beware of spaces and /'s in some of the shell variable contents.
1058 sed \
1059     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"\n\n#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
1060     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
1061     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
1062     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
1063     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
1064     -e 's/.* GST_API_VERSION$/#define GST_API_VERSION "'$GST_API_VERSION'"/' \
1065     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
1066     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
1067     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
1068     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
1069     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
1070     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
1071     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
1072     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
1073     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
1074     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
1075     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
1076     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
1077     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
1078     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
1079     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
1080     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
1081     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
1082     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
1083     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
1084     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
1085     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
1086     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
1087     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.11"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.11"\n#endif/' \
1088     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
1089     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
1090     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directsoundsink\"/" \
1091     -e "s/.* DEFAULT_AUDIOSRC$/#define DEFAULT_AUDIOSRC \"audiotestsrc\"/" \
1092     -e "s/.* DEFAULT_VIDEOSRC$/#define DEFAULT_VIDEOSRC \"videotestsrc\"/" \
1093     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
1094     config.h.in >win32/common/config.h-new
1095
1096 AC_OUTPUT
1097
1098 AG_GST_OUTPUT_PLUGINS
1099 ORC_OUTPUT
1100