configure.ac

   1  ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
   2 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
   3 m4_define([v_maj], [1])
   4 m4_define([v_min], [2])
   5 m4_define([v_mic], [3])
   6 m4_define([v_rev], m4_esyscmd([svnversion . | awk -F : '{printf("%s", $1);}' | tr 'A-z' ' ' | sed 's/ //g']))
   7 m4_ifelse(m4_len[v_rev], [0], [m4_undefine([v_rev])])
   8 ##--   When released, remove the dnl on the below line
   9 dnl m4_undefine([v_rev])
  10 ##--   When doing snapshots - change soname. remove dnl on below line
  11 dnl m4_define([v_rel], [-release ver-pre-svn-v_rev])
  12 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  13 m4_ifdef([v_rev], [m4_define([v_ver], [v_maj.v_min.v_mic.v_rev])], [m4_define([v_ver], [v_maj.v_min.v_mic])])
  14 m4_define([lt_rev], m4_eval(v_maj + v_min))
  15 m4_define([lt_cur], v_mic)
  16 m4_define([lt_age], v_min)
  17 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  18  ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  19
  20 AC_INIT([eet], [v_ver], [enlightenment-devel@lists.sourceforge.net])
  21 AC_PREREQ([2.52])
  22 AC_CONFIG_SRCDIR([configure.ac])
  23 AC_CONFIG_MACRO_DIR([m4])
  24 AC_CANONICAL_BUILD
  25 AC_CANONICAL_HOST
  26 AC_ISC_POSIX
  27
  28 AM_INIT_AUTOMAKE([1.6 dist-bzip2])
  29 AM_CONFIG_HEADER([config.h])
  30 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  31
  32 AC_LIBTOOL_WIN32_DLL
  33 define([AC_LIBTOOL_LANG_CXX_CONFIG], [:])dnl
  34 define([AC_LIBTOOL_LANG_F77_CONFIG], [:])dnl
  35 AC_PROG_LIBTOOL
  36
  37  ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  38 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  39 m4_ifdef([v_rev], , [m4_define([v_rev], [0])])
  40 m4_ifdef([v_rel], , [m4_define([v_rel], [])])
  41 AC_DEFINE_UNQUOTED(VMAJ, [v_maj], [Major version])
  42 AC_DEFINE_UNQUOTED(VMIN, [v_min], [Minor version])
  43 AC_DEFINE_UNQUOTED(VMIC, [v_mic], [Micro version])
  44 AC_DEFINE_UNQUOTED(VREV, [v_rev], [Revison])
  45 version_info="lt_rev:lt_cur:lt_age"
  46 release_info="v_rel"
  47 AC_SUBST(version_info)
  48 AC_SUBST(release_info)
  49 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  50  ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  51
  52 ### Default options with respect to host
  53
  54 case "$host_os" in
  55    mingw*)
  56       want_gnutls="no"
  57       want_openssl="no"
  58       want_cipher="no"
  59       want_signature="no"
  60       ;;
  61    *)
  62       want_gnutls="auto"
  63       want_openssl="auto"
  64       want_cipher="yes"
  65       want_signature="yes"
  66       ;;
  67 esac
  68
  69 requirement_eet=""
  70
  71
  72 ### Additional options to configure
  73
  74 # Amalgamation
  75
  76 AC_ARG_ENABLE([amalgamation],
  77    [AC_HELP_STRING([--enable-amalgamation], [enable generation of one single file with all source code in it, helps compiler optimizations.])],
  78    [if test "x${enableval}" = "xyes"; then
  79        do_amalgamation="yes"
  80     else
  81        do_amalgamation="no"
  82     fi
  83    ],
  84    [do_amalgamation="no"]
  85 )
  86 AM_CONDITIONAL(EET_AMALGAMATION, test "x${do_amalgamation}" = "xyes")
  87
  88 EFL_ENABLE_BIN([eet])
  89
  90 # Old eet file format support
  91
  92 old_eet_file_format="yes"
  93 AC_ARG_ENABLE(old-eet-file-format,
  94    [AC_HELP_STRING(
  95       [--disable-old-eet-file-format],
  96       [disable old eet file format support. [[default=enabled]]]
  97     )],
  98    [old_eet_file_format=$enableval]
  99 )
 100 AC_MSG_CHECKING([whether to support old eet file format])
 101 AC_MSG_RESULT([${old_eet_file_format}])
 102
 103 if test "x${old_eet_file_format}" = "xyes" ; then
 104    AC_DEFINE(EET_OLD_EET_FILE_FORMAT, 1, [support old eet file format])
 105 else
 106    AC_DEFINE(EET_OLD_EET_FILE_FORMAT, 0, [support old eet file format])
 107 fi
 108
 109 # Gnutls support
 110
 111 AC_ARG_ENABLE([gnutls],
 112    [AC_HELP_STRING([--disable-gnutls], [disable gnutls eet support])],
 113    [want_gnutls=$enableval]
 114 )
 115 AC_MSG_CHECKING([whether to use Gnutls])
 116 AC_MSG_RESULT([${want_gnutls}])
 117
 118 # Specific GNUTLS improvement
 119
 120 new_gnutls_api="yes"
 121 AC_ARG_ENABLE(new-gnutls-api,
 122    [AC_HELP_STRING(
 123       [--disable-new-gnutls-api],
 124       [enable use of gnutls_x509_crt_verify_hash. [[default=enable]]]
 125     )],
 126    [new_gnutls_api=$enableval]
 127 )
 128 AC_MSG_CHECKING([whether to use gnutls_x509_crt_verify_hash])
 129 AC_MSG_RESULT([${new_gnutls_api}])
 130
 131 if test "x${new_gnutls_api}" = "xyes" ; then
 132    AC_CHECK_LIB(gnutls, gnutls_x509_crt_verify_hash,
 133                 [ new_gnutls_api="yes" ],
 134                 [ new_gnutls_api="no" ]
 135                 )
 136
 137    if test "x${new_gnutls_api}" = "xyes"; then
 138       AC_DEFINE(EET_USE_NEW_GNUTLS_API, 1, [use gnutls_x509_crt_verify_hash])
 139    fi
 140 fi
 141
 142 # Openssl support
 143
 144 AC_ARG_ENABLE([openssl],
 145    [AC_HELP_STRING([--disable-openssl], [disable openssl eet support])],
 146    [want_openssl=$enableval]
 147 )
 148 AC_MSG_CHECKING([whether to use OpenSSL])
 149 AC_MSG_RESULT([${want_openssl}])
 150
 151 # Cryptography support
 152
 153 AC_ARG_ENABLE([cipher],
 154    [AC_HELP_STRING([--disable-cipher], [disable cipher support for eet API])],
 155    [want_cipher=$enableval]
 156 )
 157 AC_MSG_CHECKING([whether to use cipher])
 158 AC_MSG_RESULT([${want_cipher}])
 159
 160 AC_ARG_ENABLE([signature],
 161    [AC_HELP_STRING([--disable-signature], [disable signature file support for eet])],
 162    [want_signature=$enableval]
 163 )
 164 AC_MSG_CHECKING([whether to use signature])
 165 AC_MSG_RESULT([${want_signature}])
 166
 167 # Assert or fail.
 168 prefer_assert="no"
 169 AC_ARG_ENABLE([assert],
 170    [AC_HELP_STRING([--enable-assert], [enable assert, [[default=disabled]]])],
 171    [prefer_assert=$enableval]
 172 )
 173
 174 # Examples
 175
 176 AC_ARG_ENABLE([install-examples],
 177    [AC_HELP_STRING([--disable-install-examples],
 178        [disable installing examples (compiled or just source). @<:@default==enabled@:>@])],
 179    [
 180     if test "x${enableval}" = "xyes" ; then
 181        install_examples="yes"
 182     else
 183        install_examples="no"
 184     fi
 185    ],
 186    [install_examples="yes"])
 187 AM_CONDITIONAL([INSTALL_EXAMPLES], [test "x${install_examples}" = "xyes"])
 188
 189 AC_ARG_ENABLE([build-examples],
 190    [AC_HELP_STRING([--enable-build-examples],
 191        [enable building examples. @<:@default==disabled@:>@])],
 192    [
 193     if test "x${enableval}" = "xyes" ; then
 194        build_examples="yes"
 195     else
 196        build_examples="no"
 197     fi
 198    ],
 199    [build_examples="no"])
 200 AM_CONDITIONAL([BUILD_EXAMPLES], [test "x${build_examples}" = "xyes"])
 201
 202 # Unit tests, coverage and benchmarking
 203
 204 EFL_CHECK_TESTS([enable_tests="yes"], [enable_tests="no"])
 205 EFL_CHECK_COVERAGE([${enable_tests}], [enable_coverage="yes"], [enable_coverage="no"])
 206
 207 if test "x${prefer_assert}" = "xno"; then
 208    DEBUG_CFLAGS="-DNDEBUG"
 209 else
 210 # use debug symbols and set DEBUG if coverage support is enabled
 211    DEBUG_CFLAGS="${EFL_DEBUG_CFLAGS}"
 212 fi
 213 AC_SUBST(DEBUG_CFLAGS)
 214
 215
 216 ### Checks for programs
 217 AC_PROG_CC
 218
 219 # pkg-config
 220 PKG_PROG_PKG_CONFIG
 221
 222 # Check whether pkg-config supports Requires.private
 223 if $PKG_CONFIG --atleast-pkgconfig-version 0.22; then
 224    pkgconfig_requires_private="Requires.private"
 225 else
 226    pkgconfig_requires_private="Requires"
 227 fi
 228 AC_SUBST(pkgconfig_requires_private)
 229
 230
 231 # doxygen program for documentation building
 232
 233 EFL_CHECK_DOXYGEN([build_doc="yes"], [build_doc="no"])
 234
 235 ### Checks for libraries
 236
 237 # Evil library for compilation on Windows
 238
 239 EFL_EET_BUILD=""
 240 case "$host_os" in
 241    mingw*)
 242       PKG_CHECK_MODULES([EVIL], [evil])
 243       AC_DEFINE(HAVE_EVIL, 1, [Set to 1 if Evil library is installed])
 244       requirement_eet="evil ${requirement_eet}"
 245       EFL_EET_BUILD="-DEFL_EET_BUILD"
 246    ;;
 247 esac
 248 AC_SUBST(EFL_EET_BUILD)
 249
 250 EET_LIBS=""
 251 case "$host_os" in
 252    mingw32ce*)
 253       EET_LIBS="-lws2"
 254       ;;
 255    mingw*)
 256       EET_LIBS="-lws2_32"
 257       ;;
 258 esac
 259 AC_SUBST(EET_LIBS)
 260
 261 # Eina library
 262
 263 PKG_CHECK_MODULES(EINA, [eina-0])
 264 requirement_eet="eina-0 ${requirement_eet}"
 265
 266 # Gnutls library
 267 have_gnutls="no"
 268 if test "x${want_gnutls}" = "xyes" -o "x${want_gnutls}" = "xauto" ; then
 269    PKG_CHECK_MODULES(GNUTLS, [gnutls >= 1.7.6],
 270       [
 271        have_gnutls="yes"
 272        want_openssl="no"
 273        AC_DEFINE(HAVE_GNUTLS, 1, [Have Gnutls support])
 274        requirement_eet="gnutls ${requirement_eet}"
 275       ],
 276       [have_gnutls="no"])
 277    if test "x${have_gnutls}" = "xyes" ; then
 278       AC_PATH_GENERIC([libgcrypt], [], [have_gnutls="yes"], [have_gnutls="no"])
 279       if test "x${have_gnutls}" = "xyes" ; then
 280          GNUTLS_CFLAGS="${GNUTLS_CFLAGS} ${LIBGCRYPT_CFLAGS}"
 281          GNUTLS_LIBS="${GNUTLS_LIBS} ${LIBGCRYPT_LIBS}"
 282       fi
 283    fi
 284 fi
 285
 286 # Openssl library
 287 have_openssl="no"
 288 if test "x${want_openssl}" = "xyes" -o "x${want_openssl}" = "xauto" ; then
 289    PKG_CHECK_MODULES(OPENSSL, openssl,
 290       [
 291        have_openssl="yes"
 292        AC_DEFINE(HAVE_OPENSSL, 1, [Have Openssl support])
 293        requirement_eet="openssl ${requirement_eet}"
 294       ],
 295       [have_openssl="no"])
 296 fi
 297
 298 have_cipher="no"
 299 if test "x${have_gnutls}" = "xyes" -a "x${want_cipher}" = "xyes" ; then
 300    have_cipher="yes"
 301    AC_DEFINE(HAVE_CIPHER, 1, [Have cipher support built in eet])
 302 elif test "x${have_openssl}" = "xyes" -a "x${want_cipher}" = "xyes" ; then
 303    have_cipher="yes"
 304    AC_DEFINE(HAVE_CIPHER, 1, [Have cipher support built in eet])
 305 fi
 306
 307 AC_MSG_CHECKING(whether to activate cipher support in eet)
 308 AC_MSG_RESULT(${have_cipher})
 309
 310 have_signature="no"
 311 if test "x${have_gnutls}" = "xyes" -a "x${want_signature}" = "xyes" ; then
 312    have_signature="yes"
 313    AC_DEFINE(HAVE_SIGNATURE, 1, [Have signature support for eet file])
 314 elif test "x${have_openssl}" = "xyes" -a "x${want_signature}" = "xyes" ; then
 315    have_signature="yes"
 316    AC_DEFINE(HAVE_SIGNATURE, 1, [Have signature support for eet file])
 317 fi
 318
 319 AC_MSG_CHECKING(whether to activate signature support in eet)
 320 AC_MSG_RESULT(${have_signature})
 321
 322 # pthread library
 323
 324 EFL_CHECK_PTHREAD(["no"], [have_pthread="yes"], [have_pthread="no"])
 325
 326
 327 ### Checks for header files
 328
 329 AC_CHECK_HEADER([zlib.h],
 330    [dummy="yes"],
 331    [AC_MSG_ERROR("Cannot find zlib.h. Make sure your CFLAGS environment variable contains include lines for the location of this file")])
 332
 333 AC_CHECK_HEADER([jpeglib.h],
 334    [dummy="yes"],
 335    [AC_MSG_ERROR("Cannot find jpeglib.h. Make sure your CFLAGS environment variable contains include lines for the location of this file")])
 336
 337 AC_CHECK_HEADERS(netinet/in.h)
 338
 339
 340 ### Checks for types
 341
 342
 343 ### Checks for structures
 344
 345
 346 ### Checks for compiler characteristics
 347 AM_PROG_CC_C_O
 348 AC_C_CONST
 349 AC_C_INLINE
 350 AC_PROG_CC_STDC
 351 AC_C___ATTRIBUTE__
 352
 353 # Check whether the null pointer is zero on this arch
 354 AC_TRY_RUN(
 355    [
 356 #include <stdlib.h>
 357 int main (int argc, char **argv) {
 358   void *foo = NULL;
 359   int bar = (int)foo;
 360   return (int)foo;
 361 }
 362    ],
 363    [have_null="yes"],
 364    [have_null="no"],
 365    [
 366     AC_MSG_WARN([Cannot check when cross-compiling -- assuming null is okay])
 367     have_null="yes"
 368    ])
 369 AC_MSG_CHECKING([value of the null pointer])
 370 AC_MSG_RESULT([${have_null}])
 371
 372 if test ! "x${have_null}" = "xyes" ; then
 373    AC_MSG_WARN([Your system is a bit too funny, eet might not work properly])
 374 fi
 375
 376 # These are needed for fmemopen/open_memstream
 377 AC_DEFINE(_GNU_SOURCE, , [Enable GNU extensions])
 378
 379 EET_CPPFLAGS=""
 380 EET_CFLAGS=""
 381 case "$host_os" in
 382    mingw32ce*)
 383       EET_CPPFLAGS="-D_WIN32_WCE=0x0420"
 384       ;;
 385    mingw*)
 386       EET_CPPFLAGS="-D_WIN32_WINNT=0x0501"
 387       ;;
 388 esac
 389 AC_SUBST(EET_CPPFLAGS)
 390 AC_SUBST(EET_CFLAGS)
 391
 392
 393 ### Checks for linker characteristics
 394
 395 # use --enable-auto-import on Windows
 396
 397 lt_enable_auto_import=""
 398 case "$host_os" in
 399    mingw*)
 400       lt_enable_auto_import="-Wl,--enable-auto-import"
 401       ;;
 402 esac
 403 AC_SUBST(lt_enable_auto_import)
 404
 405 # use --as-needed if supported
 406
 407 LDFLAGS_SAVE=${LDFLAGS}
 408 LDFLAGS="${LDFLAGS} -Wl,--as-needed"
 409
 410 AC_LINK_IFELSE(
 411    [AC_LANG_PROGRAM([[]], [])],
 412    [ld_as_needed="-Wl,--as-needed"],
 413    [ld_as_needed=""]
 414 )
 415
 416 LDFLAGS=${LDFLAGS_SAVE}
 417 AC_SUBST(ld_as_needed)
 418
 419
 420 ### Checks for library functions
 421 AC_FUNC_ALLOCA
 422
 423 AC_CHECK_FUNCS(fmemopen open_memstream realpath)
 424
 425 EFL_CHECK_FNMATCH([], [AC_MSG_ERROR([Cannot find fnmatch()])])
 426
 427
 428 AC_SUBST(requirement_eet)
 429
 430 AC_OUTPUT([
 431 Makefile
 432 eet.pc
 433 doc/Makefile
 434 doc/eet.dox
 435 src/Makefile
 436 src/lib/Makefile
 437 src/bin/Makefile
 438 src/tests/Makefile
 439 src/examples/Makefile
 440 README
 441 eet.spec
 442 ])
 443
 444
 445 #####################################################################
 446 ## Info
 447
 448 echo
 449 echo
 450 echo
 451 echo "------------------------------------------------------------------------"
 452 echo "$PACKAGE_NAME $PACKAGE_VERSION"
 453 echo "------------------------------------------------------------------------"
 454 echo
 455 echo "Configuration Options Summary:"
 456 echo
 457 echo "  Amalgamation.........: ${do_amalgamation}"
 458 echo "  Gnutls...............: ${have_gnutls}"
 459 echo "  Openssl..............: ${have_openssl}"
 460 echo "    Cipher support.....: ${have_cipher}"
 461 echo "    Signature..........: ${have_signature}"
 462 echo "  Thread Support.......: ${have_pthread}"
 463 echo
 464 echo "  Old eet file format..: ${old_eet_file_format}"
 465 echo
 466 echo "  Tests................: ${enable_tests}"
 467 echo "  Coverage.............: ${enable_coverage}"
 468 echo
 469 echo "  Build eet............: $have_eet"
 470 echo
 471 echo "  Documentation........: ${build_doc}"
 472 if test "x${build_doc}" = "xyes" ; then
 473    echo "    Building...........: make doc"
 474 fi
 475 echo "  Examples.............: ${build_examples}"
 476 if test "x${build_examples}" = "xyes" ; then
 477    echo "    Install............: ${install_examples}"
 478 fi
 479 echo
 480 echo "Compilation............: make (or gmake)"
 481 echo "  CPPFLAGS.............: $CPPFLAGS"
 482 echo "  CFLAGS...............: $CFLAGS"
 483 echo "  LDFLAGS..............: $LDFLAGS"
 484 echo
 485 echo "Installation...........: make install (as root if needed, with 'su' or 'sudo')"
 486 echo "  prefix...............: $prefix"
 487 echo