configure.ac

   1 # gstreamer-vaapi package version number
   2 m4_define([gst_vaapi_major_version], [0])
   3 m4_define([gst_vaapi_minor_version], [1])
   4 m4_define([gst_vaapi_micro_version], [2])
   5 m4_define([gst_vaapi_version],
   6           [gst_vaapi_major_version.gst_vaapi_minor_version.gst_vaapi_micro_version])
   7
   8 # gst version number
   9 m4_define([gst_major_version], [0])
  10 m4_define([gst_minor_version], [10])
  11 m4_define([gst_micro_version], [0])
  12 m4_define([gst_major_minor_version],
  13           [gst_major_version.gst_minor_version])
  14 m4_define([gst_version],
  15           [gst_major_version.gst_minor_version.gst_micro_version])
  16
  17 # gst plugins-base version number
  18 m4_define([gst_plugins_base_major_version], [0])
  19 m4_define([gst_plugins_base_minor_version], [10])
  20 m4_define([gst_plugins_base_micro_version], [16])
  21 m4_define([gst_plugins_base_version],
  22           [gst_plugins_base_major_version.gst_plugins_base_minor_version.gst_plugins_base_micro_version])
  23
  24 # libva package version number
  25 m4_define([libva_sds_version_0_29], [8])
  26 m4_define([libva_sds_package_version_0_29], [0.29-2+sds11])
  27 m4_define([libva_sds_version_0_30], [1])
  28 m4_define([libva_sds_package_version_0_30], [0.30-1+sds1])
  29 m4_define([libva_glx_sds_version_0_30], [5])
  30 m4_define([libva_glx_sds_package_version_0_30], [0.30.4-1+sds6])
  31 m4_define([libva_glx_sds_version_0_31], [1])
  32 m4_define([libva_glx_sds_package_version_0_31], [0.31.0-1+sds1])
  33 m4_define([libva_sds_version], [libva_glx_sds_version_0_31])
  34 m4_define([libva_sds_package_version], [libva_glx_sds_package_version_0_31])
  35
  36 # gtk-doc version number
  37 # XXX: introspection annotations require gtk-doc >= 1.12
  38 m4_define([gtkdoc_major_version], [1])
  39 m4_define([gtkdoc_minor_version], [9])
  40 m4_define([gtkdoc_version], [gtkdoc_major_version.gtkdoc_minor_version])
  41
  42 AC_PREREQ([2.57])
  43 AC_INIT([gst_vaapi], [gst_vaapi_version],
  44     [gbeauchesne@splitted-desktop.com],
  45     [gstreamer-vaapi])
  46 AC_CONFIG_SRCDIR([Makefile.am])
  47 AC_CANONICAL_TARGET
  48 AM_INIT_AUTOMAKE
  49 AM_CONFIG_HEADER([config.h])
  50
  51 TODAY="`LC_ALL=C date +'%a, %d %b %Y %X %z'`"
  52 AC_SUBST(TODAY)
  53
  54 GST_VAAPI_MAJOR_VERSION=gst_vaapi_major_version
  55 AC_SUBST(GST_VAAPI_MAJOR_VERSION)
  56
  57 LIBVA_SDS_PACKAGE_VERSION=libva_sds_package_version
  58 AC_SUBST(LIBVA_SDS_PACKAGE_VERSION)
  59
  60 dnl Versions for GStreamer and plugins-base
  61 GST_MAJORMINOR=gst_major_minor_version
  62 GST_VERSION_REQUIRED=gst_version
  63 GST_PLUGINS_BASE_VERSION_REQUIRED=gst_plugins_base_version
  64 AC_SUBST(GST_MAJORMINOR)
  65 AC_SUBST(GST_VERSION_REQUIRED)
  66 AC_SUBST(GST_PLUGINS_BASE_VERSION_REQUIRED)
  67
  68 dnl Check for tools
  69 AC_PROG_CC
  70 AM_PROG_CC_C_O
  71 AC_PROG_LIBTOOL
  72
  73 AC_ARG_ENABLE(glx,
  74     AC_HELP_STRING([--enable-glx],
  75                    [enable OpenGL/X11 @<:@default=yes@:>@]),
  76     [], [enable_glx="yes"])
  77
  78 AC_ARG_ENABLE(vaapisink-glx,
  79     AC_HELP_STRING([--enable-vaapisink-glx],
  80                    [enable OpenGL/X11 to vaapisink @<:@default=yes@:>@]),
  81     [], [enable_vaapisink_glx="no"])
  82
  83 dnl Check for __attribute__((visibility()))
  84 AC_CACHE_CHECK([whether __attribute__((visibility())) is supported],
  85   vaapi_cv_visibility_attribute,
  86   [cat > conftest.c <<EOF
  87 int foo __attribute__ ((visibility ("hidden"))) = 1;
  88 int bar __attribute__ ((visibility ("protected"))) = 1;
  89 EOF
  90   vaapi_cv_visibility_attribute=no
  91   if ${CC-cc} -Werror -S conftest.c -o conftest.s >/dev/null 2>&1; then
  92     if grep '\.hidden.*foo' conftest.s >/dev/null; then
  93       if grep '\.protected.*bar' conftest.s >/dev/null; then
  94         vaapi_cv_visibility_attribute=yes
  95       fi
  96     fi
  97   fi
  98   rm -f conftest.[cs]
  99 ])
 100 if test $vaapi_cv_visibility_attribute = yes; then
 101   vaapi_cv_visibility_attribute_hidden="__attribute__((visibility(\"hidden\")))"
 102 else
 103   vaapi_cv_visibility_attribute_hidden=""
 104 fi
 105 AC_DEFINE_UNQUOTED([attribute_hidden],
 106                    [$vaapi_cv_visibility_attribute_hidden],
 107                    [Define the "hidden" visibility attribute])
 108
 109 dnl Check for Gtk doc
 110 GTKDOC_VERSION=gtkdoc_version
 111 GTK_DOC_CHECK([$GTKDOC_VERSION])
 112 AM_CONDITIONAL([BUILD_GTK_DOC], [test "x$enable_gtk_doc" = "xyes"])
 113 AC_SUBST(GTKDOC_VERSION)
 114
 115 dnl Check for GLib
 116 AC_PATH_PROG([GLIB_GENMARSHAL], [glib-genmarshal])
 117 PKG_CHECK_MODULES([GLIB], [glib-2.0])
 118 AC_SUBST(GLIB_CFLAGS)
 119 AC_SUBST(GLIB_LIBS)
 120
 121 dnl Check for GStreamer
 122 PKG_CHECK_MODULES([GST],
 123     [gstreamer-$GST_MAJORMINOR >= $GST_VERSION_REQUIRED]
 124 )
 125 AC_SUBST(GST_CFLAGS)
 126 AC_SUBST(GST_LIBS)
 127
 128 dnl Check for GStreamer plugins-base
 129 PKG_CHECK_MODULES([GST_PLUGINS_BASE],
 130     [gstreamer-plugins-base-$GST_MAJORMINOR >= $GST_PLUGINS_BASE_VERSION_REQUIRED]
 131 )
 132 AC_SUBST(GST_PLUGINS_BASE_CFLAGS)
 133 AC_SUBST(GST_PLUGINS_BASE_LIBS)
 134
 135 dnl Check for GStreamer base
 136 PKG_CHECK_MODULES([GST_BASE],
 137     [gstreamer-base-$GST_MAJORMINOR >= $GST_VERSION_REQUIRED]
 138 )
 139 AC_SUBST(GST_BASE_CFLAGS)
 140 AC_SUBST(GST_BASE_LIBS)
 141
 142 dnl Check for GStreamer video
 143 PKG_CHECK_MODULES([GST_VIDEO],
 144     [gstreamer-video-$GST_MAJORMINOR >= $GST_VERSION_REQUIRED]
 145 )
 146 AC_SUBST(GST_VIDEO_CFLAGS)
 147 AC_SUBST(GST_VIDEO_LIBS)
 148
 149 dnl Check for the GStreamer plugins directory
 150 AC_MSG_CHECKING([for GStreamer plugins directory])
 151 GST_PLUGINS_DIR=`$PKG_CONFIG gstreamer-$GST_MAJORMINOR --variable pluginsdir`
 152 if test -z "$GST_PLUGINS_DIR"; then
 153     echo "FAIL FAIL FAIL"
 154     GST_PLUGINS_DIR="\$(libdir)/gstreamer-$GST_MAJORMINOR"
 155 fi
 156 AC_MSG_RESULT([$GST_PLUGINS_DIR])
 157 plugindir="$GST_PLUGINS_DIR"
 158 AC_SUBST(plugindir)
 159
 160 dnl Check for X11
 161 PKG_CHECK_MODULES(X11, [x11])
 162
 163 dnl Check for OpenGL
 164 USE_GLX=1
 165 if test "$enable_glx" != "yes"; then
 166     USE_GLX=0
 167 fi
 168 GLX_CFLAGS=""
 169 GLX_LIBS=""
 170 AC_CHECK_HEADERS([GL/gl.h GL/glext.h GL/glx.h], [], [USE_GLX=0], [
 171 #ifdef HAVE_GL_GL_H
 172 # include <GL/gl.h>
 173 #endif
 174 ])
 175 AC_CHECK_LIB(GL, glXCreateContext, [GLX_LIBS="-lGL"], [USE_GLX=0])
 176 AC_SUBST(GLX_CFLAGS)
 177 AC_SUBST(GLX_LIBS)
 178
 179 dnl Check for VA-API
 180 LIBVA_PKGNAME="libva"
 181 PKG_CHECK_MODULES(LIBVA, [$LIBVA_PKGNAME])
 182 AC_SUBST(LIBVA_PKGNAME)
 183
 184 dnl ... original VA-API 0.29
 185 AC_CACHE_CHECK([for old VA-API 0.29],
 186     ac_cv_have_vaapi_old, [
 187     saved_CFLAGS="$CFLAGS"
 188     CFLAGS="$CFLAGS $LIBVA_CFLAGS"
 189     saved_LIBS="$LIBS"
 190     LIBS="$LIBS $LIBVA_LIBS"
 191     AC_TRY_LINK(
 192     [#include <va_x11.h>],
 193     [vaGetDisplay(NULL)],
 194     [ac_cv_have_vaapi_old="yes"],
 195     [ac_cv_have_vaapi_old="no"])
 196     CFLAGS="$saved_CFLAGS"
 197     LIBS="$saved_LIBS"
 198 ])
 199 if test "$ac_cv_have_vaapi_old" = "yes"; then
 200     LIBVA_EXTRA_CFLAGS="$LIBVA_CFLAGS -DGST_VAAPI_USE_OLD_VAAPI_0_29"
 201 fi
 202
 203 dnl ... VA-API >= 0.31 or -sds
 204 LIBVA_X11_PKGNAME="libva-x11"
 205 PKG_CHECK_MODULES(LIBVA_X11, [$LIBVA_X11_PKGNAME],
 206     [ac_cv_have_vaapi_x11="yes"],
 207     [ac_cv_have_vaapi_x11="no"]
 208 )
 209 if test "$ac_cv_have_vaapi_x11" = "no"; then
 210     if test "$ac_cv_have_vaapi_old" = "yes"; then
 211         LIBVA_X11_PKGNAME="libva"
 212         CFLAGS="$CFLAGS $LIBVA_EXTRA_CFLAGS"
 213         LIBS="$LIBS $LIBVA_EXTRA_LIBS"
 214     else
 215         AC_MSG_ERROR([could not find VA-API])
 216     fi
 217 fi
 218 AC_SUBST(LIBVA_X11_PKGNAME)
 219
 220 dnl ... VA-API >= 0.31 or -sds
 221 LIBVA_GLX_PKGNAME="libva-glx"
 222 PKG_CHECK_MODULES(LIBVA_GLX, [$LIBVA_GLX_PKGNAME],
 223     [ac_cv_have_vaapi_glx="yes"],
 224     [ac_cv_have_vaapi_glx="no"]
 225 )
 226 if test "$ac_cv_have_vaapi_glx" = "no"; then
 227     AC_MSG_WARN([could not find VA/GLX extensions. Disabling GLX support])
 228     USE_GLX=0
 229 fi
 230 AC_SUBST(LIBVA_GLX_PKGNAME)
 231
 232 AC_SUBST(LIBVA_EXTRA_CFLAGS)
 233 AC_SUBST(LIBVA_EXTRA_LIBS)
 234
 235 dnl Check for OpenGL support to
 236 if test "$enable_vaapisink_glx:$USE_GLX" = "yes:1"; then
 237     USE_VAAPISINK_GLX=1
 238 else
 239     USE_VAAPISINK_GLX=0
 240 fi
 241
 242 AC_DEFINE_UNQUOTED(USE_GLX, $USE_GLX, [Defined to 1 if GLX is enabled])
 243 AM_CONDITIONAL(USE_GLX, test $USE_GLX -eq 1)
 244
 245 AC_DEFINE_UNQUOTED(USE_VAAPISINK_GLX, $USE_VAAPISINK_GLX,
 246     [Defined to 1 to enable GLX support to vaapisink])
 247 AM_CONDITIONAL(USE_VAAPISINK_GLX, test $USE_VAAPISINK_GLX -eq 1)
 248
 249 VA_VERSION=`$PKG_CONFIG --modversion libva`
 250 VA_MAJOR_VERSION=`echo "$VA_VERSION" | cut -d'.' -f1`
 251 VA_MINOR_VERSION=`echo "$VA_VERSION" | cut -d'.' -f2`
 252 VA_MICRO_VERSION=`echo "$VA_VERSION" | cut -d'.' -f3`
 253 VA_SDS_VERSION=`$PKG_CONFIG libva --variable sdsversion`
 254
 255 VA_VERSION_STR="$VA_VERSION"
 256 if test -n "$VA_SDS_VERSION"; then
 257     VA_VERSION_STR="$VA_VERSION_STR-sds$VA_SDS_VERSION"
 258 fi
 259
 260 pkgconfigdir=${libdir}/pkgconfig
 261 AC_SUBST(pkgconfigdir)
 262
 263 AC_OUTPUT([
 264     Makefile
 265     debian.upstream/Makefile
 266     debian.upstream/changelog
 267     debian.upstream/control
 268     debian.upstream/gstreamer$GST_MAJORMINOR-vaapi.install:\
 269 debian.upstream/gstreamer-vaapi.install.in
 270     debian.upstream/gstreamer$GST_MAJORMINOR-vaapi-doc.install:\
 271 debian.upstream/gstreamer-vaapi-doc.install.in
 272     debian.upstream/libgstvaapi$GST_VAAPI_MAJOR_VERSION.install:\
 273 debian.upstream/libgstvaapi.install.in
 274     debian.upstream/libgstvaapi$GST_VAAPI_MAJOR_VERSION-dev.install:\
 275 debian.upstream/libgstvaapi-dev.install.in
 276     debian.upstream/libgstvaapi-x11-$GST_VAAPI_MAJOR_VERSION.install:\
 277 debian.upstream/libgstvaapi-x11.install.in
 278     debian.upstream/libgstvaapi-glx-$GST_VAAPI_MAJOR_VERSION.install:\
 279 debian.upstream/libgstvaapi-glx.install.in
 280     docs/Makefile
 281     docs/reference/Makefile
 282     docs/reference/libs/Makefile
 283     docs/reference/libs/libs-docs.xml
 284     docs/reference/plugins/Makefile
 285     docs/reference/plugins/plugins-docs.xml
 286     gst-libs/Makefile
 287     gst-libs/gst/Makefile
 288     gst-libs/gst/vaapi/Makefile
 289     pkgconfig/Makefile
 290     pkgconfig/gstreamer-vaapi-$GST_MAJORMINOR.pc:\
 291 pkgconfig/gstreamer-vaapi.pc.in
 292     pkgconfig/gstreamer-vaapi-glx-$GST_MAJORMINOR.pc:\
 293 pkgconfig/gstreamer-vaapi-glx.pc.in
 294     pkgconfig/gstreamer-vaapi-x11-$GST_MAJORMINOR.pc:\
 295 pkgconfig/gstreamer-vaapi-x11.pc.in
 296     sys/Makefile
 297     sys/vaapiconvert/Makefile
 298     sys/vaapisink/Makefile
 299     tests/Makefile
 300 ])
 301
 302 dnl Print summary
 303 echo
 304 echo $PACKAGE configuration summary:
 305 echo
 306 echo VA-API version ................... : $VA_VERSION_STR
 307 echo GLX support ...................... : $(test $USE_GLX  -eq 1 && echo yes || echo no)
 308 echo Build vaapisink with OpenGL ...... : $(test $USE_VAAPISINK_GLX  -eq 1 && echo yes || echo no)
 309 echo